gst-libs/gst/app/meson.build

   1 app_sources = ['gstappsrc.c', 'gstappsink.c']
   2
   3 app_mkenum_headers = [
   4   'gstappsrc.h',
   5 ]
   6
   7 app_headers = app_mkenum_headers + [ 'app.h', 'app-prelude.h', 'gstappsink.h' ]
   8 install_headers(app_headers, subdir : 'gstreamer-1.0/gst/app/')
   9
  10 app_enums = gnome.mkenums_simple('app-enumtypes',
  11   sources : app_mkenum_headers,
  12   body_prefix : '#ifdef HAVE_CONFIG_H\n#include "config.h"\n#endif',
  13   header_prefix : '#include <gst/app/app-prelude.h>',
  14   decorator : 'GST_APP_API',
  15   install_header: true,
  16   install_dir : join_paths(get_option('includedir'), 'gstreamer-1.0/gst/app'))
  17 gstapp_c = app_enums[0]
  18 gstapp_h = app_enums[1]
  19
  20 app_gen_sources = [gstapp_h]
  21
  22 gstapp = library('gstapp-@0@'.format(api_version),
  23   app_sources, gstapp_h, gstapp_c,
  24   c_args : gst_plugins_base_args + ['-DBUILDING_GST_APP'],
  25   include_directories: [configinc, libsinc],
  26   version : libversion,
  27   soversion : soversion,
  28   darwin_versions : osxversion,
  29   install : true,
  30   dependencies : [gst_base_dep],
  31 )
  32
  33 if build_gir
  34   gst_gir_extra_args = gir_init_section + [ '--c-include=gst/app/app.h' ]
  35   app_gen_sources += [gnome.generate_gir(gstapp,
  36     sources : app_sources + app_headers + [gstapp_c] + [gstapp_h],
  37     namespace : 'GstApp',
  38     nsversion : api_version,
  39     identifier_prefix : 'Gst',
  40     symbol_prefix : 'gst',
  41     export_packages : 'gstreamer-app-1.0',
  42     includes : ['Gst-1.0', 'GstBase-1.0'],
  43     install : true,
  44     extra_args : gst_gir_extra_args,
  45     dependencies : [gst_dep, gst_base_dep]
  46   )]
  47 endif
  48
  49 app_dep = declare_dependency(link_with: gstapp,
  50   include_directories : [libsinc],
  51   dependencies : [gst_base_dep],
  52   sources : app_gen_sources)