configure.ac

   1 AC_PREREQ(2.52)
   2
   3 dnl initialize autoconf
   4 dnl when going to/from release please set the nano (fourth number) right !
   5 dnl releases only do Wall, cvs and prerelease does Werror too
   6 AC_INIT(GStreamer, 0.10.20.1,
   7     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
   8     gstreamer)
   9 AG_GST_INIT
  10
  11 dnl initialize automake
  12 AM_INIT_AUTOMAKE
  13
  14 dnl define PACKAGE_VERSION_* variables
  15 AS_VERSION
  16
  17 dnl check if this is a release version
  18 AS_NANO(GST_CVS="no", GST_CVS="yes")
  19
  20 dnl can autoconf find the source ?
  21 AC_CONFIG_SRCDIR([gst/gst.c])
  22
  23 dnl define the output header for config
  24 AM_CONFIG_HEADER([config.h])
  25
  26 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  27 AM_MAINTAINER_MODE
  28
  29 dnl sets host_* variables
  30 AC_CANONICAL_HOST
  31
  32 dnl our libraries and install dirs use major.minor as a version
  33 GST_MAJORMINOR=$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR
  34 dnl we override it here for release candidates for a new series
  35 GST_MAJORMINOR=0.10
  36 AC_SUBST(GST_MAJORMINOR)
  37 AC_DEFINE_UNQUOTED(GST_MAJORMINOR, "$GST_MAJORMINOR",
  38   [library major.minor version])
  39
  40 dnl CURRENT, REVISION, AGE
  41 dnl - library source changed -> increment REVISION
  42 dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
  43 dnl - interfaces added -> increment AGE
  44 dnl - interfaces removed -> AGE = 0
  45 dnl sets GST_LT_LDFLAGS
  46 AS_LIBTOOL(GST, 17, 0, 17)
  47
  48 dnl FIXME: this macro doesn't actually work;
  49 dnl the generated libtool script has no support for the listed tags.
  50 dnl So this needs to be fixed first if we want to use this
  51 dnl AS_LIBTOOL_TAGS
  52
  53 AC_LIBTOOL_WIN32_DLL
  54 AM_PROG_LIBTOOL
  55
  56 dnl *** autotools stuff ****
  57
  58 dnl allow for different autotools
  59 AS_AUTOTOOLS_ALTERNATE
  60
  61 dnl Add parameters for aclocal
  62 AC_SUBST(ACLOCAL_AMFLAGS, "-I common/m4")
  63
  64 dnl set up gettext
  65 dnl the version check needs to stay here because autopoint greps for it
  66 AM_GNU_GETTEXT_VERSION([0.11.5])
  67 AM_GNU_GETTEXT([external])
  68 AG_GST_GETTEXT([gstreamer-$GST_MAJORMINOR])
  69
  70 dnl *** check for arguments to configure ***
  71
  72 dnl subsystems - can influence other decisions so needs to be high up
  73 dnl we need to AM_CONDITIONAL them here for automake 1.6.x compatibility
  74 AG_GST_CHECK_SUBSYSTEM_DISABLE(GST_DEBUG,[debugging subsystem])
  75 AM_CONDITIONAL(GST_DISABLE_GST_DEBUG, test "x$GST_DISABLE_GST_DEBUG" = "xyes")
  76 AG_GST_CHECK_SUBSYSTEM_DISABLE(LOADSAVE,[pipeline XML load/save])
  77 AM_CONDITIONAL(GST_DISABLE_LOADSAVE, test "x$GST_DISABLE_LOADSAVE" = "xyes")
  78 dnl define a substitution to use in docs/gst/gstreamer.types
  79 if test "x$GST_DISABLE_LOADSAVE" = "xyes"
  80 then
  81   GST_LOADSAVE_DOC_TYPES="%"
  82 else
  83   GST_LOADSAVE_DOC_TYPES=
  84 fi
  85 AC_SUBST(GST_LOADSAVE_DOC_TYPES)
  86 AG_GST_CHECK_SUBSYSTEM_DISABLE(PARSE,[command-line parser])
  87 AM_CONDITIONAL(GST_DISABLE_PARSE, test "x$GST_DISABLE_PARSE" = "xyes")
  88 if test "x$GST_DISABLE_PARSE" = xyes; then
  89   AC_DEFINE(GST_DISABLE_PARSE, 1,
  90     [Define if pipeline parsing code is disabled])
  91 fi
  92 AG_GST_CHECK_SUBSYSTEM_DISABLE(OPTION_PARSING,[option parsing when gst_init])
  93 AM_CONDITIONAL(GST_DISABLE_OPTION_PARSING, test "x$GST_DISABLE_OPTION_PARSING" = "xyes")
  94 if test "x$GST_DISABLE_OPTION_PARSING" = xyes; then
  95   AC_DEFINE(GST_DISABLE_OPTION_PARSING, 1,
  96     [Define if option parsing is disabled])
  97 fi
  98 AG_GST_CHECK_SUBSYSTEM_DISABLE(TRACE,[tracing subsystem])
  99 AM_CONDITIONAL(GST_DISABLE_TRACE, test "x$GST_DISABLE_TRACE" = "xyes")
 100 AG_GST_CHECK_SUBSYSTEM_DISABLE(ALLOC_TRACE,[allocation tracing])
 101 AM_CONDITIONAL(GST_DISABLE_ALLOC_TRACE, test "x$GST_DISABLE_ALLOC_TRACE" = "xyes")
 102 AG_GST_CHECK_SUBSYSTEM_DISABLE(REGISTRY,[plugin registry])
 103 AM_CONDITIONAL(GST_DISABLE_REGISTRY, test "x$GST_DISABLE_REGISTRY" = "xyes")
 104 dnl define a substitution to use in docs/gst/gstreamer.types
 105 if test "x$GST_DISABLE_REGISTRY" = "xyes"
 106 then
 107   GST_REGISTRY_DOC_TYPES="%"
 108 else
 109   GST_REGISTRY_DOC_TYPES=
 110 fi
 111 AC_SUBST(GST_REGISTRY_DOC_TYPES)
 112 AG_GST_CHECK_SUBSYSTEM_DISABLE(ENUMTYPES,[enum types])
 113 AM_CONDITIONAL(GST_DISABLE_ENUMTYPES, test "x$GST_DISABLE_ENUMTYPES" = "xyes")
 114 AG_GST_CHECK_SUBSYSTEM_DISABLE(INDEX,[index])
 115 AM_CONDITIONAL(GST_DISABLE_INDEX, test "x$GST_DISABLE_INDEX" = "xyes")
 116 dnl define a substitution to use in docs/gst/gstreamer.types
 117 if test "x$GST_DISABLE_INDEX" = "xyes"
 118 then
 119   GST_INDEX_DOC_TYPES="%"
 120 else
 121   GST_INDEX_DOC_TYPES=
 122 fi
 123 AC_SUBST(GST_INDEX_DOC_TYPES)
 124 AG_GST_CHECK_SUBSYSTEM_DISABLE(NET,[network distribution])
 125 AM_CONDITIONAL(GST_DISABLE_NET, test "x$GST_DISABLE_NET" = "xyes")
 126 AG_GST_CHECK_SUBSYSTEM_DISABLE(PLUGIN,[plugin])
 127 AM_CONDITIONAL(GST_DISABLE_PLUGIN, test "x$GST_DISABLE_PLUGIN" = "xyes")
 128 AG_GST_CHECK_SUBSYSTEM_DISABLE(URI,[uri handlers])
 129 AM_CONDITIONAL(GST_DISABLE_URI, test "x$GST_DISABLE_URI" = "xyes")
 130
 131 AG_GST_ARG_DEBUG
 132 AG_GST_ARG_PROFILING
 133 AG_GST_ARG_VALGRIND
 134 AG_GST_ARG_GCOV
 135
 136 AG_GST_ARG_EXAMPLES
 137
 138 AG_GST_ARG_WITH_PKG_CONFIG_PATH
 139 AG_GST_ARG_WITH_PACKAGE_NAME
 140 AG_GST_ARG_WITH_PACKAGE_ORIGIN
 141
 142 dnl building of tests
 143 AC_ARG_ENABLE(tests,
 144   AC_HELP_STRING([--disable-tests], [disable building test apps]),
 145   [
 146     case "${enableval}" in
 147       yes) BUILD_TESTS=yes ;;
 148       no)  BUILD_TESTS=no ;;
 149       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-tests) ;;
 150     esac
 151   ],
 152 [BUILD_TESTS=yes]) dnl Default value
 153 AM_CONDITIONAL(BUILD_TESTS,         test "x$BUILD_TESTS" = "xyes")
 154
 155 dnl tests known to fail
 156 AC_ARG_ENABLE(failing-tests,
 157   AC_HELP_STRING([--disable-failing-tests],
 158     [disable building tests known to fail]),
 159   [
 160     case "${enableval}" in
 161       yes) BUILD_FAILING_TESTS=yes ;;
 162       no)  BUILD_FAILING_TESTS=no ;;
 163       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-failing-tests) ;;
 164     esac
 165   ],
 166   [BUILD_FAILING_TESTS=no]) dnl Default value
 167 AM_CONDITIONAL(BUILD_FAILING_TESTS, test "x$BUILD_FAILING_TESTS" = "xyes")
 168 if test x$BUILD_FAILING_TESTS = xyes; then
 169   AC_MSG_WARN([building tests known to fail, use --disable-failing-tests to disable])
 170 else
 171   AC_MSG_WARN([Sissy ! By asking to not build the tests known to fail, you hereby waive your right to customer support.  If you do not agree with this EULA, please press Ctrl-C before the next line is printed.  By allowing the next line to be printed, you expressly acknowledge your acceptance of this EULA.])
 172 fi
 173
 174 dnl poison destroyed objects
 175 AC_ARG_ENABLE(poisoning,
 176   AC_HELP_STRING([--enable-poisoning],
 177     [enable poisoning of deallocated objects]),
 178   [
 179     case "${enableval}" in
 180       yes) USE_POISONING=yes ;;
 181       no)  USE_POISONING=no ;;
 182       *)   AC_MSG_ERROR(bad value ${enableval} for --enable-poisoning) ;;
 183     esac
 184   ],
 185   [USE_POISONING=no]) dnl Default value
 186 if test "x$USE_POISONING" = xyes; then
 187   AC_DEFINE(USE_POISONING, 1,
 188     [Define if we should poison deallocated memory])
 189 fi
 190
 191 dnl Use binary registry
 192 AC_ARG_ENABLE(binary-registry,
 193   AC_HELP_STRING([--disable-binary-registry],
 194     [disable binary registry]),
 195   [
 196     case "${enableval}" in
 197       yes) USE_BINARY_REGISTRY=yes ;;
 198       no)  USE_BINARY_REGISTRY=no ;;
 199       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-binary-registry) ;;
 200     esac
 201   ],
 202   [USE_BINARY_REGISTRY=yes]) dnl Default value
 203
 204 if test "x$USE_BINARY_REGISTRY" = xyes; then
 205   dnl for config.h:
 206   AC_DEFINE(USE_BINARY_REGISTRY, 1,
 207     [Define if we should use binary registry instead xml registry])
 208 fi
 209 AM_CONDITIONAL(USE_BINARY_REGISTRY, test "x$USE_BINARY_REGISTRY" = "xyes")
 210
 211 dnl *** checks for platform ***
 212
 213 dnl * hardware/architecture *
 214
 215 dnl common/m4/gst-arch.m4
 216 dnl check CPU type
 217 AG_GST_ARCH
 218 dnl substitution for win32/common/config.h
 219 HOST_CPU=$host_cpu
 220 AC_SUBST(HOST_CPU)
 221
 222 dnl common/m4/gst-arch.m4
 223 dnl check for unaligned access
 224 AG_GST_UNALIGNED_ACCESS
 225 dnl create a configure variable for gst/gstconfig.h
 226 if test x${as_cv_unaligned_access} = xyes ; then
 227   GST_HAVE_UNALIGNED_ACCESS_DEFINE="#define GST_HAVE_UNALIGNED_ACCESS 1"
 228 else
 229   GST_HAVE_UNALIGNED_ACCESS_DEFINE="#define GST_HAVE_UNALIGNED_ACCESS 0"
 230 fi
 231 AC_SUBST(GST_HAVE_UNALIGNED_ACCESS_DEFINE)
 232
 233 dnl check for platform specific settings
 234 case $host_os in
 235      rhapsody*)
 236         AC_DEFINE_UNQUOTED(GST_EXTRA_MODULE_SUFFIX, [".dylib"], [Extra platform specific plugin suffix])
 237         ;;
 238      darwin*)
 239         AC_DEFINE_UNQUOTED(GST_EXTRA_MODULE_SUFFIX, [".dylib"], [Extra platform specific plugin suffix])
 240         AC_DEFINE_UNQUOTED(GST_HAVE_UNSAFE_FORK, 1, [Defined when registry scanning through fork is unsafe])
 241         ;;
 242      cygwin* | mingw* | msvc* | mks*)
 243         dnl HAVE_WIN32 currently means "disable POSIXisms".
 244         AC_DEFINE_UNQUOTED(HAVE_WIN32, 1, [Defined if compiling for Windows])
 245         ;;
 246      *)
 247         ;;
 248 esac
 249
 250 dnl * software *
 251
 252 dnl check for large file support
 253 dnl affected plugins must include config.h
 254 AC_SYS_LARGEFILE
 255
 256 dnl *** checks for programs ***
 257
 258 dnl find a compiler
 259 AC_PROG_CC
 260
 261 dnl check if the compiler supports '-c' and '-o' options
 262 AM_PROG_CC_C_O
 263
 264 dnl find an assembler
 265 AM_PROG_AS
 266
 267 dnl Perl is used in building documentation and in the version checks
 268 AC_PATH_PROG(PERL_PATH, perl, no)
 269 if test x$PERL_PATH = xno; then
 270   AC_MSG_ERROR(Could not find perl)
 271 fi
 272
 273 dnl we require flex and bison for building the parser
 274 AG_GST_BISON_CHECK
 275 AG_GST_FLEX_CHECK
 276
 277 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 278 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 279
 280 dnl check for documentation tools
 281 AG_GST_DOCBOOK_CHECK
 282 GTK_DOC_CHECK([1.3])
 283 AS_PATH_PYTHON([2.1])
 284 AG_GST_PLUGIN_DOCS([1.3],[2.1])
 285
 286 dnl *** checks for libraries ***
 287
 288 dnl For interactive UNIX (a Sun thing)
 289 dnl FIXME: this adds -lcposix to LIBS, but I doubt we use LIBS
 290 AC_ISC_POSIX
 291
 292 dnl check for libm, for sin()
 293 AC_CHECK_LIBM
 294 AC_SUBST(LIBM)
 295
 296 dnl *** checks for header files ***
 297
 298 dnl check if we have ANSI C header files
 299 AC_HEADER_STDC
 300
 301 dnl Check for ucontext.h
 302 AC_CHECK_HEADERS([ucontext.h])
 303
 304 dnl Check for sys/socket.h
 305 AC_CHECK_HEADERS([sys/socket.h], HAVE_SYS_SOCKET_H=yes)
 306 AM_CONDITIONAL(HAVE_SYS_SOCKET_H, test "x$HAVE_SYS_SOCKET_H" = "xyes")
 307
 308 dnl check for sys/times.h for tests/examples/adapter/
 309 AC_CHECK_HEADERS([sys/times.h], HAVE_SYS_TIMES_H=yes)
 310 AC_CHECK_HEADERS([unistd.h], HAVE_UNISTD_H=yes)
 311 AM_CONDITIONAL(HAVE_SYS_TIMES_H_AND_UNISTD_H, test "x$HAVE_SYS_TIMES_H" = "xyes" -a "x$HAVE_UNISTD_H" = "xyes")
 312
 313 dnl Check for process.h for getpid() on win32
 314 AC_CHECK_HEADERS([process.h])
 315
 316 dnl Check for sys/utsname.h for uname
 317 AC_CHECK_HEADERS([sys/utsname.h])
 318
 319 dnl Check for stdio_ext.f for __fbufsize
 320 AC_CHECK_HEADERS([stdio_ext.h])
 321
 322 dnl Check for valgrind.h
 323 dnl separate from HAVE_VALGRIND because you can have the program, but not
 324 dnl the dev package
 325 AC_CHECK_HEADERS([valgrind/valgrind.h], HAVE_VALGRIND_H=yes)
 326
 327 dnl *** checks for types/defines ***
 328
 329 dnl *** checks for structures ***
 330
 331 dnl *** checks for compiler characteristics ***
 332
 333 dnl make sure we can use "inline" from C code
 334 AC_C_INLINE
 335
 336 OPT_CFLAGS=
 337 dnl Check for some compiler flags that optimize our code.
 338 if test "x$GCC" = xyes; then
 339   AS_COMPILER_FLAG(-fno-common, OPT_CFLAGS="$OPT_CFLAGS -fno-common")
 340 fi
 341
 342 dnl FIXME: decide what kind of flag this is, maybe it's not an optimization
 343 dnl flag
 344 dnl check if we should use -Wa,-mregnames on PowerPC, so we can use
 345 dnl symbolic register names in inline asm
 346 if test x$HAVE_CPU_PPC = xyes ; then
 347   AS_COMPILER_FLAG(["-Wa,-mregnames"],
 348     [OPT_CFLAGS="$OPT_CFLAGS -Wa,-mregnames"])
 349 fi
 350
 351 dnl *** checks for library functions ***
 352
 353 AC_CHECK_FUNCS([sigaction])
 354
 355 dnl we use fork in the registry code
 356 AC_CHECK_FUNCS([fork])
 357
 358 dnl check for fseeko()
 359 AC_FUNC_FSEEKO
 360 dnl check for ftello()
 361 AC_CHECK_FUNCS([ftello])
 362
 363 AC_CHECK_FUNCS([fgetpos])
 364 AC_CHECK_FUNCS([fsetpos])
 365
 366 dnl check for poll(), ppoll() and pselect()
 367 AC_CHECK_FUNCS([poll])
 368 AC_CHECK_FUNCS([ppoll])
 369 AC_CHECK_FUNCS([pselect])
 370
 371 dnl check for mmap()
 372 AC_FUNC_MMAP
 373 AM_CONDITIONAL(HAVE_MMAP, test "x$ac_cv_func_mmap_fixed_mapped" = "xyes")
 374
 375 dnl Check for POSIX timers
 376 AC_CHECK_FUNCS(clock_gettime, [], [
 377   AC_CHECK_LIB(rt, clock_gettime, [
 378     AC_DEFINE(HAVE_CLOCK_GETTIME, 1)
 379     LIBS="$LIBS -lrt"
 380   ])
 381 ])
 382
 383 AC_CACHE_CHECK(for posix timers, gst_cv_posix_timers,
 384     AC_TRY_COMPILE([
 385 #include <time.h>
 386 #ifdef HAVE_UNISTD_H
 387 #include <unistd.h>
 388 #endif
 389     ], [
 390 #if !defined(_POSIX_TIMERS) || _POSIX_TIMERS < 0 || !defined(CLOCK_REALTIME)
 391 #error Either _POSIX_TIMERS or CLOCK_REALTIME not defined
 392 #endif
 393       return 0;
 394     ], [
 395       gst_cv_posix_timers=yes
 396     ], [
 397       gst_cv_posix_timers=no
 398     ])
 399 )
 400
 401 if test "$gst_cv_posix_timers" = "yes"; then
 402   AC_DEFINE(HAVE_POSIX_TIMERS,1,[Have posix timers])
 403   GST_HAVE_POSIX_TIMERS_DEFINE="#define GST_HAVE_POSIX_TIMERS 1"
 404 else
 405   GST_HAVE_POSIX_TIMERS_DEFINE="#define GST_HAVE_POSIX_TIMERS 0"
 406 fi
 407 AC_SUBST(GST_HAVE_POSIX_TIMERS_DEFINE)
 408 AM_CONDITIONAL(GST_HAVE_POSIX_TIMERS, test "$gst_cv_posix_timers" = "yes")
 409
 410 AC_CACHE_CHECK(for monotonic clock, gst_cv_monotonic_clock,
 411     AC_TRY_COMPILE([
 412 #include <time.h>
 413 #ifdef HAVE_UNISTD_H
 414 #include <unistd.h>
 415 #endif
 416     ], [
 417 #if !defined(_POSIX_MONOTONIC_CLOCK) || _POSIX_MONOTONIC_CLOCK < 0 || !defined(CLOCK_MONOTONIC)
 418 #error Either _POSIX_MONOTONIC_CLOCK or CLOCK_MONOTONIC not defined
 419 #endif
 420       return 0;
 421     ], [
 422       gst_cv_monotonic_clock=yes
 423     ], [
 424       gst_cv_monotonic_clock=no
 425     ])
 426 )
 427
 428 if test "$gst_cv_monotonic_clock" = "yes"; then
 429   AC_DEFINE(HAVE_MONOTONIC_CLOCK,1,[Have a monotonic clock])
 430   GST_HAVE_MONOTONIC_CLOCK_DEFINE="#define GST_HAVE_MONOTONIC_CLOCK 1"
 431 else
 432   GST_HAVE_MONOTONIC_CLOCK_DEFINE="#define GST_HAVE_MONOTONIC_CLOCK 0"
 433 fi
 434 AC_SUBST(GST_HAVE_MONOTONIC_CLOCK_DEFINE)
 435 AM_CONDITIONAL(GST_HAVE_MONOTONIC_CLOCK, test "$gst_cv_monotonic_clock" = "yes")
 436
 437 dnl Check for a way to display the function name in debug output
 438 AG_GST_CHECK_FUNCTION
 439
 440 dnl test for register_printf_function
 441 AC_CHECK_FUNC(register_printf_function,
 442   [
 443     GST_PRINTF_EXTENSION_POINTER_FORMAT_DEFINE="#define GST_PTR_FORMAT \"P\""
 444     GST_PRINTF_EXTENSION_SEGMENT_FORMAT_DEFINE="#define GST_SEGMENT_FORMAT \"Q\""
 445     GST_USING_PRINTF_EXTENSION_DEFINE="#define GST_USING_PRINTF_EXTENSION"
 446     AC_DEFINE(HAVE_PRINTF_EXTENSION, 1,
 447       [Defined if we have register_printf_function ()])
 448   ], [
 449     GST_PRINTF_EXTENSION_POINTER_FORMAT_DEFINE="#define GST_PTR_FORMAT \"p\""
 450     GST_PRINTF_EXTENSION_SEGMENT_FORMAT_DEFINE="#define GST_SEGMENT_FORMAT \"p\""
 451     GST_USING_PRINTF_EXTENSION_DEFINE="#undef GST_USING_PRINTF_EXTENSION"
 452   ]
 453 )
 454 AC_SUBST(GST_PRINTF_EXTENSION_POINTER_FORMAT_DEFINE)
 455 AC_SUBST(GST_PRINTF_EXTENSION_SEGMENT_FORMAT_DEFINE)
 456 AC_SUBST(GST_USING_PRINTF_EXTENSION_DEFINE)
 457
 458 dnl test if we have dladdr(); we use it for debugging; see gst/gstinfo.c
 459 save_cflags="$CFLAGS"
 460 CFLAGS="$CFLAGS -D_GNU_SOURCE"
 461 AC_CHECK_LIB(dl, dladdr,
 462    AC_DEFINE(HAVE_DLADDR, 1, [Defined if we have dladdr ()])
 463    LIBS="$LIBS -ldl")
 464 CFLAGS="$save_cflags"
 465
 466 dnl check for inet_aton()
 467 save_libs="$LIBS"
 468 AC_CHECK_FUNC(inet_aton, ,
 469    AC_CHECK_LIB(nsl, inet_aton, ,
 470       AC_CHECK_LIB(socket, inet_aton, ,
 471          AC_CHECK_LIB(resolv, inet_aton, ,[AC_DEFINE(NO_INET_ATON, 1, [Define if you have no native inet_aton() function.])]))))
 472 INET_ATON_LIBS=$LIBS
 473 AC_SUBST(INET_ATON_LIBS)
 474 LIBS="$save_libs"
 475
 476 dnl *** checks for dependency libraries ***
 477
 478 dnl GLib
 479 GLIB_REQ=2.12
 480
 481 AG_GST_GLIB_CHECK([$GLIB_REQ])
 482
 483 dnl FIXME: 0.11: Guess we need to keep this around until 0.11
 484 GST_HAVE_GLIB_2_8_DEFINE="#define GST_HAVE_GLIB_2_8 1"
 485 AC_SUBST(GST_HAVE_GLIB_2_8_DEFINE)
 486
 487 dnl Check for glib2 without extra fat, useful for the unversioned tool frontends
 488 PKG_CHECK_MODULES(GLIB_ONLY, glib-2.0 >= $GLIB_REQ)
 489
 490 dnl Check for documentation xrefs
 491 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 492 AC_SUBST(GLIB_PREFIX)
 493
 494 dnl libxml 2 is optional in some cases
 495 if test "x$GST_DISABLE_LOADSAVE" = "xyes" && \
 496    ( test "x$GST_DISABLE_REGISTRY" = "xyes" || \
 497    test "x$USE_BINARY_REGISTRY" = "xyes" )
 498 then
 499   AC_MSG_NOTICE([XML registry and load/save are disabled, not checking for libxml2])
 500   GST_DISABLE_XML_DEFINE="#define GST_DISABLE_XML 1"
 501 else
 502   dnl check for libxml2 with minimum req version
 503   AG_GST_LIBXML2_CHECK(2.4.9)
 504   GST_DISABLE_XML_DEFINE="/* #undef GST_DISABLE_XML */"
 505 fi
 506 AC_SUBST(GST_DISABLE_XML_DEFINE)
 507
 508 dnl check for "check", unit testing library/header
 509 AM_PATH_CHECK(0.9.2,
 510     [
 511         HAVE_CHECK=yes
 512         AC_MSG_NOTICE(CHECK_CFLAGS: $CHECK_CFLAGS)
 513         AC_MSG_NOTICE(CHECK_LIBS: $CHECK_LIBS)
 514     ],
 515     HAVE_CHECK=no)
 516 AM_CONDITIONAL(HAVE_CHECK, test "x$HAVE_CHECK" = "xyes")
 517
 518 dnl pkg-config check that for libcheck that works for cross-compiling
 519 dnl but not normal compilation on Fedora & Ubuntu:
 520 dnl PKG_CHECK_MODULES(CHECK, check >= 0.9.2,
 521 dnl   AM_CONDITIONAL(HAVE_CHECK, true),
 522 dnl   AM_CONDITIONAL(HAVE_CHECK, false)
 523 dnl )
 524
 525 dnl *** set variables based on configure arguments
 526
 527 dnl set license and copyright notice
 528 GST_LICENSE="LGPL"
 529 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 530 AC_SUBST(GST_LICENSE)
 531
 532 dnl define LIBDIR, GST_DATADIR so we can inform people where we live
 533 AS_AC_EXPAND(LIBDIR, $libdir)
 534 AC_DEFINE_UNQUOTED(LIBDIR, "$LIBDIR", [library dir])
 535 AS_AC_EXPAND(DATADIR, $datadir)
 536 AC_DEFINE_UNQUOTED(GST_DATADIR, "$DATADIR", [data dir])
 537
 538 dnl set location of plugin directory
 539 AG_GST_SET_PLUGINDIR
 540
 541 dnl FIXME: add LIBXML_PKG here if we use it
 542 GST_PKG_DEPS="glib-2.0, gobject-2.0, gmodule-no-export-2.0, gthread-2.0"
 543 AC_SUBST(GST_PKG_DEPS)
 544
 545 dnl define an ERROR_CFLAGS Makefile variable
 546 AG_GST_SET_ERROR_CFLAGS($GST_CVS)
 547
 548 dnl define correct level for debugging messages
 549 AG_GST_SET_LEVEL_DEFAULT($GST_CVS)
 550
 551 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 552
 553 dnl Overview:
 554 dnl GST_OPTION_CFLAGS:  common cflags for profiling, debugging, errors, ...
 555 dnl GST_ALL_*:          vars shared by all built objects
 556 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 557 dnl GST_OBJ_*:          additional vars to link to the core library
 558 dnl                     include GST_ALL_*
 559 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 560 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 561
 562 dnl GST_OPTION_CFLAGS
 563 if test "x$USE_DEBUG" = xyes; then
 564    PROFILE_CFLAGS="-g"
 565 fi
 566 AC_SUBST(PROFILE_CFLAGS)
 567
 568 # GST_DISABLE_DEPRECATED: hide the visibility of deprecated
 569 # functionality from the API that gstreamer uses
 570 # GST_REMOVE_DEPRECATED: don't compile deprecated functionality (breaks ABI)
 571 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
 572   dnl Define _only_ during CVS (not pre-releases or releases)
 573   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 574 else
 575   DEPRECATED_CFLAGS=""
 576 fi
 577 AC_SUBST(DEPRECATED_CFLAGS)
 578
 579 dnl every flag in GST_OPTION_CFLAGS can be overridden at make time via e.g.
 580 dnl make DEPRECATED_CFLAGS=''
 581 GST_OPTION_CFLAGS="\$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 582 AC_SUBST(GST_OPTION_CFLAGS)
 583
 584 dnl GST_ALL_*
 585 dnl vars common to for all internal objects (core libs, elements, applications)
 586 dnl CFLAGS:
 587 dnl - XML needs to be added because xmlPtr is used in core
 588 dnl - src and build dirs need to be added because every piece that gets built
 589 dnl   will need the GStreamer source and generated headers
 590 dnl LIBS: XML doesn't need to be added because we don't explicitly use symbols
 591 dnl       from LibXML except for in the core library
 592 GST_ALL_CFLAGS="-I\$(top_srcdir)/libs -I\$(top_srcdir) -I\$(top_builddir) $GLIB_CFLAGS $XML_CFLAGS \$(GST_OPTION_CFLAGS)"
 593
 594 dnl FIXME: check if LTLIBINTL is needed everywhere
 595 dnl I presume it is given that it contains the symbols that _() stuff maps to
 596 GST_ALL_LIBS="$GLIB_LIBS $LTLIBINTL \$(GCOV_LIBS)"
 597
 598 dnl LDFLAGS really should only contain flags, not libs - they get added before
 599 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 600 GST_ALL_LDFLAGS="-no-undefined"
 601
 602 AC_SUBST(GST_ALL_CFLAGS)
 603 AC_SUBST(GST_ALL_LIBS)
 604 AC_SUBST(GST_ALL_LDFLAGS)
 605
 606 dnl GST_LIB_LDFLAGS
 607 dnl linker flags shared by all libraries
 608 dnl LDFLAGS modifier defining exported symbols from built libraries
 609 GST_LIB_LDFLAGS="-export-symbols-regex \^[_]*\(gst_\|Gst\|GST_\).*"
 610 AC_SUBST(GST_LIB_LDFLAGS)
 611 dnl Version of the linker flags specifically for libgstcheck to support the boonky extra symbols it exports.
 612 GST_CHECK_LIB_LDFLAGS="-export-symbols-regex \^\([_]*\(gst_\|Gst\|GST_\).*\|check_\(debug\|mutex\|cond\)\|buffers\|mutex\|start_cond\|sync_cond\|thread_list\)$"
 613 dnl HACK: add non-portable --export-dynamic if we have GNU ld (needed on my debian stable, tpm)
 614 if test "x$ac_cv_prog_gnu_ld" = "xyes" -o "x$acl_cv_prog_gnu_ld" = "xyes" ; then
 615   GST_CHECK_LIB_LDFLAGS="-Wl,--export-dynamic $GST_CHECK_LIB_LDFLAGS"
 616 fi
 617 AC_SUBST(GST_CHECK_LIB_LDFLAGS)
 618
 619 dnl GST_OBJ_*
 620 dnl default vars for all internal objects built on libgstreamer
 621 dnl includes GST_ALL_*
 622 GST_OBJ_CFLAGS="\$(GST_ALL_CFLAGS)"
 623 GST_OBJ_LIBS="\$(top_builddir)/gst/libgstreamer-$GST_MAJORMINOR.la \$(GST_ALL_LIBS)"
 624 AC_SUBST(GST_OBJ_CFLAGS)
 625 AC_SUBST(GST_OBJ_LIBS)
 626
 627 dnl GST_PLUGIN_LDFLAGS
 628 dnl LDFLAGS for plugins; includes GST_ALL_LDFLAGS
 629 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc\$\$' $GST_ALL_LDFLAGS"
 630 AC_SUBST(GST_PLUGIN_LDFLAGS, "$GST_PLUGIN_LDFLAGS")
 631
 632 AC_CONFIG_FILES(
 633 Makefile
 634 gst/Makefile
 635 gst/gstconfig.h
 636 gst/gstversion.h
 637 gst/parse/Makefile
 638 libs/Makefile
 639 libs/gst/Makefile
 640 libs/gst/base/Makefile
 641 libs/gst/check/Makefile
 642 libs/gst/controller/Makefile
 643 libs/gst/dataprotocol/Makefile
 644 libs/gst/net/Makefile
 645 plugins/Makefile
 646 plugins/indexers/Makefile
 647 plugins/elements/Makefile
 648 po/Makefile.in
 649 tests/Makefile
 650 tests/benchmarks/Makefile
 651 tests/check/Makefile
 652 tests/misc/Makefile
 653 tests/examples/Makefile
 654 tests/examples/adapter/Makefile
 655 tests/examples/controller/Makefile
 656 tests/examples/helloworld/Makefile
 657 tests/examples/launch/Makefile
 658 tests/examples/manual/Makefile
 659 tests/examples/metadata/Makefile
 660 tests/examples/queue/Makefile
 661 tests/examples/typefind/Makefile
 662 tests/examples/xml/Makefile
 663 tools/Makefile
 664 common/Makefile
 665 common/m4/Makefile
 666 docs/Makefile
 667 docs/design/Makefile
 668 docs/faq/Makefile
 669 docs/gst/Makefile
 670 docs/gst/gstreamer.types
 671 docs/libs/Makefile
 672 docs/plugins/Makefile
 673 docs/manual/Makefile
 674 docs/pwg/Makefile
 675 docs/slides/Makefile
 676 docs/xsl/Makefile
 677 docs/version.entities
 678 win32/common/config.h
 679 pkgconfig/Makefile
 680 stamp.h
 681 pkgconfig/gstreamer.pc
 682 pkgconfig/gstreamer-uninstalled.pc
 683 pkgconfig/gstreamer-base.pc
 684 pkgconfig/gstreamer-base-uninstalled.pc
 685 pkgconfig/gstreamer-check.pc
 686 pkgconfig/gstreamer-check-uninstalled.pc
 687 pkgconfig/gstreamer-controller.pc
 688 pkgconfig/gstreamer-controller-uninstalled.pc
 689 pkgconfig/gstreamer-dataprotocol.pc
 690 pkgconfig/gstreamer-dataprotocol-uninstalled.pc
 691 pkgconfig/gstreamer-net.pc
 692 pkgconfig/gstreamer-net-uninstalled.pc
 693 gst-element-check.m4
 694 gstreamer.spec
 695 )
 696
 697 AC_OUTPUT