configure.ac

   1 AC_PREREQ(2.60)
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, cvs and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for cvs/prerelease
   8 AC_INIT(GStreamer Ugly Plug-ins, 0.11.2.1,
   9     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
  10     gst-plugins-ugly)
  11
  12 AG_GST_INIT
  13
  14 dnl initialize automake
  15 AM_INIT_AUTOMAKE([-Wno-portability 1.10])
  16
  17 dnl define PACKAGE_VERSION_* variables
  18 AS_VERSION
  19
  20 dnl check if this is a release version
  21 AS_NANO(GST_GIT="no", GST_GIT="yes")
  22
  23 dnl can autoconf find the source ?
  24 AC_CONFIG_SRCDIR([ext/mad/gstmad.c])
  25
  26 dnl define the output header for config
  27 AM_CONFIG_HEADER(config.h)
  28
  29 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  30 AM_MAINTAINER_MODE
  31
  32 dnl sets host_* variables
  33 AC_CANONICAL_HOST
  34
  35 dnl use pretty build output with automake >= 1.11
  36 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],
  37   [AM_DEFAULT_VERBOSITY=1
  38    AC_SUBST(AM_DEFAULT_VERBOSITY)])
  39
  40 dnl our libraries and install dirs use major.minor as a version
  41 GST_MAJORMINOR=$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR
  42 dnl we override it here if we need to for the release candidate of new series
  43 GST_MAJORMINOR=0.11
  44 AC_SUBST(GST_MAJORMINOR)
  45
  46 dnl FIXME: this macro doesn't actually work;
  47 dnl the generated libtool script has no support for the listed tags.
  48 dnl So this needs to be fixed first if we want to use this
  49 dnl AS_LIBTOOL_TAGS([CXX])
  50
  51 AC_LIBTOOL_WIN32_DLL
  52 AM_PROG_LIBTOOL
  53
  54 dnl *** required versions of GStreamer stuff ***
  55 GST_REQ=0.11.3
  56 GSTPB_REQ=0.11.3
  57
  58 dnl *** autotools stuff ****
  59
  60 dnl allow for different autotools
  61 AS_AUTOTOOLS_ALTERNATE
  62
  63 dnl Add parameters for aclocal
  64 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  65
  66 dnl set up gettext
  67 dnl the version check needs to stay here because autopoint greps for it
  68 AM_GNU_GETTEXT_VERSION(0.17)
  69 AM_GNU_GETTEXT([external])
  70 AG_GST_GETTEXT([gst-plugins-ugly-$GST_MAJORMINOR])
  71
  72 dnl *** check for arguments to configure ***
  73
  74 AG_GST_ARG_DISABLE_FATAL_WARNINGS
  75
  76 AG_GST_ARG_DEBUG
  77 AG_GST_ARG_PROFILING
  78 AG_GST_ARG_VALGRIND
  79 AG_GST_ARG_GCOV
  80
  81 AG_GST_ARG_EXAMPLES
  82
  83 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  84 AG_GST_ARG_WITH_PACKAGE_NAME
  85 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  86
  87 AG_GST_ARG_WITH_PLUGINS
  88
  89 AG_GST_ARG_ENABLE_EXTERNAL
  90
  91 AG_GST_ARG_ENABLE_EXPERIMENTAL
  92
  93 dnl *** checks for platform ***
  94
  95 dnl * hardware/architecture *
  96
  97 dnl common/m4/gst-arch.m4
  98 dnl check CPU type
  99 AG_GST_ARCH
 100
 101 dnl Determine endianness
 102 AC_C_BIGENDIAN
 103
 104 dnl *** checks for programs ***
 105
 106 dnl find a compiler
 107 AC_PROG_CC
 108 AC_PROG_CC_STDC
 109
 110 dnl determine c++ compiler
 111 AC_PROG_CXX
 112 dnl determine if c++ is available on this system
 113 AC_CHECK_PROG(HAVE_CXX, $CXX, yes, no)
 114
 115 dnl check if the compiler supports '-c' and '-o' options
 116 AM_PROG_CC_C_O
 117
 118 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 119 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 120
 121 dnl check if the compiler supports do while(0) macros
 122 AG_GST_CHECK_DOWHILE_MACROS
 123
 124 dnl check for documentation tools
 125 GTK_DOC_CHECK([1.3])
 126 AS_PATH_PYTHON([2.1])
 127 AG_GST_PLUGIN_DOCS([1.3],[2.1])
 128
 129 dnl *** checks for libraries ***
 130
 131 dnl check for libm, for sin()
 132 AC_CHECK_LIBM
 133 AC_SUBST(LIBM)
 134
 135 dnl *** checks for header files ***
 136
 137 dnl used by ext/a52dec
 138 AX_CREATE_STDINT_H
 139
 140 dnl Check for malloc.h
 141 AC_CHECK_HEADERS([malloc.h])
 142
 143 dnl *** checks for types/defines ***
 144
 145 dnl *** checks for structures ***
 146
 147 dnl *** checks for compiler characteristics ***
 148
 149 dnl *** checks for library functions ***
 150
 151 dnl Check for a way to display the function name in debug output
 152 AG_GST_CHECK_FUNCTION
 153
 154 dnl *** checks for dependency libraries ***
 155
 156 dnl GLib is required
 157 GLIB_REQ=2.31.14
 158 AG_GST_GLIB_CHECK([$GLIB_REQ])
 159
 160 ORC_CHECK([0.4.6])
 161
 162 dnl checks for gstreamer
 163 dnl uninstalled is selected preferentially -- see pkg-config(1)
 164 AG_GST_CHECK_GST($GST_MAJORMINOR, [$GST_REQ], yes)
 165 AG_GST_CHECK_GST_BASE($GST_MAJORMINOR, [$GST_REQ], yes)
 166 AG_GST_CHECK_GST_CHECK($GST_MAJORMINOR, [$GST_REQ], no)
 167 AG_GST_CHECK_GST_PLUGINS_BASE($GST_MAJORMINOR, [$GSTPB_REQ], yes)
 168 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 169
 170 dnl Check for documentation xrefs
 171 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 172 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_MAJORMINOR`"
 173 GSTPB_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-plugins-base-$GST_MAJORMINOR`"
 174 AC_SUBST(GLIB_PREFIX)
 175 AC_SUBST(GST_PREFIX)
 176 AC_SUBST(GSTPB_PREFIX)
 177
 178 dnl *** set variables based on configure arguments ***
 179
 180 dnl set license and copyright notice
 181 GST_LICENSE="LGPL"
 182 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 183 AC_SUBST(GST_LICENSE)
 184
 185 dnl set location of plugin directory
 186 AG_GST_SET_PLUGINDIR
 187
 188 dnl set release date/time
 189 AG_GST_SET_PACKAGE_RELEASE_DATETIME_WITH_NANO([$PACKAGE_VERSION_NANO],
 190   ["${srcdir}/gst-plugins-ugly.doap"],
 191   [$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_MICRO])
 192
 193 dnl define an ERROR_CFLAGS Makefile variable
 194 AG_GST_SET_ERROR_CFLAGS($FATAL_WARNINGS, [
 195     -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls
 196     -Wwrite-strings -Wformat-nonliteral -Wformat-security -Wold-style-definition
 197     -Winit-self -Wmissing-include-dirs -Waddress
 198     -Waggregate-return -Wno-multichar -Wnested-externs ])
 199
 200 dnl define an ERROR_CXXFLAGS Makefile variable
 201 AG_GST_SET_ERROR_CXXFLAGS($FATAL_WARNINGS, [
 202     -Wmissing-declarations -Wredundant-decls
 203     -Wwrite-strings -Wformat-nonliteral -Wformat-security
 204     -Winit-self -Wmissing-include-dirs -Waddress -Waggregate-return
 205     -Wno-multichar])
 206
 207 dnl define correct level for debugging messages
 208 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 209
 210 dnl used in examples
 211 AG_GST_DEFAULT_ELEMENTS
 212
 213 dnl *** plug-ins to include ***
 214
 215 dnl Non ported plugins (non-dependant, then dependant)
 216 dnl Make sure you have a space before and after all plugins
 217 GST_PLUGINS_NONPORTED=" "
 218 AC_SUBST(GST_PLUGINS_NONPORTED)
 219
 220 dnl these are all the gst plug-ins, compilable without additional libs
 221 AG_GST_CHECK_PLUGIN(asfdemux)
 222 AG_GST_CHECK_PLUGIN(dvdlpcmdec)
 223 AG_GST_CHECK_PLUGIN(dvdsub)
 224 AG_GST_CHECK_PLUGIN(xingmux)
 225 AG_GST_CHECK_PLUGIN(realmedia)
 226 AG_GST_CHECK_PLUGIN(synaesthesia)
 227
 228 AC_CHECK_HEADERS([winsock2.h], HAVE_WINSOCK2_H=yes)
 229
 230 if test "x$HAVE_WINSOCK2_H" = "xyes"; then
 231   WIN32_LIBS="-lws2_32"
 232   AC_SUBST(WIN32_LIBS)
 233 fi
 234
 235 dnl disable experimental plug-ins
 236 if test "x$BUILD_EXPERIMENTAL" != "xyes"; then
 237   AG_GST_DISABLE_PLUGIN(synaesthesia)
 238 fi
 239
 240 dnl *** ext plug-ins ***
 241 dnl keep this list sorted alphabetically !
 242
 243 if test "x$BUILD_EXTERNAL" = "xyes"; then
 244
 245 echo
 246 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 247 echo
 248
 249 dnl *** a52dec ***
 250 translit(dnm, m, l) AM_CONDITIONAL(USE_A52DEC, true)
 251 AG_GST_CHECK_FEATURE(A52DEC, [a52dec], a52dec, [
 252   AC_CHECK_A52DEC(HAVE_A52DEC=yes, HAVE_A52DEC=no)
 253 ])
 254
 255 dnl *** amr-nb ***
 256 translit(dnm, m, l) AM_CONDITIONAL(USE_AMRNB, true)
 257 AG_GST_CHECK_FEATURE(AMRNB, [amrnb library], amrnb, [
 258   PKG_CHECK_MODULES(AMRNB, opencore-amrnb, [
 259     if $PKG_CONFIG --atleast-version=0.1.3 opencore-amrnb; then
 260       AC_DEFINE(HAVE_OPENCORE_AMRNB_0_1_3_OR_LATER, 1, [Defined for newer opencore-amrnb])
 261     fi
 262     HAVE_AMRNB="yes"
 263   ], [
 264     HAVE_AMRNB="no"
 265   ])
 266   AC_SUBST(AMRNB_CFLAGS)
 267   AC_SUBST(AMRNB_LIBS)
 268 ])
 269
 270 dnl *** amr-wb dec ***
 271 translit(dnm, m, l) AM_CONDITIONAL(USE_AMRWB, true)
 272 AG_GST_CHECK_FEATURE(AMRWB, [amrwb library], amrwbdec, [
 273   PKG_CHECK_MODULES(AMRWB, opencore-amrwb, [
 274     if $PKG_CONFIG --atleast-version=0.1.3 opencore-amrwb; then
 275       AC_DEFINE(HAVE_OPENCORE_AMRWB_0_1_3_OR_LATER, 1, [Defined for newer opencore-amrwb])
 276     fi
 277     HAVE_AMRWB="yes"
 278   ], [
 279     HAVE_AMRWB="no"
 280   ])
 281   AC_SUBST(AMRWB_CFLAGS)
 282   AC_SUBST(AMRWB_LIBS)
 283 ])
 284
 285 dnl *** cdio ***
 286 translit(dnm, m, l) AM_CONDITIONAL(USE_CDIO, true)
 287 AG_GST_CHECK_FEATURE(CDIO, [cdio library], cdio, [
 288   AG_GST_PKG_CHECK_MODULES(CDIO, libcdio >= 0.76)
 289 ])
 290
 291 dnl *** dvdread ***
 292 translit(dnm, m, l) AM_CONDITIONAL(USE_DVDREAD, true)
 293 AG_GST_CHECK_FEATURE(DVDREAD, [dvdread library], dvdreadsrc, [
 294   AG_GST_CHECK_LIBHEADER(DVDREAD, dvdread, DVDOpen, , dvdread/dvd_reader.h, DVDREAD_LIBS="-ldvdread")
 295   AC_SUBST(DVDREAD_LIBS)
 296 ])
 297
 298 dnl *** lame ***
 299 translit(dnm, m, l) AM_CONDITIONAL(USE_LAME, true)
 300 AG_GST_CHECK_FEATURE(LAME, [lame mp3 encoder library], lame, [
 301   AG_GST_CHECK_LIBHEADER(LAME, mp3lame, lame_init, $LIBM, lame/lame.h,
 302   [
 303     HAVE_LAME="yes"
 304     LAME_LIBS="-lmp3lame $LIBM"
 305     dnl is lame presets available
 306     LAME_CFLAGS=""
 307     AC_TRY_COMPILE([#include <lame/lame.h>], [ int preset = MEDIUM ],
 308       [LAME_CFLAGS="-DGSTLAME_PRESET"],
 309       [LAME_CFLAGS=""]
 310     )
 311     AC_TRY_COMPILE([#include <lame/lame.h>], [
 312         void *ptr = &lame_set_VBR_quality
 313       ],
 314       [LAME_CFLAGS="$LAME_CFLAGS -DHAVE_LAME_SET_VBR_QUALITY"],
 315       [LAME_CFLAGS="$LAME_CFLAGS"]
 316     )
 317   AC_SUBST(LAME_CFLAGS)
 318   AC_SUBST(LAME_LIBS)
 319   ])
 320 ])
 321
 322 dnl *** mad ***
 323 translit(dnm, m, l) AM_CONDITIONAL(USE_MAD, true)
 324 AG_GST_CHECK_FEATURE(MAD, [mad mp3 decoder], mad, [
 325
 326   dnl check with pkg-config first
 327   AG_GST_PKG_CHECK_MODULES(MAD, mad >= 0.15)
 328   MAD_LIBS="$MAD_LIBS"
 329   if test "x$HAVE_MAD" = "xno"; then
 330     dnl fall back to oldskool detection
 331     AC_CHECK_HEADER(mad.h, [
 332       AC_CHECK_LIB(mad, mad_decoder_finish,
 333         HAVE_MAD="yes" MAD_LIBS="-lmad")
 334     ])
 335   fi
 336 ])
 337 AC_SUBST(MAD_LIBS)
 338
 339 dnl *** mpeg2dec ***
 340 translit(dnm, m, l) AM_CONDITIONAL(USE_MPEG2DEC, true)
 341 AG_GST_CHECK_FEATURE(MPEG2DEC, [mpeg2dec], mpeg2dec, [
 342   AG_GST_PKG_CHECK_MODULES(MPEG2DEC, libmpeg2 >= 0.4.0)
 343 ])
 344
 345 dnl *** sidplay : works with libsidplay 1.36.x (not 2.x.x) ***
 346 translit(dnm, m, l) AM_CONDITIONAL(USE_SIDPLAY, true)
 347 AG_GST_CHECK_FEATURE(SIDPLAY, [libsidplay], sid, [
 348   GST_PATH_SIDPLAY()
 349 ])
 350
 351 dnl *** twolame ***
 352 translit(dnm, m, l) AM_CONDITIONAL(USE_TWOLAME, true)
 353 AG_GST_CHECK_FEATURE(TWOLAME, [twolame], twolame, [
 354   PKG_CHECK_MODULES(TWOLAME, twolame >= 0.3.10, [
 355       HAVE_TWOLAME="yes"], [
 356       HAVE_TWOLAME="no"
 357   ])
 358   AC_SUBST(TWOLAME_CFLAGS)
 359   AC_SUBST(TWOLAME_LIBS)
 360 ])
 361
 362 dnl *** x264 (MPEG-4 part 10/h.264/AVC encoder) ***
 363 translit(dnm, m, l) AM_CONDITIONAL(USE_X264, true)
 364 AG_GST_CHECK_FEATURE(X264, [x264 plug-in], x264, [
 365   AG_GST_PKG_CHECK_MODULES(X264, x264 >= 0.55.0)
 366 ])
 367
 368 else
 369
 370 dnl not building plugins with external dependencies,
 371 dnl but we still need to set the conditionals
 372
 373 AM_CONDITIONAL(USE_A52DEC, false)
 374 AM_CONDITIONAL(USE_AMRNB, false)
 375 AM_CONDITIONAL(USE_AMRWB, false)
 376 AM_CONDITIONAL(USE_CDIO, false)
 377 AM_CONDITIONAL(USE_DVDREAD, false)
 378 AM_CONDITIONAL(USE_LAME, false)
 379 AM_CONDITIONAL(USE_MAD, false)
 380 AM_CONDITIONAL(USE_MPEG2DEC, false)
 381 AM_CONDITIONAL(USE_SIDPLAY, false)
 382 AM_CONDITIONAL(USE_TWOLAME, false)
 383 AM_CONDITIONAL(USE_X264, false)
 384
 385 fi dnl of EXT plugins
 386
 387 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 388
 389 dnl Overview:
 390 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
 391 dnl GST_*:              flags shared by built objects to link against GStreamer
 392 dnl GST_ALL_LDFLAGS:    linker flags shared by all
 393 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 394 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 395 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 396
 397 dnl GST_OPTION_CFLAGS
 398 if test "x$USE_DEBUG" = xyes; then
 399    PROFILE_CFLAGS="-g"
 400 fi
 401 AC_SUBST(PROFILE_CFLAGS)
 402
 403 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
 404   dnl Define _only_ during CVS (not pre-releases or releases)
 405   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 406 else
 407   DEPRECATED_CFLAGS=""
 408 fi
 409 AC_SUBST(DEPRECATED_CFLAGS)
 410
 411 dnl every flag in GST_OPTION_CFLAGS and GST_OPTION_CXXFLAGS can be overridden
 412 dnl at make time with e.g. make ERROR_CFLAGS=""
 413 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 414 GST_OPTION_CXXFLAGS="\$(WARNING_CXXFLAGS) \$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 415 AC_SUBST(GST_OPTION_CFLAGS)
 416 AC_SUBST(GST_OPTION_CXXFLAGS)
 417
 418 dnl FIXME: do we want to rename to GST_ALL_* ?
 419 dnl prefer internal headers to already installed ones
 420 dnl also add builddir include for enumtypes and marshal
 421 dnl add GST_OPTION_CFLAGS, but overridable
 422 GST_CFLAGS="$GST_CFLAGS -DGST_USE_UNSTABLE_API"
 423 GST_CXXFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs $GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_CXXFLAGS)"
 424 GST_CFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs $GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_CFLAGS)"
 425 AC_SUBST(GST_CFLAGS)
 426 AC_SUBST(GST_CXXFLAGS)
 427 AC_SUBST(GST_LIBS)
 428
 429 dnl LDFLAGS really should only contain flags, not libs - they get added before
 430 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 431 GST_ALL_LDFLAGS="-no-undefined"
 432 AC_SUBST(GST_ALL_LDFLAGS)
 433
 434 dnl this really should only contain flags, not libs - they get added before
 435 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 436 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc.*' $GST_ALL_LDFLAGS"
 437 AC_SUBST(GST_PLUGIN_LDFLAGS)
 438
 439 dnl *** output files ***
 440
 441 AC_CONFIG_FILES(
 442 Makefile
 443 common/Makefile
 444 common/m4/Makefile
 445 gst-libs/Makefile
 446 gst-libs/gst/Makefile
 447 gst/Makefile
 448 gst/asfdemux/Makefile
 449 gst/dvdlpcmdec/Makefile
 450 gst/dvdsub/Makefile
 451 gst/realmedia/Makefile
 452 gst/synaesthesia/Makefile
 453 gst/xingmux/Makefile
 454 ext/Makefile
 455 ext/a52dec/Makefile
 456 ext/amrnb/Makefile
 457 ext/amrwbdec/Makefile
 458 ext/cdio/Makefile
 459 ext/dvdread/Makefile
 460 ext/lame/Makefile
 461 ext/mad/Makefile
 462 ext/mpeg2dec/Makefile
 463 ext/sidplay/Makefile
 464 ext/twolame/Makefile
 465 ext/x264/Makefile
 466 docs/Makefile
 467 docs/plugins/Makefile
 468 docs/version.entities
 469 tests/Makefile
 470 tests/check/Makefile
 471 m4/Makefile
 472 po/Makefile.in
 473 pkgconfig/Makefile
 474 pkgconfig/gstreamer-plugins-ugly-uninstalled.pc
 475 gst-plugins-ugly.spec
 476 )
 477
 478 dnl Create the config.h file for Visual Studio builds
 479 dnl Beware of spaces and /'s in some of the shell variable contents.
 480 sed \
 481     -e 's/.*config.h.in.*autoheader.*/\/* Autogenerated config.h created for win32 Visual Studio builds *\/\n\n\/* PREFIX -- specifically added for Windows for easier moving *\/\n#define PREFIX "C:\\\\gstreamer"\n\n/' \
 482     -e 's/.* GETTEXT_PACKAGE$/#define GETTEXT_PACKAGE "'$GETTEXT_PACKAGE'"/' \
 483     -e 's/.* GST_DATADIR$/#define GST_DATADIR PREFIX "\\\\share"/' \
 484     -e 's/.* GST_LEVEL_DEFAULT$/#define GST_LEVEL_DEFAULT GST_LEVEL_ERROR/' \
 485     -e 's/.* GST_LICENSE$/#define GST_LICENSE "'$GST_LICENSE'"/' \
 486     -e 's/.* GST_MAJORMINOR$/#define GST_MAJORMINOR "'$GST_MAJORMINOR'"/' \
 487     -e "s,.* GST_PACKAGE_NAME$,#define GST_PACKAGE_NAME \"${GST_PACKAGE_NAME}\"," \
 488     -e 's/.* GST_PACKAGE_ORIGIN$/#define GST_PACKAGE_ORIGIN "Unknown package origin"/' \
 489     -e "s,.* GST_PACKAGE_RELEASE_DATETIME$,#define GST_PACKAGE_RELEASE_DATETIME \"${GST_PACKAGE_RELEASE_DATETIME}\"," \
 490     -e 's/.* HAVE_CPU_I386$/#define HAVE_CPU_I386 1/' \
 491     -e 's/.* HAVE_FGETPOS$/#define HAVE_FGETPOS 1/' \
 492     -e 's/.* HAVE_FSETPOS$/#define HAVE_FSETPOS 1/' \
 493     -e 's/.* HAVE_LIBXML2$/#define HAVE_LIBXML2 1/' \
 494     -e 's/.* HAVE_PROCESS_H$/#define HAVE_PROCESS_H 1/' \
 495     -e 's/.* HAVE_STDLIB_H$/#define HAVE_STDLIB_H 1/' \
 496     -e 's/.* HAVE_STRING_H$/#define HAVE_STRING_H 1/' \
 497     -e 's/.* HAVE_SYS_STAT_H$/#define HAVE_SYS_STAT_H 1/' \
 498     -e 's/.* HAVE_SYS_TYPES_H$/#define HAVE_SYS_TYPES_H 1/' \
 499     -e 's/.* HAVE_WIN32$/#define HAVE_WIN32 1/' \
 500     -e 's/.* HAVE_WINSOCK2_H$/#define HAVE_WINSOCK2_H 1/' \
 501     -e 's/.* HOST_CPU$/#define HOST_CPU "i686"/' \
 502     -e 's/.* LIBDIR$/#ifdef _DEBUG\n#  define LIBDIR PREFIX "\\\\debug\\\\lib"\n#else\n#  define LIBDIR PREFIX "\\\\lib"\n#endif/' \
 503     -e 's/.* LOCALEDIR$/#define LOCALEDIR PREFIX "\\\\share\\\\locale"/' \
 504     -e "s/.* PACKAGE$/#define PACKAGE \"$PACKAGE\"/" \
 505     -e 's/.* PACKAGE_BUGREPORT$/#define PACKAGE_BUGREPORT "http:\/\/bugzilla.gnome.org\/enter_bug.cgi?product=GStreamer"/' \
 506     -e "s/.* PACKAGE_NAME$/#define PACKAGE_NAME \"$PACKAGE_NAME\"/" \
 507     -e "s/.* PACKAGE_STRING$/#define PACKAGE_STRING \"$PACKAGE_STRING\"/" \
 508     -e 's/.* PACKAGE_TARNAME$/#define PACKAGE_TARNAME "'$PACKAGE_TARNAME'"/' \
 509     -e 's/.* PACKAGE_VERSION$/#define PACKAGE_VERSION "'$PACKAGE_VERSION'"/' \
 510     -e 's/.* PLUGINDIR$/#ifdef _DEBUG\n#  define PLUGINDIR PREFIX "\\\\debug\\\\lib\\\\gstreamer-0.11"\n#else\n#  define PLUGINDIR PREFIX "\\\\lib\\\\gstreamer-0.11"\n#endif/' \
 511     -e 's/.* USE_BINARY_REGISTRY$/#define USE_BINARY_REGISTRY/' \
 512     -e 's/.* VERSION$/#define VERSION "'$VERSION'"/' \
 513     -e "s/.* DEFAULT_AUDIOSINK$/#define DEFAULT_AUDIOSINK \"directsoundsink\"/" \
 514     -e "s/.* DEFAULT_AUDIOSRC$/#define DEFAULT_AUDIOSRC \"audiotestsrc\"/" \
 515     -e "s/.* DEFAULT_VIDEOSRC$/#define DEFAULT_VIDEOSRC \"videotestsrc\"/" \
 516     -e "s/.* DEFAULT_VISUALIZER$/#define DEFAULT_VISUALIZER \"goom\"/" \
 517     config.h.in >win32/common/config.h-new
 518
 519 AC_OUTPUT
 520
 521 AG_GST_OUTPUT_PLUGINS
 522
 523 ORC_OUTPUT