libs/gst/check/meson.build

   1 gst_check_sources = [
   2   'gstbufferstraw.c',
   3   'gstcheck.c',
   4   'gstconsistencychecker.c',
   5   'gstharness.c',
   6   'gsttestclock.c',
   7 ]
   8 gst_check_headers = [
   9   'check.h',
  10   'check-prelude.h',
  11   'gstbufferstraw.h',
  12   'gstcheck.h',
  13   'gstconsistencychecker.h',
  14   'gstharness.h',
  15   'gsttestclock.h',
  16 ]
  17 install_headers(gst_check_headers, subdir : 'gstreamer-1.0/gst/check/')
  18
  19
  20 check_cdata = configuration_data()
  21
  22 check_cdata.set('ENABLE_SUBUNIT', 0)
  23 check_cdata.set('CHECK_MAJOR_VERSION', 0)
  24 check_cdata.set('CHECK_MINOR_VERSION', 9)
  25 check_cdata.set('CHECK_MICRO_VERSION', 14)
  26 if host_machine.system() != 'windows'
  27   check_cdata.set('HAVE_FORK', 1)
  28 else
  29   check_cdata.set('HAVE_FORK', 0)
  30 endif
  31
  32 subdir('libcheck')
  33
  34 configure_file(input : 'libcheck/check.h.in',
  35   output : 'internal-check.h',
  36   install : true,
  37   install_dir : join_paths(get_option('includedir'), 'gstreamer-1.0/gst/check'),
  38   configuration : check_cdata)
  39
  40 gst_check = shared_library('gstcheck-@0@'.format(apiversion),
  41   gst_check_sources,
  42   c_args : gst_c_args + ['-DGST_EXPORTS'],
  43   version : libversion,
  44   soversion : soversion,
  45   install : true,
  46   include_directories : [configinc, libsinc],
  47   link_with : [libcheck],
  48   dependencies : [gobject_dep, glib_dep, gst_dep],
  49 )
  50
  51 gst_check_gen_sources = []
  52
  53 if build_gir
  54   gst_gir_extra_args = gir_init_section + [ '--c-include=gst/check/check.h' ]
  55   gst_check_gen_sources += [gnome.generate_gir(gst_check,
  56     sources : gst_check_sources + gst_check_headers,
  57     namespace : 'GstCheck',
  58     nsversion : apiversion,
  59     identifier_prefix : 'Gst',
  60     symbol_prefix : 'gst',
  61     export_packages : 'gstreamer-check-1.0',
  62     dependencies : [gst_dep],
  63     include_directories : [configinc, libsinc, privinc],
  64     includes : ['GLib-2.0', 'GObject-2.0', 'GModule-2.0', 'Gst-1.0'],
  65     install : true,
  66     extra_args : gst_gir_extra_args,
  67   )]
  68 endif
  69
  70 gst_check_dep = declare_dependency(link_with : gst_check,
  71   include_directories : [libsinc],
  72   dependencies : [gst_dep],
  73   sources : gst_check_gen_sources)