libs/gst/check/libcheck/meson.build

   1 libcheck_files = [
   2   'check.c',
   3   'check_error.c',
   4   'check_list.c',
   5   'check_log.c',
   6   'check_msg.c',
   7   'check_pack.c',
   8   'check_print.c',
   9   'check_run.c',
  10   'check_str.c',
  11   'libcompat/libcompat.c'
  12 ]
  13
  14 if not cdata.has('HAVE_ALARM')
  15   libcheck_files += ['libcompat/alarm.c']
  16 endif
  17
  18 if not cdata.has('HAVE_CLOCK_GETTIME')
  19   libcheck_files += ['libcompat/clock_gettime.c']
  20 endif
  21
  22 if not cdata.has('HAVE_DECL_STRSIGNAL')
  23   libcheck_files += ['libcompat/strsignal.c']
  24 endif
  25
  26 # FIXME: check for symbols timer_create, timer_settime, timer_delete as well
  27 if not rt_lib.found()
  28   libcheck_files += [
  29     'libcompat/timer_create.c',
  30     'libcompat/timer_settime.c',
  31     'libcompat/timer_delete.c'
  32   ]
  33 endif
  34
  35 configure_file(input : 'check.h.in',
  36   output : 'check.h',
  37   configuration : check_cdata)
  38
  39 internal_check_h_inc = include_directories('..')
  40
  41 libcheck = static_library('check',
  42   libcheck_files,
  43   include_directories : [configinc, internal_check_h_inc],
  44   dependencies : [rt_lib, mathlib],
  45   c_args: gst_c_args,
  46   pic: true)