gst-libs/gst/insertbin/meson.build

   1 insert_sources = ['gstinsertbin.c']
   2 insert_headers = ['gstinsertbin.h']
   3 install_headers(insert_headers, subdir : 'gstreamer-1.0/gst/insertbin')
   4
   5 gstinsertbin = library('gstinsertbin-' + api_version,
   6   insert_sources,
   7   c_args : gst_plugins_bad_args + [ '-DGST_USE_UNSTABLE_API' ],
   8   include_directories : [configinc, libsinc],
   9   version : libversion,
  10   soversion : soversion,
  11   darwin_versions : osxversion,
  12   install : true,
  13   dependencies : [gst_dep],
  14 )
  15
  16 gen_sources = []
  17 if build_gir
  18   insertbin_gir = gnome.generate_gir(gstinsertbin,
  19     sources : insert_sources + insert_headers,
  20     namespace : 'GstInsertBin',
  21     nsversion : api_version,
  22     identifier_prefix : 'Gst',
  23     symbol_prefix : 'gst',
  24     export_packages : 'gstreamer-insertbin-1.0',
  25     includes : ['Gst-1.0'],
  26     install : true,
  27     extra_args : gir_init_section + ['-DGST_USE_UNSTABLE_API'] + ['--c-include=gst/insertbin/gstinsertbin.h'],
  28     dependencies : [gst_dep]
  29   )
  30   gen_sources += insertbin_gir
  31 endif
  32
  33 gstinsertbin_dep = declare_dependency(link_with : gstinsertbin,
  34   include_directories : [libsinc],
  35   sources: gen_sources,
  36   dependencies : [gst_dep])