configure.ac

   1 AC_PREREQ(2.62)
   2 dnl initialize autoconf
   3 dnl when going to/from release please set the nano (fourth number) right !
   4 dnl releases only do Wall, cvs and prerelease does Werror too
   5 AC_INIT([GStreamer RTSP Server Library], [1.3.0.1],
   6     [http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer],
   7     [gst-rtsp-server])
   8 AG_GST_INIT
   9
  10 dnl initialize automake
  11 AM_INIT_AUTOMAKE([-Wno-portability 1.11 no-dist-gzip dist-xz tar-ustar subdir-objects])
  12
  13 dnl define PACKAGE_VERSION_* variables
  14 AS_VERSION
  15
  16 dnl check if this is a release version
  17 AS_NANO(GST_GIT="no", GST_GIT="yes")
  18
  19 dnl can autoconf find the source ?
  20 AC_CONFIG_SRCDIR([gst/rtsp-server/rtsp-server.c])
  21
  22 dnl define the output header for config
  23 AC_CONFIG_HEADERS([config.h])
  24
  25 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  26 AM_MAINTAINER_MODE([enable])
  27
  28 dnl sets host_* variables
  29 AC_CANONICAL_HOST
  30
  31 dnl use pretty build output with automake >= 1.11
  32 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],
  33   [AM_DEFAULT_VERBOSITY=1
  34    AC_SUBST(AM_DEFAULT_VERBOSITY)])
  35
  36 dnl our libraries and install dirs use major.minor as a version
  37 dnl GST_API_VERSION=$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR
  38 dnl we override it here if we need to for the release candidate of new series
  39 GST_API_VERSION=1.0
  40 AC_SUBST(GST_API_VERSION)
  41
  42 dnl CURRENT, REVISION, AGE
  43 dnl - library source changed -> increment REVISION
  44 dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
  45 dnl - interfaces added -> increment AGE
  46 dnl - interfaces removed -> AGE = 0
  47 dnl
  48 dnl Keep CURRENT as MINOR * 100 + MICRO
  49 dnl Ex : 1.0.0 => 0
  50 dnl      1.0.3 => 3
  51 dnl      1.1.0 => 100
  52 dnl      1.2.5 => 205
  53 dnl      1.10.9 (who knows) => 1009
  54 dnl
  55 dnl sets GST_LT_LDFLAGS
  56 AS_LIBTOOL(GST, 300, 0, 300)
  57
  58 dnl *** required versions of GStreamer stuff ***
  59 GST_REQ=1.3.0.1
  60 GSTPB_REQ=1.3.0.1
  61 GSTPG_REQ=1.3.0.1
  62
  63 dnl *** autotools stuff ****
  64
  65 dnl allow for different autotools
  66 AS_AUTOTOOLS_ALTERNATE
  67
  68 dnl Add parameters for aclocal
  69 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  70 AC_CONFIG_MACRO_DIR([m4])
  71
  72 dnl set up gettext
  73 dnl the version check needs to stay here because autopoint greps for it
  74 #AM_GNU_GETTEXT_VERSION([0.17])
  75 #AM_GNU_GETTEXT([external])
  76 #AG_GST_GETTEXT([gst-rtsp-server-$GST_API_VERSION])
  77
  78 dnl *** check for arguments to configure ***
  79
  80 AG_GST_ARG_DISABLE_FATAL_WARNINGS
  81
  82 AG_GST_ARG_DEBUG
  83 AG_GST_ARG_VALGRIND
  84 AG_GST_ARG_GCOV
  85 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  86 AG_GST_ARG_WITH_PACKAGE_NAME
  87 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  88
  89 AG_GST_PKG_CONFIG_PATH
  90
  91 AG_GST_SET_PACKAGE_RELEASE_DATETIME_WITH_NANO([$PACKAGE_VERSION_NANO],
  92   ["${srcdir}/gst-rtsp-server.doap"],
  93   [$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_MICRO])
  94
  95 dnl building of tests
  96 AC_ARG_ENABLE(tests,
  97   AS_HELP_STRING([--disable-tests],[disable building test apps]),
  98   [
  99     case "${enableval}" in
 100       yes) BUILD_TESTS=yes ;;
 101       no)  BUILD_TESTS=no ;;
 102       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-tests) ;;
 103     esac
 104   ],
 105 [BUILD_TESTS=yes]) dnl Default value
 106 AM_CONDITIONAL(BUILD_TESTS,         test "x$BUILD_TESTS" = "xyes")
 107
 108 dnl *** checks for platform ***
 109
 110 dnl * hardware/architecture *
 111
 112 dnl *** checks for programs ***
 113
 114 dnl find a compiler
 115 AC_PROG_CC
 116 AC_PROG_CC_STDC
 117
 118 dnl check if the compiler supports '-c' and '-o' options
 119 AM_PROG_CC_C_O
 120
 121 dnl find an assembler
 122 AM_PROG_AS
 123
 124 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 125 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 126
 127 dnl check for gobject-introspection
 128 GOBJECT_INTROSPECTION_CHECK([1.31.1])
 129
 130 dnl check for documentation tools
 131 AG_GST_DOCBOOK_CHECK
 132 GTK_DOC_CHECK([1.12])
 133
 134 dnl *** checks for libraries ***
 135
 136 dnl *** checks for header files ***
 137
 138 dnl *** checks for types/defines ***
 139
 140 dnl *** checks for structures ***
 141
 142 dnl *** checks for compiler characteristics ***
 143
 144 dnl *** checks for library functions ***
 145
 146 dnl *** checks for dependancy libraries ***
 147
 148 dnl GLib is required
 149 GLIB_REQ=2.32.0
 150 AC_SUBST([GLIB_REQ])
 151 AG_GST_GLIB_CHECK([$GLIB_REQ])
 152
 153 dnl checks for gstreamer
 154 dnl uninstalled is selected preferentially -- see pkg-config(1)
 155 AG_GST_CHECK_GST($GST_API_VERSION, [$GST_REQ], [yes])
 156
 157 GST_TOOLS_DIR=`$PKG_CONFIG --variable=toolsdir gstreamer-$GST_API_VERSION`
 158 if test -z $GST_TOOLS_DIR; then
 159   AC_MSG_ERROR([no tools dir defined in GStreamer pkg-config file; core upgrade needed.])
 160 fi
 161 AC_SUBST(GST_TOOLS_DIR)
 162
 163 GST_PLUGINS_DIR=`$PKG_CONFIG gstreamer-$GST_API_VERSION --variable pluginsdir`
 164 AC_SUBST(GST_PLUGINS_DIR)
 165 AC_MSG_NOTICE(Using GStreamer Core Plugins in $GST_PLUGINS_DIR)
 166
 167 AG_GST_CHECK_GST_BASE($GST_API_VERSION, [$GST_REQ], [yes])
 168
 169 AG_GST_CHECK_GST_PLUGINS_BASE($GST_API_VERSION, [$GSTPB_REQ], [yes])
 170 GSTPB_PLUGINS_DIR=`$PKG_CONFIG gstreamer-plugins-base-$GST_API_VERSION --variable pluginsdir`
 171 AC_SUBST(GSTPB_PLUGINS_DIR)
 172 AC_MSG_NOTICE(Using GStreamer Base Plugins in $GSTPB_PLUGINS_DIR)
 173
 174 AG_GST_CHECK_GST_PLUGINS_GOOD($GST_API_VERSION, [$GSTPG_REQ], [yes])
 175 GSTPG_PLUGINS_DIR=`$PKG_CONFIG gstreamer-plugins-good-$GST_API_VERSION --variable pluginsdir`
 176 AC_SUBST(GSTPG_PLUGINS_DIR)
 177 AC_MSG_NOTICE(Using GStreamer Good Plugins in $GSTPG_PLUGINS_DIR)
 178
 179 AG_GST_CHECK_GST_CHECK($GST_API_VERSION, [$GST_REQ], no)
 180 AM_CONDITIONAL(HAVE_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 181
 182 dnl Check for -Bsymbolic-functions linker flag used to avoid
 183 dnl intra-library PLT jumps, if available.
 184 AC_ARG_ENABLE(Bsymbolic,
 185               [AS_HELP_STRING([--disable-Bsymbolic],[avoid linking with -Bsymbolic])],,
 186               [SAVED_LDFLAGS="${LDFLAGS}"
 187                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
 188                LDFLAGS=-Wl,-Bsymbolic-functions
 189                AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [[int main (void) { return 0; }]])],[
 190                            AC_MSG_RESULT(yes)
 191                            enable_Bsymbolic=yes],[
 192                            AC_MSG_RESULT(no)
 193                            enable_Bsymbolic=no])
 194                LDFLAGS="${SAVED_LDFLAGS}"])
 195
 196 dnl *** set variables based on configure arguments ***
 197
 198 dnl set license and copyright notice
 199 GST_LICENSE="LGPL"
 200 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 201 AC_SUBST(GST_LICENSE)
 202
 203 dnl set location of plugin directory
 204 AG_GST_SET_PLUGINDIR
 205
 206 dnl set release date/time (and check that release version is in doap file)
 207 AG_GST_SET_PACKAGE_RELEASE_DATETIME_WITH_NANO([$PACKAGE_VERSION_NANO],
 208   ["${srcdir}/gst-rtsp-server.doap"],
 209   [$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_MICRO])
 210
 211 # set by AG_GST_PARSE_SUBSYSTEM_DISABLES above
 212 dnl make sure it doesn't complain about unused variables if debugging is disabled
 213 NO_WARNINGS=""
 214 AG_GST_CHECK_GST_DEBUG_DISABLED([NO_WARNINGS="-Wno-unused"], [NO_WARNINGS=""])
 215
 216 dnl define an ERROR_CFLAGS Makefile variable
 217 AG_GST_SET_ERROR_CFLAGS($FATAL_WARNINGS, [-Wmissing-declarations -Wmissing-prototypes -Wredundant-decls -Wundef -Wwrite-strings -Wformat-nonliteral -Wformat-security -Wold-style-definition -Winit-self -Wmissing-include-dirs -Waddress -Waggregate-return -Wno-multichar -Wnested-externs $NO_WARNINGS])
 218
 219 dnl define correct level for debugging messages
 220 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 221
 222 dnl used in examples
 223 AG_GST_DEFAULT_ELEMENTS
 224
 225 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 226
 227 dnl Overview:
 228 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
 229 dnl GST_*:              flags shared by built objects to link against GStreamer
 230 dnl GST_ALL_LDFLAGS:    linker flags shared by all
 231 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 232 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 233 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 234
 235 dnl GST_OPTION_CFLAGS
 236 if test "x$USE_DEBUG" = xyes; then
 237    PROFILE_CFLAGS="-g"
 238 fi
 239 AC_SUBST(PROFILE_CFLAGS)
 240
 241 # GST_DISABLE_DEPRECATED: hide the visibility of deprecated
 242 # functionality from the API that gstreamer uses
 243 # GST_REMOVE_DEPRECATED: don't compile deprecated functionality (breaks ABI)
 244 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
 245   dnl Define _only_ when compiling from git (not for pre-releases or releases)
 246   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 247 else
 248   DEPRECATED_CFLAGS=""
 249 fi
 250 AC_SUBST(DEPRECATED_CFLAGS)
 251
 252 dnl every flag in GST_OPTION_CFLAGS can be overridden at make time
 253 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 254 AC_SUBST(GST_OPTION_CFLAGS)
 255
 256 dnl FIXME: do we want to rename to GST_ALL_* ?
 257 dnl prefer internal headers to already installed ones
 258 dnl add GST_OPTION_CFLAGS, but overridable
 259 GST_CFLAGS="$GST_CFLAGS \$(GST_OPTION_CFLAGS)"
 260 AC_SUBST(GST_CFLAGS)
 261 AC_SUBST(GST_LIBS)
 262
 263 dnl GST_ALL_*
 264 dnl vars common to for all internal objects (core libs, elements, applications)
 265 dnl CFLAGS:
 266 dnl - src and build dirs need to be added because every piece that gets built
 267 dnl   will need the GStreamer source and generated headers
 268 GST_ALL_CFLAGS="-I\$(top_srcdir) -I\$(top_builddir) $GST_PLUGINS_BASE_CFLAGS $GST_CFLAGS \$(GST_OPTION_CFLAGS)"
 269 AC_SUBST([GST_ALL_CFLAGS])
 270
 271 dnl FIXME: check if LTLIBINTL is needed everywhere
 272 dnl I presume it is given that it contains the symbols that _() stuff maps to
 273 GST_ALL_LIBS="$GST_LIBS $LTLIBINTL \$(GCOV_LIBS)"
 274 AC_SUBST([GST_ALL_LIBS])
 275
 276 dnl LDFLAGS really should only contain flags, not libs - they get added before
 277 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 278 GST_ALL_LDFLAGS="-no-undefined"
 279 if test "x${enable_Bsymbolic}" = "xyes"; then
 280   GST_ALL_LDFLAGS="$GST_ALL_LDFLAGS -Wl,-Bsymbolic-functions"
 281 fi
 282
 283 AC_SUBST(GST_ALL_LDFLAGS)
 284
 285 dnl GST_LIB_LDFLAGS
 286 dnl linker flags shared by all libraries
 287 dnl LDFLAGS modifier defining exported symbols from built libraries
 288 GST_LIB_LDFLAGS="-export-symbols-regex \^[_]?\(gst_\|Gst\|GST_\).*"
 289 AC_SUBST(GST_LIB_LDFLAGS)
 290
 291 dnl GST_OBJ_*
 292 dnl default vars for all internal objects built on libgstrtspserver
 293 dnl includes GST_ALL_*
 294 GST_OBJ_CFLAGS="\$(GST_ALL_CFLAGS)"
 295 AC_SUBST([GST_OBJ_CFLAGS])
 296 GST_OBJ_LIBS="\$(top_builddir)/gst/rtsp-server/libgstrtspserver-$GST_API_VERSION.la \$(GST_ALL_LIBS)"
 297 AC_SUBST([GST_OBJ_LIBS])
 298
 299 PKG_CHECK_MODULES(LIBCGROUP, libcgroup >= 0.26, HAVE_LIBCGROUP="yes", HAVE_LIBCGROUP="no")
 300 AC_SUBST(LIBCGROUP_CFLAGS)
 301 AC_SUBST(LIBCGROUP_LIBS)
 302 AM_CONDITIONAL(HAVE_LIBCGROUP, test "x$HAVE_LIBCGROUP" = "xyes")
 303
 304 dnl this really should only contain flags, not libs - they get added before
 305 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 306
 307 dnl *** output files ***
 308
 309 dnl keep this alphabetic per directory, please
 310 AC_CONFIG_FILES([
 311 Makefile
 312 gst-rtsp.spec
 313 common/Makefile
 314 common/m4/Makefile
 315 gst/Makefile
 316 gst/rtsp-server/Makefile
 317 examples/Makefile
 318 tests/Makefile
 319 tests/check/Makefile
 320 pkgconfig/Makefile
 321 pkgconfig/gstreamer-rtsp-server.pc
 322 pkgconfig/gstreamer-rtsp-server-uninstalled.pc
 323 docs/Makefile
 324 docs/version.entities
 325 docs/libs/Makefile
 326 ])
 327 AC_OUTPUT
 328
 329 echo "
 330
 331 Configuration
 332         Version                    : ${VERSION}
 333         Source code location       : ${srcdir}
 334         Prefix                     : ${prefix}
 335         Compiler                   : ${CC}
 336         CGroups example            : ${HAVE_LIBCGROUP}
 337
 338 gst-rtsp-server configured. Type 'make' to build.
 339 "