gst-libs/gst/tag/meson.build

   1 tag_sources = [
   2   'gstvorbistag.c',
   3   'gstid3tag.c',
   4   'gstxmptag.c',
   5   'gstexiftag.c',
   6   'lang.c',
   7   'licenses.c',
   8   'tags.c',
   9   'gsttagdemux.c',
  10   'gsttagmux.c',
  11   'gsttageditingprivate.c',
  12   'id3v2.c',
  13   'id3v2frames.c',
  14   'xmpwriter.c',
  15 ]
  16
  17 tag_mkenum_headers = [
  18   'gsttagdemux.h',
  19   'tag.h',
  20 ]
  21
  22 tag_headers = tag_mkenum_headers + [
  23   'gsttagmux.h',
  24   'xmpwriter.h',
  25   'tag-prelude.h',
  26 ]
  27 install_headers(tag_headers, subdir : 'gstreamer-1.0/gst/tag/')
  28
  29 tag_enums = gnome.mkenums_simple('tag-enumtypes',
  30   sources : tag_mkenum_headers,
  31   body_prefix : '#ifdef HAVE_CONFIG_H\n#include "config.h"\n#endif',
  32   header_prefix : '#include <gst/tag/tag-prelude.h>',
  33   decorator : 'GST_TAG_API',
  34   install_header: true,
  35   install_dir : join_paths(get_option('includedir'), 'gstreamer-1.0/gst/tag'))
  36 gsttag_c = tag_enums[0]
  37 gsttag_h = tag_enums[1]
  38 tag_gen_sources = [gsttag_h]
  39
  40 install_data('license-translations.dict',
  41   install_dir : join_paths(get_option('datadir'), 'gst-plugins-base', api_version))
  42
  43 gst_tag_args = [
  44   '-DLICENSE_TRANSLATIONS_PATH="@0@"'.format(
  45     join_paths(
  46       get_option('prefix'),
  47       get_option('datadir'),
  48       'gst-plugins-base',
  49       api_version,
  50       'license-translations.dict'))
  51 ]
  52
  53 # iso-codes (optional, used for language names lookup and translation)
  54 have_iso_codes = false
  55 iso_codes_dep = dependency('iso-codes', required: get_option('iso-codes'))
  56 if iso_codes_dep.found()
  57   if iso_codes_dep.get_pkgconfig_variable('domains').split(' ').contains('iso_639-2')
  58     iso_codes_prefix = iso_codes_dep.get_pkgconfig_variable('prefix')
  59     if iso_codes_prefix != ''
  60       core_conf.set_quoted('ISO_CODES_PREFIX', iso_codes_prefix)
  61       core_conf.set_quoted('ISO_CODES_VERSION', iso_codes_dep.version())
  62       have_iso_codes = true
  63     elif get_option('iso-codes').enabled()
  64       error('iso-codes was requested for libgsttag, but could not determine prefix')
  65     endif
  66   elif get_option('iso-codes').enabled()
  67     error('iso-codes was requested for libgsttag, but does not provide iso 639')
  68   endif
  69 endif
  70 core_conf.set('HAVE_ISO_CODES', have_iso_codes)
  71
  72 # could drop optional zlib dep and use g_zlib_decompressor_new()
  73 zlib_dep = dependency('zlib', required: false, fallback: ['zlib', 'zlib_dep'])
  74 core_conf.set('HAVE_ZLIB', zlib_dep.found())
  75
  76 tag_deps = [gst_base_dep, libm, zlib_dep]
  77 gsttag = library('gsttag-@0@'.format(api_version),
  78   tag_sources, gsttag_h, gsttag_c,
  79   c_args : gst_plugins_base_args + gst_tag_args + ['-DBUILDING_GST_TAG'],
  80   include_directories: [configinc, libsinc],
  81   version : libversion,
  82   soversion : soversion,
  83   darwin_versions : osxversion,
  84   install : true,
  85   dependencies : tag_deps,
  86 )
  87
  88 if build_gir
  89   gst_gir_extra_args = gir_init_section + [ '--c-include=gst/tag/tag.h' ]
  90   tag_gen_sources += [gnome.generate_gir(gsttag,
  91     sources : tag_sources + tag_headers + [gsttag_h] + [gsttag_c],
  92     namespace : 'GstTag',
  93     nsversion : api_version,
  94     identifier_prefix : 'Gst',
  95     symbol_prefix : 'gst',
  96     export_packages : 'gstreamer-tag-1.0',
  97     includes : ['Gst-1.0', 'GstBase-1.0'],
  98     install : true,
  99     extra_args : gst_gir_extra_args,
 100     dependencies : tag_deps
 101   )]
 102 endif
 103
 104 tag_dep = declare_dependency(link_with: gsttag,
 105   include_directories : [libsinc],
 106   dependencies : tag_deps,
 107   sources: tag_gen_sources)
 108
 109 # Little program that reads iso_639.xml and outputs tables for us as fallback
 110 # for when iso-codes are not available (and so we don't have to read the xml
 111 # just to map codes)
 112 if have_iso_codes
 113   executable('mklangtables', 'mklangtables.c',
 114     c_args: ['-DHAVE_CONFIG_H'],
 115     include_directories: [configinc, libsinc],
 116     dependencies: gst_dep,
 117     install: false)
 118 endif
 119
 120 executable('mklicensestables', 'mklicensestables.c',
 121   c_args : gst_plugins_base_args,
 122   include_directories: [configinc],
 123   dependencies : [tag_dep, gst_base_dep],
 124   install : false)
 125
 126 gst_tag_dir = meson.current_source_dir()