configure.ac

   1 AC_PREREQ(2.52)
   2
   3 dnl initialize autoconf
   4 dnl when going to/from release please set the nano (fourth number) right !
   5 dnl releases only do Wall, cvs and prerelease does Werror too
   6 AC_INIT(GStreamer, 0.10.11.1,
   7     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
   8     gstreamer)
   9
  10 dnl initialize automake
  11 AM_INIT_AUTOMAKE
  12
  13 dnl define PACKAGE_VERSION_* variables
  14 AS_VERSION
  15
  16 dnl check if this is a release version
  17 AS_NANO(GST_CVS="no", GST_CVS="yes")
  18
  19 dnl can autoconf find the source ?
  20 AC_CONFIG_SRCDIR([gst/gst.c])
  21
  22 dnl define the output header for config
  23 AM_CONFIG_HEADER([config.h])
  24
  25 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  26 AM_MAINTAINER_MODE
  27
  28 dnl sets host_* variables
  29 AC_CANONICAL_HOST
  30
  31 dnl our libraries and install dirs use major.minor as a version
  32 GST_MAJORMINOR=$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR
  33 dnl we override it here for release candidates for a new series
  34 GST_MAJORMINOR=0.10
  35 AC_SUBST(GST_MAJORMINOR)
  36 AC_DEFINE_UNQUOTED(GST_MAJORMINOR, "$GST_MAJORMINOR",
  37   [library major.minor version])
  38
  39 dnl CURRENT, REVISION, AGE
  40 dnl - library source changed -> increment REVISION
  41 dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
  42 dnl - interfaces added -> increment AGE
  43 dnl - interfaces removed -> AGE = 0
  44 dnl sets GST_LT_LDFLAGS
  45 AS_LIBTOOL(GST, 10, 0, 10)
  46
  47 dnl FIXME: this macro doesn't actually work;
  48 dnl the generated libtool script has no support for the listed tags.
  49 dnl So this needs to be fixed first if we want to use this
  50 dnl AS_LIBTOOL_TAGS
  51
  52 AM_PROG_LIBTOOL
  53
  54 dnl *** autotools stuff ****
  55
  56 dnl allow for different autotools
  57 AS_AUTOTOOLS_ALTERNATE
  58
  59 dnl Add parameters for aclocal
  60 AC_SUBST(ACLOCAL_AMFLAGS, "-I common/m4")
  61
  62 dnl set up gettext
  63 dnl the version check needs to stay here because autopoint greps for it
  64 AM_GNU_GETTEXT_VERSION([0.11.5])
  65 AM_GNU_GETTEXT([external])
  66 GST_GETTEXT([gstreamer-$GST_MAJORMINOR])
  67
  68 dnl *** check for arguments to configure ***
  69
  70 dnl subsystems - can influence other decisions so needs to be high up
  71 dnl we need to AM_CONDITIONAL them here for automake 1.6.x compatibility
  72 GST_CHECK_SUBSYSTEM_DISABLE(GST_DEBUG,[debugging subsystem])
  73 AM_CONDITIONAL(GST_DISABLE_GST_DEBUG, test "x$GST_GST_DISABLE_DEBUG" = "xyes")
  74 GST_CHECK_SUBSYSTEM_DISABLE(LOADSAVE,[pipeline XML load/save])
  75 AM_CONDITIONAL(GST_DISABLE_LOADSAVE, test "x$GST_DISABLE_LOADSAVE" = "xyes")
  76 dnl define a substitution to use in docs/gst/gstreamer.types
  77 if test "x$GST_DISABLE_LOADSAVE" = "xyes"
  78 then
  79   GST_LOADSAVE_DOC_TYPES="%"
  80 else
  81   GST_LOADSAVE_DOC_TYPES=
  82 fi
  83 AC_SUBST(GST_LOADSAVE_DOC_TYPES)
  84 GST_CHECK_SUBSYSTEM_DISABLE(PARSE,[command-line parser])
  85 AM_CONDITIONAL(GST_DISABLE_PARSE, test "x$GST_DISABLE_PARSE" = "xyes")
  86 if test "x$GST_DISABLE_PARSE" = xyes; then
  87   AC_DEFINE(GST_DISABLE_PARSE, 1,
  88     [Define if pipeline parsing code is disabled])
  89 fi
  90 GST_CHECK_SUBSYSTEM_DISABLE(TRACE,[tracing subsystem])
  91 AM_CONDITIONAL(GST_DISABLE_TRACE, test "x$GST_DISABLE_TRACE" = "xyes")
  92 GST_CHECK_SUBSYSTEM_DISABLE(ALLOC_TRACE,[allocation tracing])
  93 AM_CONDITIONAL(GST_DISABLE_ALLOC_TRACE, test "x$GST_DISABLE_ALLOC_TRACE" = "xyes")
  94 GST_CHECK_SUBSYSTEM_DISABLE(REGISTRY,[plugin registry])
  95 AM_CONDITIONAL(GST_DISABLE_REGISTRY, test "x$GST_DISABLE_REGISTRY" = "xyes")
  96 dnl define a substitution to use in docs/gst/gstreamer.types
  97 if test "x$GST_DISABLE_REGISTRY" = "xyes"
  98 then
  99   GST_REGISTRY_DOC_TYPES="%"
 100 else
 101   GST_REGISTRY_DOC_TYPES=
 102 fi
 103 AC_SUBST(GST_REGISTRY_DOC_TYPES)
 104 GST_CHECK_SUBSYSTEM_DISABLE(ENUMTYPES,[enum types])
 105 AM_CONDITIONAL(GST_DISABLE_ENUMTYPES, test "x$GST_DISABLE_ENUMTYPES" = "xyes")
 106 GST_CHECK_SUBSYSTEM_DISABLE(INDEX,[index])
 107 AM_CONDITIONAL(GST_DISABLE_INDEX, test "x$GST_DISABLE_INDEX" = "xyes")
 108 GST_CHECK_SUBSYSTEM_DISABLE(NET,[network distribution])
 109 AM_CONDITIONAL(GST_DISABLE_NET, test "x$GST_DISABLE_NET" = "xyes")
 110 GST_CHECK_SUBSYSTEM_DISABLE(PLUGIN,[plugin])
 111 AM_CONDITIONAL(GST_DISABLE_PLUGIN, test "x$GST_DISABLE_PLUGIN" = "xyes")
 112 GST_CHECK_SUBSYSTEM_DISABLE(URI,[uri handlers])
 113 AM_CONDITIONAL(GST_DISABLE_URI, test "x$GST_DISABLE_URI" = "xyes")
 114
 115 GST_ARG_DEBUG
 116 GST_ARG_PROFILING
 117 GST_ARG_VALGRIND
 118 GST_ARG_GCOV
 119
 120 GST_ARG_EXAMPLES
 121
 122 GST_ARG_WITH_PKG_CONFIG_PATH
 123 GST_ARG_WITH_PACKAGE_NAME
 124 GST_ARG_WITH_PACKAGE_ORIGIN
 125
 126 dnl use a cache dir for storing element registry info.
 127 GST_CACHE_DIR=${localstatedir}/cache/gstreamer-$GST_MAJORMINOR
 128
 129 AC_ARG_WITH(cachedir,
 130   AC_HELP_STRING([--with-cachedir],
 131     [specify path to use for plugin and command completion registries]),
 132   [
 133     case "${withval}" in
 134       yes) AC_MSG_ERROR(bad value ${withval} for --with-cachedir) ;;
 135       no)  AC_MSG_ERROR(bad value ${withval} for --with-cachedir) ;;
 136       *)   GST_CACHE_DIR="${withval}" ;;
 137     esac
 138   ],
 139   [:]) dnl Default value
 140
 141 AS_AC_EXPAND(GST_CACHE_DIR, $GST_CACHE_DIR)
 142 AC_DEFINE_UNQUOTED(GST_CACHE_DIR, "$GST_CACHE_DIR", [Location of registry])
 143 AC_MSG_NOTICE(Using $GST_CACHE_DIR as registry cache dir)
 144
 145 dnl building of tests
 146 AC_ARG_ENABLE(tests,
 147   AC_HELP_STRING([--disable-tests], [disable building test apps]),
 148   [
 149     case "${enableval}" in
 150       yes) BUILD_TESTS=yes ;;
 151       no)  BUILD_TESTS=no ;;
 152       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-tests) ;;
 153     esac
 154   ],
 155 [BUILD_TESTS=yes]) dnl Default value
 156 AM_CONDITIONAL(BUILD_TESTS,         test "x$BUILD_TESTS" = "xyes")
 157
 158 dnl tests known to fail
 159 AC_ARG_ENABLE(failing-tests,
 160   AC_HELP_STRING([--disable-failing-tests],
 161     [disable building tests known to fail]),
 162   [
 163     case "${enableval}" in
 164       yes) BUILD_FAILING_TESTS=yes ;;
 165       no)  BUILD_FAILING_TESTS=no ;;
 166       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-failing-tests) ;;
 167     esac
 168   ],
 169   [BUILD_FAILING_TESTS=no]) dnl Default value
 170 AM_CONDITIONAL(BUILD_FAILING_TESTS, test "x$BUILD_FAILING_TESTS" = "xyes")
 171 if test x$BUILD_FAILING_TESTS = xyes; then
 172   AC_MSG_WARN([building tests known to fail, use --disable-failing-tests to disable])
 173 else
 174   AC_MSG_WARN([Sissy ! By asking to not build the tests known to fail, you hereby waive your right to customer support.  If you do not agree with this EULA, please press Ctrl-C before the next line is printed.  By allowing the next line to be printed, you expressly acknowledge your acceptance of this EULA.])
 175 fi
 176
 177 dnl poison destroyed objects
 178 AC_ARG_ENABLE(poisoning,
 179   AC_HELP_STRING([--enable-poisoning],
 180     [enable poisoning of deallocated objects]),
 181   [
 182     case "${enableval}" in
 183       yes) USE_POISONING=yes ;;
 184       no)  USE_POISONING=no ;;
 185       *)   AC_MSG_ERROR(bad value ${enableval} for --enable-poisoning) ;;
 186     esac
 187   ],
 188   [USE_POISONING=no]) dnl Default value
 189 if test "x$USE_POISONING" = xyes; then
 190   AC_DEFINE(USE_POISONING, 1,
 191     [Define if we should poison deallocated memory])
 192 fi
 193
 194 dnl Use binary registry
 195 AC_ARG_ENABLE(binary-registry,
 196   AC_HELP_STRING([--enable-binary-registry],
 197     [enable experimental binary registry]),
 198   [
 199     case "${enableval}" in
 200       yes) USE_BINARY_REGISTRY=yes ;;
 201       no)  USE_BINARY_REGISTRY=no ;;
 202       *)   AC_MSG_ERROR(bad value ${enableval} for --enable-binary-registry) ;;
 203     esac
 204   ],
 205   [USE_BINARY_REGISTRY=no]) dnl Default value
 206 if test "x$USE_BINARY_REGISTRY" = xyes; then
 207   AC_DEFINE(USE_BINARY_REGISTRY, 1,
 208     [Define if we should use binary registry instead xml registry])
 209 fi
 210
 211 dnl *** checks for platform ***
 212
 213 dnl * hardware/architecture *
 214
 215 dnl common/m4/gst-arch.m4
 216 dnl check CPU type
 217 GST_ARCH
 218 dnl substitution for win32/common/config.h
 219 HOST_CPU=$host_cpu
 220 AC_SUBST(HOST_CPU)
 221
 222 dnl common/m4/gst-arch.m4
 223 dnl check for unaligned access
 224 GST_UNALIGNED_ACCESS
 225 dnl create a configure variable for gst/gstconfig.h
 226 if test x${as_cv_unaligned_access} = xyes ; then
 227   GST_HAVE_UNALIGNED_ACCESS_DEFINE="#define GST_HAVE_UNALIGNED_ACCESS 1"
 228 else
 229   GST_HAVE_UNALIGNED_ACCESS_DEFINE="#define GST_HAVE_UNALIGNED_ACCESS 0"
 230 fi
 231 AC_SUBST(GST_HAVE_UNALIGNED_ACCESS_DEFINE)
 232
 233 dnl * software *
 234
 235 dnl check for large file support
 236 dnl affected plugins must include config.h
 237 AC_SYS_LARGEFILE
 238
 239 dnl HAVE_WIN32 currently means "disable POSIXisms".
 240 case "$host" in
 241   *-*-mingw*)
 242     AC_DEFINE_UNQUOTED(HAVE_WIN32, 1, [Defined if compiling for Windows])
 243     ;;
 244   *)
 245     ;;
 246 esac
 247
 248 dnl *** checks for programs ***
 249
 250 dnl find a compiler
 251 AC_PROG_CC
 252
 253 dnl find an assembler
 254 AM_PROG_AS
 255
 256 dnl Perl is used in building documentation and in the version checks
 257 AC_PATH_PROG(PERL_PATH, perl, no)
 258 if test x$PERL_PATH = xno; then
 259   AC_MSG_ERROR(Could not find perl)
 260 fi
 261
 262 dnl we require flex and bison for building the parser
 263 GST_BISON_CHECK
 264 GST_FLEX_CHECK
 265
 266 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 267 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 268
 269 dnl check for documentation tools
 270 GST_DOCBOOK_CHECK
 271 GTK_DOC_CHECK([1.3])
 272 AS_PATH_PYTHON([2.1])
 273 GST_PLUGIN_DOCS([1.3],[2.1])
 274
 275 dnl *** checks for libraries ***
 276
 277 dnl For interactive UNIX (a Sun thing)
 278 dnl FIXME: this adds -lcposix to LIBS, but I doubt we use LIBS
 279 AC_ISC_POSIX
 280
 281 dnl *** checks for header files ***
 282
 283 dnl check if we have ANSI C header files
 284 AC_HEADER_STDC
 285
 286 dnl Check for ucontext.h
 287 AC_CHECK_HEADERS([ucontext.h])
 288
 289 dnl Check for sys/socket.h
 290 AC_CHECK_HEADERS([sys/socket.h], HAVE_SYS_SOCKET_H=yes)
 291 AM_CONDITIONAL(HAVE_SYS_SOCKET_H, test "x$HAVE_SYS_SOCKET_H" = "xyes")
 292
 293 dnl check for sys/times.h for tests/examples/adapter/
 294 AC_CHECK_HEADERS([sys/times.h], HAVE_SYS_TIMES_H=yes)
 295 AC_CHECK_HEADERS([unistd.h], HAVE_UNISTD_H=yes)
 296 AM_CONDITIONAL(HAVE_SYS_TIMES_H_AND_UNISTD_H, test "x$HAVE_SYS_TIMES_H" = "xyes" -a "x$HAVE_UNISTD_H" = "xyes")
 297
 298 dnl Check for process.h for getpid() on win32
 299 AC_CHECK_HEADERS([process.h])
 300
 301 dnl Check for sys/utsname.h for uname
 302 AC_CHECK_HEADERS([sys/utsname.h])
 303
 304 dnl *** checks for types/defines ***
 305
 306 dnl *** checks for structures ***
 307
 308 dnl *** checks for compiler characteristics ***
 309
 310 dnl make sure we can use "inline" from C code
 311 AC_C_INLINE
 312
 313 OPT_CFLAGS=
 314 dnl Check for some compiler flags that optimize our code.
 315 if test "x$GCC" = xyes; then
 316   AS_COMPILER_FLAG(-fno-common, OPT_CFLAGS="$OPT_CFLAGS -fno-common")
 317 fi
 318
 319 dnl FIXME: decide what kind of flag this is, maybe it's not an optimization
 320 dnl flag
 321 dnl check if we should use -Wa,-mregnames on PowerPC, so we can use
 322 dnl symbolic register names in inline asm
 323 if test x$HAVE_CPU_PPC = xyes ; then
 324   AS_COMPILER_FLAG(["-Wa,-mregnames"],
 325     [OPT_CFLAGS="$OPT_CFLAGS -Wa,-mregnames"])
 326 fi
 327
 328 dnl *** checks for library functions ***
 329
 330 AC_CHECK_FUNCS([sigaction])
 331
 332 dnl we use fork in the registry code
 333 AC_CHECK_FUNCS([fork])
 334
 335 dnl check for fseeko()
 336 AC_FUNC_FSEEKO
 337 dnl check for ftello()
 338 AC_CHECK_FUNCS([ftello])
 339
 340 AC_CHECK_FUNCS([fgetpos])
 341 AC_CHECK_FUNCS([fsetpos])
 342
 343 dnl check for mmap()
 344 AC_FUNC_MMAP
 345 AM_CONDITIONAL(HAVE_MMAP, test "x$ac_cv_func_mmap_fixed_mapped" = "xyes")
 346
 347 dnl Check for a way to display the function name in debug output
 348 GST_CHECK_FUNCTION
 349
 350 dnl test for register_printf_function
 351 AC_CHECK_FUNC(register_printf_function,
 352   [
 353     GST_PRINTF_EXTENSION_POINTER_FORMAT_DEFINE="#define GST_PTR_FORMAT \"P\""
 354     GST_PRINTF_EXTENSION_SEGMENT_FORMAT_DEFINE="#define GST_SEGMENT_FORMAT \"Q\""
 355     GST_USING_PRINTF_EXTENSION_DEFINE="#define GST_USING_PRINTF_EXTENSION"
 356     AC_DEFINE(HAVE_PRINTF_EXTENSION, 1,
 357       [Defined if we have register_printf_function ()])
 358   ], [
 359     GST_PRINTF_EXTENSION_POINTER_FORMAT_DEFINE="#define GST_PTR_FORMAT \"p\""
 360     GST_PRINTF_EXTENSION_SEGMENT_FORMAT_DEFINE="#define GST_SEGMENT_FORMAT \"p\""
 361     GST_USING_PRINTF_EXTENSION_DEFINE="#undef GST_USING_PRINTF_EXTENSION"
 362   ]
 363 )
 364 AC_SUBST(GST_PRINTF_EXTENSION_POINTER_FORMAT_DEFINE)
 365 AC_SUBST(GST_PRINTF_EXTENSION_SEGMENT_FORMAT_DEFINE)
 366 AC_SUBST(GST_USING_PRINTF_EXTENSION_DEFINE)
 367
 368 dnl test if we have dladdr(); we use it for debugging; see gst/gstinfo.c
 369 save_cflags="$CFLAGS"
 370 CFLAGS="$CFLAGS -D_GNU_SOURCE"
 371 AC_CHECK_LIB(dl, dladdr,
 372    AC_DEFINE(HAVE_DLADDR, 1,
 373              [Defined if we have dladdr ()]))
 374 CFLAGS="$save_cflags"
 375
 376 dnl check for inet_aton()
 377 save_libs="$LIBS"
 378 AC_CHECK_FUNC(inet_aton, ,
 379    AC_CHECK_LIB(nsl, inet_aton, ,
 380       AC_CHECK_LIB(socket, inet_aton, ,
 381          AC_CHECK_LIB(resolv, inet_aton, ,[AC_DEFINE(NO_INET_ATON, 1, [Define if you have no native inet_aton() function.])]))))
 382 INET_ATON_LIBS=$LIBS
 383 AC_SUBST(INET_ATON_LIBS)
 384 LIBS="$save_libs"
 385
 386 dnl *** checks for dependency libraries ***
 387
 388 dnl GLib
 389
 390 GST_GLIB_CHECK([2.8])
 391
 392 dnl Guess we need to keep this around until 0.11
 393 GST_HAVE_GLIB_2_8_DEFINE="#define GST_HAVE_GLIB_2_8 1"
 394 AC_SUBST(GST_HAVE_GLIB_2_8_DEFINE)
 395
 396 dnl Check for glib2 without extra fat, useful for the unversioned tool frontends
 397 PKG_CHECK_MODULES(GLIB_ONLY, glib-2.0 >= $GLIB_REQ)
 398
 399 dnl Checks for documentation xrefs
 400 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 401 AC_SUBST(GLIB_PREFIX)
 402
 403 dnl libxml 2, which is/should be optional (FIXME)
 404 dnl (FIXME) if we use binary registry, the DISABLE_REGISTRY check need to go
 405 if test "x$GST_DISABLE_LOADSAVE" = "xyes" && \
 406    test "x$GST_DISABLE_REGISTRY" = "xyes"
 407 then
 408   AC_MSG_NOTICE([Registry and load/save are disabled, not checking for libxml2])
 409 else
 410   dnl check for libxml2 with minimum req version
 411   GST_LIBXML2_CHECK(2.4.9)
 412 fi
 413
 414 dnl check for "check", unit testing library/header
 415 AM_PATH_CHECK(0.9.2,
 416     [
 417         HAVE_CHECK=yes
 418         AC_MSG_NOTICE(CHECK_CFLAGS: $CHECK_CFLAGS)
 419         AC_MSG_NOTICE(CHECK_LIBS: $CHECK_LIBS)
 420     ],
 421     HAVE_CHECK=no)
 422 AM_CONDITIONAL(HAVE_CHECK, test "x$HAVE_CHECK" = "xyes")
 423
 424 dnl *** set variables based on configure arguments
 425
 426 dnl set license and copyright notice
 427 GST_LICENSE="LGPL"
 428 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 429 AC_SUBST(GST_LICENSE)
 430
 431 dnl define LIBDIR so we can inform people where we live
 432 AS_AC_EXPAND(LIBDIR, $libdir)
 433 AC_DEFINE_UNQUOTED(LIBDIR, "$LIBDIR", [library dir])
 434
 435 dnl set location of plugin directory
 436 GST_SET_PLUGINDIR
 437
 438 dnl FIXME: add LIBXML_PKG here
 439 GST_PKG_DEPS="glib-2.0, gobject-2.0, gmodule-no-export-2.0, gthread-2.0"
 440 AC_SUBST(GST_PKG_DEPS)
 441
 442 dnl define an ERROR_CFLAGS Makefile variable
 443 GST_SET_ERROR_CFLAGS($GST_CVS)
 444
 445 dnl define correct level for debugging messages
 446 GST_SET_LEVEL_DEFAULT($GST_CVS)
 447
 448 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 449
 450 dnl Overview:
 451 dnl GST_OPTION_CFLAGS:  common cflags for profiling, debugging, errors, ...
 452 dnl GST_ALL_*:          vars shared by all built objects
 453 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 454 dnl GST_OBJ_*:          additional vars to link to the core library
 455 dnl                     include GST_ALL_*
 456 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 457 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 458
 459 dnl GST_OPTION_CFLAGS
 460 if test "x$USE_DEBUG" = xyes; then
 461    PROFILE_CFLAGS="-g"
 462 fi
 463 AC_SUBST(PROFILE_CFLAGS)
 464
 465 # GST_DISABLE_DEPRECATED: hide the visibility of deprecated
 466 # functionality from the API that gstreamer uses
 467 # GST_REMOVE_DEPRECATED: don't compile deprecated functionality (breaks ABI)
 468 DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 469 AC_SUBST(DEPRECATED_CFLAGS)
 470
 471 dnl every flag in GST_OPTION_CFLAGS can be overridden at make time
 472 GST_OPTION_CFLAGS="\$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 473 AC_SUBST(GST_OPTION_CFLAGS)
 474
 475 dnl GST_ALL_*
 476 dnl vars common to for all internal objects (core libs, elements, applications)
 477 dnl CFLAGS:
 478 dnl - XML needs to be added because xmlPtr is used in core
 479 dnl - src and build dirs need to be added because every piece that gets built
 480 dnl   will need the GStreamer source and generated headers
 481 dnl LIBS: XML doesn't need to be added because we don't explicitly use symbols
 482 dnl       from LibXML except for in the core library
 483 GST_ALL_CFLAGS="-I\$(top_srcdir)/libs -I\$(top_srcdir) -I\$(top_builddir) $GLIB_CFLAGS $XML_CFLAGS \$(GST_OPTION_CFLAGS)"
 484 dnl FIXME: check if LTLIBINTL is needed everywhere
 485 dnl I presume it is given that it contains the symbols that _() stuff maps to
 486 GST_ALL_LIBS="$GLIB_LIBS $LTLIBINTL \$(GCOV_LIBS)"
 487 dnl LDFLAGS really should only contain flags, not libs - they get added before
 488 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 489 GST_ALL_LDFLAGS="-no-undefined"
 490
 491 AC_SUBST(GST_ALL_CFLAGS)
 492 AC_SUBST(GST_ALL_LIBS)
 493 AC_SUBST(GST_ALL_LDFLAGS)
 494
 495 dnl GST_LIB_LDFLAGS
 496 dnl linker flags shared by all libraries
 497 dnl LDFLAGS modifier defining exported symbols from built libraries
 498 GST_LIB_LDFLAGS="-export-symbols-regex \^[_]*\(gst_\|Gst\|GST_\).*"
 499 AC_SUBST(GST_LIB_LDFLAGS)
 500
 501 dnl GST_OBJ_*
 502 dnl default vars for all internal objects built on libgstreamer
 503 dnl includes GST_ALL_*
 504 GST_OBJ_CFLAGS="\$(GST_ALL_CFLAGS)"
 505 GST_OBJ_LIBS="\$(top_builddir)/gst/libgstreamer-$GST_MAJORMINOR.la \$(GST_ALL_LIBS)"
 506 AC_SUBST(GST_OBJ_CFLAGS)
 507 AC_SUBST(GST_OBJ_LIBS)
 508
 509 dnl GST_PLUGIN_LDFLAGS
 510 dnl LDFLAGS for plugins; includes GST_ALL_LDFLAGS
 511 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc\$\$' $GST_ALL_LDFLAGS"
 512 AC_SUBST(GST_PLUGIN_LDFLAGS, "$GST_PLUGIN_LDFLAGS")
 513
 514 AC_CONFIG_FILES(
 515 Makefile
 516 gst/Makefile
 517 gst/gstconfig.h
 518 gst/gstversion.h
 519 gst/parse/Makefile
 520 libs/Makefile
 521 libs/gst/Makefile
 522 libs/gst/base/Makefile
 523 libs/gst/check/Makefile
 524 libs/gst/controller/Makefile
 525 libs/gst/dataprotocol/Makefile
 526 libs/gst/net/Makefile
 527 plugins/Makefile
 528 plugins/indexers/Makefile
 529 plugins/elements/Makefile
 530 po/Makefile.in
 531 tests/Makefile
 532 tests/benchmarks/Makefile
 533 tests/check/Makefile
 534 tests/misc/Makefile
 535 tests/examples/Makefile
 536 tests/examples/adapter/Makefile
 537 tests/examples/controller/Makefile
 538 tests/examples/helloworld/Makefile
 539 tests/examples/launch/Makefile
 540 tests/examples/manual/Makefile
 541 tests/examples/metadata/Makefile
 542 tests/examples/queue/Makefile
 543 tests/examples/typefind/Makefile
 544 tests/examples/xml/Makefile
 545 tools/Makefile
 546 common/Makefile
 547 common/m4/Makefile
 548 docs/Makefile
 549 docs/design/Makefile
 550 docs/faq/Makefile
 551 docs/gst/Makefile
 552 docs/gst/gstreamer.types
 553 docs/libs/Makefile
 554 docs/plugins/Makefile
 555 docs/manual/Makefile
 556 docs/pwg/Makefile
 557 docs/slides/Makefile
 558 docs/xsl/Makefile
 559 docs/version.entities
 560 win32/common/config.h
 561 pkgconfig/Makefile
 562 stamp.h
 563 pkgconfig/gstreamer.pc
 564 pkgconfig/gstreamer-uninstalled.pc
 565 pkgconfig/gstreamer-base.pc
 566 pkgconfig/gstreamer-base-uninstalled.pc
 567 pkgconfig/gstreamer-check.pc
 568 pkgconfig/gstreamer-check-uninstalled.pc
 569 pkgconfig/gstreamer-controller.pc
 570 pkgconfig/gstreamer-controller-uninstalled.pc
 571 pkgconfig/gstreamer-dataprotocol.pc
 572 pkgconfig/gstreamer-dataprotocol-uninstalled.pc
 573 pkgconfig/gstreamer-net.pc
 574 pkgconfig/gstreamer-net-uninstalled.pc
 575 gst-element-check.m4
 576 gstreamer.spec
 577 )
 578
 579 AC_OUTPUT