configure.ac

   1 AC_PREREQ([2.68])
   2
   3 dnl initialize autoconf
   4 dnl when going to/from release please set the nano (fourth number) right !
   5 dnl releases only do Wall, git and prerelease does Werror too
   6 dnl
   7 AC_INIT([GStreamer],[1.1.2.1],[http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer],[gstreamer])
   8 AG_GST_INIT
   9
  10 dnl initialize automake (we require GNU make)
  11 AM_INIT_AUTOMAKE([-Wno-portability 1.11 no-dist-gzip dist-xz tar-ustar])
  12
  13 dnl define PACKAGE_VERSION_* variables
  14 AS_VERSION
  15
  16 dnl check if this is a release version
  17 AS_NANO(GST_GIT="no", GST_GIT="yes")
  18
  19 dnl can autoconf find the source ?
  20 AC_CONFIG_SRCDIR([gst/gst.c])
  21
  22 dnl define the output header for config
  23 AC_CONFIG_HEADERS([config.h])
  24
  25 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  26 AM_MAINTAINER_MODE([enable])
  27
  28 dnl sets host_* variables
  29 AC_CANONICAL_HOST
  30
  31 dnl use pretty build output with automake >= 1.11
  32 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],
  33   [AM_DEFAULT_VERBOSITY=1
  34    AC_SUBST(AM_DEFAULT_VERBOSITY)])
  35
  36 dnl GStreamer versioning, this is mostly informational
  37 GST_VERSION_MAJOR=$PACKAGE_VERSION_MAJOR
  38 GST_VERSION_MINOR=$PACKAGE_VERSION_MINOR
  39 GST_VERSION_MICRO=$PACKAGE_VERSION_MICRO
  40 GST_VERSION_NANO=$PACKAGE_VERSION_NANO
  41 AC_SUBST(GST_VERSION_MAJOR)
  42 AC_SUBST(GST_VERSION_MINOR)
  43 AC_SUBST(GST_VERSION_MICRO)
  44 AC_SUBST(GST_VERSION_NANO)
  45
  46 dnl our libraries and install dirs use GST_API_VERSION in the filename
  47 dnl to allow side-by-side installation of different API versions
  48 GST_API_VERSION=1.0
  49 AC_SUBST(GST_API_VERSION)
  50 AC_DEFINE_UNQUOTED(GST_API_VERSION, "$GST_API_VERSION",
  51   [GStreamer API Version])
  52
  53 dnl CURRENT, REVISION, AGE
  54 dnl - library source changed -> increment REVISION
  55 dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
  56 dnl - interfaces added -> increment AGE
  57 dnl - interfaces removed -> AGE = 0
  58 dnl
  59 dnl Keep CURRENT as MINOR * 100 + MICRO
  60 dnl Ex : 1.0.0 => 0
  61 dnl      1.0.3 => 3
  62 dnl      1.1.0 => 100
  63 dnl      1.2.5 => 205
  64 dnl      1.10.9 (who knows) => 1009
  65 dnl
  66 dnl sets GST_LT_LDFLAGS
  67 AS_LIBTOOL(GST, 102, 0, 102)
  68
  69 dnl *** autotools stuff ****
  70
  71 dnl allow for different autotools
  72 AS_AUTOTOOLS_ALTERNATE
  73
  74 dnl Add parameters for aclocal (keep in sync with Makefile.am)
  75 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  76
  77 dnl set up gettext
  78 dnl the version check needs to stay here because autopoint greps for it
  79 AM_GNU_GETTEXT_VERSION([0.17])
  80 AM_GNU_GETTEXT([external])
  81 AG_GST_GETTEXT([gstreamer-$GST_API_VERSION])
  82
  83 dnl *** check for arguments to configure ***
  84
  85 AG_GST_ARG_DISABLE_FATAL_WARNINGS
  86
  87 dnl subsystems - can influence other decisions so needs to be high up
  88 dnl we need to AM_CONDITIONAL them here for automake 1.6.x compatibility
  89 AG_GST_CHECK_SUBSYSTEM_DISABLE(GST_DEBUG,[debugging subsystem])
  90 AM_CONDITIONAL(GST_DISABLE_GST_DEBUG, test "x$GST_DISABLE_GST_DEBUG" = "xyes")
  91 AG_GST_CHECK_SUBSYSTEM_DISABLE(PARSE,[command-line parser])
  92 AM_CONDITIONAL(GST_DISABLE_PARSE, test "x$GST_DISABLE_PARSE" = "xyes")
  93 if test "x$GST_DISABLE_PARSE" = xyes; then
  94   AC_DEFINE(GST_DISABLE_PARSE, 1,
  95     [Define if pipeline parsing code is disabled])
  96 fi
  97 AG_GST_CHECK_SUBSYSTEM_DISABLE(OPTION_PARSING,[option parsing when gst_init])
  98 AM_CONDITIONAL(GST_DISABLE_OPTION_PARSING, test "x$GST_DISABLE_OPTION_PARSING" = "xyes")
  99 if test "x$GST_DISABLE_OPTION_PARSING" = xyes; then
 100   AC_DEFINE(GST_DISABLE_OPTION_PARSING, 1,
 101     [Define if option parsing is disabled])
 102 fi
 103 AG_GST_CHECK_SUBSYSTEM_DISABLE(TRACE,[tracing subsystem])
 104 AM_CONDITIONAL(GST_DISABLE_TRACE, test "x$GST_DISABLE_TRACE" = "xyes")
 105 AG_GST_CHECK_SUBSYSTEM_DISABLE(ALLOC_TRACE,[allocation tracing])
 106 AM_CONDITIONAL(GST_DISABLE_ALLOC_TRACE, test "x$GST_DISABLE_ALLOC_TRACE" = "xyes")
 107 AG_GST_CHECK_SUBSYSTEM_DISABLE(REGISTRY,[plugin registry])
 108 AM_CONDITIONAL(GST_DISABLE_REGISTRY, test "x$GST_DISABLE_REGISTRY" = "xyes")
 109 dnl define a substitution to use in docs/gst/gstreamer.types
 110 if test "x$GST_DISABLE_REGISTRY" = "xyes"
 111 then
 112   GST_REGISTRY_DOC_TYPES="%"
 113 else
 114   GST_REGISTRY_DOC_TYPES=
 115 fi
 116 AC_SUBST(GST_REGISTRY_DOC_TYPES)
 117 AG_GST_CHECK_SUBSYSTEM_DISABLE(PLUGIN,[plugin])
 118 AM_CONDITIONAL(GST_DISABLE_PLUGIN, test "x$GST_DISABLE_PLUGIN" = "xyes")
 119
 120 AG_GST_ARG_DEBUG
 121 AG_GST_ARG_PROFILING
 122 AG_GST_ARG_VALGRIND
 123 AG_GST_ARG_GCOV
 124
 125 AG_GST_ARG_EXAMPLES
 126
 127 AG_GST_ARG_WITH_PKG_CONFIG_PATH
 128 AG_GST_ARG_WITH_PACKAGE_NAME
 129 AG_GST_ARG_WITH_PACKAGE_ORIGIN
 130
 131 AG_GST_PKG_CONFIG_PATH
 132
 133 AG_GST_SET_PACKAGE_RELEASE_DATETIME_WITH_NANO([$PACKAGE_VERSION_NANO],
 134   ["${srcdir}/gstreamer.doap"],
 135   [$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_MICRO])
 136
 137 dnl build static plugins or not
 138 AC_MSG_CHECKING([whether to build static plugins or not])
 139 AC_ARG_ENABLE(
 140   static-plugins,
 141   AC_HELP_STRING(
 142     [--enable-static-plugins],
 143     [build static plugins @<:@default=no@:>@]),
 144   [AS_CASE(
 145     [$enableval], [no], [], [yes], [],
 146     [AC_MSG_ERROR([bad value "$enableval" for --enable-static-plugins])])],
 147   [enable_static_plugins=no])
 148 AC_MSG_RESULT([$enable_static_plugins])
 149 if test "x$enable_static_plugins" = xyes; then
 150   AC_DEFINE(GST_PLUGIN_BUILD_STATIC, 1,
 151     [Define if static plugins should be built])
 152   GST_PLUGIN_LIBTOOLFLAGS=""
 153 else
 154   GST_PLUGIN_LIBTOOLFLAGS="--tag=disable-static"
 155 fi
 156 AC_SUBST(GST_PLUGIN_LIBTOOLFLAGS)
 157 AM_CONDITIONAL(GST_PLUGIN_BUILD_STATIC, test "x$enable_static_plugins" = "xyes")
 158
 159 dnl building of tests
 160 AC_ARG_ENABLE(tests,
 161   AS_HELP_STRING([--disable-tests],[disable building test apps]),
 162   [
 163     case "${enableval}" in
 164       yes) BUILD_TESTS=yes ;;
 165       no)  BUILD_TESTS=no ;;
 166       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-tests) ;;
 167     esac
 168   ],
 169 [BUILD_TESTS=yes]) dnl Default value
 170 AM_CONDITIONAL(BUILD_TESTS,         test "x$BUILD_TESTS" = "xyes")
 171
 172 dnl tests known to fail
 173 AC_ARG_ENABLE(failing-tests,
 174   AS_HELP_STRING([--disable-failing-tests],[disable building tests known to fail]),
 175   [
 176     case "${enableval}" in
 177       yes) BUILD_FAILING_TESTS=yes ;;
 178       no)  BUILD_FAILING_TESTS=no ;;
 179       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-failing-tests) ;;
 180     esac
 181   ],
 182   [BUILD_FAILING_TESTS=no]) dnl Default value
 183 AM_CONDITIONAL(BUILD_FAILING_TESTS, test "x$BUILD_FAILING_TESTS" = "xyes")
 184 if test x$BUILD_FAILING_TESTS = xyes; then
 185   AC_MSG_WARN([building tests known to fail, use --disable-failing-tests to disable])
 186 else
 187   AC_MSG_WARN([Sissy ! By asking to not build the tests known to fail, you hereby waive your right to customer support.  If you do not agree with this EULA, please press Ctrl-C before the next line is printed.  By allowing the next line to be printed, you expressly acknowledge your acceptance of this EULA.])
 188 fi
 189
 190 dnl building of benchmarks
 191 AC_ARG_ENABLE(benchmarks,
 192   AS_HELP_STRING([--disable-benchmarks],[disable building benchmarks apps]),
 193   [
 194     case "${enableval}" in
 195       yes) BUILD_BENCHMARKS=yes ;;
 196       no)  BUILD_BENCHMARKS=no ;;
 197       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-benchmarks) ;;
 198     esac
 199   ],
 200 [BUILD_BENCHMARKS=yes]) dnl Default value
 201 AM_CONDITIONAL(BUILD_BENCHMARKS, test "x$BUILD_BENCHMARKS" = "xyes")
 202
 203 dnl building of tools
 204 AC_ARG_ENABLE(tools,
 205   AS_HELP_STRING([--disable-tools],[disable building tools]),
 206   [
 207     case "${enableval}" in
 208       yes) BUILD_TOOLS=yes ;;
 209       no)  BUILD_TOOLS=no ;;
 210       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-tools) ;;
 211     esac
 212   ],
 213 [BUILD_TOOLS=yes]) dnl Default value
 214 AM_CONDITIONAL(BUILD_TOOLS, test "x$BUILD_TOOLS" = "xyes")
 215
 216 dnl poison destroyed objects
 217 AC_ARG_ENABLE(poisoning,
 218   AS_HELP_STRING([--enable-poisoning],[enable poisoning of deallocated objects]),
 219   [
 220     case "${enableval}" in
 221       yes) USE_POISONING=yes ;;
 222       no)  USE_POISONING=no ;;
 223       *)   AC_MSG_ERROR(bad value ${enableval} for --enable-poisoning) ;;
 224     esac
 225   ],
 226   [USE_POISONING=no]) dnl Default value
 227 if test "x$USE_POISONING" = xyes; then
 228   AC_DEFINE(USE_POISONING, 1,
 229     [Define if we should poison deallocated memory])
 230 fi
 231
 232 dnl *** checks for platform ***
 233
 234 dnl * hardware/architecture *
 235
 236 dnl common/m4/gst-arch.m4
 237 dnl check CPU type
 238 AG_GST_ARCH
 239 dnl substitution for win32/common/config.h
 240 HOST_CPU=$host_cpu
 241 AC_SUBST(HOST_CPU)
 242
 243 dnl common/m4/gst-arch.m4
 244 dnl check for unaligned access
 245 AG_GST_UNALIGNED_ACCESS
 246 dnl create a configure variable for gst/gstconfig.h
 247 if test x${as_cv_unaligned_access} = xyes ; then
 248   GST_HAVE_UNALIGNED_ACCESS_DEFINE="#define GST_HAVE_UNALIGNED_ACCESS 1"
 249 else
 250   GST_HAVE_UNALIGNED_ACCESS_DEFINE="#define GST_HAVE_UNALIGNED_ACCESS 0"
 251 fi
 252 AC_SUBST(GST_HAVE_UNALIGNED_ACCESS_DEFINE)
 253
 254 dnl check for platform specific settings
 255 AG_GST_PLATFORM
 256
 257 dnl * software *
 258
 259 dnl check for large file support
 260 dnl affected plugins must include config.h
 261 AC_SYS_LARGEFILE
 262
 263 dnl *** checks for programs ***
 264
 265 dnl find a compiler
 266 AC_PROG_CC
 267 AC_PROG_CC_STDC
 268
 269 dnl check if the compiler supports '-c' and '-o' options
 270 AM_PROG_CC_C_O
 271
 272 dnl find an assembler
 273 AM_PROG_AS
 274
 275 dnl determine if c++ is available on this system
 276 AC_PROG_CXX
 277 dnl CXX may be set to some default even if no c++ compiler is available
 278 dnl (thanks autotools!), so just try to compile some c++ code to make sure
 279 AC_LANG_PUSH([C++])
 280 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[ class Foo { int bar; };]], [[]])],[working_cxx=yes],[working_cxx=no])
 281 AC_LANG_POP([C++])
 282 AC_MSG_NOTICE([working c++ compiler found: $working_cxx])
 283 AM_CONDITIONAL(HAVE_CXX, test "x$working_cxx" = "xyes")
 284
 285 dnl Perl is used in building documentation and in the version checks
 286 AC_PATH_PROG(PERL_PATH, perl, no)
 287 if test x$PERL_PATH = xno; then
 288   AC_MSG_ERROR(Could not find perl)
 289 fi
 290
 291 dnl we require flex and bison for building the parser
 292 if test "x$GST_DISABLE_PARSE" != xyes; then
 293   AG_GST_BISON_CHECK
 294   AG_GST_FLEX_CHECK
 295 fi
 296
 297 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 298 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 299
 300 dnl check for gobject-introspection
 301 GOBJECT_INTROSPECTION_CHECK([1.31.1])
 302
 303 dnl check for documentation tools
 304 AG_GST_DOCBOOK_CHECK
 305 GTK_DOC_CHECK([1.12])
 306 AG_GST_PLUGIN_DOCS([1.12])
 307
 308 dnl *** checks for libraries ***
 309
 310 dnl check for libm, for sin()
 311 LT_LIB_M
 312 AC_SUBST(LIBM)
 313
 314 dnl *** checks for header files ***
 315
 316 dnl check if we have ANSI C header files
 317 AC_HEADER_STDC
 318
 319 dnl Check for ucontext.h
 320 AC_CHECK_HEADERS([ucontext.h], [], [], [AC_INCLUDES_DEFAULT])
 321
 322 dnl Check for sys/socket.h
 323 AC_CHECK_HEADERS([sys/socket.h], [HAVE_SYS_SOCKET_H=yes], [HAVE_SYS_SOCKET_H=no], [AC_INCLUDES_DEFAULT])
 324 AM_CONDITIONAL(HAVE_SYS_SOCKET_H, test "x$HAVE_SYS_SOCKET_H" = "xyes")
 325
 326 dnl check for sys/times.h for tests/examples/adapter/
 327 AC_CHECK_HEADERS([sys/times.h], [HAVE_SYS_TIMES_H=yes], [HAVE_SYS_TIME_H=no], [AC_INCLUDES_DEFAULT])
 328 AC_CHECK_HEADERS([unistd.h], [HAVE_UNISTD_H=yes], [HAVE_UNISTD_H=no], [AC_INCLUDES_DEFAULT])
 329 AM_CONDITIONAL(HAVE_SYS_TIMES_H_AND_UNISTD_H, test "x$HAVE_SYS_TIMES_H" = "xyes" -a "x$HAVE_UNISTD_H" = "xyes")
 330
 331 dnl Check for process.h for getpid() on win32
 332 AC_CHECK_HEADERS([process.h], [], [], [AC_INCLUDES_DEFAULT])
 333
 334 dnl Check for sys/utsname.h for uname
 335 AC_CHECK_HEADERS([sys/utsname.h], [], [], [AC_INCLUDES_DEFAULT])
 336
 337 dnl Check for stdio_ext.f for __fbufsize
 338 AC_CHECK_HEADERS([stdio_ext.h], [], [], [AC_INCLUDES_DEFAULT])
 339
 340 dnl check for pthreads
 341 AX_PTHREAD([HAVE_PTHREAD=yes], [HAVE_PTHREAD=no])
 342 AM_CONDITIONAL(HAVE_PTHREAD, test "x$HAVE_PTHREAD" = "xyes")
 343
 344 dnl check for sys/prctl for setting thread name on Linux
 345 AC_CHECK_HEADERS([sys/prctl.h], [], [], [AC_INCLUDES_DEFAULT])
 346
 347 dnl Check for valgrind.h
 348 dnl separate from HAVE_VALGRIND because you can have the program, but not
 349 dnl the dev package
 350 AC_CHECK_HEADERS([valgrind/valgrind.h], [], [], [AC_INCLUDES_DEFAULT])
 351
 352 dnl used in gst/gstpoll.c
 353 AC_CHECK_HEADERS([winsock2.h], [HAVE_WINSOCK2_H=yes], [HAVE_WINSOCK2_H=no], [AC_INCLUDES_DEFAULT])
 354 AM_CONDITIONAL(HAVE_WINSOCK2_H, test "x$HAVE_WINSOCK2_H" = "xyes")
 355 if test "x$HAVE_WINSOCK2_H" = "xyes"; then
 356   WIN32_LIBS="-lws2_32"
 357   AC_SUBST(WIN32_LIBS)
 358 fi
 359
 360 dnl check for GMP/GSL, used by the gst_util_uint64_scale unit test only
 361 if test "x$BUILD_TESTS" = "xyes"; then
 362   AG_GST_CHECK_LIBHEADER(GMP, gmp,
 363                          __gmpz_init_set_d, ,
 364                          gmp.h,
 365                          GMP_LIBS="-lgmp"
 366                          AC_SUBST(GMP_LIBS)
 367                          AC_DEFINE(HAVE_GMP, [1],[Have GMP library]))
 368   AG_GST_CHECK_LIBHEADER(GSL, gsl,
 369                          gsl_rng_uniform_int, -lgslcblas,
 370                          gsl/gsl_rng.h,
 371                          GSL_LIBS="-lgsl -lgslcblas"
 372                          AC_SUBST(GSL_LIBS)
 373                          AC_DEFINE(HAVE_GSL, [1],[Have GSL library]))
 374 fi
 375
 376 dnl *** checks for types/defines ***
 377
 378 dnl *** checks for structures ***
 379
 380 dnl *** checks for compiler characteristics ***
 381
 382 dnl check if the compiler supports __uint128_t (gcc)
 383 dnl Actually check for 128-bit division, since that's what we use
 384 dnl uint128_t for.
 385 AC_CACHE_CHECK(for __uint128_t, gst_cv_uint128_t,
 386     AC_LINK_IFELSE([AC_LANG_PROGRAM([[ ]], [[
 387       static __uint128_t v1 = 100;
 388       static __uint128_t v2 = 10;
 389       static __uint128_t u;
 390       u = v1 / v2;
 391     ]])],[
 392       gst_cv_uint128_t=yes
 393     ],[
 394       gst_cv_uint128_t=no
 395     ])
 396 )
 397 if test x$gst_cv_uint128_t = xyes; then
 398   AC_DEFINE(HAVE_UINT128_T, 1, [Have __uint128_t type])
 399 fi
 400
 401 dnl *** checking for tm_gmtoff ***
 402 AC_MSG_CHECKING([for tm_gmtoff])
 403 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 404         #include <time.h>
 405         int main(void) {
 406           struct tm t;
 407           t.tm_gmtoff = 0;
 408           exit(0);
 409         }]])],
 410   [have_tm_gmtoff=yes
 411    AC_DEFINE(HAVE_TM_GMTOFF,1,[Have tm_gmtoff field in struct tm])],
 412   [have_tm_gmtoff=no],
 413   [have_tm_gmtoff="no (cross compiling)"])
 414 AC_MSG_RESULT($have_tm_gmtoff)
 415
 416
 417 dnl *** checks for library functions ***
 418
 419 AC_CHECK_FUNCS([gmtime_r])
 420 AC_CHECK_FUNCS([localtime_r])
 421 AC_CHECK_FUNCS([sigaction])
 422
 423 dnl check for fseeko()
 424 AC_FUNC_FSEEKO
 425 dnl check for ftello()
 426 AC_CHECK_FUNCS([ftello])
 427
 428 AC_CHECK_FUNCS([fgetpos])
 429 AC_CHECK_FUNCS([fsetpos])
 430
 431 dnl check for poll(), ppoll() and pselect()
 432 AC_CHECK_HEADERS([sys/poll.h], [], [], [AC_INCLUDES_DEFAULT])
 433 AC_CHECK_HEADERS([poll.h], [], [], [AC_INCLUDES_DEFAULT])
 434 AC_CHECK_FUNCS([poll])
 435 AC_CHECK_FUNCS([ppoll])
 436 AC_CHECK_FUNCS([pselect])
 437
 438 dnl ****************************************
 439 dnl *** GLib POLL* compatibility defines ***
 440 dnl ****************************************
 441
 442 AC_MSG_CHECKING([for broken poll])
 443 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 444         #include <stdlib.h>
 445         #include <fcntl.h>
 446         #ifdef HAVE_SYS_POLL_H
 447         #include <sys/poll.h>
 448         #endif
 449         #ifdef HAVE_POLL_H
 450         #include <poll.h>
 451         #endif
 452         int main(void) {
 453           struct pollfd fds[1];
 454           int fd;
 455           fd = open("/dev/null", 1);
 456           fds[0].fd = fd;
 457           fds[0].events = POLLIN;
 458           fds[0].revents = 0;
 459           if (poll(fds, 1, 0) < 0 || (fds[0].revents & POLLNVAL) != 0) {
 460                 exit(1);  /* Does not work for devices -- fail */
 461           }
 462           exit(0);
 463         }]])],
 464   [broken_poll=no],
 465   [broken_poll=yes
 466    AC_DEFINE(BROKEN_POLL,1,[poll doesn't work on devices])],
 467   [broken_poll="no (cross compiling)"])
 468 AC_MSG_RESULT($broken_poll)
 469
 470 dnl check for mmap()
 471 AC_FUNC_MMAP
 472 AM_CONDITIONAL(HAVE_MMAP, test "x$ac_cv_func_mmap_fixed_mapped" = "xyes")
 473
 474 dnl check for posix_memalign(), getpagesize()
 475 AC_CHECK_FUNCS([posix_memalign])
 476 AC_CHECK_FUNCS([getpagesize])
 477
 478 dnl Check for POSIX timers
 479 AC_CHECK_FUNCS(clock_gettime, [], [
 480   AC_CHECK_LIB(rt, clock_gettime, [
 481     AC_DEFINE(HAVE_CLOCK_GETTIME, 1)
 482     LIBS="$LIBS -lrt"
 483   ], [
 484     AC_CHECK_LIB(pthread, clock_gettime, [
 485       AC_DEFINE(HAVE_CLOCK_GETTIME, 1)
 486       LIBS="$LIBS -lpthread"
 487     ])
 488   ])
 489 ])
 490
 491 AC_CACHE_CHECK(for posix timers, gst_cv_posix_timers,
 492     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 493 #include <time.h>
 494 #ifdef HAVE_UNISTD_H
 495 #include <unistd.h>
 496 #endif
 497     ]], [[
 498 #if !defined(_POSIX_TIMERS) || _POSIX_TIMERS < 0 || !defined(CLOCK_REALTIME)
 499 #error Either _POSIX_TIMERS or CLOCK_REALTIME not defined
 500 #endif
 501     ]])],[
 502       gst_cv_posix_timers=yes
 503     ],[
 504       gst_cv_posix_timers=no
 505     ])
 506 )
 507
 508 if test "$gst_cv_posix_timers" = "yes"; then
 509   AC_DEFINE(HAVE_POSIX_TIMERS,1,[Have posix timers])
 510   GST_HAVE_POSIX_TIMERS_DEFINE="#define GST_HAVE_POSIX_TIMERS 1"
 511 else
 512   GST_HAVE_POSIX_TIMERS_DEFINE="#define GST_HAVE_POSIX_TIMERS 0"
 513 fi
 514 AC_SUBST(GST_HAVE_POSIX_TIMERS_DEFINE)
 515 AM_CONDITIONAL(GST_HAVE_POSIX_TIMERS, test "$gst_cv_posix_timers" = "yes")
 516
 517 AC_CACHE_CHECK(for monotonic clock, gst_cv_monotonic_clock,
 518     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 519 #include <time.h>
 520 #ifdef HAVE_UNISTD_H
 521 #include <unistd.h>
 522 #endif
 523     ]], [[
 524 #if !defined(_POSIX_MONOTONIC_CLOCK) || _POSIX_MONOTONIC_CLOCK < 0 || !defined(CLOCK_MONOTONIC)
 525 #error Either _POSIX_MONOTONIC_CLOCK or CLOCK_MONOTONIC not defined
 526 #endif
 527     ]])],[
 528       gst_cv_monotonic_clock=yes
 529     ],[
 530       gst_cv_monotonic_clock=no
 531     ])
 532 )
 533
 534 if test "$gst_cv_monotonic_clock" = "yes"; then
 535   AC_DEFINE(HAVE_MONOTONIC_CLOCK,1,[Have a monotonic clock])
 536   GST_HAVE_MONOTONIC_CLOCK_DEFINE="#define GST_HAVE_MONOTONIC_CLOCK 1"
 537 else
 538   GST_HAVE_MONOTONIC_CLOCK_DEFINE="#define GST_HAVE_MONOTONIC_CLOCK 0"
 539 fi
 540 AC_SUBST(GST_HAVE_MONOTONIC_CLOCK_DEFINE)
 541 AM_CONDITIONAL(GST_HAVE_MONOTONIC_CLOCK, test "$gst_cv_monotonic_clock" = "yes")
 542
 543 dnl Check for a way to display the function name in debug output
 544 AG_GST_CHECK_FUNCTION
 545
 546 dnl test if we have dladdr(); we use it for debugging; see gst/gstinfo.c
 547 save_cflags="$CFLAGS"
 548 CFLAGS="$CFLAGS -D_GNU_SOURCE"
 549 AC_CHECK_LIB(dl, dladdr,
 550    AC_DEFINE(HAVE_DLADDR, 1, [Defined if we have dladdr ()])
 551    LIBS="$LIBS -ldl")
 552 CFLAGS="$save_cflags"
 553
 554 dnl Check printf stuff
 555 if test "x${GST_DISABLE_GST_DEBUG}" != "xyes"; then
 556   AC_TYPE_LONG_LONG_INT
 557   AC_TYPE_UNSIGNED_LONG_LONG_INT
 558
 559   if test x$ac_cv_type_long_long_int$ac_cv_type_unsigned_long_long_int = xyesyes; then
 560     AC_DEFINE([HAVE_LONG_LONG], [1], [Define to 1 if the system has the type long long])
 561   fi
 562
 563   dnl /usr/share/aclocal/inttypes_h.m4 - ships with gettext apparently
 564   gl_AC_HEADER_INTTYPES_H
 565
 566   dnl /usr/share/aclocal/stdint_h.m4 - ships with gettext apparently
 567   gl_AC_HEADER_STDINT_H
 568
 569   AC_CHECK_TYPES(ptrdiff_t)
 570
 571   AC_TYPE_INTMAX_T
 572   AC_TYPE_SIZE_T
 573 fi
 574
 575 dnl *** checks for dependency libraries ***
 576
 577 dnl GLib
 578 GLIB_REQ=2.32.0
 579 AG_GST_GLIB_CHECK([$GLIB_REQ])
 580
 581 dnl Check for documentation xrefs
 582 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 583 AC_SUBST(GLIB_PREFIX)
 584
 585 dnl building of unit test libraries
 586 AC_ARG_ENABLE(check,
 587   AS_HELP_STRING([--disable-check],[disable building unit test libraries]),
 588   [
 589     case "${enableval}" in
 590       yes) BUILD_CHECK=yes ;;
 591       no)  BUILD_CHECK=no ;;
 592       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-check) ;;
 593     esac
 594   ], [
 595     dnl Default value
 596     case $host_os in
 597       mingw* | msvc* | mks*) BUILD_CHECK=no ;;
 598       *) BUILD_CHECK=yes ;;
 599     esac
 600 ])
 601 dnl bit of a misnomer, but keep the conditional named like this so we don't
 602 dnl have to change too much elsewhere
 603 AM_CONDITIONAL(HAVE_CHECK, test "x$BUILD_CHECK" = "xyes")
 604
 605 dnl configure the desired memory alignment
 606 AC_ARG_WITH([memory-alignment],
 607   AS_HELP_STRING([--with-memory-alignment],[8,N,malloc,pagesize (default is 32)]),
 608   [
 609     if test "x$withval" = "xyes"
 610     then
 611       AC_DEFINE(MEMORY_ALIGNMENT, 32, [Memory alignment to use])
 612     else
 613       case "${withval}" in
 614         malloc) AC_DEFINE(MEMORY_ALIGNMENT_MALLOC, 1, [Memory alignment by malloc default]) ;;
 615         pagesize)  AC_DEFINE(MEMORY_ALIGNMENT_PAGESIZE, 1, [Memory alignment by pagesize]) ;;
 616         *)   AC_DEFINE_UNQUOTED(MEMORY_ALIGNMENT, ${withval}, [Memory alignment to use]) ;;
 617       esac
 618     fi
 619   ], [
 620     AC_DEFINE(MEMORY_ALIGNMENT_MALLOC, 1, [Memory alignment by malloc default])
 621   ]
 622 )
 623
 624 dnl Check for -Bsymbolic-functions linker flag used to avoid
 625 dnl intra-library PLT jumps, if available.
 626 AC_ARG_ENABLE(Bsymbolic,
 627               [AS_HELP_STRING([--disable-Bsymbolic],[avoid linking with -Bsymbolic])],,
 628               [SAVED_LDFLAGS="${LDFLAGS}"
 629                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
 630                LDFLAGS=-Wl,-Bsymbolic-functions
 631                AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [[int main (void) { return 0; }]])],[
 632                            AC_MSG_RESULT(yes)
 633                            enable_Bsymbolic=yes],[
 634                            AC_MSG_RESULT(no)
 635                            enable_Bsymbolic=no])
 636                LDFLAGS="${SAVED_LDFLAGS}"])
 637
 638
 639 dnl *** set variables based on configure arguments
 640
 641 dnl set license and copyright notice
 642 GST_LICENSE="LGPL"
 643 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 644 AC_SUBST(GST_LICENSE)
 645
 646 dnl define LIBDIR, GST_DATADIR so we can inform people where we live
 647 AS_AC_EXPAND(LIBDIR, $libdir)
 648 AC_DEFINE_UNQUOTED(LIBDIR, "$LIBDIR", [library dir])
 649 AS_AC_EXPAND(DATADIR, $datadir)
 650 AC_DEFINE_UNQUOTED(GST_DATADIR, "$DATADIR", [data dir])
 651
 652 dnl set location of plugin directory
 653 AG_GST_SET_PLUGINDIR
 654
 655 dnl make sure it doesn't complain about unused variables if debugging is disabled
 656 NO_WARNINGS=""
 657 if test "x${GST_DISABLE_GST_DEBUG}" = "xyes"; then
 658   NO_WARNINGS="-Wno-unused"
 659 fi
 660
 661 dnl define an ERROR_CFLAGS Makefile variable
 662 AG_GST_SET_ERROR_CFLAGS($FATAL_WARNINGS, [-Wmissing-declarations -Wmissing-prototypes -Wredundant-decls -Wundef -Wwrite-strings -Wformat-nonliteral -Wformat-security -Wold-style-definition -Winit-self -Wmissing-include-dirs -Waddress -Waggregate-return -Wno-multichar -Wnested-externs $NO_WARNINGS])
 663
 664 dnl special warning flags for gst/printf
 665 AS_COMPILER_FLAG([-Wno-format-nonliteral], [PRINTF_CFLAGS="-Wno-format-nonliteral"])
 666 AC_SUBST(PRINTF_CFLAGS)
 667
 668 dnl define correct level for debugging messages
 669 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 670
 671 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 672
 673 dnl Overview:
 674 dnl GST_OPTION_CFLAGS:  common cflags for profiling, debugging, errors, ...
 675 dnl GST_ALL_*:          vars shared by all built objects
 676 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 677 dnl GST_OBJ_*:          additional vars to link to the core library
 678 dnl                     include GST_ALL_*
 679 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 680 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 681
 682 dnl GST_OPTION_CFLAGS
 683 if test "x$USE_DEBUG" = xyes; then
 684    PROFILE_CFLAGS="-g"
 685 fi
 686 AC_SUBST(PROFILE_CFLAGS)
 687
 688 # GST_DISABLE_DEPRECATED: hide the visibility of deprecated
 689 # functionality from the API that gstreamer uses
 690 # GST_REMOVE_DEPRECATED: don't compile deprecated functionality (breaks ABI)
 691 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
 692   dnl Define _only_ when compiling from git (not for pre-releases or releases)
 693   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 694 else
 695   DEPRECATED_CFLAGS=""
 696 fi
 697 AC_SUBST(DEPRECATED_CFLAGS)
 698
 699 dnl every flag in GST_OPTION_CFLAGS can be overridden at make time via e.g.
 700 dnl make DEPRECATED_CFLAGS=''
 701 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 702 GST_OPTION_CXXFLAGS="\$(WARNING_CXXFLAGS) \$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 703 GST_OPTION_CFLAGS="$GST_OPTION_CFLAGS"
 704 GST_OPTION_CXXFLAGS="$GST_OPTION_CXXFLAGS"
 705 AC_SUBST(GST_OPTION_CFLAGS)
 706 AC_SUBST(GST_OPTION_CXXFLAGS)
 707
 708 dnl GST_ALL_*
 709 dnl vars common to for all internal objects (core libs, elements, applications)
 710 dnl CFLAGS:
 711 dnl - src and build dirs need to be added because every piece that gets built
 712 dnl   will need the GStreamer source and generated headers
 713 dnl LIBS: XML doesn't need to be added because we don't explicitly use symbols
 714 dnl       from LibXML except for in the core library
 715 GST_ALL_CXXFLAGS="-I\$(top_srcdir)/libs -I\$(top_srcdir) -I\$(top_builddir)/libs -I\$(top_builddir) $GLIB_CFLAGS \$(GLIB_EXTRA_CFLAGS) $XML_CFLAGS \$(GST_OPTION_CXXFLAGS) \$(ERROR_CXXFLAGS)"
 716 GST_ALL_CFLAGS="-I\$(top_srcdir)/libs -I\$(top_srcdir) -I\$(top_builddir)/libs -I\$(top_builddir) $GLIB_CFLAGS \$(GLIB_EXTRA_CFLAGS) $XML_CFLAGS \$(GST_OPTION_CFLAGS) \$(ERROR_CFLAGS)"
 717
 718 dnl FIXME: check if LTLIBINTL is needed everywhere
 719 dnl I presume it is given that it contains the symbols that _() stuff maps to
 720 GST_ALL_LIBS="$GLIB_LIBS $LTLIBINTL \$(GCOV_LIBS)"
 721
 722 dnl LDFLAGS really should only contain flags, not libs - they get added before
 723 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 724 GST_ALL_LDFLAGS="-no-undefined"
 725 if test "x${enable_Bsymbolic}" = "xyes"; then
 726   GST_ALL_LDFLAGS="$GST_ALL_LDFLAGS -Wl,-Bsymbolic-functions"
 727 fi
 728
 729 AC_SUBST(GST_ALL_CFLAGS)
 730 AC_SUBST(GST_ALL_CXXFLAGS)
 731 AC_SUBST(GST_ALL_LIBS)
 732 AC_SUBST(GST_ALL_LDFLAGS)
 733
 734 dnl GST_LIB_LDFLAGS
 735 dnl linker flags shared by all libraries
 736 dnl LDFLAGS modifier defining exported symbols from built libraries
 737 GST_LIB_LDFLAGS="-export-symbols-regex \^[_]?\(gst_\|Gst\|GST_\).*"
 738 AC_SUBST(GST_LIB_LDFLAGS)
 739
 740 dnl GST_OBJ_*
 741 dnl default vars for all internal objects built on libgstreamer
 742 dnl includes GST_ALL_*
 743 GST_OBJ_CFLAGS="\$(GST_ALL_CFLAGS)"
 744 GST_OBJ_CXXFLAGS="\$(GST_ALL_CXXFLAGS)"
 745 GST_OBJ_LIBS="\$(top_builddir)/gst/libgstreamer-$GST_API_VERSION.la \$(GST_ALL_LIBS)"
 746 AC_SUBST(GST_OBJ_CFLAGS)
 747 AC_SUBST(GST_OBJ_CXXFLAGS)
 748 AC_SUBST(GST_OBJ_LIBS)
 749
 750 dnl GST_PLUGIN_LDFLAGS
 751 dnl LDFLAGS for plugins; includes GST_ALL_LDFLAGS
 752 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_.*' $GST_ALL_LDFLAGS"
 753 AC_SUBST(GST_PLUGIN_LDFLAGS, "$GST_PLUGIN_LDFLAGS")
 754
 755 dnl plugin scanner locations
 756 AS_AC_EXPAND(GST_PLUGIN_SCANNER_INSTALLED,${libexecdir}/gstreamer-$GST_API_VERSION/gst-plugin-scanner)
 757 AC_DEFINE_UNQUOTED(GST_PLUGIN_SCANNER_INSTALLED,
 758     "$GST_PLUGIN_SCANNER_INSTALLED", [location of the installed gst-plugin-scanner])
 759 AC_SUBST(GST_PLUGIN_SCANNER_INSTALLED)
 760
 761 dnl things for our internal libcheck (must be called even if building
 762 dnl libcheck is disabled because it defines conditionals)
 763 AG_GST_CHECK_CHECKS()
 764
 765 AC_CONFIG_FILES(
 766 Makefile
 767 gst/Makefile
 768 gst/gstconfig.h
 769 gst/gstversion.h
 770 gst/parse/Makefile
 771 gst/printf/Makefile
 772 libs/Makefile
 773 libs/gst/Makefile
 774 libs/gst/base/Makefile
 775 libs/gst/check/Makefile
 776 libs/gst/check/libcheck/Makefile
 777 libs/gst/check/libcheck/check.h
 778 libs/gst/controller/Makefile
 779 libs/gst/helpers/Makefile
 780 libs/gst/net/Makefile
 781 plugins/Makefile
 782 plugins/elements/Makefile
 783 po/Makefile.in
 784 tests/Makefile
 785 tests/benchmarks/Makefile
 786 tests/check/Makefile
 787 tests/misc/Makefile
 788 tests/examples/Makefile
 789 tests/examples/adapter/Makefile
 790 tests/examples/controller/Makefile
 791 tests/examples/stepping/Makefile
 792 tests/examples/helloworld/Makefile
 793 tests/examples/launch/Makefile
 794 tests/examples/manual/Makefile
 795 tests/examples/memory/Makefile
 796 tests/examples/metadata/Makefile
 797 tests/examples/queue/Makefile
 798 tests/examples/streams/Makefile
 799 tests/examples/typefind/Makefile
 800 tools/Makefile
 801 common/Makefile
 802 common/m4/Makefile
 803 docs/Makefile
 804 docs/design/Makefile
 805 docs/faq/Makefile
 806 docs/gst/Makefile
 807 docs/gst/gstreamer.types
 808 docs/libs/Makefile
 809 docs/plugins/Makefile
 810 docs/manual/Makefile
 811 docs/pwg/Makefile
 812 docs/slides/Makefile
 813 docs/xsl/Makefile
 814 docs/version.entities
 815 m4/Makefile
 816 pkgconfig/Makefile
 817 stamp.h
 818 pkgconfig/gstreamer.pc
 819 pkgconfig/gstreamer-uninstalled.pc
 820 pkgconfig/gstreamer-base.pc
 821 pkgconfig/gstreamer-base-uninstalled.pc
 822 pkgconfig/gstreamer-check.pc
 823 pkgconfig/gstreamer-check-uninstalled.pc
 824 pkgconfig/gstreamer-controller.pc
 825 pkgconfig/gstreamer-controller-uninstalled.pc
 826 pkgconfig/gstreamer-net.pc
 827 pkgconfig/gstreamer-net-uninstalled.pc
 828 gstreamer.spec
 829 )
 830
 831 dnl Create the config.h file for Visual Studio builds
 832 dnl Beware of spaces and /'s in some of the shell variable contents.
 833 sed \
 834     -e 's/.*config.h.in.*autoheader.*/\/* Autogenerated config.h created for win32 Visual Studio builds *\/\n\n\/* PREFIX -- specifically added for Windows for easier moving *\/\n#define PREFIX "C:\\\\gstreamer"/' \
 835     -e 's/.* GETTEXT_PACKAGE$/#define GETTEXT_PACKAGE "'$GETTEXT_PACKAGE'"/' \
 836     -e 's/.* GST_DATADIR$/#define GST_DATADIR PREFIX "\\\\share"/' \
 837     -e 's/.* GST_LEVEL_DEFAULT$/#define GST_LEVEL_DEFAULT GST_LEVEL_ERROR/' \
 838     -e 's/.* GST_LICENSE$/#define GST_LICENSE "'$GST_LICENSE'"/' \
 839     -e 's/.* GST_API_VERSION$/#define GST_API_VERSION "'$GST_API_VERSION'"/' \
 840     -e "s,.* GST_PACKAGE_NAME$,#define GST_PACKAGE_NAME \"${GST_PACKAGE_NAME}\"," \
 841     -e 's/.* GST_PACKAGE_ORIGIN$/#define GST_PACKAGE_ORIGIN "Unknown package origin"/' \
 842     -e "s,.* GST_PACKAGE_RELEASE_DATETIME$,#define GST_PACKAGE_RELEASE_DATETIME \"${GST_PACKAGE_RELEASE_DATETIME}\"," \
 843     -e 's/.* HAVE_CPU_I386$/#define HAVE_CPU_I386 1/' \
 844     -e 's/.* HAVE_FGETPOS$/#define HAVE_FGETPOS 1/' \
 845     -e 's/.* HAVE_FSETPOS$/#define HAVE_FSETPOS 1/' \
 846     -e 's/.* HAVE_PROCESS_H$/#define HAVE_PROCESS_H 1/' \
 847     -e 's/.* HAVE_STDLIB_H$/#define HAVE_STDLIB_H 1/' \
 848     -e 's/.* HAVE_STRING_H$/#define HAVE_STRING_H 1/' \
 849     -e 's/.* HAVE_SYS_STAT_H$/#define HAVE_SYS_STAT_H 1/' \
 850     -e 's/.* HAVE_SYS_TYPES_H$/#define HAVE_SYS_TYPES_H 1/' \
 851     -e 's/.* HAVE_WIN32$/#define HAVE_WIN32 1/' \
 852     -e 's/.* HAVE_WINSOCK2_H$/#define HAVE_WINSOCK2_H 1/' \
 853     -e 's/.* HOST_CPU$/#define HOST_CPU "i686"/' \
 854     -e 's/.* MEMORY_ALIGNMENT_MALLOC/#define MEMORY_ALIGNMENT_MALLOC 1/' \
 855     -e 's/.* LIBDIR$/#ifdef _DEBUG\n#  define LIBDIR PREFIX "\\\\debug\\\\lib"\n#else\n#  define LIBDIR PREFIX "\\\\lib"\n#endif/' \
 856     -e 's/.* LOCALEDIR$/#define LOCALEDIR PREFIX "\\\\share\\\\locale"/' \
 857     -e 's/.* PACKAGE$/#define PACKAGE "gstreamer"/' \
 858     -e 's/.* PACKAGE_BUGREPORT$/#define PACKAGE_BUGREPORT "http:\/\/bugzilla.gnome.org\/enter_bug.cgi?product=GStreamer"/' \
 859     -e 's/.* PACKAGE_NAME$/#define PACKAGE_NAME "'$PACKAGE_NAME'"/' \
 860     -e "s/.* PACKAGE_STRING$/#define PACKAGE_STRING \"$PACKAGE_STRING\"/" \
 861     -e 's/.* PACKAGE_TARNAME$/#define PACKAGE_TARNAME "'$PACKAGE_TARNAME'"/' \
 862     -e 's/.* PACKAGE_VERSION$/#define PACKAGE_VERSION "'$PACKAGE_VERSION'"/' \
 863     -e 's/.* PLUGINDIR$/#ifdef _DEBUG\n#  define PLUGINDIR PREFIX "\\\\debug\\\\lib\\\\gstreamer-1.0"\n#else\n#  define PLUGINDIR PREFIX "\\\\lib\\\\gstreamer-1.0"\n#endif/' \
 864     -e 's/.* GST_PLUGIN_SCANNER_INSTALLED$/#define GST_PLUGIN_SCANNER_INSTALLED LIBDIR "\\\\gst-plugin-scanner"/' \
 865     -e 's/.* VERSION$/#define VERSION "'$VERSION'"/' \
 866     config.h.in >win32/common/config.h-new
 867
 868 AC_OUTPUT
 869
 870 dnl negate for output
 871 if test "x${GST_DISABLE_GST_DEBUG}" = "xno"; then enable_gst_debug="yes"; fi
 872 if test "x${GST_DISABLE_PARSE}" = "xno"; then enable_parse="yes"; fi
 873 if test "x${GST_DISABLE_OPTION_PARSING}" = "xno"; then enable_option_parsing="yes"; fi
 874 if test "x${GST_DISABLE_TRACE}" = "xno"; then enable_trace="yes"; fi
 875 if test "x${GST_DISABLE_ALLOC_TRACE}" = "xno"; then enable_alloc_trace="yes"; fi
 876 if test "x${GST_DISABLE_PLUGIN}" = "xno"; then enable_plugin="yes"; fi
 877 if test "x${GST_DISABLE_REGISTRY}" = "xno"; then enable_registry="yes"; fi
 878
 879 echo "
 880
 881 Configuration
 882         Version                    : ${VERSION}
 883         Source code location       : ${srcdir}
 884         Prefix                     : ${prefix}
 885         Compiler                   : ${CC}
 886         Package name               : ${GST_PACKAGE_NAME}
 887         Package origin             : ${GST_PACKAGE_ORIGIN}
 888
 889         Documentation (manuals)    : ${enable_docbook}
 890         Documentation (API)        : ${enable_gtk_doc}
 891
 892         Debug Logging              : ${enable_gst_debug}
 893         Command-line parser        : ${enable_parse}
 894         Option parsing in gst_init : ${enable_option_parsing}
 895         Tracing subsystem          : ${enable_trace}
 896         Allocation tracing         : ${enable_alloc_trace}
 897         Plugin registry            : ${enable_registry}
 898         Plugin support             : ${enable_plugin}
 899         Static plugins             : ${enable_static_plugins}
 900         Unit testing support       : ${BUILD_CHECK}
 901
 902         Debug                      : ${USE_DEBUG}
 903         Profiling                  : ${USE_PROFILING}
 904
 905         Building benchmarks        : ${BUILD_BENCHMARKS}
 906         Building examples          : ${BUILD_EXAMPLES}
 907         Building test apps         : ${BUILD_TESTS}
 908         Building tests that fail   : ${BUILD_FAILING_TESTS}
 909         Building tools             : ${BUILD_TOOLS}
 910 "