configure.ac

   1 dnl autoconf configuration file for gst-plugins
   2 AC_INIT
   3 AC_CANONICAL_TARGET([])
   4
   5 dnl We disable static building for development, for time savings
   6 dnl this goes before AS_LIBTOOL to appease autoconf
   7 dnl *NOTE*: dnl this line before release, so release does static too
   8 AM_DISABLE_STATIC
   9
  10 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  11 AM_MAINTAINER_MODE
  12
  13 dnl when going to/from release please set the nano (fourth number) right !
  14 dnl releases only do Wall, cvs and prerelease does Werror too
  15 AS_VERSION(gst-plugins, GST_PLUGINS_VERSION, 0, 5, 1, 1, GST_ERROR="-Wall", GST_ERROR="-Wall -Werror")
  16 AM_INIT_AUTOMAKE($PACKAGE,$VERSION)
  17
  18 dnl our libraries and install dirs use major.minor as a version
  19 GST_MAJORMINOR=$GST_PLUGINS_VERSION_MAJOR.$GST_PLUGINS_VERSION_MINOR
  20 AC_SUBST(GST_MAJORMINOR)
  21
  22 dnl CURRENT, REVISION, AGE
  23 dnl - library source changed -> increment REVISION
  24 dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
  25 dnl - interfaces added -> increment AGE
  26 dnl - interfaces removed -> AGE = 0
  27 AS_LIBTOOL(GST_PLUGINS, 1, 0, 0)
  28
  29 dnl FIXME take something else ?
  30 AC_CONFIG_SRCDIR([gst/law/alaw.c])
  31 AM_CONFIG_HEADER(config.h)
  32
  33 dnl Add parameters for aclocal
  34 dnl (This must come after AM_INIT_AUTOMAKE, since it modifies ACLOCAL)
  35 ACLOCAL_FLAGS="-I m4 -I common/m4"
  36 AC_SUBST(ACLOCAL_AMFLAGS, $ACLOCAL_FLAGS)
  37
  38 AC_PROG_CC
  39 AM_PROG_CC_STDC
  40 AM_PROG_AS
  41 AS="${CC}"
  42 dnl determine c++ compiler
  43 AC_PROG_CXX
  44 dnl determine if c++ is available on this system
  45 AC_CHECK_PROG(HAVE_CXX, $CXX, yes, no)
  46 dnl determine c++ preprocessor
  47 AC_PROG_CXXCPP
  48 AC_ISC_POSIX
  49
  50 AC_HEADER_STDC([])
  51
  52 dnl ############################################
  53 dnl # Super Duper options for plug-in building #
  54 dnl ############################################
  55
  56 dnl ext plug-ins; plug-ins that have external dependencies
  57 GST_CHECK_FEATURE(EXTERNAL, [enable building of plug-ins with external deps],,
  58 [HAVE_EXTERNAL=yes],enabled,
  59 [
  60   AC_MSG_WARN(building external plug-ins)
  61   BUILD_EXTERNAL="yes"
  62 ],[
  63   AC_MSG_WARN(all plug-ins with external dependencies will not be built)
  64   BUILD_EXTERNAL="no"
  65 ])
  66 # make BUILD_EXTERNAL available to Makefile.am
  67 AM_CONDITIONAL(BUILD_EXTERNAL, test "x$BUILD_EXTERNAL" = "xyes")
  68
  69 dnl experimental plug-ins; stuff that hasn't had the dust settle yet
  70 dnl read 'builds, but might not work'UTO
  71 GST_CHECK_FEATURE(EXPERIMENTAL, [enable building of experimental plug-ins],,
  72 [HAVE_EXPERIMENTAL=yes],disabled,
  73 [
  74   AC_MSG_WARN(building experimental plug-ins)
  75   USE_TARKIN="yes"
  76   USE_RTP="yes"
  77   USE_SHOUT2="yes"
  78 ],[
  79   AC_MSG_NOTICE(not building experimental plug-ins)
  80   USE_TARKIN="no"
  81   USE_RTP="no"
  82   USE_SHOUT2="no"
  83 ])
  84
  85 dnl broken plug-ins; stuff that doesn't seem to build at the moment
  86 GST_CHECK_FEATURE(BROKEN, [enable building of broken plug-ins],,
  87 HAVE_BROKEN=yes,disabled,
  88 [
  89   AC_MSG_WARN([building broken plug-ins -- no bug reports on these, only patches :)])
  90   USE_SMOOTHWAVE="yes"
  91   USE_VGA="yes"
  92   USE_XMMS="yes"
  93 ],[
  94   USE_SMOOTHWAVE="no"
  95   USE_VGA="no"
  96   USE_XMMS="no"
  97   AC_MSG_NOTICE([not building broken plug-ins])
  98 ])
  99
 100 dnl ##############################
 101 dnl # Do automated configuration #
 102 dnl ##############################
 103
 104 dnl Check for tools:
 105 dnl ================
 106
 107 dnl allow for different autotools
 108 AS_AUTOTOOLS_ALTERNATE()
 109
 110 dnl modify pkg-config path
 111 AC_ARG_WITH(pkg-config-path,
 112    AC_HELP_STRING([--with-pkg-config-path],[colon-separated list of pkg-config(1) dirs]),
 113    [export PKG_CONFIG_PATH=${withval}])
 114
 115 dnl Check for nasm
 116 AC_PATH_PROG(NASM_PATH, nasm, no)
 117 AC_SUBST(NASM_PATH)
 118 if test x$NASM_PATH = xno; then
 119   AC_MSG_WARN(Couldn't find nasm)
 120   HAVE_NASM="no"
 121 else
 122   AC_DEFINE(HAVE_NASM, 1, [Define if NASM, the netwide assembler, is available])
 123   HAVE_NASM="yes"
 124 fi
 125
 126 dnl check for gconftool-2
 127 translit(dnm, m, l) AM_CONDITIONAL(USE_GCONFTOOL, true)
 128 GST_CHECK_FEATURE(GCONFTOOL, [GConf schemas], , [
 129   AC_PATH_PROG(GCONFTOOL, gconftool-2, no)
 130   if test x$GCONFTOOL = xno; then
 131     AC_MSG_WARN(Not installing GConf schemas)
 132     HAVE_GCONFTOOL="no"
 133   else
 134     AM_GCONF_SOURCE_2
 135     HAVE_GCONFTOOL="yes"
 136   fi
 137   AC_SUBST(HAVE_GCONFTOOL)
 138 ])
 139
 140 dnl check for GConf libraries
 141 translit(dnm, m, l) AM_CONDITIONAL(USE_GCONF, true)
 142 GST_CHECK_FEATURE(GCONF, [GConf libraries], , [
 143   PKG_CHECK_MODULES(GCONF, gconf-2.0, HAVE_GCONF="yes", HAVE_GCONF="no")
 144   AC_SUBST(GCONF_CFLAGS)
 145   AC_SUBST(GCONF_LIBS)
 146 ])
 147
 148 dnl check for gstreamer; uninstalled is selected preferentially -- see pkg-config(1)
 149 PKG_CHECK_MODULES(GST, gstreamer-$GST_MAJORMINOR >= $GST_PLUGINS_VERSION_MAJOR.$GST_PLUGINS_VERSION_MINOR.$GST_PLUGINS_VERSION_MICRO,
 150   HAVE_GST="yes", HAVE_GST="no")
 151
 152 if test "x$HAVE_GST" = "xno"; then
 153   AC_MSG_ERROR(no GStreamer found)
 154 fi
 155
 156 GST_TOOLS_DIR=`pkg-config --variable=toolsdir gstreamer-$GST_MAJORMINOR`
 157 if test -z $GST_TOOLS_DIR; then
 158   AC_MSG_ERROR([no tools dir defined in GStreamer pkg-config file; core upgrade needed.])
 159 fi
 160 AC_SUBST(GST_TOOLS_DIR)
 161
 162 dnl additional gstcontrol libs
 163 GST_CONTROL_LIBS=`pkg-config --variable=gstcontrol_libs gstreamer-$GST_MAJORMINOR`
 164 AC_SUBST(GST_CONTROL_LIBS)
 165
 166 dnl Set up conditionals for (target) architecture:
 167 dnl ==============================================
 168
 169 dnl Determine CPU
 170 case "x${target_cpu}" in
 171   xi?86 | k?) HAVE_CPU_I386=yes
 172               AC_DEFINE(HAVE_CPU_I386, 1, [Define if the target CPU is an x86])
 173               dnl FIXME could use some better detection
 174               dnl       (ie CPUID)
 175               case "x${target_cpu}" in
 176                 xi386 | xi486) ;;
 177                 *)             AC_DEFINE(HAVE_RDTSC, 1, [Define if RDTSC is available]) ;;
 178               esac ;;
 179   xpowerpc)   HAVE_CPU_PPC=yes
 180               AC_DEFINE(HAVE_CPU_PPC, 1, [Define if the target CPU is a PPC]) ;;
 181   xalpha)     HAVE_CPU_ALPHA=yes
 182               AC_DEFINE(HAVE_CPU_ALPHA, 1, [Define if the target CPU is an Alpha]) ;;
 183   xarm*)      HAVE_CPU_ARM=yes
 184               AC_DEFINE(HAVE_CPU_ARM, 1, [Define if the target CPU is an ARM]) ;;
 185   xsparc*)    HAVE_CPU_SPARC=yes
 186               AC_DEFINE(HAVE_CPU_SPARC, 1, [Define if the target CPU is a PPC]) ;;
 187   xmips*)     HAVE_CPU_MIPS=yes
 188               AC_DEFINE(HAVE_CPU_MIPS, 1, [Define if the target CPU is a MIPS]) ;;
 189   xhppa*)     HAVE_CPU_HPPA=yes
 190               AC_DEFINE(HAVE_CPU_HPPA, 1, [Define if the target CPU is a HPPA]) ;;
 191 esac
 192
 193 dnl Determine endianness
 194 AC_C_BIGENDIAN
 195
 196 dnl Check for fast float to int casting as defined in C99
 197 AC_C99_FUNC_LRINT()
 198 AC_C99_FUNC_LRINTF()
 199
 200 dnl Check for essential libraries first:
 201 dnl ====================================
 202
 203 GST_GLIB2_CHECK()
 204 PKG_CHECK_MODULES(GTK2, gtk+-2.0, HAVE_GTK=yes, HAVE_GTK=no)
 205 GTK_CFLAGS=$GTK2_CFLAGS
 206 GTK_LIBS=$GTK2_LIBS
 207 AC_SUBST(GTK_LIBS)
 208 AC_SUBST(GTK_CFLAGS)
 209
 210
 211 dnl Check for X11 extensions
 212 AC_PATH_XTRA
 213 if test "-DX_DISPLAY_MISSING" = "$X_CFLAGS"; then
 214   AC_MSG_NOTICE([cannot find X11, the build system needs fixage])
 215 fi
 216 AC_SUBST(X_CFLAGS)
 217 AC_SUBST(X_PRE_LIBS)
 218 AC_SUBST(X_EXTRA_LIBS)
 219 AC_SUBST(X_LIBS)
 220
 221 dnl ===========================================================================
 222 dnl ============================= gst plug-ins ================================
 223 dnl ===========================================================================
 224
 225 GST_PLUGIN_LDFLAGS='-module -avoid-version'
 226 AC_SUBST(GST_PLUGIN_LDFLAGS)
 227
 228 dnl these are all the gst plug-ins, compilable without additional libs
 229 GST_PLUGINS_ALL="\
 230         ac3parse adder audioscale auparse avi cdxaparse chart\
 231         cutter deinterlace effectv festival filter flx goom\
 232         intfloat law level\
 233         median mixmatrix mpeg1enc mpeg1sys mpeg1videoparse mpeg2enc mpeg2sub\
 234         mpegaudio mpegaudioparse mpegstream mpegtypes\
 235         monoscope oneton passthrough playondemand qtdemux rtjpeg silence sine\
 236         smooth smpte spectrum speed stereo stereomono synaesthesia\
 237         udp vbidec videocrop videoscale videotestsrc volenv volume\
 238         vumeter wavenc wavparse y4m"
 239
 240 dnl see if we can build C++ plug-ins
 241 if test "x$HAVE_CXX" = "xyes"; then
 242   GST_PLUGINS_ALL="$GST_PLUGINS_ALL \
 243                   modplug"
 244 else
 245   AC_MSG_WARN([Not compiling plug-ins requiring C++ compiler])
 246 fi
 247
 248 AC_SUBST(GST_PLUGINS_ALL)
 249
 250 GST_PLUGINS_SELECTED=""
 251
 252 AC_ARG_WITH(plugins,
 253     AC_HELP_STRING([--with-plugins],[comma-separated list of plug-ins to compile]),
 254     [for i in `echo $withval | tr , ' '`; do
 255         if test -n `echo $i | grep $GST_PLUGINS_ALL`; then
 256             GST_PLUGINS_SELECTED="$GST_PLUGINS_SELECTED $i"
 257         else
 258             echo "plug-in $i not recognized, ignoring..."
 259         fi
 260     done],
 261     [GST_PLUGINS_SELECTED=$GST_PLUGINS_ALL])
 262
 263 AC_SUBST(GST_PLUGINS_SELECTED)
 264
 265 dnl ==========================================================================
 266 dnl ============================= sys plug-ins ================================
 267 dnl ==========================================================================
 268
 269 dnl *** DXR3 card ***
 270 translit(dnm, m, l) AM_CONDITIONAL(USE_DXR3, true)
 271 GST_CHECK_FEATURE(DXR3, [DXR3 hardware mpeg video decoder], dxr3videosink, [
 272   AC_CHECK_HEADER(linux/em8300.h, HAVE_DXR3="yes", HAVE_DXR3="no")
 273 ])
 274
 275 dnl *** OSS audio ***
 276 translit(dnm, m, l) AM_CONDITIONAL(USE_OSS, true)
 277 GST_CHECK_FEATURE(OSS, [OSS audio], osssrc osssink, [
 278   AC_CHECK_HEADER(sys/soundcard.h, HAVE_OSS="yes", HAVE_OSS="no")
 279 ])
 280
 281 dnl *** QuickCam ***
 282 translit(dnm, m, l) AM_CONDITIONAL(USE_QCAM, true)
 283 GST_CHECK_FEATURE(QCAM, [QuickCam], qcamsrc, [
 284 dnl this one is for hadess, no qcam when no nasm found
 285   if test "x$HAVE_NASM" = "xno";
 286   then
 287     HAVE_QCAM="no"
 288     AC_MSG_WARN([QuickCam needs nasm])
 289   else
 290     HAVE_QCAM="yes"
 291   fi
 292 ])
 293
 294 dnl *** Video 4 Linux ***
 295 translit(dnm, m, l) AM_CONDITIONAL(USE_V4L, true)
 296 GST_CHECK_FEATURE(V4L, [Video 4 Linux], v4lsrc v4lmjpegsrc v4lmjpegsink, [
 297   AC_CHECK_DECL(VID_TYPE_MPEG_ENCODER, HAVE_V4L="yes", HAVE_V4L="no", [#include <linux/videodev.h>])
 298 ])
 299
 300 dnl *** Video 4 Linux 2***
 301 translit(dnm, m, l) AM_CONDITIONAL(USE_V4L2, true)
 302 GST_CHECK_FEATURE(V4L2, [Video 4 Linux 2], v4l2src, [
 303   AC_CHECK_HEADER(linux/videodev2.h, HAVE_V4L2="yes", HAVE_V4L2="no")
 304 ])
 305
 306 dnl *** Video CD ***
 307 translit(dnm, m, l) AM_CONDITIONAL(USE_VCD, true)
 308 GST_CHECK_FEATURE(VCD, [Video CD], vcdsrc, [
 309   AC_CHECK_HEADER(linux/cdrom.h, HAVE_VCD="yes", HAVE_VCD="no")
 310 ])
 311
 312 dnl *** VGA ***
 313 translit(dnm, m, l) AM_CONDITIONAL(USE_VGA, true)
 314 GST_CHECK_FEATURE(VGA, [VGA], vgavideosink, [
 315   AC_CHECK_HEADER(asm/vga.h, HAVE_VGA="yes", HAVE_VGA="no")
 316 ])
 317
 318 dnl *** CDROM Audio ***
 319 translit(dnm, m, l) AM_CONDITIONAL(USE_CDROM, true)
 320 GST_CHECK_FEATURE(CDROM, [CDROM Audio], cdrom, [
 321   AC_CHECK_HEADERS(linux/cdrom.h) dnl linux
 322   AC_CHECK_HEADERS(sys/cdio.h) dnl almost everything else
 323 dnl  AC_CHECK_HEADERS(dmedia/cdaudio.h) dnl irix
 324
 325   if test "${ac_cv_header_linux_cdrom_h}" = "yes" || test "${ac_cv_header_sys_cdio_h}" = "yes" || test "${ac_cv_header_dmedia_cdaudio_h}" = "yes"; then
 326         case "$host" in
 327                 *-sun-* | *-*-linux*)
 328                         AC_DEFINE(HAVE_CDROM_SOLARIS,, [Define if cdrom access is in Solaris style])
 329                 ;;
 330                 *-*-freebsd*)
 331                         AC_DEFINE(HAVE_CDROM_BSD,, [Define if cdrom access is in BSD style])
 332                 ;;
 333                 *-*-netbsd* | *-*-openbsd*)
 334                         AC_DEFINE(HAVE_CDROM_BSD,, [Define if cdrom access is in BSD style])
 335                         AC_DEFINE(HAVE_CDROM_BSD_NETBSD,, [Define if cdrom access uses NetBSD variant])
 336                 ;;
 337                 *-*darwin*)
 338                         AC_DEFINE(HAVE_CDROM_BSD,, [Define if cdrom access is in BSD style])
 339                         AC_DEFINE(HAVE_CDROM_BSD_DARWIN,, [Define if cdrom access uses Darwin variant])
 340                 ;;
 341 dnl             *-irix-*)
 342 dnl                     AC_DEFINE(HAVE_CDROM_IRIX,, [Define if cdrom access is in Irix DMedia style])
 343 dnl             ;;
 344     esac
 345
 346         HAVE_CDROM="yes"
 347   else
 348         HAVE_CDROM="no"
 349   fi
 350 ])
 351
 352 dnl *** XVideo ***
 353 dnl Look for the PIC library first, Debian requires it.
 354 dnl Check debian-devel archives for gory details.
 355 dnl 20020110:
 356 dnl At the moment XFree86 doesn't distribute shared libXv due
 357 dnl to unstable API.  On many platforms you CAN NOT link a shared
 358 dnl lib to a static non-PIC lib.  This is what the xvideo GStreamer
 359 dnl plug-in wants to do.  So Debian distributes a PIC compiled
 360 dnl version of the static lib for plug-ins to link to when it is
 361 dnl inappropriate to link the main application to libXv directly.
 362 dnl FIXME: add check if this platform can support linking to a
 363 dnl        non-PIC libXv, if not then don not use Xv.
 364 dnl FIXME: perhaps warn user if they have a shared libXv since
 365 dnl        this is an error until XFree86 starts shipping one
 366 translit(dnm, m, l) AM_CONDITIONAL(USE_XVIDEO, true)
 367 GST_CHECK_FEATURE(XVIDEO, [X11 XVideo extensions], xvideosink videosink, [
 368   dnl check for PIC static lib
 369   GST_CHECK_LIBHEADER(XVIDEO, Xv_pic, XvQueryExtension, $X_LIBS $X_PRE_LIBS -lXext -lX11 $X_EXTRA_LIBS, X11/extensions/Xvlib.h, XVIDEO_LIBS="-lXv_pic -lXext")
 370   if test x$HAVE_XVIDEO = xno; then
 371     dnl PIC lib not found, check for regular lib
 372     GST_CHECK_LIBHEADER(XVIDEO, Xv, XvQueryExtension, $X_LIBS $X_PRE_LIBS -lXext -lX11 $X_EXTRA_LIBS, X11/extensions/Xvlib.h, XVIDEO_LIBS="-lXv -lXext")
 373   fi
 374   AC_SUBST(XVIDEO_LIBS)
 375 ])
 376
 377 dnl Next, check for the optional libraries:
 378 dnl These are all libraries used in building plug-ins
 379 dnl ================================================
 380 dnl let's try and sort them alphabetically, shall we ?
 381
 382 if test "x$BUILD_EXTERNAL" = "xyes"; then
 383
 384 AC_MSG_NOTICE(Checking for plug-in dependency libraries)
 385
 386 dnl *** a52dec ***
 387 translit(dnm, m, l) AM_CONDITIONAL(USE_A52DEC, true)
 388 GST_CHECK_FEATURE(A52DEC, [a52dec], a52dec, [
 389   AC_CHECK_A52DEC(HAVE_A52DEC=yes, HAVE_A52DEC=no)
 390 ])
 391
 392 dnl *** aalib ***
 393 translit(dnm, m, l) AM_CONDITIONAL(USE_AALIB, true)
 394 GST_CHECK_FEATURE(AALIB, [aasink plug-in], aasink, [
 395   AM_PATH_AALIB(, HAVE_AALIB=yes, HAVE_AALIB=no)
 396   AS_SCRUB_INCLUDE(AALIB_CFLAGS)
 397 ])
 398
 399 dnl *** alsa ***
 400 translit(dnm, m, l) AM_CONDITIONAL(USE_ALSA, true)
 401 GST_CHECK_FEATURE(ALSA, [alsa plug-ins], gstalsa, [
 402    AM_PATH_ALSA(0.9.0, HAVE_ALSA=yes, HAVE_ALSA=no)
 403 ])
 404
 405 dnl *** arts ***
 406 dnl if mcopidl can't be found there's no use in compiling it
 407 AC_CHECK_PROG(MCOPIDL, mcopidl, yes, no)
 408 if test "xHAVE_MCOPIDL" = "xno";
 409 then
 410   USE_ARTS=no
 411 fi
 412
 413 translit(dnm, m, l) AM_CONDITIONAL(USE_ARTS, true)
 414 GST_CHECK_FEATURE(ARTS, [arts plug-ins], arts, [
 415   AM_PATH_ARTS(, HAVE_ARTS=yes, HAVE_ARTS=no)
 416 ])
 417
 418 dnl *** artsc ***
 419 translit(dnm, m, l) AM_CONDITIONAL(USE_ARTSC, true)
 420 GST_CHECK_FEATURE(ARTSC, [artsd plug-ins], artsdsink, [
 421   GST_CHECK_ARTSC()
 422 ])
 423
 424 dnl *** audiofile ***
 425 dnl this check uses the GST_CHECK_CONFIGPROG macro
 426 translit(dnm, m, l) AM_CONDITIONAL(USE_AUDIOFILE, true)
 427 GST_CHECK_FEATURE(AUDIOFILE, [audiofile], afsink afsrc, [
 428   translit(dnm, m, l) AC_SUBST(AUDIOFILE_LIBS)
 429   translit(dnm, m, l) AC_SUBST(AUDIOFILE_CFLAGS)
 430   GST_CHECK_CONFIGPROG(AUDIOFILE, audiofile-config)
 431   dnl we need this function
 432   AC_CHECK_LIB(audiofile, afOpenVirtualFile, , HAVE_AUDIOFILE="no")
 433 ])
 434
 435 dnl *** avifile ***
 436 translit(dnm, m, l) AM_CONDITIONAL(USE_AVIFILE, true)
 437 GST_CHECK_FEATURE(AVIFILE, [avifile], winenc windec, [
 438   if test "x$no_x" = "xyes"; then
 439     AC_MSG_WARN([No X libraries found, avifile test might fail compilation])
 440   fi
 441   if test "x$HAVE_CXX" != "xyes"; then
 442     AC_MSG_WARN([No C++ compiler found, avifile test will fail compilation])
 443   fi
 444   AS_AVIFILE(0.7.0)
 445 ])
 446
 447 dnl *** CDParanoia ***
 448 translit(dnm, m, l) AM_CONDITIONAL(USE_CDPARANOIA, true)
 449 GST_CHECK_FEATURE(CDPARANOIA, [CDParanoia], cdparanoia, [
 450   GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 451                       cdda_open, -lm,
 452                       cdda_interface.h,
 453                       CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 454                       HEADER_DIR="no"
 455                       FOUND_CDPARANOIA="yes")
 456   if test "x$FOUND_CDPARANOIA" != "xyes";
 457   then
 458     GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 459                         cdda_open, -lm,
 460                         cdda/cdda_interface.h,
 461                         CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 462                         HEADER_DIR="yes"
 463                         FOUND_CDPARANOIA="yes")
 464   fi
 465   if test "x$HEADER_DIR" = "xyes";
 466   then
 467     AC_DEFINE_UNQUOTED(CDPARANOIA_HEADERS_IN_DIR, ,
 468                        defined if cdda headers are in a cdda/ directory)
 469   fi
 470   AC_SUBST(CDPARANOIA_LIBS)
 471 ])
 472 dnl FIXME : add second check somehow if that is necessary
 473 dnl AC_CHECK_LIB(cdda_paranoia, paranoia_init, : , HAVE_CDPARANOIA=no, -lcdda_interface )
 474 dnl AC_CHECK_HEADER(cdda_paranoia.h, :, HAVE_CDPARANOIA=no)
 475
 476 dnl *** dvdread ***
 477 translit(dnm, m, l) AM_CONDITIONAL(USE_DVDREAD, true)
 478 GST_CHECK_FEATURE(DVDREAD, [dvdread library], dvdreadsrc, [
 479   GST_CHECK_LIBHEADER(DVDREAD, dvdread, DVDOpen, , dvdread/dvd_reader.h, DVDREAD_LIBS="-ldvdread")
 480   AC_SUBST(DVDREAD_LIBS)
 481 ])
 482
 483 dnl *** dvdnav ***
 484 translit(dnm, m, l) AM_CONDITIONAL(USE_DVDNAV, true)
 485 GST_CHECK_FEATURE(DVDNAV, [dvdnav library], dvdnavsrc, [
 486   translit(dnm, m, l) AC_SUBST(DVDNAV_LIBS)
 487   translit(dnm, m, l) AC_SUBST(DVDNAV_CFLAGS)
 488   GST_CHECK_CONFIGPROG(DVDNAV, dvdnav-config)
 489   AS_SCRUB_INCLUDE(DVDNAV_CFLAGS)
 490 ])
 491
 492 dnl **** ESound ****
 493 translit(dnm, m, l) AM_CONDITIONAL(USE_ESD, true)
 494 GST_CHECK_FEATURE(ESD, [esound plug-ins], esdsink esdmon, [
 495   AM_PATH_ESD(0.2.12, HAVE_ESD=yes, HAVE_ESD=no)
 496   AS_SCRUB_INCLUDE(ESD_CFLAGS)
 497 ])
 498
 499 dnl **** festival ****
 500 dnl translit(dnm, m, l) AM_CONDITIONAL(USE_FESTIVAL, true)
 501 dnl GST_CHECK_FEATURE(FESTIVAL, [festival plug-ins], festivalsrc, [
 502   dnl NOTE: just using local net connection now, add this lib check
 503   dnl       in the future if needed
 504   dnl AC_LANG_PUSH(C++)
 505   dnl dnl FIXME: took out func to check for
 506   dnl dnl This check puts festival_tidy_up in extern "C".
 507   dnl dnl But, at least on Debian as of 20020110, it is compiled with name
 508   dnl dnl mangling C++ nonsense and symbols can't resolve
 509   dnl dnl GST_CHECK_LIBHEADER(FESTIVAL, Festival, festival_tidy_up, , festival/festival.h, FESTIVAL_LIBS="-lFestival")
 510   dnl GST_CHECK_LIBHEADER(FESTIVAL, Festival, , , festival/festival.h, FESTIVAL_LIBS="-lFestival")
 511   dnl AC_LANG_POP(C++)
 512   dnl AC_SUBST(FESTIVAL_LIBS)
 513 dnl  HAVE_FESTIVAL=yes
 514 dnl])
 515
 516 dnl *** FLAC ***
 517 translit(dnm, m, l) AM_CONDITIONAL(USE_FLAC, true)
 518 GST_CHECK_FEATURE(FLAC, [FLAC lossless audio], flacenc flacdec, [
 519   GST_CHECK_LIBHEADER(FLAC, FLAC, FLAC__stream_decoder_new, -lm, FLAC/all.h, FLAC_LIBS="-lFLAC")
 520   AC_SUBST(FLAC_LIBS)
 521 ])
 522
 523 dnl *** FFMPEG ***
 524 translit(dnm, m, l) AM_CONDITIONAL(USE_FFMPEG, true)
 525 GST_CHECK_FEATURE(FFMPEG, [ffmpeg plug-ins], ffmpeg, [
 526   # only slurp in the case where we are in CVS mode;
 527   # prerelease and release should get it disted
 528   if test "x$GST_PLUGINS_VERSION_NANO" = x1; then
 529     AC_MSG_NOTICE(slurping FFmpeg CVS source)
 530     AS_SLURP_FFMPEG(gst-libs/ext/ffmpeg, 2002-12-14 12:00 GMT,
 531                     HAVE_FFMPEG=yes, HAVE_FFMPEG=no)
 532   else
 533     AC_MSG_NOTICE(FFmpeg CVS code should be included already)
 534     HAVE_FFMPEG=yes
 535   fi
 536   # we only bother with uninstalled (included) ffmpeg for now
 537   AC_DEFINE_UNQUOTED(HAVE_FFMPEG_UNINSTALLED, 1,
 538                      [defined if we use uninstalled ffmpeg])
 539 ])
 540
 541 dnl *** Gnome VFS ***
 542 translit(dnm, m, l) AM_CONDITIONAL(USE_GNOME_VFS, true)
 543 GST_CHECK_FEATURE(GNOME_VFS, [Gnome VFS], gnomevfssrc, [
 544   PKG_CHECK_MODULES(GNOME_VFS, gnome-vfs-2.0, HAVE_GNOME_VFS="yes", HAVE_GNOME_VFS="no")
 545   AC_SUBST(GNOME_VFS_CFLAGS)
 546   AC_SUBST(GNOME_VFS_LIBS)
 547 ])
 548
 549 dnl *** gsm ***
 550 translit(dnm, m, l) AM_CONDITIONAL(USE_GSM, true)
 551 GST_CHECK_FEATURE(GSM, [GSM library], gsmenc gsmdec, [
 552   GST_CHECK_LIBHEADER(GSM, gsm, gsm_create, , gsm.h, GSM_LIBS="-lgsm")
 553   if test $HAVE_GSM != "yes"; then
 554     GST_CHECK_LIBHEADER(GSM, gsm, gsm_create, , gsm/gsm.h, GSM_LIBS="-lgsm")
 555     if test $HAVE_GSM = "yes"; then
 556       AC_DEFINE(GSM_HEADER_IN_SUBDIR, 1, [Define if GSM header in gsm/ subdir])
 557     fi
 558   fi
 559   AC_SUBST(GSM_LIBS)
 560 ])
 561
 562 dnl *** Hermes ***
 563 translit(dnm, m, l) AM_CONDITIONAL(USE_HERMES, true)
 564 GST_CHECK_FEATURE(HERMES, [Hermes library], colorspace, [
 565   GST_CHECK_LIBHEADER(HERMES, Hermes, Hermes_ConverterInstance, , Hermes/Hermes.h, HERMES_LIBS="-lHermes")
 566 ], AC_SUBST(HERMES_LIBS))
 567
 568 dnl *** http ***
 569 translit(dnm, m, l) AM_CONDITIONAL(USE_HTTP, true)
 570 GST_CHECK_FEATURE(HTTP, [http plug-ins], gsthttpsrc, [
 571   dnl FIXME: need to check for header
 572   GHTTP_LIBS=
 573   GST_HTTPSRC_GET_TYPE=
 574   if test x$USE_GLIB2 = xyes; then
 575     AC_MSG_WARN(ghttp disabled for glib2.0)
 576   else
 577     AC_CHECK_LIB(ghttp, ghttp_request_new,
 578       [HTTP_LIBS="-lghttp"
 579        GST_HTTPSRC_GET_TYPE="gst_httpsrc_get_type"
 580        HAVE_HTTP=yes
 581       ], :, $LIBS)
 582   fi
 583   AC_SUBST(HTTP_LIBS)
 584   AC_SUBST(GST_HTTPSRC_GET_TYPE)
 585 ])
 586
 587 dnl *** Jack ***
 588 translit(dnm, m, l) AM_CONDITIONAL(USE_JACK, true)
 589 GST_CHECK_FEATURE(JACK, Jack, jack, [
 590   PKG_CHECK_MODULES(JACK, jack >= 0.29.0, HAVE_JACK="yes", HAVE_JACK="no")
 591   AC_SUBST(JACK_CFLAGS)
 592   AC_SUBST(JACK_LIBS)
 593 ])
 594
 595 dnl *** jpeg ***
 596 dnl FIXME: we could use header checks here as well IMO
 597 translit(dnm, m, l) AM_CONDITIONAL(USE_JPEG, true)
 598 GST_CHECK_FEATURE(JPEG, [jpeg], jpegenc jpegdec, [
 599   AC_CHECK_LIB(jpeg, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
 600   JPEG_LIBS="-ljpeg"
 601   AC_SUBST(JPEG_LIBS)
 602 ])
 603
 604 dnl *** ladspa ***
 605 translit(dnm, m, l) AM_CONDITIONAL(USE_LADSPA, true)
 606 GST_CHECK_FEATURE(LADSPA, [ladspa], ladspa, [
 607   AC_CHECK_HEADER(ladspa.h, HAVE_LADSPA="yes", HAVE_LADSPA="no")
 608 ])
 609
 610 dnl *** lame ***
 611 translit(dnm, m, l) AM_CONDITIONAL(USE_LAME, true)
 612 GST_CHECK_FEATURE(LAME, [lame mp3 encoder library], lame, [
 613   GST_CHECK_LIBHEADER(LAME, mp3lame, lame_init, -lm, lame/lame.h, HAVE_LAME="yes" LAME_LIBS="-lmp3lame")
 614 ])
 615 AC_SUBST(LAME_LIBS)
 616
 617 dnl *** libcolorspace ***
 618 translit(dnm, m, l) AM_CONDITIONAL(USE_LCS, true)
 619 GST_CHECK_FEATURE(LCS, Lcs, lcs, [
 620   PKG_CHECK_MODULES(LCS, lcs, HAVE_LCS="yes", HAVE_LCS="no")
 621   AC_SUBST(LCS_CFLAGS)
 622   AC_SUBST(LCS_LIBS)
 623 ])
 624
 625 dnl *** libdv ***
 626 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBDV, true)
 627 GST_CHECK_FEATURE(LIBDV, [libdv DV/video decoder], dvdec, [
 628   PKG_CHECK_MODULES(LIBDV, libdv >= 0.98, HAVE_LIBDV="yes", HAVE_LIBDV="no")
 629   AC_SUBST(LIBDV_CFLAGS)
 630   AC_SUBST(LIBDV_LIBS)
 631 ])
 632
 633 dnl *** libfame ***
 634 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBFAME, true)
 635 GST_CHECK_FEATURE(LIBFAME, [libfame MPEG1/4 encoder], libfame, [
 636   AM_PATH_LIBFAME(0.9.0, HAVE_LIBFAME="yes", HAVE_LIBFAME="no")
 637   AC_SUBST(LIBFAME_CFLAGS)
 638   AC_SUBST(LIBFAME_LIBS)
 639 ])
 640
 641 dnl *** libpng ***
 642 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBPNG, true)
 643 GST_CHECK_FEATURE(LIBPNG, [libpng PNG encoder], pngenc, [
 644   PKG_CHECK_MODULES(LIBPNG, libpng12, HAVE_LIBPNG="yes", HAVE_LIBPNG="no")
 645   AC_SUBST(LIBPNG_CFLAGS)
 646   AC_SUBST(LIBPNG_LIBS)
 647 ])
 648
 649
 650 dnl *** mad ***
 651 dnl FIXME: we could use header checks here as well IMO
 652 translit(dnm, m, l) AM_CONDITIONAL(USE_MAD, true)
 653 GST_CHECK_FEATURE(MAD, [mad mp3 decoder], mad, [
 654   AC_CHECK_LIB(mad, mad_decoder_finish, HAVE_MAD="yes" MAD_LIBS="-lmad")
 655   if test "x$HAVE_MAD" = "xyes"; then
 656     # installed with mad >= 0.14
 657     HAVE_MAD="no"
 658     save_libs=$LIBS
 659     LIBS="-lz"
 660     AC_CHECK_LIB(id3tag, id3_tag_query, HAVE_MAD="yes" MAD_LIBS="$MAD_LIBS -lid3tag")
 661     LIBS=$save_LIBS
 662   fi
 663 ])
 664 AC_SUBST(MAD_LIBS)
 665
 666 dnl *** mikmod ***
 667 translit(dnm, m, l) AM_CONDITIONAL(USE_MIKMOD, true)
 668 GST_CHECK_FEATURE(MIKMOD, [mikmod plug-in], mikmod, [
 669   AM_PATH_LIBMIKMOD(, HAVE_MIKMOD=yes, HAVE_MIKMOD=no)
 670   AC_SUBST(MIKMOD_LIBS, "$LIBMIKMOD_LIBS")
 671   AC_SUBST(MIKMOD_CFLAGS, "$LIBMIKMODCFLAGS")
 672 ])
 673
 674 dnl *** mjpegtools ***
 675 translit(dnm, m, l) AM_CONDITIONAL(USE_MJPEGTOOLS, true)
 676 GST_CHECK_FEATURE(MJPEGTOOLS, [mjpegtools], jpegmmxenc jpegmmxdec, [
 677   PKG_CHECK_MODULES(MJPEGTOOLS, mjpegtools, HAVE_MJPEGTOOLS="yes", HAVE_MJPEGTOOLS="no")
 678
 679   if [ test x$HAVE_MJPEGTOOLS = x"yes" ]; then
 680     dnl some headers we might want to need
 681     AC_CHECK_HEADERS(stdint.h, HAVE_STDINT_H="yes", HAVE_STDINT_H="no")
 682     if [ test x$HAVE_STDINT_H = x"no" ]; then
 683       AC_CHECK_HEADERS(inttypes.h sys/types.h, HAVE_INTTYPES_H="yes", [
 684         AC_MSG_WARN(No valid header files found, mjpegtools plugins disabled)
 685         HAVE_INTTYPES_H="no" HAVE_MJPEGTOOLS="no"
 686       ])
 687     fi
 688     AC_CHECK_HEADERS(stdbool.h, HAVE_STDBOOL_H="yes", HAVE_STDBOOL_H="no")
 689
 690     dnl sizeof PRId64 etc...
 691     AC_CHECK_SIZEOF(int)
 692     AC_CHECK_SIZEOF(long)
 693     AC_CHECK_SIZEOF(long long)
 694     case 8 in
 695     $ac_cv_sizeof_int)
 696       PRID64_STRING_FORMAT="d"
 697       ;;
 698     $ac_cv_sizeof_long)
 699       PRID64_STRING_FORMAT="ld"
 700       ;;
 701     $ac_cv_sizeof_long_long)
 702       PRID64_STRING_FORMAT="lld"
 703       ;;
 704     *)
 705       AC_MSG_WARN(No suitable variant for 64bits integers found, mjpegtools plugins disabled)
 706       HAVE_MJPEGTOOLS="no"
 707       ;;
 708     esac
 709
 710     AC_DEFINE_UNQUOTED(PRID64_STRING_FORMAT, "$PRID64_STRING_FORMAT",
 711       [ A printf type definition for 64 bit integers ])
 712     AC_SUBST(MJPEGTOOLS_LIBS)
 713     AC_SUBST(MJPEGTOOLS_CFLAGS)
 714   fi
 715 ])
 716
 717 dnl *** mpeg2dec ***
 718 translit(dnm, m, l) AM_CONDITIONAL(USE_MPEG2DEC, true)
 719 GST_CHECK_FEATURE(MPEG2DEC, [mpeg2dec], mpeg2dec, [
 720   PKG_CHECK_MODULES(MPEG2DEC, libmpeg2 >= 0.3.1,
 721       HAVE_MPEG2DEC="yes", HAVE_MPEG2DEC="no")
 722   AC_SUBST(MPEG2DEC_CFLAGS)
 723   AC_SUBST(MPEG2DEC_LIBS)
 724 ])
 725
 726 dnl *** openquicktime ***
 727 translit(dnm, m, l) AM_CONDITIONAL(USE_OPENQUICKTIME, true)
 728 GST_CHECK_FEATURE(OPENQUICKTIME, [Open Quicktime], quicktime_parser quicktime_decoder quicktime_demux,[
 729   GST_CHECK_LIBHEADER(OPENQUICKTIME, openquicktime, quicktime_init,, openquicktime/openquicktime.h, OPENQUICKTIME_LIBS="-lopenquicktime")
 730   AC_SUBST(OPENQUICKTIME_LIBS)
 731 ])
 732
 733 dnl *** raw1394 ***
 734 translit(dnm, m, l) AM_CONDITIONAL(USE_RAW1394, true)
 735 GST_CHECK_FEATURE(RAW1394, [raw1394 library], dv1394src, [
 736   GST_CHECK_LIBHEADER(RAW1394, raw1394, raw1394_new_handle,, libraw1394/raw1394.h, RAW1394_LIBS="-lraw1394")
 737   AC_SUBST(RAW1394_LIBS)
 738 ])
 739
 740 dnl *** rtp ***
 741 dnl FIXME : adapt and make it work
 742 translit(dnm, m, l) AM_CONDITIONAL(USE_RTP, true)
 743 GST_CHECK_FEATURE(RTP, [RTP library], rtpenc rtpdec,[
 744   AC_CHECK_LIB(ortp, ortp_init, HAVE_RTP=yes, HAVE_RTP=no, $GST_CFLAGS $GST_LIBS)
 745   RTP_LIBS="-lortp"
 746   AC_SUBST(RTP_LIBS)
 747 ])
 748
 749 dnl FIXME header check needs to use GLIB_CFLAGS in order to succeed for rtp
 750 dnl can use GST_* which should have GLIB_* info
 751 dnl AC_CHECK_HEADERS(rtp/rtp.h, HAVE_LIBRTP=yes, HAVE_LIBRTP=no)
 752 dnl AC_CHECK_HEADERS(rtp/rtp-packet.h, :, HAVE_LIBRTP=no)
 753 dnl AC_CHECK_HEADERS(rtp/rtcp-packet.h, :, HAVE_LIBRTP=no)
 754 dnl AC_CHECK_HEADERS(rtp/rtp-audio.h, :, HAVE_LIBRTP=no)
 755
 756 dnl *** SDL ***
 757 translit(dnm, m, l) AM_CONDITIONAL(USE_SDL, true)
 758 GST_CHECK_FEATURE(SDL, [SDL plug-in], sdlvideosink, [
 759  AM_PATH_SDL(, HAVE_SDL=yes, HAVE_SDL=no)
 760 ])
 761
 762 dnl *** shout ***
 763 translit(dnm, m, l) AM_CONDITIONAL(USE_SHOUT, true)
 764 GST_CHECK_FEATURE(SHOUT, [shout plug-in], icecastsend, [
 765   GST_CHECK_LIBHEADER(SHOUT, shout, shout_init_connection,, shout/shout.h, SHOUT_LIBS="-lshout")
 766   AC_SUBST(SHOUT_LIBS)
 767 ])
 768
 769 dnl *** shout2 ***
 770 translit(dnm, m, l) AM_CONDITIONAL(USE_SHOUT2, true)
 771 GST_CHECK_FEATURE(SHOUT2, [shout2 plug-in], shout2send, [
 772   AM_PATH_SHOUT2(HAVE_SHOUT2=yes, HAVE_SHOUT2=no)
 773   AC_SUBST(SHOUT2_CFLAGS)
 774   AC_SUBST(SHOUT2_LIBS)
 775 ])
 776
 777 dnl *** sidplay ***
 778 translit(dnm, m, l) AM_CONDITIONAL(USE_SIDPLAY, true)
 779 GST_CHECK_FEATURE(SIDPLAY, [sidplay plug-in], sidplay, [
 780   GST_PATH_SIDPLAY()
 781 ])
 782
 783 dnl *** smoothwave ***
 784 translit(dnm, m, l) AM_CONDITIONAL(USE_SMOOTHWAVE, true)
 785 GST_CHECK_FEATURE(SMOOTHWAVE, [smoothwave plug-in], smoothwave, [
 786   if test $HAVE_GTK = "yes"; then HAVE_SMOOTHWAVE=yes; fi;
 787 ])
 788
 789
 790 dnl *** snapshot ***
 791 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBPNG, true)
 792 GST_CHECK_FEATURE(LIBPNG, [snapshot plug-in], snapshot, [
 793   GST_CHECK_LIBHEADER(LIBPNG, png, png_read_info, -lz -lm, png.h, LIBPNG_LIBS="-lpng -lz -lm")
 794   AC_SUBST(LIBPNG_LIBS)
 795 ])
 796
 797 dnl *** swfdec ***
 798 translit(dnm, m, l) AM_CONDITIONAL(USE_SWFDEC, true)
 799 GST_CHECK_FEATURE(SWFDEC, [swfdec plug-in], swfdec, [
 800   PKG_CHECK_MODULES(SWFDEC, swfdec >= 0.1.3.1, HAVE_SWFDEC=yes, HAVE_SWFDEC=no)
 801   AC_SUBST(SWFDEC_CFLAGS)
 802   AC_SUBST(SWFDEC_LIBS)
 803 ])
 804
 805 dnl *** tarkin ***
 806 dnl for now the sources are included in the plug-in
 807 dnl and should be moved to ext-libs/ perhaps
 808 translit(dnm, m, l) AM_CONDITIONAL(USE_TARKIN, true)
 809 GST_CHECK_FEATURE(TARKIN, [tarkinenc tarkindec], tarkin, [
 810   HAVE_TARKIN="yes"
 811 ])
 812
 813 dnl *** vorbis ***
 814 dnl AM_PATH_VORBIS only takes two options
 815 translit(dnm, m, l) AM_CONDITIONAL(USE_VORBIS, true)
 816 GST_CHECK_FEATURE(VORBIS, [vorbis plug-in], vorbisenc vorbisdec, [
 817   XIPH_PATH_VORBIS(HAVE_VORBIS=yes, HAVE_VORBIS=no)
 818   AS_SCRUB_INCLUDE(VORBIS_CFLAGS)
 819 ])
 820
 821 dnl *** XMMS ***
 822 translit(dnm, m, l) AM_CONDITIONAL(USE_XMMS, true)
 823 GST_CHECK_FEATURE(XMMS, [xmms plug-in], xmms, [
 824   AM_PATH_XMMS(0.1.0, HAVE_XMMS=yes, HAVE_XMMS=no)
 825 ])
 826
 827 fi dnl of EXT plugins
 828
 829 dnl Check for atomic.h
 830 dnl Note: use AC_CHECK_HEADER not AC_CHECK_HEADERS, because the latter
 831 dnl defines the wrong default symbol as well (HAVE_ASM_ATOMIC_H)
 832 AC_CHECK_HEADER(asm/atomic.h, HAVE_ATOMIC_H=yes, HAVE_ATOMIC_H=no)
 833 dnl Do a compile to check that it has atomic_set (eg, linux 2.0 didn't)
 834 if test x$HAVE_ATOMIC_H = xyes; then
 835   AC_TRY_RUN([
 836 #include "asm/atomic.h"
 837 main() { atomic_t t; atomic_set(&t,0); atomic_inc(&t); atomic_add(1,&t);return 0;}
 838   ],, [
 839     # Not successful
 840     if test x$HAVE_ATOMIC_H = xyes; then
 841       AC_MSG_WARN(Atomic reference counting is out of date: doing without.)
 842     fi
 843     HAVE_ATOMIC_H=no
 844   ], [
 845     # Cross compiling
 846     AC_MSG_RESULT(yes)
 847     AC_MSG_WARN(Can't check properly for atomic reference counting.  Assuming OK.)
 848   ])
 849 fi
 850
 851
 852 dnl ######################################################################
 853 dnl # Check command line parameters, and set shell variables accordingly #
 854 dnl ######################################################################
 855
 856 GST_DEBUGINFO
 857
 858 AC_ARG_ENABLE(libmmx,
 859   AC_HELP_STRING([--enable-libmmx],[use libmmx, if available]),
 860 [case "${enableval}" in
 861   yes) USE_LIBMMX=$HAVE_LIBMMX ;;
 862   no)  USE_LIBMMX=no ;;
 863   *) AC_MSG_ERROR(bad value ${enableval} for --enable-libmmx) ;;
 864 esac],
 865 [USE_LIBMMX=$HAVE_LIBMMX]) dnl Default value
 866
 867 AC_ARG_ENABLE(atomic,
 868   AC_HELP_STRING([--enable-atomic],[use atomic reference counting header]),
 869 [case "${enableval}" in
 870   yes) USE_ATOMIC_H=$HAVE_ATOMIC_H;;
 871   noset) USE_ATOMIC_H=$HAVE_ATOMIC_H;;
 872   no)  USE_ATOMIC_H=no;;
 873   *) AC_MSG_ERROR(bad value ${enableval} for --enable-atomic) ;;
 874 esac],
 875 [USE_ATOMIC_H=$HAVE_ATOMIC_H]) dnl Default value
 876
 877 AC_ARG_ENABLE(profiling,
 878   AC_HELP_STRING([--enable-profiling],
 879                  [-pg to compiler commandline, for profiling]),
 880 [case "${enableval}" in
 881   yes) USE_PROFILING=yes ;;
 882   no)  UES_PROFILING=no ;;
 883   *) AC_MSG_ERROR(bad value ${enableval} for --enable-profiling) ;;
 884 esac],
 885 [USE_PROFILING=no]) dnl Default value
 886
 887 AC_ARG_ENABLE(tests,
 888   AC_HELP_STRING([--disable-tests],[disable building test apps]),
 889 [case "${enableval}" in
 890   yes) BUILD_TESTS=yes ;;
 891   no)  BUILD_TESTS=no ;;
 892   *) AC_MSG_ERROR(bad value ${enableval} for --disable-tests) ;;
 893 esac],
 894 [BUILD_TESTS=yes]) dnl Default value
 895
 896 AC_ARG_ENABLE(examples,
 897   AC_HELP_STRING([--disable-examples],[disable building examples]),
 898 [case "${enableval}" in
 899   yes) BUILD_EXAMPLES=yes ;;
 900   no)  BUILD_EXAMPLES=no ;;
 901   *) AC_MSG_ERROR(bad value ${enableval} for --disable-examples) ;;
 902 esac],
 903 [BUILD_EXAMPLES=yes]) dnl Default value
 904
 905 dnl seeking needs freetype, so check for it here
 906 AC_CHECK_FT2(2.0.9,HAVE_FT2=yes,HAVE_FT2=no)
 907 dnl make the HAVE_FT2 variable available to automake and Makefile.am
 908 AM_CONDITIONAL(HAVE_FT2, test "x$HAVE_FT2" = "xyes")
 909 AC_SUBST(FT2_CFLAGS)
 910 AC_SUBST(FT2_LIBS)
 911
 912 dnl ################################################
 913 dnl # Set defines according to variables set above #
 914 dnl ################################################
 915
 916
 917 if test "x$USE_LIBMMX" = xyes; then
 918   AC_DEFINE(HAVE_LIBMMX, 1, [Define if libmmx is available])
 919 fi
 920
 921 if test "x$USE_ATOMIC_H" = xyes; then
 922   AC_DEFINE(HAVE_ATOMIC_H, 1, [Define if atomic.h header file is available])
 923 fi
 924
 925 # do not use deprecated stuff
 926 GST_CFLAGS="$GST_CFLAGS -DGST_DISABLE_DEPRECATED"
 927
 928 if test "x$USE_DEBUG" = xyes; then
 929   GST_CFLAGS="$GST_CFLAGS -g"
 930 fi
 931
 932 if test "x$USE_PROFILING" = xyes; then
 933 dnl  CFLAGS="$CFLAGS -pg -fprofile-arcs"
 934   FOMIT_FRAME_POINTER=""
 935 else
 936   FOMIT_FRAME_POINTER="-fomit-frame-pointer"
 937 fi
 938
 939 dnl
 940 dnl AC_SUBST(FOMIT_FRAME_POINTER)
 941 dnl
 942
 943 dnl #############################
 944 dnl # Set automake conditionals #
 945 dnl #############################
 946
 947 dnl These should be "USE_*" instead of "HAVE_*", but some packages expect
 948 dnl HAVE_ and it is likely to be easier to stick with the old name
 949 AM_CONDITIONAL(HAVE_CPU_I386,       test "x$HAVE_CPU_I386" = "xyes")
 950 AM_CONDITIONAL(HAVE_CPU_PPC,        test "x$HAVE_CPU_PPC" = "xyes")
 951 AM_CONDITIONAL(HAVE_CPU_ALPHA,      test "x$HAVE_CPU_ALPHA" = "xyes")
 952 AM_CONDITIONAL(HAVE_CPU_ARM,        test "x$HAVE_CPU_ARM" = "xyes")
 953 AM_CONDITIONAL(HAVE_CPU_SPARC,      test "x$HAVE_CPU_SPARC" = "xyes")
 954 AM_CONDITIONAL(HAVE_LIBMMX,         test "x$USE_LIBMMX" = "xyes")
 955
 956 AM_CONDITIONAL(HAVE_ATOMIC_H,       test "x$USE_ATOMIC_H" = "xyes")
 957
 958 AM_CONDITIONAL(EXPERIMENTAL,        test "$EXPERIMENTAL" = "$xyes")
 959 AM_CONDITIONAL(BROKEN,              test "$BROKEN" = "$xyes")
 960
 961 AM_CONDITIONAL(HAVE_NASM,           test "x$HAVE_NASM" = "xyes")
 962 AM_CONDITIONAL(HAVE_GTK,            test "x$HAVE_GTK" = "xyes")
 963 AM_CONDITIONAL(HAVE_GTK_DOC,        $HAVE_GTK_DOC)
 964 AM_CONDITIONAL(BUILD_DOCS,          test "x$BUILD_DOCS" = "xyes")
 965 AM_CONDITIONAL(BUILD_TESTS,         test "x$BUILD_TESTS" = "xyes")
 966 AM_CONDITIONAL(BUILD_EXAMPLES,      test "x$BUILD_EXAMPLES" = "xyes")
 967 AM_CONDITIONAL(BUILD_PLUGIN_DOCS,   test "x$BUILD_PLUGIN_DOCS" = "xyes")
 968 AM_CONDITIONAL(HAVE_FIG2DEV_PNG,    $HAVE_FIG2DEV_PNG)
 969 AM_CONDITIONAL(HAVE_FIG2DEV_PDF,    $HAVE_FIG2DEV_PDF)
 970 AM_CONDITIONAL(HAVE_RAW1394,        test "x$HAVE_RAW1394" = "xyes")
 971
 972 dnl prefer internal headers to already installed ones
 973 GST_CFLAGS="-I\$(top_srcdir)/gst-libs $GST_CFLAGS $GST_ERROR"
 974
 975 AC_SUBST(GST_LIBS)
 976 AC_SUBST(GST_CFLAGS)
 977
 978 dnl ###########################
 979 dnl # Configure external libs #
 980 dnl ###########################
 981 if test "x$HAVE_FFMPEG" = xyes; then
 982   AC_CONFIG_SUBDIRS(gst-libs/ext/ffmpeg/ffmpeg)
 983 fi
 984
 985 dnl #########################
 986 dnl # Make the output files #
 987 dnl #########################
 988
 989 AC_CONFIG_FILES(
 990 Makefile
 991 gstreamer-libs.pc
 992 gstreamer-libs-uninstalled.pc
 993 gstreamer-play.pc
 994 gstreamer-play-uninstalled.pc
 995 gst-plugins.spec
 996 gst/Makefile
 997 gst/ac3parse/Makefile
 998 gst/adder/Makefile
 999 gst/audioscale/Makefile
1000 gst/auparse/Makefile
1001 gst/avi/Makefile
1002 gst/cdxaparse/Makefile
1003 gst/chart/Makefile
1004 gst/cutter/Makefile
1005 gst/deinterlace/Makefile
1006 gst/effectv/Makefile
1007 gst/festival/Makefile
1008 gst/filter/Makefile
1009 gst/flx/Makefile
1010 gst/goom/Makefile
1011 gst/intfloat/Makefile
1012 gst/law/Makefile
1013 gst/level/Makefile
1014 gst/median/Makefile
1015 gst/mixmatrix/Makefile
1016 gst/mpeg1enc/Makefile
1017 gst/mpeg1sys/Makefile
1018 gst/mpeg1videoparse/Makefile
1019 gst/mpeg2enc/Makefile
1020 gst/mpeg2sub/Makefile
1021 gst/mpegaudio/Makefile
1022 gst/mpegaudioparse/Makefile
1023 gst/mpegstream/Makefile
1024 gst/mpegtypes/Makefile
1025 gst/modplug/Makefile
1026 gst/modplug/libmodplug/Makefile
1027 gst/monoscope/Makefile
1028 gst/oneton/Makefile
1029 gst/passthrough/Makefile
1030 gst/playondemand/Makefile
1031 gst/qtdemux/Makefile
1032 gst/rtjpeg/Makefile
1033 gst/silence/Makefile
1034 gst/sine/Makefile
1035 gst/smooth/Makefile
1036 gst/smpte/Makefile
1037 gst/spectrum/Makefile
1038 gst/speed/Makefile
1039 gst/stereo/Makefile
1040 gst/stereomono/Makefile
1041 gst/synaesthesia/Makefile
1042 gst/udp/Makefile
1043 gst/vbidec/Makefile
1044 gst/videoscale/Makefile
1045 gst/videotestsrc/Makefile
1046 gst/videocrop/Makefile
1047 gst/volenv/Makefile
1048 gst/volume/Makefile
1049 gst/vumeter/Makefile
1050 gst/wavenc/Makefile
1051 gst/wavparse/Makefile
1052 gst/y4m/Makefile
1053 sys/Makefile
1054 sys/cdrom/Makefile
1055 sys/dxr3/Makefile
1056 sys/oss/Makefile
1057 sys/qcam/Makefile
1058 sys/v4l/Makefile
1059 sys/v4l2/Makefile
1060 sys/vcd/Makefile
1061 sys/vga/Makefile
1062 sys/xvideo/Makefile
1063 sys/videosink/Makefile
1064 ext/Makefile
1065 ext/a52dec/Makefile
1066 ext/aalib/Makefile
1067 ext/alsa/Makefile
1068 ext/arts/Makefile
1069 ext/artsd/Makefile
1070 ext/audiofile/Makefile
1071 ext/avifile/Makefile
1072 ext/cdparanoia/Makefile
1073 ext/dv/Makefile
1074 ext/dvdread/Makefile
1075 ext/dvdnav/Makefile
1076 ext/esd/Makefile
1077 ext/ffmpeg/Makefile
1078 ext/flac/Makefile
1079 ext/gnomevfs/Makefile
1080 ext/gsm/Makefile
1081 ext/hermes/Makefile
1082 ext/http/Makefile
1083 ext/jack/Makefile
1084 ext/jpeg/Makefile
1085 ext/ladspa/Makefile
1086 ext/lame/Makefile
1087 ext/lcs/Makefile
1088 ext/libfame/Makefile
1089 ext/libpng/Makefile
1090 ext/mad/Makefile
1091 ext/mikmod/Makefile
1092 ext/mjpegtools/Makefile
1093 ext/mpeg2dec/Makefile
1094 ext/openquicktime/Makefile
1095 ext/raw1394/Makefile
1096 ext/rtp/Makefile
1097 ext/sdl/Makefile
1098 ext/shout/Makefile
1099 ext/shout2/Makefile
1100 ext/sidplay/Makefile
1101 ext/smoothwave/Makefile
1102 ext/snapshot/Makefile
1103 ext/swfdec/Makefile
1104 ext/vorbis/Makefile
1105 ext/tarkin/Makefile
1106 ext/xmms/Makefile
1107 gst-libs/Makefile
1108 gst-libs/gst/Makefile
1109 gst-libs/gst/audio/Makefile
1110 gst-libs/gst/floatcast/Makefile
1111 gst-libs/gst/gconf/Makefile
1112 gst-libs/gst/idct/Makefile
1113 gst-libs/gst/media-info/Makefile
1114 gst-libs/gst/play/Makefile
1115 gst-libs/gst/resample/Makefile
1116 gst-libs/gst/riff/Makefile
1117 gst-libs/gst/video/Makefile
1118 gst-libs/ext/Makefile
1119 gst-libs/ext/ffmpeg/Makefile
1120 examples/dynparams/Makefile
1121 examples/capsfilter/Makefile
1122 examples/seeking/Makefile
1123 examples/indexing/Makefile
1124 examples/Makefile
1125 testsuite/autoplug/Makefile
1126 testsuite/spider/Makefile
1127 testsuite/Makefile
1128 tools/Makefile
1129 gconf/Makefile
1130 )
1131 AC_OUTPUT
1132
1133 echo -e "configure: *** Plug-ins that will be built : $GST_PLUGINS_YES"
1134 echo
1135 echo -e "configure: *** Plug-ins that will not be built : $GST_PLUGINS_NO"
1136 echo
1137 if test "x$BUILD_EXTERNAL" = "xno"; then
1138   echo "configure: *** No external plug-ins will be built"
1139 fi