configure.ac

   1 AC_PREREQ(2.62)
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, git and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for git/prerelease
   8 AC_INIT(GStreamer Base Plug-ins, 1.1.0.1,
   9     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
  10     gst-plugins-base)
  11
  12 AG_GST_INIT
  13
  14 dnl initialize automake
  15 AM_INIT_AUTOMAKE([-Wno-portability 1.11 no-dist-gzip dist-xz tar-ustar])
  16
  17 dnl define PACKAGE_VERSION_* variables
  18 AS_VERSION
  19
  20 dnl check if this is a release version
  21 AS_NANO(GST_GIT="no", GST_GIT="yes")
  22
  23 dnl can autoconf find the source ?
  24 AC_CONFIG_SRCDIR([gst/audiotestsrc/gstaudiotestsrc.c])
  25
  26 dnl define the output header for config
  27 AM_CONFIG_HEADER([config.h])
  28
  29 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  30 AM_MAINTAINER_MODE([enable])
  31
  32 dnl sets host_* variables
  33 AC_CANONICAL_HOST
  34
  35 dnl use pretty build output with automake >= 1.11
  36 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],
  37   [AM_DEFAULT_VERBOSITY=1
  38    AC_SUBST(AM_DEFAULT_VERBOSITY)])
  39
  40 dnl our libraries and install dirs use GST_API_VERSION in the filename
  41 dnl to allow side-by-side installation of different API versions
  42 GST_API_VERSION=1.0
  43 AC_SUBST(GST_API_VERSION)
  44 AC_DEFINE_UNQUOTED(GST_API_VERSION, "$GST_API_VERSION",
  45   [GStreamer API Version])
  46
  47 dnl CURRENT, REVISION, AGE
  48 dnl - library source changed -> increment REVISION
  49 dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
  50 dnl - interfaces added -> increment AGE
  51 dnl - interfaces removed -> AGE = 0
  52 dnl sets GST_LT_LDFLAGS
  53 AS_LIBTOOL(GST, 2, 0, 2)
  54
  55 dnl *** required versions of GStreamer stuff ***
  56 GST_REQ=1.1.0
  57
  58 dnl *** autotools stuff ****
  59
  60 dnl allow for different autotools
  61 AS_AUTOTOOLS_ALTERNATE
  62
  63 dnl Add parameters for aclocal
  64 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  65
  66 dnl set up gettext
  67 dnl the version check needs to stay here because autopoint greps for it
  68 AM_GNU_GETTEXT_VERSION([0.17])
  69 AM_GNU_GETTEXT([external])
  70 AG_GST_GETTEXT([gst-plugins-base-$GST_API_VERSION])
  71
  72 dnl *** check for arguments to configure ***
  73
  74 AG_GST_ARG_DISABLE_FATAL_WARNINGS
  75
  76 AG_GST_ARG_DEBUG
  77 AG_GST_ARG_PROFILING
  78 AG_GST_ARG_VALGRIND
  79 AG_GST_ARG_GCOV
  80
  81 AG_GST_ARG_EXAMPLES
  82
  83 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  84 AG_GST_ARG_WITH_PACKAGE_NAME
  85 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  86
  87 AG_GST_PKG_CONFIG_PATH
  88
  89 dnl let distro override plugin install helper path
  90 AC_ARG_WITH(install-plugins-helper,
  91   AC_HELP_STRING([--with-install-plugins-helper],
  92     [specify path of helper script to call to install plugins]),
  93   [
  94     case "${withval}" in
  95       yes) AC_MSG_ERROR(bad value ${withval} for --with-install-plugins-helper) ;;
  96       no)  AC_MSG_ERROR(bad value ${withval} for --with-install-plugins-helper) ;;
  97       *)   GST_INSTALL_PLUGINS_HELPER="${withval}" ;;
  98     esac
  99   ],
 100   [
 101     dnl Default value
 102     AS_AC_EXPAND(GST_INSTALL_PLUGINS_HELPER,${libexecdir}/gst-install-plugins-helper)
 103   ]
 104 )
 105 AC_MSG_NOTICE(Using $GST_INSTALL_PLUGINS_HELPER as plugin install helper)
 106 AC_DEFINE_UNQUOTED(GST_INSTALL_PLUGINS_HELPER, "$GST_INSTALL_PLUGINS_HELPER",
 107     [plugin install helper script])
 108 AC_SUBST(GST_INSTALL_PLUGINS_HELPER)
 109
 110 AG_GST_ARG_WITH_PLUGINS
 111
 112 AG_GST_ARG_ENABLE_EXTERNAL
 113
 114 AG_GST_ARG_ENABLE_EXPERIMENTAL
 115
 116 dnl *** checks for platform ***
 117 AG_GST_PLATFORM
 118
 119 dnl * hardware/architecture *
 120
 121 dnl common/m4/gst-arch.m4
 122 dnl check CPU type
 123 AG_GST_ARCH
 124
 125 dnl check for large file support
 126 dnl affected plugins must include config.h
 127 AC_SYS_LARGEFILE
 128
 129 dnl *** checks for programs ***
 130
 131 dnl find a compiler
 132 AC_PROG_CC
 133 AC_PROG_CC_STDC
 134
 135 dnl check if the compiler supports '-c' and '-o' options
 136 AM_PROG_CC_C_O
 137
 138 dnl determine if c++ is available on this system
 139 AC_PROG_CXX
 140 dnl CXX may be set to some default even if no c++ compiler is available
 141 dnl (thanks autotools!), so just try to compile some c++ code to make sure
 142 AC_LANG_PUSH([C++])
 143 AC_TRY_COMPILE([ class Foo { int bar; };], , working_cxx=yes, working_cxx=no)
 144 AC_LANG_POP([C++])
 145 AC_MSG_NOTICE([working c++ compiler found: $working_cxx])
 146 AM_CONDITIONAL(HAVE_CXX, test "x$working_cxx" = "xyes")
 147
 148 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 149 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 150
 151 dnl check for gobject-introspection
 152 GOBJECT_INTROSPECTION_CHECK([1.31.1])
 153
 154 dnl check for documentation tools
 155 GTK_DOC_CHECK([1.12])
 156 AS_PATH_PYTHON([2.1])
 157 AG_GST_PLUGIN_DOCS([1.3],[2.1])
 158
 159 dnl *** checks for libraries ***
 160
 161 dnl libm, for sin() etc.
 162 LT_LIB_M
 163 AC_SUBST(LIBM)
 164
 165 dnl *** checks for header files ***
 166
 167 dnl check if we have ANSI C header files
 168 AC_HEADER_STDC
 169
 170 dnl check for GCC specific SSE headers
 171 dnl these are used by the speex resampler code
 172 AC_CHECK_HEADERS([xmmintrin.h emmintrin.h])
 173
 174 ac_cppflags_save="$CPPFLAGS"
 175 CPPFLAGS="`$PKG_CONFIG --cflags libxml-2.0`"
 176 AC_COMPILE_IFELSE([
 177   AC_LANG_PROGRAM([[
 178 #include <libxml/HTMLparser.h>
 179 ]],[[
 180 #ifndef LIBXML_HTML_ENABLED
 181 #error libxml2 has no HTML support
 182 #endif /* LIBXML_HTML_ENABLED */
 183 ]])], [
 184   HAVE_LIBXML_HTML="yes"
 185 ], [
 186   HAVE_LIBXML_HTML="no"
 187 ])
 188 CPPFLAGS="$ac_cppflags_save"
 189 AM_CONDITIONAL(HAVE_LIBXML_HTML, test "x$HAVE_LIBXML_HTML" = "xyes")
 190
 191 dnl used in gst/tcp
 192 AC_CHECK_HEADERS([sys/socket.h],
 193   [HAVE_SYS_SOCKET_H="yes"], [HAVE_SYS_SOCKET_H="no"], [AC_INCLUDES_DEFAULT])
 194 AM_CONDITIONAL(HAVE_SYS_SOCKET_H, test "x$HAVE_SYS_SOCKET_H" = "xyes")
 195
 196 dnl used in gst-libs/gst/pbutils and associated unit test
 197 AC_CHECK_HEADERS([process.h sys/types.h sys/wait.h sys/stat.h], [], [], [AC_INCLUDES_DEFAULT])
 198
 199 dnl checks for ARM NEON support
 200 dnl this instruction set is used by the speex resampler code
 201 AC_MSG_CHECKING(for ARM NEON support in current arch/CFLAGS)
 202 AC_LINK_IFELSE([
 203 AC_LANG_PROGRAM([[
 204   #include <arm_neon.h>
 205   int32x4_t testfunc(int16_t *a, int16_t *b) {
 206       return vmull_s16(vld1_s16(a), vld1_s16(b));
 207   }
 208 ]])],
 209 [
 210   AC_DEFINE(HAVE_ARM_NEON,[],[ARM NEON support is enabled])
 211   AC_MSG_RESULT(yes)
 212 ],
 213 [
 214   AC_MSG_RESULT(no)
 215 ])
 216
 217 dnl also, Windows does not have long long
 218 AX_CREATE_STDINT_H
 219
 220 dnl *** checks for functions ***
 221 AC_CHECK_FUNCS([localtime_r gmtime_r])
 222
 223 dnl *** checks for math functions ***
 224 LIBS_SAVE=$LIBS
 225 LIBS="$LIBS $LIBM"
 226 AC_CHECK_FUNCS(log2)
 227 LIBS=$LIBS_SAVE
 228
 229 dnl *** checks for types/defines ***
 230
 231 dnl *** checks for structures ***
 232
 233 dnl *** checks for compiler characteristics ***
 234
 235 dnl *** checks for library functions ***
 236
 237 dnl check for fseeko()
 238 AC_FUNC_FSEEKO
 239
 240 dnl Check for fast float to int casting as defined in C99
 241 dnl used to be used in gst-libs/gst/floatcast/floatcast.h (FIXME: still needed?)
 242 save_libs=$LIBS
 243 LIBS="$LIBS $LIBM"
 244 AC_C99_FUNC_LRINT
 245 AC_C99_FUNC_LRINTF
 246 LIBS=$save_libs
 247
 248 dnl Check for a way to display the function name in debug output
 249 AG_GST_CHECK_FUNCTION
 250
 251 dnl *** checks for dependency libraries ***
 252
 253 dnl GLib
 254 GLIB_REQ=2.32
 255 AG_GST_GLIB_CHECK([$GLIB_REQ])
 256
 257 ORC_CHECK([0.4.16])
 258
 259 dnl checks for gstreamer
 260 dnl uninstalled is selected preferentially -- see pkg-config(1)
 261 AG_GST_CHECK_GST($GST_API_VERSION, [$GST_REQ], yes)
 262 AG_GST_CHECK_GST_BASE($GST_API_VERSION, [$GST_REQ], yes)
 263 AG_GST_CHECK_GST_CONTROLLER($GST_API_VERSION, [$GST_REQ], yes)
 264 AG_GST_CHECK_GST_CHECK($GST_API_VERSION, [$GST_REQ], no)
 265 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 266
 267 dnl Check for documentation xrefs
 268 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 269 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_API_VERSION`"
 270 AC_SUBST(GLIB_PREFIX)
 271 AC_SUBST(GST_PREFIX)
 272
 273 dnl GTK is optional and only used in examples
 274 HAVE_GTK=no
 275 HAVE_GTK_X11=no
 276 GTK_REQ=3.0.0
 277 if test "x$BUILD_EXAMPLES" = "xyes"; then
 278   PKG_CHECK_MODULES(GTK, gtk+-3.0 >= $GTK_REQ, HAVE_GTK=yes, HAVE_GTK=no)
 279   dnl some examples need gtk+-x11
 280   PKG_CHECK_MODULES(GTK_X11, gtk+-x11-3.0 >= $GTK_REQ, HAVE_GTK_X11=yes, HAVE_GTK_X11=no)
 281   PKG_CHECK_MODULES(GTK_QUARTZ, gtk+-quartz-3.0 >= $GTK_REQ, HAVE_GTK_QUARTZ=yes, HAVE_GTK_QUARTZ=no)
 282   AC_SUBST(GTK_LIBS)
 283   AC_SUBST(GTK_CFLAGS)
 284 fi
 285 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 286 AM_CONDITIONAL(HAVE_GTK_X11, test "x$HAVE_GTK_X11" = "xyes")
 287 AM_CONDITIONAL(HAVE_GTK_QUARTZ, test "x$HAVE_GTK_QUARTZ" = "xyes")
 288
 289 dnl QT is optional and only used in examples
 290 PKG_CHECK_MODULES(QT, QtGui >= 4.6, [
 291   HAVE_QT_GV=yes
 292   HAVE_QT=yes
 293 ], [
 294   HAVE_QT_GV=no
 295   PKG_CHECK_MODULES(QT, QtGui >= 4.0, HAVE_QT=yes, HAVE_QT=no)
 296 ])
 297 if test "x$HAVE_QT" = "xyes"; then
 298   AC_MSG_CHECKING([Qt moc])
 299   QT4_MOC=`$PKG_CONFIG --variable=moc_location QtGui`
 300   AC_MSG_RESULT($QT4_MOC)
 301   AC_SUBST(QT4_MOC)
 302 fi
 303 AM_CONDITIONAL(HAVE_QT, test "x$HAVE_QT" = "xyes")
 304 AM_CONDITIONAL(HAVE_QT_GV, test "x$HAVE_QT_GV" = "xyes")
 305
 306 dnl chck for linux headers needed by the joystick seek example
 307 AC_COMPILE_IFELSE(
 308 [
 309   AC_LANG_PROGRAM([
 310     #include <linux/input.h>
 311     #include <linux/joystick.h>
 312   ],[
 313     struct js_event js;
 314     js.type = JS_EVENT_AXIS;
 315   ])
 316 ], [
 317   HAVE_LINUX_JOYSTICK_HEADERS="yes"
 318 ], [
 319   HAVE_LINUX_JOYSTICK_HEADERS="no"
 320 ])
 321 AM_CONDITIONAL(HAVE_LINUX_JOYSTICK_HEADERS, test "x$HAVE_LINUX_JOYSTICK_HEADERS" = "xyes")
 322
 323 dnl Check for -Bsymbolic-functions linker flag used to avoid
 324 dnl intra-library PLT jumps, if available.
 325 AC_ARG_ENABLE(Bsymbolic,
 326               [AC_HELP_STRING([--disable-Bsymbolic],
 327                               [avoid linking with -Bsymbolic])],,
 328               [SAVED_LDFLAGS="${LDFLAGS}"
 329                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
 330                LDFLAGS=-Wl,-Bsymbolic-functions
 331                AC_TRY_LINK([], [int main (void) { return 0; }],
 332                            AC_MSG_RESULT(yes)
 333                            enable_Bsymbolic=yes,
 334                            AC_MSG_RESULT(no)
 335                            enable_Bsymbolic=no)
 336                LDFLAGS="${SAVED_LDFLAGS}"])
 337
 338
 339 dnl *** set variables based on configure arguments ***
 340
 341 dnl set license and copyright notice
 342 GST_LICENSE="LGPL"
 343 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 344 AC_SUBST(GST_LICENSE)
 345
 346 dnl set location of plugin directory
 347 AG_GST_SET_PLUGINDIR
 348
 349 dnl set release date/time
 350 AG_GST_SET_PACKAGE_RELEASE_DATETIME_WITH_NANO([$PACKAGE_VERSION_NANO],
 351   ["${srcdir}/gst-plugins-base.doap"],
 352   [$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_MICRO])
 353
 354 # set by AG_GST_PARSE_SUBSYSTEM_DISABLES above
 355 dnl make sure it doesn't complain about unused variables if debugging is disabled
 356 NO_WARNINGS=""
 357 AG_GST_CHECK_GST_DEBUG_DISABLED([NO_WARNINGS="-Wno-unused"], [NO_WARNINGS=""])
 358
 359 dnl define an ERROR_CFLAGS Makefile variable
 360 dnl -Wformat-nonliteral - see ext/pango/gstclockoverlay.c and http://gcc.gnu.org/bugzilla/show_bug.cgi?id=39438
 361 AG_GST_SET_ERROR_CFLAGS($FATAL_WARNINGS, [
 362     -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls -Wundef
 363     -Wwrite-strings -Wformat-nonliteral -Wformat-security
 364     -Winit-self -Wmissing-include-dirs -Waddress -Waggregate-return
 365     -Wno-multichar -Wnested-externs $NO_WARNINGS])
 366
 367 dnl define an ERROR_CXXFLAGS Makefile variable
 368 AG_GST_SET_ERROR_CXXFLAGS($FATAL_WARNINGS, [
 369     -Wmissing-declarations -Wredundant-decls -Wundef
 370     -Wwrite-strings -Wformat-nonliteral -Wformat-security
 371     -Winit-self -Wmissing-include-dirs -Waddress -Waggregate-return
 372     -Wno-multichar $NO_WARNINGS])
 373
 374 dnl define correct level for debugging messages
 375 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 376
 377 dnl used in examples
 378 AG_GST_DEFAULT_ELEMENTS
 379
 380 dnl needed for encoding-target
 381 GST_DATADIR="$GST_PREFIX/share"
 382 AC_DEFINE_UNQUOTED(GST_DATADIR, "$GST_DATADIR", [system wide data directory])
 383 AC_DEFINE_UNQUOTED(GST_API_VERSION, "$GST_API_VERSION", [major/minor version])
 384
 385 dnl behaviour of speex based audio resampler
 386 AC_MSG_CHECKING(which audio resample format to use for integer)
 387 AC_ARG_WITH([audioresample_format],
 388         AS_HELP_STRING([--with-audioresample-format],[Which implementation should be used for integer audio resampling, int/float/auto, (default is auto)]),
 389         [ac_cv_audioresample_format=$withval], [ac_cv_audioresample_format=auto])dnl
 390 AC_MSG_RESULT($ac_cv_audioresample_format)
 391 case $ac_cv_audioresample_format in
 392   int)
 393     AC_DEFINE(AUDIORESAMPLE_FORMAT_INT,1,[The int implementation should be used for integer audio resampling])
 394     AC_SUBST(AUDIORESAMPLE_FORMAT_INT)
 395   ;;
 396   float)
 397     AC_DEFINE(AUDIORESAMPLE_FORMAT_FLOAT,1,[The float implementation should be used for integer audio resampling])
 398     AC_SUBST(AUDIORESAMPLE_FORMAT_FLOAT)
 399   ;;
 400   auto)
 401     AC_DEFINE(AUDIORESAMPLE_FORMAT_AUTO,1,[The implementation that should be used for integer audio resampling witll be benchmarked at runtime])
 402     AC_SUBST(AUDIORESAMPLE_FORMAT_AUTO)
 403 esac
 404
 405 dnl *** plug-ins to include ***
 406
 407 dnl these are all the gst plug-ins, compilable without additional libs
 408 AG_GST_CHECK_PLUGIN(adder)
 409 AG_GST_CHECK_PLUGIN(app)
 410 AG_GST_CHECK_PLUGIN(audioconvert)
 411 AG_GST_CHECK_PLUGIN(audiorate)
 412 AG_GST_CHECK_PLUGIN(audiotestsrc)
 413 AG_GST_CHECK_PLUGIN(encoding)
 414 AG_GST_CHECK_PLUGIN(videoconvert)
 415 AG_GST_CHECK_PLUGIN(gio)
 416 AG_GST_CHECK_PLUGIN(playback)
 417 AG_GST_CHECK_PLUGIN(audioresample)
 418 AG_GST_CHECK_PLUGIN(subparse)
 419 AG_GST_CHECK_PLUGIN(tcp)
 420 AG_GST_CHECK_PLUGIN(typefind)
 421 AG_GST_CHECK_PLUGIN(videotestsrc)
 422 AG_GST_CHECK_PLUGIN(videorate)
 423 AG_GST_CHECK_PLUGIN(videoscale)
 424 AG_GST_CHECK_PLUGIN(volume)
 425
 426 dnl FIXME 0.11: check for libxml, split subparse and move libxml parts to ext/
 427 AM_CONDITIONAL(USE_XML, false)
 428 AC_DEFINE([GST_DISABLE_XML], [1], [set to disable libxml2-dependent code in subparse])
 429
 430 dnl disable plug-ins that require libxml2's HTML support if it is not available
 431 if test "x$HAVE_LIBXML_HTML" != "xyes"; then
 432   AG_GST_DISABLE_PLUGIN(subparse)
 433 fi
 434
 435 dnl iso-codes is optional, used by libgsttag
 436 AC_ARG_ENABLE(iso-codes,
 437 AC_HELP_STRING([--enable-iso-codes],[use iso-codes if installed]),
 438 [case "${enableval}" in
 439   yes) enable_iso_codes=yes ;;
 440   no)  enable_iso_codes=no ;;
 441   *) AC_MSG_ERROR(bad value ${enableval} for --enable-iso-codes) ;;
 442 esac
 443 ],
 444 [enable_iso_codes=yes]) dnl Default value
 445
 446 AC_MSG_CHECKING([whether to use iso-codes if they are available])
 447 if test "x$enable_iso_codes" = "xyes"; then
 448   AC_MSG_RESULT([yes])
 449   have_iso_codes=no
 450   AC_MSG_CHECKING([whether iso-codes are available on this system])
 451   if $PKG_CONFIG iso-codes; then
 452     AC_MSG_RESULT([yes])
 453     AC_MSG_CHECKING([whether iso-codes has iso-639 domain])
 454     if $PKG_CONFIG --variable=domains iso-codes | $GREP -q 639 ; then
 455       AC_MSG_RESULT([yes])
 456       AC_MSG_CHECKING([for iso-codes prefix])
 457       ISO_CODES_PREFIX=`$PKG_CONFIG --variable=prefix iso-codes`
 458       if test -d "$ISO_CODES_PREFIX"; then
 459         AC_MSG_RESULT([yes])
 460         AC_MSG_CHECKING([ISO_CODES_PREFIX])
 461         AC_MSG_RESULT([$ISO_CODES_PREFIX])
 462         ISO_639_DOMAIN="iso_639"
 463         AC_MSG_CHECKING([ISO_639_DOMAIN])
 464         AC_MSG_RESULT([$ISO_639_DOMAIN])
 465         have_iso_codes=yes
 466         AC_DEFINE([HAVE_ISO_CODES], [1], [make use of iso-codes for ISO-639])
 467         AC_DEFINE_UNQUOTED([ISO_CODES_PREFIX], ["$ISO_CODES_PREFIX"], [prefix])
 468         ISO_CODES_VERSION=`$PKG_CONFIG --modversion iso-codes`
 469         AC_DEFINE_UNQUOTED([ISO_CODES_VERSION], ["$ISO_CODES_VERSION"], [ ])
 470       else
 471         AC_MSG_RESULT([no])
 472       fi
 473     else
 474       AC_MSG_RESULT([no])
 475     fi
 476   else
 477     AC_MSG_RESULT([no])
 478   fi
 479   AM_CONDITIONAL(USE_ISO_CODES, test "x$have_iso_codes" = "xyes")
 480 else
 481   AC_MSG_RESULT([no (disabled via --disable-iso-codes)])
 482   AM_CONDITIONAL(USE_ISO_CODES, false)
 483 fi
 484
 485 dnl *** zlib is optionally used by id3 tag parsing in libgsttag ***
 486 translit(dnm, m, l) AM_CONDITIONAL(USE_ZLIB, true)
 487 AG_GST_CHECK_FEATURE(ZLIB, [zlib support for ID3 parsing in libgsttag],, [
 488   PKG_CHECK_MODULES(ZLIB, [ zlib ], [
 489       HAVE_ZLIB="yes"
 490     ], [
 491       AG_GST_CHECK_LIBHEADER(ZLIB, z, uncompress,, zlib.h, [
 492         HAVE_ZLIB="yes"
 493         ZLIB_LIBS="-lz"
 494         AC_SUBST(ZLIB_LIBS)
 495       ])
 496     ])
 497 ])
 498
 499 dnl *** sys plug-ins ***
 500
 501 echo
 502 AC_MSG_NOTICE([Checking libraries for plugins in sys/])
 503 echo
 504
 505 dnl *** X11 ***
 506 translit(dnm, m, l) AM_CONDITIONAL(USE_X, true)
 507 AG_GST_CHECK_FEATURE(X, [X libraries and plugins],
 508                   [ximagesink], [
 509   AC_PATH_XTRA
 510   ac_cflags_save="$CFLAGS"
 511   ac_cppflags_save="$CPPFLAGS"
 512   CFLAGS="$CFLAGS $X_CFLAGS"
 513   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 514
 515   dnl now try to find the HEADER
 516   AC_CHECK_HEADER([X11/Xlib.h], [HAVE_X="yes"], [HAVE_X="no"], [AC_INCLUDES_DEFAULT])
 517
 518   if test "x$HAVE_X" = "xno"
 519   then
 520     AC_MSG_NOTICE([cannot find X11 development files])
 521   else
 522     dnl this is much more than we want
 523     X_LIBS="$X_LIBS $X_PRE_LIBS $X_EXTRA_LIBS"
 524     dnl AC_PATH_XTRA only defines the path needed to find the X libs,
 525     dnl it does not add the libs; therefore we add them here
 526     X_LIBS="$X_LIBS -lX11"
 527     AC_SUBST(X_CFLAGS)
 528     AC_SUBST(X_LIBS)
 529   fi
 530   AC_SUBST(HAVE_X)
 531   CFLAGS="$ac_cflags_save"
 532   CPPFLAGS="$ac_cppflags_save"
 533 ])
 534
 535 dnl Check for Xv extension
 536 translit(dnm, m, l) AM_CONDITIONAL(USE_XVIDEO, true)
 537 AG_GST_CHECK_FEATURE(XVIDEO, [X11 XVideo extensions],
 538                   [xvimagesink], [
 539   AG_GST_CHECK_XV
 540 ])
 541
 542 dnl check for X Shm
 543 translit(dnm, m, l) AM_CONDITIONAL(USE_XSHM, true)
 544 AG_GST_CHECK_FEATURE(XSHM, [X Shared Memory extension], , [
 545   if test x$HAVE_X = xyes; then
 546     AC_CHECK_LIB(Xext, XShmAttach,
 547                  HAVE_XSHM="yes", HAVE_XSHM="no",
 548                  $X_LIBS)
 549     if test "x$HAVE_XSHM" = "xyes"; then
 550       XSHM_LIBS="-lXext"
 551     else
 552       dnl On AIX, it is in XextSam instead, but we still need -lXext
 553       AC_CHECK_LIB(XextSam, XShmAttach,
 554                    HAVE_XSHM="yes", HAVE_XSHM="no",
 555                    $X_LIBS)
 556       if test "x$HAVE_XSHM" = "xyes"; then
 557         XSHM_LIBS="-lXext -lXextSam"
 558       fi
 559     fi
 560   fi
 561 ], , [
 562   AC_SUBST(HAVE_XSHM)
 563   AC_SUBST(XSHM_LIBS)
 564 ])
 565
 566 dnl *** ext plug-ins ***
 567 dnl keep this list sorted alphabetically !
 568
 569 if test "x$BUILD_EXTERNAL" = "xyes"; then
 570
 571 echo
 572 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 573 echo
 574
 575 dnl *** alsa ***
 576 translit(dnm, m, l) AM_CONDITIONAL(USE_ALSA, true)
 577 AG_GST_CHECK_FEATURE(ALSA, [ALSA], alsa, [
 578   PKG_CHECK_MODULES(ALSA, alsa >= 0.9.1, [
 579     HAVE_ALSA="yes"
 580     AC_SUBST(ALSA_CFLAGS)
 581     AC_SUBST(ALSA_LIBS)
 582   ], [
 583     AM_PATH_ALSA(0.9.1, HAVE_ALSA="yes", HAVE_ALSA="no")
 584   ])
 585 ])
 586
 587 dnl *** CDParanoia ***
 588 dnl Note: upstream has a pkg-config file only in post-10.2 SVN so far
 589 translit(dnm, m, l) AM_CONDITIONAL(USE_CDPARANOIA, true)
 590 AG_GST_CHECK_FEATURE(CDPARANOIA, [CDParanoia], cdparanoia, [
 591   PKG_CHECK_MODULES(CDPARANOIA, cdparanoia-3 >= 10.2, [
 592     HAVE_CDPARANOIA="yes"
 593   ], [
 594     AG_GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 595                         cdda_open, -lm,
 596                         cdda_interface.h,
 597                         CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 598                         HEADER_DIR="no"
 599                         FOUND_CDPARANOIA="yes")
 600     if test "x$FOUND_CDPARANOIA" != "xyes";
 601     then
 602       AG_GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 603                           cdda_open, -lm,
 604                           cdda/cdda_interface.h,
 605                           CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 606                           HEADER_DIR="yes"
 607                           FOUND_CDPARANOIA="yes")
 608     fi
 609     if test "x$HEADER_DIR" = "xyes";
 610     then
 611       AC_DEFINE_UNQUOTED(CDPARANOIA_HEADERS_IN_DIR, ,
 612                          defined if cdda headers are in a cdda/ directory)
 613     fi
 614     if test "x$FOUND_CDPARANOIA" = "xyes";
 615     then
 616       AC_CHECK_LIB(cdda_paranoia,
 617                    paranoia_cachemodel_size,
 618                    : ,
 619                    HAVE_CDPARANOIA=no,
 620                  [-lcdda_interface])
 621     fi
 622
 623     AC_SUBST(CDPARANOIA_LIBS)
 624   ])
 625 ])
 626 dnl FIXME : add second check somehow if that is necessary
 627 dnl AC_CHECK_LIB(cdda_paranoia, paranoia_init, : , HAVE_CDPARANOIA=no, -lcdda_interface )
 628 dnl AC_CHECK_HEADER(cdda_paranoia.h, :, HAVE_CDPARANOIA=no)
 629
 630 dnl *** ivorbis ***
 631 dnl AM_PATH_IVORBIS only takes two options
 632 translit(dnm, m, l) AM_CONDITIONAL(USE_IVORBIS, true)
 633 AG_GST_CHECK_FEATURE(IVORBIS, [integer vorbis plug-in], ivorbisdec, [
 634   AG_GST_PKG_CHECK_MODULES(IVORBIS, vorbisidec)
 635   if test $HAVE_IVORBIS = no
 636   then
 637     IVORBIS_LIBS=
 638     IVORBIS_CFLAGS=
 639     AC_CHECK_LIB(vorbisidec, vorbis_block_init,
 640       [IVORBIS_LIBS=-lvorbisidec
 641       HAVE_IVORBIS=yes
 642       case $host in
 643       arm-*-*)
 644         IVORBIS_CFLAGS="-D_ARM_ASSEM_ $IVORBIS_CFLAGS"
 645       esac
 646       ],
 647       HAVE_IVORBIS=no)
 648     AC_SUBST(IVORBIS_LIBS)
 649     AC_SUBST(IVORBIS_CFLAGS)
 650   else
 651     AC_CHECK_LIB(vorbisidec, vorbis_dsp_pcmout,
 652       AC_DEFINE([USE_TREMOLO],1, "Define if building for android"),
 653       USE_TREMOLO=no)
 654   fi
 655 ])
 656
 657 dnl *** libvisual ***
 658 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBVISUAL, true)
 659 AG_GST_CHECK_FEATURE(LIBVISUAL, [libvisual visualization library], libvisual, [
 660   AG_GST_PKG_CHECK_MODULES(LIBVISUAL, libvisual-0.4 >= 0.4.0)
 661   if test $HAVE_LIBVISUAL = no
 662   then
 663     AG_GST_PKG_CHECK_MODULES(LIBVISUAL, libvisual = 0.2.0)
 664     if test x$HAVE_LIBVISUAL = xyes; then
 665       LIBVIS_PLUGINSDIR="`$PKG_CONFIG --variable=pluginsbasedir libvisual-0.2`"
 666     fi
 667   else
 668     if test x$HAVE_LIBVISUAL = xyes; then
 669       LIBVIS_PLUGINSDIR="`$PKG_CONFIG --variable=pluginsbasedir libvisual-0.4`"
 670     fi
 671   fi
 672   AC_MSG_NOTICE([libvisual pluginsdir: $LIBVIS_PLUGINSDIR])
 673   if test x$LIBVIS_PLUGINSDIR != x; then
 674     AC_DEFINE_UNQUOTED(LIBVISUAL_PLUGINSBASEDIR,
 675         "$LIBVIS_PLUGINSDIR",
 676         [directory in which the detected libvisual's plugins are located])
 677   fi
 678 ])
 679
 680 dnl *** ogg ***
 681 translit(dnm, m, l) AM_CONDITIONAL(USE_OGG, true)
 682 AG_GST_CHECK_FEATURE(OGG, [Xiph Ogg library], ogg, [
 683   AG_GST_PKG_CHECK_MODULES(OGG, ogg >= 1.0)
 684   if test $HAVE_OGG = no
 685   then
 686     XIPH_PATH_OGG(HAVE_OGG="yes", HAVE_OGG="no")
 687     AS_SCRUB_INCLUDE(OGG_CFLAGS)
 688   fi
 689 ])
 690
 691 dnl *** pango ***
 692 translit(dnm, m, l) AM_CONDITIONAL(USE_PANGO, true)
 693 AG_GST_CHECK_FEATURE(PANGO, [Pango font rendering], pango, [
 694   AG_GST_PKG_CHECK_MODULES(PANGO, pango >= 1.22.0  pangocairo >= 1.22.0)
 695 ])
 696
 697 dnl *** theora ***
 698 translit(dnm, m, l) AM_CONDITIONAL(USE_THEORA, true)
 699 AG_GST_CHECK_FEATURE(THEORA, [Xiph Theora video codec], theora, [
 700   AG_GST_PKG_CHECK_MODULES(THEORA, theoradec >= 1.1 theoraenc >= 1.1)
 701 ])
 702
 703 dnl *** vorbis ***
 704 dnl AM_PATH_VORBIS only takes two options
 705 translit(dnm, m, l) AM_CONDITIONAL(USE_VORBIS, true)
 706 AG_GST_CHECK_FEATURE(VORBIS, [Xiph Vorbis audio codec], vorbis, [
 707   AG_GST_PKG_CHECK_MODULES(VORBIS, vorbis >= 1.0 vorbisenc >= 1.0)
 708   if test $HAVE_VORBIS = no
 709   then
 710     XIPH_PATH_VORBIS(HAVE_VORBIS="yes", HAVE_VORBIS="no")
 711     AS_SCRUB_INCLUDE(VORBIS_CFLAGS)
 712   fi
 713 ])
 714
 715 if test "x$HAVE_VORBIS" = "xyes"; then
 716   ac_cflags_save="$CFLAGS"
 717   AC_COMPILE_IFELSE([
 718     AC_LANG_PROGRAM([[
 719 #include <vorbis/codec.h>
 720                      ]],[[
 721 vorbis_dsp_state *v;
 722
 723 vorbis_synthesis_restart (v);
 724                      ]])], HAVE_VSR=yes, HAVE_VSR=no)
 725   if test "x$HAVE_VSR" = "xyes"; then
 726     AC_DEFINE_UNQUOTED(HAVE_VORBIS_SYNTHESIS_RESTART, 1,
 727                        [defined if vorbis_synthesis_restart is present])
 728   fi
 729   CFLAGS="$ac_cflags_save"
 730 fi
 731
 732 else
 733
 734 dnl not building plugins with external dependencies,
 735 dnl but we still need to set the conditionals
 736 AM_CONDITIONAL(USE_ALSA, false)
 737 AM_CONDITIONAL(USE_CDPARANOIA, false)
 738 AM_CONDITIONAL(USE_IVORBIS, false)
 739 AM_CONDITIONAL(USE_LIBVISUAL, false)
 740 AM_CONDITIONAL(USE_OGG, false)
 741 AM_CONDITIONAL(USE_PANGO, false)
 742 AM_CONDITIONAL(USE_THEORA, false)
 743 AM_CONDITIONAL(USE_VORBIS, false)
 744
 745 fi dnl of EXT plugins
 746
 747 dnl seeking needs freetype, so check for it here
 748 PKG_CHECK_MODULES(FT2, freetype2 >= 2.0.9, HAVE_FT2="yes", [
 749   AC_CHECK_FT2(2.0.9, HAVE_FT2="yes", HAVE_FT2="no")
 750 ])
 751 dnl make the HAVE_FT2 variable available to automake and Makefile.am
 752 AM_CONDITIONAL(HAVE_FT2, test "x$HAVE_FT2" = "xyes")
 753 AC_SUBST(FT2_CFLAGS)
 754 AC_SUBST(FT2_LIBS)
 755
 756 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 757
 758 dnl Overview:
 759 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
 760 dnl GST_*:              flags shared by built objects to link against GStreamer
 761 dnl GST_PLUGINS_BASE_CFLAGS: to link internally against the plugins base libs
 762 dnl                          (compare to other modules) or for i18n
 763 dnl GST_ALL_LDFLAGS:    linker flags shared by all
 764 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 765 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 766 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 767
 768 dnl GST_OPTION_CFLAGS
 769 if test "x$USE_DEBUG" = xyes; then
 770    PROFILE_CFLAGS="-g"
 771 fi
 772 AC_SUBST(PROFILE_CFLAGS)
 773
 774 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
 775   dnl Define _only_ when compiling a git version (not pre-releases or releases)
 776   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 777 else
 778   DEPRECATED_CFLAGS=""
 779 fi
 780 AC_SUBST(DEPRECATED_CFLAGS)
 781
 782 dnl every flag in GST_OPTION_CFLAGS and GST_OPTION_CXXFLAGS can be overridden
 783 dnl at make time with e.g. make ERROR_CFLAGS=""
 784 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 785 GST_OPTION_CXXFLAGS="\$(WARNING_CXXFLAGS) \$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 786 AC_SUBST(GST_OPTION_CFLAGS)
 787 AC_SUBST(GST_OPTION_CXXFLAGS)
 788
 789 dnl our libraries need to be versioned correctly
 790 AC_SUBST(GST_LT_LDFLAGS)
 791
 792 dnl GST_PLUGINS_BASE_CFLAGS
 793 dnl prefer internal headers to already installed ones
 794 dnl also add builddir include for enumtypes and marshal
 795 GST_PLUGINS_BASE_CFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs"
 796 AC_SUBST(GST_PLUGINS_BASE_CFLAGS)
 797
 798 dnl FIXME: do we want to rename to GST_ALL_* ?
 799 dnl add GST_OPTION_CFLAGS, but overridable
 800 GST_CFLAGS="$GST_CFLAGS"
 801 GST_CXXFLAGS="$GLIB_CFLAGS $GST_CFLAGS \$(GLIB_EXTRA_CFLAGS) \$(GST_OPTION_CXXFLAGS)"
 802 GST_CFLAGS="$GLIB_CFLAGS $GST_CFLAGS \$(GLIB_EXTRA_CFLAGS) \$(GST_OPTION_CFLAGS)"
 803 AC_SUBST(GST_CFLAGS)
 804 AC_SUBST(GST_CXXFLAGS)
 805 dnl add GCOV libs because libtool strips -fprofile-arcs -ftest-coverage
 806 GST_LIBS="$GST_LIBS \$(GCOV_LIBS)"
 807 AC_SUBST(GST_LIBS)
 808
 809 dnl LDFLAGS really should only contain flags, not libs - they get added before
 810 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 811 GST_ALL_LDFLAGS="-no-undefined"
 812 if test "x${enable_Bsymbolic}" = "xyes"; then
 813   GST_ALL_LDFLAGS="$GST_ALL_LDFLAGS -Wl,-Bsymbolic-functions"
 814 fi
 815 AC_SUBST(GST_ALL_LDFLAGS)
 816
 817 dnl GST_LIB_LDFLAGS
 818 dnl linker flags shared by all libraries
 819 dnl LDFLAGS modifier defining exported symbols from built libraries
 820 dnl (export _gst_foo but not __gst_foo)
 821 GST_LIB_LDFLAGS="-export-symbols-regex ^_?\(gst_\|Gst\|GST_\).*"
 822 AC_SUBST(GST_LIB_LDFLAGS)
 823
 824 dnl this really should only contain flags, not libs - they get added before
 825 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 826 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc.*' $GST_ALL_LDFLAGS"
 827 AC_SUBST(GST_PLUGIN_LDFLAGS)
 828
 829 dnl *** output files ***
 830
 831 AC_CONFIG_FILES(
 832 Makefile
 833 gst-plugins-base.spec
 834 gst/Makefile
 835 gst/adder/Makefile
 836 gst/app/Makefile
 837 gst/audioconvert/Makefile
 838 gst/audiorate/Makefile
 839 gst/audiotestsrc/Makefile
 840 gst/encoding/Makefile
 841 gst/videoconvert/Makefile
 842 gst/gio/Makefile
 843 gst/playback/Makefile
 844 gst/audioresample/Makefile
 845 gst/subparse/Makefile
 846 gst/tcp/Makefile
 847 gst/typefind/Makefile
 848 gst/videotestsrc/Makefile
 849 gst/videorate/Makefile
 850 gst/videoscale/Makefile
 851 gst/volume/Makefile
 852 sys/Makefile
 853 sys/ximage/Makefile
 854 sys/xvimage/Makefile
 855 ext/Makefile
 856 ext/alsa/Makefile
 857 ext/cdparanoia/Makefile
 858 ext/libvisual/Makefile
 859 ext/ogg/Makefile
 860 ext/pango/Makefile
 861 ext/theora/Makefile
 862 ext/vorbis/Makefile
 863 gst-libs/Makefile
 864 gst-libs/gst/Makefile
 865 gst-libs/gst/audio/Makefile
 866 gst-libs/gst/app/Makefile
 867 gst-libs/gst/fft/Makefile
 868 gst-libs/gst/riff/Makefile
 869 gst-libs/gst/rtp/Makefile
 870 gst-libs/gst/rtsp/Makefile
 871 gst-libs/gst/sdp/Makefile
 872 gst-libs/gst/tag/Makefile
 873 gst-libs/gst/pbutils/Makefile
 874 gst-libs/gst/pbutils/gstpluginsbaseversion.h
 875 gst-libs/gst/video/Makefile
 876 tools/Makefile
 877 pkgconfig/Makefile
 878 pkgconfig/gstreamer-audio.pc
 879 pkgconfig/gstreamer-audio-uninstalled.pc
 880 pkgconfig/gstreamer-app.pc
 881 pkgconfig/gstreamer-app-uninstalled.pc
 882 pkgconfig/gstreamer-fft.pc
 883 pkgconfig/gstreamer-fft-uninstalled.pc
 884 pkgconfig/gstreamer-pbutils.pc
 885 pkgconfig/gstreamer-pbutils-uninstalled.pc
 886 pkgconfig/gstreamer-riff.pc
 887 pkgconfig/gstreamer-riff-uninstalled.pc
 888 pkgconfig/gstreamer-rtp.pc
 889 pkgconfig/gstreamer-rtp-uninstalled.pc
 890 pkgconfig/gstreamer-rtsp.pc
 891 pkgconfig/gstreamer-rtsp-uninstalled.pc
 892 pkgconfig/gstreamer-sdp.pc
 893 pkgconfig/gstreamer-sdp-uninstalled.pc
 894 pkgconfig/gstreamer-tag.pc
 895 pkgconfig/gstreamer-tag-uninstalled.pc
 896 pkgconfig/gstreamer-video.pc
 897 pkgconfig/gstreamer-video-uninstalled.pc
 898 pkgconfig/gstreamer-plugins-base.pc
 899 pkgconfig/gstreamer-plugins-base-uninstalled.pc
 900 tests/Makefile
 901 tests/check/Makefile
 902 tests/examples/Makefile
 903 tests/examples/app/Makefile
 904 tests/examples/audio/Makefile
 905 tests/examples/dynamic/Makefile
 906 tests/examples/encoding/Makefile
 907 tests/examples/fft/Makefile
 908 tests/examples/gio/Makefile
 909 tests/examples/overlay/Makefile
 910 tests/examples/seek/Makefile
 911 tests/examples/snapshot/Makefile
 912 tests/examples/playback/Makefile
 913 tests/examples/playrec/Makefile
 914 tests/files/Makefile
 915 tests/icles/Makefile
 916 tests/icles/playback/Makefile
 917 docs/Makefile
 918 docs/design/Makefile
 919 docs/libs/Makefile
 920 docs/plugins/Makefile
 921 docs/version.entities
 922 po/Makefile.in
 923 common/Makefile
 924 common/m4/Makefile
 925 m4/Makefile
 926 )
 927
 928 dnl Create the config.h file for Visual Studio builds
 929 dnl Beware of spaces and /'s in some of the shell variable contents.
 930 sed \
 931     -e 's/.*config.h.in.*autoheader.*/\/* Autogenerated config.h created for win32 Visual Studio builds *\/\n\n\/* PREFIX -- specifically added for Windows for easier moving *\/\n#define PREFIX "C:\\\\gstreamer"/' \
 932     -e 's/.* GST_INSTALL_PLUGINS_HELPER/#define GST_INSTALL_PLUGINS_HELPER PREFIX "\\\\libexec\\\\gst-install-plugins-helper.exe"/' \
 933     -e 's/.* GETTEXT_PACKAGE$/#define GETTEXT_PACKAGE "'$GETTEXT_PACKAGE'"/' \
 934     -e 's/.* GST_DATADIR$/#define GST_DATADIR PREFIX "\\\\share"/' \
 935     -e 's/.* GST_LEVEL_DEFAULT$/#define GST_LEVEL_DEFAULT GST_LEVEL_ERROR/' \
 936     -e 's/.* GST_LICENSE$/#define GST_LICENSE "'$GST_LICENSE'"/' \
 937     -e 's/.* GST_API_VERSION$/#define GST_API_VERSION "'$GST_API_VERSION'"/' \
 938     -e "s,.* GST_PACKAGE_NAME$,#define GST_PACKAGE_NAME \"${GST_PACKAGE_NAME}\"," \
 939     -e 's/.* GST_PACKAGE_ORIGIN$/#define GST_PACKAGE_ORIGIN "Unknown package origin"/' \
 940     -e "s,.* GST_PACKAGE_RELEASE_DATETIME$,#define GST_PACKAGE_RELEASE_DATETIME \"${GST_PACKAGE_RELEASE_DATETIME}\"," \
 941     -e 's/.* HAVE_CPU_I386$/#define HAVE_CPU_I386 1/' \
 942     -e 's/.* HAVE_FGETPOS$/#define HAVE_FGETPOS 1/' \
 943     -e 's/.* HAVE_FSETPOS$/#define HAVE_FSETPOS 1/' \
 944     -e 's/.* HAVE_ISO_CODES$/#undef HAVE_ISO_CODES/' \
 945     -e 's/.* HAVE_LIBXML2$/#define HAVE_LIBXML2 1/' \
 946     -e 's/.* HAVE_PROCESS_H$/#define HAVE_PROCESS_H 1/' \
 947     -e 's/.* HAVE_STDLIB_H$/#define HAVE_STDLIB_H 1/' \
 948     -e 's/.* HAVE_STRING_H$/#define HAVE_STRING_H 1/' \
 949     -e 's/.* HAVE_SYS_STAT_H$/#define HAVE_SYS_STAT_H 1/' \
 950     -e 's/.* HAVE_SYS_TYPES_H$/#define HAVE_SYS_TYPES_H 1/' \
 951     -e 's/.* HAVE_WIN32$/#define HAVE_WIN32 1/' \
 952     -e 's/.* HOST_CPU$/#define HOST_CPU "i686"/' \
 953     -e 's/.* ISO_CODES_PREFIX$/#undef ISO_CODES_PREFIX/' \
 954     -e 's/.* ISO_CODES_VERSION$/#undef ISO_CODES_VERSION/' \
 955     -e 's/.* LIBDIR$/#ifdef _DEBUG\n#  define LIBDIR PREFIX "\\\\debug\\\\lib"\n#else\n#  define LIBDIR PREFIX "\\\\lib"\n#endif/' \
 956     -e 's/.* LOCALEDIR$/#define LOCALEDIR PREFIX "\\\\share\\\\locale"/' \
 957     -e "s/.* PACKAGE$/#define PACKAGE \"$PACKAGE\"/" \
 958     -e 's/.* PACKAGE_BUGREPORT$/#define PACKAGE_BUGREPORT "http:\/\/bugzilla.gnome.org\/enter_bug.cgi?product=GStreamer"/' \
 959     -e "s/.* PACKAGE_NAME$/#define PACKAGE_NAME \"$PACKAGE_NAME\"/" \
 960     -e "s/.* PACKAGE_STRING$/#define PACKAGE_STRING \"$PACKAGE_STRING\"/" \
 961     -e 's/.* PACKAGE_TARNAME$/#define PACKAGE_TARNAME "'$PACKAGE_TARNAME'"/' \
 962     -e 's/.* PACKAGE_VERSION$/#define PACKAGE_VERSION "'$PACKAGE_VERSION'"/' \
 963     -e 's/.* PLUGINDIR$/#ifdef _DEBUG\n#  define PLUGINDIR PREFIX "\\\\debug\\\\lib\\\\gstreamer-0.11"\n#else\n#  define PLUGINDIR PREFIX "\\\\lib\\\\gstreamer-0.11"\n#endif/' \
 964     -e 's/.* USE_BINARY_REGISTRY$/#define USE_BINARY_REGISTRY/' \
 965     -e 's/.* VERSION$/#define VERSION "'$VERSION'"/' \
 966     -e "s/.* DEFAULT_AUDIOSINK$/#define DEFAULT_AUDIOSINK \"directsoundsink\"/" \
 967     -e "s/.* DEFAULT_VIDEOSINK$/#define DEFAULT_VIDEOSINK \"directdrawsink\"/" \
 968     -e "s/.* DEFAULT_VISUALIZER$/#define DEFAULT_VISUALIZER \"goom\"/" \
 969     config.h.in >win32/common/config.h-new
 970
 971
 972
 973 AC_OUTPUT
 974
 975 AG_GST_OUTPUT_PLUGINS
 976 ORC_OUTPUT
 977