libs/gst/check/meson.build

   1 gst_check_sources = [
   2   'gstbufferstraw.c',
   3   'gstcheck.c',
   4   'gstconsistencychecker.c',
   5   'gstharness.c',
   6   'gsttestclock.c',
   7 ]
   8 gst_check_headers = [
   9   'check.h',
  10   'gstbufferstraw.h',
  11   'gstcheck.h',
  12   'gstconsistencychecker.h',
  13   'gstharness.h',
  14   'gsttestclock.h',
  15 ]
  16 install_headers(gst_check_headers, subdir : 'gstreamer-1.0/gst/check/')
  17
  18
  19 check_cdata = configuration_data()
  20
  21 check_cdata.set('ENABLE_SUBUNIT', 0)
  22 check_cdata.set('CHECK_MAJOR_VERSION', 0)
  23 check_cdata.set('CHECK_MINOR_VERSION', 9)
  24 check_cdata.set('CHECK_MICRO_VERSION', 14)
  25 if host_machine.system() != 'windows'
  26   check_cdata.set('HAVE_FORK', 1)
  27 else
  28   check_cdata.set('HAVE_FORK', 0)
  29 endif
  30
  31 subdir('libcheck')
  32
  33 configure_file(input : 'libcheck/check.h.in',
  34   output : 'internal-check.h',
  35   install : true,
  36   install_dir : 'include/gstreamer-1.0/gst/check/',
  37   configuration : check_cdata)
  38
  39 gst_check = shared_library('gstcheck-@0@'.format(apiversion),
  40   gst_check_sources,
  41   c_args : gst_c_args,
  42   version : libversion,
  43   soversion : soversion,
  44   install : true,
  45   include_directories : [configinc, libsinc],
  46   link_with : [libcheck],
  47   dependencies : [gobject_dep, glib_dep, gst_dep],
  48 )
  49
  50 gst_check_gen_sources = []
  51
  52 if build_gir
  53   gst_gir_extra_args = gir_init_section + [ '--c-include=gst/check/check.h' ]
  54   gst_check_gen_sources += [gnome.generate_gir(gst_check,
  55     sources : gst_check_sources + gst_check_headers,
  56     namespace : 'GstCheck',
  57     nsversion : apiversion,
  58     identifier_prefix : 'Gst',
  59     symbol_prefix : 'gst',
  60     export_packages : 'gstreamer-check-1.0',
  61     dependencies : [gst_dep],
  62     include_directories : [configinc, libsinc, privinc],
  63     includes : ['GLib-2.0', 'GObject-2.0', 'GModule-2.0', 'Gst-1.0'],
  64     install : true,
  65     extra_args : gst_gir_extra_args,
  66   )]
  67 endif
  68
  69 gst_check_dep = declare_dependency(link_with : gst_check,
  70   include_directories : [libsinc],
  71   dependencies : [gst_dep],
  72   sources : gst_check_gen_sources)