configure.ac

   1 dnl autoconf configuration file for gst-plugins
   2 AC_INIT
   3 AC_CANONICAL_TARGET([])
   4
   5 dnl We disable static building for development, for time savings
   6 dnl this goes before AS_LIBTOOL to appease autoconf
   7 dnl *NOTE*: dnl this line before release, so release does static too
   8 AM_DISABLE_STATIC
   9
  10 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  11 AM_MAINTAINER_MODE
  12
  13 dnl when going to/from release please set the nano (fourth number) right !
  14 dnl releases only do Wall, cvs and prerelease does Werror too
  15 AS_VERSION(gst-plugins, GST_PLUGINS_VERSION, 0, 7, 4, 1, GST_CVS="no", GST_CVS="yes")
  16
  17 dnl add a suffix to apps
  18 if test x$program_suffix = xNONE ; then
  19   program_suffix=-$GST_PLUGINS_VERSION_MAJOR.$GST_PLUGINS_VERSION_MINOR
  20 fi
  21
  22 AM_INIT_AUTOMAKE($PACKAGE,$VERSION)
  23
  24 dnl our libraries and install dirs use major.minor as a version
  25 GST_MAJORMINOR=$GST_PLUGINS_VERSION_MAJOR.$GST_PLUGINS_VERSION_MINOR
  26 AC_SUBST(GST_MAJORMINOR)
  27
  28 dnl CURRENT, REVISION, AGE
  29 dnl - library source changed -> increment REVISION
  30 dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
  31 dnl - interfaces added -> increment AGE
  32 dnl - interfaces removed -> AGE = 0
  33 AS_LIBTOOL(GST_PLUGINS, 2, 0, 0)
  34 AM_PROG_LIBTOOL
  35
  36 dnl FIXME take something else ?
  37 AC_CONFIG_SRCDIR([gst/law/alaw.c])
  38 AM_CONFIG_HEADER(config.h)
  39
  40 dnl Add parameters for aclocal
  41 dnl (This must come after AM_INIT_AUTOMAKE, since it modifies ACLOCAL)
  42 ACLOCAL_FLAGS="-I m4 -I common/m4"
  43 AC_SUBST(ACLOCAL_AMFLAGS, $ACLOCAL_FLAGS)
  44
  45 AC_PROG_CC
  46 AM_PROG_CC_STDC
  47 AM_PROG_AS
  48 AS="${CC}"
  49
  50 dnl the gettext stuff needed
  51 AM_GNU_GETTEXT_VERSION(0.11.5)
  52 AM_GNU_GETTEXT([external])
  53
  54 GETTEXT_PACKAGE=gst-plugins-$GST_MAJORMINOR
  55 AC_SUBST(GETTEXT_PACKAGE)
  56 AC_DEFINE_UNQUOTED([GETTEXT_PACKAGE], "$GETTEXT_PACKAGE",
  57                    [gettext package name])
  58
  59 dnl define LOCALEDIR in config.h
  60 AS_AC_EXPAND(LOCALEDIR, $datadir/locale)
  61 AC_DEFINE_UNQUOTED([LOCALEDIR], "$LOCALEDIR",
  62                    [gettext locale dir])
  63
  64 dnl decide on error flags
  65 AS_COMPILER_FLAG(-Wall, GST_WALL="yes", GST_WALL="no")
  66
  67 if test "x$GST_WALL" = "xyes"; then
  68    GST_ERROR="$GST_ERROR -Wall -Wno-sign-compare"
  69
  70    if test "x$GST_CVS" = "xyes"; then
  71      AS_COMPILER_FLAG(-Werror,GST_ERROR="$GST_ERROR -Werror",GST_ERROR="$GST_ERROR")
  72      GST_ERROR="$GST_ERROR -DG_DISABLE_DEPRECATED"
  73    fi
  74 fi
  75
  76 dnl determine c++ compiler
  77 AC_PROG_CXX
  78 dnl determine if c++ is available on this system
  79 AC_CHECK_PROG(HAVE_CXX, $CXX, yes, no)
  80 dnl determine c++ preprocessor
  81 AC_PROG_CXXCPP
  82 AC_ISC_POSIX
  83
  84 AC_HEADER_STDC([])
  85 AC_C_INLINE
  86 AX_CREATE_STDINT_H
  87
  88 dnl Check for a way to display the function name in debug output
  89 GST_CHECK_FUNCTION()
  90
  91 dnl define correct errorlevel for debugging messages. We want to have GST_ERROR
  92 dnl messages printed when running cvs builds
  93 if test "x$GST_CVS" = "xyes"; then
  94   AC_DEFINE(GST_LEVEL_DEFAULT, GST_LEVEL_ERROR, [Default errorlevel to use])
  95 fi
  96
  97 dnl ############################################
  98 dnl # Super Duper options for plug-in building #
  99 dnl ############################################
 100
 101 dnl ext plug-ins; plug-ins that have external dependencies
 102 GST_CHECK_FEATURE(EXTERNAL, [enable building of plug-ins with external deps],,
 103 [HAVE_EXTERNAL=yes],enabled,
 104 [
 105   AC_MSG_WARN(building external plug-ins)
 106   BUILD_EXTERNAL="yes"
 107 ],[
 108   AC_MSG_WARN(all plug-ins with external dependencies will not be built)
 109   BUILD_EXTERNAL="no"
 110 ])
 111 # make BUILD_EXTERNAL available to Makefile.am
 112 AM_CONDITIONAL(BUILD_EXTERNAL, test "x$BUILD_EXTERNAL" = "xyes")
 113
 114 dnl experimental plug-ins; stuff that hasn't had the dust settle yet
 115 dnl read 'builds, but might not work'UTO
 116 GST_CHECK_FEATURE(EXPERIMENTAL, [enable building of experimental plug-ins],,
 117 [HAVE_EXPERIMENTAL=yes],disabled,
 118 [
 119   AC_MSG_WARN(building experimental plug-ins)
 120   USE_TARKIN="yes"
 121   USE_SHOUT2="yes"
 122 ],[
 123   AC_MSG_NOTICE(not building experimental plug-ins)
 124   USE_TARKIN="no"
 125   USE_SHOUT2="no"
 126 ])
 127
 128 dnl broken plug-ins; stuff that doesn't seem to build at the moment
 129 GST_CHECK_FEATURE(BROKEN, [enable building of broken plug-ins],,
 130 HAVE_BROKEN=yes,disabled,
 131 [
 132   AC_MSG_WARN([building broken plug-ins -- no bug reports on these, only patches :)])
 133 ],[
 134   AC_MSG_NOTICE([not building broken plug-ins])
 135 ])
 136
 137 dnl ##############################
 138 dnl # Do automated configuration #
 139 dnl ##############################
 140
 141 dnl Check for tools:
 142 dnl ================
 143
 144 dnl allow for different autotools
 145 AS_AUTOTOOLS_ALTERNATE()
 146
 147 dnl modify pkg-config path
 148 AC_ARG_WITH(pkg-config-path,
 149    AC_HELP_STRING([--with-pkg-config-path],[colon-separated list of pkg-config(1) dirs]),
 150    [export PKG_CONFIG_PATH=${withval}])
 151
 152 dnl check architecture
 153 GST_ARCH()
 154
 155 dnl Check for nasm
 156 AC_PATH_PROG(NASM_PATH, nasm, no)
 157 AC_SUBST(NASM_PATH)
 158 if test x$NASM_PATH = xno; then
 159   AC_MSG_WARN(Couldn't find nasm)
 160   HAVE_NASM="no"
 161 else
 162   AC_DEFINE(HAVE_NASM, 1, [Define if NASM, the netwide assembler, is available])
 163   HAVE_NASM="yes"
 164 fi
 165
 166 dnl check for gconftool-2
 167 translit(dnm, m, l) AM_CONDITIONAL(USE_GCONFTOOL, true)
 168 GST_CHECK_FEATURE(GCONFTOOL, [GConf schemas], , [
 169   AC_PATH_PROG(GCONFTOOL, gconftool-2, no)
 170   if test x$GCONFTOOL = xno; then
 171     AC_MSG_WARN(Not installing GConf schemas)
 172     HAVE_GCONFTOOL="no"
 173   else
 174     AM_GCONF_SOURCE_2
 175     HAVE_GCONFTOOL="yes"
 176   fi
 177   AC_SUBST(HAVE_GCONFTOOL)
 178 ])
 179
 180 dnl check for GConf libraries
 181 translit(dnm, m, l) AM_CONDITIONAL(USE_GCONF, true)
 182 GST_CHECK_FEATURE(GCONF, [GConf libraries], , [
 183   PKG_CHECK_MODULES(GCONF, gconf-2.0, HAVE_GCONF="yes", HAVE_GCONF="no")
 184   AC_SUBST(GCONF_CFLAGS)
 185   AC_SUBST(GCONF_LIBS)
 186 ])
 187
 188 dnl check for gstreamer; uninstalled is selected preferentially -- see pkg-config(1)
 189 PKG_CHECK_MODULES(GST, gstreamer-$GST_MAJORMINOR >= $GST_PLUGINS_VERSION_MAJOR.$GST_PLUGINS_VERSION_MINOR.$GST_PLUGINS_VERSION_MICRO,
 190   HAVE_GST="yes", HAVE_GST="no")
 191
 192 if test "x$HAVE_GST" = "xno"; then
 193   AC_MSG_ERROR(no GStreamer found)
 194 fi
 195
 196 GST_TOOLS_DIR=`pkg-config --variable=toolsdir gstreamer-$GST_MAJORMINOR`
 197 if test -z $GST_TOOLS_DIR; then
 198   AC_MSG_ERROR([no tools dir defined in GStreamer pkg-config file; core upgrade needed.])
 199 fi
 200 AC_SUBST(GST_TOOLS_DIR)
 201
 202 dnl check for gstreamer-control; uninstalled is selected preferentially
 203 PKG_CHECK_MODULES(GST_CONTROL, gstreamer-control-$GST_MAJORMINOR >= $GST_PLUGINS_VERSION_MAJOR.$GST_PLUGINS_VERSION_MINOR.$GST_PLUGINS_VERSION_MICRO,
 204   HAVE_GST_CONTROL="yes", HAVE_GST_CONTROL="no")
 205
 206 if test "x$HAVE_GST_CONTROL" = "xno"; then
 207   AC_MSG_ERROR(no GStreamer Control Libs found)
 208 fi
 209
 210 AC_SUBST(GST_CONTROL_LIBS)
 211
 212 dnl Determine endianness
 213 AC_C_BIGENDIAN
 214
 215 dnl Check for fast float to int casting as defined in C99
 216 AC_C99_FUNC_LRINT()
 217 AC_C99_FUNC_LRINTF()
 218
 219 dnl Check for essential libraries first:
 220 dnl ====================================
 221
 222 GST_GLIB2_CHECK()
 223
 224 dnl Check for additional libraries that we might use:
 225 dnl =================================================
 226 dnl GTK
 227 HAVE_GTK=NO
 228 PKG_CHECK_MODULES(GTK2, gtk+-2.0 >= 2.2.0, HAVE_GTK_22=yes, HAVE_GTK_22=no)
 229 if test "x$HAVE_GTK_22" = "xyes"; then
 230   HAVE_GTK=yes
 231   GTK_VERSION=`$PKG_CONFIG --variable=gtk_binary_version gtk+-2.0`
 232   AC_SUBST(GTK_VERSION)
 233   GTK_PREFIX=`$PKG_CONFIG --variable=prefix gdk-pixbuf-2.0`
 234   GDK_PIXBUF_LIBDIR=`$PKG_CONFIG --variable=libdir gdk-pixbuf-2.0`
 235   GDK_PIXBUF_PREFIXDIR=`$PKG_CONFIG --variable=prefix gdk-pixbuf-2.0`
 236   AC_SUBST(GTK_BASE_DIR)
 237 else
 238   PKG_CHECK_MODULES(GTK2, gtk+-2.0, HAVE_GTK_20=yes, HAVE_GTK_20=no)
 239 fi
 240 if test "x$HAVE_GTK_20" = "xyes"; then
 241   HAVE_GTK=yes
 242 fi
 243 GTK_CFLAGS=$GTK2_CFLAGS
 244 GTK_LIBS=$GTK2_LIBS
 245 AC_SUBST(GTK_LIBS)
 246 AC_SUBST(GTK_CFLAGS)
 247 AC_SUBST(HAVE_GTK)
 248
 249 # gdk_pixbuf gstreamer loader is considered experimental, so disable
 250 # by default
 251 if test "x$HAVE_GTK_22" = "xyes"; then
 252   HAVE_GDK_LOADERS=yes
 253 else
 254   HAVE_GDK_LOADERS=no
 255 fi
 256
 257 # we set the defaults always to make sure we have non-empty variables
 258 # for the Makefile
 259
 260 # by default, stick to prefix
 261 GDK_PIXBUF_LOADER_DIR=${libdir}/gtk-2.0/\${GTK_VERSION}/loaders
 262 GDK_PIXBUF_CONF_DIR=${sysconfdir}/gtk-2.0
 263
 264
 265 AC_ARG_ENABLE(gdk-pixbuf-loader,
 266   AC_HELP_STRING([--enable-gdk-pixbuf-loader],
 267               [whether to enable building of gdk_pixbuf loader]),
 268               :, HAVE_GDK_LOADERS="no")
 269
 270 if test "x$HAVE_GDK_LOADERS" = "xyes"; then
 271   AC_PATH_PROG(QUERYLOADERS, gdk-pixbuf-query-loaders, no)
 272   # allow customization of pixbuf loader install location
 273   # when nothing specified, adhere to prefix settings
 274   # when called without any option with this argument, autodetect
 275   # when called with a path, set to the given path
 276
 277   AC_ARG_WITH(gdk-pixbuf-loader-dir,
 278      AC_HELP_STRING([--with-gdk-pixbuf-loader-dir],
 279         [directory to install the gdk_pixbuf loader (none for pkg-config default)]),
 280      [
 281       if test "x${withval}" != xyes ; then
 282         GDK_PIXBUF_LOADER_DIR="${withval}"
 283       else
 284         GDK_PIXBUF_LOADER_DIR="$GDK_PIXBUF_LIBDIR/gtk-2.0/\$GTK_VERSION/loaders"
 285       fi
 286      ]
 287   )
 288   AS_AC_EXPAND(GDK_PIXBUF_LOADER_DIR, $GDK_PIXBUF_LOADER_DIR)
 289   AC_SUBST(GDK_PIXBUF_LOADER_DIR)
 290   AC_MSG_NOTICE([Putting GTK+-2 pixbuf loaders in $GDK_PIXBUF_LOADER_DIR])
 291
 292   # allow customization of pixbuf loader configuration file
 293   # when nothing specified, adhere to prefix settings
 294   # when called without any option with this argument, autodetect
 295   # when called with a path, set to the given path
 296
 297   AC_ARG_WITH(gdk-pixbuf-conf-dir,
 298      AC_HELP_STRING([--with-gdk-pixbuf-conf-dir],
 299         [directory to install the gdk_pixbuf config (none for pkg-config default)]),
 300      [
 301       if test "x${withval}" != xyes ; then
 302         GDK_PIXBUF_CONF_DIR="${withval}"
 303       else
 304         GDK_PIXBUF_CONF_DIR="$GDK_PIXBUF_PREFIXDIR/etc/gtk-2.0/"
 305       fi
 306      ]
 307   )
 308   AS_AC_EXPAND(GDK_PIXBUF_CONF_DIR, $GDK_PIXBUF_CONF_DIR)
 309   AC_SUBST(GDK_PIXBUF_CONF_DIR)
 310   AC_MSG_NOTICE([Putting GTK+-2 pixbuf loader config in $GDK_PIXBUF_CONF_DIR])
 311 fi
 312 AM_CONDITIONAL(HAVE_GDK_LOADERS, test "x$HAVE_GDK_LOADERS" = "xyes")
 313
 314 PKG_CHECK_MODULES(LIBOIL, liboil-0.1, HAVE_LIBOIL=yes, HAVE_LIBOIL=no)
 315 AC_SUBST(LIBOIL_CFLAGS)
 316 AC_SUBST(LIBOIL_LIBS)
 317 if test "x${HAVE_LIBOIL}" = xyes ; then
 318   #AC_DEFINE_UNQUOTED(HAVE_LIBOIL, 1, [Define if liboil is being used])
 319   true
 320 fi
 321
 322 dnl ===========================================================================
 323 dnl ============================= gst plug-ins ================================
 324 dnl ===========================================================================
 325
 326 plugindir="\$(libdir)/gstreamer-$GST_MAJORMINOR"
 327 AC_SUBST(plugindir)
 328
 329 GST_PLUGIN_LDFLAGS='-module -avoid-version -export-symbols-regex gst_plugin_desc'
 330 AC_SUBST(GST_PLUGIN_LDFLAGS)
 331
 332 dnl these are all the gst plug-ins, compilable without additional libs
 333 GST_PLUGINS_ALL="\
 334         ac3parse \
 335         adder \
 336         asfdemux \
 337         audioconvert \
 338         audioscale \
 339         auparse \
 340         avi \
 341         cdxaparse \
 342         chart \
 343         colorspace \
 344         cutter \
 345         debug \
 346         deinterlace \
 347         effectv \
 348         festival \
 349         filter \
 350         flx \
 351         goom \
 352         id3 \
 353         interleave \
 354         law \
 355         level \
 356         matroska \
 357         median \
 358         mixmatrix \
 359         mpeg1sys \
 360         mpeg1videoparse \
 361         mpeg2sub \
 362         mpegaudio \
 363         mpegaudioparse \
 364         mpegstream \
 365         monoscope \
 366         overlay \
 367         passthrough \
 368         playondemand \
 369         qtdemux \
 370         realmedia \
 371         rtjpeg \
 372         rtp \
 373         silence \
 374         sine \
 375         smooth \
 376         smpte \
 377         spectrum \
 378         speed \
 379         stereo \
 380         switch \
 381         synaesthesia \
 382         tags \
 383         tcp \
 384         typefind \
 385         udp \
 386         vbidec \
 387         videocrop \
 388         videodrop \
 389         videoflip \
 390         videofilter \
 391         videoscale \
 392         videotestsrc \
 393         volenv \
 394         volume \
 395         wavenc \
 396         wavparse \
 397         y4m"
 398
 399 dnl see if we can build C++ plug-ins
 400 if test "x$HAVE_CXX" = "xyes"; then
 401   GST_PLUGINS_ALL="$GST_PLUGINS_ALL \
 402                   modplug"
 403 else
 404   AC_MSG_WARN([Not compiling plug-ins requiring C++ compiler])
 405 fi
 406
 407 AC_SUBST(GST_PLUGINS_ALL)
 408
 409 GST_PLUGINS_SELECTED=""
 410
 411 AC_ARG_WITH(plugins,
 412     AC_HELP_STRING([--with-plugins],[comma-separated list of plug-ins to compile]),
 413     [for i in `echo $withval | tr , ' '`; do
 414         if test -n `echo $i | grep $GST_PLUGINS_ALL`; then
 415             GST_PLUGINS_SELECTED="$GST_PLUGINS_SELECTED $i"
 416         else
 417             echo "plug-in $i not recognized, ignoring..."
 418         fi
 419     done],
 420     [GST_PLUGINS_SELECTED=$GST_PLUGINS_ALL])
 421
 422 AC_SUBST(GST_PLUGINS_SELECTED)
 423
 424 dnl ==========================================================================
 425 dnl ============================= sys plug-ins ================================
 426 dnl ==========================================================================
 427
 428 dnl *** DXR3 card ***
 429 translit(dnm, m, l) AM_CONDITIONAL(USE_DXR3, true)
 430 GST_CHECK_FEATURE(DXR3, [DXR3 hardware MPEG DVD decoder],
 431   dxr3videosink dxr3audiosink dxr3spusink, [
 432   HAVE_DXR3=yes
 433   AC_CHECK_HEADER(linux/em8300.h, ,
 434                   [ AC_MSG_WARN([DXR3/em8300 header file not found]) &&
 435                     HAVE_DXR3=no ] )
 436   AC_CHECK_HEADER(linux/soundcard.h, ,
 437                   [ AC_MSG_WARN([Generic sound header file not found]) &&
 438                     HAVE_DXR3=no ] )
 439 ])
 440
 441 dnl *** OSS audio ***
 442 translit(dnm, m, l) AM_CONDITIONAL(USE_OSS, true)
 443 GST_CHECK_FEATURE(OSS, [OSS audio], osssrc osssink, [
 444   AC_CHECK_HEADER(sys/soundcard.h, HAVE_OSS="yes", HAVE_OSS="no")
 445 ])
 446
 447 dnl *** QuickCam ***
 448 translit(dnm, m, l) AM_CONDITIONAL(USE_QCAM, true)
 449 GST_CHECK_FEATURE(QCAM, [QuickCam], qcamsrc, [
 450   if test "x$HAVE_CPU_I386" != "xyes";
 451   then
 452     HAVE_QCAM="no"
 453   else
 454     AC_CHECK_HEADER(sys/io.h, HAVE_QCAM="yes", HAVE_QCAM="no")
 455   fi
 456   if test "x$HAVE_QCAM" != "xyes";
 457   then
 458     AC_MSG_WARN([QuickCam only works on i386-linux])
 459   fi
 460 ])
 461
 462 dnl *** Video CD ***
 463 translit(dnm, m, l) AM_CONDITIONAL(USE_VCD, true)
 464 GST_CHECK_FEATURE(VCD, [Video CD], vcdsrc, [
 465   AC_CHECK_HEADER(linux/cdrom.h, HAVE_VCD="yes", HAVE_VCD="no")
 466 ])
 467
 468 dnl *** CDROM Audio ***
 469 translit(dnm, m, l) AM_CONDITIONAL(USE_CDROM, true)
 470 GST_CHECK_FEATURE(CDROM, [CDROM Audio], cdrom, [
 471   AC_CHECK_HEADERS(linux/cdrom.h) dnl linux
 472   AC_CHECK_HEADERS(sys/cdio.h) dnl almost everything else
 473 dnl  AC_CHECK_HEADERS(dmedia/cdaudio.h) dnl irix
 474
 475   if test "${ac_cv_header_linux_cdrom_h}" = "yes" || test "${ac_cv_header_sys_cdio_h}" = "yes" || test "${ac_cv_header_dmedia_cdaudio_h}" = "yes"; then
 476         case "$host" in
 477                 *-sun-* | *-*-linux*)
 478                         AC_DEFINE(HAVE_CDROM_SOLARIS,, [Define if cdrom access is in Solaris style])
 479                 ;;
 480                 *-*-freebsd*)
 481                         AC_DEFINE(HAVE_CDROM_BSD,, [Define if cdrom access is in BSD style])
 482                 ;;
 483                 *-*-netbsd* | *-*-openbsd*)
 484                         AC_DEFINE(HAVE_CDROM_BSD,, [Define if cdrom access is in BSD style])
 485                         AC_DEFINE(HAVE_CDROM_BSD_NETBSD,, [Define if cdrom access uses NetBSD variant])
 486                 ;;
 487                 *-*darwin*)
 488                         AC_DEFINE(HAVE_CDROM_BSD,, [Define if cdrom access is in BSD style])
 489                         AC_DEFINE(HAVE_CDROM_BSD_DARWIN,, [Define if cdrom access uses Darwin variant])
 490                 ;;
 491 dnl             *-irix-*)
 492 dnl                     AC_DEFINE(HAVE_CDROM_IRIX,, [Define if cdrom access is in Irix DMedia style])
 493 dnl             ;;
 494     esac
 495
 496         HAVE_CDROM="yes"
 497   else
 498         HAVE_CDROM="no"
 499   fi
 500 ])
 501
 502 dnl Check for X11
 503 translit(dnm, m, l) AM_CONDITIONAL(USE_X, true)
 504 GST_CHECK_FEATURE(X, [X libraries and plugins],
 505                   [ximagesink], [
 506   AC_PATH_XTRA
 507 dnl  if test "x$X_CFLAGS" == "x" -o "$X_CFLAGS" == "-DX_DISPLAY_MISSING"
 508   if test "x$X_DISPLAY_MISSING" = "x1"
 509   then
 510     AC_MSG_NOTICE([cannot find X11 development files])
 511     HAVE_X="no"
 512   else
 513     dnl this is much more than we want
 514     X_LIBS="$X_LIBS $X_PRE_LIBS $X_EXTRA_LIBS"
 515     dnl AC_PATH_XTRA only defines the path needed to find the X libs, not the libs
 516     dnl therefore we add them here
 517     X_LIBS="$X_LIBS -lX11"
 518     AC_SUBST(X_CFLAGS)
 519     AC_SUBST(X_LIBS)
 520     HAVE_X="yes"
 521   fi
 522   AC_SUBST(HAVE_X)
 523 ])
 524
 525 dnl *** XVideo ***
 526 dnl Look for the PIC library first, Debian requires it.
 527 dnl Check debian-devel archives for gory details.
 528 dnl 20020110:
 529 dnl At the moment XFree86 doesn't distribute shared libXv due
 530 dnl to unstable API.  On many platforms you CAN NOT link a shared
 531 dnl lib to a static non-PIC lib.  This is what the xvideo GStreamer
 532 dnl plug-in wants to do.  So Debian distributes a PIC compiled
 533 dnl version of the static lib for plug-ins to link to when it is
 534 dnl inappropriate to link the main application to libXv directly.
 535 dnl FIXME: add check if this platform can support linking to a
 536 dnl        non-PIC libXv, if not then don not use Xv.
 537 dnl FIXME: perhaps warn user if they have a shared libXv since
 538 dnl        this is an error until XFree86 starts shipping one
 539
 540 dnl Check for Xv extension
 541 translit(dnm, m, l) AM_CONDITIONAL(USE_XVIDEO, true)
 542 GST_CHECK_FEATURE(XVIDEO, [X11 XVideo extensions],
 543                   [xvimagesink xvideosink], [
 544   if test x$HAVE_X = xyes; then
 545     AC_CHECK_LIB(Xv_pic, XvQueryExtension,
 546                  HAVE_XVIDEO="yes", HAVE_XVIDEO="no",
 547                  $X_LIBS -lXext)
 548
 549     if test x$HAVE_XVIDEO = xyes; then
 550       XVIDEO_LIBS="-lXv_pic -lXext"
 551       AC_SUBST(XVIDEO_LIBS)
 552     else
 553       dnl try again using something else if we didn't find it first
 554       if test x$HAVE_XVIDEO = xno; then
 555         AC_CHECK_LIB(Xv, XvQueryExtension,
 556                    HAVE_XVIDEO="yes", HAVE_XVIDEO="no",
 557                    $X_LIBS -lXext)
 558
 559         if test x$HAVE_XVIDEO = xyes; then
 560           XVIDEO_LIBS="-lXv -lXext"
 561           AC_SUBST(XVIDEO_LIBS)
 562         fi
 563       fi
 564     fi
 565   fi
 566 ])
 567
 568 dnl check for X Shm
 569 translit(dnm, m, l) AM_CONDITIONAL(USE_XSHM, true)
 570 GST_CHECK_FEATURE(XSHM, [X Shared Memory extension], xshm, [
 571   if test x$HAVE_X = xyes; then
 572     AC_CHECK_LIB(Xext, XShmAttach,
 573                  HAVE_XSHM="yes", HAVE_XSHM="no",
 574                  $X_LIBS)
 575     if test "x$HAVE_XSHM" = "xyes"; then
 576       XSHM_LIBS="-lXext"
 577     else
 578       dnl On AIX, it is in XextSam instead, but we still need -lXext
 579       AC_CHECK_LIB(XextSam, XShmAttach,
 580                    HAVE_XSHM="yes", HAVE_XSHM="no",
 581                    $X_LIBS)
 582       if test "x$HAVE_XSHM" = "xyes"; then
 583         XSHM_LIBS="-lXext -lXextSam"
 584       fi
 585     fi
 586   fi
 587 ], , [
 588   AC_SUBST(HAVE_XSHM)
 589   AC_SUBST(XSHM_LIBS)
 590 ] )
 591
 592 dnl v4l/v4l2 checks have been moved down because they require X
 593
 594 dnl *** Video 4 Linux ***
 595 dnl for information about the header/define, see sys/v4l/gstv4lelement.h
 596 translit(dnm, m, l) AM_CONDITIONAL(USE_V4L, true)
 597 GST_CHECK_FEATURE(V4L, [Video 4 Linux], v4lsrc v4lmjpegsrc v4lmjpegsink, [
 598   # first check X
 599   HAVE_V4L="no"
 600   if test "$HAVE_X" == "yes"
 601   then
 602     AC_CHECK_DECL(VID_TYPE_MPEG_ENCODER, HAVE_V4L="yes", HAVE_V4L="no", [
 603 #include <sys/types.h>
 604 #define _LINUX_TIME_H
 605 #include <linux/videodev.h>
 606     ])
 607   fi
 608 ])
 609
 610 dnl *** Video 4 Linux 2 ***
 611 dnl for information about the header/define, see sys/v4l2/gstv4l2element.h
 612 translit(dnm, m, l) AM_CONDITIONAL(USE_V4L2, true)
 613 GST_CHECK_FEATURE(V4L2, [Video 4 Linux 2], v4l2src, [
 614   HAVE_V4L2="no"
 615   if test "$HAVE_X" == "yes"
 616   then
 617     AC_MSG_CHECKING([Checking for uptodate v4l2 installation])
 618     AC_TRY_COMPILE([
 619 #include <sys/types.h>
 620 #include <linux/types.h>
 621 #define _LINUX_TIME_H
 622 #include <linux/videodev2.h>
 623 #if defined(V4L2_MAJOR_VERSION) || defined(V4L2_MINOR_VERSION)
 624 #error too early v4l2 version or no v4l2 at all
 625 #endif
 626     ], [
 627 return 0;
 628     ], [ HAVE_V4L2="yes" && AC_MSG_RESULT(yes)],
 629        [ HAVE_V4L2="no"  && AC_MSG_RESULT(no) &&
 630          AC_CHECK_HEADER(linux/videodev2.h,
 631                          [ AC_MSG_WARN([video4linux2 headers were found, but they're old. Please update v4l2 to compile the v4l2 plugins])],
 632                          [ AC_MSG_WARN([video4linux2 was not found])])
 633        ])
 634   fi
 635 ])
 636
 637 dnl Next, check for the optional libraries:
 638 dnl These are all libraries used in building plug-ins
 639 dnl ================================================
 640 dnl let's try and sort them alphabetically, shall we ?
 641
 642 if test "x$BUILD_EXTERNAL" = "xyes"; then
 643
 644 AC_MSG_NOTICE(Checking for plug-in dependency libraries)
 645
 646 dnl *** a52dec ***
 647 translit(dnm, m, l) AM_CONDITIONAL(USE_A52DEC, true)
 648 GST_CHECK_FEATURE(A52DEC, [a52dec], a52dec, [
 649   AC_CHECK_A52DEC(HAVE_A52DEC=yes, HAVE_A52DEC=no)
 650 ])
 651
 652 dnl *** aalib ***
 653 translit(dnm, m, l) AM_CONDITIONAL(USE_AALIB, true)
 654 GST_CHECK_FEATURE(AALIB, [aasink plug-in], aasink, [
 655   AM_PATH_AALIB(, HAVE_AALIB=yes, HAVE_AALIB=no)
 656   AS_SCRUB_INCLUDE(AALIB_CFLAGS)
 657 ])
 658
 659 dnl *** alsa ***
 660 translit(dnm, m, l) AM_CONDITIONAL(USE_ALSA, true)
 661 GST_CHECK_FEATURE(ALSA, [alsa plug-ins], gstalsa, [
 662    AM_PATH_ALSA(0.9.1, HAVE_ALSA=yes, HAVE_ALSA=no)
 663 ])
 664
 665 dnl *** arts ***
 666 dnl if mcopidl can't be found there's no use in compiling it
 667 AC_CHECK_PROG(MCOPIDL, mcopidl, yes, no)
 668 if test "x$HAVE_MCOPIDL" = "xno";
 669 then
 670   USE_ARTS=no
 671 fi
 672
 673 translit(dnm, m, l) AM_CONDITIONAL(USE_ARTS, true)
 674 GST_CHECK_FEATURE(ARTS, [arts plug-ins], arts, [
 675   AM_PATH_ARTS(, HAVE_ARTS=yes, HAVE_ARTS=no)
 676 ])
 677
 678 dnl *** artsc ***
 679 translit(dnm, m, l) AM_CONDITIONAL(USE_ARTSC, true)
 680 GST_CHECK_FEATURE(ARTSC, [artsd plug-ins], artsdsink, [
 681   GST_CHECK_ARTSC()
 682 ])
 683
 684 dnl *** audiofile ***
 685 dnl this check uses the GST_CHECK_CONFIGPROG macro
 686 translit(dnm, m, l) AM_CONDITIONAL(USE_AUDIOFILE, true)
 687 GST_CHECK_FEATURE(AUDIOFILE, [audiofile], afsink afsrc, [
 688   translit(dnm, m, l) AC_SUBST(AUDIOFILE_LIBS)
 689   translit(dnm, m, l) AC_SUBST(AUDIOFILE_CFLAGS)
 690   dnl check with pkg-config first
 691   PKG_CHECK_MODULES(AUDIOFILE, audiofile, HAVE_AUDIOFILE="yes", HAVE_AUDIOFILE="no")
 692   if test "x$HAVE_AUDIOFILE" = "xno"; then
 693     GST_CHECK_CONFIGPROG(AUDIOFILE, audiofile-config)
 694     dnl we need this function
 695     AC_CHECK_LIB(audiofile, afOpenVirtualFile, , HAVE_AUDIOFILE="no")
 696   fi])
 697
 698 dnl *** CDParanoia ***
 699 translit(dnm, m, l) AM_CONDITIONAL(USE_CDPARANOIA, true)
 700 GST_CHECK_FEATURE(CDPARANOIA, [CDParanoia], cdparanoia, [
 701   GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 702                       cdda_open, -lm,
 703                       cdda_interface.h,
 704                       CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 705                       HEADER_DIR="no"
 706                       FOUND_CDPARANOIA="yes")
 707   if test "x$FOUND_CDPARANOIA" != "xyes";
 708   then
 709     GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 710                         cdda_open, -lm,
 711                         cdda/cdda_interface.h,
 712                         CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 713                         HEADER_DIR="yes"
 714                         FOUND_CDPARANOIA="yes")
 715   fi
 716   if test "x$HEADER_DIR" = "xyes";
 717   then
 718     AC_DEFINE_UNQUOTED(CDPARANOIA_HEADERS_IN_DIR, ,
 719                        defined if cdda headers are in a cdda/ directory)
 720   fi
 721   AC_SUBST(CDPARANOIA_LIBS)
 722 ])
 723 dnl FIXME : add second check somehow if that is necessary
 724 dnl AC_CHECK_LIB(cdda_paranoia, paranoia_init, : , HAVE_CDPARANOIA=no, -lcdda_interface )
 725 dnl AC_CHECK_HEADER(cdda_paranoia.h, :, HAVE_CDPARANOIA=no)
 726
 727 dnl *** DIVX ***
 728 translit(dnm, m, l) AM_CONDITIONAL(USE_DIVX, true)
 729 GST_CHECK_FEATURE(DIVX, [divx plugins], divx, [
 730   HAVE_DIVX=yes
 731   AC_CHECK_HEADER(encore2.h, ,
 732                   [ AC_MSG_WARN([Divx4linux encore headers not found]) &&
 733                     HAVE_DIVX=no ] )
 734   if [ test x$HAVE_DIVX = xyes ]; then
 735     AC_MSG_CHECKING([Checking for valid divx4linux encore version])
 736     AC_TRY_COMPILE([
 737 #include <encore2.h>
 738 #if ENCORE_VERSION != 20021024
 739 #error Wrong version of divx encore libraries
 740 #endif
 741     ], [
 742 return 0;
 743     ], [ HAVE_DIVX=yes && AC_MSG_RESULT(yes)],
 744        [ HAVE_DIVX=no  && AC_MSG_RESULT(no) &&
 745          AC_MSG_WARN([Wrong version of divx4linux installed]) ])
 746   fi
 747   if [ test x$HAVE_DIVX = xyes ]; then
 748     AC_CHECK_HEADER(decore.h, ,
 749                     [ AC_MSG_WARN([Divx4linux decoder headers not found]) &&
 750                       HAVE_DIVX=no ] )
 751   fi
 752   if [ test x$HAVE_DIVX = xyes ]; then
 753     AC_MSG_CHECKING([Checking for valid divx4linux decore version])
 754     AC_TRY_COMPILE([
 755 #include <decore.h>
 756 #if DECORE_VERSION != 20021112
 757 #error Wrong version of divx decore libraries
 758 #endif
 759     ], [
 760 return 0;
 761     ], [ HAVE_DIVX=yes && AC_MSG_RESULT(yes)],
 762        [ HAVE_DIVX=no  && AC_MSG_RESULT(no) &&
 763          AC_MSG_WARN([Wrong version of divx4linux installed]) ])
 764   fi
 765   LIBS="-lm"
 766   if test x$HAVE_DIVX = xyes; then
 767     AC_CHECK_LIB(divxencore, encore, ,
 768                  [ AC_MSG_WARN([Divx4linux encore libs not found]) &&
 769                    HAVE_DIVX=no ] )
 770   fi
 771   if test x$HAVE_DIVX = xyes; then
 772     AC_CHECK_LIB(divxdecore, decore, ,
 773                  [ AC_MSG_WARN([Divx4linux decore libs not found]) &&
 774                    HAVE_DIVX=no ] )
 775   fi
 776   if test x$HAVE_DIVX = xyes; then
 777     DIVXENC_LIBS="-ldivxencore -lm"
 778     DIVXDEC_LIBS="-ldivxdecore -lm"
 779     AC_SUBST(DIVXENC_LIBS)
 780     AC_SUBST(DIVXDEC_LIBS)
 781   fi
 782 ])
 783
 784 dnl *** dvdread ***
 785 translit(dnm, m, l) AM_CONDITIONAL(USE_DVDREAD, true)
 786 GST_CHECK_FEATURE(DVDREAD, [dvdread library], dvdreadsrc, [
 787   GST_CHECK_LIBHEADER(DVDREAD, dvdread, DVDOpen, , dvdread/dvd_reader.h, DVDREAD_LIBS="-ldvdread")
 788   AC_SUBST(DVDREAD_LIBS)
 789 ])
 790
 791 dnl *** dvdnav ***
 792 translit(dnm, m, l) AM_CONDITIONAL(USE_DVDNAV, true)
 793 GST_CHECK_FEATURE(DVDNAV, [dvdnav library], dvdnavsrc, [
 794   translit(dnm, m, l) AC_SUBST(DVDNAV_LIBS)
 795   translit(dnm, m, l) AC_SUBST(DVDNAV_CFLAGS)
 796   GST_CHECK_CONFIGPROG(DVDNAV, dvdnav-config)
 797   if test x"$HAVE_DVDNAV" = x"yes"; then
 798     dnl check version
 799     DVDNAV_VERSION=`dvdnav-config --version|head -n 1|sed 's/^.*) //'|sed 's/ (.*)//'`
 800     DVDNAV_MAJOR=`echo $DVDNAV_VERSION | cut -d. -f1 | sed s/[a-zA-Z\-].*//g`
 801     DVDNAV_MINOR=`echo $DVDNAV_VERSION | cut -d. -f2 | sed s/[a-zA-Z\-].*//g`
 802     DVDNAV_MICRO=`echo $DVDNAV_VERSION | cut -d. -f3 | sed s/[a-zA-Z\-].*//g`
 803     if [[ "$DVDNAV_MAJOR" -eq "0" ]] && \
 804        [[ "$DVDNAV_MINOR" -lt "1" ]]; then
 805       AC_MSG_WARN([libdvdnav >= 0.1.7 is required, you have $DVDNAV_VERSION])
 806       HAVE_DVDNAV="no"
 807     elif [[ "$DVDNAV_MAJOR" -eq "0" ]] && \
 808          [[ "$DVDNAV_MINOR" -eq "1" ]] && \
 809          [[ "$DVDNAV_MICRO" -lt "7" ]]; then
 810       AC_MSG_WARN([libdvdnav >= 0.1.7 is required, you have $DVDNAV_VERSION])
 811       HAVE_DVDNAV="no"
 812       fi
 813     fi
 814   AS_SCRUB_INCLUDE(DVDNAV_CFLAGS)
 815 ])
 816
 817 dnl **** ESound ****
 818 translit(dnm, m, l) AM_CONDITIONAL(USE_ESD, true)
 819 GST_CHECK_FEATURE(ESD, [esound plug-ins], esdsink esdmon, [
 820   AM_PATH_ESD(0.2.12, HAVE_ESD=yes, HAVE_ESD=no)
 821   AS_SCRUB_INCLUDE(ESD_CFLAGS)
 822 ])
 823
 824 dnl **** Free AAC Encoder (FAAC) ****
 825 translit(dnm, m, l) AM_CONDITIONAL(USE_FAAC, true)
 826 GST_CHECK_FEATURE(FAAC, [AAC encoder plug-in], faac, [
 827   GST_CHECK_LIBHEADER(FAAC, faac, faacEncOpen, -lm, faac.h, FAAC_LIBS="-lfaac -lm")
 828   AS_SCRUB_INCLUDE(FAAC_CFLAGS)
 829   AC_SUBST(FAAC_LIBS)
 830 ])
 831
 832 dnl **** Free AAC Decoder (FAAD) ****
 833 translit(dnm, m, l) AM_CONDITIONAL(USE_FAAD, true)
 834 GST_CHECK_FEATURE(FAAD, [AAC decoder plug-in], faad, [
 835   GST_CHECK_LIBHEADER(FAAD, faad, faacDecOpen, -lm, faad.h, FAAD_LIBS="-lfaad -lm")
 836   AC_MSG_CHECKING([Checking for FAAD >= 2])
 837   AC_TRY_COMPILE([
 838 #include <faad.h>
 839 #if !defined(FAAD2_VERSION) || !defined(FAAD_FMT_DOUBLE)
 840 #error Not faad2
 841 #endif
 842   ], [ return 0; ],
 843      [ HAVE_FAAD="yes" && AC_MSG_RESULT(yes)],
 844      [ HAVE_FAAD="no"  && AC_MSG_RESULT(no)])
 845   AS_SCRUB_INCLUDE(FAAD_CFLAGS)
 846   AC_SUBST(FAAD_LIBS)
 847 ])
 848
 849 dnl **** festival ****
 850 dnl translit(dnm, m, l) AM_CONDITIONAL(USE_FESTIVAL, true)
 851 dnl GST_CHECK_FEATURE(FESTIVAL, [festival plug-ins], festivalsrc, [
 852   dnl NOTE: just using local net connection now, add this lib check
 853   dnl       in the future if needed
 854   dnl AC_LANG_PUSH(C++)
 855   dnl dnl FIXME: took out func to check for
 856   dnl dnl This check puts festival_tidy_up in extern "C".
 857   dnl dnl But, at least on Debian as of 20020110, it is compiled with name
 858   dnl dnl mangling C++ nonsense and symbols can't resolve
 859   dnl dnl GST_CHECK_LIBHEADER(FESTIVAL, Festival, festival_tidy_up, , festival/festival.h, FESTIVAL_LIBS="-lFestival")
 860   dnl GST_CHECK_LIBHEADER(FESTIVAL, Festival, , , festival/festival.h, FESTIVAL_LIBS="-lFestival")
 861   dnl AC_LANG_POP(C++)
 862   dnl AC_SUBST(FESTIVAL_LIBS)
 863 dnl  HAVE_FESTIVAL=yes
 864 dnl])
 865
 866 dnl *** FLAC ***
 867 translit(dnm, m, l) AM_CONDITIONAL(USE_FLAC, true)
 868 GST_CHECK_FEATURE(FLAC, [FLAC lossless audio], flacenc flacdec, [
 869   GST_CHECK_LIBHEADER(FLAC, FLAC, FLAC__seekable_stream_encoder_new, -lm, FLAC/all.h, FLAC_LIBS="-lFLAC")
 870   AC_SUBST(FLAC_LIBS)
 871 ])
 872
 873 dnl *** GDK pixbuf ***
 874 translit(dnm, m, l) AM_CONDITIONAL(USE_GDK_PIXBUF, true)
 875 GST_CHECK_FEATURE(GDK_PIXBUF, [GDK pixbuf], gdkpixbufsrc, [
 876   if test $HAVE_GTK_22 = "yes"; then HAVE_GDK_PIXBUF=yes; fi;
 877 ])
 878
 879 dnl *** Gnome VFS ***
 880 translit(dnm, m, l) AM_CONDITIONAL(USE_GNOME_VFS, true)
 881 GST_CHECK_FEATURE(GNOME_VFS, [Gnome VFS], gnomevfssrc, [
 882   PKG_CHECK_MODULES(GNOME_VFS, gnome-vfs-2.0, HAVE_GNOME_VFS="yes", HAVE_GNOME_VFS="no")
 883   AC_SUBST(GNOME_VFS_CFLAGS)
 884   AC_SUBST(GNOME_VFS_LIBS)
 885 ])
 886
 887 dnl *** gsm ***
 888 translit(dnm, m, l) AM_CONDITIONAL(USE_GSM, true)
 889 GST_CHECK_FEATURE(GSM, [GSM library], gsmenc gsmdec, [
 890   GST_CHECK_LIBHEADER(GSM, gsm, gsm_create, , gsm.h, GSM_LIBS="-lgsm")
 891   if test $HAVE_GSM != "yes"; then
 892     GST_CHECK_LIBHEADER(GSM, gsm, gsm_create, , gsm/gsm.h, GSM_LIBS="-lgsm")
 893     if test $HAVE_GSM = "yes"; then
 894       AC_DEFINE(GSM_HEADER_IN_SUBDIR, 1, [Define if GSM header in gsm/ subdir])
 895     fi
 896   fi
 897   AC_SUBST(GSM_LIBS)
 898 ])
 899
 900 dnl *** Hermes ***
 901 translit(dnm, m, l) AM_CONDITIONAL(USE_HERMES, true)
 902 GST_CHECK_FEATURE(HERMES, [Hermes library], colorspace, [
 903   GST_CHECK_LIBHEADER(HERMES, Hermes, Hermes_ConverterInstance, , Hermes/Hermes.h, HERMES_LIBS="-lHermes")
 904 ], AC_SUBST(HERMES_LIBS))
 905
 906 dnl *** http ***
 907 dnl translit(dnm, m, l) AM_CONDITIONAL(USE_HTTP, true)
 908 dnl GST_CHECK_FEATURE(HTTP, [http plug-ins], gsthttpsrc, [
 909 dnl  dnl FIXME: need to check for header
 910 dnl  GHTTP_LIBS=
 911 dnl  GST_HTTPSRC_GET_TYPE=
 912 dnl  if test x$USE_GLIB2 = xyes; then
 913 dnl    AC_MSG_WARN(ghttp disabled for glib2.0)
 914 dnl  else
 915 dnl    AC_CHECK_LIB(ghttp, ghttp_request_new,
 916 dnl      [HTTP_LIBS="-lghttp"
 917 dnl       GST_HTTPSRC_GET_TYPE="gst_httpsrc_get_type"
 918 dnl       HAVE_HTTP=yes
 919 dnl      ], :, $LIBS)
 920 dnl  fi
 921 dnl  AC_SUBST(HTTP_LIBS)
 922 dnl  AC_SUBST(GST_HTTPSRC_GET_TYPE)
 923 dnl ])
 924
 925 dnl *** ivorbis ***
 926 dnl AM_PATH_IVORBIS only takes two options
 927 translit(dnm, m, l) AM_CONDITIONAL(USE_IVORBIS, true)
 928 GST_CHECK_FEATURE(IVORBIS, [integer vorbis plug-in], ivorbisdec, [
 929   IVORBIS_LIBS=
 930   IVORBIS_CFLAGS=
 931   AC_CHECK_LIB(vorbisidec, vorbis_block_init,
 932     [IVORBIS_LIBS=-lvorbisidec
 933      HAVE_IVORBIS=yes],
 934     HAVE_IVORBIS=no)
 935   AC_SUBST(IVORBIS_LIBS)
 936   AC_SUBST(IVORBIS_CFLAGS)
 937 ])
 938
 939 dnl *** Jack ***
 940 translit(dnm, m, l) AM_CONDITIONAL(USE_JACK, true)
 941 GST_CHECK_FEATURE(JACK, Jack, jack, [
 942   PKG_CHECK_MODULES(JACK, jack >= 0.29.0, HAVE_JACK="yes", HAVE_JACK="no")
 943   AC_SUBST(JACK_CFLAGS)
 944   AC_SUBST(JACK_LIBS)
 945 ])
 946
 947 dnl *** jpeg ***
 948 dnl FIXME: we could use header checks here as well IMO
 949 translit(dnm, m, l) AM_CONDITIONAL(USE_JPEG, true)
 950 GST_CHECK_FEATURE(JPEG, [jpeg], jpegenc jpegdec, [
 951   AC_ARG_WITH(jpeg-mmx,
 952     [  --with-jpeg-mmx, path to MMX'ified JPEG library])
 953   OLD_LIBS="$LIBS"
 954   if test x$with_jpeg_mmx != x; then
 955     LIBS="$LIBS -L$with_jpeg_mmx"
 956   fi
 957   AC_CHECK_LIB(jpeg-mmx, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
 958   JPEG_LIBS="$LIBS -ljpeg-mmx"
 959   LIBS="$OLD_LIBS"
 960   if test x$HAVE_JPEG != xyes; then
 961     AC_CHECK_LIB(jpeg, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
 962     JPEG_LIBS="-ljpeg"
 963   fi
 964   AC_SUBST(JPEG_LIBS)
 965 ])
 966
 967 dnl *** ladspa ***
 968 translit(dnm, m, l) AM_CONDITIONAL(USE_LADSPA, true)
 969 GST_CHECK_FEATURE(LADSPA, [ladspa], ladspa, [
 970   AC_CHECK_HEADER(ladspa.h, HAVE_LADSPA="yes", HAVE_LADSPA="no")
 971 ])
 972
 973 dnl *** lame ***
 974 translit(dnm, m, l) AM_CONDITIONAL(USE_LAME, true)
 975 GST_CHECK_FEATURE(LAME, [lame mp3 encoder library], lame, [
 976   GST_CHECK_LIBHEADER(LAME, mp3lame, lame_init, -lm, lame/lame.h, HAVE_LAME="yes" LAME_LIBS="-lmp3lame")
 977 ])
 978 AC_SUBST(LAME_LIBS)
 979
 980 dnl *** libcolorspace ***
 981 translit(dnm, m, l) AM_CONDITIONAL(USE_LCS, true)
 982 GST_CHECK_FEATURE(LCS, Lcs, lcs, [
 983   PKG_CHECK_MODULES(LCS, lcs, HAVE_LCS="yes", HAVE_LCS="no")
 984   AC_SUBST(LCS_CFLAGS)
 985   AC_SUBST(LCS_LIBS)
 986 ])
 987
 988 dnl *** libdv ***
 989 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBDV, true)
 990 GST_CHECK_FEATURE(LIBDV, [libdv DV/video decoder], dvdec, [
 991   PKG_CHECK_MODULES(LIBDV, libdv >= 0.98, HAVE_LIBDV="yes", HAVE_LIBDV="no")
 992   AC_SUBST(LIBDV_CFLAGS)
 993   AC_SUBST(LIBDV_LIBS)
 994 ])
 995
 996 dnl *** libcaca ***
 997 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBCACA, true)
 998 GST_CHECK_FEATURE(LIBCACA, [libcaca], libcaca, [
 999   GST_CHECK_CONFIGPROG(LIBCACA, caca-config)
1000   AC_SUBST(LIBCACA_CFLAGS)
1001   AC_SUBST(LIBCACA_LIBS)
1002 ])
1003
1004 dnl *** libfame ***
1005 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBFAME, true)
1006 GST_CHECK_FEATURE(LIBFAME, [libfame MPEG1/4 encoder], libfame, [
1007   AM_PATH_LIBFAME(0.9.0, HAVE_LIBFAME="yes", HAVE_LIBFAME="no")
1008   AC_SUBST(LIBFAME_CFLAGS)
1009   AC_SUBST(LIBFAME_LIBS)
1010 ])
1011
1012 dnl *** libpng ***
1013 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBPNG, true)
1014 GST_CHECK_FEATURE(LIBPNG, [libpng PNG encoder], pngenc, [
1015   PKG_CHECK_MODULES(LIBPNG, libpng12, HAVE_LIBPNG="yes", HAVE_LIBPNG="no")
1016   AC_SUBST(LIBPNG_CFLAGS)
1017   AC_SUBST(LIBPNG_LIBS)
1018 ])
1019
1020 dnl *** librfb ***
1021 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBRFB, true)
1022 GST_CHECK_FEATURE(LIBRFB, [librfb Remote Framebuffer], rfbsrc, [
1023   PKG_CHECK_MODULES(LIBRFB, librfb-0.1, HAVE_LIBRFB="yes", HAVE_LIBRFB="no")
1024   AC_SUBST(LIBRFB_CFLAGS)
1025   AC_SUBST(LIBRFB_LIBS)
1026 ])
1027
1028 dnl *** mad ***
1029 dnl FIXME: we could use header checks here as well IMO
1030 translit(dnm, m, l) AM_CONDITIONAL(USE_MAD, true)
1031 GST_CHECK_FEATURE(MAD, [mad mp3 decoder], mad, [
1032   dnl check with pkg-config first
1033   PKG_CHECK_MODULES(MAD, mad >= 0.15 id3tag >= 0.15, HAVE_MAD="yes", HAVE_MAD="no")
1034   if test "x$HAVE_MAD" = "xno"; then
1035     dnl fall back to oldskool detection
1036     AC_CHECK_LIB(mad, mad_decoder_finish, HAVE_MAD="yes" MAD_LIBS="-lmad")
1037     if test "x$HAVE_MAD" = "xyes"; then
1038       HAVE_MAD="no"
1039       save_libs=$LIBS
1040       LIBS="-lz"
1041       AC_CHECK_LIB(id3tag, id3_tag_options, HAVE_MAD="yes" MAD_LIBS="-lmad -lid3tag -lz")
1042       LIBS=$save_LIBS
1043     fi
1044   fi
1045 ])
1046 AC_SUBST(MAD_LIBS)
1047
1048 dnl *** mikmod ***
1049 translit(dnm, m, l) AM_CONDITIONAL(USE_MIKMOD, true)
1050 GST_CHECK_FEATURE(MIKMOD, [mikmod plug-in], mikmod, [
1051   AM_PATH_LIBMIKMOD(, HAVE_MIKMOD=yes, HAVE_MIKMOD=no)
1052   AC_SUBST(MIKMOD_LIBS, "$LIBMIKMOD_LIBS")
1053   AC_SUBST(MIKMOD_CFLAGS, "$LIBMIKMODCFLAGS")
1054 ])
1055
1056 dnl *** mpeg2dec ***
1057 translit(dnm, m, l) AM_CONDITIONAL(USE_MPEG2DEC, true)
1058 GST_CHECK_FEATURE(MPEG2DEC, [mpeg2dec], mpeg2dec, [
1059   PKG_CHECK_MODULES(MPEG2DEC, libmpeg2 >= 0.3.1,
1060       HAVE_MPEG2DEC="yes", HAVE_MPEG2DEC="no")
1061   AC_SUBST(MPEG2DEC_CFLAGS)
1062   AC_SUBST(MPEG2DEC_LIBS)
1063 ])
1064
1065 dnl *** mpeg2enc ***
1066 translit(dnm, m, l) AM_CONDITIONAL(USE_MPEG2ENC, true)
1067 GST_CHECK_FEATURE(MPEG2ENC, [mpeg2enc], mpeg2enc, [
1068   HAVE_MPEG2ENC="no"
1069   dnl we require a c++ compiler for this one
1070   if [ test x$HAVE_CXX = xyes ]; then
1071     dnl libmpeg2enc was first included in mjpegtools-1.6.2-rc3 (1.6.1.92)
1072     dnl since many distros include mjpegtools specifically without mplex
1073     dnl and mpeg2enc, we check for mpeg2enc on its own, too.
1074     PKG_CHECK_MODULES(MPEG2ENC, mjpegtools >= 1.6.1.93, [
1075       dnl switch over to c++ to test things
1076       AC_LANG_CPLUSPLUS
1077       OLD_CPPFLAGS="$CPPFLAGS"
1078       CPPFLAGS="$CPPFLAGS $MPEG2ENC_CFLAGS"
1079       AC_CHECK_HEADER(mpeg2encoder.hh, [
1080         MPEG2ENC_LIBS="$MPEG2ENC_LIBS -lmpeg2encpp -lm -lpthread"
1081         OLD_LIBS="$LIBS"
1082         LIBS="$LIBS $MPEG2ENC_LIBS"
1083         AC_MSG_CHECKING([for valid mpeg2enc objects])
1084         AC_TRY_RUN([
1085 #include <mpeg2encoder.hh>
1086 #include <mpeg2encoptions.hh>
1087
1088 int
1089 main (int   argc,
1090       char *argv[])
1091 {
1092   MPEG2EncOptions *options = new MPEG2EncOptions ();
1093   MPEG2Encoder encoder (*options);
1094   return 0;
1095 }
1096         ],[
1097           HAVE_MPEG2ENC="yes"
1098           AC_SUBST(MPEG2ENC_CFLAGS)
1099           AC_SUBST(MPEG2ENC_LIBS)
1100           AC_MSG_RESULT(yes)
1101         ], AC_MSG_RESULT(no))
1102         LIBS="$OLD_LIBS"
1103       ])
1104       CPPFLAGS="$OLD_CPPFLAGS"
1105       AC_LANG_C
1106     ],
1107     HAVE_MPEG2ENC="no")
1108   fi
1109 ])
1110
1111 dnl *** mplex ***
1112 translit(dnm, m, l) AM_CONDITIONAL(USE_MPLEX, true)
1113 GST_CHECK_FEATURE(MPLEX, [mplex], mplex, [
1114   HAVE_MPLEX="no"
1115   dnl we require a c++ compiler for this one
1116   if [ test x$HAVE_CXX = xyes ]; then
1117     dnl libmplex was first included in mjpegtools-1.6.2-rc4 (1.6.1.93)
1118     dnl since many distros include mjpegtools specifically without mplex
1119     dnl and mpeg2enc, we check for mplex on its own, too.
1120     PKG_CHECK_MODULES(MPLEX, mjpegtools >= 1.6.1.93, [
1121       dnl switch over to c++ to test things
1122       AC_LANG_CPLUSPLUS
1123       OLD_CPPFLAGS="$CPPFLAGS"
1124       CPPFLAGS="$CPPFLAGS $MPLEX_CFLAGS"
1125       AC_CHECK_HEADER(interact.hpp, [
1126         MPLEX_LIBS="$MPLEX_LIBS -lmplex2 -lm"
1127         OLD_LIBS="$LIBS"
1128         LIBS="$LIBS $MPLEX_LIBS"
1129         AC_MSG_CHECKING([for valid mplex objects])
1130         AC_TRY_RUN([
1131 #include <interact.hpp>
1132 #include <outputstrm.hpp>
1133 #include <multiplexor.hpp>
1134
1135 int
1136 main (int   argc,
1137       char *argv[])
1138 {
1139   class TestOutputStream : public OutputStream {
1140   public:
1141     TestOutputStream () : OutputStream () { }
1142     void Write (uint8_t *a, unsigned int b) { }
1143     void NextSegment () { }
1144     off_t SegmentSize () { }
1145     void Close () { }
1146     int Open () { }
1147   };
1148   MultiplexJob *job = new MultiplexJob ();
1149   vector<IBitStream *> inputs;
1150   job->SetupInputStreams (inputs);
1151   TestOutputStream *out = new TestOutputStream ();
1152   Multiplexor mux (*job, *out);
1153   return 0;
1154 }
1155         ],[
1156           HAVE_MPLEX="yes"
1157           AC_SUBST(MPLEX_CFLAGS)
1158           AC_SUBST(MPLEX_LIBS)
1159           AC_MSG_RESULT(yes)
1160         ], AC_MSG_RESULT(no))
1161         LIBS="$OLD_LIBS"
1162       ])
1163       CPPFLAGS="$OLD_CPPFLAGS"
1164       AC_LANG_C
1165     ], HAVE_MPLEX="no")
1166   fi
1167 ])
1168
1169 dnl *** musicbrainz ***
1170 dnl libmusicbrainz <= 2.0.2 has symbol clashes with ffmpeg
1171 translit(dnm, m, l) AM_CONDITIONAL(USE_MUSICBRAINZ, true)
1172 GST_CHECK_FEATURE(MUSICBRAINZ, [musicbrainz], musicbrainz, [
1173   PKG_CHECK_MODULES(MUSICBRAINZ, libmusicbrainz > 2.0.2,
1174       HAVE_MUSICBRAINZ="yes", HAVE_MUSICBRAINZ="no")
1175   AC_SUBST(MUSICBRAINZ_CFLAGS)
1176   AC_SUBST(MUSICBRAINZ_LIBS)
1177 ])
1178
1179 dnl *** nas ***
1180 translit(dnm, m, l) AM_CONDITIONAL(USE_NAS, true)
1181 GST_CHECK_FEATURE(NAS, [nas plug-in], nassink, [
1182   HAVE_NAS="no"
1183   if test "x$HAVE_X" = "xyes"; then
1184     save_cppflags=$CFLAGS
1185     CPPFLAGS="$CPPFLAGS $X_CFLAGS"
1186     GST_CHECK_LIBHEADER(NAS, audio, AuOpenServer, $X_LIBS, audio/audiolib.h,
1187       NAS_LIBS="$X_LIBS -laudio" NAS_CFLAGS="$X_CFLAGS")
1188     CPPFLAGS="$save_cppflags"
1189   fi
1190   AC_SUBST(NAS_CFLAGS)
1191   AC_SUBST(NAS_LIBS)
1192 ])
1193
1194 dnl *** pango ***
1195 translit(dnm, m, l) AM_CONDITIONAL(USE_PANGO, true)
1196 GST_CHECK_FEATURE(PANGO, [pango], pango, [
1197   PKG_CHECK_MODULES(PANGO, pango pangoft2,
1198       HAVE_PANGO="yes", HAVE_PANGO="no")
1199   AC_SUBST(PANGO_CFLAGS)
1200   AC_SUBST(PANGO_LIBS)
1201 ])
1202
1203 dnl *** raw1394 ***
1204 translit(dnm, m, l) AM_CONDITIONAL(USE_RAW1394, true)
1205 GST_CHECK_FEATURE(RAW1394, [raw1394 library], dv1394src, [
1206   GST_CHECK_LIBHEADER(RAW1394, raw1394, raw1394_new_handle,, libraw1394/raw1394.h, RAW1394_LIBS="-lraw1394")
1207   AC_SUBST(RAW1394_LIBS)
1208 ])
1209
1210 dnl *** SDL ***
1211 translit(dnm, m, l) AM_CONDITIONAL(USE_SDL, true)
1212 GST_CHECK_FEATURE(SDL, [SDL plug-in], sdlvideosink, [
1213   dnl sdlvideosink depends on the xoverlay interface, which depends on X
1214   if test x$HAVE_X = xyes; then
1215     AM_PATH_SDL(, HAVE_SDL=yes, HAVE_SDL=no)
1216   fi
1217 ])
1218
1219 dnl *** shout ***
1220 translit(dnm, m, l) AM_CONDITIONAL(USE_SHOUT, true)
1221 GST_CHECK_FEATURE(SHOUT, [shout plug-in], icecastsend, [
1222   GST_CHECK_LIBHEADER(SHOUT, shout, shout_init_connection,, shout/shout.h, SHOUT_LIBS="-lshout")
1223   AC_SUBST(SHOUT_LIBS)
1224 ])
1225
1226 dnl *** shout2 ***
1227 translit(dnm, m, l) AM_CONDITIONAL(USE_SHOUT2, true)
1228 GST_CHECK_FEATURE(SHOUT2, [shout2 plug-in], shout2send, [
1229   AM_PATH_SHOUT2(HAVE_SHOUT2=yes, HAVE_SHOUT2=no)
1230   AC_SUBST(SHOUT2_CFLAGS)
1231   AC_SUBST(SHOUT2_LIBS)
1232 ])
1233
1234 dnl *** sidplay ***
1235 translit(dnm, m, l) AM_CONDITIONAL(USE_SIDPLAY, true)
1236 GST_CHECK_FEATURE(SIDPLAY, [sidplay plug-in], sidplay, [
1237   GST_PATH_SIDPLAY()
1238 ])
1239
1240 dnl *** smoothwave ***
1241 translit(dnm, m, l) AM_CONDITIONAL(USE_SMOOTHWAVE, true)
1242 GST_CHECK_FEATURE(SMOOTHWAVE, [smoothwave plug-in], smoothwave, [
1243   if test $HAVE_GTK = "yes"; then HAVE_SMOOTHWAVE=yes; fi;
1244 ])
1245
1246
1247 dnl *** snapshot ***
1248 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBPNG, true)
1249 GST_CHECK_FEATURE(LIBPNG, [snapshot plug-in], snapshot, [
1250   GST_CHECK_LIBHEADER(LIBPNG, png, png_read_info, -lz -lm, png.h, LIBPNG_LIBS="-lpng -lz -lm")
1251   AC_SUBST(LIBPNG_LIBS)
1252 ])
1253
1254 dnl *** speex ***
1255 translit(dnm, m, l) AM_CONDITIONAL(USE_SPEEX, true)
1256 GST_CHECK_FEATURE(SPEEX, [speex plug-in], speex, [
1257   GST_CHECK_LIBHEADER(SPEEX, speex, speex_bits_init, , speex.h, HAVE_SPEEX="yes" SPEEX_LIBS="-lspeex")
1258   AC_SUBST(SPEEX_CFLAGS)
1259   AC_SUBST(SPEEX_LIBS)
1260 ])
1261
1262 dnl *** sndfile ***
1263 translit(dnm, m, l) AM_CONDITIONAL(USE_SNDFILE, true)
1264 GST_CHECK_FEATURE(SNDFILE, [sndfile plug-in], sfsrc sfsink, [
1265   PKG_CHECK_MODULES(SNDFILE, sndfile >= 1.0.0, HAVE_SNDFILE="yes", HAVE_SNDFILE="no")
1266   AC_SUBST(SNDFILE_CFLAGS)
1267   AC_SUBST(SNDFILE_LIBS)
1268 ])
1269
1270 dnl *** swfdec ***
1271 translit(dnm, m, l) AM_CONDITIONAL(USE_SWFDEC, true)
1272 GST_CHECK_FEATURE(SWFDEC, [swfdec plug-in], swfdec, [
1273   PKG_CHECK_MODULES(SWFDEC, swfdec >= 0.1.3.1, HAVE_SWFDEC=yes, HAVE_SWFDEC=no)
1274   AC_SUBST(SWFDEC_CFLAGS)
1275   AC_SUBST(SWFDEC_LIBS)
1276 ])
1277
1278 dnl *** tarkin ***
1279 dnl for now the sources are included in the plug-in
1280 dnl and should be moved to ext-libs/ perhaps
1281 translit(dnm, m, l) AM_CONDITIONAL(USE_TARKIN, true)
1282 GST_CHECK_FEATURE(TARKIN, [tarkinenc tarkindec], tarkin, [
1283   HAVE_TARKIN="yes"
1284 ])
1285
1286 dnl *** ogg ***
1287 translit(dnm, m, l) AM_CONDITIONAL(USE_OGG, true)
1288 GST_CHECK_FEATURE(OGG, [ogg de/encoder], oggdemux oggmux, [
1289   XIPH_PATH_OGG(HAVE_OGG=yes, HAVE_OGG=no)
1290   AS_SCRUB_INCLUDE(OGG_CFLAGS)
1291 ])
1292
1293 dnl *** theora ***
1294 dnl FIXME: theora doesn't have proper pc/m4 files yet, change this when this happens
1295 translit(dnm, m, l) AM_CONDITIONAL(USE_THEORA, true)
1296 GST_CHECK_FEATURE(THEORA, [ogg theora codec], theoradec, [
1297   GST_CHECK_LIBHEADER(THEORA, theora, theora_version_string, , theora/theora.h, THEORA_LIBS="-ltheora")
1298   AC_SUBST(THEORA_LIBS)
1299 ])
1300
1301 dnl *** vorbis ***
1302 dnl AM_PATH_VORBIS only takes two options
1303 translit(dnm, m, l) AM_CONDITIONAL(USE_VORBIS, true)
1304 GST_CHECK_FEATURE(VORBIS, [vorbis plug-in], vorbisenc vorbisdec, [
1305   XIPH_PATH_VORBIS(HAVE_VORBIS=yes, HAVE_VORBIS=no)
1306   AS_SCRUB_INCLUDE(VORBIS_CFLAGS)
1307 ])
1308 if test "x$HAVE_VORBIS" = "xyes"; then
1309   ac_cflags_save="$CFLAGS"
1310   CFLAGS="-Wall -Werror"
1311   AC_COMPILE_IFELSE(
1312     AC_LANG_PROGRAM([
1313 #include <vorbis/codec.h>
1314                      ],[
1315 vorbis_dsp_state *v;
1316
1317 vorbis_synthesis_restart (v);
1318                      ]), HAVE_VSR=yes, HAVE_VSR=no)
1319   if test "x$HAVE_VSR" = "xyes"; then
1320     AC_DEFINE_UNQUOTED(HAVE_VORBIS_SYNTHESIS_RESTART, 1,
1321                        [defined if vorbis_synthesis_restart is present])
1322   fi
1323   CFLAGS="$ac_cflags_save"
1324 fi
1325
1326 dnl *** xine ***
1327 translit(dnm, m, l) AM_CONDITIONAL(USE_XINE, true)
1328 GST_CHECK_FEATURE(XINE, [xine wrapper], xine, [
1329   PKG_CHECK_MODULES(XINE, libxine >= 1.0.0, HAVE_XINE=yes, HAVE_XINE=no)
1330   AC_SUBST(XINE_CFLAGS)
1331   AC_SUBST(XINE_LIBS)
1332 ],disabled)
1333
1334 dnl *** XVID ***
1335 translit(dnm, m, l) AM_CONDITIONAL(USE_XVID, true)
1336 GST_CHECK_FEATURE(XVID, [xvid plugins], xvid, [
1337   HAVE_XVID=no
1338   AC_CHECK_HEADER(xvid.h, [
1339     OLD_LIBS="$LIBS"
1340     LIBS="-lm"
1341     AC_CHECK_LIB(xvidcore, xvid_encore, [
1342       AC_CHECK_LIB(xvidcore, xvid_decore, [
1343         AC_CHECK_LIB(xvidcore, xvid_global, [
1344           AC_MSG_CHECKING([for uptodate XviD API version])
1345           AC_TRY_RUN([
1346 #include <xvid.h>
1347 #if XVID_API != XVID_MAKE_API(4,0)
1348 #error "Incompatible XviD API version"
1349 #endif
1350 int main () { return 0; }
1351           ],[ AC_MSG_RESULT(yes)
1352             XVID_LIBS="-lxvidcore -lm"
1353             AC_SUBST(XVID_LIBS)
1354             HAVE_XVID=yes
1355           ], AC_MSG_RESULT(no) )
1356         ], )
1357       ], )
1358     ], )
1359     LIBS="$OLD_LIBS"
1360   ], )
1361 ])
1362
1363
1364 fi dnl of EXT plugins
1365
1366 dnl Check for atomic.h
1367 dnl Note: use AC_CHECK_HEADER not AC_CHECK_HEADERS, because the latter
1368 dnl defines the wrong default symbol as well (HAVE_ASM_ATOMIC_H)
1369 AC_CHECK_HEADER(asm/atomic.h, HAVE_ATOMIC_H=yes, HAVE_ATOMIC_H=no)
1370 dnl Do a compile to check that it has atomic_set (eg, linux 2.0 didn't)
1371 if test x$HAVE_ATOMIC_H = xyes; then
1372   AC_TRY_RUN([
1373 #include "asm/atomic.h"
1374 main() { atomic_t t; atomic_set(&t,0); atomic_inc(&t); atomic_add(1,&t);return 0;}
1375   ],, [
1376     # Not successful
1377     if test x$HAVE_ATOMIC_H = xyes; then
1378       AC_MSG_WARN(Atomic reference counting is out of date: doing without.)
1379     fi
1380     HAVE_ATOMIC_H=no
1381   ], [
1382     # Cross compiling
1383     AC_MSG_RESULT(yes)
1384     AC_MSG_WARN(Can't check properly for atomic reference counting.  Assuming OK.)
1385   ])
1386 fi
1387
1388
1389 dnl ######################################################################
1390 dnl # Check command line parameters, and set shell variables accordingly #
1391 dnl ######################################################################
1392
1393 AC_ARG_ENABLE(libmmx,
1394   AC_HELP_STRING([--enable-libmmx],[use libmmx, if available]),
1395 [case "${enableval}" in
1396   yes) USE_LIBMMX=$HAVE_LIBMMX ;;
1397   no)  USE_LIBMMX=no ;;
1398   *) AC_MSG_ERROR(bad value ${enableval} for --enable-libmmx) ;;
1399 esac],
1400 [USE_LIBMMX=$HAVE_LIBMMX]) dnl Default value
1401
1402 AC_ARG_ENABLE(atomic,
1403   AC_HELP_STRING([--enable-atomic],[use atomic reference counting header]),
1404 [case "${enableval}" in
1405   yes) USE_ATOMIC_H=$HAVE_ATOMIC_H;;
1406   noset) USE_ATOMIC_H=$HAVE_ATOMIC_H;;
1407   no)  USE_ATOMIC_H=no;;
1408   *) AC_MSG_ERROR(bad value ${enableval} for --enable-atomic) ;;
1409 esac],
1410 [USE_ATOMIC_H=$HAVE_ATOMIC_H]) dnl Default value
1411
1412 AC_ARG_ENABLE(profiling,
1413   AC_HELP_STRING([--enable-profiling],
1414                  [-pg to compiler commandline, for profiling]),
1415 [case "${enableval}" in
1416   yes) USE_PROFILING=yes ;;
1417   no)  UES_PROFILING=no ;;
1418   *) AC_MSG_ERROR(bad value ${enableval} for --enable-profiling) ;;
1419 esac],
1420 [USE_PROFILING=no]) dnl Default value
1421
1422 AC_ARG_ENABLE(tests,
1423   AC_HELP_STRING([--disable-tests],[disable building test apps]),
1424 [case "${enableval}" in
1425   yes) BUILD_TESTS=yes ;;
1426   no)  BUILD_TESTS=no ;;
1427   *) AC_MSG_ERROR(bad value ${enableval} for --disable-tests) ;;
1428 esac],
1429 [BUILD_TESTS=yes]) dnl Default value
1430
1431 AC_ARG_ENABLE(examples,
1432   AC_HELP_STRING([--disable-examples],[disable building examples]),
1433 [case "${enableval}" in
1434   yes) BUILD_EXAMPLES=yes ;;
1435   no)  BUILD_EXAMPLES=no ;;
1436   *) AC_MSG_ERROR(bad value ${enableval} for --disable-examples) ;;
1437 esac],
1438 [BUILD_EXAMPLES=yes]) dnl Default value
1439
1440 dnl seeking needs freetype, so check for it here
1441 AC_CHECK_FT2(2.0.9,HAVE_FT2=yes,HAVE_FT2=no)
1442 dnl make the HAVE_FT2 variable available to automake and Makefile.am
1443 AM_CONDITIONAL(HAVE_FT2, test "x$HAVE_FT2" = "xyes")
1444 AC_SUBST(FT2_CFLAGS)
1445 AC_SUBST(FT2_LIBS)
1446
1447 dnl ################################################
1448 dnl # Set defines according to variables set above #
1449 dnl ################################################
1450
1451
1452 if test "x$USE_LIBMMX" = xyes; then
1453   AC_DEFINE(HAVE_LIBMMX, 1, [Define if libmmx is available])
1454 fi
1455
1456 if test "x$USE_ATOMIC_H" = xyes; then
1457   AC_DEFINE(HAVE_ATOMIC_H, 1, [Define if atomic.h header file is available])
1458 fi
1459
1460 # do not use deprecated stuff
1461 GST_CFLAGS="$GST_CFLAGS -DGST_DISABLE_DEPRECATED"
1462
1463 if test "x$USE_DEBUG" = xyes; then
1464   GST_CFLAGS="$GST_CFLAGS -g"
1465 fi
1466
1467 dnl #############################
1468 dnl # Set automake conditionals #
1469 dnl #############################
1470
1471 dnl These should be "USE_*" instead of "HAVE_*", but some packages expect
1472 dnl HAVE_ and it is likely to be easier to stick with the old name
1473 AM_CONDITIONAL(HAVE_LIBMMX,         test "x$USE_LIBMMX" = "xyes")
1474
1475 AM_CONDITIONAL(HAVE_ATOMIC_H,       test "x$USE_ATOMIC_H" = "xyes")
1476
1477 AM_CONDITIONAL(EXPERIMENTAL,        test "$EXPERIMENTAL" = "$xyes")
1478 AM_CONDITIONAL(BROKEN,              test "$BROKEN" = "$xyes")
1479
1480 AM_CONDITIONAL(HAVE_NASM,           test "x$HAVE_NASM" = "xyes")
1481 AM_CONDITIONAL(HAVE_GTK,            test "x$HAVE_GTK" = "xyes")
1482 AM_CONDITIONAL(HAVE_GTK_DOC,        $HAVE_GTK_DOC)
1483 AM_CONDITIONAL(BUILD_DOCS,          test "x$BUILD_DOCS" = "xyes")
1484 AM_CONDITIONAL(BUILD_TESTS,         test "x$BUILD_TESTS" = "xyes")
1485 AM_CONDITIONAL(BUILD_EXAMPLES,      test "x$BUILD_EXAMPLES" = "xyes")
1486 AM_CONDITIONAL(BUILD_PLUGIN_DOCS,   test "x$BUILD_PLUGIN_DOCS" = "xyes")
1487 AM_CONDITIONAL(HAVE_FIG2DEV_PNG,    $HAVE_FIG2DEV_PNG)
1488 AM_CONDITIONAL(HAVE_FIG2DEV_PDF,    $HAVE_FIG2DEV_PDF)
1489 AM_CONDITIONAL(HAVE_RAW1394,        test "x$HAVE_RAW1394" = "xyes")
1490
1491 dnl prefer internal headers to already installed ones
1492 GST_CFLAGS="-I\$(top_srcdir)/gst-libs $GST_CFLAGS $GST_ERROR"
1493
1494 AC_SUBST(GST_LIBS)
1495 AC_SUBST(GST_CFLAGS)
1496
1497 dnl ###########################
1498 dnl # Configure external libs #
1499 dnl ###########################
1500
1501 dnl ############################
1502 dnl # Set up some more defines #
1503 dnl ############################
1504
1505 dnl set license and copyright notice
1506 AC_DEFINE(GST_LICENSE, "LGPL", [GStreamer license])
1507 dnl package name in plugins
1508 AC_ARG_WITH(package-name,
1509 AC_HELP_STRING([--with-package-name],[specify package name to use in plugins]),
1510 [case "${withval}" in
1511   yes) AC_MSG_ERROR(bad value ${withval} for --with-package-name) ;;
1512   no) AC_MSG_ERROR(bad value ${withval} for --with-package-name) ;;
1513   *) GST_PACKAGE="${withval}" ;;
1514 esac],
1515 [GST_PACKAGE="GStreamer"]) dnl Default value
1516 AC_MSG_NOTICE(Using $GST_PACKAGE as package name)
1517 AC_DEFINE_UNQUOTED(GST_PACKAGE, "$GST_PACKAGE", [package name in plugins])
1518 dnl package origin URL
1519 AC_ARG_WITH(package-origin,
1520 AC_HELP_STRING([--with-package-origin],[specify package origin URL to use in plugins]),
1521 [case "${withval}" in
1522   yes) AC_MSG_ERROR(bad value ${withval} for --with-package-origin) ;;
1523   no) AC_MSG_ERROR(bad value ${withval} for --with-package-origin) ;;
1524   *) GST_ORIGIN="${withval}" ;;
1525 esac],
1526 [GST_ORIGIN="http://gstreamer.net"]) dnl Default value
1527 AC_MSG_NOTICE(Using $GST_ORIGIN as package origin)
1528 AC_DEFINE_UNQUOTED(GST_ORIGIN, "$GST_ORIGIN", [package origin])
1529
1530 dnl #########################
1531 dnl # Make the output files #
1532 dnl #########################
1533
1534 AC_CONFIG_FILES(
1535 Makefile
1536 pkgconfig/gstreamer-libs.pc
1537 pkgconfig/gstreamer-libs-uninstalled.pc
1538 pkgconfig/gstreamer-play.pc
1539 pkgconfig/gstreamer-play-uninstalled.pc
1540 pkgconfig/gstreamer-interfaces.pc
1541 pkgconfig/gstreamer-interfaces-uninstalled.pc
1542 gst-libs/gst/gconf/gstreamer-gconf.pc
1543 gst-libs/gst/gconf/gstreamer-gconf-uninstalled.pc
1544 gst-plugins.spec
1545 gst/Makefile
1546 gst/ac3parse/Makefile
1547 gst/adder/Makefile
1548 gst/audioconvert/Makefile
1549 gst/audioscale/Makefile
1550 gst/auparse/Makefile
1551 gst/avi/Makefile
1552 gst/asfdemux/Makefile
1553 gst/cdxaparse/Makefile
1554 gst/chart/Makefile
1555 gst/colorspace/Makefile
1556 gst/cutter/Makefile
1557 gst/debug/Makefile
1558 gst/deinterlace/Makefile
1559 gst/effectv/Makefile
1560 gst/festival/Makefile
1561 gst/filter/Makefile
1562 gst/flx/Makefile
1563 gst/goom/Makefile
1564 gst/id3/Makefile
1565 gst/interleave/Makefile
1566 gst/law/Makefile
1567 gst/level/Makefile
1568 gst/matroska/Makefile
1569 gst/median/Makefile
1570 gst/mixmatrix/Makefile
1571 gst/mpeg1sys/Makefile
1572 gst/mpeg1videoparse/Makefile
1573 gst/mpeg2sub/Makefile
1574 gst/mpegaudio/Makefile
1575 gst/mpegaudioparse/Makefile
1576 gst/mpegstream/Makefile
1577 gst/modplug/Makefile
1578 gst/modplug/libmodplug/Makefile
1579 gst/monoscope/Makefile
1580 gst/overlay/Makefile
1581 gst/passthrough/Makefile
1582 gst/playondemand/Makefile
1583 gst/qtdemux/Makefile
1584 gst/realmedia/Makefile
1585 gst/rtjpeg/Makefile
1586 gst/rtp/Makefile
1587 gst/silence/Makefile
1588 gst/sine/Makefile
1589 gst/smooth/Makefile
1590 gst/smpte/Makefile
1591 gst/spectrum/Makefile
1592 gst/speed/Makefile
1593 gst/stereo/Makefile
1594 gst/switch/Makefile
1595 gst/synaesthesia/Makefile
1596 gst/tags/Makefile
1597 gst/tcp/Makefile
1598 gst/typefind/Makefile
1599 gst/udp/Makefile
1600 gst/vbidec/Makefile
1601 gst/videocrop/Makefile
1602 gst/videodrop/Makefile
1603 gst/videofilter/Makefile
1604 gst/videoflip/Makefile
1605 gst/videoscale/Makefile
1606 gst/videotestsrc/Makefile
1607 gst/volenv/Makefile
1608 gst/volume/Makefile
1609 gst/wavenc/Makefile
1610 gst/wavparse/Makefile
1611 gst/y4m/Makefile
1612 sys/Makefile
1613 sys/cdrom/Makefile
1614 sys/dxr3/Makefile
1615 sys/glsink/Makefile
1616 sys/oss/Makefile
1617 sys/qcam/Makefile
1618 sys/v4l/Makefile
1619 sys/v4l2/Makefile
1620 sys/vcd/Makefile
1621 sys/ximage/Makefile
1622 sys/xvimage/Makefile
1623 sys/xvideo/Makefile
1624 ext/Makefile
1625 ext/a52dec/Makefile
1626 ext/aalib/Makefile
1627 ext/alsa/Makefile
1628 ext/arts/Makefile
1629 ext/artsd/Makefile
1630 ext/audiofile/Makefile
1631 ext/cdparanoia/Makefile
1632 ext/divx/Makefile
1633 ext/dv/Makefile
1634 ext/dvdread/Makefile
1635 ext/dvdnav/Makefile
1636 ext/esd/Makefile
1637 ext/faac/Makefile
1638 ext/faad/Makefile
1639 ext/flac/Makefile
1640 ext/gdk_pixbuf/Makefile
1641 ext/gnomevfs/Makefile
1642 ext/gsm/Makefile
1643 ext/hermes/Makefile
1644 dnl ext/http/Makefile
1645 ext/jack/Makefile
1646 ext/jpeg/Makefile
1647 ext/ladspa/Makefile
1648 ext/lame/Makefile
1649 ext/ivorbis/Makefile
1650 ext/lcs/Makefile
1651 ext/libcaca/Makefile
1652 ext/libfame/Makefile
1653 ext/libpng/Makefile
1654 ext/librfb/Makefile
1655 ext/mad/Makefile
1656 ext/mikmod/Makefile
1657 ext/mpeg2dec/Makefile
1658 ext/mpeg2enc/Makefile
1659 ext/mplex/Makefile
1660 ext/musicbrainz/Makefile
1661 ext/nas/Makefile
1662 ext/ogg/Makefile
1663 ext/pango/Makefile
1664 ext/raw1394/Makefile
1665 ext/sdl/Makefile
1666 ext/shout/Makefile
1667 ext/shout2/Makefile
1668 ext/sidplay/Makefile
1669 ext/smoothwave/Makefile
1670 ext/snapshot/Makefile
1671 ext/speex/Makefile
1672 ext/sndfile/Makefile
1673 ext/swfdec/Makefile
1674 ext/tarkin/Makefile
1675 ext/theora/Makefile
1676 ext/vorbis/Makefile
1677 ext/xine/Makefile
1678 ext/xvid/Makefile
1679 gst-libs/Makefile
1680 gst-libs/gst/Makefile
1681 gst-libs/gst/audio/Makefile
1682 gst-libs/gst/colorbalance/Makefile
1683 gst-libs/gst/floatcast/Makefile
1684 gst-libs/gst/gconf/Makefile
1685 gst-libs/gst/idct/Makefile
1686 gst-libs/gst/media-info/Makefile
1687 gst-libs/gst/mixer/Makefile
1688 gst-libs/gst/navigation/Makefile
1689 gst-libs/gst/play/Makefile
1690 gst-libs/gst/propertyprobe/Makefile
1691 gst-libs/gst/resample/Makefile
1692 gst-libs/gst/riff/Makefile
1693 gst-libs/gst/tag/Makefile
1694 gst-libs/gst/tuner/Makefile
1695 gst-libs/gst/video/Makefile
1696 gst-libs/gst/xoverlay/Makefile
1697 gst-libs/gst/xwindowlistener/Makefile
1698 gst-libs/ext/Makefile
1699 examples/dynparams/Makefile
1700 examples/capsfilter/Makefile
1701 examples/seeking/Makefile
1702 examples/indexing/Makefile
1703 examples/gstplay/Makefile
1704 examples/switch/Makefile
1705 examples/Makefile
1706 testsuite/spider/Makefile
1707 testsuite/alsa/Makefile
1708 testsuite/Makefile
1709 tools/Makefile
1710 tools/gst-launch-ext
1711 gconf/Makefile
1712 pkgconfig/Makefile
1713 po/Makefile.in
1714 )
1715 AC_OUTPUT
1716
1717 echo -n "configure: *** Plug-ins that will be built :"
1718 echo -e "$GST_PLUGINS_YES" | sort
1719 echo
1720 echo -n "configure: *** Plug-ins that will not be built :"
1721 echo -e "$GST_PLUGINS_NO" | sort
1722 echo
1723 if test "x$BUILD_EXTERNAL" = "xno"; then
1724   echo "configure: *** No external plug-ins will be built"
1725 fi