configure.ac

   1 AC_PREREQ(2.69)
   2 dnl initialize autoconf
   3 dnl when going to/from release please set the nano (fourth number) right !
   4 dnl releases only do Wall, cvs and prerelease does Werror too
   5 AC_INIT([GStreamer RTSP Server Library], [1.9.0.1],
   6     [http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer],
   7     [gst-rtsp-server])
   8 AG_GST_INIT
   9
  10 dnl initialize automake
  11 AM_INIT_AUTOMAKE([-Wno-portability 1.14 no-dist-gzip dist-xz tar-ustar subdir-objects])
  12
  13 dnl define PACKAGE_VERSION_* variables
  14 AS_VERSION
  15
  16 dnl check if this is a release version
  17 AS_NANO(GST_GIT="no", GST_GIT="yes")
  18
  19 dnl can autoconf find the source ?
  20 AC_CONFIG_SRCDIR([gst/rtsp-server/rtsp-server.c])
  21
  22 dnl define the output header for config
  23 AC_CONFIG_HEADERS([config.h])
  24
  25 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  26 AM_MAINTAINER_MODE([enable])
  27
  28 dnl sets host_* variables
  29 AC_CANONICAL_HOST
  30
  31 dnl use pretty build output with automake >= 1.11
  32 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],
  33   [AM_DEFAULT_VERBOSITY=1
  34    AC_SUBST(AM_DEFAULT_VERBOSITY)])
  35
  36 dnl our libraries and install dirs use major.minor as a version
  37 dnl GST_API_VERSION=$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR
  38 dnl we override it here if we need to for the release candidate of new series
  39 GST_API_VERSION=1.0
  40 AC_SUBST(GST_API_VERSION)
  41
  42 dnl CURRENT, REVISION, AGE
  43 dnl - library source changed -> increment REVISION
  44 dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
  45 dnl - interfaces added -> increment AGE
  46 dnl - interfaces removed -> AGE = 0
  47 dnl
  48 dnl Keep CURRENT as MINOR * 100 + MICRO
  49 dnl Ex : 1.0.0 => 0
  50 dnl      1.0.3 => 3
  51 dnl      1.1.0 => 100
  52 dnl      1.2.5 => 205
  53 dnl      1.10.9 (who knows) => 1009
  54 dnl
  55 dnl sets GST_LT_LDFLAGS
  56 AS_LIBTOOL(GST, 900, 0, 900)
  57
  58 dnl *** required versions of GStreamer stuff ***
  59 GST_REQ=1.9.0.1
  60 GSTPB_REQ=1.9.0.1
  61 GSTPG_REQ=1.9.0.1
  62 GSTPD_REQ=1.9.0.1
  63
  64 dnl *** autotools stuff ****
  65
  66 dnl allow for different autotools
  67 AS_AUTOTOOLS_ALTERNATE
  68
  69 dnl Add parameters for aclocal
  70 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  71 AC_CONFIG_MACRO_DIR([m4])
  72
  73 dnl set up gettext
  74 dnl the version check needs to stay here because autopoint greps for it
  75 #AM_GNU_GETTEXT_VERSION([0.17])
  76 #AM_GNU_GETTEXT([external])
  77 #AG_GST_GETTEXT([gst-rtsp-server-$GST_API_VERSION])
  78
  79 dnl *** check for arguments to configure ***
  80
  81 AG_GST_ARG_DISABLE_FATAL_WARNINGS
  82 AG_GST_ARG_ENABLE_EXTRA_CHECKS
  83
  84 AG_GST_ARG_DEBUG
  85 AG_GST_ARG_VALGRIND
  86 AG_GST_ARG_GCOV
  87 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  88 AG_GST_ARG_WITH_PACKAGE_NAME
  89 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  90
  91 AG_GST_ARG_EXAMPLES
  92
  93 AG_GST_PKG_CONFIG_PATH
  94
  95 AG_GST_SET_PACKAGE_RELEASE_DATETIME_WITH_NANO([$PACKAGE_VERSION_NANO],
  96   ["${srcdir}/gst-rtsp-server.doap"],
  97   [$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_MICRO])
  98
  99 dnl building of tests
 100 AC_ARG_ENABLE(tests,
 101   AS_HELP_STRING([--disable-tests],[disable building test apps]),
 102   [
 103     case "${enableval}" in
 104       yes) BUILD_TESTS=yes ;;
 105       no)  BUILD_TESTS=no ;;
 106       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-tests) ;;
 107     esac
 108   ],
 109 [BUILD_TESTS=yes]) dnl Default value
 110 AM_CONDITIONAL(BUILD_TESTS,         test "x$BUILD_TESTS" = "xyes")
 111
 112 dnl *** checks for platform ***
 113
 114 dnl * hardware/architecture *
 115
 116 dnl *** checks for programs ***
 117
 118 dnl find a compiler
 119 AC_PROG_CC
 120 AC_PROG_CC_STDC
 121
 122 dnl check if the compiler supports '-c' and '-o' options
 123 AM_PROG_CC_C_O
 124
 125 dnl find an assembler
 126 AM_PROG_AS
 127
 128 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 129 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 130
 131 dnl check for gobject-introspection
 132 GOBJECT_INTROSPECTION_CHECK([1.31.1])
 133
 134 dnl check for documentation tools
 135 AG_GST_DOCBOOK_CHECK
 136 GTK_DOC_CHECK([1.12])
 137
 138 dnl *** checks for libraries ***
 139
 140 dnl *** checks for header files ***
 141
 142 dnl *** checks for types/defines ***
 143
 144 dnl *** checks for structures ***
 145
 146 dnl *** checks for compiler characteristics ***
 147
 148 dnl *** checks for library functions ***
 149
 150 dnl *** checks for dependancy libraries ***
 151
 152 dnl GLib is required
 153 GLIB_REQ=2.40.0
 154 AC_SUBST([GLIB_REQ])
 155 AG_GST_GLIB_CHECK([$GLIB_REQ])
 156
 157 dnl checks for gstreamer
 158 dnl uninstalled is selected preferentially -- see pkg-config(1)
 159 AG_GST_CHECK_GST($GST_API_VERSION, [$GST_REQ], [yes])
 160
 161 GST_TOOLS_DIR=`$PKG_CONFIG --variable=toolsdir gstreamer-$GST_API_VERSION`
 162 if test -z $GST_TOOLS_DIR; then
 163   AC_MSG_ERROR([no tools dir defined in GStreamer pkg-config file; core upgrade needed.])
 164 fi
 165 AC_SUBST(GST_TOOLS_DIR)
 166
 167 GST_PLUGINS_DIR=`$PKG_CONFIG gstreamer-$GST_API_VERSION --variable pluginsdir`
 168 AC_SUBST(GST_PLUGINS_DIR)
 169 AC_MSG_NOTICE(Using GStreamer Core Plugins in $GST_PLUGINS_DIR)
 170
 171 AG_GST_CHECK_GST_BASE($GST_API_VERSION, [$GST_REQ], [yes])
 172
 173 AG_GST_CHECK_GST_NET($GST_API_VERSION, [$GST_REQ], yes)
 174
 175 AG_GST_CHECK_GST_PLUGINS_BASE($GST_API_VERSION, [$GSTPB_REQ], [yes])
 176 GSTPB_PLUGINS_DIR=`$PKG_CONFIG gstreamer-plugins-base-$GST_API_VERSION --variable pluginsdir`
 177 AC_SUBST(GSTPB_PLUGINS_DIR)
 178 AC_MSG_NOTICE(Using GStreamer Base Plugins in $GSTPB_PLUGINS_DIR)
 179
 180 AG_GST_CHECK_GST_PLUGINS_GOOD($GST_API_VERSION, [$GSTPG_REQ], [yes])
 181 GSTPG_PLUGINS_DIR=`$PKG_CONFIG gstreamer-plugins-good-$GST_API_VERSION --variable pluginsdir`
 182 AC_SUBST(GSTPG_PLUGINS_DIR)
 183 AC_MSG_NOTICE(Using GStreamer Good Plugins in $GSTPG_PLUGINS_DIR)
 184
 185 AG_GST_CHECK_GST_PLUGINS_BAD($GST_API_VERSION, [$GSTPD_REQ], [yes])
 186 GSTPD_PLUGINS_DIR=`$PKG_CONFIG gstreamer-plugins-bad-$GST_API_VERSION --variable pluginsdir`
 187 AC_SUBST(GSTPD_PLUGINS_DIR)
 188 AC_MSG_NOTICE(Using GStreamer Bad Plugins in $GSTPD_PLUGINS_DIR)
 189
 190 AG_GST_CHECK_GST_CHECK($GST_API_VERSION, [$GST_REQ], no)
 191 AM_CONDITIONAL(HAVE_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 192
 193 dnl Check for -Bsymbolic-functions linker flag used to avoid
 194 dnl intra-library PLT jumps, if available.
 195 AC_ARG_ENABLE(Bsymbolic,
 196               [AS_HELP_STRING([--disable-Bsymbolic],[avoid linking with -Bsymbolic])],,
 197               [SAVED_LDFLAGS="${LDFLAGS}" SAVED_LIBS="${LIBS}"
 198                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
 199                LDFLAGS=-Wl,-Bsymbolic-functions
 200                LIBS=
 201                AC_TRY_LINK([], [return 0],
 202                            AC_MSG_RESULT(yes)
 203                            enable_Bsymbolic=yes,
 204                            AC_MSG_RESULT(no)
 205                            enable_Bsymbolic=no)
 206                LDFLAGS="${SAVED_LDFLAGS}" LIBS="${SAVED_LIBS}"])
 207
 208 dnl *** set variables based on configure arguments ***
 209
 210 dnl set license and copyright notice
 211 GST_LICENSE="LGPL"
 212 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 213 AC_SUBST(GST_LICENSE)
 214
 215 dnl set location of plugin directory
 216 AG_GST_SET_PLUGINDIR
 217
 218 dnl set release date/time (and check that release version is in doap file)
 219 AG_GST_SET_PACKAGE_RELEASE_DATETIME_WITH_NANO([$PACKAGE_VERSION_NANO],
 220   ["${srcdir}/gst-rtsp-server.doap"],
 221   [$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_MICRO])
 222
 223 # set by AG_GST_PARSE_SUBSYSTEM_DISABLES above
 224 dnl make sure it doesn't complain about unused variables if debugging is disabled
 225 NO_WARNINGS=""
 226 AG_GST_CHECK_GST_DEBUG_DISABLED([NO_WARNINGS="-Wno-unused"], [NO_WARNINGS=""])
 227
 228 dnl define an ERROR_CFLAGS Makefile variable
 229 AG_GST_SET_ERROR_CFLAGS($FATAL_WARNINGS, [-Wmissing-declarations -Wmissing-prototypes -Wredundant-decls -Wundef -Wwrite-strings -Wformat-nonliteral -Wformat-security -Wold-style-definition -Winit-self -Wmissing-include-dirs -Waddress -Waggregate-return -Wno-multichar -Wnested-externs $NO_WARNINGS])
 230
 231 dnl define correct level for debugging messages
 232 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 233
 234 dnl used in examples
 235 AG_GST_DEFAULT_ELEMENTS
 236
 237 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 238
 239 dnl Overview:
 240 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
 241 dnl GST_*:              flags shared by built objects to link against GStreamer
 242 dnl GST_ALL_LDFLAGS:    linker flags shared by all
 243 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 244 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 245 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 246
 247 dnl GST_OPTION_CFLAGS
 248 if test "x$USE_DEBUG" = xyes; then
 249    PROFILE_CFLAGS="-g"
 250 fi
 251 AC_SUBST(PROFILE_CFLAGS)
 252
 253 # GST_DISABLE_DEPRECATED: hide the visibility of deprecated
 254 # functionality from the API that gstreamer uses
 255 # GST_REMOVE_DEPRECATED: don't compile deprecated functionality (breaks ABI)
 256 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
 257   dnl Define _only_ when compiling from git (not for pre-releases or releases)
 258   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 259 else
 260   DEPRECATED_CFLAGS=""
 261 fi
 262 AC_SUBST(DEPRECATED_CFLAGS)
 263
 264 dnl every flag in GST_OPTION_CFLAGS can be overridden at make time
 265 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 266 AC_SUBST(GST_OPTION_CFLAGS)
 267
 268 dnl FIXME: do we want to rename to GST_ALL_* ?
 269 dnl prefer internal headers to already installed ones
 270 dnl add GST_OPTION_CFLAGS, but overridable
 271 GST_CFLAGS="$GST_CFLAGS \$(GST_STATIC_CFLAGS) \$(GST_OPTION_CFLAGS)"
 272 AC_SUBST(GST_CFLAGS)
 273 AC_SUBST(GST_LIBS)
 274
 275 dnl GST_ALL_*
 276 dnl vars common to for all internal objects (core libs, elements, applications)
 277 dnl CFLAGS:
 278 dnl - src and build dirs need to be added because every piece that gets built
 279 dnl   will need the GStreamer source and generated headers
 280 GST_ALL_CFLAGS="-I\$(top_srcdir) -I\$(top_builddir) $GST_PLUGINS_BASE_CFLAGS $GST_CFLAGS \$(GST_OPTION_CFLAGS)"
 281 AC_SUBST([GST_ALL_CFLAGS])
 282
 283 dnl FIXME: check if LTLIBINTL is needed everywhere
 284 dnl I presume it is given that it contains the symbols that _() stuff maps to
 285 GST_ALL_LIBS="$GST_LIBS $LTLIBINTL \$(GCOV_LIBS)"
 286 AC_SUBST([GST_ALL_LIBS])
 287
 288 dnl LDFLAGS really should only contain flags, not libs - they get added before
 289 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 290 GST_ALL_LDFLAGS="-no-undefined"
 291 if test "x${enable_Bsymbolic}" = "xyes"; then
 292   GST_ALL_LDFLAGS="$GST_ALL_LDFLAGS -Wl,-Bsymbolic-functions"
 293 fi
 294
 295 AC_SUBST(GST_ALL_LDFLAGS)
 296
 297 dnl GST_LIB_LDFLAGS
 298 dnl linker flags shared by all libraries
 299 dnl LDFLAGS modifier defining exported symbols from built libraries
 300 GST_LIB_LDFLAGS="-export-symbols-regex \^[_]?\(gst_\|Gst\|GST_\).*"
 301 AC_SUBST(GST_LIB_LDFLAGS)
 302
 303 dnl GST_OBJ_*
 304 dnl default vars for all internal objects built on libgstrtspserver
 305 dnl includes GST_ALL_*
 306 GST_OBJ_CFLAGS="\$(GST_ALL_CFLAGS)"
 307 AC_SUBST([GST_OBJ_CFLAGS])
 308 GST_OBJ_LIBS="\$(top_builddir)/gst/rtsp-server/libgstrtspserver-$GST_API_VERSION.la \$(GST_ALL_LIBS)"
 309 AC_SUBST([GST_OBJ_LIBS])
 310
 311 dnl build static plugins or not
 312 AC_MSG_CHECKING([whether to build static plugins or not])
 313 AC_ARG_ENABLE(
 314   static-plugins,
 315   AC_HELP_STRING(
 316     [--enable-static-plugins],
 317     [build static plugins @<:@default=no@:>@]),
 318   [AS_CASE(
 319     [$enableval], [no], [], [yes], [],
 320     [AC_MSG_ERROR([bad value "$enableval" for --enable-static-plugins])])],
 321   [enable_static_plugins=no])
 322 AC_MSG_RESULT([$enable_static_plugins])
 323 if test "x$enable_static_plugins" = xyes; then
 324   AC_DEFINE(GST_PLUGIN_BUILD_STATIC, 1,
 325     [Define if static plugins should be built])
 326   GST_PLUGIN_LIBTOOLFLAGS=""
 327 else
 328   GST_PLUGIN_LIBTOOLFLAGS="--tag=disable-static"
 329 fi
 330 AC_SUBST(GST_PLUGIN_LIBTOOLFLAGS)
 331 AM_CONDITIONAL(GST_PLUGIN_BUILD_STATIC, test "x$enable_static_plugins" = "xyes")
 332
 333 dnl If only building static libraries, define GST_STATIC_COMPILATION. This is
 334 dnl needed only on Windows, but it doesn't hurt to have it everywhere.
 335 if test x$enable_static = xyes -a x$enable_shared = xno; then
 336   GST_STATIC_CFLAGS="-DGST_STATIC_COMPILATION"
 337 fi
 338 AC_SUBST(GST_STATIC_CFLAGS)
 339
 340 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_.*' $GST_ALL_LDFLAGS"
 341 AC_SUBST(GST_PLUGIN_LDFLAGS)
 342
 343 PKG_CHECK_MODULES(LIBCGROUP, libcgroup >= 0.26, HAVE_LIBCGROUP="yes", HAVE_LIBCGROUP="no")
 344 AC_SUBST(LIBCGROUP_CFLAGS)
 345 AC_SUBST(LIBCGROUP_LIBS)
 346 AM_CONDITIONAL(HAVE_LIBCGROUP, test "x$HAVE_LIBCGROUP" = "xyes")
 347
 348 dnl this really should only contain flags, not libs - they get added before
 349 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 350
 351 dnl *** output files ***
 352
 353 dnl keep this alphabetic per directory, please
 354 AC_CONFIG_FILES([
 355 Makefile
 356 gst-rtsp.spec
 357 common/Makefile
 358 common/m4/Makefile
 359 gst/Makefile
 360 gst/rtsp-server/Makefile
 361 gst/rtsp-sink/Makefile
 362 examples/Makefile
 363 tests/Makefile
 364 tests/check/Makefile
 365 pkgconfig/Makefile
 366 pkgconfig/gstreamer-rtsp-server.pc
 367 pkgconfig/gstreamer-rtsp-server-uninstalled.pc
 368 docs/Makefile
 369 docs/version.entities
 370 docs/libs/Makefile
 371 ])
 372 AC_OUTPUT
 373
 374 echo "
 375
 376 Configuration
 377         Version                    : ${VERSION}
 378         Source code location       : ${srcdir}
 379         Prefix                     : ${prefix}
 380         Compiler                   : ${CC}
 381         CGroups example            : ${HAVE_LIBCGROUP}
 382
 383 gst-rtsp-server configured. Type 'make' to build.
 384 "