configure.in

   1 AC_INIT(gst/gstobject.h)
   2
   3 AC_CANONICAL_SYSTEM
   4
   5 AM_CONFIG_HEADER(config.h)
   6
   7 GST_VERSION_MAJOR=0
   8 GST_VERSION_MINOR=2
   9 GST_VERSION_MICRO=0
  10 GST_VERSION=$GST_VERSION_MAJOR.$GST_VERSION_MINOR.$GST_VERSION_MICRO
  11
  12 PACKAGE=gstreamer
  13 VERSION=$GST_VERSION
  14 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE")
  15 AC_DEFINE_UNQUOTED(VERSION, "$VERSION")
  16 AC_SUBST(PACKAGE)
  17 AC_SUBST(VERSION)
  18
  19 dnl libtool
  20 GST_CURRENT=0
  21 GST_REVISION=0
  22 GST_AGE=0
  23 GST_LIBVERSION=$GST_CURRENT:$GST_REVISION:$GST_AGE
  24
  25 AM_INIT_AUTOMAKE($PACKAGE, $VERSION)
  26 dnl Add parameters for aclocal
  27 dnl (This must come after AM_INIT_AUTOMAKE, since it modifies ACLOCAL)
  28 ACLOCAL="$ACLOCAL $ACLOCAL_FLAGS"
  29
  30 AC_SUBST(GST_VERSION_MAJOR)
  31 AC_SUBST(GST_VERSION_MINOR)
  32 AC_SUBST(GST_VERSION_MICRO)
  33 AC_SUBST(GST_VERSION)
  34
  35 AC_SUBST(GST_CURRENT)
  36 AC_SUBST(GST_REVISION)
  37 AC_SUBST(GST_AGE)
  38 AC_SUBST(GST_LIBVERSION)
  39
  40
  41 AM_MAINTAINER_MODE
  42
  43 AC_PROG_CC
  44 AC_PROG_CXX
  45 AC_PROG_CXXCPP
  46 AC_ISC_POSIX
  47 AC_STDC_HEADERS
  48 AC_ARG_PROGRAM
  49
  50 dnl We disable static building for development, for time savings
  51 dnl *NOTE*: dnl this line before release, so release does static too
  52 AM_DISABLE_STATIC
  53 AC_LIBTOOL_DLOPEN
  54 AM_PROG_LIBTOOL
  55
  56 CFLAGS=""
  57
  58 dnl This is used for the -config script...
  59 builddir=`pwd`
  60 AC_SUBST(builddir)
  61
  62 dnl ##############################
  63 dnl # Do automated configuration #
  64 dnl ##############################
  65
  66 dnl Check for tools:
  67 dnl ================
  68
  69 dnl Check for nasm
  70 AC_PATH_PROG(NASM_PATH, nasm, no)
  71 AC_SUBST(NASM_PATH)
  72 if test x$NASM_PATH = xno; then
  73   AC_MSG_WARN(Couldn't find nasm)
  74   HAVE_NASM="no"
  75 else
  76   AC_DEFINE(HAVE_NASM)
  77   HAVE_NASM="yes"
  78 fi
  79
  80 dnl check for gtkdoc
  81 AC_CHECK_PROG(HAVE_GTK_DOC, gtkdoc-mkdb, true, false)
  82 AC_CHECK_PROG(HAVE_GTK_DOC, gtkdoc-scanobj, :, false)
  83 AC_CHECK_PROG(HAVE_GTK_DOC, gtkdoc-scan, :, false)
  84 AC_CHECK_PROG(HAVE_GTK_DOC, gtkdoc-mktmpl, :, false)
  85 AC_CHECK_PROG(HAVE_GTK_DOC, gtkdoc-mkdb, :, false)
  86 AC_CHECK_PROG(HAVE_GTK_DOC, gtkdoc-mkhtml, :, false)
  87 AC_CHECK_PROG(HAVE_GTK_DOC, gtkdoc-fixxref, :, false)
  88
  89 dnl check for docbook tools
  90 AC_CHECK_PROG(HAVE_DB2HTML, db2html, true, false)
  91 AC_CHECK_PROG(HAVE_DB2PS, db2ps, true, false)
  92 AC_CHECK_PROG(HAVE_PS2PDF, ps2pdf, true, false)
  93
  94 dnl check for image conversion tool
  95 AC_CHECK_PROG(HAVE_FIG2DEV, fig2dev, true, false)
  96
  97 dnl The following is a hack: if fig2dev doesn't display an error message
  98 dnl for the desired type, we assume it supports it.
  99 HAVE_FIG2DEV_PNG=false
 100 if test "x$HAVE_FIG2DEV" = "xtrue" ; then
 101   fig2dev_quiet=`fig2dev -L png </dev/null 2>&1 >/dev/null`
 102   if test "x$fig2dev_quiet" = "x" ; then
 103     HAVE_FIG2DEV_PNG=true
 104   fi
 105 fi
 106 HAVE_FIG2DEV_EPS=false
 107 if test "x$HAVE_FIG2DEV" = "xtrue" ; then
 108   fig2dev_quiet=`fig2dev -L eps </dev/null 2>&1 >/dev/null`
 109   if test "x$fig2dev_quiet" = "x" ; then
 110     HAVE_FIG2DEV_EPS=true
 111   fi
 112 fi
 113
 114
 115 dnl Set up conditionals for (target) architecture:
 116 dnl ==============================================
 117
 118 dnl Determine CPU
 119 case "x${target_cpu}" in
 120   xi?86 | k?) HAVE_CPU_I386=yes
 121               AC_DEFINE(HAVE_CPU_I386)
 122               dnl FIXME could use some better detection
 123               dnl       (ie CPUID)
 124               case "x${target_cpu}" in
 125                 xi386 | xi486) ;;
 126                 *)             AC_DEFINE(HAVE_RDTSC) ;;
 127               esac ;;
 128   xpowerpc)   HAVE_CPU_PPC=yes
 129               AC_DEFINE(HAVE_CPU_PPC) ;;
 130   xalpha)     HAVE_CPU_ALPHA=yes
 131               AC_DEFINE(HAVE_CPU_ALPHA) ;;
 132   xarm*)      HAVE_CPU_ARM=yes
 133               AC_DEFINE(HAVE_CPU_ARM) ;;
 134   xsparc*)    HAVE_CPU_SPARC=yes
 135               AC_DEFINE(HAVE_CPU_SPARC) ;;
 136 esac
 137
 138 dnl Determine endianness
 139 AC_C_BIGENDIAN
 140
 141 dnl Check for MMX-capable compiler
 142 AC_MSG_CHECKING(for MMX-capable compiler)
 143 AC_TRY_RUN([
 144 #include "include/mmx.h"
 145
 146 main()
 147 { movq_r2r(mm0, mm1); return 0; }
 148 ],
 149 [
 150 HAVE_LIBMMX="yes"
 151 AC_MSG_RESULT(yes)
 152 ],
 153 HAVE_LIBMMX="no"
 154 AC_MSG_RESULT(no)
 155 ,
 156 HAVE_LIBMMX="no"
 157 AC_MSG_RESULT(no)
 158 )
 159
 160
 161
 162 dnl Check for essential libraries first:
 163 dnl ====================================
 164
 165
 166 dnl Check for glib
 167 AM_PATH_GLIB(1.2.0,,
 168             AC_MSG_ERROR(Cannot find glib: Is glib-config in path?),
 169             glib gmodule gthread)
 170 dnl Put the glib flags into $LIBS and $CFLAGS since we always use them
 171 CORE_LIBS="$GLIB_LIBS"
 172 CORE_CFLAGS="$GLIB_CFLAGS"
 173
 174
 175 dnl Check for gtk
 176 AM_PATH_GTK(1.2.0,,
 177             AC_MSG_ERROR(Cannot find gtk: Is gtk-config in path?))
 178 dnl Put the gtk flags into $LIBS and $CFLAGS since we always use them
 179 CORE_LIBS="$CORE_LIBS $GTK_LIBS"
 180 CORE_CFLAGS="$CORE_CFLAGS $GTK_CFLAGS"
 181
 182
 183 dnl Check for libxml
 184 AC_PATH_PROG(XML_CONFIG, xml-config, no)
 185 if test x$XML_CONFIG = xno; then
 186   AC_MSG_ERROR(Couldn't find xml-config)
 187 fi
 188 XML_LIBS=`xml-config --libs`
 189 XML_CFLAGS=`xml-config --cflags`
 190 AC_CHECK_LIB(xml, xmlDocGetRootElement, ,
 191   [ AC_MSG_ERROR(Need version 1.8.1 or better of libxml) ],
 192   $XML_LIBS)
 193 AC_SUBST(XML_LIBS)
 194 AC_SUBST(XML_CFLAGS)
 195 CORE_LIBS="$CORE_LIBS $XML_LIBS"
 196 CORE_CFLAGS="$CORE_CFLAGS $XML_CFLAGS"
 197
 198
 199 dnl Next, check for the optional libraries:
 200 dnl =======================================
 201
 202
 203 dnl Check for libesd
 204 esd_save_LIBS=$LIBS
 205 esd_save_CFLAGS=$CFLAGS
 206 AM_PATH_ESD(0.2.12, HAVE_LIBESD=yes, HAVE_LIBESD=no)
 207 LIBS=$esd_save_LIBS
 208 CFLAGS=$esd_save_CFLAGS
 209 AC_ARG_ENABLE(esdsink,
 210 [  --enable-esdsink          enable the building of the esdsink],
 211 [case "${enableval}" in
 212         yes) : ;;
 213         no) HAVE_LIBESD=no ;;
 214         *) AC_MSG_ERROR(bad value ${enableval} for --enable-esdsink) ;;
 215         esac],
 216 [HAVE_LIBESD=$HAVE_LIBESD])
 217
 218 dnl Check for artsc
 219 AC_PATH_PROG(ARTSC_CONFIG, artsc-config, no)
 220 if test x$ARTSC_CONFIG = xno; then
 221   AC_MSG_WARN(Couldn't find artsc-config)
 222   ARTSC_LIBS=
 223   ARTSC_CFLAGS=
 224   HAVE_ARTSC=no
 225 else
 226   ARTSC_LIBS=`artsc-config --libs`
 227   ARTSC_CFLAGS=`artsc-config --cflags`
 228   dnl AC_CHECK_HEADER uses CPPFLAGS, but not CFLAGS.
 229   dnl Assume only suitable flags result from artsc-config --cflags
 230   artsc_save_CPPFLAGS=$CPPFLAGS
 231   CPPFLAGS="$CPPFLAGS $ARTSC_CFLAGS"
 232   AC_CHECK_HEADER(artsc.h,
 233                   HAVE_ARTSC=yes,
 234                   HAVE_ARTSC=no
 235   )
 236   CPPFLAGS=$artsc_save_CPPFLAGS
 237 fi
 238 AC_SUBST(ARTSC_LIBS)
 239 AC_SUBST(ARTSC_CFLAGS)
 240 AC_ARG_ENABLE(artsd,
 241 [  --enable-artsd            enable the building of artsd plugins],
 242 [case "${enableval}" in
 243         yes) : ;;
 244         no) HAVE_ARTSC=no ;;
 245         *) AC_MSG_ERROR(bad value ${enableval} for --enable-artsd) ;;
 246         esac],
 247 [:])
 248
 249 dnl AM_PATH_XMMS(0.1.0, HAVE_LIBXMMS=yes, HAVE_LIBXMMS=no)
 250
 251 dnl Check for libasound
 252 alsa_save_LIBS=$LIBS
 253 alsa_save_CFLAGS=$CFLAGS
 254 AM_PATH_ALSA(0.5.0, HAVE_LIBASOUND=yes, HAVE_LIBASOUND=no)
 255 LIBS=$alsa_save_LIBS
 256 CFLAGS=$alsa_save_CFLAGS
 257 AC_ARG_ENABLE(alsasink,
 258 [  --enable-alsasink          enable the building of the alsasink],
 259 [case "${enableval}" in
 260         yes) HAVE_LIBASOUND=$HAVE_LIBASOUND ;;
 261         no) HAVE_LIBASOUND=no ;;
 262         *) AC_MSG_ERROR(bad value ${enableval} for --enable-alsasink) ;;
 263 esac],
 264 [HAVE_LIBASOUND=$HAVE_LIBASOUND])
 265
 266
 267 dnl Check for libaudiofile
 268 AC_PATH_PROG(AUDIOFILE_CONFIG, audiofile-config, no)
 269 if test x$AUDIOFILE_CONFIG = xno; then
 270   AC_MSG_WARN(Couldn't find audiofile-config: can't build afsink)
 271   AUDIOFILE_LIBS=
 272   HAVE_LIBAUDIOFILE=no
 273 else
 274   AC_MSG_WARN(did find audiofile-config: delete this msg)
 275   AUDIOFILE_LIBS=`audiofile-config --libs`
 276   HAVE_LIBAUDIOFILE=yes
 277 fi
 278 AC_SUBST(AUDIOFILE_LIBS)
 279
 280 alsa_save_LIBS=$LIBS
 281 alsa_save_CFLAGS=$CFLAGS
 282 AM_PATH_ALSA(0.5.0, HAVE_LIBASOUND=yes, HAVE_LIBASOUND=no)
 283 LIBS=$alsa_save_LIBS
 284 CFLAGS=$alsa_save_CFLAGS
 285 AC_ARG_ENABLE(alsasink,
 286 [  --enable-alsasink          enable the building of the alsasink],
 287 [case "${enableval}" in
 288         yes) HAVE_LIBASOUND=$HAVE_LIBASOUND ;;
 289         no) HAVE_LIBASOUND=no ;;
 290         *) AC_MSG_ERROR(bad value ${enableval} for --enable-alsasink) ;;
 291 esac],
 292 [HAVE_LIBASOUND=$HAVE_LIBASOUND])
 293
 294 dnl Check for libgdk-pixbuf
 295 AC_PATH_PROG(GDK_PIXBUF_CONFIG, gdk-pixbuf-config, no)
 296 if test x$GDK_PIXBUF_CONFIG = xno; then
 297   AC_MSG_WARN(Couldn't find gdk-pixbuf-config)
 298   GDK_PIXBUF_LIBS=
 299   GDK_PIXBUF_CFLAGS=
 300   HAVE_GDK_PIXBUF=no
 301 else
 302   GDK_PIXBUF_LIBS=`gdk-pixbuf-config --libs`
 303   GDK_PIXBUF_CFLAGS=`gdk-pixbuf-config --cflags`
 304   HAVE_GDK_PIXBUF=yes
 305 fi
 306 AC_SUBST(GDK_PIXBUF_LIBS)
 307 AC_SUBST(GDK_PIXBUF_CFLAGS)
 308
 309
 310 dnl Check for libgnome
 311 AC_PATH_PROG(GNOME_CONFIG, gnome-config, no)
 312 if test x$GNOME_CONFIG = xno; then
 313   AC_MSG_WARN(Couldn't find gnome-config: can't build editor or gstplay)
 314   GNOME_LIBS=
 315   GNOME_CFLAGS=
 316   HAVE_GNOME=no
 317 else
 318   GNOME_LIBS=`gnome-config --libs gnome gnomeui`
 319   GNOME_CFLAGS=`gnome-config --cflags gnome gnomeui`
 320   GHTTP_LIBS=`gnome-config --libs gnome gnomeui`
 321   GHTTP_CFLAGS=`gnome-config --cflags gnome gnomeui`
 322   HAVE_GNOME=yes
 323 fi
 324 AC_SUBST(GNOME_LIBS)
 325 AC_SUBST(GNOME_CFLAGS)
 326 AC_SUBST(GHTTP_LIBS)
 327
 328 dnl Check for libghttp
 329 dnl FIXME: need to check for header
 330 AC_CHECK_LIB(ghttp, ghttp_request_new,
 331   [GHTTP_LIBS="-lghttp"
 332    GST_HTTPSRC_GET_TYPE="gst_httpsrc_get_type"
 333    HAVE_LIBGHTTP=yes
 334   ],
 335   [AC_MSG_WARN(Cannot find libghttp: can't build gsthttpsrc)
 336    GHTTP_LIBS=
 337    GST_HTTPSRC_GET_TYPE=
 338    HAVE_LIBGHTTP=no
 339   ],
 340   $LIBS)
 341 AC_SUBST(GST_HTTPSRC_GET_TYPE)
 342
 343 dnl Check for libglade
 344 HAVE_LIBGLADE_GNOME="no"
 345 AC_PATH_PROG(LIBGLADE_CONFIG_PATH, libglade-config, no)
 346 if test x$LIBGLADE_CONFIG_PATH = xno; then
 347   AC_MSG_WARN(Couldn't find libglade-config - Can't build gstplay)
 348   LIBGLADE_GNOME_LIBS=
 349   LIBGLADE_GNOME_CFLAGS=
 350 else
 351   LIBGLADE_GNOME_LIBS=`libglade-config --libs gnome`
 352   LIBGLADE_GNOME_CFLAGS=`libglade-config --cflags gnome`
 353   libglade_save_CFLAGS="$CFLAGS"
 354   libglade_save_LIBS="$LIBS"
 355   CFLAGS="$CFLAGS $LIBGLADE_GNOME_CFLAGS $GTK_CFLAGS"
 356   LIBS="$LIBS $LIBGLADE_GNOME_LIBS $GTK_LIBS"
 357   AC_TRY_LINK([#include <glade/glade.h>],[glade_gnome_init();],
 358               HAVE_LIBGLADE_GNOME="yes",
 359               AC_MSG_WARN(
 360       [Couldn't find gnome libraries for libglade - Can't build gstmediaplay and gsteditor])
 361              )
 362   CFLAGS="$libglade_save_CFLAGS"
 363   LIBS="$libglade_save_LIBS"
 364 fi
 365 AC_SUBST(LIBGLADE_GNOME_LIBS)
 366 AC_SUBST(LIBGLADE_GNOME_CFLAGS)
 367
 368 dnl Check for Gnome VFS
 369 HAVE_GNOME_VFS="no"
 370 AC_MSG_CHECKING(for Gnome VFS)
 371 if gnome-config --libs vfs > /dev/null 2>&1; then
 372         HAVE_GNOME_VFS="yes"
 373         AC_MSG_RESULT(found)
 374 else
 375         AC_MSG_WARN(Did not find Gnome-VFS installed)
 376 fi
 377
 378 VFS_LIBS="`gnome-config --libs vfs`"
 379 VFS_CFLAGS="`gnome-config --cflags vfs`"
 380
 381 AC_SUBST(VFS_LIBS)
 382 AC_SUBST(VFS_CFLAGS)
 383
 384 dnl Check for atomic.h
 385 dnl Note: use AC_CHECK_HEADER not AC_CHECK_HEADERS, because the latter
 386 dnl defines the wrong default symbol as well (HAVE_ASM_ATOMIC_H)
 387 AC_CHECK_HEADER(asm/atomic.h, HAVE_ATOMIC_H=yes, HAVE_ATOMIC_H=no)
 388 dnl Do a compile to check that it has atomic_set (eg, linux 2.0 didn't)
 389 if test x$HAVE_ATOMIC_H = xyes; then
 390   AC_TRY_RUN([
 391 #include "asm/atomic.h"
 392 main() { atomic_t t; atomic_set(&t,0); atomic_inc(&t); atomic_add(1,&t);return 0;}
 393   ],, [
 394     # Not successful
 395     if test x$HAVE_ATOMIC_H = xyes; then
 396       AC_MSG_WARN(Atomic reference counting is out of date: doing without.)
 397     fi
 398     HAVE_ATOMIC_H=no
 399   ], [
 400     # Cross compiling
 401     AC_MSG_RESULT(yes)
 402     AC_MSG_WARN(Can't check properly for atomic reference counting.  Assuming OK.)
 403   ])
 404 fi
 405
 406
 407 dnl Check for X11 extensions
 408 AC_PATH_XTRA
 409 if test "-DX_DISPLAY_MISSING" = "$X_CFLAGS"; then
 410   AC_MSG_ERROR(can not find X11)
 411 fi
 412 AC_SUBST(X_CFLAGS)
 413 AC_SUBST(X_PRE_LIBS)
 414 AC_SUBST(X_EXTRA_LIBS)
 415 AC_SUBST(X_LIBS)
 416
 417
 418 dnl Check for the Xv library
 419 xvsave_LIBS=${LIBS}
 420 AC_CHECK_LIB(Xv, XvQueryExtension,
 421   HAVE_LIBXV=yes
 422   AC_DEFINE(HAVE_LIBXV),
 423   HAVE_LIBXV=no,
 424   $X_LIBS $X_PRE_LIBS -lXext -lX11 $X_EXTRA_LIBS
 425 )
 426 LIBS=${xvsave_LIBS}
 427 AC_CHECK_HEADER(X11/extensions/Xv.h, :, HAVE_LIBXV=no)
 428 AC_CHECK_HEADER(X11/extensions/Xvlib.h, :, HAVE_LIBXV=no)
 429
 430 dnl Check for OSS audio
 431 AC_CHECK_HEADER(sys/soundcard.h,
 432   AC_DEFINE(HAVE_OSS)
 433   HAVE_OSS=yes, []
 434 )
 435
 436 dnl Check for xaudio
 437 AC_CHECK_HEADER(xaudio/decoder.h,
 438   AC_DEFINE(HAVE_XAUDIO)
 439   HAVE_XAUDIO="yes",
 440   AC_MSG_WARN(
 441 ***** NOTE: These plugins won't be built: gstxa
 442 )
 443   HAVE_XAUDIO="no",
 444 )
 445
 446 dnl Check for libmad
 447 AC_MSG_CHECKING(MAD library)
 448 AC_CHECK_LIB(mad, mad_decoder_finish,
 449   HAVE_LIBMAD=yes
 450   AC_DEFINE(HAVE_LIBMAD),
 451   AC_MSG_WARN(
 452 ***** NOTE: These plugins won't be built: mad
 453 )
 454   HAVE_LIBMAD=no,
 455 )
 456
 457 dnl Check for libvorbis
 458 AC_MSG_CHECKING(Vorbis library)
 459 AC_CHECK_LIB(vorbis, ogg_sync_init,
 460   HAVE_VORBIS=yes
 461   AC_DEFINE(HAVE_VORBIS),
 462   AC_MSG_WARN(
 463 ***** NOTE: These plugins won't be built: vorbisdec vorbisenc
 464 )
 465   HAVE_VORBIS=no,
 466 )
 467
 468 dnl Check for libjpeg
 469 AC_MSG_CHECKING(libjpeg library)
 470 AC_CHECK_LIB(jpeg, jpeg_set_defaults,
 471   HAVE_LIBJPEG=yes
 472   AC_DEFINE(HAVE_LIBJPEG),
 473   AC_MSG_WARN(
 474 ***** NOTE: These plugins won't be built: jpegdec jpegenc
 475 )
 476   HAVE_LIBJPEG=no,
 477 )
 478
 479 dnl Check for Hermes
 480 AC_MSG_CHECKING(Hermes library)
 481 AC_CHECK_LIB(Hermes, Hermes_ConverterInstance,
 482   HAVE_LIBHERMES=yes
 483   AC_DEFINE(HAVE_LIBHERMES),
 484   AC_MSG_WARN(
 485 ***** NOTE: These plugins won't be built: colorspace
 486 )
 487   HAVE_LIBHERMES=no,
 488 )
 489 AC_CHECK_HEADER(Hermes/Hermes.h, :, HAVE_LIBHERMES=no)
 490
 491 dnl Check for cdparanoia
 492 AC_MSG_CHECKING(CDparanoia library)
 493 HAVE_CDPARANOIA=yes
 494 AC_CHECK_LIB(cdda_interface, cdda_open, : , HAVE_CDPARANOIA=no, )
 495 AC_CHECK_HEADER(cdda_interface.h, :, HAVE_CDPARANOIA=no)
 496 AC_CHECK_LIB(cdda_paranoia, paranoia_init, : , HAVE_CDPARANOIA=no, -lcdda_interface )
 497 AC_CHECK_HEADER(cdda_paranoia.h, :, HAVE_CDPARANOIA=no)
 498
 499 dnl Check for liblame
 500 AC_MSG_CHECKING(LAME library)
 501 AC_CHECK_LIB(mp3lame, lame_init, HAVE_LIBLAME=yes, HAVE_LIBLAME=no, )
 502 AC_CHECK_HEADER(lame/lame.h, :, HAVE_LIBLAME=no)
 503
 504 dnl Check for libshout
 505 AC_MSG_CHECKING(Shout library)
 506 AC_CHECK_LIB(shout, shout_init_connection, HAVE_LIBSHOUT=yes, HAVE_LIBSHOUT=no, )
 507 AC_CHECK_HEADER(shout/shout.h, :, HAVE_LIBSHOUT=no)
 508
 509 dnl Check for mpeg2dec
 510 AC_MSG_CHECKING(mpeg2dec library)
 511 AC_CHECK_LIB(mpeg2, mpeg2_init, HAVE_MPEG2DEC=yes, HAVE_MPEG2DEC=no, )
 512 AC_CHECK_HEADER(mpeg2dec/mpeg2.h, :, HAVE_MPEG2DEC=no)
 513
 514 dnl Check for librtp
 515 AC_MSG_CHECKING(rtp library)
 516 AC_CHECK_LIB(rtp, rtp_packet_new_take_data, HAVE_LIBRTP=yes, HAVE_LIBRTP=no, $GLIB_LIBS $GLIB_CFLAGS)
 517 AC_CHECK_HEADER(rtp/rtp-packet.h, :, HAVE_LIBRTP=no)
 518 AC_CHECK_HEADER(rtp/rtcp-packet.h, :, HAVE_LIBRTP=no)
 519 AC_CHECK_HEADER(rtp/rtp-audio.h, :, HAVE_LIBRTP=no)
 520
 521 dnl Check for arts
 522 AC_LANG_SAVE
 523 AC_LANG_CPLUSPLUS
 524 AC_MSG_CHECKING(arts library)
 525 dnl AC_CHECK_LIB(artsflow, convert_stereo_ifloat_2float, HAVE_ARTS=yes, HAVE_ARTS=no, -lmcop -lartsflow_idl)
 526 AC_CHECK_HEADER(arts/artsflow.h, HAVE_ARTS=yes, HAVE_ARTS=no)
 527 AC_LANG_RESTORE
 528
 529 dnl Check for libraw1394
 530 AC_MSG_CHECKING(raw1394 library)
 531 AC_CHECK_LIB(raw1394, raw1394_get_handle, HAVE_RAW1394=yes, HAVE_RAW1394=no, )
 532 AC_CHECK_HEADER(libraw1394/raw1394.h, :, HAVE_RAW1394=no)
 533
 534 dnl Check for libdv
 535 AC_MSG_CHECKING(libdv)
 536 AC_CHECK_LIB(dv, dv_init, HAVE_LIBDV=yes, HAVE_LIBDV=no, -lm $GLIB_LIBS $GLIB_CFLAGS)
 537 AC_CHECK_HEADER(libdv/dv.h, :, HAVE_LIBDV=no)
 538
 539 dnl Check for aalib
 540 AC_MSG_CHECKING(aalib)
 541 AC_CHECK_LIB(aa, aa_init, HAVE_LIBAA=yes, HAVE_LIBAA=no, )
 542 AC_CHECK_HEADER(aalib.h, :, HAVE_LIBAA=no)
 543
 544 dnl Check for quicktime
 545 AC_MSG_CHECKING(openquicktime)
 546 AC_CHECK_LIB(openquicktime, quicktime_init, HAVE_LIBOPENQUICKTIME=yes, HAVE_LIBOPENQUICKTIME=no, )
 547 AC_CHECK_HEADER(openquicktime/openquicktime.h, :, HAVE_LIBOPENQUICKTIME=no)
 548
 549 dnl check if css-auth.c exists (FIXME)
 550 AC_MSG_CHECKING(DVD CSS code)
 551 if test -f plugins/dvdsrc/css-auth.c
 552 then
 553   AC_MSG_RESULT(yes)
 554   HAVE_CSSAUTH="yes"
 555 else
 556   AC_MSG_RESULT(no)
 557   HAVE_CSSAUTH="no"
 558 fi
 559
 560 dnl Check for SDLlib
 561 AC_MSG_CHECKING(SDLlib)
 562 AC_CHECK_LIB(SDL, SDL_Init, HAVE_LIBSDL=yes, HAVE_LIBSDL=no, -L/usr/lib -L/usr/local/lib -lpthread)
 563 AC_CHECK_HEADER(SDL/SDL.h, :, HAVE_LIBSDL=no)
 564
 565 dnl Check for SDL
 566 HAVE_LIBSDL="no"
 567 AC_MSG_CHECKING(for SDL)
 568 if sdl-config --libs > /dev/null 2>&1; then
 569   HAVE_LIBSDL="yes"
 570   AC_MSG_RESULT(found)
 571 else
 572   AC_MSG_RESULT(not found)
 573 fi
 574
 575 SDL_LIBS="`sdl-config --libs`"
 576 SDL_CFLAGS="`sdl-config --cflags`"
 577
 578 AC_SUBST(SDL_LIBS)
 579 AC_SUBST(SDL_CFLAGS)
 580
 581 dnl Check for linux/cdrom.h
 582 AC_CHECK_HEADER(linux/cdrom.h,
 583   HAVE_LINUX_CDROM=yes, []
 584 )
 585
 586 dnl Check for linux/videodev.h
 587 AC_CHECK_HEADER(linux/videodev.h,
 588   HAVE_LINUX_VIDEODEV=yes, []
 589 )
 590
 591
 592 dnl ######################################################################
 593 dnl # Check command line parameters, and set shell variables accordingly #
 594 dnl ######################################################################
 595
 596 AC_ARG_ENABLE(gdk-pixbuf,
 597 [  --enable-gdk-pixbuf          use gdk pixbuf, if available],
 598 [case "${enableval}" in
 599   yes) USE_GDK_PIXBUF=$HAVE_GDK_PIXBUF ;;
 600   no)  USE_GDK_PIXBUF=no ;;
 601   *) AC_MSG_ERROR(bad value ${enableval} for --enable-gdk-pixbuf) ;;
 602 esac],
 603 [USE_GDK_PIXBUF=$HAVE_GDK_PIXBUF]) dnl Default value
 604
 605 AC_ARG_ENABLE(libghttp,
 606 [  --enable-libghttp            use the ghttp library, if available],
 607 [case "${enableval}" in
 608   yes) USE_LIBGHTTP=$HAVE_LIBGHTTP ;;
 609   no)  USE_LIBGHTTP=no ;;
 610   *) AC_MSG_ERROR(bad value ${enableval} for --enable-libghttp) ;;
 611 esac],
 612 [USE_LIBGHTTP=$HAVE_LIBGHTTP]) dnl Default value
 613
 614 AC_ARG_ENABLE(libmmx,
 615 [  --enable-libmmx              use libmmx, if available],
 616 [case "${enableval}" in
 617   yes) USE_LIBMMX=$HAVE_LIBMMX ;;
 618   no)  USE_LIBMMX=no ;;
 619   *) AC_MSG_ERROR(bad value ${enableval} for --enable-libmmx) ;;
 620 esac],
 621 [USE_LIBMMX=$HAVE_LIBMMX]) dnl Default value
 622
 623 AC_ARG_ENABLE(atomic,
 624 [  --enable-atomic              use atomic reference counting header],
 625 [case "${enableval}" in
 626   yes) USE_ATOMIC_H=$HAVE_ATOMIC_H;;
 627   noset) USE_ATOMIC_H=$HAVE_ATOMIC_H;;
 628   no)  USE_ATOMIC_H=no;;
 629   *) AC_MSG_ERROR(bad value ${enableval} for --enable-atomic) ;;
 630 esac],
 631 [USE_ATOMIC_H=$HAVE_ATOMIC_H]) dnl Default value
 632
 633 AC_ARG_ENABLE(plugin-srcdir,
 634 [  --enable-plugin-srcdir       allow tests/demos to use non-installed plugins ],
 635 [case "${enableval}" in
 636   yes) PLUGINS_USE_SRCDIR=yes ;;
 637   no)  PLUGINS_USE_SRCDIR=no ;;
 638   *) AC_MSG_ERROR(bad value ${enableval} for --enable-plugin-srcdir) ;;
 639 esac],
 640 [PLUGINS_USE_SRCDIR=no]) dnl Default value
 641
 642 AC_ARG_ENABLE(debug,
 643 [  --enable-debug               compile with -g debugging info],
 644 [case "${enableval}" in
 645   yes) USE_DEBUG=yes ;;
 646   no)  USE_DEBUG=no ;;
 647   *) AC_MSG_ERROR(bad value ${enableval} for --enable-debug) ;;
 648 esac],
 649 [USE_DEBUG=no]) dnl Default value
 650
 651 AC_ARG_ENABLE(debug-verbose,
 652 [  --enable-debug-verbose       spews lots of useless debugging info at runtime],
 653 [case "${enableval}" in
 654   yes) USE_DEBUG_VERBOSE=yes ;;
 655   no)  USE_DEBUG_VERBOSE=no ;;
 656   *) AC_MSG_ERROR(bad value ${enableval} for --enable-debug-verbose) ;;
 657 esac],
 658 [USE_DEBUG_VERBOSE=no]) dnl Default value
 659
 660 AC_ARG_ENABLE(info,
 661 [  --enable-info                spews lots of info at runtime for plugin writers],
 662 [case "${enableval}" in
 663   yes) USE_DEBUG_INFO_VERBOSE=yes ;;
 664   no)  USE_DEBUG_INFO_VERBOSE=no ;;
 665   *) AC_MSG_ERROR(bad value ${enableval} for --enable-info) ;;
 666 esac],
 667 [USE_DEBUG_INFO_VERBOSE=no]) dnl Default value
 668
 669 AC_ARG_ENABLE(info-system,
 670 [  --disable-info-system        disables the info debugging system],
 671 [case "${enableval}" in
 672   yes) DISABLE_DEBUG_INFO=no ;;
 673   no)  DISABLE_DEBUG_INFO=yes ;;
 674   *) AC_MSG_ERROR(bad value ${enableval} for --disable-info) ;;
 675 esac],
 676 [DISABLE_DEBUG_INFO=no]) dnl Default value
 677
 678 AC_ARG_ENABLE(debug-color,
 679 [  --disable-debug-color        disables color output of DEBUG and INFO output],
 680 [case "${enableval}" in
 681   yes) DISABLE_DEBUG_COLOR=no ;;
 682   no)  DISABLE_DEBUG_COLOR=yes ;;
 683   *) AC_MSG_ERROR(bad value ${enableval} for --disable-info) ;;
 684 esac],
 685 [DISABLE_DEBUG_COLOR=no]) dnl Default value
 686
 687 AC_ARG_ENABLE(profiling,
 688 [  --enable-profiling           adds -pg to compiler commandline, for profiling],
 689 [case "${enableval}" in
 690   yes) USE_PROFILING=yes ;;
 691   no)  UES_PROFILING=no ;;
 692   *) AC_MSG_ERROR(bad value ${enableval} for --enable-profiling) ;;
 693 esac],
 694 [USE_PROFILING=no]) dnl Default value
 695
 696 dnl Default value
 697 GST_CONFIG_DIR="/etc/gstreamer"
 698 AC_ARG_WITH(configdir,
 699 [  --with-configdir             specify path to use for configdir],
 700 [case "${withval}" in
 701   yes) AC_MSG_ERROR(bad value ${withval} for --with-configdir) ;;
 702   no) AC_MSG_ERROR(bad value ${withval} for --with-configdir) ;;
 703   *) GST_CONFIG_DIR="${withval}" ;;
 704 esac],
 705 [:]) dnl Default value
 706
 707 dnl Default value
 708 GST_WIN32_LIBDIR="/usr/lib/win32"
 709 AC_ARG_WITH(win32_libdir,
 710 [  --with-win32-libdir          specify location for win32 DLLs],
 711 [case "${withval}" in
 712   yes) AC_MSG_ERROR(bad value ${withval} for --with-win32-libdir) ;;
 713   no) AC_MSG_ERROR(bad value ${withval} for --with-win32-libdir) ;;
 714   *) GST_WIN32_LIBDIR="${withval}" ;;
 715 esac],
 716 [:]) dnl Default value
 717
 718 AC_ARG_ENABLE(docs-build,
 719 [  --enable-docs-build           enable building of documentation],
 720 [case "${enableval}" in
 721   yes) BUILD_DOCS=yes ;;
 722   no)  BUILD_DOCS=no ;;
 723   *) AC_MSG_ERROR(bad value ${enableval} for --enable-docs-build) ;;
 724 esac],
 725 [BUILD_DOCS=no]) dnl Default value
 726
 727 AC_ARG_ENABLE(plugin-docs,
 728 [  --enable-plugin-docs         enable the building of plugin documentation
 729                                (this is currently broken, so off by default)],
 730 [case "${enableval}" in
 731   yes) BUILD_PLUGIN_DOCS=yes ;;
 732   no)  BUILD_PLUGIN_DOCS=no ;;
 733   *) AC_MSG_ERROR(bad value ${enableval} for --enable-plugin-docs) ;;
 734 esac],
 735 [BUILD_PLUGIN_DOCS=no]) dnl Default value
 736
 737
 738
 739
 740 dnl ################################################
 741 dnl # Set defines according to variables set above #
 742 dnl ################################################
 743
 744
 745 dnl These should be "USE_*" instead of "HAVE_*", but some packages expect
 746 dnl HAVE_ and it is likely to be easier to stick with the old name
 747 if test "x$USE_GDK_PIXBUF" = xyes; then
 748   AC_DEFINE(HAVE_GDK_PIXBUF)
 749 fi
 750
 751 if test "x$USE_LIBGHTTP" = xyes; then
 752   AC_DEFINE(HAVE_LIBGHTTP)
 753 fi
 754
 755 if test "x$USE_LIBMMX" = xyes; then
 756   AC_DEFINE(HAVE_LIBMMX)
 757 fi
 758
 759 if test "x$USE_ATOMIC_H" = xyes; then
 760   AC_DEFINE(HAVE_ATOMIC_H)
 761 fi
 762
 763 if test "x$PLUGINS_USE_SRCDIR" = xyes; then
 764   AC_DEFINE(PLUGINS_USE_SRCDIR)
 765 fi
 766
 767 if test "x$USE_DEBUG" = xyes; then
 768   CFLAGS="$CFLAGS -g"
 769 fi
 770
 771 if test "x$USE_DEBUG_VERBOSE" = xyes; then
 772   AC_DEFINE(GST_DEBUG_ENABLED)
 773 fi
 774
 775 if test "x$USE_DEBUG_INFO_VERBOSE" = xyes; then
 776   AC_DEFINE(GST_INFO_ENABLED_VERBOSE)
 777   AC_DEFINE(GST_INFO_ENABLED)
 778 else
 779   AC_DEFINE(GST_INFO_ENABLED)
 780 fi
 781
 782 if test "x$DISABLE_DEBUG_INFO" = xyes; then
 783   AC_DEFINE(GST_INFO_FORCE_DISABLE)
 784 fi
 785
 786 if test "x$DISABLE_DEBUG_COLOR" = xno; then
 787   AC_DEFINE(GST_DEBUG_COLOR)
 788 fi
 789
 790 if test "x$USE_PROFILING" = xyes; then
 791   CFLAGS="$CFLAGS -pg"
 792   FOMIT_FRAME_POINTER=""
 793 else
 794   FOMIT_FRAME_POINTER="-fomit-frame-pointer"
 795 fi
 796
 797 if test "x$HAVE_LIBXV" = xyes; then
 798   AC_DEFINE(HAVE_LIBXV)
 799 fi
 800
 801 if test "x$HAVE_OSS" = xyes; then
 802   AC_DEFINE(HAVE_OSS)
 803 fi
 804
 805 if test "x$HAVE_XAUDIO" = xyes; then
 806   AC_DEFINE(HAVE_XAUDIO)
 807 fi
 808
 809 if test "x$HAVE_LIBMAD" = xyes; then
 810   AC_DEFINE(HAVE_LIBMAD)
 811 fi
 812
 813 if test "x$HAVE_VORBIS" = xyes; then
 814   AC_DEFINE(HAVE_VORBIS)
 815 fi
 816
 817 if test "x$HAVE_LIBJPEG" = xyes; then
 818   AC_DEFINE(HAVE_LIBJPEG)
 819 fi
 820
 821 if test "x$HAVE_LIBSDL" = xyes; then
 822   AC_DEFINE(HAVE_LIBSDL)
 823 fi
 824
 825 if test "x$HAVE_LIBHERMES" = "xyes"; then
 826   AC_DEFINE(HAVE_LIBHERMES)
 827 fi
 828
 829 if test "x$HAVE_CSSAUTH" = xyes; then
 830   AC_DEFINE(HAVE_CSSAUTH)
 831 fi
 832
 833 if test "x$HAVE_LINUX_CDROM" = xyes; then
 834   AC_DEFINE(HAVE_LINUX_CDROM)
 835 fi
 836
 837 if test "x$HAVE_LINUX_VIDEODEV" = xyes; then
 838   AC_DEFINE(HAVE_LINUX_VIDEODEV)
 839 fi
 840
 841 if test "x$HAVE_MPEG2DEC" = xyes; then
 842   AC_DEFINE(HAVE_MPEG2DEC)
 843 fi
 844
 845 if test "x$HAVE_LIBAUDIOFILE" = xyes; then
 846   AC_DEFINE(HAVE_LIBAUDIOFILE)
 847 fi
 848
 849 dnl #############################
 850 dnl # Set automake conditionals #
 851 dnl #############################
 852
 853 dnl These should be "USE_*" instead of "HAVE_*", but some packages expect
 854 dnl HAVE_ and it is likely to be easier to stick with the old name
 855 AM_CONDITIONAL(HAVE_CPU_I386,       test "x$HAVE_CPU_I386" = "xyes")
 856 AM_CONDITIONAL(HAVE_CPU_PPC,        test "x$HAVE_CPU_PPC" = "xyes")
 857 AM_CONDITIONAL(HAVE_CPU_ALPHA,      test "x$HAVE_CPU_ALPHA" = "xyes")
 858 AM_CONDITIONAL(HAVE_CPU_ARM,        test "x$HAVE_CPU_ARM" = "xyes")
 859 AM_CONDITIONAL(HAVE_CPU_SPARC,      test "x$HAVE_CPU_SPARC" = "xyes")
 860 AM_CONDITIONAL(HAVE_GDK_PIXBUF,     test "x$USE_GDK_PIXBUF" = "xyes")
 861 AM_CONDITIONAL(HAVE_LIBGHTTP,       test "x$USE_LIBGHTTP" = "xyes")
 862 AM_CONDITIONAL(HAVE_LIBAUDIOFILE,   test "x$HAVE_LIBAUDIOFILE" = "xyes")
 863 AM_CONDITIONAL(HAVE_LIBMMX,         test "x$USE_LIBMMX" = "xyes")
 864 AM_CONDITIONAL(HAVE_ATOMIC_H,       test "x$USE_ATOMIC_H" = "xyes")
 865 AM_CONDITIONAL(HAVE_OSS,            test "x$HAVE_OSS" = "xyes")
 866 AM_CONDITIONAL(HAVE_XAUDIO,         test "x$HAVE_XAUDIO" = "xyes")
 867 AM_CONDITIONAL(HAVE_LIBMAD,         test "x$HAVE_LIBMAD" = "xyes")
 868 AM_CONDITIONAL(HAVE_LINUX_CDROM,    test "x$HAVE_LINUX_CDROM" = "xyes")
 869 AM_CONDITIONAL(HAVE_LINUX_VIDEODEV, test "x$HAVE_LINUX_VIDEODEV" = "xyes")
 870 AM_CONDITIONAL(HAVE_CSSAUTH,        test "x$HAVE_CSSAUTH" = "xyes")
 871 AM_CONDITIONAL(HAVE_VORBIS,         test "x$HAVE_VORBIS" = "xyes")
 872 AM_CONDITIONAL(HAVE_LIBJPEG,        test "x$HAVE_LIBJPEG" = "xyes")
 873 AM_CONDITIONAL(HAVE_LIBSDL,         test "x$HAVE_LIBSDL" = "xyes")
 874 AM_CONDITIONAL(HAVE_LIBHERMES,      test "x$HAVE_LIBHERMES" = "xyes")
 875 AM_CONDITIONAL(HAVE_NASM,           test "x$HAVE_NASM" = "xyes")
 876 AM_CONDITIONAL(HAVE_LIBGLADE_GNOME, test "x$HAVE_LIBGLADE_GNOME" = "xyes")
 877 AM_CONDITIONAL(HAVE_GNOME,          test "x$HAVE_GNOME" = "xyes")
 878 AM_CONDITIONAL(HAVE_LIBXV,          test "x$HAVE_LIBXV" = "xyes")
 879 AM_CONDITIONAL(HAVE_GTK_DOC,        $HAVE_GTK_DOC)
 880 AM_CONDITIONAL(BUILD_DOCS,          test "x$BUILD_DOCS" = "xyes")
 881 AM_CONDITIONAL(BUILD_PLUGIN_DOCS,   test "x$BUILD_PLUGIN_DOCS" = "xyes")
 882 AM_CONDITIONAL(HAVE_DB2HTML,        $HAVE_DB2HTML)
 883 AM_CONDITIONAL(HAVE_DB2PS,          $HAVE_DB2PS)
 884 AM_CONDITIONAL(HAVE_PS2PDF,         $HAVE_PS2PDF)
 885 AM_CONDITIONAL(HAVE_FIG2DEV_PNG,    $HAVE_FIG2DEV_PNG)
 886 AM_CONDITIONAL(HAVE_FIG2DEV_EPS,    $HAVE_FIG2DEV_EPS)
 887 AM_CONDITIONAL(HAVE_CDPARANOIA,     test "x$HAVE_CDPARANOIA" = "xyes")
 888 AM_CONDITIONAL(HAVE_LIBLAME,        test "x$HAVE_LIBLAME" = "xyes")
 889 AM_CONDITIONAL(HAVE_LIBSHOUT,       test "x$HAVE_LIBSHOUT" = "xyes")
 890 AM_CONDITIONAL(HAVE_LIBESD,         test "x$HAVE_LIBESD" = "xyes")
 891 AM_CONDITIONAL(HAVE_ARTSC,          test "x$HAVE_ARTSC" = "xyes")
 892 AM_CONDITIONAL(HAVE_LIBASOUND,      test "x$HAVE_LIBASOUND" = "xyes")
 893 AM_CONDITIONAL(HAVE_MPEG2DEC,       test "x$HAVE_MPEG2DEC" = "xyes")
 894 AM_CONDITIONAL(HAVE_LIBXMMS,        test "x$HAVE_LIBXMMS" = "xyes")
 895 AM_CONDITIONAL(HAVE_LIBRTP,         test "x$HAVE_LIBRTP" = "xyes")
 896 AM_CONDITIONAL(HAVE_ARTS,           test "x$HAVE_ARTS" = "xyes")
 897 AM_CONDITIONAL(HAVE_RAW1394,        test "x$HAVE_RAW1394" = "xyes")
 898 AM_CONDITIONAL(HAVE_LIBDV,          test "x$HAVE_LIBDV" = "xyes")
 899 AM_CONDITIONAL(HAVE_LIBAA,          test "x$HAVE_LIBAA" = "xyes")
 900 AM_CONDITIONAL(HAVE_GNOME_VFS,      test "x$HAVE_GNOME_VFS" = "xyes")
 901 AM_CONDITIONAL(HAVE_LIBSDL,         test "x$HAVE_LIBSDL" = "xyes")
 902 AM_CONDITIONAL(HAVE_LIBOPENQUICKTIME,      test "x$HAVE_LIBOPENQUICKTIME" = "xyes")
 903
 904
 905
 906 dnl ############################
 907 dnl # Set up some more defines #
 908 dnl ############################
 909
 910 dnl Set location of configuration dir.
 911 AC_DEFINE_UNQUOTED(GST_CONFIG_DIR,"$GST_CONFIG_DIR")
 912 AC_SUBST(GST_CONFIG_DIR)
 913
 914 dnl Set location of windows dll dir.
 915 AC_DEFINE_UNQUOTED(GST_WIN32_LIBDIR,"$GST_WIN32_LIBDIR")
 916 AC_SUBST(GST_WIN32_LIBDIR)
 917
 918 dnl Set location of plugin directory
 919 if test "x${prefix}" = "xNONE"; then
 920   PLUGINS_DIR=${ac_default_prefix}/lib/gst
 921 else
 922   PLUGINS_DIR=${prefix}/lib/gst
 923 fi
 924 AC_DEFINE_UNQUOTED(PLUGINS_DIR,"$PLUGINS_DIR")
 925 AC_SUBST(PLUGINS_DIR)
 926
 927 dnl Set location of uninstalled plugin directory
 928 PLUGINS_SRCDIR=`pwd`/$srcdir
 929 AC_DEFINE_UNQUOTED(PLUGINS_SRCDIR,"$PLUGINS_SRCDIR")
 930 AC_SUBST(PLUGINS_SRCDIR)
 931
 932
 933
 934 dnl ##############################
 935 dnl # Set up the defaults cflags #
 936 dnl ##############################
 937 dnl CC="kgcc"
 938 if test "x$USE_PROFILING" = xyes; then
 939   CFLAGS="$CORE_CFLAGS $CFLAGS -Wall"
 940 else
 941   CFLAGS="$CORE_CFLAGS $CFLAGS -O6 -Wall"
 942 fi
 943 LIBS="$CORE_LIBS $LIBS"
 944 AC_SUBST(CORE_LIBS)
 945 AC_SUBST(CORE_CFLAGS)
 946
 947 dnl FIXME: having to AC_SUBST these is messy.  Not sure if CPPFLAGS and LDFLAGS
 948 dnl need it, either.
 949
 950 dnl Private vars for libgst only
 951 LIBGST_LIBS="$LIBS"
 952 LIBGST_CFLAGS="$CFLAGS"
 953 AC_SUBST(LIBGST_LIBS)
 954 AC_SUBST(LIBGST_CFLAGS)
 955
 956 dnl Vars for everyone else
 957 GST_LIBS="\$(top_builddir)/gst/libgst.la"
 958 GST_CFLAGS="-I\$(top_srcdir) -I\$(top_srcdir)/include"
 959 AC_SUBST(GST_LIBS)
 960 AC_SUBST(GST_CFLAGS)
 961
 962 dnl CFLAGS for everyone else
 963 CFLAGS="$CFLAGS $GST_CFLAGS"
 964 AC_SUBST(LIBS)
 965 AC_SUBST(CFLAGS)
 966
 967 dnl AC_SUBST(CPPFLAGS)
 968 dnl AC_SUBST(LDFLAGS)
 969
 970
 971 dnl #############################
 972 dnl # Configure the subpackages #
 973 dnl #############################
 974
 975 dnl AC_CONFIG_SUBDIRS(gist)
 976 dnl AC_CONFIG_SUBDIRS(plugins/mp3decode/xing/libxing)
 977
 978
 979 dnl #########################
 980 dnl # Make the output files #
 981 dnl #########################
 982
 983 AC_OUTPUT([Makefile
 984 include/Makefile
 985 include/wine/Makefile
 986 gst/Makefile
 987 gst/gstversion.h
 988 gst/types/Makefile
 989 gst/elements/Makefile
 990 gst/autoplug/Makefile
 991 libs/Makefile
 992 libs/riff/Makefile
 993 libs/colorspace/Makefile
 994 libs/videoscale/Makefile
 995 libs/getbits/Makefile
 996 libs/putbits/Makefile
 997 libs/winloader/Makefile
 998 libs/idct/Makefile
 999 plugins/Makefile
1000 plugins/aasink/Makefile
1001 plugins/alsa/Makefile
1002 plugins/au/Makefile
1003 plugins/audiofile/Makefile
1004 plugins/audioscale/Makefile
1005 plugins/avi/Makefile
1006 plugins/avi/wincodec/Makefile
1007 plugins/flx/Makefile
1008 plugins/jpeg/Makefile
1009 plugins/mp3decode/Makefile
1010 plugins/mp3decode/types/Makefile
1011 plugins/mp3decode/xa/Makefile
1012 plugins/mp3decode/mpg123/Makefile
1013 plugins/mp3decode/mad/Makefile
1014 plugins/mp3decode/parse/Makefile
1015 plugins/mp3encode/Makefile
1016 plugins/mp3encode/lame/Makefile
1017 plugins/mpeg2/Makefile
1018 plugins/mpeg2/parse/Makefile
1019 plugins/mpeg2/ac3parse/Makefile
1020 plugins/mpeg2/ac3dec/Makefile
1021 plugins/mpeg2/video/Makefile
1022 plugins/mpeg2/mpeg2enc/Makefile
1023 plugins/mpeg2/mpeg2dec/Makefile
1024 plugins/mpeg2/subtitles/Makefile
1025 plugins/mpeg2/videoparse/Makefile
1026 plugins/mpeg2/mpegtypes/Makefile
1027 plugins/mpeg1/Makefile
1028 plugins/mpeg1/mpegtypes/Makefile
1029 plugins/mpeg1/mpeg_play/Makefile
1030 plugins/mpeg1/mpegaudio/Makefile
1031 plugins/mpeg1/parse/Makefile
1032 plugins/mpeg1/system_encode/Makefile
1033 plugins/mpeg1/mpeg1encoder/Makefile
1034 plugins/mpeg1video/Makefile
1035 plugins/mpeg1video/parse/Makefile
1036 plugins/oss/Makefile
1037 plugins/rtp/Makefile
1038 plugins/rtp/rtpsend/Makefile
1039 plugins/mulaw/Makefile
1040 plugins/alaw/Makefile
1041 plugins/filters/Makefile
1042 plugins/filters/smooth/Makefile
1043 plugins/filters/median/Makefile
1044 plugins/filters/ladspa/Makefile
1045 plugins/filters/stereo2mono/Makefile
1046 plugins/filters/mono2stereo/Makefile
1047 plugins/filters/intfloatconvert/Makefile
1048 plugins/filters/passthrough/Makefile
1049 plugins/filters/adder/Makefile
1050 plugins/filters/colorspace/Makefile
1051 plugins/filters/volenv/Makefile
1052 plugins/filters/level/Makefile
1053 plugins/gnomevfs/Makefile
1054 plugins/icecast/Makefile
1055 plugins/icecast/icecastsend/Makefile
1056 plugins/effects/Makefile
1057 plugins/effects/stereo/Makefile
1058 plugins/effects/volume/Makefile
1059 plugins/visualization/Makefile
1060 plugins/visualization/spectrum/Makefile
1061 plugins/visualization/vumeter/Makefile
1062 plugins/visualization/synaesthesia/Makefile
1063 plugins/visualization/smoothwave/Makefile
1064 plugins/videoscale/Makefile
1065 plugins/xvideosink/Makefile
1066 plugins/wav/Makefile
1067 plugins/dvdsrc/Makefile
1068 plugins/vcdsrc/Makefile
1069 plugins/rtjpeg/Makefile
1070 plugins/vorbis/Makefile
1071 plugins/capture/Makefile
1072 plugins/capture/v4l/Makefile
1073 plugins/cdparanoia/Makefile
1074 plugins/esd/Makefile
1075 plugins/esd/esdsink/Makefile
1076 plugins/artsd/Makefile
1077 plugins/quicktime/Makefile
1078 plugins/xmms/Makefile
1079 plugins/arts/Makefile
1080 plugins/1394/Makefile
1081 plugins/sdlsink/Makefile
1082 plugins/dv/Makefile
1083 gstplay/Makefile
1084 dnl components/bonobo-gstmediaplay/Makefile
1085 test/Makefile
1086 test/xml/Makefile
1087 test/bindings/Makefile
1088 tests/Makefile
1089 tests/sched/Makefile
1090 tests/eos/Makefile
1091 testsuite/Makefile
1092 testsuite/refcounting/Makefile
1093 testsuite/capsnego/Makefile
1094 tests/nego/Makefile
1095 examples/Makefile
1096 examples/autoplug/Makefile
1097 examples/helloworld/Makefile
1098 examples/helloworld2/Makefile
1099 examples/launch/Makefile
1100 examples/queue/Makefile
1101 examples/queue2/Makefile
1102 examples/queue3/Makefile
1103 examples/queue4/Makefile
1104 examples/thread/Makefile
1105 examples/mixer/Makefile
1106 examples/launch/Makefile
1107 examples/xml/Makefile
1108 examples/plugins/Makefile
1109 examples/typefind/Makefile
1110 examples/mixer/Makefile
1111 editor/Makefile
1112 editor/pixmaps/Makefile
1113 tools/Makefile
1114 docs/Makefile
1115 docs/gst/Makefile
1116 docs/gst/gstreamer.types
1117 docs/libs/Makefile
1118 docs/plugins/Makefile
1119 docs/plugins/gstreamer-plugins.types
1120 docs/manual/Makefile
1121 docs/fwg/Makefile
1122 debian/Makefile
1123 stamp.h
1124 gstreamer-config
1125 gstreamer.spec
1126 gstreamer.pc
1127 gstreamer-uninstalled.pc])
1128 AC_OUTPUT_COMMANDS([chmod +x gstreamer-config])