gst-libs/gst/player/meson.build

   1 gstplayer_sources = [
   2   'gstplayer.c',
   3   'gstplayer-signal-dispatcher.c',
   4   'gstplayer-video-renderer.c',
   5   'gstplayer-media-info.c',
   6   'gstplayer-g-main-context-signal-dispatcher.c',
   7   'gstplayer-video-overlay-video-renderer.c',
   8   'gstplayer-visualization.c',
   9 ]
  10
  11 gstplayer_headers = [
  12   'player.h',
  13   'player-prelude.h',
  14   'gstplayer.h',
  15   'gstplayer-types.h',
  16   'gstplayer-signal-dispatcher.h',
  17   'gstplayer-video-renderer.h',
  18   'gstplayer-media-info.h',
  19   'gstplayer-g-main-context-signal-dispatcher.h',
  20   'gstplayer-video-overlay-video-renderer.h',
  21   'gstplayer-visualization.h',
  22 ]
  23
  24 install_headers(gstplayer_headers, subdir : 'gstreamer-' + api_version + '/gst/player/')
  25
  26 gstplayer = library('gstplayer-' + api_version,
  27   gstplayer_sources,
  28   c_args : gst_plugins_bad_args,
  29   include_directories : [configinc, libsinc],
  30   version : libversion,
  31   soversion : soversion,
  32   darwin_versions : osxversion,
  33   install : true,
  34   dependencies : [gstbase_dep, gstvideo_dep, gstaudio_dep,
  35                   gsttag_dep, gstpbutils_dep],
  36 )
  37
  38 gen_sources = []
  39 if build_gir
  40   player_gir = gnome.generate_gir(gstplayer,
  41     sources : gstplayer_sources + gstplayer_headers,
  42     namespace : 'GstPlayer',
  43     nsversion : api_version,
  44     identifier_prefix : 'Gst',
  45     symbol_prefix : 'gst',
  46     export_packages : 'gstreamer-player-1.0',
  47     includes : ['Gst-1.0', 'GstPbutils-1.0', 'GstBase-1.0', 'GstVideo-1.0',
  48       'GstAudio-1.0', 'GstTag-1.0'],
  49     install : true,
  50     extra_args : gir_init_section + ['-DGST_USE_UNSTABLE_API'] + ['--c-include=gst/player/player.h'],
  51     dependencies : [gstbase_dep, gstvideo_dep, gstaudio_dep,
  52                   gsttag_dep, gstpbutils_dep]
  53   )
  54   gen_sources += player_gir
  55 endif
  56
  57 gstplayer_dep = declare_dependency(link_with : gstplayer,
  58   include_directories : [libsinc],
  59   sources: gen_sources,
  60   dependencies : [gstbase_dep, gstvideo_dep, gstaudio_dep,
  61                   gsttag_dep, gstpbutils_dep])