configure.ac

   1 AC_PREREQ(2.60)
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, git and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for git/prerelease
   8 AC_INIT(GStreamer Base Plug-ins, 0.11.1.1,
   9     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
  10     gst-plugins-base)
  11
  12 AG_GST_INIT
  13
  14 dnl initialize automake
  15 AM_INIT_AUTOMAKE([-Wno-portability 1.10])
  16
  17 dnl define PACKAGE_VERSION_* variables
  18 AS_VERSION
  19
  20 dnl check if this is a release version
  21 AS_NANO(GST_GIT="no", GST_GIT="yes")
  22
  23 dnl can autoconf find the source ?
  24 AC_CONFIG_SRCDIR([gst/audiotestsrc/gstaudiotestsrc.c])
  25
  26 dnl define the output header for config
  27 AM_CONFIG_HEADER([config.h])
  28
  29 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  30 AM_MAINTAINER_MODE
  31
  32 dnl sets host_* variables
  33 AC_CANONICAL_HOST
  34
  35 dnl use pretty build output with automake >= 1.11
  36 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],
  37   [AM_DEFAULT_VERBOSITY=1
  38    AC_SUBST(AM_DEFAULT_VERBOSITY)])
  39
  40 dnl our libraries and install dirs use major.minor as a version
  41 GST_MAJORMINOR=$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR
  42 dnl we override it here if we need to for the release candidate of new series
  43 GST_MAJORMINOR=0.11
  44 AC_SUBST(GST_MAJORMINOR)
  45
  46 dnl CURRENT, REVISION, AGE
  47 dnl - library source changed -> increment REVISION
  48 dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
  49 dnl - interfaces added -> increment AGE
  50 dnl - interfaces removed -> AGE = 0
  51 dnl sets GST_LT_LDFLAGS
  52 AS_LIBTOOL(GST, 26, 0, 0)
  53
  54 dnl FIXME: this macro doesn't actually work;
  55 dnl the generated libtool script has no support for the listed tags.
  56 dnl So this needs to be fixed first if we want to use this
  57 dnl AS_LIBTOOL_TAGS
  58
  59 AC_LIBTOOL_WIN32_DLL
  60 AM_PROG_LIBTOOL
  61
  62 dnl *** required versions of GStreamer stuff ***
  63 GST_REQ=0.11.1
  64
  65 dnl *** autotools stuff ****
  66
  67 dnl allow for different autotools
  68 AS_AUTOTOOLS_ALTERNATE
  69
  70 dnl Add parameters for aclocal
  71 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  72
  73 dnl set up gettext
  74 dnl the version check needs to stay here because autopoint greps for it
  75 AM_GNU_GETTEXT_VERSION([0.17])
  76 AM_GNU_GETTEXT([external])
  77 AG_GST_GETTEXT([gst-plugins-base-$GST_MAJORMINOR])
  78
  79 dnl *** check for arguments to configure ***
  80
  81 AG_GST_ARG_DEBUG
  82 AG_GST_ARG_PROFILING
  83 AG_GST_ARG_VALGRIND
  84 AG_GST_ARG_GCOV
  85
  86 AG_GST_ARG_EXAMPLES
  87
  88 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  89 AG_GST_ARG_WITH_PACKAGE_NAME
  90 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  91
  92 AG_GST_PKG_CONFIG_PATH
  93
  94 dnl let distro override plugin install helper path
  95 AC_ARG_WITH(install-plugins-helper,
  96   AC_HELP_STRING([--with-install-plugins-helper],
  97     [specify path of helper script to call to install plugins]),
  98   [
  99     case "${withval}" in
 100       yes) AC_MSG_ERROR(bad value ${withval} for --with-install-plugins-helper) ;;
 101       no)  AC_MSG_ERROR(bad value ${withval} for --with-install-plugins-helper) ;;
 102       *)   GST_INSTALL_PLUGINS_HELPER="${withval}" ;;
 103     esac
 104   ],
 105   [
 106     dnl Default value
 107     AS_AC_EXPAND(GST_INSTALL_PLUGINS_HELPER,${libexecdir}/gst-install-plugins-helper)
 108   ]
 109 )
 110 AC_MSG_NOTICE(Using $GST_INSTALL_PLUGINS_HELPER as plugin install helper)
 111 AC_DEFINE_UNQUOTED(GST_INSTALL_PLUGINS_HELPER, "$GST_INSTALL_PLUGINS_HELPER",
 112     [plugin install helper script])
 113 AC_SUBST(GST_INSTALL_PLUGINS_HELPER)
 114
 115 AG_GST_ARG_WITH_PLUGINS
 116
 117 AG_GST_ARG_ENABLE_EXTERNAL
 118
 119 AG_GST_ARG_ENABLE_EXPERIMENTAL
 120
 121 dnl *** checks for platform ***
 122 AG_GST_PLATFORM
 123
 124 dnl * hardware/architecture *
 125
 126 dnl common/m4/gst-arch.m4
 127 dnl check CPU type
 128 AG_GST_ARCH
 129
 130 dnl check for large file support
 131 dnl affected plugins must include config.h
 132 AC_SYS_LARGEFILE
 133
 134 dnl *** checks for programs ***
 135
 136 dnl find a compiler
 137 AC_PROG_CC
 138 AC_PROG_CC_STDC
 139
 140 dnl check if the compiler supports '-c' and '-o' options
 141 AM_PROG_CC_C_O
 142
 143 dnl determine if c++ is available on this system
 144 AC_PROG_CXX
 145 dnl CXX may be set to some default even if no c++ compiler is available
 146 dnl (thanks autotools!), so just try to compile some c++ code to make sure
 147 AC_LANG_PUSH([C++])
 148 AC_TRY_COMPILE([ class Foo { int bar; };], , working_cxx=yes, working_cxx=no)
 149 AC_LANG_POP([C++])
 150 AC_MSG_NOTICE([working c++ compiler found: $working_cxx])
 151 AM_CONDITIONAL(HAVE_CXX, test "x$working_cxx" = "xyes")
 152
 153 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 154 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 155
 156 dnl check for gobject-introspection
 157 GOBJECT_INTROSPECTION_CHECK([1.31.1])
 158
 159 dnl check for documentation tools
 160 GTK_DOC_CHECK([1.3])
 161 AS_PATH_PYTHON([2.1])
 162 AG_GST_PLUGIN_DOCS([1.3],[2.1])
 163
 164 dnl *** checks for libraries ***
 165
 166 dnl libm, for sin() etc.
 167 AC_CHECK_LIBM
 168 AC_SUBST(LIBM)
 169
 170 dnl *** checks for header files ***
 171
 172 dnl check if we have ANSI C header files
 173 AC_HEADER_STDC
 174
 175 ac_cppflags_save="$CPPFLAGS"
 176 CPPFLAGS="`$PKG_CONFIG --cflags libxml-2.0`"
 177 AC_COMPILE_IFELSE(
 178   AC_LANG_PROGRAM([
 179 #include <libxml/HTMLparser.h>
 180                      ],[
 181 #ifndef LIBXML_HTML_ENABLED
 182 #error libxml2 has no HTML support
 183 #endif /* LIBXML_HTML_ENABLED */
 184                    ]), HAVE_LIBXML_HTML="yes", HAVE_LIBXML_HTML="no")
 185 CPPFLAGS="$ac_cppflags_save"
 186 AM_CONDITIONAL(HAVE_LIBXML_HTML, test "x$HAVE_LIBXML_HTML" = "xyes")
 187
 188 dnl used in gst-libs/gst/rtsp
 189 AC_CHECK_HEADERS([winsock2.h], HAVE_WINSOCK2_H=yes)
 190 if test "x$HAVE_WINSOCK2_H" = "xyes"; then
 191   WIN32_LIBS="-lws2_32"
 192   AC_SUBST(WIN32_LIBS)
 193 fi
 194
 195 dnl check for hstrerror, for gst-libs/gst/rtsp
 196 save_libs="$LIBS"
 197 AC_CHECK_FUNC(hstrerror, ,
 198     AC_CHECK_LIB(resolv, hstrerror, ,
 199         [AC_DEFINE(NO_HSTRERROR, 1,
 200              [Define if you have no native hstrerror() function.])]))
 201 HSTRERROR_LIBS=$LIBS
 202 AC_SUBST(HSTRERROR_LIBS)
 203 LIBS="$save_libs"
 204
 205 dnl used in gst-libs/gst/pbutils and associated unit test
 206 AC_CHECK_HEADERS([process.h sys/types.h sys/wait.h sys/stat.h])
 207
 208 dnl also, Windows does not have long long
 209 AX_CREATE_STDINT_H
 210
 211 dnl *** checks for functions ***
 212 AC_CHECK_FUNCS([localtime_r gmtime_r])
 213
 214 dnl *** checks for math functions ***
 215 LIBS_SAVE=$LIBS
 216 LIBS="$LIBS $LIBM"
 217 AC_CHECK_FUNCS(log2)
 218 LIBS=$LIBS_SAVE
 219
 220 dnl *** checks for types/defines ***
 221
 222 dnl *** checks for structures ***
 223
 224 dnl *** checks for compiler characteristics ***
 225
 226 dnl *** checks for library functions ***
 227
 228 dnl check for fseeko()
 229 AC_FUNC_FSEEKO
 230
 231 dnl Check for fast float to int casting as defined in C99
 232 dnl used to be used in gst-libs/gst/floatcast/floatcast.h (FIXME: still needed?)
 233 save_libs=$LIBS
 234 LIBS="$LIBS $LIBM"
 235 AC_C99_FUNC_LRINT
 236 AC_C99_FUNC_LRINTF
 237 LIBS=$save_libs
 238
 239 dnl Check for a way to display the function name in debug output
 240 AG_GST_CHECK_FUNCTION
 241
 242 dnl *** checks for socket and nsl libraries ***
 243 AC_CHECK_FUNC(socket,,[AC_CHECK_LIB(socket,socket)])
 244 AC_CHECK_FUNC(gethostbyname,,[AC_CHECK_LIB(nsl,gethostbyname)])
 245
 246 dnl *** checks for dependency libraries ***
 247
 248 dnl GLib is required
 249 AG_GST_GLIB_CHECK([2.26])
 250
 251 dnl Check for GIO
 252 translit(dnm, m, l) AM_CONDITIONAL(USE_GIO, true)
 253 AG_GST_CHECK_FEATURE(GIO, [GIO library], gio, [
 254   PKG_CHECK_MODULES(GIO, gio-2.0 >= 2.31.10)
 255   GIO_MODULE_DIR="`$PKG_CONFIG --variable=giomoduledir gio-2.0`"
 256   AC_DEFINE_UNQUOTED(GIO_MODULE_DIR, "$GIO_MODULE_DIR",
 257       [The GIO modules directory.])
 258   GIO_LIBDIR="`$PKG_CONFIG --variable=libdir gio-2.0`"
 259       AC_DEFINE_UNQUOTED(GIO_LIBDIR, "$GIO_LIBDIR",
 260           [The GIO library directory.])
 261
 262   AC_SUBST(GIO_CFLAGS)
 263   AC_SUBST(GIO_LIBS)
 264   AC_SUBST(GIO_LDFLAGS)
 265 ])
 266
 267 ORC_CHECK([0.4.11])
 268
 269 dnl checks for gstreamer
 270 dnl uninstalled is selected preferentially -- see pkg-config(1)
 271 AG_GST_CHECK_GST($GST_MAJORMINOR, [$GST_REQ], yes)
 272 AG_GST_CHECK_GST_BASE($GST_MAJORMINOR, [$GST_REQ], yes)
 273 AG_GST_CHECK_GST_CONTROLLER($GST_MAJORMINOR, [$GST_REQ], yes)
 274 AG_GST_CHECK_GST_CHECK($GST_MAJORMINOR, [$GST_REQ], no)
 275 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 276
 277 dnl Check for documentation xrefs
 278 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 279 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_MAJORMINOR`"
 280 AC_SUBST(GLIB_PREFIX)
 281 AC_SUBST(GST_PREFIX)
 282
 283 dnl GTK is optional and only used in examples
 284 HAVE_GTK=no
 285 HAVE_GTK_X11=no
 286 GTK_REQ=3.0.0
 287 if test "x$BUILD_EXAMPLES" = "xyes"; then
 288   PKG_CHECK_MODULES(GTK, gtk+-3.0 >= $GTK_REQ, HAVE_GTK=yes, HAVE_GTK=no)
 289   dnl some examples need gtk+-x11
 290   PKG_CHECK_MODULES(GTK_X11, gtk+-x11-3.0 >= $GTK_REQ, HAVE_GTK_X11=yes, HAVE_GTK_X11=no)
 291   AC_SUBST(GTK_LIBS)
 292   AC_SUBST(GTK_CFLAGS)
 293 fi
 294 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 295 AM_CONDITIONAL(HAVE_GTK_X11, test "x$HAVE_GTK_X11" = "xyes")
 296
 297 dnl QT is optional and only used in examples
 298 PKG_CHECK_MODULES(QT, QtGui >= 4.6, [
 299   HAVE_QT_GV=yes
 300   HAVE_QT=yes
 301 ], [
 302   HAVE_QT_GV=no
 303   PKG_CHECK_MODULES(QT, QtGui >= 4.0, HAVE_QT=yes, HAVE_QT=no)
 304 ])
 305 if test "x$HAVE_QT" = "xyes"; then
 306   AC_MSG_CHECKING([Qt moc])
 307   QT4_MOC=`$PKG_CONFIG --variable=moc_location QtGui`
 308   AC_MSG_RESULT($QT4_MOC)
 309   AC_SUBST(QT4_MOC)
 310 fi
 311 AM_CONDITIONAL(HAVE_QT, test "x$HAVE_QT" = "xyes")
 312 AM_CONDITIONAL(HAVE_QT_GV, test "x$HAVE_QT_GV" = "xyes")
 313
 314 dnl chck for linux headers needed by the joystick seek example
 315 AC_COMPILE_IFELSE(
 316 [
 317   AC_LANG_PROGRAM([
 318     #include <linux/input.h>
 319     #include <linux/joystick.h>
 320   ],[
 321     struct js_event js;
 322     js.type = JS_EVENT_AXIS;
 323   ])
 324 ], [
 325   HAVE_LINUX_JOYSTICK_HEADERS="yes"
 326 ], [
 327   HAVE_LINUX_JOYSTICK_HEADERS="no"
 328 ])
 329 AM_CONDITIONAL(HAVE_LINUX_JOYSTICK_HEADERS, test "x$HAVE_LINUX_JOYSTICK_HEADERS" = "xyes")
 330
 331 dnl Check for -Bsymbolic-functions linker flag used to avoid
 332 dnl intra-library PLT jumps, if available.
 333 AC_ARG_ENABLE(Bsymbolic,
 334               [AC_HELP_STRING([--disable-Bsymbolic],
 335                               [avoid linking with -Bsymbolic])],,
 336               [SAVED_LDFLAGS="${LDFLAGS}"
 337                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
 338                LDFLAGS=-Wl,-Bsymbolic-functions
 339                AC_TRY_LINK([], [int main (void) { return 0; }],
 340                            AC_MSG_RESULT(yes)
 341                            enable_Bsymbolic=yes,
 342                            AC_MSG_RESULT(no)
 343                            enable_Bsymbolic=no)
 344                LDFLAGS="${SAVED_LDFLAGS}"])
 345
 346
 347 dnl *** set variables based on configure arguments ***
 348
 349 dnl set license and copyright notice
 350 GST_LICENSE="LGPL"
 351 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 352 AC_SUBST(GST_LICENSE)
 353
 354 dnl set location of plugin directory
 355 AG_GST_SET_PLUGINDIR
 356
 357 dnl set release date/time
 358 AG_GST_SET_PACKAGE_RELEASE_DATETIME_WITH_NANO([$PACKAGE_VERSION_NANO],
 359   ["${srcdir}/gst-plugins-base.doap"],
 360   [$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_MICRO])
 361
 362 # set by AG_GST_PARSE_SUBSYSTEM_DISABLES above
 363 dnl make sure it doesn't complain about unused variables if debugging is disabled
 364 NO_WARNINGS=""
 365 AG_GST_CHECK_GST_DEBUG_DISABLED([NO_WARNINGS="-Wno-unused"], [NO_WARNINGS=""])
 366
 367 dnl define an ERROR_CFLAGS Makefile variable
 368 dnl -Wformat-nonliteral - see ext/pango/gstclockoverlay.c and http://gcc.gnu.org/bugzilla/show_bug.cgi?id=39438
 369 AG_GST_SET_ERROR_CFLAGS($GST_GIT, [
 370     -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls -Wundef
 371     -Wwrite-strings -Wformat-nonliteral -Wformat-security
 372     -Winit-self -Wmissing-include-dirs -Waddress -Waggregate-return
 373     -Wno-multichar -Wnested-externs $NO_WARNINGS])
 374
 375 dnl define an ERROR_CXXFLAGS Makefile variable
 376 AG_GST_SET_ERROR_CXXFLAGS($GST_GIT, [
 377     -Wmissing-declarations -Wredundant-decls -Wundef
 378     -Wwrite-strings -Wformat-nonliteral -Wformat-security
 379     -Winit-self -Wmissing-include-dirs -Waddress -Waggregate-return
 380     -Wno-multichar $NO_WARNINGS])
 381
 382 dnl define correct level for debugging messages
 383 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 384
 385 dnl used in examples
 386 AG_GST_DEFAULT_ELEMENTS
 387
 388 dnl needed for encoding-target
 389 GST_DATADIR="$GST_PREFIX/share"
 390 AC_DEFINE_UNQUOTED(GST_DATADIR, "$GST_DATADIR", [system wide data directory])
 391 AC_DEFINE_UNQUOTED(GST_MAJORMINOR, "$GST_MAJORMINOR", [major/minor version])
 392
 393 dnl behaviour of speex based audio resampler
 394 AC_MSG_CHECKING(which audio resample format to use for integer)
 395 AC_ARG_WITH([audioresample_format],
 396         AS_HELP_STRING([--with-audioresample-format],[Which implementation should be used for integer audio resampling, int/float/auto, (default is auto)]),
 397         [ac_cv_audioresample_format=$withval], [ac_cv_audioresample_format=auto])dnl
 398 AC_MSG_RESULT($ac_cv_audioresample_format)
 399 case $ac_cv_audioresample_format in
 400   int)
 401     AC_DEFINE(AUDIORESAMPLE_FORMAT_INT,1,[The int implementation should be used for integer audio resampling])
 402     AC_SUBST(AUDIORESAMPLE_FORMAT_INT)
 403   ;;
 404   float)
 405     AC_DEFINE(AUDIORESAMPLE_FORMAT_FLOAT,1,[The float implementation should be used for integer audio resampling])
 406     AC_SUBST(AUDIORESAMPLE_FORMAT_FLOAT)
 407   ;;
 408   auto)
 409     AC_DEFINE(AUDIORESAMPLE_FORMAT_AUTO,1,[The implementation that should be used for integer audio resampling witll be benchmarked at runtime])
 410     AC_SUBST(AUDIORESAMPLE_FORMAT_AUTO)
 411 esac
 412
 413 dnl *** plug-ins to include ***
 414
 415 dnl these are all the gst plug-ins, compilable without additional libs
 416 AG_GST_CHECK_PLUGIN(adder)
 417 AG_GST_CHECK_PLUGIN(app)
 418 AG_GST_CHECK_PLUGIN(audioconvert)
 419 AG_GST_CHECK_PLUGIN(audiorate)
 420 AG_GST_CHECK_PLUGIN(audiotestsrc)
 421 AG_GST_CHECK_PLUGIN(encoding)
 422 AG_GST_CHECK_PLUGIN(videoconvert)
 423 AG_GST_CHECK_PLUGIN(gdp)
 424 AG_GST_CHECK_PLUGIN(playback)
 425 AG_GST_CHECK_PLUGIN(audioresample)
 426 AG_GST_CHECK_PLUGIN(subparse)
 427 AG_GST_CHECK_PLUGIN(tcp)
 428 AG_GST_CHECK_PLUGIN(typefind)
 429 AG_GST_CHECK_PLUGIN(videotestsrc)
 430 AG_GST_CHECK_PLUGIN(videorate)
 431 AG_GST_CHECK_PLUGIN(videoscale)
 432 AG_GST_CHECK_PLUGIN(volume)
 433
 434 dnl FIXME 0.11: check for libxml, split subparse and move libxml parts to ext/
 435 AM_CONDITIONAL(USE_XML, false)
 436 AC_DEFINE([GST_DISABLE_XML], [1], [set to disable libxml2-dependent code in subparse])
 437
 438 dnl disable plug-ins that require libxml2's HTML support if it is not available
 439 if test "x$HAVE_LIBXML_HTML" != "xyes"; then
 440   AG_GST_DISABLE_PLUGIN(subparse)
 441 fi
 442
 443 dnl iso-codes is optional, used by libgsttag
 444 AC_ARG_ENABLE(iso-codes,
 445 AC_HELP_STRING([--enable-iso-codes],[use iso-codes if installed]),
 446 [case "${enableval}" in
 447   yes) enable_iso_codes=yes ;;
 448   no)  enable_iso_codes=no ;;
 449   *) AC_MSG_ERROR(bad value ${enableval} for --enable-iso-codes) ;;
 450 esac
 451 ],
 452 [enable_iso_codes=yes]) dnl Default value
 453
 454 AC_MSG_CHECKING([whether to use iso-codes if they are available])
 455 if test "x$enable_iso_codes" = "xyes"; then
 456   AC_MSG_RESULT([yes])
 457   have_iso_codes=no
 458   AC_MSG_CHECKING([whether iso-codes are available on this system])
 459   if $PKG_CONFIG iso-codes; then
 460     AC_MSG_RESULT([yes])
 461     AC_MSG_CHECKING([whether iso-codes has iso-639 domain])
 462     if $PKG_CONFIG --variable=domains iso-codes | $GREP -q 639 ; then
 463       AC_MSG_RESULT([yes])
 464       AC_MSG_CHECKING([for iso-codes prefix])
 465       ISO_CODES_PREFIX=`$PKG_CONFIG --variable=prefix iso-codes`
 466       if test -d "$ISO_CODES_PREFIX"; then
 467         AC_MSG_RESULT([yes])
 468         AC_MSG_CHECKING([ISO_CODES_PREFIX])
 469         AC_MSG_RESULT([$ISO_CODES_PREFIX])
 470         ISO_639_DOMAIN="iso_639"
 471         AC_MSG_CHECKING([ISO_639_DOMAIN])
 472         AC_MSG_RESULT([$ISO_639_DOMAIN])
 473         have_iso_codes=yes
 474         AC_DEFINE([HAVE_ISO_CODES], [1], [make use of iso-codes for ISO-639])
 475         AC_DEFINE_UNQUOTED([ISO_CODES_PREFIX], ["$ISO_CODES_PREFIX"], [prefix])
 476         ISO_CODES_VERSION=`$PKG_CONFIG --modversion iso-codes`
 477         AC_DEFINE_UNQUOTED([ISO_CODES_VERSION], ["$ISO_CODES_VERSION"], [ ])
 478       else
 479         AC_MSG_RESULT([no])
 480       fi
 481     else
 482       AC_MSG_RESULT([no])
 483     fi
 484   else
 485     AC_MSG_RESULT([no])
 486   fi
 487   AM_CONDITIONAL(USE_ISO_CODES, test "x$have_iso_codes" = "xyes")
 488 else
 489   AC_MSG_RESULT([no (disabled via --disable-iso-codes)])
 490   AM_CONDITIONAL(USE_ISO_CODES, false)
 491 fi
 492
 493 dnl *** zlib is optionally used by id3 tag parsing in libgsttag ***
 494 translit(dnm, m, l) AM_CONDITIONAL(USE_ZLIB, true)
 495 AG_GST_CHECK_FEATURE(ZLIB, [zlib support for ID3 parsing in libgsttag],, [
 496   PKG_CHECK_MODULES(ZLIB, [ zlib ], [
 497       HAVE_ZLIB="yes"
 498     ], [
 499       AG_GST_CHECK_LIBHEADER(ZLIB, z, uncompress,, zlib.h, [
 500         HAVE_ZLIB="yes"
 501         ZLIB_LIBS="-lz"
 502         AC_SUBST(ZLIB_LIBS)
 503       ])
 504     ])
 505 ])
 506
 507 dnl *** sys plug-ins ***
 508
 509 echo
 510 AC_MSG_NOTICE([Checking libraries for plugins in sys/])
 511 echo
 512
 513 dnl *** X11 ***
 514 translit(dnm, m, l) AM_CONDITIONAL(USE_X, true)
 515 AG_GST_CHECK_FEATURE(X, [X libraries and plugins],
 516                   [ximagesink], [
 517   AC_PATH_XTRA
 518   ac_cflags_save="$CFLAGS"
 519   ac_cppflags_save="$CPPFLAGS"
 520   CFLAGS="$CFLAGS $X_CFLAGS"
 521   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 522
 523   dnl now try to find the HEADER
 524   AC_CHECK_HEADER(X11/Xlib.h, HAVE_X="yes", HAVE_X="no")
 525
 526   if test "x$HAVE_X" = "xno"
 527   then
 528     AC_MSG_NOTICE([cannot find X11 development files])
 529   else
 530     dnl this is much more than we want
 531     X_LIBS="$X_LIBS $X_PRE_LIBS $X_EXTRA_LIBS"
 532     dnl AC_PATH_XTRA only defines the path needed to find the X libs,
 533     dnl it does not add the libs; therefore we add them here
 534     X_LIBS="$X_LIBS -lX11"
 535     AC_SUBST(X_CFLAGS)
 536     AC_SUBST(X_LIBS)
 537   fi
 538   AC_SUBST(HAVE_X)
 539   CFLAGS="$ac_cflags_save"
 540   CPPFLAGS="$ac_cppflags_save"
 541 ])
 542
 543 dnl Check for Xv extension
 544 translit(dnm, m, l) AM_CONDITIONAL(USE_XVIDEO, true)
 545 AG_GST_CHECK_FEATURE(XVIDEO, [X11 XVideo extensions],
 546                   [xvimagesink], [
 547   AG_GST_CHECK_XV
 548 ])
 549
 550 dnl check for X Shm
 551 translit(dnm, m, l) AM_CONDITIONAL(USE_XSHM, true)
 552 AG_GST_CHECK_FEATURE(XSHM, [X Shared Memory extension], , [
 553   if test x$HAVE_X = xyes; then
 554     AC_CHECK_LIB(Xext, XShmAttach,
 555                  HAVE_XSHM="yes", HAVE_XSHM="no",
 556                  $X_LIBS)
 557     if test "x$HAVE_XSHM" = "xyes"; then
 558       XSHM_LIBS="-lXext"
 559     else
 560       dnl On AIX, it is in XextSam instead, but we still need -lXext
 561       AC_CHECK_LIB(XextSam, XShmAttach,
 562                    HAVE_XSHM="yes", HAVE_XSHM="no",
 563                    $X_LIBS)
 564       if test "x$HAVE_XSHM" = "xyes"; then
 565         XSHM_LIBS="-lXext -lXextSam"
 566       fi
 567     fi
 568   fi
 569 ], , [
 570   AC_SUBST(HAVE_XSHM)
 571   AC_SUBST(XSHM_LIBS)
 572 ])
 573
 574 dnl *** ext plug-ins ***
 575 dnl keep this list sorted alphabetically !
 576
 577 if test "x$BUILD_EXTERNAL" = "xyes"; then
 578
 579 echo
 580 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 581 echo
 582
 583 dnl *** alsa ***
 584 translit(dnm, m, l) AM_CONDITIONAL(USE_ALSA, true)
 585 AG_GST_CHECK_FEATURE(ALSA, [ALSA], alsa, [
 586   PKG_CHECK_MODULES(ALSA, alsa >= 0.9.1, [
 587     HAVE_ALSA="yes"
 588     AC_SUBST(ALSA_CFLAGS)
 589     AC_SUBST(ALSA_LIBS)
 590   ], [
 591     AM_PATH_ALSA(0.9.1, HAVE_ALSA="yes", HAVE_ALSA="no")
 592   ])
 593 ])
 594
 595 dnl *** CDParanoia ***
 596 dnl Note: upstream has a pkg-config file only in post-10.2 SVN so far
 597 translit(dnm, m, l) AM_CONDITIONAL(USE_CDPARANOIA, true)
 598 AG_GST_CHECK_FEATURE(CDPARANOIA, [CDParanoia], cdparanoia, [
 599   PKG_CHECK_MODULES(CDPARANOIA, cdparanoia-3 >= 10.2, [
 600     HAVE_CDPARANOIA="yes"
 601   ], [
 602     AG_GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 603                         cdda_open, -lm,
 604                         cdda_interface.h,
 605                         CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 606                         HEADER_DIR="no"
 607                         FOUND_CDPARANOIA="yes")
 608     if test "x$FOUND_CDPARANOIA" != "xyes";
 609     then
 610       AG_GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 611                           cdda_open, -lm,
 612                           cdda/cdda_interface.h,
 613                           CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 614                           HEADER_DIR="yes"
 615                           FOUND_CDPARANOIA="yes")
 616     fi
 617     if test "x$HEADER_DIR" = "xyes";
 618     then
 619       AC_DEFINE_UNQUOTED(CDPARANOIA_HEADERS_IN_DIR, ,
 620                          defined if cdda headers are in a cdda/ directory)
 621     fi
 622     if test "x$FOUND_CDPARANOIA" = "xyes";
 623     then
 624       AC_CHECK_LIB(cdda_paranoia,
 625                    paranoia_cachemodel_size,
 626                    : ,
 627                    HAVE_CDPARANOIA=no,
 628                  [-lcdda_interface])
 629     fi
 630
 631     AC_SUBST(CDPARANOIA_LIBS)
 632   ])
 633 ])
 634 dnl FIXME : add second check somehow if that is necessary
 635 dnl AC_CHECK_LIB(cdda_paranoia, paranoia_init, : , HAVE_CDPARANOIA=no, -lcdda_interface )
 636 dnl AC_CHECK_HEADER(cdda_paranoia.h, :, HAVE_CDPARANOIA=no)
 637
 638 dnl *** ivorbis ***
 639 dnl AM_PATH_IVORBIS only takes two options
 640 translit(dnm, m, l) AM_CONDITIONAL(USE_IVORBIS, true)
 641 AG_GST_CHECK_FEATURE(IVORBIS, [integer vorbis plug-in], ivorbisdec, [
 642   AG_GST_PKG_CHECK_MODULES(IVORBIS, vorbisidec)
 643   if test $HAVE_IVORBIS = no
 644   then
 645     IVORBIS_LIBS=
 646     IVORBIS_CFLAGS=
 647     AC_CHECK_LIB(vorbisidec, vorbis_block_init,
 648       [IVORBIS_LIBS=-lvorbisidec
 649       HAVE_IVORBIS=yes
 650       case $host in
 651       arm-*-*)
 652         IVORBIS_CFLAGS="-D_ARM_ASSEM_ $IVORBIS_CFLAGS"
 653       esac
 654       ],
 655       HAVE_IVORBIS=no)
 656     AC_SUBST(IVORBIS_LIBS)
 657     AC_SUBST(IVORBIS_CFLAGS)
 658   else
 659     AC_CHECK_LIB(vorbisidec, vorbis_dsp_pcmout,
 660       AC_DEFINE([USE_TREMOLO],1, "Define if building for android"),
 661       USE_TREMOLO=no)
 662   fi
 663 ])
 664
 665 dnl *** libvisual ***
 666 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBVISUAL, true)
 667 AG_GST_CHECK_FEATURE(LIBVISUAL, [libvisual visualization library], libvisual, [
 668   AG_GST_PKG_CHECK_MODULES(LIBVISUAL, libvisual-0.4 >= 0.4.0)
 669   if test $HAVE_LIBVISUAL = no
 670   then
 671     AG_GST_PKG_CHECK_MODULES(LIBVISUAL, libvisual = 0.2.0)
 672     if test x$HAVE_LIBVISUAL = xyes; then
 673       LIBVIS_PLUGINSDIR="`$PKG_CONFIG --variable=pluginsbasedir libvisual-0.2`"
 674     fi
 675   else
 676     if test x$HAVE_LIBVISUAL = xyes; then
 677       LIBVIS_PLUGINSDIR="`$PKG_CONFIG --variable=pluginsbasedir libvisual-0.4`"
 678     fi
 679   fi
 680   AC_MSG_NOTICE([libvisual pluginsdir: $LIBVIS_PLUGINSDIR])
 681   if test x$LIBVIS_PLUGINSDIR != x; then
 682     AC_DEFINE_UNQUOTED(LIBVISUAL_PLUGINSBASEDIR,
 683         "$LIBVIS_PLUGINSDIR",
 684         [directory in which the detected libvisual's plugins are located])
 685   fi
 686 ])
 687
 688 dnl *** ogg ***
 689 translit(dnm, m, l) AM_CONDITIONAL(USE_OGG, true)
 690 AG_GST_CHECK_FEATURE(OGG, [Xiph Ogg library], ogg, [
 691   AG_GST_PKG_CHECK_MODULES(OGG, ogg >= 1.0)
 692   if test $HAVE_OGG = no
 693   then
 694     XIPH_PATH_OGG(HAVE_OGG="yes", HAVE_OGG="no")
 695     AS_SCRUB_INCLUDE(OGG_CFLAGS)
 696   fi
 697 ])
 698
 699 dnl *** pango ***
 700 translit(dnm, m, l) AM_CONDITIONAL(USE_PANGO, true)
 701 AG_GST_CHECK_FEATURE(PANGO, [Pango font rendering], pango, [
 702   AG_GST_PKG_CHECK_MODULES(PANGO, pango >= 1.16.0  pangocairo >= 1.16.0)
 703 ])
 704
 705 dnl *** theora ***
 706 translit(dnm, m, l) AM_CONDITIONAL(USE_THEORA, true)
 707 AG_GST_CHECK_FEATURE(THEORA, [Xiph Theora video codec], theora, [
 708   AG_GST_PKG_CHECK_MODULES(THEORA, theoradec >= 1.1 theoraenc >= 1.1)
 709 ])
 710
 711 dnl *** vorbis ***
 712 dnl AM_PATH_VORBIS only takes two options
 713 translit(dnm, m, l) AM_CONDITIONAL(USE_VORBIS, true)
 714 AG_GST_CHECK_FEATURE(VORBIS, [Xiph Vorbis audio codec], vorbis, [
 715   AG_GST_PKG_CHECK_MODULES(VORBIS, vorbis >= 1.0 vorbisenc >= 1.0)
 716   if test $HAVE_VORBIS = no
 717   then
 718     XIPH_PATH_VORBIS(HAVE_VORBIS="yes", HAVE_VORBIS="no")
 719     AS_SCRUB_INCLUDE(VORBIS_CFLAGS)
 720   fi
 721 ])
 722
 723 if test "x$HAVE_VORBIS" = "xyes"; then
 724   ac_cflags_save="$CFLAGS"
 725   AC_COMPILE_IFELSE(
 726     AC_LANG_PROGRAM([
 727 #include <vorbis/codec.h>
 728                      ],[
 729 vorbis_dsp_state *v;
 730
 731 vorbis_synthesis_restart (v);
 732                      ]), HAVE_VSR=yes, HAVE_VSR=no)
 733   if test "x$HAVE_VSR" = "xyes"; then
 734     AC_DEFINE_UNQUOTED(HAVE_VORBIS_SYNTHESIS_RESTART, 1,
 735                        [defined if vorbis_synthesis_restart is present])
 736   fi
 737   CFLAGS="$ac_cflags_save"
 738 fi
 739
 740 else
 741
 742 dnl not building plugins with external dependencies,
 743 dnl but we still need to set the conditionals
 744 AM_CONDITIONAL(USE_ALSA, false)
 745 AM_CONDITIONAL(USE_CDPARANOIA, false)
 746 AM_CONDITIONAL(USE_GIO, false)
 747 AM_CONDITIONAL(USE_IVORBIS, false)
 748 AM_CONDITIONAL(USE_LIBVISUAL, false)
 749 AM_CONDITIONAL(USE_OGG, false)
 750 AM_CONDITIONAL(USE_PANGO, false)
 751 AM_CONDITIONAL(USE_THEORA, false)
 752 AM_CONDITIONAL(USE_VORBIS, false)
 753
 754 fi dnl of EXT plugins
 755
 756 dnl seeking needs freetype, so check for it here
 757 PKG_CHECK_MODULES(FT2, freetype2 >= 2.0.9, HAVE_FT2="yes", [
 758   AC_CHECK_FT2(2.0.9, HAVE_FT2="yes", HAVE_FT2="no")
 759 ])
 760 dnl make the HAVE_FT2 variable available to automake and Makefile.am
 761 AM_CONDITIONAL(HAVE_FT2, test "x$HAVE_FT2" = "xyes")
 762 AC_SUBST(FT2_CFLAGS)
 763 AC_SUBST(FT2_LIBS)
 764
 765 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 766
 767 dnl Overview:
 768 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
 769 dnl GST_*:              flags shared by built objects to link against GStreamer
 770 dnl GST_PLUGINS_BASE_CFLAGS: to link internally against the plugins base libs
 771 dnl                          (compare to other modules) or for i18n
 772 dnl GST_ALL_LDFLAGS:    linker flags shared by all
 773 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 774 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 775 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 776
 777 dnl GST_OPTION_CFLAGS
 778 if test "x$USE_DEBUG" = xyes; then
 779    PROFILE_CFLAGS="-g"
 780 fi
 781 AC_SUBST(PROFILE_CFLAGS)
 782
 783 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
 784   dnl Define _only_ when compiling a git version (not pre-releases or releases)
 785   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 786 else
 787   DEPRECATED_CFLAGS=""
 788 fi
 789 AC_SUBST(DEPRECATED_CFLAGS)
 790
 791 dnl every flag in GST_OPTION_CFLAGS and GST_OPTION_CXXFLAGS can be overridden
 792 dnl at make time with e.g. make ERROR_CFLAGS=""
 793 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 794 GST_OPTION_CXXFLAGS="\$(WARNING_CXXFLAGS) \$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 795 AC_SUBST(GST_OPTION_CFLAGS)
 796 AC_SUBST(GST_OPTION_CXXFLAGS)
 797
 798 dnl our libraries need to be versioned correctly
 799 AC_SUBST(GST_LT_LDFLAGS)
 800
 801 dnl GST_PLUGINS_BASE_CFLAGS
 802 dnl prefer internal headers to already installed ones
 803 dnl also add builddir include for enumtypes and marshal
 804 GST_PLUGINS_BASE_CFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs"
 805 AC_SUBST(GST_PLUGINS_BASE_CFLAGS)
 806
 807 dnl FIXME: do we want to rename to GST_ALL_* ?
 808 dnl add GST_OPTION_CFLAGS, but overridable
 809 GST_CFLAGS="$GST_CFLAGS -DGST_USE_UNSTABLE_API"
 810 GST_CXXFLAGS="$GLIB_CFLAGS $GST_CFLAGS \$(GLIB_EXTRA_CFLAGS) \$(GST_OPTION_CXXFLAGS)"
 811 GST_CFLAGS="$GLIB_CFLAGS $GST_CFLAGS \$(GLIB_EXTRA_CFLAGS) \$(GST_OPTION_CFLAGS)"
 812 AC_SUBST(GST_CFLAGS)
 813 AC_SUBST(GST_CXXFLAGS)
 814 dnl add GCOV libs because libtool strips -fprofile-arcs -ftest-coverage
 815 GST_LIBS="$GST_LIBS \$(GCOV_LIBS)"
 816 AC_SUBST(GST_LIBS)
 817
 818 dnl LDFLAGS really should only contain flags, not libs - they get added before
 819 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 820 GST_ALL_LDFLAGS="-no-undefined"
 821 if test "x${enable_Bsymbolic}" = "xyes"; then
 822   GST_ALL_LDFLAGS="$GST_ALL_LDFLAGS -Wl,-Bsymbolic-functions"
 823 fi
 824 AC_SUBST(GST_ALL_LDFLAGS)
 825
 826 dnl GST_LIB_LDFLAGS
 827 dnl linker flags shared by all libraries
 828 dnl LDFLAGS modifier defining exported symbols from built libraries
 829 dnl (export _gst_foo but not __gst_foo)
 830 GST_LIB_LDFLAGS="-export-symbols-regex ^_?\(gst_\|Gst\|GST_\).*"
 831 AC_SUBST(GST_LIB_LDFLAGS)
 832
 833 dnl this really should only contain flags, not libs - they get added before
 834 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 835 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc.*' $GST_ALL_LDFLAGS"
 836 AC_SUBST(GST_PLUGIN_LDFLAGS)
 837
 838 dnl *** output files ***
 839
 840 AC_CONFIG_FILES(
 841 Makefile
 842 gst-plugins-base.spec
 843 gst/Makefile
 844 gst/adder/Makefile
 845 gst/app/Makefile
 846 gst/audioconvert/Makefile
 847 gst/audiorate/Makefile
 848 gst/audiotestsrc/Makefile
 849 gst/encoding/Makefile
 850 gst/videoconvert/Makefile
 851 gst/gdp/Makefile
 852 gst/playback/Makefile
 853 gst/audioresample/Makefile
 854 gst/subparse/Makefile
 855 gst/tcp/Makefile
 856 gst/typefind/Makefile
 857 gst/videotestsrc/Makefile
 858 gst/videorate/Makefile
 859 gst/videoscale/Makefile
 860 gst/volume/Makefile
 861 sys/Makefile
 862 sys/ximage/Makefile
 863 sys/xvimage/Makefile
 864 ext/Makefile
 865 ext/alsa/Makefile
 866 ext/cdparanoia/Makefile
 867 ext/gio/Makefile
 868 ext/libvisual/Makefile
 869 ext/ogg/Makefile
 870 ext/pango/Makefile
 871 ext/theora/Makefile
 872 ext/vorbis/Makefile
 873 gst-libs/Makefile
 874 gst-libs/gst/Makefile
 875 gst-libs/gst/audio/Makefile
 876 gst-libs/gst/app/Makefile
 877 gst-libs/gst/fft/Makefile
 878 gst-libs/gst/interfaces/Makefile
 879 gst-libs/gst/riff/Makefile
 880 gst-libs/gst/rtp/Makefile
 881 gst-libs/gst/rtsp/Makefile
 882 gst-libs/gst/sdp/Makefile
 883 gst-libs/gst/tag/Makefile
 884 gst-libs/gst/pbutils/Makefile
 885 gst-libs/gst/pbutils/gstpluginsbaseversion.h
 886 gst-libs/gst/video/Makefile
 887 tools/Makefile
 888 pkgconfig/Makefile
 889 pkgconfig/gstreamer-audio.pc
 890 pkgconfig/gstreamer-audio-uninstalled.pc
 891 pkgconfig/gstreamer-app.pc
 892 pkgconfig/gstreamer-app-uninstalled.pc
 893 pkgconfig/gstreamer-fft.pc
 894 pkgconfig/gstreamer-fft-uninstalled.pc
 895 pkgconfig/gstreamer-interfaces.pc
 896 pkgconfig/gstreamer-interfaces-uninstalled.pc
 897 pkgconfig/gstreamer-pbutils.pc
 898 pkgconfig/gstreamer-pbutils-uninstalled.pc
 899 pkgconfig/gstreamer-riff.pc
 900 pkgconfig/gstreamer-riff-uninstalled.pc
 901 pkgconfig/gstreamer-rtp.pc
 902 pkgconfig/gstreamer-rtp-uninstalled.pc
 903 pkgconfig/gstreamer-rtsp.pc
 904 pkgconfig/gstreamer-rtsp-uninstalled.pc
 905 pkgconfig/gstreamer-sdp.pc
 906 pkgconfig/gstreamer-sdp-uninstalled.pc
 907 pkgconfig/gstreamer-tag.pc
 908 pkgconfig/gstreamer-tag-uninstalled.pc
 909 pkgconfig/gstreamer-video.pc
 910 pkgconfig/gstreamer-video-uninstalled.pc
 911 pkgconfig/gstreamer-plugins-base.pc
 912 pkgconfig/gstreamer-plugins-base-uninstalled.pc
 913 tests/Makefile
 914 tests/check/Makefile
 915 tests/examples/Makefile
 916 tests/examples/app/Makefile
 917 tests/examples/audio/Makefile
 918 tests/examples/dynamic/Makefile
 919 tests/examples/encoding/Makefile
 920 tests/examples/fft/Makefile
 921 tests/examples/gio/Makefile
 922 tests/examples/overlay/Makefile
 923 tests/examples/seek/Makefile
 924 tests/examples/snapshot/Makefile
 925 tests/examples/playrec/Makefile
 926 tests/files/Makefile
 927 tests/icles/Makefile
 928 tests/icles/playback/Makefile
 929 docs/Makefile
 930 docs/design/Makefile
 931 docs/libs/Makefile
 932 docs/plugins/Makefile
 933 docs/version.entities
 934 po/Makefile.in
 935 common/Makefile
 936 common/m4/Makefile
 937 m4/Makefile
 938 )
 939
 940 dnl Create the config.h file for Visual Studio builds
 941 dnl Beware of spaces and /'s in some of the shell variable contents.
 942 sed \
 943     -e 's/.*config.h.in.*autoheader.*/\/* Autogenerated config.h created for win32 Visual Studio builds *\/\n\n\/* PREFIX -- specifically added for Windows for easier moving *\/\n#define PREFIX "C:\\\\gstreamer"/' \
 944     -e 's/.* GST_INSTALL_PLUGINS_HELPER/#define GST_INSTALL_PLUGINS_HELPER PREFIX "\\\\libexec\\\\gst-install-plugins-helper.exe"/' \
 945     -e 's/.* GETTEXT_PACKAGE$/#define GETTEXT_PACKAGE "'$GETTEXT_PACKAGE'"/' \
 946     -e 's/.* GST_DATADIR$/#define GST_DATADIR PREFIX "\\\\share"/' \
 947     -e 's/.* GST_LEVEL_DEFAULT$/#define GST_LEVEL_DEFAULT GST_LEVEL_ERROR/' \
 948     -e 's/.* GST_LICENSE$/#define GST_LICENSE "'$GST_LICENSE'"/' \
 949     -e 's/.* GST_MAJORMINOR$/#define GST_MAJORMINOR "'$GST_MAJORMINOR'"/' \
 950     -e "s,.* GST_PACKAGE_NAME$,#define GST_PACKAGE_NAME \"${GST_PACKAGE_NAME}\"," \
 951     -e 's/.* GST_PACKAGE_ORIGIN$/#define GST_PACKAGE_ORIGIN "Unknown package origin"/' \
 952     -e "s,.* GST_PACKAGE_RELEASE_DATETIME$,#define GST_PACKAGE_RELEASE_DATETIME \"${GST_PACKAGE_RELEASE_DATETIME}\"," \
 953     -e 's/.* HAVE_CPU_I386$/#define HAVE_CPU_I386 1/' \
 954     -e 's/.* HAVE_FGETPOS$/#define HAVE_FGETPOS 1/' \
 955     -e 's/.* HAVE_FSETPOS$/#define HAVE_FSETPOS 1/' \
 956     -e 's/.* HAVE_ISO_CODES$/#undef HAVE_ISO_CODES/' \
 957     -e 's/.* HAVE_LIBXML2$/#define HAVE_LIBXML2 1/' \
 958     -e 's/.* HAVE_PROCESS_H$/#define HAVE_PROCESS_H 1/' \
 959     -e 's/.* HAVE_STDLIB_H$/#define HAVE_STDLIB_H 1/' \
 960     -e 's/.* HAVE_STRING_H$/#define HAVE_STRING_H 1/' \
 961     -e 's/.* HAVE_SYS_STAT_H$/#define HAVE_SYS_STAT_H 1/' \
 962     -e 's/.* HAVE_SYS_TYPES_H$/#define HAVE_SYS_TYPES_H 1/' \
 963     -e 's/.* HAVE_WIN32$/#define HAVE_WIN32 1/' \
 964     -e 's/.* HAVE_WINSOCK2_H$/#define HAVE_WINSOCK2_H 1/' \
 965     -e 's/.* HOST_CPU$/#define HOST_CPU "i686"/' \
 966     -e 's/.* ISO_CODES_PREFIX$/#undef ISO_CODES_PREFIX/' \
 967     -e 's/.* ISO_CODES_VERSION$/#undef ISO_CODES_VERSION/' \
 968     -e 's/.* LIBDIR$/#ifdef _DEBUG\n#  define LIBDIR PREFIX "\\\\debug\\\\lib"\n#else\n#  define LIBDIR PREFIX "\\\\lib"\n#endif/' \
 969     -e 's/.* LOCALEDIR$/#define LOCALEDIR PREFIX "\\\\share\\\\locale"/' \
 970     -e "s/.* PACKAGE$/#define PACKAGE \"$PACKAGE\"/" \
 971     -e 's/.* PACKAGE_BUGREPORT$/#define PACKAGE_BUGREPORT "http:\/\/bugzilla.gnome.org\/enter_bug.cgi?product=GStreamer"/' \
 972     -e "s/.* PACKAGE_NAME$/#define PACKAGE_NAME \"$PACKAGE_NAME\"/" \
 973     -e "s/.* PACKAGE_STRING$/#define PACKAGE_STRING \"$PACKAGE_STRING\"/" \
 974     -e 's/.* PACKAGE_TARNAME$/#define PACKAGE_TARNAME "'$PACKAGE_TARNAME'"/' \
 975     -e 's/.* PACKAGE_VERSION$/#define PACKAGE_VERSION "'$PACKAGE_VERSION'"/' \
 976     -e 's/.* PLUGINDIR$/#ifdef _DEBUG\n#  define PLUGINDIR PREFIX "\\\\debug\\\\lib\\\\gstreamer-0.11"\n#else\n#  define PLUGINDIR PREFIX "\\\\lib\\\\gstreamer-0.11"\n#endif/' \
 977     -e 's/.* USE_BINARY_REGISTRY$/#define USE_BINARY_REGISTRY/' \
 978     -e 's/.* VERSION$/#define VERSION "'$VERSION'"/' \
 979     -e "s/.* DEFAULT_AUDIOSINK$/#define DEFAULT_AUDIOSINK \"directsoundsink\"/" \
 980     -e "s/.* DEFAULT_VIDEOSINK$/#define DEFAULT_VIDEOSINK \"directdrawsink\"/" \
 981     -e "s/.* DEFAULT_VISUALIZER$/#define DEFAULT_VISUALIZER \"goom\"/" \
 982     config.h.in >win32/common/config.h-new
 983
 984
 985
 986 AC_OUTPUT
 987
 988 AG_GST_OUTPUT_PLUGINS
 989 ORC_OUTPUT
 990