gst-libs/gst/webrtc/meson.build

   1 webrtc_sources = [
   2   'dtlstransport.c',
   3   'icetransport.c',
   4   'rtcsessiondescription.c',
   5   'rtpreceiver.c',
   6   'rtpsender.c',
   7   'rtptransceiver.c',
   8 ]
   9
  10 webrtc_headers = [
  11   'dtlstransport.h',
  12   'icetransport.h',
  13   'rtcsessiondescription.h',
  14   'rtpreceiver.h',
  15   'rtpsender.h',
  16   'rtptransceiver.h',
  17   'webrtc_fwd.h',
  18   'webrtc.h',
  19 ]
  20
  21 webrtc_enumtypes_headers = [
  22   'dtlstransport.h',
  23   'icetransport.h',
  24   'rtptransceiver.h',
  25   'webrtc_fwd.h',
  26 ]
  27
  28 webrtc_enums = gnome.mkenums_simple('webrtc-enumtypes',
  29   sources : webrtc_enumtypes_headers,
  30   header_prefix : '#include <gst/webrtc/webrtc_fwd.h>',
  31   decorator: 'GST_WEBRTC_API',
  32   install_header: true,
  33   install_dir : join_paths(get_option('includedir'), 'gstreamer-1.0/gst/webrtc/'))
  34
  35 gstwebrtc_c = webrtc_enums[0]
  36 gstwebrtc_h = webrtc_enums[1]
  37
  38 webrtc_gen_sources = [gstwebrtc_h]
  39
  40 gstwebrtc_dependencies = [gstbase_dep, gstsdp_dep]
  41
  42 gstwebrtc = library('gstwebrtc-' + api_version,
  43   webrtc_sources, gstwebrtc_c, gstwebrtc_h,
  44   c_args : gst_plugins_bad_args + ['-DGST_USE_UNSTABLE_API'],
  45   include_directories : [configinc, libsinc],
  46   version : libversion,
  47   soversion : soversion,
  48   darwin_versions : osxversion,
  49   install : true,
  50   dependencies : gstwebrtc_dependencies,
  51 )
  52
  53 if build_gir
  54   webrtc_gir = gnome.generate_gir(gstwebrtc,
  55     sources : webrtc_sources + webrtc_headers + [gstwebrtc_h],
  56     namespace : 'GstWebRTC',
  57     nsversion : api_version,
  58     identifier_prefix : 'Gst',
  59     symbol_prefix : 'gst',
  60     export_packages : 'gstreamer-webrtc-1.0',
  61     includes : ['Gst-1.0', 'GstSdp-1.0'],
  62     install : true,
  63     extra_args : gir_init_section + ['-DGST_USE_UNSTABLE_API'] + ['--c-include=gst/webrtc/webrtc.h'],
  64     dependencies : [gstbase_dep, gstsdp_dep]
  65   )
  66   webrtc_gen_sources += webrtc_gir
  67 endif
  68
  69 install_headers(webrtc_headers, subdir : 'gstreamer-1.0/gst/webrtc')
  70
  71 gstwebrtc_dep = declare_dependency(link_with: gstwebrtc,
  72   include_directories : libsinc,
  73   sources: webrtc_gen_sources,
  74   dependencies: gstwebrtc_dependencies)