help2man.PL

   1 #!/usr/bin/perl
   2
   3 #
   4 # Self extracting help2man script.
   5 #
   6 #   -q, --quiet         Suppress extraction message
   7 #   -s, --stdout        Extract to stdout
   8 #   -w, --with-gettext  Add support for localized man pages
   9 #   -n, --name          Print name only*
  10 #   -v, --version       Print version only*
  11 #
  12 # *script not created
  13 #
  14
  15 use 5.008;
  16 use Config;
  17 use Getopt::Long;
  18
  19 my ($program, $version) = ('help2man', '1.46.4');
  20
  21 my %opts;
  22 die "Usage: $0 [--quiet] [--stdout] [--with-gettext] [--name] [--version]\n"
  23     unless GetOptions \%opts, qw(quiet stdout with-gettext name version)
  24       and !@ARGV;
  25
  26 print "$program\n" if $opts{name};
  27 print "$version\n" if $opts{version};
  28 exit               if $opts{name} or $opts{version};
  29
  30 my $target = $0;
  31 my $tmp;
  32 if ($opts{stdout})
  33 {
  34     *OUT = *STDOUT;
  35     $opts{quiet} = 1;
  36 }
  37 else
  38 {
  39     $target =~ s!.*/!!;
  40     $target =~ s/\.PL$// or die "$0: can't determine target name\n";
  41     $tmp = "$target.tmp$$";
  42     unlink $tmp          or die "$0: can't unlink $tmp ($!)\n" if -e $tmp;
  43     open OUT, ">$tmp"    or die "$0: can't create $tmp ($!)\n";
  44 }
  45
  46 print "Extracting $target (with variable substitutions)\n"
  47     unless $opts{quiet};
  48
  49 # Add startup header.
  50 print OUT "$Config{startperl} -w\n";
  51
  52 # For systems without the crash-bang hack also add:
  53 print OUT <<"!GROK!THIS!" if $Config{sharpbang} !~ /^#!/;
  54 eval 'exec $Config{perlpath} -wS \$0 \${1+"\$@"}'
  55     if \$running_under_some_shell;
  56
  57 \$running_under_some_shell = 0; # for -w
  58 !GROK!THIS!
  59
  60 # No substitutions for this chunk:
  61 print OUT <<'!NO!SUBS!';
  62
  63 # Generate a short man page from --help and --version output.
  64 # Copyright (C) 1997, 1998, 1999, 2000, 2001, 2002, 2003, 2004, 2005, 2009,
  65 # 2010, 2011, 2012, 2013, 2014 Free Software Foundation, Inc.
  66
  67 # This program is free software; you can redistribute it and/or modify
  68 # it under the terms of the GNU General Public License as published by
  69 # the Free Software Foundation; either version 3, or (at your option)
  70 # any later version.
  71
  72 # This program is distributed in the hope that it will be useful,
  73 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  74 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  75 # GNU General Public License for more details.
  76
  77 # You should have received a copy of the GNU General Public License
  78 # along with this program; if not, see <http://www.gnu.org/licenses/>.
  79
  80 # Written by Brendan O'Dea <bod@debian.org>
  81 # Available from ftp://ftp.gnu.org/gnu/help2man/
  82
  83 use 5.008;
  84 use strict;
  85 use Getopt::Long;
  86 use Text::ParseWords qw(shellwords);
  87 use Text::Tabs qw(expand);
  88 use POSIX qw(strftime setlocale LC_ALL);
  89 !NO!SUBS!
  90
  91 print OUT <<'!NO!SUBS!' if $opts{'with-gettext'};
  92 use Locale::gettext;
  93 use Encode qw(decode encode);
  94 use I18N::Langinfo qw(langinfo CODESET);
  95 !NO!SUBS!
  96
  97 # Interpolate program name and version:
  98 print OUT <<"!GROK!THIS!";
  99
 100 my \$this_program = '$program';
 101 my \$this_version = '$version';
 102 !GROK!THIS!
 103
 104 # Conditionally include gettext support:
 105 print OUT $opts{'with-gettext'} ? <<'!WITH!GETTEXT!' : <<'!NO!GETTEXT!';
 106 my $encoding;
 107
 108 {
 109     my $gettext = Locale::gettext->domain($this_program);
 110     sub _ { $gettext->get($_[0]) }
 111
 112     my ($user_locale) = grep defined && length,
 113         (map $ENV{$_}, qw(LANGUAGE LC_ALL LC_MESSAGES LANG)), 'C';
 114
 115     my $user_encoding = langinfo CODESET;
 116
 117     # Set localisation of date and executable's output.
 118     sub configure_locale
 119     {
 120         delete @ENV{qw(LANGUAGE LC_MESSAGES LANG)};
 121         setlocale LC_ALL, $ENV{LC_ALL} = shift || 'C';
 122         $encoding = langinfo CODESET;
 123     }
 124
 125     sub dec { $encoding ? decode $encoding, $_[0] : $_[0] }
 126     sub enc { $encoding ? encode $encoding, $_[0] : $_[0] }
 127     sub enc_user { encode $user_encoding, $_[0] }
 128     sub kark # die with message formatted in the invoking user's locale
 129     {
 130         setlocale LC_ALL, $user_locale;
 131         my $fmt = $gettext->get(shift);
 132         my $errmsg = enc_user sprintf $fmt, @_;
 133         die $errmsg, "\n";
 134     }
 135 }
 136
 137 !WITH!GETTEXT!
 138
 139 sub _ { $_[0] }
 140 sub configure_locale
 141 {
 142     my $locale = shift;
 143     die "$this_program: no locale support (Locale::gettext required)\n"
 144         unless $locale eq 'C';
 145 }
 146
 147 sub dec { $_[0] }
 148 sub enc { $_[0] }
 149 sub enc_user { $_[0] }
 150 sub kark { die +(sprintf shift, @_), "\n" }
 151 !NO!GETTEXT!
 152
 153 # No substitutions for this chunk:
 154 print OUT <<'!NO!SUBS!';
 155 sub N_ { $_[0] }
 156
 157 sub program_basename;
 158 sub get_option_value;
 159 sub convert_option;
 160 sub fix_italic_spacing;
 161
 162 my $version_info = enc_user sprintf _(<<'EOT'), $this_program, $this_version;
 163 GNU %s %s
 164
 165 Copyright (C) 1997, 1998, 1999, 2000, 2001, 2002, 2003, 2004, 2005, 2009, 2010,
 166 2011, 2012, 2013, 2014 Free Software Foundation, Inc.
 167 This is free software; see the source for copying conditions.  There is NO
 168 warranty; not even for MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.
 169
 170 Written by Brendan O'Dea <bod@debian.org>
 171 EOT
 172
 173 my $help_info = enc_user sprintf _(<<'EOT'), $this_program, $this_program;
 174 `%s' generates a man page out of `--help' and `--version' output.
 175
 176 Usage: %s [OPTION]... EXECUTABLE
 177
 178  -n, --name=STRING       description for the NAME paragraph
 179  -s, --section=SECTION   section number for manual page (1, 6, 8)
 180  -m, --manual=TEXT       name of manual (User Commands, ...)
 181  -S, --source=TEXT       source of program (FSF, Debian, ...)
 182  -L, --locale=STRING     select locale (default "C")
 183  -i, --include=FILE      include material from `FILE'
 184  -I, --opt-include=FILE  include material from `FILE' if it exists
 185  -o, --output=FILE       send output to `FILE'
 186  -p, --info-page=TEXT    name of Texinfo manual
 187  -N, --no-info           suppress pointer to Texinfo manual
 188  -l, --libtool           exclude the `lt-' from the program name
 189      --help              print this help, then exit
 190      --version           print version number, then exit
 191
 192 EXECUTABLE should accept `--help' and `--version' options and produce output on
 193 stdout although alternatives may be specified using:
 194
 195  -h, --help-option=STRING     help option string
 196  -v, --version-option=STRING  version option string
 197  --version-string=STRING      version string
 198  --no-discard-stderr          include stderr when parsing option output
 199
 200 Report bugs to <bug-help2man@gnu.org>.
 201 EOT
 202
 203 my $section = 1;
 204 my $manual = '';
 205 my $source = '';
 206 my $help_option = '--help';
 207 my $version_option = '--version';
 208 my $discard_stderr = 1;
 209 my ($opt_name, @opt_include, $opt_output, $opt_info, $opt_no_info, $opt_libtool,
 210     $version_text);
 211
 212 my %opt_def = (
 213     'n|name=s'           => \$opt_name,
 214     's|section=s'        => \$section,
 215     'm|manual=s'         => \$manual,
 216     'S|source=s'         => \$source,
 217     'L|locale=s'         => sub { configure_locale pop },
 218     'i|include=s'        => sub { push @opt_include, [ pop, 1 ] },
 219     'I|opt-include=s'    => sub { push @opt_include, [ pop, 0 ] },
 220     'o|output=s'         => \$opt_output,
 221     'p|info-page=s'      => \$opt_info,
 222     'N|no-info'          => \$opt_no_info,
 223     'l|libtool'          => \$opt_libtool,
 224     'help'               => sub { print $help_info; exit },
 225     'version'            => sub { print $version_info; exit },
 226     'h|help-option=s'    => \$help_option,
 227     'v|version-option=s' => \$version_option,
 228     'version-string=s'   => \$version_text,
 229     'discard-stderr!'    => \$discard_stderr,
 230 );
 231
 232 # Parse options.
 233 Getopt::Long::config('bundling');
 234 die $help_info unless GetOptions %opt_def and @ARGV == 1;
 235
 236 !NO!SUBS!
 237
 238 print OUT <<'!NO!SUBS!' if $opts{'with-gettext'};
 239 configure_locale unless $encoding;
 240
 241 !NO!SUBS!
 242
 243 # No substitutions for the remainder of the script:
 244 print OUT <<'!NO!SUBS!';
 245 my %include = ();
 246 my %replace = ();
 247 my %append = ();
 248 my %append_match = ();
 249 my @sections = ();  # retain order of include file or in-line *section*s
 250
 251 # Process include file (if given).  Format is:
 252 #
 253 #   Optional initial text, ignored.  May include lines starting with `-'
 254 #   which are processed as options.
 255 #
 256 #   [section]
 257 #   Verbatim text to be included in the named section.  By default at
 258 #   the start, but in the case of `name' and `synopsis' the content
 259 #   will replace the autogenerated contents.
 260 #
 261 #   [<section]
 262 #   Verbatim text to be inserted at the start of the named section.
 263 #
 264 #   [=section]
 265 #   Verbatim text to replace the named section.
 266 #
 267 #   [>section]
 268 #   Verbatim text to be appended to the end of the named section.
 269 #
 270 #   /pattern/
 271 #   Verbatim text for inclusion below a paragraph matching `pattern'.
 272 #
 273
 274 while (@opt_include)
 275 {
 276     my ($inc, $required) = @{shift @opt_include};
 277
 278     next unless -f $inc or $required;
 279     kark N_("%s: can't open `%s' (%s)"), $this_program, $inc, $!
 280         unless open INC, $inc;
 281
 282     my $key;
 283     my $hash;
 284
 285     while (<INC>)
 286     {
 287         # Convert input to internal Perl format, so that multibyte
 288         # sequences are treated as single characters.
 289         $_ = dec $_;
 290
 291         # [section]
 292         if (/^\[([^]]+)\]\s*$/)
 293         {
 294             $key = uc $1;
 295             $key =~ s/^\s+//;
 296             $key =~ s/\s+$//;
 297             $hash = \%include;
 298             # Handle explicit [<section], [=section] and [>section]
 299             if ($key =~ s/^([<>=])\s*//)
 300             {
 301                 if    ($1 eq '>') { $hash = \%append; }
 302                 elsif ($1 eq '=') { $hash = \%replace; }
 303             }
 304             # NAME/SYNOPSIS replace by default
 305             elsif ($key eq _('NAME') or $key eq _('SYNOPSIS'))
 306             {
 307                 $hash = \%replace;
 308             }
 309             else
 310             {
 311                 $hash = \%include;
 312             }
 313
 314             push @sections, $key;
 315             next;
 316         }
 317
 318         # /pattern/
 319         if (m!^/(.*)/([ims]*)\s*$!)
 320         {
 321             my $pat = $2 ? "(?$2)$1" : $1;
 322
 323             # Check pattern.
 324             eval { $key = qr($pat) };
 325             if ($@)
 326             {
 327                 $@ =~ s/ at .*? line \d.*//;
 328                 die "$inc:$.:$@";
 329             }
 330
 331             $hash = \%append_match;
 332             next;
 333         }
 334
 335         # Check for options before the first section--anything else is
 336         # silently ignored, allowing the first for comments and
 337         # revision info.
 338         unless ($key)
 339         {
 340             # handle options
 341             if (/^-/)
 342             {
 343                 local @ARGV = shellwords $_;
 344                 GetOptions %opt_def;
 345             }
 346
 347             next;
 348         }
 349
 350         $hash->{$key} .= $_;
 351     }
 352
 353     close INC;
 354
 355     kark N_("%s: no valid information found in `%s'"), $this_program, $inc
 356         unless $key;
 357 }
 358
 359 # Compress trailing blank lines.
 360 for my $hash (\(%include, %replace, %append, %append_match))
 361 {
 362     for (keys %$hash) { $hash->{$_} =~ s/\n+$/\n/ }
 363 }
 364
 365 # Grab help and version info from executable.
 366 my $help_text   = get_option_value $ARGV[0], $help_option;
 367 $version_text ||= get_option_value $ARGV[0], $version_option;
 368
 369 # Translators: the following message is a strftime(3) format string, which in
 370 # the English version expands to the month as a word and the full year.  It
 371 # is used on the footer of the generated manual pages.  If in doubt, you may
 372 # just use %x as the value (which should be the full locale-specific date).
 373 my $date = enc strftime _("%B %Y"), localtime;
 374 my $program = program_basename $ARGV[0];
 375 my $package = $program;
 376 my $version;
 377
 378 if ($opt_output)
 379 {
 380     unlink $opt_output or kark N_("%s: can't unlink %s (%s)"),
 381         $this_program, $opt_output, $! if -e $opt_output;
 382
 383     open STDOUT, ">$opt_output"
 384         or kark N_("%s: can't create %s (%s)"), $this_program, $opt_output, $!;
 385 }
 386
 387 # The first line of the --version information is assumed to be in one
 388 # of the following formats:
 389 #
 390 #   <version>
 391 #   <program> <version>
 392 #   {GNU,Free} <program> <version>
 393 #   <program> ({GNU,Free} <package>) <version>
 394 #   <program> - {GNU,Free} <package> <version>
 395 #
 396 # and separated from any copyright/author details by a blank line.
 397
 398 ($_, $version_text) = ((split /\n+/, $version_text, 2), '');
 399
 400 if (/^(\S+) +\(((?:GNU|Free) +[^)]+)\) +(.*)/ or
 401     /^(\S+) +- *((?:GNU|Free) +\S+) +(.*)/)
 402 {
 403     $program = program_basename $1;
 404     $package = $2;
 405     $version = $3;
 406 }
 407 elsif (/^((?:GNU|Free) +)?(\S+) +(.*)/)
 408 {
 409     $program = program_basename $2;
 410     $package = $1 ? "$1$program" : $program;
 411     $version = $3;
 412 }
 413 else
 414 {
 415     $version = $_;
 416 }
 417
 418 # No info for `info' itself.
 419 $opt_no_info = 1 if $program eq 'info';
 420
 421 if ($opt_name)
 422 {
 423     # --name overrides --include contents.
 424     $replace{_('NAME')} = "$program \\- $opt_name\n";
 425 }
 426
 427 # Translators: "NAME", "SYNOPSIS" and other one or two word strings in all
 428 # upper case are manual page section headings.  The man(1) manual page in your
 429 # language, if available should provide the conventional translations.
 430 for ($replace{_('NAME')} || ($include{_('NAME')} ||= ''))
 431 {
 432     if ($_) # Use first name given as $program
 433     {
 434         $program = $1 if /^([^\s,]+)(?:,?\s*[^\s,\\-]+)*\s+\\?-/;
 435     }
 436     else # Set a default (useless) NAME paragraph.
 437     {
 438         $_ = sprintf _("%s \\- manual page for %s %s") . "\n", $program,
 439             $program, $version;
 440     }
 441 }
 442
 443 # Man pages traditionally have the page title in caps.
 444 my $PROGRAM = uc $program;
 445
 446 # Set default page head/footers
 447 $source ||= "$program $version";
 448 unless ($manual)
 449 {
 450     for ($section)
 451     {
 452         if (/^(1[Mm]|8)/) { $manual = enc _('System Administration Utilities') }
 453         elsif (/^6/)      { $manual = enc _('Games') }
 454         else              { $manual = enc _('User Commands') }
 455     }
 456 }
 457
 458 # Extract usage clause(s) [if any] for SYNOPSIS.
 459 # Translators: "Usage" and "or" here are patterns (regular expressions) which
 460 # are used to match the usage synopsis in program output.  An example from cp
 461 # (GNU coreutils) which contains both strings:
 462 #  Usage: cp [OPTION]... [-T] SOURCE DEST
 463 #    or:  cp [OPTION]... SOURCE... DIRECTORY
 464 #    or:  cp [OPTION]... -t DIRECTORY SOURCE...
 465 my $PAT_USAGE = _('Usage');
 466 my $PAT_USAGE_CONT = _('or');
 467 if ($help_text =~ s/^($PAT_USAGE):( +(\S+))(.*)((?:\n(?: {6}\1| *($PAT_USAGE_CONT): +\S).*)*)//om)
 468 {
 469     my @syn = $3 . $4;
 470
 471     if ($_ = $5)
 472     {
 473         s/^\n//;
 474         for (split /\n/) { s/^ *(($PAT_USAGE_CONT): +)?//o; push @syn, $_ }
 475     }
 476
 477     my $synopsis = '';
 478     for (@syn)
 479     {
 480         $synopsis .= ".br\n" if $synopsis;
 481         s!^\S*/!!;
 482         s/^lt-// if $opt_libtool;
 483         s/^(\S+) *//;
 484         $synopsis .= ".B $1\n";
 485         s/\s+$//;
 486         s/(([][]|\.\.+)+)/\\fR$1\\fI/g;
 487         s/^/\\fI/ unless s/^\\fR//;
 488         $_ .= '\fR';
 489         s/(\\fI)( *)/$2$1/g;
 490         s/\\fI\\fR//g;
 491         s/^\\fR//;
 492         s/\\fI$//;
 493         s/^\./\\&./;
 494
 495         $_ = fix_italic_spacing $_;
 496         $synopsis .= "$_\n";
 497     }
 498
 499     $include{_('SYNOPSIS')} .= $synopsis;
 500 }
 501
 502 # Process text, initial section is DESCRIPTION.
 503 my $sect = _('DESCRIPTION');
 504 $_ = "$help_text\n\n$version_text";
 505
 506 # Normalise paragraph breaks.
 507 s/^\n+//;
 508 s/\n*$/\n/;
 509 s/\n\n+/\n\n/g;
 510
 511 # Join hyphenated lines.
 512 s/([A-Za-z])-\n *([A-Za-z])/$1$2/g;
 513
 514 # Temporarily exchange leading dots, apostrophes and backslashes for
 515 # tokens.
 516 s/^\./\x80/mg;
 517 s/^'/\x81/mg;
 518 s/\\/\x82/g;
 519
 520 # Translators: patterns are used to match common program output. In the source
 521 # these strings are all of the form of "my $PAT_something = _('...');" and are
 522 # regular expressions.  If there is more than one commonly used string, you
 523 # may separate alternatives with "|".  Spaces in these expressions are written
 524 # as " +" to indicate that more than one space may be matched.  The string
 525 # "(?:[\\w-]+ +)?" in the bug reporting pattern is used to indicate an
 526 # optional word, so that either "Report bugs" or "Report _program_ bugs" will
 527 # be matched.
 528 my $PAT_BUGS          = _('Report +(?:[\w-]+ +)?bugs|Email +bug +reports +to');
 529 my $PAT_AUTHOR        = _('Written +by');
 530 my $PAT_OPTIONS       = _('Options');
 531 my $PAT_ENVIRONMENT   = _('Environment');
 532 my $PAT_FILES         = _('Files');
 533 my $PAT_EXAMPLES      = _('Examples');
 534 my $PAT_FREE_SOFTWARE = _('This +is +free +software');
 535
 536 # Start a new paragraph (if required) for these.
 537 s/([^\n])\n($PAT_BUGS|$PAT_AUTHOR) /$1\n\n$2 /og;
 538
 539 # Convert iso-8859-1 copyright symbol or (c) to nroff
 540 # character.
 541 s/^Copyright +(?:\xa9|\([Cc]\))/Copyright \\(co/mg;
 542
 543 while (length)
 544 {
 545     # Convert some standard paragraph names.
 546     if (s/^($PAT_OPTIONS): *\n+//o)
 547     {
 548         $sect = _('OPTIONS');
 549         next;
 550     }
 551     if (s/^($PAT_ENVIRONMENT): *\n+//o)
 552     {
 553         $sect = _('ENVIRONMENT');
 554         next;
 555     }
 556     if (s/^($PAT_FILES): *\n+//o)
 557     {
 558         $sect = _('FILES');
 559         next;
 560     }
 561     elsif (s/^($PAT_EXAMPLES): *\n+//o)
 562     {
 563         $sect = _('EXAMPLES');
 564         next;
 565     }
 566
 567     # Custom section indicated by a line containing "*Section Name*".
 568     if (s/^\*(\w(.*\w)?)\* *\n+//)
 569     {
 570         $sect = uc $1;
 571         $sect =~ tr/*/ /;  # also accept *Section*Name*
 572         push @sections, $sect;
 573         next;
 574     }
 575
 576     # Copyright section.
 577     if (/^Copyright /)
 578     {
 579         $sect = _('COPYRIGHT');
 580     }
 581
 582     # Bug reporting section.
 583     elsif (/^($PAT_BUGS) /o)
 584     {
 585         $sect = _('REPORTING BUGS');
 586     }
 587
 588     # Author section.
 589     elsif (/^($PAT_AUTHOR)/o)
 590     {
 591         $sect = _('AUTHOR');
 592     }
 593
 594     # Examples, indicated by an indented leading $, % or > are
 595     # rendered in a constant width font.
 596     if (/^( +)([\$\%>] )\S/)
 597     {
 598         my $indent = $1;
 599         my $prefix = $2;
 600         my $break = '.IP';
 601         while (s/^$indent\Q$prefix\E(\S.*)\n*//)
 602         {
 603             $include{$sect} .= "$break\n\\f(CW$prefix$1\\fR\n";
 604             $break = '.br';
 605         }
 606
 607         next;
 608     }
 609
 610     my $matched = '';
 611
 612     # Sub-sections have a trailing colon and the second line indented.
 613     if (s/^(\S.*:) *\n / /)
 614     {
 615         $matched .= $& if %append_match;
 616         $include{$sect} .= qq(.SS "$1"\n);
 617     }
 618
 619     my $indent = 0;
 620     my $content = '';
 621
 622     # Option with description.
 623     if (s/^( {1,10}([+-]\S.*?))(?:(  +(?!-))|\n( {20,}))(\S.*)\n//)
 624     {
 625         $matched .= $& if %append_match;
 626         $indent = length ($4 || "$1$3");
 627         $content = ".TP\n\x84$2\n\x84$5\n";
 628         unless ($4)
 629         {
 630             # Indent may be different on second line.
 631             $indent = length $& if /^ {20,}/;
 632         }
 633     }
 634
 635     # Option without description.
 636     elsif (s/^ {1,10}([+-]\S.*)\n//)
 637     {
 638         $matched .= $& if %append_match;
 639         $content = ".HP\n\x84$1\n";
 640         $indent = 80; # not continued
 641     }
 642
 643     # Indented paragraph with tag.
 644     elsif (s/^( +(\S.*?))(?:(  +)|\n( {20,}))(\S.*)\n//)
 645     {
 646         $matched .= $& if %append_match;
 647         $indent = length ($4 || "$1$3");
 648         $content = ".TP\n\x84$2\n\x84$5\n";
 649     }
 650
 651     # Indented paragraph.
 652     elsif (s/^( +)(\S.*)\n//)
 653     {
 654         $matched .= $& if %append_match;
 655         $indent = length $1;
 656         $content = ".IP\n\x84$2\n";
 657     }
 658
 659     # Left justified paragraph.
 660     else
 661     {
 662         s/(.*)\n//;
 663         $matched .= $& if %append_match;
 664         $content = ".PP\n" if $include{$sect};
 665         $content .= "$1\n";
 666     }
 667
 668     # Append continuations.
 669     while ($indent ? s/^ {$indent}(\S.*)\n// : s/^(\S.*)\n//)
 670     {
 671         $matched .= $& if %append_match;
 672         $content .= "\x84$1\n";
 673     }
 674
 675     # Move to next paragraph.
 676     s/^\n+//;
 677
 678     for ($content)
 679     {
 680         # Leading dot and apostrophe protection.
 681         s/\x84\./\x80/g;
 682         s/\x84'/\x81/g;
 683         s/\x84//g;
 684
 685         # Examples should be verbatim.
 686         unless ($sect eq _('EXAMPLES'))
 687         {
 688             # Convert options.
 689             s/(^|[ (])(-[][\w=-]+)/$1 . convert_option $2/mge;
 690
 691             # Italicise filenames: /a/b, $VAR/c/d, ~/e/f
 692             s!
 693                 (^|[ (])                        # space/punctuation before
 694                 (
 695                     (?:\$\w+|~)?                # leading variable, or tilde
 696                     (?:/\w(?:[\w.-]*\w)?)+      # path components
 697                 )
 698                 ($|[ ,;.)])                     # space/punctuation after
 699             !$1\\fI$2\\fP$3!xmg;
 700
 701             $_ = fix_italic_spacing $_;
 702         }
 703
 704         # Escape remaining hyphens.
 705         s/-/\x83/g;
 706
 707         if ($sect eq _('COPYRIGHT'))
 708         {
 709             # Insert line breaks before additional copyright messages
 710             # and the disclaimer.
 711             s/\n(Copyright |$PAT_FREE_SOFTWARE)/\n.br\n$1/og;
 712         }
 713         elsif ($sect eq _('REPORTING BUGS'))
 714         {
 715             # Handle multi-line bug reporting sections of the form:
 716             #
 717             #   Report <program> bugs to <addr>
 718             #   GNU <package> home page: <url>
 719             #   ...
 720             s/\n([[:upper:]])/\n.br\n$1/g;
 721         }
 722     }
 723
 724     # Check if matched paragraph contains /pat/.
 725     if (%append_match)
 726     {
 727         for my $pat (keys %append_match)
 728         {
 729             if ($matched =~ $pat)
 730             {
 731                 $content .= ".PP\n" unless $append_match{$pat} =~ /^\./;
 732                 $content .= $append_match{$pat};
 733             }
 734         }
 735     }
 736
 737     $include{$sect} .= $content;
 738 }
 739
 740 # Refer to the real documentation.
 741 unless ($opt_no_info)
 742 {
 743     my $info_page = $opt_info || $program;
 744
 745     $sect = _('SEE ALSO');
 746     $include{$sect} .= ".PP\n" if $include{$sect};
 747     $include{$sect} .= sprintf _(<<'EOT'), $program, $program, $info_page;
 748 The full documentation for
 749 .B %s
 750 is maintained as a Texinfo manual.  If the
 751 .B info
 752 and
 753 .B %s
 754 programs are properly installed at your site, the command
 755 .IP
 756 .B info %s
 757 .PP
 758 should give you access to the complete manual.
 759 EOT
 760 }
 761
 762 # Append additional text.
 763 while (my ($sect, $text) = each %append)
 764 {
 765     $include{$sect} .= $append{$sect};
 766 }
 767
 768 # Replace sections.
 769 while (my ($sect, $text) = each %replace)
 770 {
 771     $include{$sect} = $replace{$sect};
 772 }
 773
 774 # Output header.
 775 print <<EOT;
 776 .\\" DO NOT MODIFY THIS FILE!  It was generated by $this_program $this_version.
 777 .TH $PROGRAM "$section" "$date" "$source" "$manual"
 778 EOT
 779
 780 # Section ordering.
 781 my @pre = (_('NAME'), _('SYNOPSIS'), _('DESCRIPTION'), _('OPTIONS'));
 782 my @post = (_('ENVIRONMENT'), _('FILES'), _('EXAMPLES'), _('AUTHOR'),
 783     _('REPORTING BUGS'), _('COPYRIGHT'), _('SEE ALSO'));
 784 my %filter = map { $_ => 1 } @pre, @post;
 785
 786 # Output content.
 787 my %done;
 788 for my $sect (@pre, (grep !$filter{$_}, @sections), @post)
 789 {
 790     next if $done{$sect}++;  # ignore duplicates
 791     next unless $include{$sect};
 792     if ($include{$sect})
 793     {
 794         my $quote = $sect =~ /\W/ ? '"' : '';
 795         print enc ".SH $quote$sect$quote\n";
 796
 797         for ($include{$sect})
 798         {
 799             # Replace leading dot, apostrophe, backslash and hyphen
 800             # tokens.
 801             s/\x80/\\&./g;
 802             s/\x81/\\&'/g;
 803             s/\x82/\\e/g;
 804             s/\x83/\\-/g;
 805
 806             # Convert some latin1 chars to troff equivalents
 807             s/\xa0/\\ /g; # non-breaking space
 808
 809             print enc $_;
 810         }
 811     }
 812 }
 813
 814 close STDOUT or kark N_("%s: error writing to %s (%s)"), $this_program,
 815     $opt_output || 'stdout', $!;
 816
 817 exit;
 818
 819 # Get program basename, and strip libtool "lt-" prefix if required.
 820 sub program_basename
 821 {
 822     local $_ = shift;
 823     s!.*/!!;
 824     s/^lt-// if $opt_libtool;
 825     $_;
 826 }
 827
 828 # Call program with given option and return results.
 829 sub get_option_value
 830 {
 831     my ($prog, $opt) = @_;
 832     my $stderr = $discard_stderr ? '/dev/null' : '&1';
 833     my $value = join '',
 834         map { s/ +$//; expand $_ }
 835         map { dec $_ }
 836         `$prog $opt 2>$stderr`;
 837
 838     unless ($value)
 839     {
 840         my $err = N_("%s: can't get `%s' info from %s%s");
 841         my $extra = $discard_stderr
 842             ? "\n" . N_("Try `--no-discard-stderr' if option outputs to stderr")
 843             : '';
 844
 845         kark $err, $this_program, $opt, $prog, $extra;
 846     }
 847
 848     $value;
 849 }
 850
 851 # Convert option dashes to \- to stop nroff from hyphenating 'em, and
 852 # embolden.  Option arguments get italicised.
 853 sub convert_option
 854 {
 855     local $_ = '\fB' . shift;
 856
 857     s/-/\x83/g;
 858     unless (s/\[=(.*)\]$/\\fR[=\\fI$1\\fR]/)
 859     {
 860         s/=(.)/\\fR=\\fI$1/;
 861         s/ (.)/ \\fI$1/;
 862         $_ .= '\fR';
 863     }
 864
 865     $_;
 866 }
 867
 868 # Insert spacing escape characters \, and \/ before and after italic text.  See
 869 # http://www.gnu.org/software/groff/manual/html_node/Ligatures-and-Kerning.html
 870 sub fix_italic_spacing
 871 {
 872     local $_ = shift;
 873     s!\\fI(.*?)\\f([BRP])!\\fI\\,$1\\/\\f$2!g;
 874     return $_;
 875 }
 876 !NO!SUBS!
 877
 878 # Rename output and fix permissions
 879 unless ($opts{stdout})
 880 {
 881     close OUT;
 882     rename $tmp, $target or die "$0: can't rename $tmp to $target ($!)\n";
 883     chmod 0555, $target  or warn "$0: can't change mode of $target ($!)\n";
 884 }
 885
 886 exit 0;