gst-libs/gst/app/meson.build

   1 app_sources = ['gstappsrc.c', 'gstappsink.c']
   2
   3 app_mkenum_headers = [
   4   'gstappsrc.h',
   5 ]
   6
   7 app_headers = app_mkenum_headers + [ 'app.h', 'app-prelude.h', 'gstappsink.h' ]
   8 install_headers(app_headers, subdir : 'gstreamer-1.0/gst/app/')
   9
  10 mkenums = find_program('app_mkenum.py')
  11 gstapp_h = custom_target('gstappenum_h',
  12   output : 'app-enumtypes.h',
  13   input : app_mkenum_headers,
  14   install : true,
  15   install_dir : 'include/gstreamer-1.0/gst/app/',
  16   command : [mkenums, glib_mkenums, '@OUTPUT@', '@INPUT@'])
  17
  18 gstapp_c = custom_target('gstappenum_c',
  19   output : 'app-enumtypes.c',
  20   input : app_mkenum_headers,
  21   depends : [gstapp_h],
  22   command : [mkenums, glib_mkenums, '@OUTPUT@', '@INPUT@'])
  23 app_gen_sources = [gstapp_h]
  24
  25 gstapp = library('gstapp-@0@'.format(api_version),
  26   app_sources, gstapp_h, gstapp_c,
  27   c_args : gst_plugins_base_args,
  28   include_directories: [configinc, libsinc],
  29   version : libversion,
  30   soversion : soversion,
  31   install : true,
  32   dependencies : [gst_base_dep],
  33 )
  34
  35 if build_gir
  36   gst_gir_extra_args = gir_init_section + [ '--c-include=gst/app/app.h' ]
  37   app_gen_sources += [gnome.generate_gir(gstapp,
  38     sources : app_sources + app_headers + [gstapp_c] + [gstapp_h],
  39     namespace : 'GstApp',
  40     nsversion : api_version,
  41     identifier_prefix : 'Gst',
  42     symbol_prefix : 'gst',
  43     export_packages : 'gstreamer-app-1.0',
  44     includes : ['Gst-1.0', 'GstBase-1.0'],
  45     install : true,
  46     extra_args : gst_gir_extra_args,
  47     dependencies : [gst_dep, gst_base_dep]
  48   )]
  49 endif
  50
  51 app_dep = declare_dependency(link_with: gstapp,
  52   include_directories : [libsinc],
  53   dependencies : [gst_base_dep],
  54   sources : app_gen_sources)