configure.ac

   1 AC_PREREQ([2.69])
   2
   3 dnl initialize autoconf
   4 dnl when going to/from release please set the nano (fourth number) right !
   5 dnl releases only do Wall, git and prerelease does Werror too
   6 dnl
   7 AC_INIT([GStreamer],[1.9.1.1],[http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer],[gstreamer])
   8 AG_GST_INIT
   9
  10 dnl initialize automake (we require GNU make)
  11 AM_INIT_AUTOMAKE([-Wno-portability 1.14 no-dist-gzip dist-xz tar-ustar subdir-objects])
  12
  13 dnl define PACKAGE_VERSION_* variables
  14 AS_VERSION
  15
  16 dnl check if this is a release version
  17 AS_NANO(GST_GIT="no", GST_GIT="yes")
  18
  19 dnl can autoconf find the source ?
  20 AC_CONFIG_SRCDIR([gst/gst.c])
  21
  22 dnl define the output header for config
  23 AC_CONFIG_HEADERS([config.h])
  24
  25 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  26 AM_MAINTAINER_MODE([enable])
  27
  28 dnl sets host_* variables
  29 AC_CANONICAL_HOST
  30
  31 dnl use pretty build output by default
  32 AM_SILENT_RULES([yes])
  33
  34 dnl GStreamer versioning, this is mostly informational
  35 GST_VERSION_MAJOR=$PACKAGE_VERSION_MAJOR
  36 GST_VERSION_MINOR=$PACKAGE_VERSION_MINOR
  37 GST_VERSION_MICRO=$PACKAGE_VERSION_MICRO
  38 GST_VERSION_NANO=$PACKAGE_VERSION_NANO
  39 AC_SUBST(GST_VERSION_MAJOR)
  40 AC_SUBST(GST_VERSION_MINOR)
  41 AC_SUBST(GST_VERSION_MICRO)
  42 AC_SUBST(GST_VERSION_NANO)
  43
  44 dnl our libraries and install dirs use GST_API_VERSION in the filename
  45 dnl to allow side-by-side installation of different API versions
  46 GST_API_VERSION=1.0
  47 AC_SUBST(GST_API_VERSION)
  48 AC_DEFINE_UNQUOTED(GST_API_VERSION, "$GST_API_VERSION",
  49   [GStreamer API Version])
  50
  51 dnl CURRENT, REVISION, AGE
  52 dnl - library source changed -> increment REVISION
  53 dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
  54 dnl - interfaces added -> increment AGE
  55 dnl - interfaces removed -> AGE = 0
  56 dnl
  57 dnl Keep CURRENT as MINOR * 100 + MICRO
  58 dnl Ex : 1.0.0 => 0
  59 dnl      1.0.3 => 3
  60 dnl      1.1.0 => 100
  61 dnl      1.2.5 => 205
  62 dnl      1.10.9 (who knows) => 1009
  63 dnl
  64 dnl sets GST_LT_LDFLAGS
  65 AS_LIBTOOL(GST, 901, 0, 901)
  66
  67 dnl *** autotools stuff ****
  68
  69 dnl allow for different autotools
  70 AS_AUTOTOOLS_ALTERNATE
  71
  72 dnl Add parameters for aclocal (keep in sync with Makefile.am)
  73 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  74
  75 dnl set up gettext
  76 dnl the version check needs to stay here because autopoint greps for it
  77 AM_GNU_GETTEXT_VERSION([0.17])
  78 AM_GNU_GETTEXT([external])
  79 AG_GST_GETTEXT([gstreamer-$GST_API_VERSION])
  80
  81 dnl *** check for arguments to configure ***
  82
  83 AG_GST_ARG_DISABLE_FATAL_WARNINGS
  84 AG_GST_ARG_ENABLE_EXTRA_CHECKS
  85
  86 dnl subsystems - can influence other decisions so needs to be high up
  87 dnl we need to AM_CONDITIONAL them here for automake 1.6.x compatibility
  88 AG_GST_CHECK_SUBSYSTEM_DISABLE(GST_DEBUG,[debugging subsystem])
  89 AM_CONDITIONAL(GST_DISABLE_GST_DEBUG, test "x$GST_DISABLE_GST_DEBUG" = "xyes")
  90 AG_GST_CHECK_SUBSYSTEM_DISABLE(GST_TRACER_HOOKS,[tracing subsystem hooks])
  91 AM_CONDITIONAL(GST_DISABLE_GST_TRACER_HOOKS, test "x$GST_DISABLE_GST_TRACER_HOOKS" = "xyes")
  92 AG_GST_CHECK_SUBSYSTEM_DISABLE(PARSE,[command-line parser])
  93 AM_CONDITIONAL(GST_DISABLE_PARSE, test "x$GST_DISABLE_PARSE" = "xyes")
  94 if test "x$GST_DISABLE_PARSE" = xyes; then
  95   AC_DEFINE(GST_DISABLE_PARSE, 1,
  96     [Define if pipeline parsing code is disabled])
  97 fi
  98 AG_GST_CHECK_SUBSYSTEM_DISABLE(OPTION_PARSING,[option parsing when gst_init])
  99 AM_CONDITIONAL(GST_DISABLE_OPTION_PARSING, test "x$GST_DISABLE_OPTION_PARSING" = "xyes")
 100 if test "x$GST_DISABLE_OPTION_PARSING" = xyes; then
 101   AC_DEFINE(GST_DISABLE_OPTION_PARSING, 1,
 102     [Define if option parsing is disabled])
 103 fi
 104 AG_GST_CHECK_SUBSYSTEM_DISABLE(REGISTRY,[plugin registry])
 105 AM_CONDITIONAL(GST_DISABLE_REGISTRY, test "x$GST_DISABLE_REGISTRY" = "xyes")
 106 dnl define a substitution to use in docs/gst/gstreamer.types
 107 if test "x$GST_DISABLE_REGISTRY" = "xyes"
 108 then
 109   GST_REGISTRY_DOC_TYPES="%"
 110 else
 111   GST_REGISTRY_DOC_TYPES=
 112 fi
 113 AC_SUBST(GST_REGISTRY_DOC_TYPES)
 114 AG_GST_CHECK_SUBSYSTEM_DISABLE(PLUGIN,[plugin])
 115 AM_CONDITIONAL(GST_DISABLE_PLUGIN, test "x$GST_DISABLE_PLUGIN" = "xyes")
 116
 117 AG_GST_ARG_DEBUG
 118 AG_GST_ARG_PROFILING
 119 AG_GST_ARG_VALGRIND
 120 AG_GST_ARG_GCOV
 121
 122 AG_GST_ARG_EXAMPLES
 123
 124 AG_GST_ARG_WITH_PKG_CONFIG_PATH
 125 AG_GST_ARG_WITH_PACKAGE_NAME
 126 AG_GST_ARG_WITH_PACKAGE_ORIGIN
 127
 128 AG_GST_PKG_CONFIG_PATH
 129
 130 AG_GST_SET_PACKAGE_RELEASE_DATETIME_WITH_NANO([$PACKAGE_VERSION_NANO],
 131   ["${srcdir}/gstreamer.doap"],
 132   [$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_MICRO])
 133
 134 dnl check for bash completion
 135 AC_ARG_WITH([bash-completion-dir],
 136     AS_HELP_STRING([--with-bash-completion-dir[=PATH]],
 137         [Install the bash auto-completion script in this directory. @<:@default=yes@:>@]),
 138     [],
 139     [with_bash_completion_dir=yes])
 140
 141 if test "x$with_bash_completion_dir" = "xyes"
 142 then
 143     extra_args=
 144
 145     if test "x$prefix" != "xNONE"
 146     then
 147         extra_args="--define-variable=prefix=\"$prefix\""
 148     fi
 149
 150     PKG_CHECK_MODULES([BASH_COMPLETION], [bash-completion >= 2.0],
 151         [BASH_COMPLETION_DIR="`eval pkg-config $extra_args --variable=completionsdir bash-completion`"],
 152         [BASH_COMPLETION_DIR="$datadir/bash-completion/completions"])
 153     PKG_CHECK_MODULES([BASH_COMPLETION], [bash-completion >= 2.0],
 154         [BASH_HELPERS_DIR="`eval pkg-config $extra_args --variable=helpersdir bash-completion`"],
 155         [BASH_HELPERS_DIR="$datadir/bash-completion/helpers"])
 156 else
 157     BASH_COMPLETION_DIR="$with_bash_completion_dir/completions"
 158     BASH_HELPERS_DIR="$with_bash_completion_dir/helpers"
 159 fi
 160
 161 AC_SUBST([BASH_COMPLETION_DIR])
 162 AC_SUBST([BASH_HELPERS_DIR])
 163 AM_CONDITIONAL([ENABLE_BASH_COMPLETION],[test "x$with_bash_completion_dir" != "xno"])
 164
 165 dnl build static plugins or not
 166 AC_MSG_CHECKING([whether to build static plugins or not])
 167 AC_ARG_ENABLE(
 168   static-plugins,
 169   AC_HELP_STRING(
 170     [--enable-static-plugins],
 171     [build static plugins @<:@default=no@:>@]),
 172   [AS_CASE(
 173     [$enableval], [no], [], [yes], [],
 174     [AC_MSG_ERROR([bad value "$enableval" for --enable-static-plugins])])],
 175   [enable_static_plugins=no])
 176 AC_MSG_RESULT([$enable_static_plugins])
 177 if test "x$enable_static_plugins" = xyes; then
 178   AC_DEFINE(GST_PLUGIN_BUILD_STATIC, 1,
 179     [Define if static plugins should be built])
 180   GST_PLUGIN_LIBTOOLFLAGS=""
 181 else
 182   GST_PLUGIN_LIBTOOLFLAGS="--tag=disable-static"
 183 fi
 184 AC_SUBST(GST_PLUGIN_LIBTOOLFLAGS)
 185 AM_CONDITIONAL(GST_PLUGIN_BUILD_STATIC, test "x$enable_static_plugins" = "xyes")
 186
 187 dnl If only building static libraries, define GST_STATIC_COMPILATION. This is
 188 dnl needed only on Windows, but it doesn't hurt to have it everywhere.
 189 if test x$enable_static = xyes -a x$enable_shared = xno; then
 190   GST_OBJ_STATIC_CFLAGS="-DGST_STATIC_COMPILATION"
 191 fi
 192
 193 dnl building of tests
 194 AC_ARG_ENABLE(tests,
 195   AS_HELP_STRING([--disable-tests],[disable building test apps]),
 196   [
 197     case "${enableval}" in
 198       yes) BUILD_TESTS=yes ;;
 199       no)  BUILD_TESTS=no ;;
 200       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-tests) ;;
 201     esac
 202   ],
 203 [BUILD_TESTS=yes]) dnl Default value
 204 AM_CONDITIONAL(BUILD_TESTS,         test "x$BUILD_TESTS" = "xyes")
 205
 206 dnl tests known to fail
 207 AC_ARG_ENABLE(failing-tests,
 208   AS_HELP_STRING([--disable-failing-tests],[disable building tests known to fail]),
 209   [
 210     case "${enableval}" in
 211       yes) BUILD_FAILING_TESTS=yes ;;
 212       no)  BUILD_FAILING_TESTS=no ;;
 213       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-failing-tests) ;;
 214     esac
 215   ],
 216   [BUILD_FAILING_TESTS=no]) dnl Default value
 217 AM_CONDITIONAL(BUILD_FAILING_TESTS, test "x$BUILD_FAILING_TESTS" = "xyes")
 218 if test x$BUILD_FAILING_TESTS = xyes; then
 219   AC_MSG_WARN([building tests known to fail, use --disable-failing-tests to disable])
 220 else
 221   AC_MSG_WARN([Sissy ! By asking to not build the tests known to fail, you hereby waive your right to customer support.  If you do not agree with this EULA, please press Ctrl-C before the next line is printed.  By allowing the next line to be printed, you expressly acknowledge your acceptance of this EULA.])
 222 fi
 223
 224 dnl building of benchmarks
 225 AC_ARG_ENABLE(benchmarks,
 226   AS_HELP_STRING([--disable-benchmarks],[disable building benchmarks apps]),
 227   [
 228     case "${enableval}" in
 229       yes) BUILD_BENCHMARKS=yes ;;
 230       no)  BUILD_BENCHMARKS=no ;;
 231       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-benchmarks) ;;
 232     esac
 233   ],
 234 [BUILD_BENCHMARKS=yes]) dnl Default value
 235 AM_CONDITIONAL(BUILD_BENCHMARKS, test "x$BUILD_BENCHMARKS" = "xyes")
 236
 237 dnl building of tools
 238 AC_ARG_ENABLE(tools,
 239   AS_HELP_STRING([--disable-tools],[disable building tools]),
 240   [
 241     case "${enableval}" in
 242       yes) BUILD_TOOLS=yes ;;
 243       no)  BUILD_TOOLS=no ;;
 244       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-tools) ;;
 245     esac
 246   ],
 247 [BUILD_TOOLS=yes]) dnl Default value
 248 AM_CONDITIONAL(BUILD_TOOLS, test "x$BUILD_TOOLS" = "xyes")
 249
 250 dnl poison destroyed objects
 251 AC_ARG_ENABLE(poisoning,
 252   AS_HELP_STRING([--enable-poisoning],[enable poisoning of deallocated objects]),
 253   [
 254     case "${enableval}" in
 255       yes) USE_POISONING=yes ;;
 256       no)  USE_POISONING=no ;;
 257       *)   AC_MSG_ERROR(bad value ${enableval} for --enable-poisoning) ;;
 258     esac
 259   ],
 260   [USE_POISONING=no]) dnl Default value
 261 if test "x$USE_POISONING" = xyes; then
 262   AC_DEFINE(USE_POISONING, 1,
 263     [Define if we should poison deallocated memory])
 264 fi
 265
 266 dnl PTP support parts
 267 AC_MSG_CHECKING([whether PTP support can be enabled])
 268 case "$host_os" in
 269   *android*)
 270     dnl Can't run on Android because of permissions
 271     HAVE_PTP=no
 272     ;;
 273   mingw*|pw32*|cygwin*)
 274     dnl Not ported to Windows yet
 275     HAVE_PTP=no
 276     ;;
 277   darwin*)
 278     dnl Can't run on iOS because of permissions
 279     AC_CHECK_HEADER(MobileCoreServices/MobileCoreServices.h, HAVE_PTP="no", HAVE_PTP="yes", [-])
 280     ;;
 281   linux*|darwin*|solaris*|netbsd*|freebsd*|openbsd*|kfreebsd*|dragonfly*|gnu*)
 282     HAVE_PTP=yes
 283     ;;
 284   *)
 285     HAVE_PTP=no
 286     ;;
 287 esac
 288 AC_MSG_RESULT([$HAVE_PTP])
 289
 290 dnl user/group to change to in gst-ptp-helper
 291 AC_ARG_WITH([ptp-helper-setuid-user],
 292   AS_HELP_STRING([--with-ptp-helper-setuid-user],[User to switch to when installing gst-ptp-helper setuid root]),
 293   [
 294     if test "x$withval" != "x"
 295     then
 296       AC_DEFINE_UNQUOTED(HAVE_PTP_HELPER_SETUID_USER, "$withval", [PTP helper setuid user])
 297     fi
 298   ], []
 299 )
 300
 301 dnl group/group to change to in gst-ptp-helper
 302 AC_ARG_WITH([ptp-helper-setuid-group],
 303   AS_HELP_STRING([--with-ptp-helper-setuid-group],[Group to switch to when installing gst-ptp-helper setuid root]),
 304   [
 305     if test "x$withval" != "x"
 306     then
 307       AC_DEFINE_UNQUOTED(HAVE_PTP_HELPER_SETUID_GROUP, "$withval", [PTP helper setuid group])
 308     fi
 309   ], []
 310 )
 311
 312 AC_ARG_WITH(
 313   ptp-helper-permissions,
 314   AC_HELP_STRING(
 315     [--with-ptp-helper-permissions],
 316     [how to gain PTP permissions (none, setuid-root, capabilities, auto)]),
 317     [],
 318     [with_ptp_helper_permissions=auto])
 319
 320 gst_ptp_have_cap=no
 321 AG_GST_CHECK_LIBHEADER(CAP, cap,
 322                        cap_init, ,
 323                        sys/capability.h,
 324                        CAP_LIBS="-lcap"
 325                        AC_SUBST(CAP_LIBS)
 326                        gst_ptp_have_cap=yes)
 327
 328 AC_PATH_PROG([SETCAP], [setcap], [no], [$PATH:/usr/bin:/bin:/usr/sbin:/sbin])
 329
 330 if test "x$HAVE_PTP" = "xyes"; then
 331 AC_DEFINE(HAVE_PTP, 1, [PTP support available])
 332
 333 AC_MSG_CHECKING([for SIOCGIFCONF, SIOCGIFFLAGS and SIOCGIFHWADDR])
 334 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
 335     [[
 336         #include <sys/ioctl.h>
 337         #include <net/if.h>
 338     ]],
 339     [[
 340         struct ifreq ifr;
 341         struct ifconf ifc;
 342         ioctl(0, SIOCGIFCONF, &ifc);
 343         ioctl(0, SIOCGIFFLAGS, &ifr);
 344         ioctl(0, SIOCGIFHWADDR, &ifr);
 345         int dummy = ifr.ifr_hwaddr.sa_data[0];
 346     ]])], [
 347         AC_MSG_RESULT(yes)
 348         AC_DEFINE(HAVE_SIOCGIFCONF_SIOCGIFFLAGS_SIOCGIFHWADDR, 1, [SIOCGIFCONF, SIOCGIFFLAGS and SIOCGIFHWADDR is available])
 349     ], [
 350         AC_MSG_RESULT(no)
 351 ])
 352
 353 AC_MSG_CHECKING([for getifaddrs() and AF_LINK])
 354 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
 355     [[
 356         #include <ifaddrs.h>
 357         #include <net/if.h>
 358         #include <net/if_dl.h>
 359     ]],
 360     [[
 361         struct ifaddrs *ifaddr;
 362         getifaddrs(&ifaddr);
 363         int dummy = (ifaddr->ifa_flags & IFF_LOOPBACK) && ifaddr->ifa_addr->sa_family != AF_LINK;
 364     ]])], [
 365         AC_MSG_RESULT(yes)
 366         AC_DEFINE(HAVE_GETIFADDRS_AF_LINK, 1, [getifaddrs() and AF_LINK is available])
 367     ], [
 368         AC_MSG_RESULT(no)
 369     ])
 370
 371 AC_MSG_CHECKING([how to install gst-ptp-helper])
 372 if test "x$with_ptp_helper_permissions" = "xauto"; then
 373     if test "x$gst_ptp_have_cap" = "xyes" -a "x$SETCAP" != "xno"; then
 374         with_ptp_helper_permissions="capabilities"
 375     else
 376         with_ptp_helper_permissions="setuid-root"
 377     fi
 378 fi
 379 AC_MSG_RESULT([$with_ptp_helper_permissions])
 380
 381 case "$with_ptp_helper_permissions" in
 382   none)
 383     ;;
 384   setuid-root)
 385      AC_DEFINE(HAVE_PTP_HELPER_SETUID, 1,
 386         [Use setuid-root for permissions in PTP helper])
 387     ;;
 388   capabilities)
 389      AC_DEFINE(HAVE_PTP_HELPER_CAPABILITIES, 1,
 390         [Use capabilities for permissions in PTP helper])
 391     ;;
 392   *)
 393     AC_MSG_ERROR(Invalid parameter [$with_ptp_helper_permissions])
 394     ;;
 395 esac
 396
 397 fi
 398
 399 AM_CONDITIONAL(HAVE_PTP, test "x$HAVE_PTP" = "xyes")
 400 AM_CONDITIONAL(HAVE_PTP_HELPER_SETUID, test "x$with_ptp_helper_permissions" = "xsetuid-root")
 401 AM_CONDITIONAL(HAVE_PTP_HELPER_CAPABILITIES, test "x$with_ptp_helper_permissions" = "xcapabilities")
 402
 403 dnl *** checks for platform ***
 404
 405 dnl * hardware/architecture *
 406
 407 dnl common/m4/gst-arch.m4
 408 dnl check CPU type
 409 AG_GST_ARCH
 410 dnl substitution for win32/common/config.h
 411 HOST_CPU=$host_cpu
 412 AC_SUBST(HOST_CPU)
 413
 414 dnl common/m4/gst-arch.m4
 415 dnl check for unaligned access
 416 AG_GST_UNALIGNED_ACCESS
 417 dnl create a configure variable for gst/gstconfig.h
 418 if test x${as_cv_unaligned_access} = xyes ; then
 419   GST_HAVE_UNALIGNED_ACCESS_DEFINE="#define GST_HAVE_UNALIGNED_ACCESS 1"
 420 else
 421   GST_HAVE_UNALIGNED_ACCESS_DEFINE="#define GST_HAVE_UNALIGNED_ACCESS 0"
 422 fi
 423 AC_SUBST(GST_HAVE_UNALIGNED_ACCESS_DEFINE)
 424
 425 dnl check for platform specific settings
 426 AG_GST_PLATFORM
 427
 428 dnl * software *
 429
 430 dnl check for large file support
 431 dnl affected plugins must include config.h
 432 AC_SYS_LARGEFILE
 433
 434 dnl *** checks for programs ***
 435
 436 dnl find a compiler
 437 AC_PROG_CC
 438 AC_PROG_CC_STDC
 439
 440 dnl check if the compiler supports '-c' and '-o' options
 441 AM_PROG_CC_C_O
 442
 443 dnl find an assembler
 444 AM_PROG_AS
 445
 446 dnl determine if c++ is available on this system
 447 AC_PROG_CXX
 448 dnl CXX may be set to some default even if no c++ compiler is available
 449 dnl (thanks autotools!), so just try to compile some c++ code to make sure
 450 AC_LANG_PUSH([C++])
 451 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[ class Foo { int bar; };]], [[]])],[working_cxx=yes],[working_cxx=no])
 452 AC_LANG_POP([C++])
 453 AC_MSG_NOTICE([working c++ compiler found: $working_cxx])
 454 AM_CONDITIONAL(HAVE_CXX, test "x$working_cxx" = "xyes")
 455
 456 dnl Perl is used in building documentation and in the version checks
 457 AC_PATH_PROG(PERL_PATH, perl, no)
 458 if test x$PERL_PATH = xno; then
 459   AC_MSG_ERROR(Could not find perl)
 460 fi
 461
 462 dnl we require flex and bison for building the parser
 463 if test "x$GST_DISABLE_PARSE" != xyes; then
 464   AG_GST_BISON_CHECK
 465   AG_GST_FLEX_CHECK
 466 fi
 467
 468 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 469 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 470
 471 dnl check for gobject-introspection
 472 GOBJECT_INTROSPECTION_CHECK([1.31.1])
 473
 474 dnl check for documentation tools
 475 AG_GST_DOCBOOK_CHECK
 476 GTK_DOC_CHECK([1.12])
 477 AG_GST_PLUGIN_DOCS([1.12])
 478
 479 dnl *** checks for libraries ***
 480
 481 dnl check for libm, for sin()
 482 LT_LIB_M
 483 AC_SUBST(LIBM)
 484
 485 dnl *** checks for header files ***
 486
 487 dnl check if we have ANSI C header files
 488 AC_HEADER_STDC
 489
 490 dnl Check for ucontext.h
 491 AC_CHECK_HEADERS([ucontext.h], [], [], [AC_INCLUDES_DEFAULT])
 492
 493 dnl Check for sys/socket.h
 494 AC_CHECK_HEADERS([sys/socket.h], [HAVE_SYS_SOCKET_H=yes], [HAVE_SYS_SOCKET_H=no], [AC_INCLUDES_DEFAULT])
 495 AM_CONDITIONAL(HAVE_SYS_SOCKET_H, test "x$HAVE_SYS_SOCKET_H" = "xyes")
 496
 497 dnl check for sys/times.h for tests/examples/adapter/
 498 AC_CHECK_HEADERS([sys/times.h], [HAVE_SYS_TIMES_H=yes], [HAVE_SYS_TIME_H=no], [AC_INCLUDES_DEFAULT])
 499 AC_CHECK_HEADERS([unistd.h], [HAVE_UNISTD_H=yes], [HAVE_UNISTD_H=no], [AC_INCLUDES_DEFAULT])
 500 AM_CONDITIONAL(HAVE_SYS_TIMES_H_AND_UNISTD_H, test "x$HAVE_SYS_TIMES_H" = "xyes" -a "x$HAVE_UNISTD_H" = "xyes")
 501
 502 dnl Check for process.h for getpid() on win32
 503 AC_CHECK_HEADERS([process.h], [], [], [AC_INCLUDES_DEFAULT])
 504
 505 dnl Check for sys/utsname.h for uname
 506 AC_CHECK_HEADERS([sys/utsname.h], [], [], [AC_INCLUDES_DEFAULT])
 507
 508 dnl Check for stdio_ext.f for __fbufsize
 509 AC_CHECK_HEADERS([stdio_ext.h], [], [], [AC_INCLUDES_DEFAULT])
 510
 511 dnl check for pthreads
 512 dnl without arguments AX_PTHREAD() will do AC_DEFINE(HAVE_PTHREAD)
 513 dnl which later checks use in their test code
 514 AX_PTHREAD()
 515 AM_CONDITIONAL(HAVE_PTHREAD, test "x$ax_pthread_ok" = "xyes")
 516
 517 dnl check for sys/prctl for setting thread name on Linux
 518 AC_CHECK_HEADERS([sys/prctl.h], [], [], [AC_INCLUDES_DEFAULT])
 519
 520 dnl check for pthread_setname_np(const char*)
 521 dnl which is present on OS X 10.6, iOS 3.2 and above
 522 AC_MSG_CHECKING(for pthread_setname_np(const char*))
 523 AC_LINK_IFELSE(
 524     [AC_LANG_PROGRAM(
 525         [#include <pthread.h>],
 526         [pthread_setname_np("example")])],
 527     [AC_MSG_RESULT(yes)
 528      AC_DEFINE(HAVE_PTHREAD_SETNAME_NP_WITHOUT_TID,1,
 529         [Have function pthread_setname_np(const char*)])],
 530     [AC_MSG_RESULT(no)])
 531
 532 dnl check for sys/uio.h for writev()
 533 AC_CHECK_HEADERS([sys/uio.h], [], [], [AC_INCLUDES_DEFAULT])
 534
 535 dnl Check for valgrind.h
 536 dnl separate from HAVE_VALGRIND because you can have the program, but not
 537 dnl the dev package
 538 AC_CHECK_HEADERS([valgrind/valgrind.h], [], [], [AC_INCLUDES_DEFAULT])
 539
 540 dnl used in gst/gstpoll.c
 541 AC_CHECK_HEADERS([winsock2.h], [HAVE_WINSOCK2_H=yes], [HAVE_WINSOCK2_H=no], [AC_INCLUDES_DEFAULT])
 542 AM_CONDITIONAL(HAVE_WINSOCK2_H, test "x$HAVE_WINSOCK2_H" = "xyes")
 543 if test "x$HAVE_WINSOCK2_H" = "xyes"; then
 544   WIN32_LIBS="-lws2_32"
 545   AC_SUBST(WIN32_LIBS)
 546 fi
 547
 548 dnl check for GMP/GSL, used by the gst_util_uint64_scale unit test only
 549 if test "x$BUILD_TESTS" = "xyes"; then
 550   AG_GST_CHECK_LIBHEADER(GMP, gmp,
 551                          __gmpz_init_set_d, ,
 552                          gmp.h,
 553                          GMP_LIBS="-lgmp"
 554                          AC_SUBST(GMP_LIBS)
 555                          AC_DEFINE(HAVE_GMP, [1],[Have GMP library]))
 556   AG_GST_CHECK_LIBHEADER(GSL, gsl,
 557                          gsl_rng_uniform_int, -lgslcblas,
 558                          gsl/gsl_rng.h,
 559                          GSL_LIBS="-lgsl -lgslcblas"
 560                          AC_SUBST(GSL_LIBS)
 561                          AC_DEFINE(HAVE_GSL, [1],[Have GSL library]))
 562 fi
 563
 564 dnl *** checks for types/defines ***
 565
 566 dnl *** checks for structures ***
 567
 568 dnl *** checks for compiler characteristics ***
 569
 570 dnl check if the compiler supports __uint128_t (gcc)
 571 dnl Actually check for 128-bit division, since that's what we use
 572 dnl uint128_t for.
 573 AC_CACHE_CHECK(for __uint128_t, gst_cv_uint128_t,
 574     AC_LINK_IFELSE([AC_LANG_PROGRAM([[ ]], [[
 575       static __uint128_t v1 = 100;
 576       static __uint128_t v2 = 10;
 577       static __uint128_t u;
 578       u = v1 / v2;
 579     ]])],[
 580       gst_cv_uint128_t=yes
 581     ],[
 582       gst_cv_uint128_t=no
 583     ])
 584 )
 585 if test x$gst_cv_uint128_t = xyes; then
 586   AC_DEFINE(HAVE_UINT128_T, 1, [Have __uint128_t type])
 587 fi
 588
 589 dnl *** checking for tm_gmtoff ***
 590 AC_MSG_CHECKING([for tm_gmtoff])
 591 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 592         #include <time.h>
 593         int main(void) {
 594           struct tm t;
 595           t.tm_gmtoff = 0;
 596           exit(0);
 597         }]])],
 598   [have_tm_gmtoff=yes
 599    AC_DEFINE(HAVE_TM_GMTOFF,1,[Have tm_gmtoff field in struct tm])],
 600   [have_tm_gmtoff=no],
 601   [have_tm_gmtoff="no (cross compiling)"])
 602 AC_MSG_RESULT($have_tm_gmtoff)
 603
 604
 605 dnl *** checks for library functions ***
 606
 607 AC_CHECK_FUNCS([strcasestr])
 608
 609 AC_CHECK_FUNCS([gmtime_r])
 610 AC_CHECK_FUNCS([localtime_r])
 611 AC_CHECK_FUNCS([sigaction])
 612 AC_CHECK_FUNCS([getrusage])
 613 AM_CONDITIONAL(HAVE_GETRUSAGE, test "x$ac_cv_func_getrusage" = "xyes")
 614 AC_CHECK_HEADERS([sys/resource.h])
 615
 616 dnl check for fseeko()
 617 AC_FUNC_FSEEKO
 618 dnl check for ftello()
 619 AC_CHECK_FUNCS([ftello])
 620
 621 AC_CHECK_FUNCS([fgetpos])
 622 AC_CHECK_FUNCS([fsetpos])
 623
 624 dnl check for poll(), ppoll() and pselect()
 625 AC_CHECK_HEADERS([sys/poll.h], [], [], [AC_INCLUDES_DEFAULT])
 626 AC_CHECK_HEADERS([poll.h], [], [], [AC_INCLUDES_DEFAULT])
 627 AC_CHECK_FUNCS([poll])
 628 AC_CHECK_FUNCS([ppoll])
 629 AC_CHECK_FUNCS([pselect])
 630
 631 dnl check for socketpair()
 632 AC_CHECK_FUNC(socketpair, [], [
 633   AC_CHECK_LIB(socket, socketpair, [
 634     SOCKET_LIBS="-lsocket"
 635     AC_SUBST(SOCKET_LIBS)
 636   ])
 637 ])
 638
 639 dnl ****************************************
 640 dnl *** GLib POLL* compatibility defines ***
 641 dnl ****************************************
 642
 643 AC_MSG_CHECKING([for broken poll])
 644 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 645         #include <stdlib.h>
 646         #include <fcntl.h>
 647         #ifdef HAVE_SYS_POLL_H
 648         #include <sys/poll.h>
 649         #endif
 650         #ifdef HAVE_POLL_H
 651         #include <poll.h>
 652         #endif
 653         int main(void) {
 654           struct pollfd fds[1];
 655           int fd;
 656           fd = open("/dev/null", 1);
 657           fds[0].fd = fd;
 658           fds[0].events = POLLIN;
 659           fds[0].revents = 0;
 660           if (poll(fds, 1, 0) < 0 || (fds[0].revents & POLLNVAL) != 0) {
 661                 exit(1);  /* Does not work for devices -- fail */
 662           }
 663           exit(0);
 664         }]])],
 665   [broken_poll=no],
 666   [broken_poll=yes
 667    AC_DEFINE(BROKEN_POLL,1,[poll doesn't work on devices])],
 668   [broken_poll="no (cross compiling)"])
 669 AC_MSG_RESULT($broken_poll)
 670
 671 dnl check for mmap()
 672 AC_FUNC_MMAP
 673 AM_CONDITIONAL(HAVE_MMAP, test "x$ac_cv_func_mmap_fixed_mapped" = "xyes")
 674
 675 dnl check for posix_memalign(), getpagesize()
 676 AC_CHECK_FUNCS([posix_memalign])
 677 AC_CHECK_FUNCS([getpagesize])
 678
 679 dnl Check for POSIX timers
 680 AC_CHECK_FUNCS(clock_gettime, [], [
 681   AC_CHECK_LIB(rt, clock_gettime, [
 682     AC_DEFINE(HAVE_CLOCK_GETTIME, 1)
 683     LIBS="$LIBS -lrt"
 684   ], [
 685     AC_CHECK_LIB(pthread, clock_gettime, [
 686       AC_DEFINE(HAVE_CLOCK_GETTIME, 1)
 687       LIBS="$LIBS -lpthread"
 688     ])
 689   ])
 690 ])
 691
 692 AC_CACHE_CHECK(for posix timers, gst_cv_posix_timers,
 693     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 694 #include <time.h>
 695 #ifdef HAVE_UNISTD_H
 696 #include <unistd.h>
 697 #endif
 698     ]], [[
 699 #if !defined(_POSIX_TIMERS) || _POSIX_TIMERS < 0 || !defined(CLOCK_REALTIME)
 700 #error Either _POSIX_TIMERS or CLOCK_REALTIME not defined
 701 #endif
 702     ]])],[
 703       gst_cv_posix_timers=yes
 704     ],[
 705       gst_cv_posix_timers=no
 706     ])
 707 )
 708
 709 if test "$gst_cv_posix_timers" = "yes"; then
 710   AC_DEFINE(HAVE_POSIX_TIMERS,1,[Have posix timers])
 711   GST_HAVE_POSIX_TIMERS_DEFINE="#define GST_HAVE_POSIX_TIMERS 1"
 712 else
 713   GST_HAVE_POSIX_TIMERS_DEFINE="#define GST_HAVE_POSIX_TIMERS 0"
 714 fi
 715 AC_SUBST(GST_HAVE_POSIX_TIMERS_DEFINE)
 716 AM_CONDITIONAL(GST_HAVE_POSIX_TIMERS, test "$gst_cv_posix_timers" = "yes")
 717
 718 AC_CACHE_CHECK(for monotonic clock, gst_cv_monotonic_clock,
 719     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 720 #include <time.h>
 721 #ifdef HAVE_UNISTD_H
 722 #include <unistd.h>
 723 #endif
 724     ]], [[
 725 #if !defined(_POSIX_MONOTONIC_CLOCK) || _POSIX_MONOTONIC_CLOCK < 0 || !defined(CLOCK_MONOTONIC)
 726 #error Either _POSIX_MONOTONIC_CLOCK or CLOCK_MONOTONIC not defined
 727 #endif
 728     ]])],[
 729       gst_cv_monotonic_clock=yes
 730     ],[
 731       gst_cv_monotonic_clock=no
 732     ])
 733 )
 734
 735 if test "$gst_cv_monotonic_clock" = "yes"; then
 736   AC_DEFINE(HAVE_MONOTONIC_CLOCK,1,[Have a monotonic clock])
 737   GST_HAVE_MONOTONIC_CLOCK_DEFINE="#define GST_HAVE_MONOTONIC_CLOCK 1"
 738 else
 739   GST_HAVE_MONOTONIC_CLOCK_DEFINE="#define GST_HAVE_MONOTONIC_CLOCK 0"
 740 fi
 741 AC_SUBST(GST_HAVE_MONOTONIC_CLOCK_DEFINE)
 742 AM_CONDITIONAL(GST_HAVE_MONOTONIC_CLOCK, test "$gst_cv_monotonic_clock" = "yes")
 743
 744 dnl Check for a way to display the function name in debug output
 745 AG_GST_CHECK_FUNCTION
 746
 747 dnl test if we have dladdr(); we use it for debugging; see gst/gstinfo.c
 748 save_cflags="$CFLAGS"
 749 CFLAGS="$CFLAGS -D_GNU_SOURCE"
 750 AC_CHECK_LIB(dl, dladdr,
 751    AC_DEFINE(HAVE_DLADDR, 1, [Defined if we have dladdr ()])
 752    LIBS="$LIBS -ldl")
 753 CFLAGS="$save_cflags"
 754
 755 dnl Check printf stuff
 756 if test "x${GST_DISABLE_GST_DEBUG}" != "xyes"; then
 757   AC_TYPE_LONG_LONG_INT
 758   AC_TYPE_UNSIGNED_LONG_LONG_INT
 759
 760   if test x$ac_cv_type_long_long_int$ac_cv_type_unsigned_long_long_int = xyesyes; then
 761     AC_DEFINE([HAVE_LONG_LONG], [1], [Define to 1 if the system has the type long long])
 762   fi
 763
 764   dnl /usr/share/aclocal/inttypes_h.m4 - ships with gettext apparently
 765   gl_AC_HEADER_INTTYPES_H
 766
 767   dnl /usr/share/aclocal/stdint_h.m4 - ships with gettext apparently
 768   gl_AC_HEADER_STDINT_H
 769
 770   AC_CHECK_TYPES(ptrdiff_t)
 771
 772   AC_TYPE_INTMAX_T
 773   AC_TYPE_SIZE_T
 774 fi
 775
 776 dnl *** checks for dependency libraries ***
 777
 778 dnl GLib
 779 GLIB_REQ=2.40.0
 780 AG_GST_GLIB_CHECK([$GLIB_REQ])
 781
 782 dnl Check for documentation xrefs
 783 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 784 AC_SUBST(GLIB_PREFIX)
 785
 786 dnl GTK is optional and only used in examples
 787 HAVE_GTK=no
 788 GTK_REQ=3.10
 789 if test "x$BUILD_EXAMPLES" = "xyes"; then
 790   PKG_CHECK_MODULES(GTK, gtk+-3.0 >= $GTK_REQ, HAVE_GTK=yes, HAVE_GTK=no)
 791   AC_SUBST(GTK_LIBS)
 792   AC_SUBST(GTK_CFLAGS)
 793 fi
 794 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 795
 796 dnl libunwind is optionally used by the leaks tracer
 797 PKG_CHECK_MODULES(UNWIND, libunwind, HAVE_UNWIND=yes, HAVE_UNWIND=no)
 798
 799 dnl Check for backtrace() from libc
 800 AC_CHECK_FUNC(backtrace, [
 801   AC_CHECK_HEADERS([execinfo.h], [
 802     AC_DEFINE(HAVE_BACKTRACE,1,[Have backtrace])
 803   ], [], [])
 804 ])
 805
 806 if test "x$HAVE_UNWIND" = "xyes"; then
 807   AC_DEFINE(HAVE_UNWIND, 1, [libunwind available])
 808 fi
 809
 810 dnl building of unit test libraries
 811 AC_ARG_ENABLE(check,
 812   AS_HELP_STRING([--disable-check],[disable building unit test libraries]),
 813   [
 814     case "${enableval}" in
 815       yes) BUILD_CHECK=yes ;;
 816       no)  BUILD_CHECK=no ;;
 817       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-check) ;;
 818     esac
 819   ], [
 820     dnl Default value
 821     case $host_os in
 822       mingw* | msvc* | mks*) BUILD_CHECK=no ;;
 823       *) BUILD_CHECK=yes ;;
 824     esac
 825 ])
 826 dnl bit of a misnomer, but keep the conditional named like this so we don't
 827 dnl have to change too much elsewhere
 828 AM_CONDITIONAL(HAVE_CHECK, test "x$BUILD_CHECK" = "xyes")
 829
 830 dnl configure the desired memory alignment
 831 AC_ARG_WITH([memory-alignment],
 832   AS_HELP_STRING([--with-memory-alignment],[8,N,malloc,pagesize (default is 32)]),
 833   [
 834     if test "x$withval" = "xyes"
 835     then
 836       AC_DEFINE(MEMORY_ALIGNMENT, 32, [Memory alignment to use])
 837     else
 838       case "${withval}" in
 839         malloc) AC_DEFINE(MEMORY_ALIGNMENT_MALLOC, 1, [Memory alignment by malloc default]) ;;
 840         pagesize)  AC_DEFINE(MEMORY_ALIGNMENT_PAGESIZE, 1, [Memory alignment by pagesize]) ;;
 841         *)   AC_DEFINE_UNQUOTED(MEMORY_ALIGNMENT, ${withval}, [Memory alignment to use]) ;;
 842       esac
 843     fi
 844   ], [
 845     AC_DEFINE(MEMORY_ALIGNMENT_MALLOC, 1, [Memory alignment by malloc default])
 846   ]
 847 )
 848
 849 dnl Check for -Bsymbolic-functions linker flag used to avoid
 850 dnl intra-library PLT jumps, if available.
 851 AC_ARG_ENABLE(Bsymbolic,
 852               [AS_HELP_STRING([--disable-Bsymbolic],[avoid linking with -Bsymbolic])],,
 853               [SAVED_LDFLAGS="${LDFLAGS}" SAVED_LIBS="${LIBS}"
 854                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
 855                LDFLAGS=-Wl,-Bsymbolic-functions
 856                LIBS=
 857                AC_TRY_LINK([], [return 0],
 858                            AC_MSG_RESULT(yes)
 859                            enable_Bsymbolic=yes,
 860                            AC_MSG_RESULT(no)
 861                            enable_Bsymbolic=no)
 862                LDFLAGS="${SAVED_LDFLAGS}" LIBS="${SAVED_LIBS}"])
 863
 864
 865 dnl *** set variables based on configure arguments
 866
 867 dnl set license and copyright notice
 868 GST_LICENSE="LGPL"
 869 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 870 AC_SUBST(GST_LICENSE)
 871
 872 dnl define LIBDIR, GST_DATADIR so we can inform people where we live
 873 AS_AC_EXPAND(LIBDIR, $libdir)
 874 AC_DEFINE_UNQUOTED(LIBDIR, "$LIBDIR", [library dir])
 875 AS_AC_EXPAND(DATADIR, $datadir)
 876 AC_DEFINE_UNQUOTED(GST_DATADIR, "$DATADIR", [data dir])
 877
 878 dnl set location of plugin directory
 879 AG_GST_SET_PLUGINDIR
 880
 881 dnl make sure it doesn't complain about unused variables if debugging is disabled
 882 NO_WARNINGS=""
 883 if test "x${GST_DISABLE_GST_DEBUG}" = "xyes"; then
 884   NO_WARNINGS="-Wno-unused"
 885 fi
 886
 887 dnl define an ERROR_CFLAGS Makefile variable
 888 AG_GST_SET_ERROR_CFLAGS($FATAL_WARNINGS, [-Wmissing-declarations -Wmissing-prototypes -Wredundant-decls -Wundef -Wwrite-strings -Wformat-nonliteral -Wformat-security -Wold-style-definition -Winit-self -Wmissing-include-dirs -Waddress -Waggregate-return -Wno-multichar -Wnested-externs $NO_WARNINGS])
 889
 890 dnl special warning flags for gst/printf
 891 AS_COMPILER_FLAG([-Wno-format-nonliteral], [PRINTF_CFLAGS="-Wno-format-nonliteral"])
 892 AC_SUBST(PRINTF_CFLAGS)
 893
 894 dnl define correct level for debugging messages
 895 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 896
 897 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 898
 899 dnl Overview:
 900 dnl GST_OPTION_CFLAGS:  common cflags for profiling, debugging, errors, ...
 901 dnl GST_ALL_*:          vars shared by all built objects
 902 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 903 dnl GST_OBJ_*:          additional vars to link to the core library
 904 dnl                     include GST_ALL_*
 905 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 906 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 907
 908 dnl GST_OPTION_CFLAGS
 909 if test "x$USE_DEBUG" = xyes; then
 910    PROFILE_CFLAGS="-g"
 911 fi
 912 AC_SUBST(PROFILE_CFLAGS)
 913
 914 # GST_DISABLE_DEPRECATED: hide the visibility of deprecated
 915 # functionality from the API that gstreamer uses
 916 # GST_REMOVE_DEPRECATED: don't compile deprecated functionality (breaks ABI)
 917 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
 918   dnl Define _only_ when compiling from git (not for pre-releases or releases)
 919   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 920 else
 921   DEPRECATED_CFLAGS=""
 922 fi
 923 AC_SUBST(DEPRECATED_CFLAGS)
 924
 925 dnl every flag in GST_OPTION_CFLAGS can be overridden at make time via e.g.
 926 dnl make DEPRECATED_CFLAGS=''
 927 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 928 GST_OPTION_CXXFLAGS="\$(WARNING_CXXFLAGS) \$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 929 GST_OPTION_CFLAGS="$GST_OPTION_CFLAGS"
 930 GST_OPTION_CXXFLAGS="$GST_OPTION_CXXFLAGS"
 931 AC_SUBST(GST_OPTION_CFLAGS)
 932 AC_SUBST(GST_OPTION_CXXFLAGS)
 933
 934 dnl GST_ALL_*
 935 dnl vars common to for all internal objects (core libs, elements, applications)
 936 dnl CFLAGS:
 937 dnl - src and build dirs need to be added because every piece that gets built
 938 dnl   will need the GStreamer source and generated headers
 939 dnl LIBS: XML doesn't need to be added because we don't explicitly use symbols
 940 dnl       from LibXML except for in the core library
 941 GST_ALL_CXXFLAGS="-I\$(top_srcdir)/libs -I\$(top_srcdir) -I\$(top_builddir)/libs -I\$(top_builddir) $GLIB_CFLAGS \$(GLIB_EXTRA_CFLAGS) $XML_CFLAGS \$(GST_OPTION_CXXFLAGS) \$(ERROR_CXXFLAGS)"
 942 GST_ALL_CFLAGS="-I\$(top_srcdir)/libs -I\$(top_srcdir) -I\$(top_builddir)/libs -I\$(top_builddir) $GLIB_CFLAGS \$(GLIB_EXTRA_CFLAGS) $XML_CFLAGS \$(GST_OPTION_CFLAGS) \$(ERROR_CFLAGS)"
 943
 944 dnl FIXME: check if LTLIBINTL is needed everywhere
 945 dnl I presume it is given that it contains the symbols that _() stuff maps to
 946 GST_ALL_LIBS="$GLIB_LIBS $LTLIBINTL \$(GCOV_LIBS)"
 947
 948 dnl LDFLAGS really should only contain flags, not libs - they get added before
 949 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 950 GST_ALL_LDFLAGS="-no-undefined"
 951 if test "x${enable_Bsymbolic}" = "xyes"; then
 952   GST_ALL_LDFLAGS="$GST_ALL_LDFLAGS -Wl,-Bsymbolic-functions"
 953 fi
 954
 955 AC_SUBST(GST_ALL_CFLAGS)
 956 AC_SUBST(GST_ALL_CXXFLAGS)
 957 AC_SUBST(GST_ALL_LIBS)
 958 AC_SUBST(GST_ALL_LDFLAGS)
 959
 960 dnl GST_LIB_LDFLAGS
 961 dnl linker flags shared by all libraries
 962 dnl LDFLAGS modifier defining exported symbols from built libraries
 963 GST_LIB_LDFLAGS="-export-symbols-regex \^[_]?\(gst_\|Gst\|GST_\).*"
 964 AC_SUBST(GST_LIB_LDFLAGS)
 965
 966 dnl GST_OBJ_*
 967 dnl default vars for all internal objects built on libgstreamer
 968 dnl includes GST_ALL_*
 969 GST_OBJ_CFLAGS="\$(GST_ALL_CFLAGS) $GST_OBJ_STATIC_CFLAGS"
 970 GST_OBJ_CXXFLAGS="\$(GST_ALL_CXXFLAGS) $GST_OBJ_STATIC_CFLAGS"
 971 GST_OBJ_LIBS="\$(top_builddir)/gst/libgstreamer-$GST_API_VERSION.la \$(GST_ALL_LIBS)"
 972 AC_SUBST(GST_OBJ_CFLAGS)
 973 AC_SUBST(GST_OBJ_CXXFLAGS)
 974 AC_SUBST(GST_OBJ_LIBS)
 975
 976 dnl GST_PLUGIN_LDFLAGS
 977 dnl LDFLAGS for plugins; includes GST_ALL_LDFLAGS
 978 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_.*' $GST_ALL_LDFLAGS"
 979 AC_SUBST(GST_PLUGIN_LDFLAGS, "$GST_PLUGIN_LDFLAGS")
 980
 981 dnl plugin scanner locations
 982 AS_AC_EXPAND(GST_PLUGIN_SCANNER_INSTALLED,${libexecdir}/gstreamer-$GST_API_VERSION/gst-plugin-scanner)
 983 AC_DEFINE_UNQUOTED(GST_PLUGIN_SCANNER_INSTALLED,
 984     "$GST_PLUGIN_SCANNER_INSTALLED", [location of the installed gst-plugin-scanner])
 985 AC_SUBST(GST_PLUGIN_SCANNER_INSTALLED)
 986
 987 dnl ptp helper locations
 988 AS_AC_EXPAND(GST_PTP_HELPER_INSTALLED,${libexecdir}/gstreamer-$GST_API_VERSION/gst-ptp-helper)
 989 AC_DEFINE_UNQUOTED(GST_PTP_HELPER_INSTALLED,
 990     "$GST_PTP_HELPER_INSTALLED", [location of the installed gst-ptp-helper])
 991 AC_SUBST(GST_PTP_HELPER_INSTALLED)
 992
 993 dnl things for our internal libcheck (must be called even if building
 994 dnl libcheck is disabled because it defines conditionals)
 995 AG_GST_CHECK_CHECKS
 996
 997 AC_CONFIG_FILES(
 998 Makefile
 999 data/Makefile
1000 gst/Makefile
1001 gst/gstconfig.h
1002 gst/gstversion.h
1003 gst/parse/Makefile
1004 gst/printf/Makefile
1005 libs/Makefile
1006 libs/gst/Makefile
1007 libs/gst/base/Makefile
1008 libs/gst/check/Makefile
1009 libs/gst/check/libcheck/Makefile
1010 libs/gst/check/internal-check.h:libs/gst/check/libcheck/check.h.in
1011 libs/gst/controller/Makefile
1012 libs/gst/helpers/Makefile
1013 libs/gst/net/Makefile
1014 plugins/Makefile
1015 plugins/elements/Makefile
1016 plugins/tracers/Makefile
1017 po/Makefile.in
1018 tests/Makefile
1019 tests/benchmarks/Makefile
1020 tests/check/Makefile
1021 tests/misc/Makefile
1022 tests/examples/Makefile
1023 tests/examples/adapter/Makefile
1024 tests/examples/controller/Makefile
1025 tests/examples/stepping/Makefile
1026 tests/examples/helloworld/Makefile
1027 tests/examples/manual/Makefile
1028 tests/examples/memory/Makefile
1029 tests/examples/netclock/Makefile
1030 tests/examples/ptp/Makefile
1031 tests/examples/streamiddemux/Makefile
1032 tests/examples/streams/Makefile
1033 tools/Makefile
1034 common/Makefile
1035 common/m4/Makefile
1036 docs/Makefile
1037 docs/design/Makefile
1038 docs/faq/Makefile
1039 docs/gst/Makefile
1040 docs/gst/gstreamer.types
1041 docs/libs/Makefile
1042 docs/plugins/Makefile
1043 docs/manual/Makefile
1044 docs/pwg/Makefile
1045 docs/slides/Makefile
1046 docs/xsl/Makefile
1047 docs/version.entities
1048 m4/Makefile
1049 pkgconfig/Makefile
1050 stamp.h
1051 pkgconfig/gstreamer.pc
1052 pkgconfig/gstreamer-uninstalled.pc
1053 pkgconfig/gstreamer-base.pc
1054 pkgconfig/gstreamer-base-uninstalled.pc
1055 pkgconfig/gstreamer-check.pc
1056 pkgconfig/gstreamer-check-uninstalled.pc
1057 pkgconfig/gstreamer-controller.pc
1058 pkgconfig/gstreamer-controller-uninstalled.pc
1059 pkgconfig/gstreamer-net.pc
1060 pkgconfig/gstreamer-net-uninstalled.pc
1061 gstreamer.spec
1062 )
1063
1064 dnl Create the config.h file for Visual Studio builds
1065 dnl Beware of spaces and /'s in some of the shell variable contents.
1066 sed \
1067     -e 's/.*config.h.in.*autoheader.*/\/* Autogenerated config.h created for win32 Visual Studio builds *\/\n\n\/* PREFIX -- specifically added for Windows for easier moving *\/\n#define PREFIX "C:\\\\gstreamer"/' \
1068     -e 's/.* GETTEXT_PACKAGE$/#define GETTEXT_PACKAGE "'$GETTEXT_PACKAGE'"/' \
1069     -e 's/.* GST_DATADIR$/#define GST_DATADIR PREFIX "\\\\share"/' \
1070     -e 's/.* GST_LEVEL_DEFAULT$/#define GST_LEVEL_DEFAULT GST_LEVEL_ERROR/' \
1071     -e 's/.* GST_LICENSE$/#define GST_LICENSE "'$GST_LICENSE'"/' \
1072     -e 's/.* GST_API_VERSION$/#define GST_API_VERSION "'$GST_API_VERSION'"/' \
1073     -e "s,.* GST_PACKAGE_NAME$,#define GST_PACKAGE_NAME \"${GST_PACKAGE_NAME}\"," \
1074     -e 's/.* GST_PACKAGE_ORIGIN$/#define GST_PACKAGE_ORIGIN "Unknown package origin"/' \
1075     -e "s,.* GST_PACKAGE_RELEASE_DATETIME$,#define GST_PACKAGE_RELEASE_DATETIME \"${GST_PACKAGE_RELEASE_DATETIME}\"," \
1076     -e 's/.* HAVE_CPU_I386$/#define HAVE_CPU_I386 1/' \
1077     -e 's/.* HAVE_FGETPOS$/#define HAVE_FGETPOS 1/' \
1078     -e 's/.* HAVE_FSETPOS$/#define HAVE_FSETPOS 1/' \
1079     -e 's/.* HAVE_PROCESS_H$/#define HAVE_PROCESS_H 1/' \
1080     -e 's/.* HAVE_STDLIB_H$/#define HAVE_STDLIB_H 1/' \
1081     -e 's/.* HAVE_STRING_H$/#define HAVE_STRING_H 1/' \
1082     -e 's/.* HAVE_SYS_STAT_H$/#define HAVE_SYS_STAT_H 1/' \
1083     -e 's/.* HAVE_SYS_TYPES_H$/#define HAVE_SYS_TYPES_H 1/' \
1084     -e 's/.* HAVE_WIN32$/#define HAVE_WIN32 1/' \
1085     -e 's/.* HAVE_WINSOCK2_H$/#define HAVE_WINSOCK2_H 1/' \
1086     -e 's/.* HOST_CPU$/#define HOST_CPU "i686"/' \
1087     -e 's/.* MEMORY_ALIGNMENT_MALLOC/#define MEMORY_ALIGNMENT_MALLOC 1/' \
1088     -e 's/.* LIBDIR$/#ifdef _DEBUG\n#  define LIBDIR PREFIX "\\\\debug\\\\lib"\n#else\n#  define LIBDIR PREFIX "\\\\lib"\n#endif/' \
1089     -e 's/.* LOCALEDIR$/#define LOCALEDIR PREFIX "\\\\share\\\\locale"/' \
1090     -e 's/.* PACKAGE$/#define PACKAGE "gstreamer"/' \
1091     -e 's/.* PACKAGE_BUGREPORT$/#define PACKAGE_BUGREPORT "http:\/\/bugzilla.gnome.org\/enter_bug.cgi?product=GStreamer"/' \
1092     -e 's/.* PACKAGE_NAME$/#define PACKAGE_NAME "'$PACKAGE_NAME'"/' \
1093     -e "s/.* PACKAGE_STRING$/#define PACKAGE_STRING \"$PACKAGE_STRING\"/" \
1094     -e 's/.* PACKAGE_TARNAME$/#define PACKAGE_TARNAME "'$PACKAGE_TARNAME'"/' \
1095     -e 's/.* PACKAGE_VERSION$/#define PACKAGE_VERSION "'$PACKAGE_VERSION'"/' \
1096     -e 's/.* PLUGINDIR$/#ifdef _DEBUG\n#  define PLUGINDIR PREFIX "\\\\debug\\\\lib\\\\gstreamer-1.0"\n#else\n#  define PLUGINDIR PREFIX "\\\\lib\\\\gstreamer-1.0"\n#endif/' \
1097     -e 's/.* GST_PLUGIN_SCANNER_INSTALLED$/#define GST_PLUGIN_SCANNER_INSTALLED LIBDIR "\\\\gst-plugin-scanner"/' \
1098     -e 's/.* VERSION$/#define VERSION "'$VERSION'"/' \
1099     config.h.in >win32/common/config.h-new
1100
1101 AC_OUTPUT
1102
1103 dnl negate for output
1104 if test "x${GST_DISABLE_GST_DEBUG}" = "xno"; then enable_gst_debug="yes"; fi
1105 if test "x${GST_DISABLE_GST_TRACER_HOOKS}" = "xno"; then enable_gst_tracer_hooks="yes"; fi
1106 if test "x${GST_DISABLE_PARSE}" = "xno"; then enable_parse="yes"; fi
1107 if test "x${GST_DISABLE_OPTION_PARSING}" = "xno"; then enable_option_parsing="yes"; fi
1108 if test "x${GST_DISABLE_PLUGIN}" = "xno"; then enable_plugin="yes"; fi
1109 if test "x${GST_DISABLE_REGISTRY}" = "xno"; then enable_registry="yes"; fi
1110
1111 echo "
1112
1113 Configuration
1114         Version                    : ${VERSION}
1115         Source code location       : ${srcdir}
1116         Prefix                     : ${prefix}
1117         Compiler                   : ${CC}
1118         Package name               : ${GST_PACKAGE_NAME}
1119         Package origin             : ${GST_PACKAGE_ORIGIN}
1120
1121         Documentation (manuals)    : ${enable_docbook}
1122         Documentation (API)        : ${enable_gtk_doc}
1123
1124         Debug logging              : ${enable_gst_debug}
1125         Tracing subsystem hooks    : ${enable_gst_tracer_hooks}
1126         Command-line parser        : ${enable_parse}
1127         Option parsing in gst_init : ${enable_option_parsing}
1128         Plugin registry            : ${enable_registry}
1129         Plugin support             : ${enable_plugin}
1130         Static plugins             : ${enable_static_plugins}
1131         Unit testing support       : ${BUILD_CHECK}
1132         PTP clock support          : ${HAVE_PTP}
1133         libunwind support          : ${HAVE_UNWIND}
1134
1135         Debug                      : ${USE_DEBUG}
1136         Profiling                  : ${USE_PROFILING}
1137
1138         Building benchmarks        : ${BUILD_BENCHMARKS}
1139         Building examples          : ${BUILD_EXAMPLES}
1140         Building test apps         : ${BUILD_TESTS}
1141         Building tests that fail   : ${BUILD_FAILING_TESTS}
1142         Building tools             : ${BUILD_TOOLS}
1143 "