ext/vorbis/meson.build

   1 vorbis_sources = [
   2   'gstvorbis.c',
   3   'gstvorbisdec.c',
   4   'gstvorbisdeclib.c',
   5   'gstvorbisenc.c',
   6   'gstvorbisparse.c',
   7   'gstvorbistag.c',
   8   'gstvorbiscommon.c',
   9 ]
  10
  11 vorbisidec_sources = [
  12   'gstivorbisdec.c',
  13   'gstvorbisdec.c',
  14   'gstvorbisdeclib.c',
  15   'gstvorbiscommon.c',
  16 ]
  17
  18 vorbis_dep = dependency('vorbis', version : '>= 1.3.1', required : get_option('vorbis'))
  19 vorbisenc_dep = dependency('vorbisenc', version : '>= 1.3.1', required : get_option('vorbis'))
  20 vorbisidec_dep = dependency('vorbisidec', required : get_option('tremor'))
  21
  22 if vorbis_dep.found()
  23   vorbis_deps = [vorbis_dep]
  24   if vorbisenc_dep.found()
  25     vorbis_deps += vorbisenc_dep
  26   endif
  27   gstvorbis = library('gstvorbis',
  28     vorbis_sources,
  29     c_args : gst_plugins_base_args,
  30     link_args : noseh_link_args,
  31     include_directories: [configinc, libsinc],
  32     dependencies : vorbis_deps + glib_deps + [audio_dep, tag_dep, gst_dep, gst_base_dep],
  33     install : true,
  34     install_dir : plugins_install_dir,
  35   )
  36   pkgconfig.generate(gstvorbis, install_dir : plugins_pkgconfig_install_dir)
  37   plugins += [gstvorbis]
  38 endif
  39
  40 if vorbisidec_dep.found()
  41   # NOTE: This plugin is only useful if your device does not support hardware
  42   # floating point and needs integer ops for performance reasons.
  43   gstivorbisdec = library('gstivorbisdec',
  44     vorbisidec_sources,
  45     c_args : gst_plugins_base_args + ['-DTREMOR'],
  46     link_args : noseh_link_args,
  47     include_directories: [configinc, libsinc],
  48     dependencies : glib_deps + [vorbisidec_dep, audio_dep, tag_dep, gst_dep, gst_base_dep],
  49     install : true,
  50     install_dir : plugins_install_dir,
  51   )
  52   pkgconfig.generate(gstivorbisdec, install_dir : plugins_pkgconfig_install_dir)
  53   plugins += [gstivorbisdec]
  54 endif