gst-libs/gst/mpegts/meson.build

   1 mpegts_sources = [
   2   'gstmpegtssection.c',
   3   'gstmpegtsdescriptor.c',
   4   'gst-dvb-descriptor.c',
   5   'gst-dvb-section.c',
   6   'gst-atsc-section.c',
   7 ]
   8
   9 mpegts_headers = [
  10   'gstmpegtssection.h',
  11   'gst-atsc-section.h',
  12   'gst-dvb-section.h',
  13   'gst-scte-section.h',
  14   'gstmpegtsdescriptor.h',
  15   'gst-dvb-descriptor.h',
  16   'mpegts-prelude.h',
  17   'mpegts.h',
  18 ]
  19 install_headers(mpegts_headers, subdir : 'gstreamer-1.0/gst/mpegts')
  20
  21 mpegts_enums = gnome.mkenums_simple('gstmpegts-enumtypes',
  22   sources : mpegts_headers,
  23   header_prefix : '#include <gst/mpegts/mpegts-prelude.h>',
  24   decorator : 'GST_MPEGTS_API',
  25   install_header: true,
  26   install_dir : join_paths(get_option('includedir'), 'gstreamer-1.0/gst/mpegts'))
  27
  28 mpegtsenumtypes_h = mpegts_enums[1]
  29
  30 gen_sources = [mpegtsenumtypes_h]
  31
  32 gstmpegts = library('gstmpegts-' + api_version,
  33   mpegts_sources, mpegts_enums,
  34   c_args : gst_plugins_bad_args + ['-DGST_USE_UNSTABLE_API'],
  35   include_directories : [configinc, libsinc],
  36   version : libversion,
  37   soversion : soversion,
  38   darwin_versions : osxversion,
  39   install : true,
  40   dependencies : [gst_dep],
  41 )
  42 if build_gir
  43   mpegts_gir = gnome.generate_gir(gstmpegts,
  44     sources : mpegts_sources + mpegts_headers,
  45     namespace : 'GstMpegts',
  46     nsversion : api_version,
  47     identifier_prefix : 'GstMpegts',
  48     symbol_prefix : 'gst_mpegts', #FIXME ['gst_mpegts', 'gst'],
  49     export_packages : 'gstreamer-mpegts-1.0',
  50     includes : ['Gst-1.0'],
  51     install : true,
  52     extra_args : gir_init_section + ['-DGST_USE_UNSTABLE_API'] + ['--c-include=gst/mpegts/mpegts.h'],
  53     dependencies : [gst_dep]
  54   )
  55   gen_sources += mpegts_gir
  56 endif
  57
  58
  59 gstmpegts_dep = declare_dependency(link_with : gstmpegts,
  60   include_directories : [libsinc],
  61   dependencies : [gst_dep],
  62   sources : gen_sources)