configure.ac

   1 AC_INIT
   2 AC_CANONICAL_TARGET([])
   3
   4 dnl when going to/from release please set the nano (fourth number) right !
   5 dnl releases only do Wall, cvs and prerelease does Werror too
   6 AS_VERSION(gstreamer, GST_VERSION, 0, 7, 0, 1, GST_CVS="no", GST_CVS="yes")
   7
   8 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
   9 AM_MAINTAINER_MODE
  10 AM_INIT_AUTOMAKE($PACKAGE,$VERSION)
  11
  12 dnl our libraries and install dirs use major.minor as a version
  13 GST_MAJORMINOR=$GST_VERSION_MAJOR.$GST_VERSION_MINOR
  14 AC_SUBST(GST_MAJORMINOR)
  15
  16 AC_PROG_CC
  17 dnl For interactive UNIX (a Sun thing)
  18 AC_ISC_POSIX
  19
  20 dnl CURRENT, REVISION, AGE
  21 dnl - library source changed -> increment REVISION
  22 dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
  23 dnl - interfaces added -> increment AGE
  24 dnl - interfaces removed -> AGE = 0
  25 AS_LIBTOOL(GST, 3, 0, 0)
  26
  27 AC_CONFIG_SRCDIR([gst/gst.c])
  28 AM_CONFIG_HEADER(config.h)
  29
  30 dnl Add parameters for aclocal
  31 dnl (This must come after AM_INIT_AUTOMAKE, since it modifies ACLOCAL)
  32 ACLOCAL="$ACLOCAL -I common/m4 $ACLOCAL_FLAGS"
  33
  34 AM_PROG_CC_STDC
  35 AM_PROG_AS
  36 AS="${CC}"
  37
  38 dnl decide on error flags
  39 AS_COMPILER_FLAG(-Wall,GST_ERROR="$GST_ERROR -Wall",)
  40 if test "x$GST_CVS"="xyes"; then
  41   AS_COMPILER_FLAG(-Werror,GST_ERROR="$GST_ERROR -Werror",)
  42 fi
  43
  44 dnl We disable static building for development, for time savings
  45 dnl *NOTE*: dnl this line before release, so release does static too
  46 dnl AM_DISABLE_STATIC
  47
  48 AC_HEADER_STDC([])
  49
  50
  51 dnl ##############################
  52 dnl # Do automated configuration #
  53 dnl ##############################
  54
  55 dnl Check for tools:
  56 dnl ================
  57
  58 dnl allow for different autotools
  59 AS_AUTOTOOLS_ALTERNATE()
  60
  61 dnl modify pkg-config path
  62 AC_ARG_WITH(pkg-config-path,
  63    AC_HELP_STRING([--with-pkg-config-path],
  64                   [colon-separated list of pkg-config(1) dirs]),
  65    [export PKG_CONFIG_PATH=${withval}])
  66
  67 GST_DOC()
  68 GST_ARCH()
  69
  70 dnl we require bison for building of some of the marshal files
  71 dnl FIXME: check if AC_PROG_YACC is suitable here
  72 AC_PATH_PROG(BISON_PATH, bison, no)
  73 if test x$BISON_PATH = xno; then
  74   AC_MSG_ERROR(Could not find bison)
  75 fi
  76
  77 dnl we require flex for building the parser
  78 dnl FIXME: check if AC_PROG_LEX is suitable here
  79 AC_PATH_PROG(FLEX_PATH, flex, no)
  80 if test x$FLEX_PATH = xno; then
  81   AC_MSG_ERROR(Could not find flex)
  82 fi
  83
  84 dnl
  85 dnl We should really use AC_SYS_LARGEFILE, but the problem is
  86 dnl many of the plugins don't include "config.h".  To assure
  87 dnl binary compatibility, it is necessary that all gstreamer
  88 dnl code be compiled with the same sizeof(off_t), so we use
  89 dnl the following crude hack.
  90 dnl
  91
  92 dnl
  93 dnl GST_CFLAGS are split up as GST_EXT_CFLAGS and GST_INT_CFLAGS
  94 dnl same for libs
  95 dnl this is so we can make GST_CFLAGS for external modules available
  96 dnl without mixing in internal (uninstalled) CFLAGS
  97 dnl
  98
  99 dnl disable deprecated functions internally
 100 GST_INT_CFLAGS="-DGST_DISABLE_DEPRECATED"
 101
 102 AC_MSG_CHECKING(for large file support)
 103 AC_TRY_RUN([
 104 #define _LARGEFILE_SOURCE
 105 #define _FILE_OFFSET_BITS 64
 106 #include <sys/types.h>
 107 int main () { return !(sizeof(off_t) == 8); }
 108 ],
 109 [
 110 AC_MSG_RESULT(yes)
 111 GST_EXT_CFLAGS="-D_LARGEFILE_SOURCE -D_FILE_OFFSET_BITS=64"
 112 ],
 113 [
 114 AC_MSG_RESULT(no)
 115 ],
 116 [
 117 AC_MSG_RESULT(no)
 118 ])
 119
 120 dnl check for makecontext and define HAVE_MAKECONTEXT if we have it
 121 AC_CHECK_MCSC()
 122 if test "$ac_cv_check_mcsc" == "yes"; then
 123   AC_DEFINE_UNQUOTED(HAVE_MAKECONTEXT, $HAVE_MAKECONTEXT,
 124                      [defined if we have makecontext ()])
 125 fi
 126
 127 dnl Check for a way to display the function name in debug output
 128 GST_CHECK_FUNCTION()
 129
 130 dnl Check for essential libraries first:
 131 dnl ====================================
 132
 133 dnl === GLib 2 ===
 134 dnl Minimum required version of GLib2
 135 dnl required for compilation without warnings
 136 GLIB2_REQ="2.0.1"
 137 AC_SUBST(GLIB2_REQ)
 138
 139 dnl Check for glib2
 140 PKG_CHECK_MODULES(GLIB2, glib-2.0 >= $GLIB2_REQ gobject-2.0 gthread-2.0 gmodule-2.0,HAVE_GLIB2=yes,HAVE_GLIB2=no)
 141 GLIB_LIBS=$GLIB2_LIBS
 142 GLIB_CFLAGS=$GLIB2_CFLAGS
 143 AC_SUBST(GLIB_LIBS)
 144 AC_SUBST(GLIB_CFLAGS)
 145
 146 if test "x$HAVE_GLIB2" = "xno"; then
 147   AC_MSG_ERROR([GStreamer requires GLib 2.0 to compile.])
 148 fi
 149
 150 GST_PKG_DEPS="glib-2.0, gobject-2.0, gmodule-2.0, gthread-2.0"
 151 AC_SUBST(GST_PKG_DEPS)
 152
 153 dnl === libxml 2 ===
 154 dnl Minimum required version of libxml2
 155 LIBXML2_REQ="2.4.9"
 156 AC_SUBST(LIBXML2_REQ)
 157
 158 dnl check for libxml2
 159 GST_LIBXML2_CHECK()
 160
 161 dnl popt checks
 162 dnl FIXME: This test passes on popt 1.6.2, maybe earlier, but popt 1.6.2
 163 dnl        causes segfaults on gst_init. Write a working test if possible.
 164 GST_CHECK_LIBHEADER(POPT, popt, poptStrippedArgv,, popt.h, POPT_LIBS="-lpopt",
 165   AC_MSG_ERROR([popt 1.6.3 or newer is required to build gstreamer. You can
 166                 download the latest version from
 167                 ftp://ftp.rpm.org/pub/rpm/dist/])
 168 )
 169 AC_MSG_NOTICE(Checking for POPT_TABLEEND)
 170 AC_COMPILE_IFELSE([
 171 #include <popt.h>
 172 int main ()
 173 {
 174 #ifndef POPT_TABLEEND
 175 #error
 176 #else
 177   return 0;
 178 #endif
 179 }
 180 ],, [
 181   dnl it failed
 182   AC_MSG_ERROR([popt 1.6.3 or newer is required to build gstreamer. You can
 183                 download the latest version from
 184                 ftp://ftp.rpm.org/pub/rpm/dist/])
 185 ])
 186
 187 dnl Check for atomic.h
 188 dnl Note: use AC_CHECK_HEADER not AC_CHECK_HEADERS, because the latter
 189 dnl defines the wrong default symbol as well (HAVE_ASM_ATOMIC_H)
 190 AC_CHECK_HEADER(asm/atomic.h, HAVE_ATOMIC_H=yes, HAVE_ATOMIC_H=no)
 191 dnl Do a compile to check that it has atomic_set (eg, linux 2.0 didn't)
 192 if test x$HAVE_ATOMIC_H = xyes; then
 193   AC_LINK_IFELSE([
 194 #include "asm/atomic.h"
 195 main() {atomic_t t; atomic_set(&t,0); atomic_inc(&t); atomic_add(1,&t);return 0;}
 196   ],, [
 197     # Not successful
 198     if test x$HAVE_ATOMIC_H = xyes; then
 199       AC_MSG_WARN(Atomic reference counting is out of date: doing without.)
 200     fi
 201     HAVE_ATOMIC_H=no
 202   ])
 203 fi
 204
 205 dnl Check for ucontext.h
 206 AC_CHECK_HEADER(ucontext.h, AC_DEFINE(HAVE_UCONTEXT_H, 1, [defined if we have ucontext.h]))
 207
 208 dnl ######################################################################
 209 dnl # Check command line parameters, and set shell variables accordingly #
 210 dnl ######################################################################
 211
 212 dnl FIXME: simplify all this down using a few m4 macros
 213
 214 AC_ARG_ENABLE(libmmx,
 215 AC_HELP_STRING([--enable-libmmx],[use libmmx, if available]),
 216 [case "${enableval}" in
 217   yes) USE_LIBMMX=$HAVE_LIBMMX ;;
 218   no)  USE_LIBMMX=no ;;
 219   *) AC_MSG_ERROR(bad value ${enableval} for --enable-libmmx) ;;
 220 esac],
 221 [USE_LIBMMX=$HAVE_LIBMMX]) dnl Default value
 222
 223 AC_ARG_ENABLE(atomic,
 224 AC_HELP_STRING([--enable-atomic],[use atomic reference counting header]),
 225 [case "${enableval}" in
 226   yes) USE_ATOMIC_H=$HAVE_ATOMIC_H;;
 227   noset) USE_ATOMIC_H=$HAVE_ATOMIC_H;;
 228   no)  USE_ATOMIC_H=no;;
 229   *) AC_MSG_ERROR(bad value ${enableval} for --enable-atomic) ;;
 230 esac],
 231 [USE_ATOMIC_H=$HAVE_ATOMIC_H]) dnl Default value
 232
 233 AC_ARG_ENABLE(plugin-builddir,
 234 AC_HELP_STRING([--enable-plugin-builddir],[allow tests/demos to use non-installed plugins]),
 235 [case "${enableval}" in
 236   yes) PLUGINS_USE_BUILDDIR=yes ;;
 237   no)  PLUGINS_USE_BUILDDIR=no ;;
 238   *) AC_MSG_ERROR(bad value ${enableval} for --enable-plugin-builddir) ;;
 239 esac],
 240 [PLUGINS_USE_BUILDDIR=no]) dnl Default value
 241
 242 GST_DEBUGINFO
 243
 244 AC_ARG_ENABLE(profiling,
 245 AC_HELP_STRING([--enable-profiling],[adds -pg to compiler commandline, for profiling]),
 246 [case "${enableval}" in
 247   yes) USE_PROFILING=yes ;;
 248   no)  UES_PROFILING=no ;;
 249   *) AC_MSG_ERROR(bad value ${enableval} for --enable-profiling) ;;
 250 esac],
 251 [USE_PROFILING=no]) dnl Default value
 252
 253 dnl use a cache dir for storing element registry info.
 254 dnl default to building registry in the source tree if we are enabling plugin build dir
 255 if test "x$PLUGINS_USE_BUILDDIR" = "xyes"; then
 256   GST_CACHE_DIR=`pwd`
 257 else
 258   dnl ${localstatedir} points to PREFIX/var
 259   GST_CACHE_DIR=${localstatedir}/cache/gstreamer-$GST_MAJORMINOR
 260 fi
 261 AC_ARG_WITH(cachedir,
 262 AC_HELP_STRING([--with-cachedir],[specify path to use for plugin and command completion registries]),
 263 [case "${withval}" in
 264   yes) AC_MSG_ERROR(bad value ${withval} for --with-cachedir) ;;
 265   no) AC_MSG_ERROR(bad value ${withval} for --with-cachedir) ;;
 266   *) GST_CACHE_DIR="${withval}" ;;
 267 esac],
 268 [:]) dnl Default value
 269
 270 AS_AC_EXPAND(GST_CACHE_DIR, $GST_CACHE_DIR)
 271 AC_MSG_NOTICE(Using $GST_CACHE_DIR as registry cache dir)
 272
 273
 274 dnl building of tests
 275 AC_ARG_ENABLE(tests,
 276 AC_HELP_STRING([--disable-tests],[disable building test apps]),
 277 [case "${enableval}" in
 278   yes) BUILD_TESTS=yes ;;
 279   no)  BUILD_TESTS=no ;;
 280   *) AC_MSG_ERROR(bad value ${enableval} for --disable-tests) ;;
 281 esac],
 282 [BUILD_TESTS=yes]) dnl Default value
 283 AM_CONDITIONAL(BUILD_TESTS,         test "x$BUILD_TESTS" = "xyes")
 284
 285 dnl tests known to fail
 286 AC_ARG_ENABLE(failing-tests,
 287 AC_HELP_STRING([--disable-failing-tests],[disable building tests known to fail]),
 288 [case "${enableval}" in
 289   yes) BUILD_FAILING_TESTS=yes ;;
 290   no)  BUILD_FAILING_TESTS=no ;;
 291   *) AC_MSG_ERROR(bad value ${enableval} for --disable-failing-tests) ;;
 292 esac],
 293 [BUILD_FAILING_TESTS=no]) dnl Default value
 294 AM_CONDITIONAL(BUILD_FAILING_TESTS, test "x$BUILD_FAILING_TESTS" = "xyes")
 295 if test x$BUILD_FAILING_TESTS = xyes; then
 296   AC_MSG_WARN([building tests known to fail, use --disable-failing-tests to disable])
 297 else
 298   AC_MSG_WARN([Sissy ! By asking to not build the tests known to fail, you hereby waive your right to customer support.  If you do not agree with this EULA, please press Ctrl-C before the next line is printed.  By allowing the next line to be printed, you expressly acknowledge your acceptance of this EULA.])
 299 fi
 300
 301 AC_ARG_ENABLE(examples,
 302 AC_HELP_STRING([--disable-examples],[disable building examples]),
 303 [case "${enableval}" in
 304   yes) BUILD_EXAMPLES=yes ;;
 305   no)  BUILD_EXAMPLES=no ;;
 306   *) AC_MSG_ERROR(bad value ${enableval} for --disable-examples) ;;
 307 esac],
 308 [BUILD_EXAMPLES=yes]) dnl Default value
 309 AM_CONDITIONAL(BUILD_EXAMPLES,      test "x$BUILD_EXAMPLES" = "xyes")
 310
 311 dnl Next, check for the optional components:
 312 dnl ========================================
 313
 314 translit(dnm, m, l) AM_CONDITIONAL(GST_DISABLE_LOADSAVE, true)
 315 GST_SUBSYSTEM_DISABLE(LOADSAVE,[pipeline XML load/save])
 316 translit(dnm, m, l) AM_CONDITIONAL(GST_DISABLE_TYPEFIND, true)
 317 GST_SUBSYSTEM_DISABLE(TYPEFIND,[typefind plugin],)
 318 translit(dnm, m, l) AM_CONDITIONAL(GST_DISABLE_AUTOPLUG, true)
 319 GST_SUBSYSTEM_DISABLE(AUTOPLUG,[autoplugger subsystem])
 320 translit(dnm, m, l) AM_CONDITIONAL(GST_DISABLE_PARSE, true)
 321 GST_SUBSYSTEM_DISABLE(PARSE,[command-line parser])
 322 translit(dnm, m, l) AM_CONDITIONAL(GST_DISABLE_TRACE, true)
 323 GST_SUBSYSTEM_DISABLE(TRACE,[tracing subsystem])
 324 translit(dnm, m, l) AM_CONDITIONAL(GST_DISABLE_ALLOC_TRACE, true)
 325 GST_SUBSYSTEM_DISABLE(ALLOC_TRACE,[allocation tracing])
 326
 327 translit(dnm, m, l) AM_CONDITIONAL(GST_DISABLE_REGISTRY, true)
 328 GST_SUBSYSTEM_DISABLE(REGISTRY,[plugin registry])
 329 translit(dnm, m, l) AM_CONDITIONAL(GST_DISABLE_ENUMTYPES, true)
 330 GST_SUBSYSTEM_DISABLE(ENUMTYPES,[enum types])
 331 translit(dnm, m, l) AM_CONDITIONAL(GST_DISABLE_INDEX, true)
 332 GST_SUBSYSTEM_DISABLE(INDEX,[index])
 333 translit(dnm, m, l) AM_CONDITIONAL(GST_DISABLE_PLUGIN, true)
 334 GST_SUBSYSTEM_DISABLE(PLUGIN,[plugin])
 335 translit(dnm, m, l) AM_CONDITIONAL(GST_DISABLE_URI, true)
 336 GST_SUBSYSTEM_DISABLE(URI,[uri handlers])
 337
 338 GST_EXT_CFLAGS="$GST_EXT_CFLAGS $GST_SUBSYSTEM_DISABLE_DEFINES"
 339
 340 dnl ################################################
 341 dnl # Set defines according to variables set above #
 342 dnl ################################################
 343
 344
 345 dnl These should be "USE_*" instead of "HAVE_*", but some packages expect
 346 dnl HAVE_ and it is likely to be easier to stick with the old name
 347 if test "x$USE_LIBMMX" = xyes; then
 348   AC_DEFINE(HAVE_LIBMMX, 1, [Define if libmmx is available])
 349 fi
 350
 351 if test "x$USE_ATOMIC_H" = xyes; then
 352   AC_DEFINE(HAVE_ATOMIC_H, 1, [Define if atomic.h header file is available])
 353 fi
 354
 355 dnl test if we have pthread_attr_setstack; if not use the older calls
 356 AC_CHECK_LIB(pthread, pthread_attr_setstack,
 357    AC_DEFINE(HAVE_PTHREAD_ATTR_SETSTACK, 1,
 358              [Defined if libpthread has pthread_attr_setstack ()]))
 359
 360 dnl test if we have posix_memalign; FreeBSD doesn't
 361 AC_CHECK_FUNC(posix_memalign,
 362    AC_DEFINE(HAVE_POSIX_MEMALIGN, 1,
 363              [Defined if we have posix_memalign ()]))
 364
 365 if test "x$PLUGINS_USE_BUILDDIR" = xyes; then
 366   AC_DEFINE(PLUGINS_USE_BUILDDIR, 1, [Define if plugins should be loaded from the build tree - only developers should use this])
 367 fi
 368
 369 if test "x$USE_DEBUG" = xyes; then
 370    GST_INT_CFLAGS="$GST_INT_CFLAGS -g"
 371 fi
 372
 373 if test "x$USE_PROFILING" = xyes; then
 374 dnl  CFLAGS="$CFLAGS -pg -fprofile-arcs"
 375   FOMIT_FRAME_POINTER=""
 376 else
 377   FOMIT_FRAME_POINTER="-fomit-frame-pointer"
 378 fi
 379
 380 dnl
 381 dnl AC_SUBST(FOMIT_FRAME_POINTER)
 382 dnl
 383
 384 dnl #############################
 385 dnl # Set automake conditionals #
 386 dnl #############################
 387
 388 dnl These should be "USE_*" instead of "HAVE_*", but some packages expect
 389 dnl HAVE_ and it is likely to be easier to stick with the old name
 390 AM_CONDITIONAL(HAVE_ATOMIC_H,       test "x$USE_ATOMIC_H" = "xyes")
 391
 392 AM_CONDITIONAL(EXPERIMENTAL,        test "$EXPERIMENTAL" = "$xyes")
 393 AM_CONDITIONAL(BROKEN,              test "$BROKEN" = "$xyes")
 394
 395 AM_CONDITIONAL(PLUGINS_USE_BUILDDIR,  test "x$PLUGINS_USE_BUILDDIR" = "xyes")
 396
 397
 398 dnl ############################
 399 dnl # Set up some more defines #
 400 dnl ############################
 401
 402 dnl Set location of registry dir.
 403 AC_DEFINE_UNQUOTED(GST_CACHE_DIR, "$GST_CACHE_DIR", [Define the registry directory])
 404 AC_SUBST(GST_CACHE_DIR)
 405
 406 dnl Set location of plugin directory
 407 if test "x${prefix}" = "xNONE"; then
 408   PLUGINS_DIR=${ac_default_prefix}/lib/gstreamer-$GST_MAJORMINOR
 409 else
 410   PLUGINS_DIR=${prefix}/lib/gstreamer-$GST_MAJORMINOR
 411 fi
 412 AC_DEFINE_UNQUOTED(PLUGINS_DIR, "$PLUGINS_DIR", [Define the plugin directory])
 413 AC_SUBST(PLUGINS_DIR)
 414
 415 dnl Set location of uninstalled plugin directory
 416 PLUGINS_BUILDDIR=`pwd`
 417 AC_DEFINE_UNQUOTED(PLUGINS_BUILDDIR, "$PLUGINS_BUILDDIR", [Define the uninstalled plugin directory])
 418 AC_SUBST(PLUGINS_BUILDDIR)
 419
 420 dnl since glib and xml are package deps, there's no need to include their cflags
 421 dnl in the pkg-config file
 422
 423 dnl for pkg-config
 424 GST_PKG_CFLAGS=$GST_EXT_CFLAGS
 425 GST_PKG_LIBS=$GST_EXT_LIBS
 426 AC_SUBST(GST_PKG_CFLAGS)
 427 AC_SUBST(GST_PKG_LIBS)
 428
 429 dnl finalize _CFLAGS and _LIBS
 430 dnl add GLIB and XML if necessary to EXT_*
 431 GST_CFLAGS="$GST_EXT_CFLAGS $XML_CFLAGS $GLIB_CFLAGS"
 432 GST_LIBS="$GST_EXT_LIBS $XML_LIBS $GLIB_LIBS -lpopt"
 433
 434 dnl Private vars for libgst only
 435 LIBGST_LIBS="$GST_LIBS"
 436 LIBGST_CFLAGS="$GST_CFLAGS -I\$(top_srcdir) $GST_ERROR"
 437 AC_SUBST(LIBGST_LIBS)
 438 AC_SUBST(LIBGST_CFLAGS)
 439
 440 dnl Vars for everyone else
 441 GST_INT_LIBS="\$(top_builddir)/gst/libgstreamer-$GST_MAJORMINOR.la"
 442 GST_INT_CFLAGS="$GST_INT_CFLAGS -I\$(top_srcdir)/libs -I\$(top_srcdir)/include"
 443
 444 AC_SUBST(GST_CFLAGS, "$LIBGST_CFLAGS $GST_INT_CFLAGS")
 445 AC_SUBST(GST_LIBS, "$LIBGST_LIBS $GST_INT_LIBS")
 446
 447 GST_PLUGIN_LDFLAGS="-module -avoid-version"
 448 AC_SUBST(GST_PLUGIN_LDFLAGS, "$GST_PLUGIN_LDFLAGS")
 449
 450 AC_CONFIG_SUBDIRS(libs/ext/cothreads)
 451
 452 dnl ##################################################
 453 dnl # deps for examples from manual                  #
 454 dnl ##################################################
 455
 456 PKG_CHECK_MODULES(LIBGNOMEUI, libgnomeui-2.0,
 457                   HAVE_LIBGNOMEUI="yes", HAVE_LIBGNOMEUI="no")
 458 AC_SUBST(LIBGNOMEUI_CFLAGS)
 459 AC_SUBST(LIBGNOMEUI_LIBS)
 460 AM_CONDITIONAL(HAVE_LIBGNOMEUI, test "x$HAVE_LIBGNOMEUI" = "xyes")
 461
 462 dnl ##################################################
 463 dnl # Prepare informative messages to display at end #
 464 dnl ##################################################
 465
 466 infomessages=
 467
 468 if test "x$PLUGINS_USE_BUILDDIR" = xyes; then
 469   infomessages="$infomessages
 470 *** Warning: You have configured using the --enable-plugin-builddir option.
 471
 472 This option is for development purposes only: binaries built with
 473 it should be used with code in the build tree only.  To build an
 474 installable version, use ./configure without the --enable-plugin-builddir
 475 option.  Note that the autogen.sh script supplies the plugin builddir
 476 option automatically -- run ./autogen.sh -- --disable-plugin-builddir to make
 477 an installable build.
 478
 479 "
 480 fi
 481
 482 dnl #########################
 483 dnl # Make the output files #
 484 dnl #########################
 485
 486 dnl libs/ext/Makefile
 487 dnl nothing there yet !
 488 AC_OUTPUT(
 489 Makefile
 490 include/Makefile
 491 gst/Makefile
 492 gst/gstversion.h
 493 gst/autoplug/Makefile
 494 gst/indexers/Makefile
 495 gst/elements/Makefile
 496 gst/parse/Makefile
 497 gst/schedulers/Makefile
 498 gst/types/Makefile
 499 gst/registries/Makefile
 500 libs/Makefile
 501 libs/gst/Makefile
 502 libs/gst/bytestream/Makefile
 503 libs/gst/getbits/Makefile
 504 libs/gst/putbits/Makefile
 505 libs/gst/control/Makefile
 506 libs/ext/Makefile
 507 tests/Makefile
 508 tests/bufspeed/Makefile
 509 tests/memchunk/Makefile
 510 tests/muxing/Makefile
 511 tests/seeking/Makefile
 512 tests/sched/Makefile
 513 tests/threadstate/Makefile
 514 testsuite/Makefile
 515 testsuite/bytestream/Makefile
 516 testsuite/caps/Makefile
 517 testsuite/cleanup/Makefile
 518 testsuite/clock/Makefile
 519 testsuite/dynparams/Makefile
 520 testsuite/elements/Makefile
 521 testsuite/indexers/Makefile
 522 testsuite/parse/Makefile
 523 testsuite/plugin/Makefile
 524 testsuite/refcounting/Makefile
 525 testsuite/threads/Makefile
 526 examples/Makefile
 527 examples/autoplug/Makefile
 528 examples/cutter/Makefile
 529 examples/helloworld/Makefile
 530 examples/helloworld2/Makefile
 531 examples/launch/Makefile
 532 examples/manual/Makefile
 533 examples/mixer/Makefile
 534 examples/pingpong/Makefile
 535 examples/plugins/Makefile
 536 examples/queue/Makefile
 537 examples/queue2/Makefile
 538 examples/queue3/Makefile
 539 examples/queue4/Makefile
 540 examples/thread/Makefile
 541 examples/typefind/Makefile
 542 examples/xml/Makefile
 543 tools/Makefile
 544 docs/Makefile
 545 docs/devhelp/Makefile
 546 docs/faq/Makefile
 547 docs/gst/Makefile
 548 docs/gst/gstreamer.types
 549 docs/libs/Makefile
 550 docs/manual/Makefile
 551 docs/pwg/Makefile
 552 docs/plugins/Makefile
 553 docs/plugins/gstreamer-plugins.types
 554 docs/xsl/Makefile
 555 pkgconfig/Makefile
 556 stamp.h
 557 pkgconfig/gstreamer.pc
 558 pkgconfig/gstreamer-uninstalled.pc
 559 pkgconfig/gstreamer-control.pc
 560 pkgconfig/gstreamer-control-uninstalled.pc
 561 gstreamer.spec,
 562 echo "$infomessages", infomessages="$infomessages"
 563 )