configure.ac

   1 AC_PREREQ(2.60)
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, git and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for git/pre
   8 AC_INIT(GStreamer Good Plug-ins, 0.10.31.1,
   9     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
  10     gst-plugins-good)
  11
  12 AG_GST_INIT
  13
  14 dnl initialize automake
  15 AM_INIT_AUTOMAKE([-Wno-portability 1.10])
  16
  17 dnl define PACKAGE_VERSION_* variables
  18 AS_VERSION
  19
  20 dnl check if this is a release version
  21 AS_NANO(GST_GIT="no", GST_GIT="yes")
  22
  23 dnl can autoconf find the source ?
  24 AC_CONFIG_SRCDIR([gst/law/alaw.c])
  25
  26 dnl define the output header for config
  27 AM_CONFIG_HEADER([config.h])
  28
  29 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  30 AM_MAINTAINER_MODE
  31
  32 dnl sets host_* variables
  33 AC_CANONICAL_HOST
  34
  35 dnl use pretty build output with automake >= 1.11
  36 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],
  37   [AM_DEFAULT_VERBOSITY=1
  38    AC_SUBST(AM_DEFAULT_VERBOSITY)])
  39
  40 dnl our libraries and install dirs use major.minor as a version
  41 GST_MAJORMINOR=$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR
  42 dnl we override it here if we need to for the release candidate of new series
  43 GST_MAJORMINOR=0.10
  44 AC_SUBST(GST_MAJORMINOR)
  45
  46 AG_GST_LIBTOOL_PREPARE
  47
  48 dnl FIXME: this macro doesn't actually work;
  49 dnl the generated libtool script has no support for the listed tags.
  50 dnl So this needs to be fixed first if we want to use this
  51 dnl AS_LIBTOOL_TAGS
  52
  53 AC_LIBTOOL_WIN32_DLL
  54 AM_PROG_LIBTOOL
  55
  56 dnl *** required versions of GStreamer stuff ***
  57 GST_REQ=0.10.36
  58 GSTPB_REQ=0.10.36
  59
  60 dnl *** autotools stuff ****
  61
  62 dnl allow for different autotools
  63 AS_AUTOTOOLS_ALTERNATE
  64
  65 dnl Add parameters for aclocal
  66 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  67
  68 dnl set up gettext
  69 dnl the version check needs to stay here because autopoint greps for it
  70 AM_GNU_GETTEXT_VERSION([0.17])
  71 AM_GNU_GETTEXT([external])
  72 AG_GST_GETTEXT([gst-plugins-good-$GST_MAJORMINOR])
  73
  74 dnl *** check for arguments to configure ***
  75
  76 AG_GST_ARG_DISABLE_FATAL_WARNINGS
  77
  78 AG_GST_ARG_DEBUG
  79 AG_GST_ARG_PROFILING
  80 AG_GST_ARG_VALGRIND
  81 AG_GST_ARG_GCOV
  82
  83 AG_GST_ARG_EXAMPLES
  84
  85 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  86 AG_GST_ARG_WITH_PACKAGE_NAME
  87 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  88
  89 AG_GST_ARG_WITH_PLUGINS
  90
  91 AG_GST_ARG_ENABLE_EXTERNAL
  92
  93 AG_GST_ARG_ENABLE_EXPERIMENTAL
  94
  95 dnl *** checks for platform ***
  96
  97 dnl * hardware/architecture *
  98
  99 dnl common/m4/gst-arch.m4
 100 dnl check CPU type
 101 AG_GST_ARCH
 102
 103 dnl Determine endianness
 104 AC_C_BIGENDIAN
 105
 106 dnl *** checks for programs ***
 107
 108 dnl find a compiler
 109 AC_PROG_CC
 110 AC_PROG_CC_STDC
 111
 112 dnl determine c++ compiler
 113 AC_PROG_CXX
 114 dnl determine if c++ is available on this system
 115 AC_CHECK_PROG(HAVE_CXX, $CXX, yes, no)
 116
 117 dnl determine c++ preprocessor
 118 dnl FIXME: do we need this ?
 119 AC_PROG_CXXCPP
 120
 121 AS_PROG_OBJC
 122
 123 dnl check if the compiler supports '-c' and '-o' options
 124 AM_PROG_CC_C_O
 125
 126 dnl find an assembler
 127 AM_PROG_AS
 128
 129 dnl check if the compiler supports do while(0) macros
 130 AG_GST_CHECK_DOWHILE_MACROS
 131
 132 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 133 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 134
 135 dnl check for gconftool-2
 136 dnl this macro defines an am conditional, so it needs to be run always
 137 AM_GCONF_SOURCE_2
 138
 139 dnl check for documentation tools
 140 GTK_DOC_CHECK([1.3])
 141 AS_PATH_PYTHON([2.1])
 142 AG_GST_PLUGIN_DOCS([1.3],[2.1])
 143
 144 dnl *** checks for libraries ***
 145
 146 dnl check for libm, for sin()
 147 AC_CHECK_LIBM
 148 AC_SUBST(LIBM)
 149
 150 dnl *** checks for header files ***
 151
 152 dnl check if we have ANSI C header files
 153 AC_HEADER_STDC
 154
 155 dnl used by ext/wavpack
 156 AX_CREATE_STDINT_H
 157
 158 dnl used in gst/rtp/gstasteriskh263.c
 159 AC_CHECK_HEADERS([netinet/in.h])
 160 AC_CHECK_HEADERS([winsock2.h], HAVE_WINSOCK2_H=yes)
 161 AM_CONDITIONAL(HAVE_WINSOCK2_H, test "x$HAVE_WINSOCK2_H" = "xyes")
 162
 163 dnl used in gst/udp
 164 AC_CHECK_HEADERS([sys/time.h])
 165
 166 dnl *** checks for types/defines ***
 167
 168 dnl Check for FIONREAD ioctl declaration.  This check is needed
 169 dnl for the UDP plugin to build on Solaris
 170 GST_CHECK_FIONREAD
 171
 172 dnl *** checks for structures ***
 173
 174 dnl *** checks for compiler characteristics ***
 175
 176 dnl check if we have GCC inline-asm
 177 AS_GCC_INLINE_ASSEMBLY([HAVE_GCC_ASM=yes], [HAVE_GCC_ASM=no])
 178 if test x$HAVE_GCC_ASM = xyes ; then
 179   AC_DEFINE(HAVE_GCC_ASM, 1,
 180     [Define if compiler supports gcc inline assembly])
 181 fi
 182 AM_CONDITIONAL(HAVE_GCC_ASM, test "x$HAVE_GCC_ASM" = "xyes")
 183
 184 dnl *** checks for library functions ***
 185
 186 LIBS_SAVE=$LIBS
 187 LIBS="$LIBS $LIBM"
 188 AC_CHECK_FUNCS(rint sinh cosh asinh fpclass)
 189 LIBS=$LIBS_SAVE
 190
 191 dnl Check whether isinf() is defined by math.h
 192 AC_CACHE_CHECK([for isinf], ac_cv_have_isinf,
 193     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>]], [[float f = 0.0; int i=isinf(f)]])],[ac_cv_have_isinf="yes"],[ac_cv_have_isinf="no"]))
 194 if test "$ac_cv_have_isinf" = "yes"
 195 then
 196     AC_DEFINE(HAVE_ISINF, 1, [Define to 1 if you have the `isinf' function.])
 197 fi
 198
 199 dnl Check for mmap (needed by electricfence plugin)
 200 AC_FUNC_MMAP
 201 AM_CONDITIONAL(GST_HAVE_MMAP, test "x$ac_cv_func_mmap_fixed_mapped" = "xyes")
 202
 203 dnl Check for mmap (needed by electricfence plugin)
 204
 205 AC_CHECK_TYPE([struct ip_mreqn], [
 206               AC_DEFINE(HAVE_IP_MREQN,, [Define if we have struct ip_mreqn])],,
 207               [#include <netinet/in.h>])
 208
 209 dnl *** checks for dependency libraries ***
 210
 211 dnl GLib is required
 212 AG_GST_GLIB_CHECK([2.24])
 213 PKG_CHECK_MODULES(GIO, [ gio-2.0 >= 2.20 ], , AC_MSG_ERROR([gio is required]))
 214
 215 dnl Orc
 216 ORC_CHECK([0.4.11])
 217
 218 dnl checks for gstreamer
 219 dnl uninstalled is selected preferentially -- see pkg-config(1)
 220 AG_GST_CHECK_GST($GST_MAJORMINOR, [$GST_REQ], yes)
 221 AG_GST_CHECK_GST_BASE($GST_MAJORMINOR, [$GST_REQ], yes)
 222 AG_GST_CHECK_GST_GDP($GST_MAJORMINOR, [$GST_REQ], yes)
 223 AG_GST_CHECK_GST_CONTROLLER($GST_MAJORMINOR, [$GST_REQ], yes)
 224 AG_GST_CHECK_GST_CHECK($GST_MAJORMINOR, [$GST_REQ], no)
 225 AG_GST_CHECK_GST_PLUGINS_BASE($GST_MAJORMINOR, [$GSTPB_REQ], yes)
 226
 227 GST_TOOLS_DIR=`$PKG_CONFIG --variable=toolsdir gstreamer-$GST_MAJORMINOR`
 228 if test -z $GST_TOOLS_DIR; then
 229   AC_MSG_ERROR([no tools dir defined in GStreamer pkg-config file; core upgrade needed.])
 230 fi
 231 AC_SUBST(GST_TOOLS_DIR)
 232
 233 AC_MSG_NOTICE(Using GStreamer Core Plugins in $GST_PLUGINS_DIR)
 234 AC_MSG_NOTICE(Using GStreamer Base Plugins in $GSTPB_PLUGINS_DIR)
 235
 236 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 237
 238 dnl Check for documentation xrefs
 239 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 240 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_MAJORMINOR`"
 241 GSTPB_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-plugins-base-$GST_MAJORMINOR`"
 242 AC_SUBST(GLIB_PREFIX)
 243 AC_SUBST(GST_PREFIX)
 244 AC_SUBST(GSTPB_PREFIX)
 245
 246 dnl GTK is optional and used in examples
 247 HAVE_GTK=no
 248 GTK2_REQ=2.14.0
 249 GTK3_REQ=2.91.3
 250 if test "x$BUILD_EXAMPLES" = "xyes"; then
 251   AC_MSG_CHECKING([which gtk+ version to compile examples against (optional)])
 252   AC_ARG_WITH([gtk],
 253     AC_HELP_STRING([--with-gtk=3.0|2.0],
 254                    [which gtk+ version to compile against (default: 2.0)]),
 255     [case "$with_gtk" in
 256         2.0) GTK_REQ=$GTK2_REQ ;;
 257         3.0) GTK_REQ=$GTK3_REQ ;;
 258         *) AC_MSG_ERROR([invalid gtk+ version specified]);;
 259     esac],
 260     [with_gtk=2.0
 261      GTK_REQ=$GTK2_REQ])
 262   AC_MSG_RESULT([$with_gtk (>= $GTK_REQ)])
 263   PKG_CHECK_MODULES(GTK, gtk+-$with_gtk >= $GTK_REQ, HAVE_GTK=yes, HAVE_GTK=no)
 264   dnl some examples need gtk+-x11
 265   PKG_CHECK_MODULES(GTK_X11, gtk+-x11-$with_gtk >= $GTK_REQ, HAVE_GTK_X11=yes, HAVE_GTK_X11=no)
 266   AC_SUBST(GTK_LIBS)
 267   AC_SUBST(GTK_CFLAGS)
 268 fi
 269 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 270 AM_CONDITIONAL(HAVE_GTK_X11, test "x$HAVE_GTK_X11" = "xyes")
 271
 272 dnl should we install schemas ?
 273 translit(dnm, m, l) AM_CONDITIONAL(USE_GCONFTOOL, true)
 274 AG_GST_CHECK_FEATURE(GCONFTOOL, [GConf schemas], , [
 275   AC_PATH_PROG(GCONFTOOL, gconftool-2, no)
 276   if test x$GCONFTOOL = xno; then
 277     AC_MSG_WARN(Not installing GConf schemas)
 278     HAVE_GCONFTOOL="no"
 279   else
 280     HAVE_GCONFTOOL="yes"
 281   fi
 282   AC_SUBST(HAVE_GCONFTOOL)
 283 ])
 284
 285 dnl *** set variables based on configure arguments ***
 286
 287 dnl set license and copyright notice
 288 GST_LICENSE="LGPL"
 289 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 290 AC_SUBST(GST_LICENSE)
 291
 292 dnl set location of plugin directory
 293 AG_GST_SET_PLUGINDIR
 294
 295 dnl set release date/time
 296 AG_GST_SET_PACKAGE_RELEASE_DATETIME_WITH_NANO([$PACKAGE_VERSION_NANO],
 297   ["${srcdir}/gst-plugins-good.doap"],
 298   [$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_MICRO])
 299
 300 dnl define an ERROR_CFLAGS Makefile variable
 301 dnl -Wundef: too many broken headers
 302 if test "x$HAVE_OSX_VIDEO" != "xyes"; then
 303   AG_GST_SET_ERROR_CFLAGS($FATAL_WARNINGS, [
 304         -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls
 305         -Wwrite-strings -Wold-style-definition -Waggregate-return
 306         -Winit-self -Wmissing-include-dirs -Waddress -Wno-multichar
 307         -Wnested-externs ])
 308 else
 309   dnl work-around for us passing GST_CFLAGS to the ObjC-compiler, which
 310   dnl doesn't understand all warning flags that the C compiler knows about
 311   dnl (e.g. -Waddress) or causes problems with some flags (-Waggregate-return)
 312   AG_GST_SET_ERROR_CFLAGS($FATAL_WARNINGS, [
 313         -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls
 314         -Wwrite-strings -Wold-style-definition
 315         -Winit-self -Wmissing-include-dirs -Wno-multichar
 316         -Wnested-externs ])
 317 fi
 318
 319 dnl define an ERROR_CXXFLAGS Makefile variable
 320 AG_GST_SET_ERROR_CXXFLAGS($FATAL_WARNINGS, [
 321         -Wmissing-declarations -Wredundant-decls
 322         -Wwrite-strings
 323         -Winit-self -Wmissing-include-dirs -Waddress -Wno-multichar ])
 324
 325 dnl define correct level for debugging messages
 326 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 327
 328 dnl used in examples
 329 AG_GST_DEFAULT_ELEMENTS
 330
 331 dnl *** plug-ins to include ***
 332
 333 dnl these are all the gst plug-ins, compilable without additional libs
 334 dnl videofilter is at the top because others depend on it
 335 AG_GST_CHECK_PLUGIN(videofilter)
 336 AG_GST_CHECK_PLUGIN(alpha)
 337 AG_GST_CHECK_PLUGIN(apetag)
 338 AG_GST_CHECK_PLUGIN(audiofx)
 339 AG_GST_CHECK_PLUGIN(audioparsers)
 340 AG_GST_CHECK_PLUGIN(auparse)
 341 AG_GST_CHECK_PLUGIN(autodetect)
 342 AG_GST_CHECK_PLUGIN(avi)
 343 AG_GST_CHECK_PLUGIN(cutter)
 344 AG_GST_CHECK_PLUGIN(debugutils)
 345 AG_GST_CHECK_PLUGIN(deinterlace)
 346 AG_GST_CHECK_PLUGIN(effectv)
 347 AG_GST_CHECK_PLUGIN(equalizer)
 348 AG_GST_CHECK_PLUGIN(flv)
 349 AG_GST_CHECK_PLUGIN(id3demux)
 350 AG_GST_CHECK_PLUGIN(icydemux)
 351 AG_GST_CHECK_PLUGIN(interleave)
 352 AG_GST_CHECK_PLUGIN(flx)
 353 AG_GST_CHECK_PLUGIN(goom)
 354 AG_GST_CHECK_PLUGIN(goom2k1)
 355 AG_GST_CHECK_PLUGIN(imagefreeze)
 356 AG_GST_CHECK_PLUGIN(isomp4)
 357 AG_GST_CHECK_PLUGIN(law)
 358 AG_GST_CHECK_PLUGIN(level)
 359 AG_GST_CHECK_PLUGIN(matroska)
 360 AG_GST_CHECK_PLUGIN(monoscope)
 361 AG_GST_CHECK_PLUGIN(multifile)
 362 AG_GST_CHECK_PLUGIN(multipart)
 363 AG_GST_CHECK_PLUGIN(replaygain)
 364 AG_GST_CHECK_PLUGIN(rtp)
 365 AG_GST_CHECK_PLUGIN(rtpmanager)
 366 AG_GST_CHECK_PLUGIN(rtsp)
 367 AG_GST_CHECK_PLUGIN(shapewipe)
 368 AG_GST_CHECK_PLUGIN(smpte)
 369 AG_GST_CHECK_PLUGIN(spectrum)
 370 AG_GST_CHECK_PLUGIN(udp)
 371 AG_GST_CHECK_PLUGIN(videobox)
 372 AG_GST_CHECK_PLUGIN(videocrop)
 373 AG_GST_CHECK_PLUGIN(videomixer)
 374 AG_GST_CHECK_PLUGIN(wavenc)
 375 AG_GST_CHECK_PLUGIN(wavparse)
 376 AG_GST_CHECK_PLUGIN(y4m)
 377
 378 dnl *** checks for socket and nsl libraries ***
 379 AC_CHECK_FUNC(socket,,[AC_CHECK_LIB(socket,socket)])
 380
 381 dnl disable gst plugins we might not be able to build on this
 382 dnl platform: udp and rtsp (ugly but minimally invasive)
 383 dnl FIXME: maybe move to sys
 384 AC_CHECK_HEADERS([sys/socket.h], HAVE_SYS_SOCKET_H=yes)
 385 AC_CHECK_HEADERS([winsock2.h], HAVE_WINSOCK2_H=yes)
 386
 387 if test "x$HAVE_SYS_SOCKET_H" != "xyes" -a "x$HAVE_WINSOCK2_H" != "xyes"; then
 388   AG_GST_DISABLE_PLUGIN(udp)
 389   AG_GST_DISABLE_PLUGIN(rtsp)
 390 fi
 391
 392 if test "x$HAVE_WINSOCK2_H" = "xyes"; then
 393   WIN32_LIBS="-lws2_32"
 394   AC_SUBST(WIN32_LIBS)
 395 fi
 396
 397 dnl disable experimental plug-ins
 398 if test "x$BUILD_EXPERIMENTAL" != "xyes"; then
 399   AG_GST_DISABLE_PLUGIN(monoscope)
 400 fi
 401
 402 dnl *** sys plug-ins ***
 403
 404 echo
 405 AC_MSG_NOTICE([Checking libraries for plugins in sys/])
 406 echo
 407
 408 dnl DirectSound
 409 translit(dnm, m, l) AM_CONDITIONAL(USE_DIRECTSOUND, true)
 410 AG_GST_CHECK_FEATURE(DIRECTSOUND, [DirectSound plug-in], directsoundsink, [
 411   HAVE_DIRECTSOUND="no"
 412   save_CFLAGS="$CFLAGS"
 413   save_LDFLAGS="$LDFLAGS"
 414   save_LIBS="$LIBS"
 415   CFLAGS="$CFLAGS $DIRECTSOUND_CFLAGS"
 416   LDFLAGS="$LDFLAGS $DIRECTSOUND_LDFLAGS"
 417   LIBS="$LIBS -ldsound -ldxerr9 -luser32"
 418   AC_MSG_CHECKING(for DirectSound LDFLAGS)
 419   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 420 #include <windows.h>
 421 #include <dxerr9.h>
 422 #include <dsound.h>
 423 ]], [[
 424   DXGetErrorString9 (0);
 425   DirectSoundCreate(NULL, NULL, NULL);
 426 ]])
 427 ],
 428     [HAVE_DIRECTSOUND="yes"],
 429     [HAVE_DIRECTSOUND="no"])
 430   AC_MSG_RESULT($HAVE_DIRECTSOUND)
 431   CFLAGS=$save_CFLAGS
 432   LDFLAGS=$save_LDFLAGS
 433   LIBS=$save_LIBS
 434
 435   if test "x$HAVE_DIRECTSOUND" = "xyes";  then
 436     dnl this is much more than we want
 437     DIRECTSOUND_LIBS="-ldsound -ldxerr9 -luser32"
 438     AC_SUBST(DIRECTSOUND_CFLAGS)
 439     AC_SUBST(DIRECTSOUND_LDFLAGS)
 440     AC_SUBST(DIRECTSOUND_LIBS)
 441   fi
 442   AC_SUBST(HAVE_DIRECTSOUND)
 443 ])
 444
 445 dnl *** Win32 WaveOut ***
 446 translit(dnm, m, l) AM_CONDITIONAL(USE_WAVEFORM, true)
 447 AG_GST_CHECK_FEATURE(WAVEFORM, [Win32 WaveForm], waveformsink, [
 448   AC_CHECK_HEADER(mmsystem.h, HAVE_WAVEFORM="yes", HAVE_WAVEFORM="no", [#include <windows.h>])
 449 ])
 450
 451 dnl *** OSS audio *** (Linux, *BSD)
 452 translit(dnm, m, l) AM_CONDITIONAL(USE_OSS, true)
 453 AG_GST_CHECK_FEATURE(OSS, [OSS audio], ossaudio, [
 454  HAVE_OSS="yes"
 455 dnl Linux and newer BSD versions :
 456  AC_CHECK_HEADER(sys/soundcard.h, [
 457    AC_DEFINE(HAVE_OSS_INCLUDE_IN_SYS,, [Define if OSS includes are in /sys/])
 458    ] , [
 459 dnl Some old BSD versions and also newer OpenBSD versions :
 460    AC_CHECK_HEADER(soundcard.h, [
 461      AC_DEFINE(HAVE_OSS_INCLUDE_IN_ROOT,, [Define if OSS includes are in /])
 462      ], [
 463   dnl Some old BSD versions :
 464      AC_CHECK_HEADER(machine/soundcard.h, [
 465        AC_DEFINE(HAVE_OSS_INCLUDE_IN_MACHINE,,
 466          [Define if OSS includes are in /machine/])
 467        ], [
 468        HAVE_OSS="no"
 469      ])
 470    ])
 471  ])
 472 ])
 473
 474 dnl *** oss4 ***
 475 translit(dnm, m, l) AM_CONDITIONAL(USE_OSS4, true)
 476 AG_GST_CHECK_FEATURE(OSS4, [Open Sound System 4], oss4, [
 477   AC_MSG_CHECKING([Checking if we can build the OSS4 elements])
 478   AC_CHECK_HEADERS([fcntl.h sys/ioctl.h sys/stat.h sys/types.h],
 479       [test -z "$OSS4_MISSING_HEADER" && HAVE_OSS4="yes"],
 480       [OSS4_MISSING_HEADER="yes";HAVE_OSS4="no"])
 481 ])
 482
 483 dnl *** Sun Audio ***
 484 translit(dnm, m, l) AM_CONDITIONAL(USE_SUNAUDIO, true)
 485 AG_GST_CHECK_FEATURE(SUNAUDIO, [Sun Audio], sunaudio, [
 486   AC_CHECK_HEADER(sys/audioio.h, HAVE_SUNAUDIO="yes", HAVE_SUNAUDIO="no")
 487 ])
 488
 489 dnl *** OSX Audio ***
 490 translit(dnm, m, l) AM_CONDITIONAL(USE_OSX_AUDIO, true)
 491 AG_GST_CHECK_FEATURE(OSX_AUDIO, [OSX audio], osxaudio, [
 492   AC_CHECK_HEADER(CoreAudio/CoreAudio.h, HAVE_OSX_AUDIO="yes", HAVE_OSX_AUDIO="no")
 493 ])
 494
 495 dnl *** OS X video ***
 496 translit(dnm, m, l) AM_CONDITIONAL(USE_OSX_VIDEO, true)
 497 HAVE_OSX_VIDEO="no"
 498 AG_GST_CHECK_FEATURE(OSX_VIDEO, [OSX video], osxvideosink, [
 499   AC_CHECK_HEADER(OpenGL/gl.h, HAVE_OSX_VIDEO="yes", HAVE_OSX_VIDEO="no")
 500 ])
 501 dnl in case header OpenGL/gl.h is found on other platforms
 502 case "$host" in
 503   *-*darwin*)
 504     dnl do nothing
 505     ;;
 506   *)
 507     HAVE_OSX_VIDEO="no"
 508     ;;
 509 esac
 510
 511
 512 dnl *** Video 4 Linux 2 ***
 513 dnl for information about the header/define, see sys/v4l2/gstv4l2element.h
 514 dnl renamed to GST_V4L2 because of some conflict with kernel headers
 515 translit(dnm, m, l) AM_CONDITIONAL(USE_GST_V4L2, true)
 516 AG_GST_CHECK_FEATURE(GST_V4L2, [Video 4 Linux 2], v4l2src, [
 517   AC_MSG_CHECKING([Checking for up to date v4l2 installation])
 518   AC_TRY_COMPILE([
 519 #include <sys/types.h>
 520 #ifdef __sun /* Solaris */
 521 #include <sys/types.h>
 522 #include <sys/videodev2.h>
 523 #else /* Linux */
 524 #include <linux/types.h>
 525 #define _LINUX_TIME_H
 526 #define __user
 527 #include <linux/videodev2.h>
 528 #endif
 529 #if defined(V4L2_MAJOR_VERSION) || defined(V4L2_MINOR_VERSION)
 530 #error too early v4l2 version or no v4l2 at all
 531 #endif
 532     ], [
 533 return 0;
 534     ], [
 535       HAVE_GST_V4L2="yes"
 536       AC_MSG_RESULT(yes)
 537     ], [
 538       HAVE_GST_V4L2="no"
 539       AC_MSG_RESULT(no)
 540
 541       HAVE_VIDEODEV=no
 542       AC_CHECK_HEADER(linux/videodev2.h, [ HAVE_VIDEODEV=yes ],
 543       [
 544         AC_CHECK_HEADER(sys/videodev2.h, [ HAVE_VIDEODEV=yes ])
 545       ])
 546
 547       if test "x$HAVE_VIDEODEV" = "xyes"; then
 548         AC_MSG_WARN([video4linux2 headers were found, but they're old.])
 549         AC_MSG_WARN([Please update v4l2 to compile the v4l2 plugins])
 550       else
 551         AC_MSG_WARN([video4linux2 was not found])
 552       fi
 553     ])
 554
 555   if [ test x$HAVE_GST_V4L2 = xyes ]; then
 556     dnl check for missing v4l2_buffer declaration (see #135919)
 557     MISSING_DECL=0
 558     AC_MSG_CHECKING(struct v4l2_buffer declaration)
 559     AC_TRY_COMPILE([
 560 #include <sys/types.h>
 561 #ifdef __sun /* Solaris */
 562 #include <sys/types.h>
 563 #include <sys/videodev2.h>
 564 #else /* Linux */
 565 #include <linux/types.h>
 566 #define _LINUX_TIME_H
 567 #define __user
 568 #include <linux/videodev2.h>
 569 #endif
 570     ],[
 571 struct v4l2_buffer buf;
 572 buf.index = 0;
 573 return 0;
 574     ], [ AC_MSG_RESULT(yes) ], [ MISSING_DECL=1 && AC_MSG_RESULT(no) ])
 575     if [ test x$MISSING_DECL = x1 ]; then
 576       AC_DEFINE(GST_V4L2_MISSING_BUFDECL, 1, [struct v4l2_buffer missing])
 577     fi
 578
 579     dnl check for XOverlay libraries
 580     AG_GST_CHECK_XV
 581   fi
 582 ])
 583
 584 # Optional gudev for device probing
 585 AC_ARG_WITH([gudev],
 586   AC_HELP_STRING([--with-gudev],
 587     [device detection with gudev]),
 588   [],
 589   [with_gudev=check])
 590 if test x$HAVE_GST_V4L2 = xyes; then
 591   if test x$with_gudev != xno; then
 592       PKG_CHECK_MODULES(GUDEV, [ gudev-1.0 >= 143 ],
 593           [ have_gudev=yes
 594             AC_DEFINE(HAVE_GUDEV, 1,
 595                [Whether gudev is available for device detection])
 596             AC_DEFINE([G_UDEV_API_IS_SUBJECT_TO_CHANGE], 1, [I know the API is subject to change.])
 597           ], [
 598           have_gudev=no
 599           ])
 600   else
 601     have_gudev=no
 602   fi
 603 fi
 604 AC_SUBST(GUDEV_CFLAGS)
 605 AC_SUBST(GUDEV_LIBS)
 606
 607 # Make libv4l2 non-automagic
 608 AC_ARG_WITH([libv4l2],
 609   AC_HELP_STRING([--with-libv4l2],
 610     [support video buffer conversion using libv4l2]),
 611   [],
 612   [with_libv4l2=check])
 613 if test x$HAVE_GST_V4L2 = xyes; then
 614   if test x$with_libv4l2 != xno; then
 615       PKG_CHECK_MODULES(LIBV4L2, libv4l2,
 616           [ have_libv4l2=yes
 617             AC_DEFINE(HAVE_LIBV4L2, 1,
 618                 [Whether libv4l2 is available for video buffer conversion])
 619           ], [
 620           have_libv4l2=no
 621           ])
 622   else
 623     have_libv4l2=no
 624   fi
 625 fi
 626
 627 dnl Check for X11
 628 translit(dnm, m, l) AM_CONDITIONAL(USE_X, true)
 629 AG_GST_CHECK_FEATURE(X, [X libraries and plugins],
 630                   [ximagesrc], [
 631   AC_PATH_XTRA
 632
 633   dnl now try to find the HEADER
 634   ac_cflags_save="$CFLAGS"
 635   ac_cppflags_save="$CPPFLAGS"
 636   CFLAGS="$CFLAGS $X_CFLAGS"
 637   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 638   AC_CHECK_HEADER(X11/Xlib.h, HAVE_X="yes", HAVE_X="no")
 639
 640   if test "x$HAVE_X" = "xno"
 641   then
 642     AC_MSG_NOTICE([cannot find X11 development files])
 643   else
 644     dnl this is much more than we want
 645     X_LIBS="$X_LIBS $X_PRE_LIBS $X_EXTRA_LIBS"
 646     dnl AC_PATH_XTRA only defines the path needed to find the X libs,
 647     dnl it does not add the libs; therefore we add them here
 648     X_LIBS="$X_LIBS -lX11"
 649     AC_SUBST(X_CFLAGS)
 650     AC_SUBST(X_LIBS)
 651
 652     dnl check for Xfixes
 653     PKG_CHECK_MODULES(XFIXES, xfixes, HAVE_XFIXES="yes", HAVE_XFIXES="no")
 654     if test "x$HAVE_XFIXES" = "xyes"
 655     then
 656         XFIXES_CFLAGS="-DHAVE_XFIXES $XFIXES_CFLAGS"
 657     fi
 658     AC_SUBST(XFIXES_LIBS)
 659     AC_SUBST(XFIXES_CFLAGS)
 660
 661     dnl check for Xdamage
 662     PKG_CHECK_MODULES(XDAMAGE, xdamage, HAVE_XDAMAGE="yes", HAVE_XDAMAGE="no")
 663     if test "x$HAVE_XDAMAGE" = "xyes"
 664     then
 665         XDAMAGE_CFLAGS="-DHAVE_XDAMAGE $XDAMAGE_CFLAGS"
 666     fi
 667     AC_SUBST(XDAMAGE_LIBS)
 668     AC_SUBST(XDAMAGE_CFLAGS)
 669   fi
 670   AC_SUBST(HAVE_X)
 671   CFLAGS="$ac_cflags_save"
 672   CPPFLAGS="$ac_cppflags_save"
 673 ])
 674
 675 dnl FIXME: this should be rolled into the test above, it's just an additional
 676 dnl feature of the ximagesrc plug-in
 677 dnl This is the same as in gst-plugins-base
 678 dnl check for X Shm
 679 translit(dnm, m, l) AM_CONDITIONAL(USE_XSHM, true)
 680 AG_GST_CHECK_FEATURE(XSHM, [X Shared Memory extension], , [
 681   if test x$HAVE_X = xyes; then
 682     AC_CHECK_LIB(Xext, XShmAttach,
 683                  HAVE_XSHM="yes", HAVE_XSHM="no",
 684                  $X_LIBS)
 685     if test "x$HAVE_XSHM" = "xyes"; then
 686       XSHM_LIBS="-lXext"
 687     else
 688       dnl On AIX, it is in XextSam instead, but we still need -lXext
 689       AC_CHECK_LIB(XextSam, XShmAttach,
 690                    HAVE_XSHM="yes", HAVE_XSHM="no",
 691                    $X_LIBS)
 692       if test "x$HAVE_XSHM" = "xyes"; then
 693         XSHM_LIBS="-lXext -lXextSam"
 694       fi
 695     fi
 696   fi
 697 ], ,[
 698   AC_SUBST(HAVE_XSHM)
 699   AC_SUBST(XSHM_LIBS)
 700 ])
 701
 702 dnl for V4L2, we also need to know if we have XVIDEO
 703 translit(dnm, m, l) AM_CONDITIONAL(USE_XVIDEO, true)
 704 AG_GST_CHECK_FEATURE(XVIDEO, [X11 XVideo extensions],
 705                   [], [
 706   AG_GST_CHECK_XV
 707 ])
 708
 709 dnl *** ext plug-ins ***
 710 dnl keep this list sorted alphabetically !
 711
 712 if test "x$BUILD_EXTERNAL" = "xyes"; then
 713
 714 echo
 715 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 716 echo
 717
 718 dnl *** aalib ***
 719 translit(dnm, m, l) AM_CONDITIONAL(USE_AALIB, true)
 720 AG_GST_CHECK_FEATURE(AALIB, [aalib ASCII Art library], aasink, [
 721   AM_PATH_AALIB(, HAVE_AALIB=yes, HAVE_AALIB=no)
 722   AS_SCRUB_INCLUDE(AALIB_CFLAGS)
 723 ])
 724
 725 dnl *** annodex ***
 726 translit(dnm, m, l) AM_CONDITIONAL(USE_ANNODEX, true)
 727 AG_GST_CHECK_FEATURE(ANNODEX, [XML library], annodex, [
 728   AG_GST_PKG_CHECK_MODULES(ANNODEX, libxml-2.0 >= 2.4.9)
 729 ])
 730
 731 dnl *** cairo ***
 732 translit(dnm, m, l) AM_CONDITIONAL(USE_CAIRO, true)
 733 AG_GST_CHECK_FEATURE(CAIRO, [Cairo graphics rendering], cairo, [
 734   AG_GST_PKG_CHECK_MODULES(CAIRO, cairo >= 1.0.0)
 735 ])
 736
 737 dnl *** cairo-gobject ***
 738 translit(dnm, m, l) AM_CONDITIONAL(USE_CAIRO_GOBJECT, true)
 739 AG_GST_CHECK_FEATURE(CAIRO_GOBJECT,
 740   [Cairo graphics rendering gobject bindings], cairooverlay, [
 741   AG_GST_PKG_CHECK_MODULES(CAIRO_GOBJECT, cairo-gobject >= 1.10.0)
 742 ])
 743
 744 dnl **** ESound ****
 745 translit(dnm, m, l) AM_CONDITIONAL(USE_ESD, true)
 746 AG_GST_CHECK_FEATURE(ESD, [ESounD sound daemon], esdsink, [
 747   AG_GST_PKG_CHECK_MODULES(ESD, esound >= 0.2.12)
 748   if test $HAVE_ESD = no
 749   then
 750     AM_PATH_ESD(0.2.12, HAVE_ESD="yes")
 751     AS_SCRUB_INCLUDE(ESD_CFLAGS)
 752   fi
 753 ])
 754
 755 dnl *** FLAC ***
 756 translit(dnm, m, l) AM_CONDITIONAL(USE_FLAC, true)
 757 AG_GST_CHECK_FEATURE(FLAC, [FLAC lossless audio], flac, [
 758   AG_GST_PKG_CHECK_MODULES(FLAC, flac >= 1.1.4)
 759 ])
 760
 761 dnl *** GConf ***
 762 translit(dnm, m, l) AM_CONDITIONAL(USE_GCONF, true)
 763 AG_GST_CHECK_FEATURE(GCONF, [GConf libraries], gconfelements, [
 764   AG_GST_PKG_CHECK_MODULES(GCONF, gconf-2.0)
 765 ])
 766
 767 dnl *** GDK pixbuf ***
 768 translit(dnm, m, l) AM_CONDITIONAL(USE_GDK_PIXBUF, true)
 769 AG_GST_CHECK_FEATURE(GDK_PIXBUF, [GDK pixbuf], gdkpixbuf, [
 770   AG_GST_PKG_CHECK_MODULES(GDK_PIXBUF, gdk-pixbuf-2.0 >= 2.8.0)
 771 ])
 772
 773 dnl *** HAL ***
 774 translit(dnm, m, l) AM_CONDITIONAL(USE_HAL, true)
 775 AG_GST_CHECK_FEATURE(HAL, [HAL libraries], halelements, [
 776   AG_GST_PKG_CHECK_MODULES(HAL, [hal >= 0.5.6, dbus-1 >= 0.32])
 777 ])
 778
 779 dnl *** Jack ***
 780 translit(dnm, m, l) AM_CONDITIONAL(USE_JACK, true)
 781 AG_GST_CHECK_FEATURE(JACK, Jack, jack, [
 782   PKG_CHECK_MODULES(JACK, jack >= 0.99.10, HAVE_JACK="yes", HAVE_JACK="no")
 783   AC_SUBST(JACK_CFLAGS)
 784   AC_SUBST(JACK_LIBS)
 785
 786   AG_GST_PKG_CHECK_MODULES(JACK_0_120_1, jack >= 0.120.1 jack < 1.0)
 787   if test x$HAVE_JACK_0_120_1 = xyes; then
 788     AC_DEFINE(HAVE_JACK_0_120_1, 1, [defined if jack >= 0.120.1 is available])
 789   fi
 790   AG_GST_PKG_CHECK_MODULES(JACK_1_9_7, jack >= 1.9.7)
 791   if test x$HAVE_JACK_1_9_7 = xyes; then
 792     AC_DEFINE(HAVE_JACK_1_9_7, 1, [defined if jack >= 1.9.7 is available])
 793   fi
 794
 795 ])
 796
 797 dnl *** jpeg ***
 798 dnl FIXME: we could use header checks here as well IMO
 799 translit(dnm, m, l) AM_CONDITIONAL(USE_JPEG, true)
 800 AG_GST_CHECK_FEATURE(JPEG, [jpeg library], jpeg, [
 801   AC_ARG_WITH(jpeg-mmx,
 802     [  --with-jpeg-mmx, path to MMX'ified JPEG library])
 803   OLD_LIBS="$LIBS"
 804   if test x$with_jpeg_mmx != x; then
 805     LIBS="$LIBS -L$with_jpeg_mmx"
 806   fi
 807   AC_CHECK_LIB(jpeg-mmx, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
 808   JPEG_LIBS="$LIBS -ljpeg-mmx"
 809   LIBS="$OLD_LIBS"
 810   if test x$HAVE_JPEG != xyes; then
 811     AC_CHECK_LIB(jpeg, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
 812     JPEG_LIBS="-ljpeg"
 813   fi
 814   AC_SUBST(JPEG_LIBS)
 815 ])
 816
 817 dnl *** libcaca ***
 818 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBCACA, true)
 819 AG_GST_CHECK_FEATURE(LIBCACA, [libcaca coloured ASCII art], cacasink, [
 820   AG_GST_PKG_CHECK_MODULES(LIBCACA, caca)
 821 ])
 822
 823 dnl *** libdv ***
 824 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBDV, true)
 825 AG_GST_CHECK_FEATURE(LIBDV, [libdv DV demuxer/decoder], dv, [
 826   AG_GST_PKG_CHECK_MODULES(LIBDV, libdv >= 0.100)
 827 ])
 828
 829 dnl *** libpng ***
 830 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBPNG, true)
 831 AG_GST_CHECK_FEATURE(LIBPNG, [Portable Network Graphics library], png, [
 832   AG_GST_PKG_CHECK_MODULES(LIBPNG, libpng >= 1.2)
 833 ])
 834
 835 dnl *** pulseaudio ***
 836 translit(dnm, m, l) AM_CONDITIONAL(USE_PULSE, true)
 837 AG_GST_CHECK_FEATURE(PULSE, [pulseaudio plug-in], pulseaudio, [
 838
 839   dnl used in ext/pulse/pulseutil.c
 840   AC_CHECK_HEADERS([process.h])
 841
 842   AG_GST_PKG_CHECK_MODULES(PULSE, libpulse >= 0.9.16)
 843   AG_GST_PKG_CHECK_MODULES(PULSE_0_9_20, libpulse >= 0.9.20)
 844   if test x$HAVE_PULSE_0_9_20 = xyes; then
 845     AC_DEFINE(HAVE_PULSE_0_9_20, 1, [defined if pulseaudio >= 0.9.20 is available])
 846   fi
 847   AG_GST_PKG_CHECK_MODULES(PULSE_1_0, libpulse >= 0.98)
 848   if test x$HAVE_PULSE_1_0 = xyes; then
 849     AC_DEFINE(HAVE_PULSE_1_0, 1, [defined if pulseaudio >= 1.0 is available])
 850   fi
 851 ])
 852
 853 dnl *** dv1394 ***
 854 translit(dnm, m, l) AM_CONDITIONAL(USE_DV1394, true)
 855 AG_GST_CHECK_FEATURE(DV1394, [raw1394 and avc1394 library], 1394, [
 856   dnl first test for libraw1394 >= 2.0.0
 857   AG_GST_PKG_CHECK_MODULES(RAW1394, libraw1394 >= 2.0.0)
 858   AG_GST_PKG_CHECK_MODULES(LIBIEC61883, libiec61883 >= 1.0.0)
 859   dnl now see how far we got
 860   if test x$HAVE_RAW1394 = xyes && \
 861      test x$HAVE_LIBIEC61883 = xyes; then
 862        AG_GST_CHECK_LIBHEADER(AVC1394,
 863         avc1394, avc1394_send_command, $RAW1394_LIBS,
 864         libavc1394/avc1394.h, AVC1394_LIBS="-lavc1394")
 865        AG_GST_CHECK_LIBHEADER(ROM1394,
 866         rom1394, rom1394_free_directory, $RAW1394_LIBS,
 867         libavc1394/rom1394.h, ROM1394_LIBS="-lrom1394")
 868        if test x$HAVE_AVC1394 = xyes && \
 869           test x$HAVE_AVC1394 = xyes && \
 870           test x$HAVE_ROM1394 = xyes; then
 871           HAVE_DV1394=yes
 872           DV1394_LIBS="$RAW1394_LIBS $AVC1394_LIBS $ROM1394_LIBS $LIBIEC61883_LIBS"
 873           DV1394_CFLAGS="$RAW1394_CFLAGS $LIBIEC61883_CFLAGS -DHAVE_LIBIEC61883"
 874           AC_SUBST(DV1394_CFLAGS)
 875           AC_SUBST(DV1394_LIBS)
 876         fi
 877   else
 878        if test x$HAVE_RAW1394 = xno; then
 879           AG_GST_PKG_CHECK_MODULES(RAW1394, libraw1394 >= 1.1.0)
 880           AG_GST_CHECK_LIBHEADER(AVC1394,
 881            avc1394, avc1394_send_command, $RAW1394_LIBS,
 882            libavc1394/avc1394.h, AVC1394_LIBS="-lavc1394")
 883           AG_GST_CHECK_LIBHEADER(ROM1394,
 884            rom1394, rom1394_free_directory, $RAW1394_LIBS,
 885            libavc1394/rom1394.h, ROM1394_LIBS="-lrom1394")
 886           if test x$HAVE_RAW1394 = xyes && \
 887              test x$HAVE_AVC1394 = xyes && \
 888              test x$HAVE_ROM1394 = xyes; then
 889              HAVE_DV1394=yes
 890              DV1394_LIBS="$RAW1394_LIBS $AVC1394_LIBS $ROM1394_LIBS"
 891              DV1394_CFLAGS="$RAW1394_CFLAGS"
 892              if test x$HAVE_LIBIEC61883 = xyes; then
 893                DV1394_CFLAGS="$RAW1394_CFLAGS $LIBIEC61883_CFLAGS -DHAVE_LIBIEC61883"
 894                DV1394_LIBS="$DV1394_LIBS $LIBIEC61883_LIBS"
 895              fi
 896              AC_SUBST(DV1394_CFLAGS)
 897              AC_SUBST(DV1394_LIBS)
 898            fi
 899          fi
 900   fi
 901 ])
 902 AM_CONDITIONAL(USE_LIBIEC61883, [ test "x${HAVE_LIBIEC61883}" = xyes ] )
 903
 904 dnl *** shout2 ***
 905 translit(dnm, m, l) AM_CONDITIONAL(USE_SHOUT2, true)
 906 AG_GST_CHECK_FEATURE(SHOUT2, [Shoutcast/Icecast client library], shout2, [
 907   AG_GST_PKG_CHECK_MODULES(SHOUT2, shout >= 2.0)
 908 ])
 909
 910 dnl *** soup ***
 911 translit(dnm, m, l) AM_CONDITIONAL(USE_SOUP, true)
 912 AG_GST_CHECK_FEATURE(SOUP, [soup http client plugin (2.4)], souphttpsrc, [
 913   PKG_CHECK_MODULES(SOUP, libsoup-gnome-2.4 >= 2.3.2, [
 914     HAVE_SOUP="yes"
 915     AC_DEFINE(HAVE_LIBSOUP_GNOME, 1, [soup gnome integration])
 916   ],[
 917     PKG_CHECK_MODULES(SOUP, libsoup-2.4 >= 2.26, HAVE_SOUP="yes", [
 918       HAVE_SOUP="no"
 919     ])
 920   ])
 921   AC_SUBST(SOUP_CFLAGS)
 922   AC_SUBST(SOUP_LIBS)
 923 ])
 924
 925 dnl *** speex >= 1.0.4 or >= 1.1.5 ***
 926 dnl   1.1.4 and earlier were not API/ABI compatible with 1.0
 927 dnl   1.1.6 is the first to use a .pc/pkg-config file ***
 928 dnl   speex_jitter.h is 1.1.x only
 929 translit(dnm, m, l) AM_CONDITIONAL(USE_SPEEX, true)
 930 AG_GST_CHECK_FEATURE(SPEEX, [speex speech codec], speex, [
 931   AG_GST_PKG_CHECK_MODULES(SPEEX, speex >= 1.1.6)
 932   if test $HAVE_SPEEX = no
 933   then
 934     AG_GST_CHECK_LIBHEADER(SPEEX, speex, speex_bits_init, , speex/speex.h, [
 935       AC_CHECK_HEADER(speex/speex_jitter.h, [
 936         dnl speex 1.1.x :
 937         AG_GST_CHECK_LIBHEADER(SPEEX, speex, speex_encode_int, , speex/speex.h, [
 938           dnl speex 1.1.5 or + :
 939           HAVE_SPEEX="yes"
 940           SPEEX_LIBS="-lspeex"
 941           AC_SUBST(SPEEX_CFLAGS)
 942           AC_SUBST(SPEEX_LIBS)
 943         ],[
 944           HAVE_SPEEX="no"
 945         ])
 946       ],[
 947         dnl speex 1.0.x :
 948           AC_CHECK_DECL(SPEEX_GET_LOOKAHEAD, [
 949             dnl speex 1.0.4
 950             HAVE_SPEEX="yes"
 951             SPEEX_LIBS="-lspeex"
 952             AC_SUBST(SPEEX_CFLAGS)
 953             AC_SUBST(SPEEX_LIBS)
 954
 955             AC_DEFINE_UNQUOTED(SPEEX_1_0, 1,
 956               [defined if speex 1.0.x API detected])
 957         ],[
 958             HAVE_SPEEX="no"
 959             AC_MSG_NOTICE(You need at least 1.0.4 to compile the speex plugin)
 960         ], [
 961 #include <speex/speex.h>
 962         ])
 963       ])
 964     ])
 965   fi
 966 ])
 967
 968 dnl *** taglib ***
 969 translit(dnm, m, l) AM_CONDITIONAL(USE_TAGLIB, true)
 970 AG_GST_CHECK_FEATURE(TAGLIB, [taglib tagging library], taglib, [
 971   AG_GST_PKG_CHECK_MODULES(TAGLIB, taglib >= 1.5)
 972   if test "x$HAVE_CXX" != "xyes"; then
 973     USE_TAGLIB=false
 974     AC_MSG_NOTICE([Not building taglib plugin: no C++ compiler found])
 975   else
 976     dnl work around bug in taglib 1.5 headers, remove once there is a 1.6
 977     AS_CXX_COMPILER_FLAG([-Wno-attributes], [
 978         TAGLIB_CXXFLAGS="$TAGLIB_CFLAGS -Wno-attributes"
 979       ], [
 980         TAGLIB_CXXFLAGS="$TAGLIB_CFLAGS"
 981     ])
 982     AC_SUBST(TAGLIB_CXXFLAGS)
 983   fi
 984 ])
 985
 986 dnl *** wavpack ***
 987 translit(dnm, m, l) AM_CONDITIONAL(USE_WAVPACK, true)
 988 AG_GST_CHECK_FEATURE(WAVPACK, [wavpack plug-in], wavpack, [
 989   PKG_CHECK_MODULES(WAVPACK, wavpack >= 4.40.0, HAVE_WAVPACK=yes, [
 990     PKG_CHECK_MODULES(WAVPACK, wavpack >= 4.20, [
 991       HAVE_WAVPACK=yes
 992       AC_DEFINE(WAVPACK_OLD_API, 1, [old wavpack API])
 993     ],[
 994       HAVE_WAVPACK=no
 995     ])
 996   ])
 997   AC_SUBST(WAVPACK_CFLAGS)
 998   AC_SUBST(WAVPACK_LIBS)
 999 ])
1000
1001 dnl *** qtdemux & matroska prefer to have zlib ***
1002 translit(dnm, m, l) AM_CONDITIONAL(USE_ZLIB, true)
1003 AG_GST_CHECK_FEATURE(ZLIB, [zlib support for qtdemux/matroska],, [
1004   AG_GST_CHECK_LIBHEADER(ZLIB,
1005     z, uncompress,, zlib.h, [
1006     HAVE_ZLIB="yes"
1007     ZLIB_LIBS="-lz"
1008     AC_SUBST(ZLIB_LIBS)
1009   ])
1010 ])
1011
1012 dnl *** matroska prefers to have bz2 ***
1013 translit(dnm, m, l) AM_CONDITIONAL(USE_BZ2, true)
1014 AG_GST_CHECK_FEATURE(BZ2, [bz2 library for matroska ],, [
1015   AG_GST_CHECK_LIBHEADER(BZ2, bz2, BZ2_bzCompress, ,bzlib.h, BZ2_LIBS="-lbz2")
1016   AC_SUBST(BZ2_LIBS)
1017 ])
1018
1019 else
1020
1021 dnl not building plugins with external dependencies,
1022 dnl but we still need to set the conditionals
1023 AM_CONDITIONAL(USE_AALIB, false)
1024 AM_CONDITIONAL(USE_ANNODEX, false)
1025 AM_CONDITIONAL(USE_BZ2, false)
1026 AM_CONDITIONAL(USE_CAIRO, false)
1027 AM_CONDITIONAL(USE_CAIRO_GOBJECT, false)
1028 AM_CONDITIONAL(USE_DIRECTSOUND, false)
1029 AM_CONDITIONAL(USE_DV1394, false)
1030 AM_CONDITIONAL(USE_ESD, false)
1031 AM_CONDITIONAL(USE_FLAC, false)
1032 AM_CONDITIONAL(USE_GCONF, false)
1033 AM_CONDITIONAL(USE_GCONFTOOL, false)
1034 AM_CONDITIONAL(USE_GDK_PIXBUF, false)
1035 AM_CONDITIONAL(USE_GST_V4L2, false)
1036 AM_CONDITIONAL(USE_HAL, false)
1037 AM_CONDITIONAL(USE_JACK, false)
1038 AM_CONDITIONAL(USE_JPEG, false)
1039 AM_CONDITIONAL(USE_LIBCACA, false)
1040 AM_CONDITIONAL(USE_LIBDV, false)
1041 AM_CONDITIONAL(USE_LIBIEC61883, false)
1042 AM_CONDITIONAL(USE_LIBPNG, false)
1043 AM_CONDITIONAL(USE_OSS, false)
1044 AM_CONDITIONAL(USE_OSS4, false)
1045 AM_CONDITIONAL(USE_OSX_AUDIO, false)
1046 AM_CONDITIONAL(USE_OSX_VIDEO, false)
1047 AM_CONDITIONAL(USE_PULSE, false)
1048 AM_CONDITIONAL(USE_SHOUT2, false)
1049 AM_CONDITIONAL(USE_SOUP, false)
1050 AM_CONDITIONAL(USE_SPEEX, false)
1051 AM_CONDITIONAL(USE_SUNAUDIO, false)
1052 AM_CONDITIONAL(USE_TAGLIB, false)
1053 AM_CONDITIONAL(USE_WAVEFORM, false)
1054 AM_CONDITIONAL(USE_WAVPACK, false)
1055 AM_CONDITIONAL(USE_X, false)
1056 AM_CONDITIONAL(USE_XSHM, false)
1057 AM_CONDITIONAL(USE_XVIDEO, false)
1058 AM_CONDITIONAL(USE_ZLIB, false)
1059
1060 fi dnl of EXT plugins
1061
1062 dnl *** finalize CFLAGS, LDFLAGS, LIBS
1063
1064 dnl Overview:
1065 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
1066 dnl GST_*:              flags shared by all built objects
1067 dnl GST_ALL_LDFLAGS:    linker flags shared by all
1068 dnl GST_LIB_LDFLAGS:    not needed, we don't install libraries
1069 dnl GST_LT_LDFLAGS:     library versioning of our libraries
1070 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
1071
1072 dnl GST_OPTION_CFLAGS
1073 if test "x$USE_DEBUG" = xyes; then
1074    PROFILE_CFLAGS="-g"
1075 fi
1076 AC_SUBST(PROFILE_CFLAGS)
1077
1078 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
1079   dnl Define _only_ for git (not pre-releases or releases)
1080   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
1081 else
1082   DEPRECATED_CFLAGS=""
1083 fi
1084 AC_SUBST(DEPRECATED_CFLAGS)
1085
1086 dnl every flag in GST_OPTION_CFLAGS and GST_OPTION_CXXFLAGS can be overridden
1087 dnl at make time with e.g. make ERROR_CFLAGS=""
1088 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
1089 GST_OPTION_CXXFLAGS="\$(WARNING_CXXFLAGS) \$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
1090 AC_SUBST(GST_OPTION_CFLAGS)
1091 AC_SUBST(GST_OPTION_CXXFLAGS)
1092
1093 dnl our libraries need to be versioned correctly
1094 AC_SUBST(GST_LT_LDFLAGS)
1095
1096 dnl FIXME: do we want to rename to GST_ALL_* ?
1097 dnl prefer internal headers to already installed ones
1098 dnl also add builddir include for enumtypes and marshal
1099 dnl add ERROR_CFLAGS, but overridable
1100 GST_CXXFLAGS="-I\$(top_srcdir)/gst-libs $GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_CXXFLAGS)"
1101 GST_CFLAGS="-I\$(top_srcdir)/gst-libs $GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_CFLAGS)"
1102 AC_SUBST(GST_CFLAGS)
1103 AC_SUBST(GST_CXXFLAGS)
1104 AC_SUBST(GST_LIBS)
1105
1106 dnl LDFLAGS really should only contain flags, not libs - they get added before
1107 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
1108 GST_ALL_LDFLAGS="-no-undefined"
1109 AC_SUBST(GST_ALL_LDFLAGS)
1110
1111 dnl this really should only contain flags, not libs - they get added before
1112 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
1113 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc.*' $GST_ALL_LDFLAGS"
1114 AC_SUBST(GST_PLUGIN_LDFLAGS)
1115
1116 dnl *** output files ***
1117
1118 dnl keep this alphabetic per directory, please
1119 AC_CONFIG_FILES(
1120 Makefile
1121 gst/Makefile
1122 gst/alpha/Makefile
1123 gst/apetag/Makefile
1124 gst/audiofx/Makefile
1125 gst/audioparsers/Makefile
1126 gst/auparse/Makefile
1127 gst/autodetect/Makefile
1128 gst/avi/Makefile
1129 gst/cutter/Makefile
1130 gst/deinterlace/Makefile
1131 gst/debugutils/Makefile
1132 gst/effectv/Makefile
1133 gst/equalizer/Makefile
1134 gst/flv/Makefile
1135 gst/goom/Makefile
1136 gst/goom2k1/Makefile
1137 gst/id3demux/Makefile
1138 gst/icydemux/Makefile
1139 gst/imagefreeze/Makefile
1140 gst/interleave/Makefile
1141 gst/isomp4/Makefile
1142 gst/law/Makefile
1143 gst/level/Makefile
1144 gst/matroska/Makefile
1145 gst/monoscope/Makefile
1146 gst/multifile/Makefile
1147 gst/multipart/Makefile
1148 gst/replaygain/Makefile
1149 gst/rtp/Makefile
1150 gst/rtpmanager/Makefile
1151 gst/rtsp/Makefile
1152 gst/shapewipe/Makefile
1153 gst/smpte/Makefile
1154 gst/spectrum/Makefile
1155 gst/udp/Makefile
1156 gst/videobox/Makefile
1157 gst/videocrop/Makefile
1158 gst/videofilter/Makefile
1159 gst/videomixer/Makefile
1160 gst/wavenc/Makefile
1161 gst/wavparse/Makefile
1162 gst/flx/Makefile
1163 gst/y4m/Makefile
1164 ext/Makefile
1165 ext/aalib/Makefile
1166 ext/annodex/Makefile
1167 ext/cairo/Makefile
1168 ext/dv/Makefile
1169 ext/esd/Makefile
1170 ext/flac/Makefile
1171 ext/gconf/Makefile
1172 ext/gdk_pixbuf/Makefile
1173 ext/hal/Makefile
1174 ext/jack/Makefile
1175 ext/jpeg/Makefile
1176 ext/libcaca/Makefile
1177 ext/libpng/Makefile
1178 ext/pulse/Makefile
1179 ext/raw1394/Makefile
1180 ext/shout2/Makefile
1181 ext/soup/Makefile
1182 ext/speex/Makefile
1183 ext/taglib/Makefile
1184 ext/wavpack/Makefile
1185 sys/Makefile
1186 sys/directsound/Makefile
1187 sys/oss/Makefile
1188 sys/oss4/Makefile
1189 sys/osxaudio/Makefile
1190 sys/osxvideo/Makefile
1191 sys/sunaudio/Makefile
1192 sys/v4l2/Makefile
1193 sys/waveform/Makefile
1194 sys/ximage/Makefile
1195 po/Makefile.in
1196 tests/Makefile
1197 tests/check/Makefile
1198 tests/examples/Makefile
1199 tests/examples/audiofx/Makefile
1200 tests/examples/cairo/Makefile
1201 tests/examples/equalizer/Makefile
1202 tests/examples/jack/Makefile
1203 tests/examples/level/Makefile
1204 tests/examples/pulse/Makefile
1205 tests/examples/rtp/Makefile
1206 tests/examples/shapewipe/Makefile
1207 tests/examples/spectrum/Makefile
1208 tests/examples/v4l2/Makefile
1209 tests/files/Makefile
1210 tests/icles/Makefile
1211 gconf/Makefile
1212 gconf/gstreamer.schemas
1213 common/Makefile
1214 common/m4/Makefile
1215 m4/Makefile
1216 docs/Makefile
1217 docs/plugins/Makefile
1218 docs/version.entities
1219 pkgconfig/Makefile
1220 pkgconfig/gstreamer-plugins-good-uninstalled.pc
1221 gst-plugins-good.spec
1222 )
1223
1224 dnl Create the config.h file for Visual Studio builds
1225 dnl Beware of spaces and /'s in some of the shell variable contents.
1226 sed \
1227     -e 's/.*config.h.in.*autoheader.*/\/* Autogenerated config.h created for win32 Visual Studio builds *\/\n\n\/* PREFIX -- specifically added for Windows for easier moving *\/\n#define PREFIX "C:\\\\gstreamer"\n\n#define GST_INSTALL_PLUGINS_HELPER PREFIX "\\\\libexec\\\\gst-install-plugins-helper.exe"/' \
1228     -e 's/.* GETTEXT_PACKAGE$/#define GETTEXT_PACKAGE "'$GETTEXT_PACKAGE'"/' \
1229     -e 's/.* GST_DATADIR$/#define GST_DATADIR PREFIX "\\\\share"/' \
1230     -e 's/.* GST_LEVEL_DEFAULT$/#define GST_LEVEL_DEFAULT GST_LEVEL_ERROR/' \
1231     -e 's/.* GST_LICENSE$/#define GST_LICENSE "'$GST_LICENSE'"/' \
1232     -e 's/.* GST_MAJORMINOR$/#define GST_MAJORMINOR "'$GST_MAJORMINOR'"/' \
1233     -e "s,.* GST_PACKAGE_NAME$,#define GST_PACKAGE_NAME \"${GST_PACKAGE_NAME}\"," \
1234     -e 's/.* GST_PACKAGE_ORIGIN$/#define GST_PACKAGE_ORIGIN "Unknown package origin"/' \
1235     -e "s,.* GST_PACKAGE_RELEASE_DATETIME$,#define GST_PACKAGE_RELEASE_DATETIME \"${GST_PACKAGE_RELEASE_DATETIME}\"," \
1236     -e 's/.* HAVE_CPU_I386$/#define HAVE_CPU_I386 1/' \
1237     -e 's/.* HAVE_FGETPOS$/#define HAVE_FGETPOS 1/' \
1238     -e 's/.* HAVE_FSETPOS$/#define HAVE_FSETPOS 1/' \
1239     -e 's/.* HAVE_LIBXML2$/#define HAVE_LIBXML2 1/' \
1240     -e 's/.* HAVE_PROCESS_H$/#define HAVE_PROCESS_H 1/' \
1241     -e 's/.* HAVE_STDLIB_H$/#define HAVE_STDLIB_H 1/' \
1242     -e 's/.* HAVE_STRING_H$/#define HAVE_STRING_H 1/' \
1243     -e 's/.* HAVE_SYS_STAT_H$/#define HAVE_SYS_STAT_H 1/' \
1244     -e 's/.* HAVE_SYS_TYPES_H$/#define HAVE_SYS_TYPES_H 1/' \
1245     -e 's/.* HAVE_WIN32$/#define HAVE_WIN32 1/' \
1246     -e 's/.* HAVE_WINSOCK2_H$/#define HAVE_WINSOCK2_H 1/' \
1247     -e 's/.* HOST_CPU$/#define HOST_CPU "i686"/' \
1248     -e 's/.* LIBDIR$/#ifdef _DEBUG\n#  define LIBDIR PREFIX "\\\\debug\\\\lib"\n#else\n#  define LIBDIR PREFIX "\\\\lib"\n#endif/' \
1249     -e 's/.* LOCALEDIR$/#define LOCALEDIR PREFIX "\\\\share\\\\locale"/' \
1250     -e "s/.* PACKAGE$/#define PACKAGE \"$PACKAGE\"/" \
1251     -e 's/.* PACKAGE_BUGREPORT$/#define PACKAGE_BUGREPORT "http:\/\/bugzilla.gnome.org\/enter_bug.cgi?product=GStreamer"/' \
1252     -e "s/.* PACKAGE_NAME$/#define PACKAGE_NAME \"$PACKAGE_NAME\"/" \
1253     -e "s/.* PACKAGE_STRING$/#define PACKAGE_STRING \"$PACKAGE_STRING\"/" \
1254     -e 's/.* PACKAGE_TARNAME$/#define PACKAGE_TARNAME "'$PACKAGE_TARNAME'"/' \
1255     -e 's/.* PACKAGE_VERSION$/#define PACKAGE_VERSION "'$PACKAGE_VERSION'"/' \
1256     -e 's/.* PLUGINDIR$/#ifdef _DEBUG\n#  define PLUGINDIR PREFIX "\\\\debug\\\\lib\\\\gstreamer-0.10"\n#else\n#  define PLUGINDIR PREFIX "\\\\lib\\\\gstreamer-0.10"\n#endif/' \
1257     -e 's/.* USE_BINARY_REGISTRY$/#define USE_BINARY_REGISTRY/' \
1258     -e 's/.* VERSION$/#define VERSION "'$VERSION'"/' \
1259     -e "s/.* DEFAULT_AUDIOSINK$/#define DEFAULT_AUDIOSINK \"directsoundsink\"/" \
1260     -e "s/.* DEFAULT_AUDIOSRC$/#define DEFAULT_AUDIOSRC \"audiotestsrc\"/" \
1261     -e "s/.* DEFAULT_VIDEOSRC$/#define DEFAULT_VIDEOSRC \"videotestsrc\"/" \
1262     -e "s/.* DEFAULT_VISUALIZER$/#define DEFAULT_VISUALIZER \"goom\"/" \
1263     config.h.in >win32/common/config.h-new
1264
1265 AC_OUTPUT
1266
1267 AG_GST_OUTPUT_PLUGINS
1268 ORC_OUTPUT
1269