configure.ac

   1 AC_PREREQ(2.60)
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, git and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for git/prerelease
   8 AC_INIT(GStreamer Base Plug-ins, 0.11.1.1,
   9     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
  10     gst-plugins-base)
  11
  12 AG_GST_INIT
  13
  14 dnl initialize automake
  15 AM_INIT_AUTOMAKE([-Wno-portability 1.10])
  16
  17 dnl define PACKAGE_VERSION_* variables
  18 AS_VERSION
  19
  20 dnl check if this is a release version
  21 AS_NANO(GST_GIT="no", GST_GIT="yes")
  22
  23 dnl can autoconf find the source ?
  24 AC_CONFIG_SRCDIR([gst/audiotestsrc/gstaudiotestsrc.c])
  25
  26 dnl define the output header for config
  27 AM_CONFIG_HEADER([config.h])
  28
  29 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  30 AM_MAINTAINER_MODE
  31
  32 dnl sets host_* variables
  33 AC_CANONICAL_HOST
  34
  35 dnl use pretty build output with automake >= 1.11
  36 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],
  37   [AM_DEFAULT_VERBOSITY=1
  38    AC_SUBST(AM_DEFAULT_VERBOSITY)])
  39
  40 dnl our libraries and install dirs use major.minor as a version
  41 GST_MAJORMINOR=$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR
  42 dnl we override it here if we need to for the release candidate of new series
  43 GST_MAJORMINOR=0.11
  44 AC_SUBST(GST_MAJORMINOR)
  45
  46 dnl CURRENT, REVISION, AGE
  47 dnl - library source changed -> increment REVISION
  48 dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
  49 dnl - interfaces added -> increment AGE
  50 dnl - interfaces removed -> AGE = 0
  51 dnl sets GST_LT_LDFLAGS
  52 AS_LIBTOOL(GST, 26, 0, 0)
  53
  54 dnl FIXME: this macro doesn't actually work;
  55 dnl the generated libtool script has no support for the listed tags.
  56 dnl So this needs to be fixed first if we want to use this
  57 dnl AS_LIBTOOL_TAGS
  58
  59 AC_LIBTOOL_WIN32_DLL
  60 AM_PROG_LIBTOOL
  61
  62 dnl *** required versions of GStreamer stuff ***
  63 GST_REQ=0.11.1
  64
  65 dnl *** autotools stuff ****
  66
  67 dnl allow for different autotools
  68 AS_AUTOTOOLS_ALTERNATE
  69
  70 dnl Add parameters for aclocal
  71 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  72
  73 dnl set up gettext
  74 dnl the version check needs to stay here because autopoint greps for it
  75 AM_GNU_GETTEXT_VERSION([0.17])
  76 AM_GNU_GETTEXT([external])
  77 AG_GST_GETTEXT([gst-plugins-base-$GST_MAJORMINOR])
  78
  79 dnl *** check for arguments to configure ***
  80
  81 AG_GST_ARG_DEBUG
  82 AG_GST_ARG_PROFILING
  83 AG_GST_ARG_VALGRIND
  84 AG_GST_ARG_GCOV
  85
  86 AG_GST_ARG_EXAMPLES
  87
  88 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  89 AG_GST_ARG_WITH_PACKAGE_NAME
  90 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  91
  92 AG_GST_PKG_CONFIG_PATH
  93
  94 dnl let distro override plugin install helper path
  95 AC_ARG_WITH(install-plugins-helper,
  96   AC_HELP_STRING([--with-install-plugins-helper],
  97     [specify path of helper script to call to install plugins]),
  98   [
  99     case "${withval}" in
 100       yes) AC_MSG_ERROR(bad value ${withval} for --with-install-plugins-helper) ;;
 101       no)  AC_MSG_ERROR(bad value ${withval} for --with-install-plugins-helper) ;;
 102       *)   GST_INSTALL_PLUGINS_HELPER="${withval}" ;;
 103     esac
 104   ],
 105   [
 106     dnl Default value
 107     AS_AC_EXPAND(GST_INSTALL_PLUGINS_HELPER,${libexecdir}/gst-install-plugins-helper)
 108   ]
 109 )
 110 AC_MSG_NOTICE(Using $GST_INSTALL_PLUGINS_HELPER as plugin install helper)
 111 AC_DEFINE_UNQUOTED(GST_INSTALL_PLUGINS_HELPER, "$GST_INSTALL_PLUGINS_HELPER",
 112     [plugin install helper script])
 113 AC_SUBST(GST_INSTALL_PLUGINS_HELPER)
 114
 115 AG_GST_ARG_WITH_PLUGINS
 116
 117 AG_GST_ARG_ENABLE_EXTERNAL
 118
 119 AG_GST_ARG_ENABLE_EXPERIMENTAL
 120
 121 dnl *** checks for platform ***
 122
 123 dnl * hardware/architecture *
 124
 125 dnl common/m4/gst-arch.m4
 126 dnl check CPU type
 127 AG_GST_ARCH
 128
 129 dnl check for large file support
 130 dnl affected plugins must include config.h
 131 AC_SYS_LARGEFILE
 132
 133 dnl *** checks for programs ***
 134
 135 dnl find a compiler
 136 AC_PROG_CC
 137 AC_PROG_CC_STDC
 138
 139 dnl check if the compiler supports '-c' and '-o' options
 140 AM_PROG_CC_C_O
 141
 142 dnl determine if c++ is available on this system
 143 AC_PROG_CXX
 144 dnl CXX may be set to some default even if no c++ compiler is available
 145 dnl (thanks autotools!), so just try to compile some c++ code to make sure
 146 AC_LANG_PUSH([C++])
 147 AC_TRY_COMPILE([ class Foo { int bar; };], , working_cxx=yes, working_cxx=no)
 148 AC_LANG_POP([C++])
 149 AC_MSG_NOTICE([working c++ compiler found: $working_cxx])
 150 AM_CONDITIONAL(HAVE_CXX, test "x$working_cxx" = "xyes")
 151
 152 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 153 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 154
 155 dnl check for gobject-introspection
 156 GOBJECT_INTROSPECTION_CHECK([0.9.12])
 157
 158 dnl check for documentation tools
 159 GTK_DOC_CHECK([1.3])
 160 AS_PATH_PYTHON([2.1])
 161 AG_GST_PLUGIN_DOCS([1.3],[2.1])
 162
 163 dnl *** checks for libraries ***
 164
 165 dnl libm, for sin() etc.
 166 AC_CHECK_LIBM
 167 AC_SUBST(LIBM)
 168
 169 dnl *** checks for header files ***
 170
 171 dnl check if we have ANSI C header files
 172 AC_HEADER_STDC
 173
 174 ac_cppflags_save="$CPPFLAGS"
 175 CPPFLAGS="`$PKG_CONFIG --cflags libxml-2.0`"
 176 AC_COMPILE_IFELSE(
 177   AC_LANG_PROGRAM([
 178 #include <libxml/HTMLparser.h>
 179                      ],[
 180 #ifndef LIBXML_HTML_ENABLED
 181 #error libxml2 has no HTML support
 182 #endif /* LIBXML_HTML_ENABLED */
 183                    ]), HAVE_LIBXML_HTML="yes", HAVE_LIBXML_HTML="no")
 184 CPPFLAGS="$ac_cppflags_save"
 185 AM_CONDITIONAL(HAVE_LIBXML_HTML, test "x$HAVE_LIBXML_HTML" = "xyes")
 186
 187 dnl used in gst/tcp
 188 AC_CHECK_HEADERS([sys/socket.h],
 189   HAVE_SYS_SOCKET_H="yes", HAVE_SYS_SOCKET_H="no")
 190 AM_CONDITIONAL(HAVE_SYS_SOCKET_H, test "x$HAVE_SYS_SOCKET_H" = "xyes")
 191
 192 dnl used in gst-libs/gst/rtsp
 193 AC_CHECK_HEADERS([winsock2.h], HAVE_WINSOCK2_H=yes)
 194 if test "x$HAVE_WINSOCK2_H" = "xyes"; then
 195   WIN32_LIBS="-lws2_32"
 196   AC_SUBST(WIN32_LIBS)
 197 fi
 198
 199 dnl check for hstrerror, for gst-libs/gst/rtsp
 200 save_libs="$LIBS"
 201 AC_CHECK_FUNC(hstrerror, ,
 202     AC_CHECK_LIB(resolv, hstrerror, ,
 203         [AC_DEFINE(NO_HSTRERROR, 1,
 204              [Define if you have no native hstrerror() function.])]))
 205 HSTRERROR_LIBS=$LIBS
 206 AC_SUBST(HSTRERROR_LIBS)
 207 LIBS="$save_libs"
 208
 209 dnl used in gst-libs/gst/pbutils and associated unit test
 210 AC_CHECK_HEADERS([process.h sys/types.h sys/wait.h sys/stat.h])
 211
 212 dnl also, Windows does not have long long
 213 AX_CREATE_STDINT_H
 214
 215 dnl *** checks for functions ***
 216 AC_CHECK_FUNCS([localtime_r gmtime_r])
 217
 218 dnl *** checks for math functions ***
 219 LIBS_SAVE=$LIBS
 220 LIBS="$LIBS $LIBM"
 221 AC_CHECK_FUNCS(log2)
 222 LIBS=$LIBS_SAVE
 223
 224 dnl *** checks for types/defines ***
 225
 226 dnl Check for FIONREAD ioctl declaration
 227 dnl used in gst/tcp
 228 GST_CHECK_FIONREAD
 229
 230 dnl *** checks for structures ***
 231
 232 dnl *** checks for compiler characteristics ***
 233
 234 dnl *** checks for library functions ***
 235
 236 dnl check for fseeko()
 237 AC_FUNC_FSEEKO
 238
 239 dnl Check for fast float to int casting as defined in C99
 240 dnl used to be used in gst-libs/gst/floatcast/floatcast.h (FIXME: still needed?)
 241 save_libs=$LIBS
 242 LIBS="$LIBS $LIBM"
 243 AC_C99_FUNC_LRINT
 244 AC_C99_FUNC_LRINTF
 245 LIBS=$save_libs
 246
 247 dnl Check for a way to display the function name in debug output
 248 AG_GST_CHECK_FUNCTION
 249
 250 dnl *** checks for socket and nsl libraries ***
 251 AC_CHECK_FUNC(socket,,[AC_CHECK_LIB(socket,socket)])
 252 AC_CHECK_FUNC(gethostbyname,,[AC_CHECK_LIB(nsl,gethostbyname)])
 253
 254 dnl *** checks for dependency libraries ***
 255
 256 dnl GLib is required
 257 AG_GST_GLIB_CHECK([2.26])
 258
 259 ORC_CHECK([0.4.11])
 260
 261 dnl checks for gstreamer
 262 dnl uninstalled is selected preferentially -- see pkg-config(1)
 263 AG_GST_CHECK_GST($GST_MAJORMINOR, [$GST_REQ], yes)
 264 AG_GST_CHECK_GST_BASE($GST_MAJORMINOR, [$GST_REQ], yes)
 265 AG_GST_CHECK_GST_GDP($GST_MAJORMINOR, [$GST_REQ], yes)
 266 AG_GST_CHECK_GST_CONTROLLER($GST_MAJORMINOR, [$GST_REQ], yes)
 267 AG_GST_CHECK_GST_CHECK($GST_MAJORMINOR, [$GST_REQ], no)
 268 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 269
 270 dnl Check for documentation xrefs
 271 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 272 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_MAJORMINOR`"
 273 AC_SUBST(GLIB_PREFIX)
 274 AC_SUBST(GST_PREFIX)
 275
 276 dnl GTK is optional and only used in examples
 277 HAVE_GTK=no
 278 HAVE_GTK_X11=no
 279 GTK2_REQ=2.14.0
 280 GTK3_REQ=2.91.3
 281 if test "x$BUILD_EXAMPLES" = "xyes"; then
 282   AC_MSG_CHECKING([which gtk+ version to compile examples against (optional)])
 283   AC_ARG_WITH([gtk],
 284     AC_HELP_STRING([--with-gtk=3.0|2.0],
 285                    [which gtk+ version to compile against (default: 2.0)]),
 286     [case "$with_gtk" in
 287         2.0) GTK_REQ=$GTK2_REQ ;;
 288         3.0) GTK_REQ=$GTK3_REQ ;;
 289         *) AC_MSG_ERROR([invalid gtk+ version specified]);;
 290     esac],
 291     [with_gtk=2.0
 292      GTK_REQ=$GTK2_REQ])
 293   AC_MSG_RESULT([$with_gtk (>= $GTK_REQ)])
 294   PKG_CHECK_MODULES(GTK, gtk+-$with_gtk >= $GTK_REQ, HAVE_GTK=yes, HAVE_GTK=no)
 295   dnl some examples need gtk+-x11
 296   PKG_CHECK_MODULES(GTK_X11, gtk+-x11-$with_gtk >= $GTK_REQ, HAVE_GTK_X11=yes, HAVE_GTK_X11=no)
 297   AC_SUBST(GTK_LIBS)
 298   AC_SUBST(GTK_CFLAGS)
 299 fi
 300 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 301 AM_CONDITIONAL(HAVE_GTK_X11, test "x$HAVE_GTK_X11" = "xyes")
 302
 303 dnl QT is optional and only used in examples
 304 PKG_CHECK_MODULES(QT, QtGui >= 4.6, [
 305   HAVE_QT_GV=yes
 306   HAVE_QT=yes
 307 ], [
 308   HAVE_QT_GV=no
 309   PKG_CHECK_MODULES(QT, QtGui >= 4.0, HAVE_QT=yes, HAVE_QT=no)
 310 ])
 311 if test "x$HAVE_QT" = "xyes"; then
 312   AC_MSG_CHECKING([Qt moc])
 313   QT4_MOC=`$PKG_CONFIG --variable=moc_location QtGui`
 314   AC_MSG_RESULT($QT4_MOC)
 315   AC_SUBST(QT4_MOC)
 316 fi
 317 AM_CONDITIONAL(HAVE_QT, test "x$HAVE_QT" = "xyes")
 318 AM_CONDITIONAL(HAVE_QT_GV, test "x$HAVE_QT_GV" = "xyes")
 319
 320 dnl chck for linux headers needed by the joystick seek example
 321 AC_COMPILE_IFELSE(
 322 [
 323   AC_LANG_PROGRAM([
 324     #include <linux/input.h>
 325     #include <linux/joystick.h>
 326   ],[
 327     struct js_event js;
 328     js.type = JS_EVENT_AXIS;
 329   ])
 330 ], [
 331   HAVE_LINUX_JOYSTICK_HEADERS="yes"
 332 ], [
 333   HAVE_LINUX_JOYSTICK_HEADERS="no"
 334 ])
 335 AM_CONDITIONAL(HAVE_LINUX_JOYSTICK_HEADERS, test "x$HAVE_LINUX_JOYSTICK_HEADERS" = "xyes")
 336
 337 dnl Check for -Bsymbolic-functions linker flag used to avoid
 338 dnl intra-library PLT jumps, if available.
 339 AC_ARG_ENABLE(Bsymbolic,
 340               [AC_HELP_STRING([--disable-Bsymbolic],
 341                               [avoid linking with -Bsymbolic])],,
 342               [SAVED_LDFLAGS="${LDFLAGS}"
 343                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
 344                LDFLAGS=-Wl,-Bsymbolic-functions
 345                AC_TRY_LINK([], [int main (void) { return 0; }],
 346                            AC_MSG_RESULT(yes)
 347                            enable_Bsymbolic=yes,
 348                            AC_MSG_RESULT(no)
 349                            enable_Bsymbolic=no)
 350                LDFLAGS="${SAVED_LDFLAGS}"])
 351
 352
 353 dnl *** set variables based on configure arguments ***
 354
 355 dnl set license and copyright notice
 356 GST_LICENSE="LGPL"
 357 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 358 AC_SUBST(GST_LICENSE)
 359
 360 dnl set location of plugin directory
 361 AG_GST_SET_PLUGINDIR
 362
 363 dnl set release date/time
 364 AG_GST_SET_PACKAGE_RELEASE_DATETIME_WITH_NANO([$PACKAGE_VERSION_NANO],
 365   ["${srcdir}/gst-plugins-base.doap"],
 366   [$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_MICRO])
 367
 368 # set by AG_GST_PARSE_SUBSYSTEM_DISABLES above
 369 dnl make sure it doesn't complain about unused variables if debugging is disabled
 370 NO_WARNINGS=""
 371 AG_GST_CHECK_GST_DEBUG_DISABLED([NO_WARNINGS="-Wno-unused"], [NO_WARNINGS=""])
 372
 373 dnl define an ERROR_CFLAGS Makefile variable
 374 dnl -Wformat-nonliteral - see ext/pango/gstclockoverlay.c and http://gcc.gnu.org/bugzilla/show_bug.cgi?id=39438
 375 AG_GST_SET_ERROR_CFLAGS($GST_GIT, [
 376     -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls -Wundef
 377     -Wwrite-strings -Wformat-nonliteral -Wformat-security
 378     -Winit-self -Wmissing-include-dirs -Waddress -Waggregate-return
 379     -Wno-multichar -Wnested-externs $NO_WARNINGS])
 380
 381 dnl define an ERROR_CXXFLAGS Makefile variable
 382 AG_GST_SET_ERROR_CXXFLAGS($GST_GIT, [
 383     -Wmissing-declarations -Wredundant-decls -Wundef
 384     -Wwrite-strings -Wformat-nonliteral -Wformat-security
 385     -Winit-self -Wmissing-include-dirs -Waddress -Waggregate-return
 386     -Wno-multichar $NO_WARNINGS])
 387
 388 dnl define correct level for debugging messages
 389 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 390
 391 dnl used in examples
 392 AG_GST_DEFAULT_ELEMENTS
 393
 394 dnl needed for encoding-target
 395 GST_DATADIR="$GST_PREFIX/share"
 396 AC_DEFINE_UNQUOTED(GST_DATADIR, "$GST_DATADIR", [system wide data directory])
 397 AC_DEFINE_UNQUOTED(GST_MAJORMINOR, "$GST_MAJORMINOR", [major/minor version])
 398
 399 dnl behaviour of speex based audio resampler
 400 AC_MSG_CHECKING(which audio resample format to use for integer)
 401 AC_ARG_WITH([audioresample_format],
 402         AS_HELP_STRING([--with-audioresample-format],[Which implementation should be used for integer audio resampling, int/float/auto, (default is auto)]),
 403         [ac_cv_audioresample_format=$withval], [ac_cv_audioresample_format=auto])dnl
 404 AC_MSG_RESULT($ac_cv_audioresample_format)
 405 case $ac_cv_audioresample_format in
 406   int)
 407     AC_DEFINE(AUDIORESAMPLE_FORMAT_INT,1,[The int implementation should be used for integer audio resampling])
 408     AC_SUBST(AUDIORESAMPLE_FORMAT_INT)
 409   ;;
 410   float)
 411     AC_DEFINE(AUDIORESAMPLE_FORMAT_FLOAT,1,[The float implementation should be used for integer audio resampling])
 412     AC_SUBST(AUDIORESAMPLE_FORMAT_FLOAT)
 413   ;;
 414   auto)
 415     AC_DEFINE(AUDIORESAMPLE_FORMAT_AUTO,1,[The implementation that should be used for integer audio resampling witll be benchmarked at runtime])
 416     AC_SUBST(AUDIORESAMPLE_FORMAT_AUTO)
 417 esac
 418
 419 dnl *** plug-ins to include ***
 420
 421 dnl these are all the gst plug-ins, compilable without additional libs
 422 AG_GST_CHECK_PLUGIN(adder)
 423 AG_GST_CHECK_PLUGIN(app)
 424 AG_GST_CHECK_PLUGIN(audioconvert)
 425 AG_GST_CHECK_PLUGIN(audiorate)
 426 AG_GST_CHECK_PLUGIN(audiotestsrc)
 427 AG_GST_CHECK_PLUGIN(encoding)
 428 AG_GST_CHECK_PLUGIN(videoconvert)
 429 AG_GST_CHECK_PLUGIN(gdp)
 430 AG_GST_CHECK_PLUGIN(playback)
 431 AG_GST_CHECK_PLUGIN(audioresample)
 432 AG_GST_CHECK_PLUGIN(subparse)
 433 AG_GST_CHECK_PLUGIN(tcp)
 434 AG_GST_CHECK_PLUGIN(typefind)
 435 AG_GST_CHECK_PLUGIN(videotestsrc)
 436 AG_GST_CHECK_PLUGIN(videorate)
 437 AG_GST_CHECK_PLUGIN(videoscale)
 438 AG_GST_CHECK_PLUGIN(volume)
 439
 440 dnl FIXME 0.11: check for libxml, split subparse and move libxml parts to ext/
 441 AM_CONDITIONAL(USE_XML, false)
 442 AC_DEFINE([GST_DISABLE_XML], [1], [set to disable libxml2-dependent code in subparse])
 443
 444 dnl disable plug-ins that require libxml2's HTML support if it is not available
 445 if test "x$HAVE_LIBXML_HTML" != "xyes"; then
 446   AG_GST_DISABLE_PLUGIN(subparse)
 447 fi
 448
 449 dnl disable plug-ins that require sys/socket.h if it is not available
 450 if test "x$HAVE_SYS_SOCKET_H" != "xyes"; then
 451   AG_GST_DISABLE_PLUGIN(tcp)
 452 fi
 453
 454 dnl iso-codes is optional, used by libgsttag
 455 AC_ARG_ENABLE(iso-codes,
 456 AC_HELP_STRING([--enable-iso-codes],[use iso-codes if installed]),
 457 [case "${enableval}" in
 458   yes) enable_iso_codes=yes ;;
 459   no)  enable_iso_codes=no ;;
 460   *) AC_MSG_ERROR(bad value ${enableval} for --enable-iso-codes) ;;
 461 esac
 462 ],
 463 [enable_iso_codes=yes]) dnl Default value
 464
 465 AC_MSG_CHECKING([whether to use iso-codes if they are available])
 466 if test "x$enable_iso_codes" = "xyes"; then
 467   AC_MSG_RESULT([yes])
 468   have_iso_codes=no
 469   AC_MSG_CHECKING([whether iso-codes are available on this system])
 470   if $PKG_CONFIG iso-codes; then
 471     AC_MSG_RESULT([yes])
 472     AC_MSG_CHECKING([whether iso-codes has iso-639 domain])
 473     if $PKG_CONFIG --variable=domains iso-codes | $GREP -q 639 ; then
 474       AC_MSG_RESULT([yes])
 475       AC_MSG_CHECKING([for iso-codes prefix])
 476       ISO_CODES_PREFIX=`$PKG_CONFIG --variable=prefix iso-codes`
 477       if test -d "$ISO_CODES_PREFIX"; then
 478         AC_MSG_RESULT([yes])
 479         AC_MSG_CHECKING([ISO_CODES_PREFIX])
 480         AC_MSG_RESULT([$ISO_CODES_PREFIX])
 481         ISO_639_DOMAIN="iso_639"
 482         AC_MSG_CHECKING([ISO_639_DOMAIN])
 483         AC_MSG_RESULT([$ISO_639_DOMAIN])
 484         have_iso_codes=yes
 485         AC_DEFINE([HAVE_ISO_CODES], [1], [make use of iso-codes for ISO-639])
 486         AC_DEFINE_UNQUOTED([ISO_CODES_PREFIX], ["$ISO_CODES_PREFIX"], [prefix])
 487         ISO_CODES_VERSION=`$PKG_CONFIG --modversion iso-codes`
 488         AC_DEFINE_UNQUOTED([ISO_CODES_VERSION], ["$ISO_CODES_VERSION"], [ ])
 489       else
 490         AC_MSG_RESULT([no])
 491       fi
 492     else
 493       AC_MSG_RESULT([no])
 494     fi
 495   else
 496     AC_MSG_RESULT([no])
 497   fi
 498   AM_CONDITIONAL(USE_ISO_CODES, test "x$have_iso_codes" = "xyes")
 499 else
 500   AC_MSG_RESULT([no (disabled via --disable-iso-codes)])
 501   AM_CONDITIONAL(USE_ISO_CODES, false)
 502 fi
 503
 504 dnl *** zlib is optionally used by id3 tag parsing in libgsttag ***
 505 translit(dnm, m, l) AM_CONDITIONAL(USE_ZLIB, true)
 506 AG_GST_CHECK_FEATURE(ZLIB, [zlib support for ID3 parsing in libgsttag],, [
 507   PKG_CHECK_MODULES(ZLIB, [ zlib ], [
 508       HAVE_ZLIB="yes"
 509     ], [
 510       AG_GST_CHECK_LIBHEADER(ZLIB, z, uncompress,, zlib.h, [
 511         HAVE_ZLIB="yes"
 512         ZLIB_LIBS="-lz"
 513         AC_SUBST(ZLIB_LIBS)
 514       ])
 515     ])
 516 ])
 517
 518 dnl *** sys plug-ins ***
 519
 520 echo
 521 AC_MSG_NOTICE([Checking libraries for plugins in sys/])
 522 echo
 523
 524 dnl *** X11 ***
 525 translit(dnm, m, l) AM_CONDITIONAL(USE_X, true)
 526 AG_GST_CHECK_FEATURE(X, [X libraries and plugins],
 527                   [ximagesink], [
 528   AC_PATH_XTRA
 529   ac_cflags_save="$CFLAGS"
 530   ac_cppflags_save="$CPPFLAGS"
 531   CFLAGS="$CFLAGS $X_CFLAGS"
 532   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 533
 534   dnl now try to find the HEADER
 535   AC_CHECK_HEADER(X11/Xlib.h, HAVE_X="yes", HAVE_X="no")
 536
 537   if test "x$HAVE_X" = "xno"
 538   then
 539     AC_MSG_NOTICE([cannot find X11 development files])
 540   else
 541     dnl this is much more than we want
 542     X_LIBS="$X_LIBS $X_PRE_LIBS $X_EXTRA_LIBS"
 543     dnl AC_PATH_XTRA only defines the path needed to find the X libs,
 544     dnl it does not add the libs; therefore we add them here
 545     X_LIBS="$X_LIBS -lX11"
 546     AC_SUBST(X_CFLAGS)
 547     AC_SUBST(X_LIBS)
 548   fi
 549   AC_SUBST(HAVE_X)
 550   CFLAGS="$ac_cflags_save"
 551   CPPFLAGS="$ac_cppflags_save"
 552 ])
 553
 554 dnl Check for Xv extension
 555 translit(dnm, m, l) AM_CONDITIONAL(USE_XVIDEO, true)
 556 AG_GST_CHECK_FEATURE(XVIDEO, [X11 XVideo extensions],
 557                   [xvimagesink], [
 558   AG_GST_CHECK_XV
 559 ])
 560
 561 dnl check for X Shm
 562 translit(dnm, m, l) AM_CONDITIONAL(USE_XSHM, true)
 563 AG_GST_CHECK_FEATURE(XSHM, [X Shared Memory extension], , [
 564   if test x$HAVE_X = xyes; then
 565     AC_CHECK_LIB(Xext, XShmAttach,
 566                  HAVE_XSHM="yes", HAVE_XSHM="no",
 567                  $X_LIBS)
 568     if test "x$HAVE_XSHM" = "xyes"; then
 569       XSHM_LIBS="-lXext"
 570     else
 571       dnl On AIX, it is in XextSam instead, but we still need -lXext
 572       AC_CHECK_LIB(XextSam, XShmAttach,
 573                    HAVE_XSHM="yes", HAVE_XSHM="no",
 574                    $X_LIBS)
 575       if test "x$HAVE_XSHM" = "xyes"; then
 576         XSHM_LIBS="-lXext -lXextSam"
 577       fi
 578     fi
 579   fi
 580 ], , [
 581   AC_SUBST(HAVE_XSHM)
 582   AC_SUBST(XSHM_LIBS)
 583 ])
 584
 585 dnl *** ext plug-ins ***
 586 dnl keep this list sorted alphabetically !
 587
 588 if test "x$BUILD_EXTERNAL" = "xyes"; then
 589
 590 echo
 591 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 592 echo
 593
 594 dnl *** alsa ***
 595 translit(dnm, m, l) AM_CONDITIONAL(USE_ALSA, true)
 596 AG_GST_CHECK_FEATURE(ALSA, [ALSA], alsa, [
 597   PKG_CHECK_MODULES(ALSA, alsa >= 0.9.1, [
 598     HAVE_ALSA="yes"
 599     AC_SUBST(ALSA_CFLAGS)
 600     AC_SUBST(ALSA_LIBS)
 601   ], [
 602     AM_PATH_ALSA(0.9.1, HAVE_ALSA="yes", HAVE_ALSA="no")
 603   ])
 604 ])
 605
 606 dnl *** CDParanoia ***
 607 dnl Note: upstream has a pkg-config file only in post-10.2 SVN so far
 608 translit(dnm, m, l) AM_CONDITIONAL(USE_CDPARANOIA, true)
 609 AG_GST_CHECK_FEATURE(CDPARANOIA, [CDParanoia], cdparanoia, [
 610   PKG_CHECK_MODULES(CDPARANOIA, cdparanoia-3 >= 10.2, [
 611     HAVE_CDPARANOIA="yes"
 612   ], [
 613     AG_GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 614                         cdda_open, -lm,
 615                         cdda_interface.h,
 616                         CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 617                         HEADER_DIR="no"
 618                         FOUND_CDPARANOIA="yes")
 619     if test "x$FOUND_CDPARANOIA" != "xyes";
 620     then
 621       AG_GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 622                           cdda_open, -lm,
 623                           cdda/cdda_interface.h,
 624                           CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 625                           HEADER_DIR="yes"
 626                           FOUND_CDPARANOIA="yes")
 627     fi
 628     if test "x$HEADER_DIR" = "xyes";
 629     then
 630       AC_DEFINE_UNQUOTED(CDPARANOIA_HEADERS_IN_DIR, ,
 631                          defined if cdda headers are in a cdda/ directory)
 632     fi
 633     if test "x$FOUND_CDPARANOIA" = "xyes";
 634     then
 635       AC_CHECK_LIB(cdda_paranoia,
 636                    paranoia_cachemodel_size,
 637                    : ,
 638                    HAVE_CDPARANOIA=no,
 639                  [-lcdda_interface])
 640     fi
 641
 642     AC_SUBST(CDPARANOIA_LIBS)
 643   ])
 644 ])
 645 dnl FIXME : add second check somehow if that is necessary
 646 dnl AC_CHECK_LIB(cdda_paranoia, paranoia_init, : , HAVE_CDPARANOIA=no, -lcdda_interface )
 647 dnl AC_CHECK_HEADER(cdda_paranoia.h, :, HAVE_CDPARANOIA=no)
 648
 649 dnl *** ivorbis ***
 650 dnl AM_PATH_IVORBIS only takes two options
 651 translit(dnm, m, l) AM_CONDITIONAL(USE_IVORBIS, true)
 652 AG_GST_CHECK_FEATURE(IVORBIS, [integer vorbis plug-in], ivorbisdec, [
 653   AG_GST_PKG_CHECK_MODULES(IVORBIS, vorbisidec)
 654   if test $HAVE_IVORBIS = no
 655   then
 656     IVORBIS_LIBS=
 657     IVORBIS_CFLAGS=
 658     AC_CHECK_LIB(vorbisidec, vorbis_block_init,
 659       [IVORBIS_LIBS=-lvorbisidec
 660       HAVE_IVORBIS=yes
 661       case $host in
 662       arm-*-*)
 663         IVORBIS_CFLAGS="-D_ARM_ASSEM_ $IVORBIS_CFLAGS"
 664       esac
 665       ],
 666       HAVE_IVORBIS=no)
 667     AC_SUBST(IVORBIS_LIBS)
 668     AC_SUBST(IVORBIS_CFLAGS)
 669   else
 670     AC_CHECK_LIB(vorbisidec, vorbis_dsp_pcmout,
 671       AC_DEFINE([USE_TREMOLO],1, "Define if building for android"),
 672       USE_TREMOLO=no)
 673   fi
 674 ])
 675
 676 dnl *** libgio ***
 677 translit(dnm, m, l) AM_CONDITIONAL(USE_GIO, true)
 678 AG_GST_CHECK_FEATURE(GIO, [GIO library], gio, [
 679   PKG_CHECK_MODULES(GIO, gio-2.0 >= 2.16, [
 680     HAVE_GIO="yes"
 681     GIO_MODULE_DIR="`$PKG_CONFIG --variable=giomoduledir gio-2.0`"
 682     AC_DEFINE_UNQUOTED(GIO_MODULE_DIR, "$GIO_MODULE_DIR",
 683            [The GIO modules directory.])
 684     GIO_LIBDIR="`$PKG_CONFIG --variable=libdir gio-2.0`"
 685     AC_DEFINE_UNQUOTED(GIO_LIBDIR, "$GIO_LIBDIR",
 686            [The GIO library directory.])
 687   ], [
 688     HAVE_GIO="no"
 689   ])
 690   AC_SUBST(GIO_CFLAGS)
 691   AC_SUBST(GIO_LIBS)
 692   AC_SUBST(GIO_LDFLAGS)
 693 ])
 694
 695 dnl *** libvisual ***
 696 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBVISUAL, true)
 697 AG_GST_CHECK_FEATURE(LIBVISUAL, [libvisual visualization library], libvisual, [
 698   AG_GST_PKG_CHECK_MODULES(LIBVISUAL, libvisual-0.4 >= 0.4.0)
 699   if test $HAVE_LIBVISUAL = no
 700   then
 701     AG_GST_PKG_CHECK_MODULES(LIBVISUAL, libvisual = 0.2.0)
 702     if test x$HAVE_LIBVISUAL = xyes; then
 703       LIBVIS_PLUGINSDIR="`$PKG_CONFIG --variable=pluginsbasedir libvisual-0.2`"
 704     fi
 705   else
 706     if test x$HAVE_LIBVISUAL = xyes; then
 707       LIBVIS_PLUGINSDIR="`$PKG_CONFIG --variable=pluginsbasedir libvisual-0.4`"
 708     fi
 709   fi
 710   AC_MSG_NOTICE([libvisual pluginsdir: $LIBVIS_PLUGINSDIR])
 711   if test x$LIBVIS_PLUGINSDIR != x; then
 712     AC_DEFINE_UNQUOTED(LIBVISUAL_PLUGINSBASEDIR,
 713         "$LIBVIS_PLUGINSDIR",
 714         [directory in which the detected libvisual's plugins are located])
 715   fi
 716 ])
 717
 718 dnl *** ogg ***
 719 translit(dnm, m, l) AM_CONDITIONAL(USE_OGG, true)
 720 AG_GST_CHECK_FEATURE(OGG, [Xiph Ogg library], ogg, [
 721   AG_GST_PKG_CHECK_MODULES(OGG, ogg >= 1.0)
 722   if test $HAVE_OGG = no
 723   then
 724     XIPH_PATH_OGG(HAVE_OGG="yes", HAVE_OGG="no")
 725     AS_SCRUB_INCLUDE(OGG_CFLAGS)
 726   fi
 727 ])
 728
 729 dnl *** pango ***
 730 translit(dnm, m, l) AM_CONDITIONAL(USE_PANGO, true)
 731 AG_GST_CHECK_FEATURE(PANGO, [Pango font rendering], pango, [
 732   AG_GST_PKG_CHECK_MODULES(PANGO, pango >= 1.16.0  pangocairo >= 1.16.0)
 733 ])
 734
 735 dnl *** theora ***
 736 translit(dnm, m, l) AM_CONDITIONAL(USE_THEORA, true)
 737 AG_GST_CHECK_FEATURE(THEORA, [Xiph Theora video codec], theora, [
 738   AG_GST_PKG_CHECK_MODULES(THEORA, theoradec >= 1.1 theoraenc >= 1.1)
 739 ])
 740
 741 dnl *** vorbis ***
 742 dnl AM_PATH_VORBIS only takes two options
 743 translit(dnm, m, l) AM_CONDITIONAL(USE_VORBIS, true)
 744 AG_GST_CHECK_FEATURE(VORBIS, [Xiph Vorbis audio codec], vorbis, [
 745   AG_GST_PKG_CHECK_MODULES(VORBIS, vorbis >= 1.0 vorbisenc >= 1.0)
 746   if test $HAVE_VORBIS = no
 747   then
 748     XIPH_PATH_VORBIS(HAVE_VORBIS="yes", HAVE_VORBIS="no")
 749     AS_SCRUB_INCLUDE(VORBIS_CFLAGS)
 750   fi
 751 ])
 752
 753 if test "x$HAVE_VORBIS" = "xyes"; then
 754   ac_cflags_save="$CFLAGS"
 755   AC_COMPILE_IFELSE(
 756     AC_LANG_PROGRAM([
 757 #include <vorbis/codec.h>
 758                      ],[
 759 vorbis_dsp_state *v;
 760
 761 vorbis_synthesis_restart (v);
 762                      ]), HAVE_VSR=yes, HAVE_VSR=no)
 763   if test "x$HAVE_VSR" = "xyes"; then
 764     AC_DEFINE_UNQUOTED(HAVE_VORBIS_SYNTHESIS_RESTART, 1,
 765                        [defined if vorbis_synthesis_restart is present])
 766   fi
 767   CFLAGS="$ac_cflags_save"
 768 fi
 769
 770 else
 771
 772 dnl not building plugins with external dependencies,
 773 dnl but we still need to set the conditionals
 774 AM_CONDITIONAL(USE_ALSA, false)
 775 AM_CONDITIONAL(USE_CDPARANOIA, false)
 776 AM_CONDITIONAL(USE_GIO, false)
 777 AM_CONDITIONAL(USE_IVORBIS, false)
 778 AM_CONDITIONAL(USE_LIBVISUAL, false)
 779 AM_CONDITIONAL(USE_OGG, false)
 780 AM_CONDITIONAL(USE_PANGO, false)
 781 AM_CONDITIONAL(USE_THEORA, false)
 782 AM_CONDITIONAL(USE_VORBIS, false)
 783
 784 fi dnl of EXT plugins
 785
 786 dnl seeking needs freetype, so check for it here
 787 PKG_CHECK_MODULES(FT2, freetype2 >= 2.0.9, HAVE_FT2="yes", [
 788   AC_CHECK_FT2(2.0.9, HAVE_FT2="yes", HAVE_FT2="no")
 789 ])
 790 dnl make the HAVE_FT2 variable available to automake and Makefile.am
 791 AM_CONDITIONAL(HAVE_FT2, test "x$HAVE_FT2" = "xyes")
 792 AC_SUBST(FT2_CFLAGS)
 793 AC_SUBST(FT2_LIBS)
 794
 795 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 796
 797 dnl Overview:
 798 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
 799 dnl GST_*:              flags shared by built objects to link against GStreamer
 800 dnl GST_PLUGINS_BASE_CFLAGS: to link internally against the plugins base libs
 801 dnl                          (compare to other modules) or for i18n
 802 dnl GST_ALL_LDFLAGS:    linker flags shared by all
 803 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 804 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 805 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 806
 807 dnl GST_OPTION_CFLAGS
 808 if test "x$USE_DEBUG" = xyes; then
 809    PROFILE_CFLAGS="-g"
 810 fi
 811 AC_SUBST(PROFILE_CFLAGS)
 812
 813 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
 814   dnl Define _only_ when compiling a git version (not pre-releases or releases)
 815   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 816 else
 817   DEPRECATED_CFLAGS=""
 818 fi
 819 AC_SUBST(DEPRECATED_CFLAGS)
 820
 821 dnl every flag in GST_OPTION_CFLAGS and GST_OPTION_CXXFLAGS can be overridden
 822 dnl at make time with e.g. make ERROR_CFLAGS=""
 823 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 824 GST_OPTION_CXXFLAGS="\$(WARNING_CXXFLAGS) \$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 825 AC_SUBST(GST_OPTION_CFLAGS)
 826 AC_SUBST(GST_OPTION_CXXFLAGS)
 827
 828 dnl our libraries need to be versioned correctly
 829 AC_SUBST(GST_LT_LDFLAGS)
 830
 831 dnl GST_PLUGINS_BASE_CFLAGS
 832 dnl prefer internal headers to already installed ones
 833 dnl also add builddir include for enumtypes and marshal
 834 GST_PLUGINS_BASE_CFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs"
 835 AC_SUBST(GST_PLUGINS_BASE_CFLAGS)
 836
 837 dnl FIXME: do we want to rename to GST_ALL_* ?
 838 dnl add GST_OPTION_CFLAGS, but overridable
 839 GST_CFLAGS="$GST_CFLAGS -DGST_USE_UNSTABLE_API"
 840 GST_CXXFLAGS="$GLIB_CFLAGS $GST_CFLAGS \$(GLIB_EXTRA_CFLAGS) \$(GST_OPTION_CXXFLAGS)"
 841 GST_CFLAGS="$GLIB_CFLAGS $GST_CFLAGS \$(GLIB_EXTRA_CFLAGS) \$(GST_OPTION_CFLAGS)"
 842 AC_SUBST(GST_CFLAGS)
 843 AC_SUBST(GST_CXXFLAGS)
 844 dnl add GCOV libs because libtool strips -fprofile-arcs -ftest-coverage
 845 GST_LIBS="$GST_LIBS \$(GCOV_LIBS)"
 846 AC_SUBST(GST_LIBS)
 847
 848 dnl LDFLAGS really should only contain flags, not libs - they get added before
 849 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 850 GST_ALL_LDFLAGS="-no-undefined"
 851 if test "x${enable_Bsymbolic}" = "xyes"; then
 852   GST_ALL_LDFLAGS="$GST_ALL_LDFLAGS -Wl,-Bsymbolic-functions"
 853 fi
 854 AC_SUBST(GST_ALL_LDFLAGS)
 855
 856 dnl GST_LIB_LDFLAGS
 857 dnl linker flags shared by all libraries
 858 dnl LDFLAGS modifier defining exported symbols from built libraries
 859 dnl (export _gst_foo but not __gst_foo)
 860 GST_LIB_LDFLAGS="-export-symbols-regex ^_?\(gst_\|Gst\|GST_\).*"
 861 AC_SUBST(GST_LIB_LDFLAGS)
 862
 863 dnl this really should only contain flags, not libs - they get added before
 864 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 865 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc.*' $GST_ALL_LDFLAGS"
 866 AC_SUBST(GST_PLUGIN_LDFLAGS)
 867
 868 dnl *** output files ***
 869
 870 AC_CONFIG_FILES(
 871 Makefile
 872 gst-plugins-base.spec
 873 gst/Makefile
 874 gst/adder/Makefile
 875 gst/app/Makefile
 876 gst/audioconvert/Makefile
 877 gst/audiorate/Makefile
 878 gst/audiotestsrc/Makefile
 879 gst/encoding/Makefile
 880 gst/videoconvert/Makefile
 881 gst/gdp/Makefile
 882 gst/playback/Makefile
 883 gst/audioresample/Makefile
 884 gst/subparse/Makefile
 885 gst/tcp/Makefile
 886 gst/typefind/Makefile
 887 gst/videotestsrc/Makefile
 888 gst/videorate/Makefile
 889 gst/videoscale/Makefile
 890 gst/volume/Makefile
 891 sys/Makefile
 892 sys/ximage/Makefile
 893 sys/xvimage/Makefile
 894 ext/Makefile
 895 ext/alsa/Makefile
 896 ext/cdparanoia/Makefile
 897 ext/gio/Makefile
 898 ext/libvisual/Makefile
 899 ext/ogg/Makefile
 900 ext/pango/Makefile
 901 ext/theora/Makefile
 902 ext/vorbis/Makefile
 903 gst-libs/Makefile
 904 gst-libs/gst/Makefile
 905 gst-libs/gst/audio/Makefile
 906 gst-libs/gst/app/Makefile
 907 gst-libs/gst/cdda/Makefile
 908 gst-libs/gst/fft/Makefile
 909 gst-libs/gst/interfaces/Makefile
 910 gst-libs/gst/riff/Makefile
 911 gst-libs/gst/rtp/Makefile
 912 gst-libs/gst/rtsp/Makefile
 913 gst-libs/gst/sdp/Makefile
 914 gst-libs/gst/tag/Makefile
 915 gst-libs/gst/pbutils/Makefile
 916 gst-libs/gst/pbutils/gstpluginsbaseversion.h
 917 gst-libs/gst/video/Makefile
 918 tools/Makefile
 919 pkgconfig/Makefile
 920 pkgconfig/gstreamer-audio.pc
 921 pkgconfig/gstreamer-audio-uninstalled.pc
 922 pkgconfig/gstreamer-app.pc
 923 pkgconfig/gstreamer-app-uninstalled.pc
 924 pkgconfig/gstreamer-cdda.pc
 925 pkgconfig/gstreamer-cdda-uninstalled.pc
 926 pkgconfig/gstreamer-fft.pc
 927 pkgconfig/gstreamer-fft-uninstalled.pc
 928 pkgconfig/gstreamer-interfaces.pc
 929 pkgconfig/gstreamer-interfaces-uninstalled.pc
 930 pkgconfig/gstreamer-pbutils.pc
 931 pkgconfig/gstreamer-pbutils-uninstalled.pc
 932 pkgconfig/gstreamer-riff.pc
 933 pkgconfig/gstreamer-riff-uninstalled.pc
 934 pkgconfig/gstreamer-rtp.pc
 935 pkgconfig/gstreamer-rtp-uninstalled.pc
 936 pkgconfig/gstreamer-rtsp.pc
 937 pkgconfig/gstreamer-rtsp-uninstalled.pc
 938 pkgconfig/gstreamer-sdp.pc
 939 pkgconfig/gstreamer-sdp-uninstalled.pc
 940 pkgconfig/gstreamer-tag.pc
 941 pkgconfig/gstreamer-tag-uninstalled.pc
 942 pkgconfig/gstreamer-video.pc
 943 pkgconfig/gstreamer-video-uninstalled.pc
 944 pkgconfig/gstreamer-plugins-base.pc
 945 pkgconfig/gstreamer-plugins-base-uninstalled.pc
 946 tests/Makefile
 947 tests/check/Makefile
 948 tests/examples/Makefile
 949 tests/examples/app/Makefile
 950 tests/examples/audio/Makefile
 951 tests/examples/dynamic/Makefile
 952 tests/examples/encoding/Makefile
 953 tests/examples/gio/Makefile
 954 tests/examples/overlay/Makefile
 955 tests/examples/seek/Makefile
 956 tests/examples/snapshot/Makefile
 957 tests/examples/playrec/Makefile
 958 tests/files/Makefile
 959 tests/icles/Makefile
 960 tests/icles/playback/Makefile
 961 docs/Makefile
 962 docs/design/Makefile
 963 docs/libs/Makefile
 964 docs/plugins/Makefile
 965 docs/version.entities
 966 po/Makefile.in
 967 common/Makefile
 968 common/m4/Makefile
 969 m4/Makefile
 970 )
 971
 972 dnl Create the config.h file for Visual Studio builds
 973 dnl Beware of spaces and /'s in some of the shell variable contents.
 974 sed \
 975     -e 's/.*config.h.in.*autoheader.*/\/* Autogenerated config.h created for win32 Visual Studio builds *\/\n\n\/* PREFIX -- specifically added for Windows for easier moving *\/\n#define PREFIX "C:\\\\gstreamer"/' \
 976     -e 's/.* GST_INSTALL_PLUGINS_HELPER/#define GST_INSTALL_PLUGINS_HELPER PREFIX "\\\\libexec\\\\gst-install-plugins-helper.exe"/' \
 977     -e 's/.* GETTEXT_PACKAGE$/#define GETTEXT_PACKAGE "'$GETTEXT_PACKAGE'"/' \
 978     -e 's/.* GST_DATADIR$/#define GST_DATADIR PREFIX "\\\\share"/' \
 979     -e 's/.* GST_LEVEL_DEFAULT$/#define GST_LEVEL_DEFAULT GST_LEVEL_ERROR/' \
 980     -e 's/.* GST_LICENSE$/#define GST_LICENSE "'$GST_LICENSE'"/' \
 981     -e 's/.* GST_MAJORMINOR$/#define GST_MAJORMINOR "'$GST_MAJORMINOR'"/' \
 982     -e "s,.* GST_PACKAGE_NAME$,#define GST_PACKAGE_NAME \"${GST_PACKAGE_NAME}\"," \
 983     -e 's/.* GST_PACKAGE_ORIGIN$/#define GST_PACKAGE_ORIGIN "Unknown package origin"/' \
 984     -e "s,.* GST_PACKAGE_RELEASE_DATETIME$,#define GST_PACKAGE_RELEASE_DATETIME \"${GST_PACKAGE_RELEASE_DATETIME}\"," \
 985     -e 's/.* HAVE_CPU_I386$/#define HAVE_CPU_I386 1/' \
 986     -e 's/.* HAVE_FGETPOS$/#define HAVE_FGETPOS 1/' \
 987     -e 's/.* HAVE_FSETPOS$/#define HAVE_FSETPOS 1/' \
 988     -e 's/.* HAVE_ISO_CODES$/#undef HAVE_ISO_CODES/' \
 989     -e 's/.* HAVE_LIBXML2$/#define HAVE_LIBXML2 1/' \
 990     -e 's/.* HAVE_PROCESS_H$/#define HAVE_PROCESS_H 1/' \
 991     -e 's/.* HAVE_STDLIB_H$/#define HAVE_STDLIB_H 1/' \
 992     -e 's/.* HAVE_STRING_H$/#define HAVE_STRING_H 1/' \
 993     -e 's/.* HAVE_SYS_STAT_H$/#define HAVE_SYS_STAT_H 1/' \
 994     -e 's/.* HAVE_SYS_TYPES_H$/#define HAVE_SYS_TYPES_H 1/' \
 995     -e 's/.* HAVE_WIN32$/#define HAVE_WIN32 1/' \
 996     -e 's/.* HAVE_WINSOCK2_H$/#define HAVE_WINSOCK2_H 1/' \
 997     -e 's/.* HOST_CPU$/#define HOST_CPU "i686"/' \
 998     -e 's/.* ISO_CODES_PREFIX$/#undef ISO_CODES_PREFIX/' \
 999     -e 's/.* ISO_CODES_VERSION$/#undef ISO_CODES_VERSION/' \
1000     -e 's/.* LIBDIR$/#ifdef _DEBUG\n#  define LIBDIR PREFIX "\\\\debug\\\\lib"\n#else\n#  define LIBDIR PREFIX "\\\\lib"\n#endif/' \
1001     -e 's/.* LOCALEDIR$/#define LOCALEDIR PREFIX "\\\\share\\\\locale"/' \
1002     -e "s/.* PACKAGE$/#define PACKAGE \"$PACKAGE\"/" \
1003     -e 's/.* PACKAGE_BUGREPORT$/#define PACKAGE_BUGREPORT "http:\/\/bugzilla.gnome.org\/enter_bug.cgi?product=GStreamer"/' \
1004     -e "s/.* PACKAGE_NAME$/#define PACKAGE_NAME \"$PACKAGE_NAME\"/" \
1005     -e "s/.* PACKAGE_STRING$/#define PACKAGE_STRING \"$PACKAGE_STRING\"/" \
1006     -e 's/.* PACKAGE_TARNAME$/#define PACKAGE_TARNAME "'$PACKAGE_TARNAME'"/' \
1007     -e 's/.* PACKAGE_VERSION$/#define PACKAGE_VERSION "'$PACKAGE_VERSION'"/' \
1008     -e 's/.* PLUGINDIR$/#ifdef _DEBUG\n#  define PLUGINDIR PREFIX "\\\\debug\\\\lib\\\\gstreamer-0.11"\n#else\n#  define PLUGINDIR PREFIX "\\\\lib\\\\gstreamer-0.11"\n#endif/' \
1009     -e 's/.* USE_BINARY_REGISTRY$/#define USE_BINARY_REGISTRY/' \
1010     -e 's/.* VERSION$/#define VERSION "'$VERSION'"/' \
1011     -e "s/.* DEFAULT_AUDIOSINK$/#define DEFAULT_AUDIOSINK \"directsoundsink\"/" \
1012     -e "s/.* DEFAULT_VIDEOSINK$/#define DEFAULT_VIDEOSINK \"directdrawsink\"/" \
1013     -e "s/.* DEFAULT_VISUALIZER$/#define DEFAULT_VISUALIZER \"goom\"/" \
1014     config.h.in >win32/common/config.h-new
1015
1016
1017
1018 AC_OUTPUT
1019
1020 AG_GST_OUTPUT_PLUGINS
1021 ORC_OUTPUT
1022