ext/wpe/meson.build

   1
   2 if not gstgl_dep.found()
   3   if get_option('wpe').enabled()
   4     error('wpe plugin enabled but GL support was not detected')
   5   endif
   6   subdir_done()
   7 endif
   8
   9 wpe_dep = dependency('wpe-webkit-1.0', version : '>= 2.24', required : get_option('wpe'))
  10 wpe_fdo_dep = dependency('wpebackend-fdo-1.0', required : get_option('wpe'))
  11 egl_dep = dependency('egl', required : get_option('wpe'))
  12 xkbcommon_dep = dependency('xkbcommon', version : '>= 0.8', required : get_option('wpe'))
  13 wl_server_dep = dependency('wayland-server', required : get_option('wpe'))
  14
  15 if not wpe_dep.found() or not wpe_fdo_dep.found() or not egl_dep.found() or not xkbcommon_dep.found()
  16   subdir_done()
  17 endif
  18
  19 gstwpe = library('gstwpe',
  20   ['WPEThreadedView.cpp', 'gstwpe.cpp', 'gstwpevideosrc.cpp', 'gstwpesrcbin.cpp'],
  21   dependencies : [egl_dep, wpe_dep, wpe_fdo_dep, gstallocators_dep, gstaudio_dep, gstvideo_dep, gstbase_dep, gstgl_dep, xkbcommon_dep, wl_server_dep],
  22   cpp_args : gst_plugins_bad_args + ['-DHAVE_CONFIG_H=1'],
  23   include_directories : [configinc],
  24   install : true,
  25   install_dir : plugins_install_dir)
  26 pkgconfig.generate(gstwpe, install_dir : plugins_pkgconfig_install_dir)
  27 plugins += [gstwpe]