configure.ac

   1 AC_PREREQ(2.60)
   2
   3 dnl initialize autoconf
   4 dnl when going to/from release please set the nano (fourth number) right !
   5 dnl releases only do Wall, git and prerelease does Werror too
   6 AC_INIT(GStreamer, 0.11.89.1,
   7     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
   8     gstreamer)
   9 AG_GST_INIT
  10
  11 dnl initialize automake (we require GNU make)
  12 AM_INIT_AUTOMAKE([-Wno-portability 1.10])
  13
  14 dnl define PACKAGE_VERSION_* variables
  15 AS_VERSION
  16
  17 dnl check if this is a release version
  18 AS_NANO(GST_GIT="no", GST_GIT="yes")
  19
  20 dnl can autoconf find the source ?
  21 AC_CONFIG_SRCDIR([gst/gst.c])
  22
  23 dnl define the output header for config
  24 AM_CONFIG_HEADER([config.h])
  25
  26 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  27 AM_MAINTAINER_MODE
  28
  29 dnl sets host_* variables
  30 AC_CANONICAL_HOST
  31
  32 dnl use pretty build output with automake >= 1.11
  33 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],
  34   [AM_DEFAULT_VERBOSITY=1
  35    AC_SUBST(AM_DEFAULT_VERBOSITY)])
  36
  37 dnl GStreamer versioning, this is mostly informational
  38 dnl GST_VERSION_MAJOR=$PACKAGE_VERSION_MAJOR
  39 dnl GST_VERSION_MINOR=$PACKAGE_VERSION_MINOR
  40 dnl GST_VERSION_MICRO=$PACKAGE_VERSION_MICRO
  41 dnl GST_VERSION_NANO=$PACKAGE_VERSION_NANO
  42 dnl Change this to the above for non-pre
  43 GST_VERSION_MAJOR=1
  44 GST_VERSION_MINOR=0
  45 GST_VERSION_MICRO=0
  46 GST_VERSION_NANO=0
  47 AC_SUBST(GST_VERSION_MAJOR)
  48 AC_SUBST(GST_VERSION_MINOR)
  49 AC_SUBST(GST_VERSION_MICRO)
  50 AC_SUBST(GST_VERSION_NANO)
  51
  52 dnl our libraries and install dirs use GST_API_VERSION in the filename
  53 dnl to allow side-by-side installation of different API versions
  54 GST_API_VERSION=1.0
  55 AC_SUBST(GST_API_VERSION)
  56 AC_DEFINE_UNQUOTED(GST_API_VERSION, "$GST_API_VERSION",
  57   [GStreamer API Version])
  58
  59 dnl CURRENT, REVISION, AGE
  60 dnl - library source changed -> increment REVISION
  61 dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
  62 dnl - interfaces added -> increment AGE
  63 dnl - interfaces removed -> AGE = 0
  64 dnl sets GST_LT_LDFLAGS
  65 AS_LIBTOOL(GST, 0, 0, 0)
  66
  67 dnl FIXME: this macro doesn't actually work;
  68 dnl the generated libtool script has no support for the listed tags.
  69 dnl So this needs to be fixed first if we want to use this
  70 dnl AS_LIBTOOL_TAGS
  71
  72 AC_LIBTOOL_WIN32_DLL
  73 AM_PROG_LIBTOOL
  74
  75 dnl *** autotools stuff ****
  76
  77 dnl allow for different autotools
  78 AS_AUTOTOOLS_ALTERNATE
  79
  80 dnl Add parameters for aclocal (keep in sync with Makefile.am)
  81 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  82
  83 dnl set up gettext
  84 dnl the version check needs to stay here because autopoint greps for it
  85 AM_GNU_GETTEXT_VERSION([0.17])
  86 AM_GNU_GETTEXT([external])
  87 AG_GST_GETTEXT([gstreamer-$GST_API_VERSION])
  88
  89 dnl *** check for arguments to configure ***
  90
  91 AG_GST_ARG_DISABLE_FATAL_WARNINGS
  92
  93 dnl subsystems - can influence other decisions so needs to be high up
  94 dnl we need to AM_CONDITIONAL them here for automake 1.6.x compatibility
  95 AG_GST_CHECK_SUBSYSTEM_DISABLE(GST_DEBUG,[debugging subsystem])
  96 AM_CONDITIONAL(GST_DISABLE_GST_DEBUG, test "x$GST_DISABLE_GST_DEBUG" = "xyes")
  97 AG_GST_CHECK_SUBSYSTEM_DISABLE(PARSE,[command-line parser])
  98 AM_CONDITIONAL(GST_DISABLE_PARSE, test "x$GST_DISABLE_PARSE" = "xyes")
  99 if test "x$GST_DISABLE_PARSE" = xyes; then
 100   AC_DEFINE(GST_DISABLE_PARSE, 1,
 101     [Define if pipeline parsing code is disabled])
 102 fi
 103 AG_GST_CHECK_SUBSYSTEM_DISABLE(OPTION_PARSING,[option parsing when gst_init])
 104 AM_CONDITIONAL(GST_DISABLE_OPTION_PARSING, test "x$GST_DISABLE_OPTION_PARSING" = "xyes")
 105 if test "x$GST_DISABLE_OPTION_PARSING" = xyes; then
 106   AC_DEFINE(GST_DISABLE_OPTION_PARSING, 1,
 107     [Define if option parsing is disabled])
 108 fi
 109 AG_GST_CHECK_SUBSYSTEM_DISABLE(TRACE,[tracing subsystem])
 110 AM_CONDITIONAL(GST_DISABLE_TRACE, test "x$GST_DISABLE_TRACE" = "xyes")
 111 AG_GST_CHECK_SUBSYSTEM_DISABLE(ALLOC_TRACE,[allocation tracing])
 112 AM_CONDITIONAL(GST_DISABLE_ALLOC_TRACE, test "x$GST_DISABLE_ALLOC_TRACE" = "xyes")
 113 AG_GST_CHECK_SUBSYSTEM_DISABLE(REGISTRY,[plugin registry])
 114 AM_CONDITIONAL(GST_DISABLE_REGISTRY, test "x$GST_DISABLE_REGISTRY" = "xyes")
 115 dnl define a substitution to use in docs/gst/gstreamer.types
 116 if test "x$GST_DISABLE_REGISTRY" = "xyes"
 117 then
 118   GST_REGISTRY_DOC_TYPES="%"
 119 else
 120   GST_REGISTRY_DOC_TYPES=
 121 fi
 122 AC_SUBST(GST_REGISTRY_DOC_TYPES)
 123 AG_GST_CHECK_SUBSYSTEM_DISABLE(PLUGIN,[plugin])
 124 AM_CONDITIONAL(GST_DISABLE_PLUGIN, test "x$GST_DISABLE_PLUGIN" = "xyes")
 125
 126 AG_GST_ARG_DEBUG
 127 AG_GST_ARG_PROFILING
 128 AG_GST_ARG_VALGRIND
 129 AG_GST_ARG_GCOV
 130
 131 AG_GST_ARG_EXAMPLES
 132
 133 AG_GST_ARG_WITH_PKG_CONFIG_PATH
 134 AG_GST_ARG_WITH_PACKAGE_NAME
 135 AG_GST_ARG_WITH_PACKAGE_ORIGIN
 136
 137 AG_GST_PKG_CONFIG_PATH
 138
 139 AG_GST_SET_PACKAGE_RELEASE_DATETIME_WITH_NANO([$PACKAGE_VERSION_NANO],
 140   ["${srcdir}/gstreamer.doap"],
 141   [$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_MICRO])
 142
 143 dnl building of tests
 144 AC_ARG_ENABLE(tests,
 145   AC_HELP_STRING([--disable-tests], [disable building test apps]),
 146   [
 147     case "${enableval}" in
 148       yes) BUILD_TESTS=yes ;;
 149       no)  BUILD_TESTS=no ;;
 150       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-tests) ;;
 151     esac
 152   ],
 153 [BUILD_TESTS=yes]) dnl Default value
 154 AM_CONDITIONAL(BUILD_TESTS,         test "x$BUILD_TESTS" = "xyes")
 155
 156 dnl tests known to fail
 157 AC_ARG_ENABLE(failing-tests,
 158   AC_HELP_STRING([--disable-failing-tests],
 159     [disable building tests known to fail]),
 160   [
 161     case "${enableval}" in
 162       yes) BUILD_FAILING_TESTS=yes ;;
 163       no)  BUILD_FAILING_TESTS=no ;;
 164       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-failing-tests) ;;
 165     esac
 166   ],
 167   [BUILD_FAILING_TESTS=no]) dnl Default value
 168 AM_CONDITIONAL(BUILD_FAILING_TESTS, test "x$BUILD_FAILING_TESTS" = "xyes")
 169 if test x$BUILD_FAILING_TESTS = xyes; then
 170   AC_MSG_WARN([building tests known to fail, use --disable-failing-tests to disable])
 171 else
 172   AC_MSG_WARN([Sissy ! By asking to not build the tests known to fail, you hereby waive your right to customer support.  If you do not agree with this EULA, please press Ctrl-C before the next line is printed.  By allowing the next line to be printed, you expressly acknowledge your acceptance of this EULA.])
 173 fi
 174
 175 dnl poison destroyed objects
 176 AC_ARG_ENABLE(poisoning,
 177   AC_HELP_STRING([--enable-poisoning],
 178     [enable poisoning of deallocated objects]),
 179   [
 180     case "${enableval}" in
 181       yes) USE_POISONING=yes ;;
 182       no)  USE_POISONING=no ;;
 183       *)   AC_MSG_ERROR(bad value ${enableval} for --enable-poisoning) ;;
 184     esac
 185   ],
 186   [USE_POISONING=no]) dnl Default value
 187 if test "x$USE_POISONING" = xyes; then
 188   AC_DEFINE(USE_POISONING, 1,
 189     [Define if we should poison deallocated memory])
 190 fi
 191
 192 dnl *** checks for platform ***
 193
 194 dnl * hardware/architecture *
 195
 196 dnl common/m4/gst-arch.m4
 197 dnl check CPU type
 198 AG_GST_ARCH
 199 dnl substitution for win32/common/config.h
 200 HOST_CPU=$host_cpu
 201 AC_SUBST(HOST_CPU)
 202
 203 dnl common/m4/gst-arch.m4
 204 dnl check for unaligned access
 205 AG_GST_UNALIGNED_ACCESS
 206 dnl create a configure variable for gst/gstconfig.h
 207 if test x${as_cv_unaligned_access} = xyes ; then
 208   GST_HAVE_UNALIGNED_ACCESS_DEFINE="#define GST_HAVE_UNALIGNED_ACCESS 1"
 209 else
 210   GST_HAVE_UNALIGNED_ACCESS_DEFINE="#define GST_HAVE_UNALIGNED_ACCESS 0"
 211 fi
 212 AC_SUBST(GST_HAVE_UNALIGNED_ACCESS_DEFINE)
 213
 214 dnl check for platform specific settings
 215 AG_GST_PLATFORM
 216
 217 dnl * software *
 218
 219 dnl check for large file support
 220 dnl affected plugins must include config.h
 221 AC_SYS_LARGEFILE
 222
 223 dnl *** checks for programs ***
 224
 225 dnl find a compiler
 226 AC_PROG_CC
 227 AC_PROG_CC_STDC
 228
 229 dnl check if the compiler supports '-c' and '-o' options
 230 AM_PROG_CC_C_O
 231
 232 dnl find an assembler
 233 AM_PROG_AS
 234
 235 dnl determine if c++ is available on this system
 236 AC_PROG_CXX
 237 dnl CXX may be set to some default even if no c++ compiler is available
 238 dnl (thanks autotools!), so just try to compile some c++ code to make sure
 239 AC_LANG_PUSH([C++])
 240 AC_TRY_COMPILE([ class Foo { int bar; };], , working_cxx=yes, working_cxx=no)
 241 AC_LANG_POP([C++])
 242 AC_MSG_NOTICE([working c++ compiler found: $working_cxx])
 243 AM_CONDITIONAL(HAVE_CXX, test "x$working_cxx" = "xyes")
 244
 245 dnl Perl is used in building documentation and in the version checks
 246 AC_PATH_PROG(PERL_PATH, perl, no)
 247 if test x$PERL_PATH = xno; then
 248   AC_MSG_ERROR(Could not find perl)
 249 fi
 250
 251 dnl we require flex and bison for building the parser
 252 if test "x$GST_DISABLE_PARSE" != xyes; then
 253   AG_GST_BISON_CHECK
 254   AG_GST_FLEX_CHECK
 255 fi
 256
 257 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 258 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 259
 260 dnl check for gobject-introspection
 261 GOBJECT_INTROSPECTION_CHECK([1.31.1])
 262
 263 dnl check for documentation tools
 264 AG_GST_DOCBOOK_CHECK
 265 GTK_DOC_CHECK([1.3])
 266 AS_PATH_PYTHON([2.1])
 267 AG_GST_PLUGIN_DOCS([1.3],[2.1])
 268
 269 dnl *** checks for libraries ***
 270
 271 dnl check for libm, for sin()
 272 AC_CHECK_LIBM
 273 AC_SUBST(LIBM)
 274
 275 dnl *** checks for header files ***
 276
 277 dnl check if we have ANSI C header files
 278 AC_HEADER_STDC
 279
 280 dnl Check for ucontext.h
 281 AC_CHECK_HEADERS([ucontext.h])
 282
 283 dnl Check for sys/socket.h
 284 AC_CHECK_HEADERS([sys/socket.h], HAVE_SYS_SOCKET_H=yes)
 285 AM_CONDITIONAL(HAVE_SYS_SOCKET_H, test "x$HAVE_SYS_SOCKET_H" = "xyes")
 286
 287 dnl check for sys/times.h for tests/examples/adapter/
 288 AC_CHECK_HEADERS([sys/times.h], HAVE_SYS_TIMES_H=yes)
 289 AC_CHECK_HEADERS([unistd.h], HAVE_UNISTD_H=yes)
 290 AM_CONDITIONAL(HAVE_SYS_TIMES_H_AND_UNISTD_H, test "x$HAVE_SYS_TIMES_H" = "xyes" -a "x$HAVE_UNISTD_H" = "xyes")
 291
 292 dnl Check for process.h for getpid() on win32
 293 AC_CHECK_HEADERS([process.h])
 294
 295 dnl Check for sys/utsname.h for uname
 296 AC_CHECK_HEADERS([sys/utsname.h])
 297
 298 dnl Check for stdio_ext.f for __fbufsize
 299 AC_CHECK_HEADERS([stdio_ext.h])
 300
 301 dnl check for pthreads
 302 AC_CHECK_HEADERS([pthread.h], HAVE_PTHREAD_H=yes)
 303 AM_CONDITIONAL(HAVE_PTHREAD_H, test "x$HAVE_PTHREAD_H" = "xyes")
 304
 305 dnl check for sys/prctl for setting thread name on Linux
 306 AC_CHECK_HEADERS([sys/prctl.h], HAVE_SYS_PRCTL_H=yes)
 307
 308 dnl Check for valgrind.h
 309 dnl separate from HAVE_VALGRIND because you can have the program, but not
 310 dnl the dev package
 311 AC_CHECK_HEADERS([valgrind/valgrind.h], HAVE_VALGRIND_H=yes)
 312
 313 dnl used in gst/gstpoll.c
 314 AC_CHECK_HEADERS([winsock2.h], HAVE_WINSOCK2_H=yes)
 315 AM_CONDITIONAL(HAVE_WINSOCK2_H, test "x$HAVE_WINSOCK2_H" = "xyes")
 316 if test "x$HAVE_WINSOCK2_H" = "xyes"; then
 317   WIN32_LIBS="-lws2_32"
 318   AC_SUBST(WIN32_LIBS)
 319 fi
 320
 321 dnl check for GMP/GSL, used by the gst_util_uint64_scale unit test only
 322 if test "x$BUILD_TESTS" = "xyes"; then
 323   AG_GST_CHECK_LIBHEADER(GMP, gmp,
 324                          __gmpz_init_set_d, ,
 325                          gmp.h,
 326                          GMP_LIBS="-lgmp"
 327                          AC_SUBST(GMP_LIBS)
 328                          AC_DEFINE(HAVE_GMP, [1],[Have GMP library]))
 329   AG_GST_CHECK_LIBHEADER(GSL, gsl,
 330                          gsl_rng_uniform_int, -lgslcblas,
 331                          gsl/gsl_rng.h,
 332                          GSL_LIBS="-lgsl -lgslcblas"
 333                          AC_SUBST(GSL_LIBS)
 334                          AC_DEFINE(HAVE_GSL, [1],[Have GSL library]))
 335 fi
 336
 337 dnl *** checks for types/defines ***
 338
 339 dnl *** checks for structures ***
 340
 341 dnl *** checks for compiler characteristics ***
 342
 343 dnl check if the compiler supports __uint128_t (gcc)
 344 dnl Actually check for 128-bit division, since that's what we use
 345 dnl uint128_t for.
 346 AC_CACHE_CHECK(for __uint128_t, gst_cv_uint128_t,
 347     AC_TRY_LINK([ ], [
 348       static __uint128_t v1 = 100;
 349       static __uint128_t v2 = 10;
 350       static __uint128_t u;
 351       u = v1 / v2;
 352     ], [
 353       gst_cv_uint128_t=yes
 354     ], [
 355       gst_cv_uint128_t=no
 356     ])
 357 )
 358 if test x$gst_cv_uint128_t = xyes; then
 359   AC_DEFINE(HAVE_UINT128_T, 1, [Have __uint128_t type])
 360 fi
 361
 362 dnl *** checking for tm_gmtoff ***
 363 AC_MSG_CHECKING([for tm_gmtoff])
 364 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 365         #include <time.h>
 366         int main(void) {
 367           struct tm t;
 368           t.tm_gmtoff = 0;
 369           exit(0);
 370         }]])],
 371   [have_tm_gmtoff=yes
 372    AC_DEFINE(HAVE_TM_GMTOFF,1,[Have tm_gmtoff field in struct tm])],
 373   [have_tm_gmtoff=no],
 374   [have_tm_gmtoff="no (cross compiling)"])
 375 AC_MSG_RESULT($have_tm_gmtoff)
 376
 377
 378 dnl *** checks for library functions ***
 379
 380 AC_CHECK_FUNCS([gmtime_r])
 381 AC_CHECK_FUNCS([localtime_r])
 382 AC_CHECK_FUNCS([sigaction])
 383
 384 dnl check for fseeko()
 385 AC_FUNC_FSEEKO
 386 dnl check for ftello()
 387 AC_CHECK_FUNCS([ftello])
 388
 389 AC_CHECK_FUNCS([fgetpos])
 390 AC_CHECK_FUNCS([fsetpos])
 391
 392 dnl check for poll(), ppoll() and pselect()
 393 AC_CHECK_FUNCS([poll])
 394 AC_CHECK_FUNCS([ppoll])
 395 AC_CHECK_FUNCS([pselect])
 396
 397 AC_CHECK_HEADERS([sys/poll.h])
 398
 399 dnl ****************************************
 400 dnl *** GLib POLL* compatibility defines ***
 401 dnl ****************************************
 402
 403 AC_MSG_CHECKING([for broken poll])
 404 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 405         #include <stdlib.h>
 406         #include <fcntl.h>
 407         #include <poll.h>
 408         #ifdef HAVE_SYS_POLL_H
 409         #include <sys/poll.h>
 410         #endif
 411         int main(void) {
 412           struct pollfd fds[1];
 413           int fd;
 414           fd = open("/dev/null", 1);
 415           fds[0].fd = fd;
 416           fds[0].events = POLLIN;
 417           fds[0].revents = 0;
 418           if (poll(fds, 1, 0) < 0 || (fds[0].revents & POLLNVAL) != 0) {
 419                 exit(1);  /* Does not work for devices -- fail */
 420           }
 421           exit(0);
 422         }]])],
 423   [broken_poll=no],
 424   [broken_poll=yes
 425    AC_DEFINE(BROKEN_POLL,1,[poll doesn't work on devices])],
 426   [broken_poll="no (cross compiling)"])
 427 AC_MSG_RESULT($broken_poll)
 428
 429 dnl check for mmap()
 430 AC_FUNC_MMAP
 431 AM_CONDITIONAL(HAVE_MMAP, test "x$ac_cv_func_mmap_fixed_mapped" = "xyes")
 432
 433 dnl check for posix_memalign(), getpagesize()
 434 AC_CHECK_FUNCS([posix_memalign])
 435 AC_CHECK_FUNCS([getpagesize])
 436
 437 dnl Check for POSIX timers
 438 AC_CHECK_FUNCS(clock_gettime, [], [
 439   AC_CHECK_LIB(rt, clock_gettime, [
 440     AC_DEFINE(HAVE_CLOCK_GETTIME, 1)
 441     LIBS="$LIBS -lrt"
 442   ])
 443 ])
 444
 445 AC_CACHE_CHECK(for posix timers, gst_cv_posix_timers,
 446     AC_TRY_COMPILE([
 447 #include <time.h>
 448 #ifdef HAVE_UNISTD_H
 449 #include <unistd.h>
 450 #endif
 451     ], [
 452 #if !defined(_POSIX_TIMERS) || _POSIX_TIMERS < 0 || !defined(CLOCK_REALTIME)
 453 #error Either _POSIX_TIMERS or CLOCK_REALTIME not defined
 454 #endif
 455     ], [
 456       gst_cv_posix_timers=yes
 457     ], [
 458       gst_cv_posix_timers=no
 459     ])
 460 )
 461
 462 if test "$gst_cv_posix_timers" = "yes"; then
 463   AC_DEFINE(HAVE_POSIX_TIMERS,1,[Have posix timers])
 464   GST_HAVE_POSIX_TIMERS_DEFINE="#define GST_HAVE_POSIX_TIMERS 1"
 465 else
 466   GST_HAVE_POSIX_TIMERS_DEFINE="#define GST_HAVE_POSIX_TIMERS 0"
 467 fi
 468 AC_SUBST(GST_HAVE_POSIX_TIMERS_DEFINE)
 469 AM_CONDITIONAL(GST_HAVE_POSIX_TIMERS, test "$gst_cv_posix_timers" = "yes")
 470
 471 AC_CACHE_CHECK(for monotonic clock, gst_cv_monotonic_clock,
 472     AC_TRY_COMPILE([
 473 #include <time.h>
 474 #ifdef HAVE_UNISTD_H
 475 #include <unistd.h>
 476 #endif
 477     ], [
 478 #if !defined(_POSIX_MONOTONIC_CLOCK) || _POSIX_MONOTONIC_CLOCK < 0 || !defined(CLOCK_MONOTONIC)
 479 #error Either _POSIX_MONOTONIC_CLOCK or CLOCK_MONOTONIC not defined
 480 #endif
 481     ], [
 482       gst_cv_monotonic_clock=yes
 483     ], [
 484       gst_cv_monotonic_clock=no
 485     ])
 486 )
 487
 488 if test "$gst_cv_monotonic_clock" = "yes"; then
 489   AC_DEFINE(HAVE_MONOTONIC_CLOCK,1,[Have a monotonic clock])
 490   GST_HAVE_MONOTONIC_CLOCK_DEFINE="#define GST_HAVE_MONOTONIC_CLOCK 1"
 491 else
 492   GST_HAVE_MONOTONIC_CLOCK_DEFINE="#define GST_HAVE_MONOTONIC_CLOCK 0"
 493 fi
 494 AC_SUBST(GST_HAVE_MONOTONIC_CLOCK_DEFINE)
 495 AM_CONDITIONAL(GST_HAVE_MONOTONIC_CLOCK, test "$gst_cv_monotonic_clock" = "yes")
 496
 497 dnl Check for a way to display the function name in debug output
 498 AG_GST_CHECK_FUNCTION
 499
 500 dnl test for register_printf_specifier or register_printf_function
 501 AC_CHECK_FUNCS([register_printf_specifier register_printf_function],
 502     [HAVE_PRINTF_EXTENSION=yes])
 503
 504 if test "$HAVE_PRINTF_EXTENSION" = yes; then
 505   GST_PRINTF_EXTENSION_POINTER_FORMAT_DEFINE="#define GST_PTR_FORMAT \"P\""
 506   GST_PRINTF_EXTENSION_SEGMENT_FORMAT_DEFINE="#define GST_SEGMENT_FORMAT \"Q\""
 507   GST_USING_PRINTF_EXTENSION_DEFINE="#define GST_USING_PRINTF_EXTENSION"
 508   AC_DEFINE(HAVE_PRINTF_EXTENSION, 1,
 509       [Defined if we have printf specifier extensions available])
 510 else
 511     GST_PRINTF_EXTENSION_POINTER_FORMAT_DEFINE="#define GST_PTR_FORMAT \"p\""
 512     GST_PRINTF_EXTENSION_SEGMENT_FORMAT_DEFINE="#define GST_SEGMENT_FORMAT \"p\""
 513     GST_USING_PRINTF_EXTENSION_DEFINE="#undef GST_USING_PRINTF_EXTENSION"
 514 fi
 515 AC_SUBST(GST_PRINTF_EXTENSION_POINTER_FORMAT_DEFINE)
 516 AC_SUBST(GST_PRINTF_EXTENSION_SEGMENT_FORMAT_DEFINE)
 517 AC_SUBST(GST_USING_PRINTF_EXTENSION_DEFINE)
 518
 519 dnl test if we have dladdr(); we use it for debugging; see gst/gstinfo.c
 520 save_cflags="$CFLAGS"
 521 CFLAGS="$CFLAGS -D_GNU_SOURCE"
 522 AC_CHECK_LIB(dl, dladdr,
 523    AC_DEFINE(HAVE_DLADDR, 1, [Defined if we have dladdr ()])
 524    LIBS="$LIBS -ldl")
 525 CFLAGS="$save_cflags"
 526
 527 dnl *** checks for dependency libraries ***
 528
 529 dnl GLib
 530 GLIB_REQ=2.31.14
 531 AG_GST_GLIB_CHECK([$GLIB_REQ])
 532
 533 dnl Check for documentation xrefs
 534 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 535 AC_SUBST(GLIB_PREFIX)
 536
 537 dnl building of unit test libraries
 538 AC_ARG_ENABLE(check,
 539   AC_HELP_STRING([--disable-check], [disable building unit test libraries]),
 540   [
 541     case "${enableval}" in
 542       yes) BUILD_CHECK=yes ;;
 543       no)  BUILD_CHECK=no ;;
 544       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-check) ;;
 545     esac
 546   ], [
 547     dnl Default value
 548     case $host_os in
 549       mingw* | msvc* | mks*) BUILD_CHECK=no ;;
 550       *) BUILD_CHECK=yes ;;
 551     esac
 552 ])
 553 dnl bit of a misnomer, but keep the conditional named like this so we don't
 554 dnl have to change too much elsewhere
 555 AM_CONDITIONAL(HAVE_CHECK, test "x$BUILD_CHECK" = "xyes")
 556
 557 dnl configure the desired memory alignment
 558 AC_ARG_WITH([memory-alignment],
 559   AS_HELP_STRING([--with-memory-alignment],[8,N,malloc,pagesize (default is 32)]),
 560   [
 561     if test "x$withval" = "xyes"
 562     then
 563       AC_DEFINE(MEMORY_ALIGNMENT, 32, [Memory alignment to use])
 564     else
 565       case "${withval}" in
 566         malloc) AC_DEFINE(MEMORY_ALIGNMENT_MALLOC, 1, [Memory alignment by malloc default]) ;;
 567         pagesize)  AC_DEFINE(MEMORY_ALIGNMENT_PAGESIZE, 1, [Memory alignment by pagesize]) ;;
 568         *)   AC_DEFINE_UNQUOTED(MEMORY_ALIGNMENT, ${withval}, [Memory alignment to use]) ;;
 569       esac
 570     fi
 571   ], [
 572     AC_DEFINE(MEMORY_ALIGNMENT_MALLOC, 1, [Memory alignment by malloc default])
 573   ]
 574 )
 575
 576 dnl Check for -Bsymbolic-functions linker flag used to avoid
 577 dnl intra-library PLT jumps, if available.
 578 AC_ARG_ENABLE(Bsymbolic,
 579               [AC_HELP_STRING([--disable-Bsymbolic],
 580                               [avoid linking with -Bsymbolic])],,
 581               [SAVED_LDFLAGS="${LDFLAGS}"
 582                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
 583                LDFLAGS=-Wl,-Bsymbolic-functions
 584                AC_TRY_LINK([], [int main (void) { return 0; }],
 585                            AC_MSG_RESULT(yes)
 586                            enable_Bsymbolic=yes,
 587                            AC_MSG_RESULT(no)
 588                            enable_Bsymbolic=no)
 589                LDFLAGS="${SAVED_LDFLAGS}"])
 590
 591
 592 dnl *** set variables based on configure arguments
 593
 594 dnl set license and copyright notice
 595 GST_LICENSE="LGPL"
 596 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 597 AC_SUBST(GST_LICENSE)
 598
 599 dnl define LIBDIR, GST_DATADIR so we can inform people where we live
 600 AS_AC_EXPAND(LIBDIR, $libdir)
 601 AC_DEFINE_UNQUOTED(LIBDIR, "$LIBDIR", [library dir])
 602 AS_AC_EXPAND(DATADIR, $datadir)
 603 AC_DEFINE_UNQUOTED(GST_DATADIR, "$DATADIR", [data dir])
 604
 605 dnl set location of plugin directory
 606 AG_GST_SET_PLUGINDIR
 607
 608 GST_PKG_DEPS="glib-2.0, gobject-2.0, gmodule-no-export-2.0, gthread-2.0"
 609 AC_SUBST(GST_PKG_DEPS)
 610
 611 dnl make sure it doesn't complain about unused variables if debugging is disabled
 612 NO_WARNINGS=""
 613 if test "x${GST_DISABLE_GST_DEBUG}" = "xyes"; then
 614   NO_WARNINGS="-Wno-unused"
 615 fi
 616
 617 dnl define an ERROR_CFLAGS Makefile variable
 618 AG_GST_SET_ERROR_CFLAGS($FATAL_WARNINGS, [-Wmissing-declarations -Wmissing-prototypes -Wredundant-decls -Wundef -Wwrite-strings -Wformat-nonliteral -Wformat-security -Wold-style-definition -Winit-self -Wmissing-include-dirs -Waddress -Waggregate-return -Wno-multichar -Wnested-externs $NO_WARNINGS])
 619
 620 dnl define correct level for debugging messages
 621 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 622
 623 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 624
 625 dnl Overview:
 626 dnl GST_OPTION_CFLAGS:  common cflags for profiling, debugging, errors, ...
 627 dnl GST_ALL_*:          vars shared by all built objects
 628 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 629 dnl GST_OBJ_*:          additional vars to link to the core library
 630 dnl                     include GST_ALL_*
 631 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 632 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 633
 634 dnl GST_OPTION_CFLAGS
 635 if test "x$USE_DEBUG" = xyes; then
 636    PROFILE_CFLAGS="-g"
 637 fi
 638 AC_SUBST(PROFILE_CFLAGS)
 639
 640 # GST_DISABLE_DEPRECATED: hide the visibility of deprecated
 641 # functionality from the API that gstreamer uses
 642 # GST_REMOVE_DEPRECATED: don't compile deprecated functionality (breaks ABI)
 643 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
 644   dnl Define _only_ when compiling from git (not for pre-releases or releases)
 645   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 646 else
 647   DEPRECATED_CFLAGS=""
 648 fi
 649 AC_SUBST(DEPRECATED_CFLAGS)
 650
 651 dnl every flag in GST_OPTION_CFLAGS can be overridden at make time via e.g.
 652 dnl make DEPRECATED_CFLAGS=''
 653 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 654 GST_OPTION_CXXFLAGS="\$(WARNING_CXXFLAGS) \$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 655 GST_OPTION_CFLAGS="$GST_OPTION_CFLAGS -DGST_USE_UNSTABLE_API"
 656 GST_OPTION_CXXFLAGS="$GST_OPTION_CXXFLAGS -DGST_USE_UNSTABLE_API"
 657 AC_SUBST(GST_OPTION_CFLAGS)
 658 AC_SUBST(GST_OPTION_CXXFLAGS)
 659
 660 dnl GST_ALL_*
 661 dnl vars common to for all internal objects (core libs, elements, applications)
 662 dnl CFLAGS:
 663 dnl - src and build dirs need to be added because every piece that gets built
 664 dnl   will need the GStreamer source and generated headers
 665 dnl LIBS: XML doesn't need to be added because we don't explicitly use symbols
 666 dnl       from LibXML except for in the core library
 667 GST_ALL_CXXFLAGS="-I\$(top_srcdir)/libs -I\$(top_srcdir) -I\$(top_builddir)/libs -I\$(top_builddir) $GLIB_CFLAGS \$(GLIB_EXTRA_CFLAGS) $XML_CFLAGS \$(GST_OPTION_CXXFLAGS) \$(ERROR_CXXFLAGS)"
 668 GST_ALL_CFLAGS="-I\$(top_srcdir)/libs -I\$(top_srcdir) -I\$(top_builddir)/libs -I\$(top_builddir) $GLIB_CFLAGS \$(GLIB_EXTRA_CFLAGS) $XML_CFLAGS \$(GST_OPTION_CFLAGS) \$(ERROR_CFLAGS)"
 669
 670 dnl FIXME: check if LTLIBINTL is needed everywhere
 671 dnl I presume it is given that it contains the symbols that _() stuff maps to
 672 GST_ALL_LIBS="$GLIB_LIBS $LTLIBINTL \$(GCOV_LIBS)"
 673
 674 dnl LDFLAGS really should only contain flags, not libs - they get added before
 675 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 676 GST_ALL_LDFLAGS="-no-undefined"
 677 if test "x${enable_Bsymbolic}" = "xyes"; then
 678   GST_ALL_LDFLAGS="$GST_ALL_LDFLAGS -Wl,-Bsymbolic-functions"
 679 fi
 680
 681 AC_SUBST(GST_ALL_CFLAGS)
 682 AC_SUBST(GST_ALL_CXXFLAGS)
 683 AC_SUBST(GST_ALL_LIBS)
 684 AC_SUBST(GST_ALL_LDFLAGS)
 685
 686 dnl GST_LIB_LDFLAGS
 687 dnl linker flags shared by all libraries
 688 dnl LDFLAGS modifier defining exported symbols from built libraries
 689 GST_LIB_LDFLAGS="-export-symbols-regex \^[_]?\(gst_\|Gst\|GST_\).*"
 690 AC_SUBST(GST_LIB_LDFLAGS)
 691
 692 dnl GST_OBJ_*
 693 dnl default vars for all internal objects built on libgstreamer
 694 dnl includes GST_ALL_*
 695 GST_OBJ_CFLAGS="\$(GST_ALL_CFLAGS)"
 696 GST_OBJ_CXXFLAGS="\$(GST_ALL_CXXFLAGS)"
 697 GST_OBJ_LIBS="\$(top_builddir)/gst/libgstreamer-$GST_API_VERSION.la \$(GST_ALL_LIBS)"
 698 AC_SUBST(GST_OBJ_CFLAGS)
 699 AC_SUBST(GST_OBJ_CXXFLAGS)
 700 AC_SUBST(GST_OBJ_LIBS)
 701
 702 dnl GST_PLUGIN_LDFLAGS
 703 dnl LDFLAGS for plugins; includes GST_ALL_LDFLAGS
 704 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc.*' $GST_ALL_LDFLAGS"
 705 AC_SUBST(GST_PLUGIN_LDFLAGS, "$GST_PLUGIN_LDFLAGS")
 706
 707 dnl plugin scanner locations
 708 AS_AC_EXPAND(GST_PLUGIN_SCANNER_INSTALLED,${libexecdir}/gstreamer-$GST_API_VERSION/gst-plugin-scanner)
 709 AC_DEFINE_UNQUOTED(GST_PLUGIN_SCANNER_INSTALLED,
 710     "$GST_PLUGIN_SCANNER_INSTALLED", [location of the installed gst-plugin-scanner])
 711 AC_SUBST(GST_PLUGIN_SCANNER_INSTALLED)
 712
 713 dnl things for our internal libcheck (must be called even if building
 714 dnl libcheck is disabled because it defines conditionals)
 715 AG_GST_CHECK_CHECKS()
 716
 717 AC_CONFIG_FILES(
 718 Makefile
 719 gst/Makefile
 720 gst/gstconfig.h
 721 gst/gstversion.h
 722 gst/parse/Makefile
 723 libs/Makefile
 724 libs/gst/Makefile
 725 libs/gst/base/Makefile
 726 libs/gst/check/Makefile
 727 libs/gst/check/libcheck/Makefile
 728 libs/gst/check/libcheck/check.h
 729 libs/gst/controller/Makefile
 730 libs/gst/helpers/Makefile
 731 libs/gst/net/Makefile
 732 plugins/Makefile
 733 plugins/elements/Makefile
 734 po/Makefile.in
 735 tests/Makefile
 736 tests/benchmarks/Makefile
 737 tests/check/Makefile
 738 tests/misc/Makefile
 739 tests/examples/Makefile
 740 tests/examples/adapter/Makefile
 741 tests/examples/controller/Makefile
 742 tests/examples/stepping/Makefile
 743 tests/examples/helloworld/Makefile
 744 tests/examples/launch/Makefile
 745 tests/examples/manual/Makefile
 746 tests/examples/metadata/Makefile
 747 tests/examples/queue/Makefile
 748 tests/examples/streams/Makefile
 749 tests/examples/typefind/Makefile
 750 tools/Makefile
 751 common/Makefile
 752 common/m4/Makefile
 753 docs/Makefile
 754 docs/design/Makefile
 755 docs/faq/Makefile
 756 docs/gst/Makefile
 757 docs/gst/gstreamer.types
 758 docs/libs/Makefile
 759 docs/plugins/Makefile
 760 docs/manual/Makefile
 761 docs/pwg/Makefile
 762 docs/slides/Makefile
 763 docs/xsl/Makefile
 764 docs/version.entities
 765 m4/Makefile
 766 pkgconfig/Makefile
 767 stamp.h
 768 pkgconfig/gstreamer.pc
 769 pkgconfig/gstreamer-uninstalled.pc
 770 pkgconfig/gstreamer-base.pc
 771 pkgconfig/gstreamer-base-uninstalled.pc
 772 pkgconfig/gstreamer-check.pc
 773 pkgconfig/gstreamer-check-uninstalled.pc
 774 pkgconfig/gstreamer-controller.pc
 775 pkgconfig/gstreamer-controller-uninstalled.pc
 776 pkgconfig/gstreamer-net.pc
 777 pkgconfig/gstreamer-net-uninstalled.pc
 778 gst-element-check.m4
 779 gstreamer.spec
 780 )
 781
 782 dnl Create the config.h file for Visual Studio builds
 783 dnl Beware of spaces and /'s in some of the shell variable contents.
 784 sed \
 785     -e 's/.*config.h.in.*autoheader.*/\/* Autogenerated config.h created for win32 Visual Studio builds *\/\n\n\/* PREFIX -- specifically added for Windows for easier moving *\/\n#define PREFIX "C:\\\\gstreamer"/' \
 786     -e 's/.* GETTEXT_PACKAGE$/#define GETTEXT_PACKAGE "'$GETTEXT_PACKAGE'"/' \
 787     -e 's/.* GST_DATADIR$/#define GST_DATADIR PREFIX "\\\\share"/' \
 788     -e 's/.* GST_LEVEL_DEFAULT$/#define GST_LEVEL_DEFAULT GST_LEVEL_ERROR/' \
 789     -e 's/.* GST_LICENSE$/#define GST_LICENSE "'$GST_LICENSE'"/' \
 790     -e 's/.* GST_API_VERSION$/#define GST_API_VERSION "'$GST_API_VERSION'"/' \
 791     -e "s,.* GST_PACKAGE_NAME$,#define GST_PACKAGE_NAME \"${GST_PACKAGE_NAME}\"," \
 792     -e 's/.* GST_PACKAGE_ORIGIN$/#define GST_PACKAGE_ORIGIN "Unknown package origin"/' \
 793     -e "s,.* GST_PACKAGE_RELEASE_DATETIME$,#define GST_PACKAGE_RELEASE_DATETIME \"${GST_PACKAGE_RELEASE_DATETIME}\"," \
 794     -e 's/.* HAVE_CPU_I386$/#define HAVE_CPU_I386 1/' \
 795     -e 's/.* HAVE_FGETPOS$/#define HAVE_FGETPOS 1/' \
 796     -e 's/.* HAVE_FSETPOS$/#define HAVE_FSETPOS 1/' \
 797     -e 's/.* HAVE_PROCESS_H$/#define HAVE_PROCESS_H 1/' \
 798     -e 's/.* HAVE_STDLIB_H$/#define HAVE_STDLIB_H 1/' \
 799     -e 's/.* HAVE_STRING_H$/#define HAVE_STRING_H 1/' \
 800     -e 's/.* HAVE_SYS_STAT_H$/#define HAVE_SYS_STAT_H 1/' \
 801     -e 's/.* HAVE_SYS_TYPES_H$/#define HAVE_SYS_TYPES_H 1/' \
 802     -e 's/.* HAVE_WIN32$/#define HAVE_WIN32 1/' \
 803     -e 's/.* HAVE_WINSOCK2_H$/#define HAVE_WINSOCK2_H 1/' \
 804     -e 's/.* HOST_CPU$/#define HOST_CPU "i686"/' \
 805     -e 's/.* MEMORY_ALIGNMENT_MALLOC/#define MEMORY_ALIGNMENT_MALLOC 1/' \
 806     -e 's/.* LIBDIR$/#ifdef _DEBUG\n#  define LIBDIR PREFIX "\\\\debug\\\\lib"\n#else\n#  define LIBDIR PREFIX "\\\\lib"\n#endif/' \
 807     -e 's/.* LOCALEDIR$/#define LOCALEDIR PREFIX "\\\\share\\\\locale"/' \
 808     -e 's/.* PACKAGE$/#define PACKAGE "gstreamer"/' \
 809     -e 's/.* PACKAGE_BUGREPORT$/#define PACKAGE_BUGREPORT "http:\/\/bugzilla.gnome.org\/enter_bug.cgi?product=GStreamer"/' \
 810     -e 's/.* PACKAGE_NAME$/#define PACKAGE_NAME "'$PACKAGE_NAME'"/' \
 811     -e "s/.* PACKAGE_STRING$/#define PACKAGE_STRING \"$PACKAGE_STRING\"/" \
 812     -e 's/.* PACKAGE_TARNAME$/#define PACKAGE_TARNAME "'$PACKAGE_TARNAME'"/' \
 813     -e 's/.* PACKAGE_VERSION$/#define PACKAGE_VERSION "'$PACKAGE_VERSION'"/' \
 814     -e 's/.* PLUGINDIR$/#ifdef _DEBUG\n#  define PLUGINDIR PREFIX "\\\\debug\\\\lib\\\\gstreamer-1.0"\n#else\n#  define PLUGINDIR PREFIX "\\\\lib\\\\gstreamer-1.0"\n#endif/' \
 815     -e 's/.* GST_PLUGIN_SCANNER_INSTALLED$/#define GST_PLUGIN_SCANNER_INSTALLED LIBDIR "\\\\gst-plugin-scanner"/' \
 816     -e 's/.* VERSION$/#define VERSION "'$VERSION'"/' \
 817     config.h.in >win32/common/config.h-new
 818
 819 AC_OUTPUT
 820
 821 dnl negate for output
 822 if test "x${GST_DISABLE_GST_DEBUG}" = "xno"; then enable_gst_debug="yes"; fi
 823 if test "x${GST_DISABLE_PARSE}" = "xno"; then enable_parse="yes"; fi
 824 if test "x${GST_DISABLE_OPTION_PARSING}" = "xno"; then enable_option_parsing="yes"; fi
 825 if test "x${GST_DISABLE_TRACE}" = "xno"; then enable_trace="yes"; fi
 826 if test "x${GST_DISABLE_ALLOC_TRACE}" = "xno"; then enable_alloc_trace="yes"; fi
 827 if test "x${GST_DISABLE_PLUGIN}" = "xno"; then enable_plugin="yes"; fi
 828 if test "x${GST_DISABLE_REGISTRY}" = "xno"; then enable_registry="yes"; fi
 829
 830 echo "
 831
 832 Configuration
 833         Version                    : ${VERSION}
 834         Source code location       : ${srcdir}
 835         Prefix                     : ${prefix}
 836         Compiler                   : ${CC}
 837         Package name               : ${GST_PACKAGE_NAME}
 838         Package origin             : ${GST_PACKAGE_ORIGIN}
 839
 840         Documentation (manuals)    : ${enable_docbook}
 841         Documentation (API)        : ${enable_gtk_doc}
 842
 843         Debug Logging              : ${enable_gst_debug}
 844         Command-line parser        : ${enable_parse}
 845         Option parsing in gst_init : ${enable_option_parsing}
 846         Tracing subsystem          : ${enable_trace}
 847         Allocation tracing         : ${enable_alloc_trace}
 848         Plugin registry            : ${enable_registry}
 849         Plugin support             : ${enable_plugin}
 850         Unit testing support       : ${BUILD_CHECK}
 851
 852         Debug                      : ${USE_DEBUG}
 853         Profiling                  : ${USE_PROFILING}
 854
 855         Building examples          : ${BUILD_EXAMPLES}
 856         Building test apps         : ${BUILD_TESTS}
 857         Building tests that fail   : ${BUILD_FAILING_TESTS}
 858 "