configure.ac

   1 AC_PREREQ(2.62)
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, git and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for git/prerelease
   8 AC_INIT(GStreamer Base Plug-ins, 1.0.1.1,
   9     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
  10     gst-plugins-base)
  11
  12 AG_GST_INIT
  13
  14 dnl initialize automake
  15 AM_INIT_AUTOMAKE([-Wno-portability 1.11 no-dist-gzip dist-xz tar-ustar])
  16
  17 dnl define PACKAGE_VERSION_* variables
  18 AS_VERSION
  19
  20 dnl check if this is a release version
  21 AS_NANO(GST_GIT="no", GST_GIT="yes")
  22
  23 dnl can autoconf find the source ?
  24 AC_CONFIG_SRCDIR([gst/audiotestsrc/gstaudiotestsrc.c])
  25
  26 dnl define the output header for config
  27 AM_CONFIG_HEADER([config.h])
  28
  29 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  30 AM_MAINTAINER_MODE([enable])
  31
  32 dnl sets host_* variables
  33 AC_CANONICAL_HOST
  34
  35 dnl use pretty build output with automake >= 1.11
  36 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],
  37   [AM_DEFAULT_VERBOSITY=1
  38    AC_SUBST(AM_DEFAULT_VERBOSITY)])
  39
  40 dnl our libraries and install dirs use GST_API_VERSION in the filename
  41 dnl to allow side-by-side installation of different API versions
  42 GST_API_VERSION=1.0
  43 AC_SUBST(GST_API_VERSION)
  44 AC_DEFINE_UNQUOTED(GST_API_VERSION, "$GST_API_VERSION",
  45   [GStreamer API Version])
  46
  47 dnl CURRENT, REVISION, AGE
  48 dnl - library source changed -> increment REVISION
  49 dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
  50 dnl - interfaces added -> increment AGE
  51 dnl - interfaces removed -> AGE = 0
  52 dnl sets GST_LT_LDFLAGS
  53 AS_LIBTOOL(GST, 1, 0, 1)
  54
  55 dnl *** required versions of GStreamer stuff ***
  56 GST_REQ=1.0.0
  57
  58 dnl *** autotools stuff ****
  59
  60 dnl allow for different autotools
  61 AS_AUTOTOOLS_ALTERNATE
  62
  63 dnl Add parameters for aclocal
  64 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  65
  66 dnl set up gettext
  67 dnl the version check needs to stay here because autopoint greps for it
  68 AM_GNU_GETTEXT_VERSION([0.17])
  69 AM_GNU_GETTEXT([external])
  70 AG_GST_GETTEXT([gst-plugins-base-$GST_API_VERSION])
  71
  72 dnl *** check for arguments to configure ***
  73
  74 AG_GST_ARG_DISABLE_FATAL_WARNINGS
  75
  76 AG_GST_ARG_DEBUG
  77 AG_GST_ARG_PROFILING
  78 AG_GST_ARG_VALGRIND
  79 AG_GST_ARG_GCOV
  80
  81 AG_GST_ARG_EXAMPLES
  82
  83 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  84 AG_GST_ARG_WITH_PACKAGE_NAME
  85 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  86
  87 AG_GST_PKG_CONFIG_PATH
  88
  89 dnl let distro override plugin install helper path
  90 AC_ARG_WITH(install-plugins-helper,
  91   AC_HELP_STRING([--with-install-plugins-helper],
  92     [specify path of helper script to call to install plugins]),
  93   [
  94     case "${withval}" in
  95       yes) AC_MSG_ERROR(bad value ${withval} for --with-install-plugins-helper) ;;
  96       no)  AC_MSG_ERROR(bad value ${withval} for --with-install-plugins-helper) ;;
  97       *)   GST_INSTALL_PLUGINS_HELPER="${withval}" ;;
  98     esac
  99   ],
 100   [
 101     dnl Default value
 102     AS_AC_EXPAND(GST_INSTALL_PLUGINS_HELPER,${libexecdir}/gst-install-plugins-helper)
 103   ]
 104 )
 105 AC_MSG_NOTICE(Using $GST_INSTALL_PLUGINS_HELPER as plugin install helper)
 106 AC_DEFINE_UNQUOTED(GST_INSTALL_PLUGINS_HELPER, "$GST_INSTALL_PLUGINS_HELPER",
 107     [plugin install helper script])
 108 AC_SUBST(GST_INSTALL_PLUGINS_HELPER)
 109
 110 AG_GST_ARG_WITH_PLUGINS
 111
 112 AG_GST_ARG_ENABLE_EXTERNAL
 113
 114 AG_GST_ARG_ENABLE_EXPERIMENTAL
 115
 116 dnl *** checks for platform ***
 117 AG_GST_PLATFORM
 118
 119 dnl * hardware/architecture *
 120
 121 dnl common/m4/gst-arch.m4
 122 dnl check CPU type
 123 AG_GST_ARCH
 124
 125 dnl check for large file support
 126 dnl affected plugins must include config.h
 127 AC_SYS_LARGEFILE
 128
 129 dnl *** checks for programs ***
 130
 131 dnl find a compiler
 132 AC_PROG_CC
 133 AC_PROG_CC_STDC
 134
 135 dnl check if the compiler supports '-c' and '-o' options
 136 AM_PROG_CC_C_O
 137
 138 dnl determine if c++ is available on this system
 139 AC_PROG_CXX
 140 dnl CXX may be set to some default even if no c++ compiler is available
 141 dnl (thanks autotools!), so just try to compile some c++ code to make sure
 142 AC_LANG_PUSH([C++])
 143 AC_TRY_COMPILE([ class Foo { int bar; };], , working_cxx=yes, working_cxx=no)
 144 AC_LANG_POP([C++])
 145 AC_MSG_NOTICE([working c++ compiler found: $working_cxx])
 146 AM_CONDITIONAL(HAVE_CXX, test "x$working_cxx" = "xyes")
 147
 148 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 149 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 150
 151 dnl check for gobject-introspection
 152 GOBJECT_INTROSPECTION_CHECK([1.31.1])
 153
 154 dnl check for documentation tools
 155 GTK_DOC_CHECK([1.12])
 156 AS_PATH_PYTHON([2.1])
 157 AG_GST_PLUGIN_DOCS([1.3],[2.1])
 158
 159 dnl *** checks for libraries ***
 160
 161 dnl libm, for sin() etc.
 162 LT_LIB_M
 163 AC_SUBST(LIBM)
 164
 165 dnl *** checks for header files ***
 166
 167 dnl check if we have ANSI C header files
 168 AC_HEADER_STDC
 169
 170 dnl check for GCC specific SSE headers
 171 dnl these are used by the speex resampler code
 172 AC_CHECK_HEADERS([xmmintrin.h emmintrin.h])
 173
 174 ac_cppflags_save="$CPPFLAGS"
 175 CPPFLAGS="`$PKG_CONFIG --cflags libxml-2.0`"
 176 AC_COMPILE_IFELSE([
 177   AC_LANG_PROGRAM([[
 178 #include <libxml/HTMLparser.h>
 179 ]],[[
 180 #ifndef LIBXML_HTML_ENABLED
 181 #error libxml2 has no HTML support
 182 #endif /* LIBXML_HTML_ENABLED */
 183 ]])], [
 184   HAVE_LIBXML_HTML="yes"
 185 ], [
 186   HAVE_LIBXML_HTML="no"
 187 ])
 188 CPPFLAGS="$ac_cppflags_save"
 189 AM_CONDITIONAL(HAVE_LIBXML_HTML, test "x$HAVE_LIBXML_HTML" = "xyes")
 190
 191 dnl used in gst/tcp
 192 AC_CHECK_HEADERS([sys/socket.h],
 193   [HAVE_SYS_SOCKET_H="yes"], [HAVE_SYS_SOCKET_H="no"], [AC_INCLUDES_DEFAULT])
 194 AM_CONDITIONAL(HAVE_SYS_SOCKET_H, test "x$HAVE_SYS_SOCKET_H" = "xyes")
 195
 196 dnl used in gst-libs/gst/pbutils and associated unit test
 197 AC_CHECK_HEADERS([process.h sys/types.h sys/wait.h sys/stat.h], [], [], [AC_INCLUDES_DEFAULT])
 198
 199 dnl also, Windows does not have long long
 200 AX_CREATE_STDINT_H
 201
 202 dnl *** checks for functions ***
 203 AC_CHECK_FUNCS([localtime_r gmtime_r])
 204
 205 dnl *** checks for math functions ***
 206 LIBS_SAVE=$LIBS
 207 LIBS="$LIBS $LIBM"
 208 AC_CHECK_FUNCS(log2)
 209 LIBS=$LIBS_SAVE
 210
 211 dnl *** checks for types/defines ***
 212
 213 dnl *** checks for structures ***
 214
 215 dnl *** checks for compiler characteristics ***
 216
 217 dnl *** checks for library functions ***
 218
 219 dnl check for fseeko()
 220 AC_FUNC_FSEEKO
 221
 222 dnl Check for fast float to int casting as defined in C99
 223 dnl used to be used in gst-libs/gst/floatcast/floatcast.h (FIXME: still needed?)
 224 save_libs=$LIBS
 225 LIBS="$LIBS $LIBM"
 226 AC_C99_FUNC_LRINT
 227 AC_C99_FUNC_LRINTF
 228 LIBS=$save_libs
 229
 230 dnl Check for a way to display the function name in debug output
 231 AG_GST_CHECK_FUNCTION
 232
 233 dnl *** checks for dependency libraries ***
 234
 235 dnl GLib
 236 GLIB_REQ=2.32
 237 AG_GST_GLIB_CHECK([$GLIB_REQ])
 238
 239 ORC_CHECK([0.4.16])
 240
 241 dnl checks for gstreamer
 242 dnl uninstalled is selected preferentially -- see pkg-config(1)
 243 AG_GST_CHECK_GST($GST_API_VERSION, [$GST_REQ], yes)
 244 AG_GST_CHECK_GST_BASE($GST_API_VERSION, [$GST_REQ], yes)
 245 AG_GST_CHECK_GST_CONTROLLER($GST_API_VERSION, [$GST_REQ], yes)
 246 AG_GST_CHECK_GST_CHECK($GST_API_VERSION, [$GST_REQ], no)
 247 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 248
 249 dnl Check for documentation xrefs
 250 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 251 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_API_VERSION`"
 252 AC_SUBST(GLIB_PREFIX)
 253 AC_SUBST(GST_PREFIX)
 254
 255 dnl GTK is optional and only used in examples
 256 HAVE_GTK=no
 257 HAVE_GTK_X11=no
 258 GTK_REQ=3.0.0
 259 if test "x$BUILD_EXAMPLES" = "xyes"; then
 260   PKG_CHECK_MODULES(GTK, gtk+-3.0 >= $GTK_REQ, HAVE_GTK=yes, HAVE_GTK=no)
 261   dnl some examples need gtk+-x11
 262   PKG_CHECK_MODULES(GTK_X11, gtk+-x11-3.0 >= $GTK_REQ, HAVE_GTK_X11=yes, HAVE_GTK_X11=no)
 263   PKG_CHECK_MODULES(GTK_QUARTZ, gtk+-quartz-3.0 >= $GTK_REQ, HAVE_GTK_QUARTZ=yes, HAVE_GTK_QUARTZ=no)
 264   AC_SUBST(GTK_LIBS)
 265   AC_SUBST(GTK_CFLAGS)
 266 fi
 267 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 268 AM_CONDITIONAL(HAVE_GTK_X11, test "x$HAVE_GTK_X11" = "xyes")
 269 AM_CONDITIONAL(HAVE_GTK_QUARTZ, test "x$HAVE_GTK_QUARTZ" = "xyes")
 270
 271 dnl QT is optional and only used in examples
 272 PKG_CHECK_MODULES(QT, QtGui >= 4.6, [
 273   HAVE_QT_GV=yes
 274   HAVE_QT=yes
 275 ], [
 276   HAVE_QT_GV=no
 277   PKG_CHECK_MODULES(QT, QtGui >= 4.0, HAVE_QT=yes, HAVE_QT=no)
 278 ])
 279 if test "x$HAVE_QT" = "xyes"; then
 280   AC_MSG_CHECKING([Qt moc])
 281   QT4_MOC=`$PKG_CONFIG --variable=moc_location QtGui`
 282   AC_MSG_RESULT($QT4_MOC)
 283   AC_SUBST(QT4_MOC)
 284 fi
 285 AM_CONDITIONAL(HAVE_QT, test "x$HAVE_QT" = "xyes")
 286 AM_CONDITIONAL(HAVE_QT_GV, test "x$HAVE_QT_GV" = "xyes")
 287
 288 dnl chck for linux headers needed by the joystick seek example
 289 AC_COMPILE_IFELSE(
 290 [
 291   AC_LANG_PROGRAM([
 292     #include <linux/input.h>
 293     #include <linux/joystick.h>
 294   ],[
 295     struct js_event js;
 296     js.type = JS_EVENT_AXIS;
 297   ])
 298 ], [
 299   HAVE_LINUX_JOYSTICK_HEADERS="yes"
 300 ], [
 301   HAVE_LINUX_JOYSTICK_HEADERS="no"
 302 ])
 303 AM_CONDITIONAL(HAVE_LINUX_JOYSTICK_HEADERS, test "x$HAVE_LINUX_JOYSTICK_HEADERS" = "xyes")
 304
 305 dnl Check for -Bsymbolic-functions linker flag used to avoid
 306 dnl intra-library PLT jumps, if available.
 307 AC_ARG_ENABLE(Bsymbolic,
 308               [AC_HELP_STRING([--disable-Bsymbolic],
 309                               [avoid linking with -Bsymbolic])],,
 310               [SAVED_LDFLAGS="${LDFLAGS}"
 311                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
 312                LDFLAGS=-Wl,-Bsymbolic-functions
 313                AC_TRY_LINK([], [int main (void) { return 0; }],
 314                            AC_MSG_RESULT(yes)
 315                            enable_Bsymbolic=yes,
 316                            AC_MSG_RESULT(no)
 317                            enable_Bsymbolic=no)
 318                LDFLAGS="${SAVED_LDFLAGS}"])
 319
 320
 321 dnl *** set variables based on configure arguments ***
 322
 323 dnl set license and copyright notice
 324 GST_LICENSE="LGPL"
 325 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 326 AC_SUBST(GST_LICENSE)
 327
 328 dnl set location of plugin directory
 329 AG_GST_SET_PLUGINDIR
 330
 331 dnl set release date/time
 332 AG_GST_SET_PACKAGE_RELEASE_DATETIME_WITH_NANO([$PACKAGE_VERSION_NANO],
 333   ["${srcdir}/gst-plugins-base.doap"],
 334   [$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_MICRO])
 335
 336 dnl build static plugins or not
 337 AC_MSG_CHECKING([whether to build static plugins or not])
 338 AC_ARG_ENABLE(
 339   static-plugins,
 340   AC_HELP_STRING(
 341     [--enable-static-plugins],
 342     [build static plugins @<:@default=no@:>@]),
 343   [AS_CASE(
 344     [$enableval], [no], [], [yes], [],
 345     [AC_MSG_ERROR([bad value "$enableval" for --enable-static-plugins])])],
 346   [enable_static_plugins=no])
 347 AC_MSG_RESULT([$enable_static_plugins])
 348 if test "x$enable_static_plugins" = xyes; then
 349   AC_DEFINE(GST_PLUGIN_BUILD_STATIC, 1,
 350     [Define if static plugins should be built])
 351   GST_PLUGIN_LIBTOOLFLAGS=""
 352 else
 353   GST_PLUGIN_LIBTOOLFLAGS="--tag=disable-static"
 354 fi
 355 AC_SUBST(GST_PLUGIN_LIBTOOLFLAGS)
 356 AM_CONDITIONAL(GST_PLUGIN_BUILD_STATIC, test "x$enable_static_plugins" = "xyes")
 357
 358 # set by AG_GST_PARSE_SUBSYSTEM_DISABLES above
 359 dnl make sure it doesn't complain about unused variables if debugging is disabled
 360 NO_WARNINGS=""
 361 AG_GST_CHECK_GST_DEBUG_DISABLED([NO_WARNINGS="-Wno-unused"], [NO_WARNINGS=""])
 362
 363 dnl define an ERROR_CFLAGS Makefile variable
 364 dnl -Wformat-nonliteral - see ext/pango/gstclockoverlay.c and http://gcc.gnu.org/bugzilla/show_bug.cgi?id=39438
 365 AG_GST_SET_ERROR_CFLAGS($FATAL_WARNINGS, [
 366     -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls -Wundef
 367     -Wwrite-strings -Wformat-nonliteral -Wformat-security
 368     -Winit-self -Wmissing-include-dirs -Waddress -Waggregate-return
 369     -Wno-multichar -Wnested-externs $NO_WARNINGS])
 370
 371 dnl define an ERROR_CXXFLAGS Makefile variable
 372 AG_GST_SET_ERROR_CXXFLAGS($FATAL_WARNINGS, [
 373     -Wmissing-declarations -Wredundant-decls -Wundef
 374     -Wwrite-strings -Wformat-nonliteral -Wformat-security
 375     -Winit-self -Wmissing-include-dirs -Waddress -Waggregate-return
 376     -Wno-multichar $NO_WARNINGS])
 377
 378 dnl define correct level for debugging messages
 379 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 380
 381 dnl used in examples
 382 AG_GST_DEFAULT_ELEMENTS
 383
 384 dnl needed for encoding-target
 385 GST_DATADIR="$GST_PREFIX/share"
 386 AC_DEFINE_UNQUOTED(GST_DATADIR, "$GST_DATADIR", [system wide data directory])
 387 AC_DEFINE_UNQUOTED(GST_API_VERSION, "$GST_API_VERSION", [major/minor version])
 388
 389 dnl behaviour of speex based audio resampler
 390 AC_MSG_CHECKING(which audio resample format to use for integer)
 391 AC_ARG_WITH([audioresample_format],
 392         AS_HELP_STRING([--with-audioresample-format],[Which implementation should be used for integer audio resampling, int/float/auto, (default is auto)]),
 393         [ac_cv_audioresample_format=$withval], [ac_cv_audioresample_format=auto])dnl
 394 AC_MSG_RESULT($ac_cv_audioresample_format)
 395 case $ac_cv_audioresample_format in
 396   int)
 397     AC_DEFINE(AUDIORESAMPLE_FORMAT_INT,1,[The int implementation should be used for integer audio resampling])
 398     AC_SUBST(AUDIORESAMPLE_FORMAT_INT)
 399   ;;
 400   float)
 401     AC_DEFINE(AUDIORESAMPLE_FORMAT_FLOAT,1,[The float implementation should be used for integer audio resampling])
 402     AC_SUBST(AUDIORESAMPLE_FORMAT_FLOAT)
 403   ;;
 404   auto)
 405     AC_DEFINE(AUDIORESAMPLE_FORMAT_AUTO,1,[The implementation that should be used for integer audio resampling witll be benchmarked at runtime])
 406     AC_SUBST(AUDIORESAMPLE_FORMAT_AUTO)
 407 esac
 408
 409 dnl *** plug-ins to include ***
 410
 411 dnl these are all the gst plug-ins, compilable without additional libs
 412 AG_GST_CHECK_PLUGIN(adder)
 413 AG_GST_CHECK_PLUGIN(app)
 414 AG_GST_CHECK_PLUGIN(audioconvert)
 415 AG_GST_CHECK_PLUGIN(audiorate)
 416 AG_GST_CHECK_PLUGIN(audiotestsrc)
 417 AG_GST_CHECK_PLUGIN(encoding)
 418 AG_GST_CHECK_PLUGIN(videoconvert)
 419 AG_GST_CHECK_PLUGIN(gio)
 420 AG_GST_CHECK_PLUGIN(playback)
 421 AG_GST_CHECK_PLUGIN(audioresample)
 422 AG_GST_CHECK_PLUGIN(subparse)
 423 AG_GST_CHECK_PLUGIN(tcp)
 424 AG_GST_CHECK_PLUGIN(typefind)
 425 AG_GST_CHECK_PLUGIN(videotestsrc)
 426 AG_GST_CHECK_PLUGIN(videorate)
 427 AG_GST_CHECK_PLUGIN(videoscale)
 428 AG_GST_CHECK_PLUGIN(volume)
 429
 430 dnl FIXME 0.11: check for libxml, split subparse and move libxml parts to ext/
 431 AM_CONDITIONAL(USE_XML, false)
 432 AC_DEFINE([GST_DISABLE_XML], [1], [set to disable libxml2-dependent code in subparse])
 433
 434 dnl disable plug-ins that require libxml2's HTML support if it is not available
 435 if test "x$HAVE_LIBXML_HTML" != "xyes"; then
 436   AG_GST_DISABLE_PLUGIN(subparse)
 437 fi
 438
 439 dnl iso-codes is optional, used by libgsttag
 440 AC_ARG_ENABLE(iso-codes,
 441 AC_HELP_STRING([--enable-iso-codes],[use iso-codes if installed]),
 442 [case "${enableval}" in
 443   yes) enable_iso_codes=yes ;;
 444   no)  enable_iso_codes=no ;;
 445   *) AC_MSG_ERROR(bad value ${enableval} for --enable-iso-codes) ;;
 446 esac
 447 ],
 448 [enable_iso_codes=yes]) dnl Default value
 449
 450 AC_MSG_CHECKING([whether to use iso-codes if they are available])
 451 if test "x$enable_iso_codes" = "xyes"; then
 452   AC_MSG_RESULT([yes])
 453   have_iso_codes=no
 454   AC_MSG_CHECKING([whether iso-codes are available on this system])
 455   if $PKG_CONFIG iso-codes; then
 456     AC_MSG_RESULT([yes])
 457     AC_MSG_CHECKING([whether iso-codes has iso-639 domain])
 458     if $PKG_CONFIG --variable=domains iso-codes | $GREP -q 639 ; then
 459       AC_MSG_RESULT([yes])
 460       AC_MSG_CHECKING([for iso-codes prefix])
 461       ISO_CODES_PREFIX=`$PKG_CONFIG --variable=prefix iso-codes`
 462       if test -d "$ISO_CODES_PREFIX"; then
 463         AC_MSG_RESULT([yes])
 464         AC_MSG_CHECKING([ISO_CODES_PREFIX])
 465         AC_MSG_RESULT([$ISO_CODES_PREFIX])
 466         ISO_639_DOMAIN="iso_639"
 467         AC_MSG_CHECKING([ISO_639_DOMAIN])
 468         AC_MSG_RESULT([$ISO_639_DOMAIN])
 469         have_iso_codes=yes
 470         AC_DEFINE([HAVE_ISO_CODES], [1], [make use of iso-codes for ISO-639])
 471         AC_DEFINE_UNQUOTED([ISO_CODES_PREFIX], ["$ISO_CODES_PREFIX"], [prefix])
 472         ISO_CODES_VERSION=`$PKG_CONFIG --modversion iso-codes`
 473         AC_DEFINE_UNQUOTED([ISO_CODES_VERSION], ["$ISO_CODES_VERSION"], [ ])
 474       else
 475         AC_MSG_RESULT([no])
 476       fi
 477     else
 478       AC_MSG_RESULT([no])
 479     fi
 480   else
 481     AC_MSG_RESULT([no])
 482   fi
 483   AM_CONDITIONAL(USE_ISO_CODES, test "x$have_iso_codes" = "xyes")
 484 else
 485   AC_MSG_RESULT([no (disabled via --disable-iso-codes)])
 486   AM_CONDITIONAL(USE_ISO_CODES, false)
 487 fi
 488
 489 dnl *** zlib is optionally used by id3 tag parsing in libgsttag ***
 490 translit(dnm, m, l) AM_CONDITIONAL(USE_ZLIB, true)
 491 AG_GST_CHECK_FEATURE(ZLIB, [zlib support for ID3 parsing in libgsttag],, [
 492   PKG_CHECK_MODULES(ZLIB, [ zlib ], [
 493       HAVE_ZLIB="yes"
 494     ], [
 495       AG_GST_CHECK_LIBHEADER(ZLIB, z, uncompress,, zlib.h, [
 496         HAVE_ZLIB="yes"
 497         ZLIB_LIBS="-lz"
 498         AC_SUBST(ZLIB_LIBS)
 499       ])
 500     ])
 501 ])
 502
 503 dnl *** sys plug-ins ***
 504
 505 echo
 506 AC_MSG_NOTICE([Checking libraries for plugins in sys/])
 507 echo
 508
 509 dnl *** X11 ***
 510 translit(dnm, m, l) AM_CONDITIONAL(USE_X, true)
 511 AG_GST_CHECK_FEATURE(X, [X libraries and plugins],
 512                   [ximagesink], [
 513   AC_PATH_XTRA
 514   ac_cflags_save="$CFLAGS"
 515   ac_cppflags_save="$CPPFLAGS"
 516   CFLAGS="$CFLAGS $X_CFLAGS"
 517   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 518
 519   dnl now try to find the HEADER
 520   AC_CHECK_HEADER([X11/Xlib.h], [HAVE_X="yes"], [HAVE_X="no"], [AC_INCLUDES_DEFAULT])
 521
 522   if test "x$HAVE_X" = "xno"
 523   then
 524     AC_MSG_NOTICE([cannot find X11 development files])
 525   else
 526     dnl this is much more than we want
 527     X_LIBS="$X_LIBS $X_PRE_LIBS $X_EXTRA_LIBS"
 528     dnl AC_PATH_XTRA only defines the path needed to find the X libs,
 529     dnl it does not add the libs; therefore we add them here
 530     X_LIBS="$X_LIBS -lX11"
 531     AC_SUBST(X_CFLAGS)
 532     AC_SUBST(X_LIBS)
 533   fi
 534   AC_SUBST(HAVE_X)
 535   CFLAGS="$ac_cflags_save"
 536   CPPFLAGS="$ac_cppflags_save"
 537 ])
 538
 539 dnl Check for Xv extension
 540 translit(dnm, m, l) AM_CONDITIONAL(USE_XVIDEO, true)
 541 AG_GST_CHECK_FEATURE(XVIDEO, [X11 XVideo extensions],
 542                   [xvimagesink], [
 543   AG_GST_CHECK_XV
 544 ])
 545
 546 dnl check for X Shm
 547 translit(dnm, m, l) AM_CONDITIONAL(USE_XSHM, true)
 548 AG_GST_CHECK_FEATURE(XSHM, [X Shared Memory extension], , [
 549   if test x$HAVE_X = xyes; then
 550     AC_CHECK_LIB(Xext, XShmAttach,
 551                  HAVE_XSHM="yes", HAVE_XSHM="no",
 552                  $X_LIBS)
 553     if test "x$HAVE_XSHM" = "xyes"; then
 554       XSHM_LIBS="-lXext"
 555     else
 556       dnl On AIX, it is in XextSam instead, but we still need -lXext
 557       AC_CHECK_LIB(XextSam, XShmAttach,
 558                    HAVE_XSHM="yes", HAVE_XSHM="no",
 559                    $X_LIBS)
 560       if test "x$HAVE_XSHM" = "xyes"; then
 561         XSHM_LIBS="-lXext -lXextSam"
 562       fi
 563     fi
 564   fi
 565 ], , [
 566   AC_SUBST(HAVE_XSHM)
 567   AC_SUBST(XSHM_LIBS)
 568 ])
 569
 570 dnl *** ext plug-ins ***
 571 dnl keep this list sorted alphabetically !
 572
 573 if test "x$BUILD_EXTERNAL" = "xyes"; then
 574
 575 echo
 576 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 577 echo
 578
 579 dnl *** alsa ***
 580 translit(dnm, m, l) AM_CONDITIONAL(USE_ALSA, true)
 581 AG_GST_CHECK_FEATURE(ALSA, [ALSA], alsa, [
 582   PKG_CHECK_MODULES(ALSA, alsa >= 0.9.1, [
 583     HAVE_ALSA="yes"
 584     AC_SUBST(ALSA_CFLAGS)
 585     AC_SUBST(ALSA_LIBS)
 586   ], [
 587     AM_PATH_ALSA(0.9.1, HAVE_ALSA="yes", HAVE_ALSA="no")
 588   ])
 589 ])
 590
 591 dnl *** CDParanoia ***
 592 dnl Note: upstream has a pkg-config file only in post-10.2 SVN so far
 593 translit(dnm, m, l) AM_CONDITIONAL(USE_CDPARANOIA, true)
 594 AG_GST_CHECK_FEATURE(CDPARANOIA, [CDParanoia], cdparanoia, [
 595   PKG_CHECK_MODULES(CDPARANOIA, cdparanoia-3 >= 10.2, [
 596     HAVE_CDPARANOIA="yes"
 597   ], [
 598     AG_GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 599                         cdda_open, -lm,
 600                         cdda_interface.h,
 601                         CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 602                         HEADER_DIR="no"
 603                         FOUND_CDPARANOIA="yes")
 604     if test "x$FOUND_CDPARANOIA" != "xyes";
 605     then
 606       AG_GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 607                           cdda_open, -lm,
 608                           cdda/cdda_interface.h,
 609                           CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 610                           HEADER_DIR="yes"
 611                           FOUND_CDPARANOIA="yes")
 612     fi
 613     if test "x$HEADER_DIR" = "xyes";
 614     then
 615       AC_DEFINE_UNQUOTED(CDPARANOIA_HEADERS_IN_DIR, ,
 616                          defined if cdda headers are in a cdda/ directory)
 617     fi
 618     if test "x$FOUND_CDPARANOIA" = "xyes";
 619     then
 620       AC_CHECK_LIB(cdda_paranoia,
 621                    paranoia_cachemodel_size,
 622                    : ,
 623                    HAVE_CDPARANOIA=no,
 624                  [-lcdda_interface])
 625     fi
 626
 627     AC_SUBST(CDPARANOIA_LIBS)
 628   ])
 629 ])
 630 dnl FIXME : add second check somehow if that is necessary
 631 dnl AC_CHECK_LIB(cdda_paranoia, paranoia_init, : , HAVE_CDPARANOIA=no, -lcdda_interface )
 632 dnl AC_CHECK_HEADER(cdda_paranoia.h, :, HAVE_CDPARANOIA=no)
 633
 634 dnl *** ivorbis ***
 635 dnl AM_PATH_IVORBIS only takes two options
 636 translit(dnm, m, l) AM_CONDITIONAL(USE_IVORBIS, true)
 637 AG_GST_CHECK_FEATURE(IVORBIS, [integer vorbis plug-in], ivorbisdec, [
 638   AG_GST_PKG_CHECK_MODULES(IVORBIS, vorbisidec)
 639   if test $HAVE_IVORBIS = no
 640   then
 641     IVORBIS_LIBS=
 642     IVORBIS_CFLAGS=
 643     AC_CHECK_LIB(vorbisidec, vorbis_block_init,
 644       [IVORBIS_LIBS=-lvorbisidec
 645       HAVE_IVORBIS=yes
 646       case $host in
 647       arm-*-*)
 648         IVORBIS_CFLAGS="-D_ARM_ASSEM_ $IVORBIS_CFLAGS"
 649       esac
 650       ],
 651       HAVE_IVORBIS=no)
 652     AC_SUBST(IVORBIS_LIBS)
 653     AC_SUBST(IVORBIS_CFLAGS)
 654   else
 655     AC_CHECK_LIB(vorbisidec, vorbis_dsp_pcmout,
 656       AC_DEFINE([USE_TREMOLO],1, "Define if building for android"),
 657       USE_TREMOLO=no)
 658   fi
 659 ])
 660
 661 dnl *** libvisual ***
 662 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBVISUAL, true)
 663 AG_GST_CHECK_FEATURE(LIBVISUAL, [libvisual visualization library], libvisual, [
 664   AG_GST_PKG_CHECK_MODULES(LIBVISUAL, libvisual-0.4 >= 0.4.0)
 665   if test $HAVE_LIBVISUAL = no
 666   then
 667     AG_GST_PKG_CHECK_MODULES(LIBVISUAL, libvisual = 0.2.0)
 668     if test x$HAVE_LIBVISUAL = xyes; then
 669       LIBVIS_PLUGINSDIR="`$PKG_CONFIG --variable=pluginsbasedir libvisual-0.2`"
 670     fi
 671   else
 672     if test x$HAVE_LIBVISUAL = xyes; then
 673       LIBVIS_PLUGINSDIR="`$PKG_CONFIG --variable=pluginsbasedir libvisual-0.4`"
 674     fi
 675   fi
 676   AC_MSG_NOTICE([libvisual pluginsdir: $LIBVIS_PLUGINSDIR])
 677   if test x$LIBVIS_PLUGINSDIR != x; then
 678     AC_DEFINE_UNQUOTED(LIBVISUAL_PLUGINSBASEDIR,
 679         "$LIBVIS_PLUGINSDIR",
 680         [directory in which the detected libvisual's plugins are located])
 681   fi
 682 ])
 683
 684 dnl *** ogg ***
 685 translit(dnm, m, l) AM_CONDITIONAL(USE_OGG, true)
 686 AG_GST_CHECK_FEATURE(OGG, [Xiph Ogg library], ogg, [
 687   AG_GST_PKG_CHECK_MODULES(OGG, ogg >= 1.0)
 688   if test $HAVE_OGG = no
 689   then
 690     XIPH_PATH_OGG(HAVE_OGG="yes", HAVE_OGG="no")
 691     AS_SCRUB_INCLUDE(OGG_CFLAGS)
 692   fi
 693 ])
 694
 695 dnl *** pango ***
 696 translit(dnm, m, l) AM_CONDITIONAL(USE_PANGO, true)
 697 AG_GST_CHECK_FEATURE(PANGO, [Pango font rendering], pango, [
 698   AG_GST_PKG_CHECK_MODULES(PANGO, pango >= 1.22.0  pangocairo >= 1.22.0)
 699 ])
 700
 701 dnl *** theora ***
 702 translit(dnm, m, l) AM_CONDITIONAL(USE_THEORA, true)
 703 AG_GST_CHECK_FEATURE(THEORA, [Xiph Theora video codec], theora, [
 704   AG_GST_PKG_CHECK_MODULES(THEORA, theoradec >= 1.1 theoraenc >= 1.1)
 705 ])
 706
 707 dnl *** vorbis ***
 708 dnl AM_PATH_VORBIS only takes two options
 709 translit(dnm, m, l) AM_CONDITIONAL(USE_VORBIS, true)
 710 AG_GST_CHECK_FEATURE(VORBIS, [Xiph Vorbis audio codec], vorbis, [
 711   AG_GST_PKG_CHECK_MODULES(VORBIS, vorbis >= 1.0 vorbisenc >= 1.0)
 712   if test $HAVE_VORBIS = no
 713   then
 714     XIPH_PATH_VORBIS(HAVE_VORBIS="yes", HAVE_VORBIS="no")
 715     AS_SCRUB_INCLUDE(VORBIS_CFLAGS)
 716   fi
 717 ])
 718
 719 if test "x$HAVE_VORBIS" = "xyes"; then
 720   ac_cflags_save="$CFLAGS"
 721   AC_COMPILE_IFELSE([
 722     AC_LANG_PROGRAM([[
 723 #include <vorbis/codec.h>
 724                      ]],[[
 725 vorbis_dsp_state *v;
 726
 727 vorbis_synthesis_restart (v);
 728                      ]])], HAVE_VSR=yes, HAVE_VSR=no)
 729   if test "x$HAVE_VSR" = "xyes"; then
 730     AC_DEFINE_UNQUOTED(HAVE_VORBIS_SYNTHESIS_RESTART, 1,
 731                        [defined if vorbis_synthesis_restart is present])
 732   fi
 733   CFLAGS="$ac_cflags_save"
 734 fi
 735
 736 else
 737
 738 dnl not building plugins with external dependencies,
 739 dnl but we still need to set the conditionals
 740 AM_CONDITIONAL(USE_ALSA, false)
 741 AM_CONDITIONAL(USE_CDPARANOIA, false)
 742 AM_CONDITIONAL(USE_IVORBIS, false)
 743 AM_CONDITIONAL(USE_LIBVISUAL, false)
 744 AM_CONDITIONAL(USE_OGG, false)
 745 AM_CONDITIONAL(USE_PANGO, false)
 746 AM_CONDITIONAL(USE_THEORA, false)
 747 AM_CONDITIONAL(USE_VORBIS, false)
 748
 749 fi dnl of EXT plugins
 750
 751 dnl seeking needs freetype, so check for it here
 752 PKG_CHECK_MODULES(FT2, freetype2 >= 2.0.9, HAVE_FT2="yes", [
 753   AC_CHECK_FT2(2.0.9, HAVE_FT2="yes", HAVE_FT2="no")
 754 ])
 755 dnl make the HAVE_FT2 variable available to automake and Makefile.am
 756 AM_CONDITIONAL(HAVE_FT2, test "x$HAVE_FT2" = "xyes")
 757 AC_SUBST(FT2_CFLAGS)
 758 AC_SUBST(FT2_LIBS)
 759
 760 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 761
 762 dnl Overview:
 763 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
 764 dnl GST_*:              flags shared by built objects to link against GStreamer
 765 dnl GST_PLUGINS_BASE_CFLAGS: to link internally against the plugins base libs
 766 dnl                          (compare to other modules) or for i18n
 767 dnl GST_ALL_LDFLAGS:    linker flags shared by all
 768 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 769 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 770 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 771
 772 dnl GST_OPTION_CFLAGS
 773 if test "x$USE_DEBUG" = xyes; then
 774    PROFILE_CFLAGS="-g"
 775 fi
 776 AC_SUBST(PROFILE_CFLAGS)
 777
 778 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
 779   dnl Define _only_ when compiling a git version (not pre-releases or releases)
 780   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 781 else
 782   DEPRECATED_CFLAGS=""
 783 fi
 784 AC_SUBST(DEPRECATED_CFLAGS)
 785
 786 dnl every flag in GST_OPTION_CFLAGS and GST_OPTION_CXXFLAGS can be overridden
 787 dnl at make time with e.g. make ERROR_CFLAGS=""
 788 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 789 GST_OPTION_CXXFLAGS="\$(WARNING_CXXFLAGS) \$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 790 AC_SUBST(GST_OPTION_CFLAGS)
 791 AC_SUBST(GST_OPTION_CXXFLAGS)
 792
 793 dnl our libraries need to be versioned correctly
 794 AC_SUBST(GST_LT_LDFLAGS)
 795
 796 dnl GST_PLUGINS_BASE_CFLAGS
 797 dnl prefer internal headers to already installed ones
 798 dnl also add builddir include for enumtypes and marshal
 799 GST_PLUGINS_BASE_CFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs"
 800 AC_SUBST(GST_PLUGINS_BASE_CFLAGS)
 801
 802 dnl FIXME: do we want to rename to GST_ALL_* ?
 803 dnl add GST_OPTION_CFLAGS, but overridable
 804 GST_CFLAGS="$GST_CFLAGS"
 805 GST_CXXFLAGS="$GLIB_CFLAGS $GST_CFLAGS \$(GLIB_EXTRA_CFLAGS) \$(GST_OPTION_CXXFLAGS)"
 806 GST_CFLAGS="$GLIB_CFLAGS $GST_CFLAGS \$(GLIB_EXTRA_CFLAGS) \$(GST_OPTION_CFLAGS)"
 807 AC_SUBST(GST_CFLAGS)
 808 AC_SUBST(GST_CXXFLAGS)
 809 dnl add GCOV libs because libtool strips -fprofile-arcs -ftest-coverage
 810 GST_LIBS="$GST_LIBS \$(GCOV_LIBS)"
 811 AC_SUBST(GST_LIBS)
 812
 813 dnl LDFLAGS really should only contain flags, not libs - they get added before
 814 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 815 GST_ALL_LDFLAGS="-no-undefined"
 816 if test "x${enable_Bsymbolic}" = "xyes"; then
 817   GST_ALL_LDFLAGS="$GST_ALL_LDFLAGS -Wl,-Bsymbolic-functions"
 818 fi
 819 AC_SUBST(GST_ALL_LDFLAGS)
 820
 821 dnl GST_LIB_LDFLAGS
 822 dnl linker flags shared by all libraries
 823 dnl LDFLAGS modifier defining exported symbols from built libraries
 824 dnl (export _gst_foo but not __gst_foo)
 825 GST_LIB_LDFLAGS="-export-symbols-regex ^_?\(gst_\|Gst\|GST_\).*"
 826 AC_SUBST(GST_LIB_LDFLAGS)
 827
 828 dnl this really should only contain flags, not libs - they get added before
 829 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 830 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_.*' $GST_ALL_LDFLAGS"
 831 AC_SUBST(GST_PLUGIN_LDFLAGS)
 832
 833 dnl *** output files ***
 834
 835 AC_CONFIG_FILES(
 836 Makefile
 837 gst-plugins-base.spec
 838 gst/Makefile
 839 gst/adder/Makefile
 840 gst/app/Makefile
 841 gst/audioconvert/Makefile
 842 gst/audiorate/Makefile
 843 gst/audiotestsrc/Makefile
 844 gst/encoding/Makefile
 845 gst/videoconvert/Makefile
 846 gst/gio/Makefile
 847 gst/playback/Makefile
 848 gst/audioresample/Makefile
 849 gst/subparse/Makefile
 850 gst/tcp/Makefile
 851 gst/typefind/Makefile
 852 gst/videotestsrc/Makefile
 853 gst/videorate/Makefile
 854 gst/videoscale/Makefile
 855 gst/volume/Makefile
 856 sys/Makefile
 857 sys/ximage/Makefile
 858 sys/xvimage/Makefile
 859 ext/Makefile
 860 ext/alsa/Makefile
 861 ext/cdparanoia/Makefile
 862 ext/libvisual/Makefile
 863 ext/ogg/Makefile
 864 ext/pango/Makefile
 865 ext/theora/Makefile
 866 ext/vorbis/Makefile
 867 gst-libs/Makefile
 868 gst-libs/gst/Makefile
 869 gst-libs/gst/audio/Makefile
 870 gst-libs/gst/app/Makefile
 871 gst-libs/gst/fft/Makefile
 872 gst-libs/gst/riff/Makefile
 873 gst-libs/gst/rtp/Makefile
 874 gst-libs/gst/rtsp/Makefile
 875 gst-libs/gst/sdp/Makefile
 876 gst-libs/gst/tag/Makefile
 877 gst-libs/gst/pbutils/Makefile
 878 gst-libs/gst/pbutils/gstpluginsbaseversion.h
 879 gst-libs/gst/video/Makefile
 880 tools/Makefile
 881 pkgconfig/Makefile
 882 pkgconfig/gstreamer-audio.pc
 883 pkgconfig/gstreamer-audio-uninstalled.pc
 884 pkgconfig/gstreamer-app.pc
 885 pkgconfig/gstreamer-app-uninstalled.pc
 886 pkgconfig/gstreamer-fft.pc
 887 pkgconfig/gstreamer-fft-uninstalled.pc
 888 pkgconfig/gstreamer-pbutils.pc
 889 pkgconfig/gstreamer-pbutils-uninstalled.pc
 890 pkgconfig/gstreamer-riff.pc
 891 pkgconfig/gstreamer-riff-uninstalled.pc
 892 pkgconfig/gstreamer-rtp.pc
 893 pkgconfig/gstreamer-rtp-uninstalled.pc
 894 pkgconfig/gstreamer-rtsp.pc
 895 pkgconfig/gstreamer-rtsp-uninstalled.pc
 896 pkgconfig/gstreamer-sdp.pc
 897 pkgconfig/gstreamer-sdp-uninstalled.pc
 898 pkgconfig/gstreamer-tag.pc
 899 pkgconfig/gstreamer-tag-uninstalled.pc
 900 pkgconfig/gstreamer-video.pc
 901 pkgconfig/gstreamer-video-uninstalled.pc
 902 pkgconfig/gstreamer-plugins-base.pc
 903 pkgconfig/gstreamer-plugins-base-uninstalled.pc
 904 tests/Makefile
 905 tests/check/Makefile
 906 tests/examples/Makefile
 907 tests/examples/app/Makefile
 908 tests/examples/audio/Makefile
 909 tests/examples/dynamic/Makefile
 910 tests/examples/encoding/Makefile
 911 tests/examples/fft/Makefile
 912 tests/examples/gio/Makefile
 913 tests/examples/overlay/Makefile
 914 tests/examples/seek/Makefile
 915 tests/examples/snapshot/Makefile
 916 tests/examples/playback/Makefile
 917 tests/examples/playrec/Makefile
 918 tests/files/Makefile
 919 tests/icles/Makefile
 920 tests/icles/playback/Makefile
 921 docs/Makefile
 922 docs/design/Makefile
 923 docs/libs/Makefile
 924 docs/plugins/Makefile
 925 docs/version.entities
 926 po/Makefile.in
 927 common/Makefile
 928 common/m4/Makefile
 929 m4/Makefile
 930 )
 931
 932 dnl Create the config.h file for Visual Studio builds
 933 dnl Beware of spaces and /'s in some of the shell variable contents.
 934 sed \
 935     -e 's/.*config.h.in.*autoheader.*/\/* Autogenerated config.h created for win32 Visual Studio builds *\/\n\n\/* PREFIX -- specifically added for Windows for easier moving *\/\n#define PREFIX "C:\\\\gstreamer"/' \
 936     -e 's/.* GST_INSTALL_PLUGINS_HELPER/#define GST_INSTALL_PLUGINS_HELPER PREFIX "\\\\libexec\\\\gst-install-plugins-helper.exe"/' \
 937     -e 's/.* GETTEXT_PACKAGE$/#define GETTEXT_PACKAGE "'$GETTEXT_PACKAGE'"/' \
 938     -e 's/.* GST_DATADIR$/#define GST_DATADIR PREFIX "\\\\share"/' \
 939     -e 's/.* GST_LEVEL_DEFAULT$/#define GST_LEVEL_DEFAULT GST_LEVEL_ERROR/' \
 940     -e 's/.* GST_LICENSE$/#define GST_LICENSE "'$GST_LICENSE'"/' \
 941     -e 's/.* GST_API_VERSION$/#define GST_API_VERSION "'$GST_API_VERSION'"/' \
 942     -e "s,.* GST_PACKAGE_NAME$,#define GST_PACKAGE_NAME \"${GST_PACKAGE_NAME}\"," \
 943     -e 's/.* GST_PACKAGE_ORIGIN$/#define GST_PACKAGE_ORIGIN "Unknown package origin"/' \
 944     -e "s,.* GST_PACKAGE_RELEASE_DATETIME$,#define GST_PACKAGE_RELEASE_DATETIME \"${GST_PACKAGE_RELEASE_DATETIME}\"," \
 945     -e 's/.* HAVE_CPU_I386$/#define HAVE_CPU_I386 1/' \
 946     -e 's/.* HAVE_FGETPOS$/#define HAVE_FGETPOS 1/' \
 947     -e 's/.* HAVE_FSETPOS$/#define HAVE_FSETPOS 1/' \
 948     -e 's/.* HAVE_ISO_CODES$/#undef HAVE_ISO_CODES/' \
 949     -e 's/.* HAVE_LIBXML2$/#define HAVE_LIBXML2 1/' \
 950     -e 's/.* HAVE_PROCESS_H$/#define HAVE_PROCESS_H 1/' \
 951     -e 's/.* HAVE_STDLIB_H$/#define HAVE_STDLIB_H 1/' \
 952     -e 's/.* HAVE_STRING_H$/#define HAVE_STRING_H 1/' \
 953     -e 's/.* HAVE_SYS_STAT_H$/#define HAVE_SYS_STAT_H 1/' \
 954     -e 's/.* HAVE_SYS_TYPES_H$/#define HAVE_SYS_TYPES_H 1/' \
 955     -e 's/.* HAVE_WIN32$/#define HAVE_WIN32 1/' \
 956     -e 's/.* HOST_CPU$/#define HOST_CPU "i686"/' \
 957     -e 's/.* ISO_CODES_PREFIX$/#undef ISO_CODES_PREFIX/' \
 958     -e 's/.* ISO_CODES_VERSION$/#undef ISO_CODES_VERSION/' \
 959     -e 's/.* LIBDIR$/#ifdef _DEBUG\n#  define LIBDIR PREFIX "\\\\debug\\\\lib"\n#else\n#  define LIBDIR PREFIX "\\\\lib"\n#endif/' \
 960     -e 's/.* LOCALEDIR$/#define LOCALEDIR PREFIX "\\\\share\\\\locale"/' \
 961     -e "s/.* PACKAGE$/#define PACKAGE \"$PACKAGE\"/" \
 962     -e 's/.* PACKAGE_BUGREPORT$/#define PACKAGE_BUGREPORT "http:\/\/bugzilla.gnome.org\/enter_bug.cgi?product=GStreamer"/' \
 963     -e "s/.* PACKAGE_NAME$/#define PACKAGE_NAME \"$PACKAGE_NAME\"/" \
 964     -e "s/.* PACKAGE_STRING$/#define PACKAGE_STRING \"$PACKAGE_STRING\"/" \
 965     -e 's/.* PACKAGE_TARNAME$/#define PACKAGE_TARNAME "'$PACKAGE_TARNAME'"/' \
 966     -e 's/.* PACKAGE_VERSION$/#define PACKAGE_VERSION "'$PACKAGE_VERSION'"/' \
 967     -e 's/.* PLUGINDIR$/#ifdef _DEBUG\n#  define PLUGINDIR PREFIX "\\\\debug\\\\lib\\\\gstreamer-0.11"\n#else\n#  define PLUGINDIR PREFIX "\\\\lib\\\\gstreamer-0.11"\n#endif/' \
 968     -e 's/.* USE_BINARY_REGISTRY$/#define USE_BINARY_REGISTRY/' \
 969     -e 's/.* VERSION$/#define VERSION "'$VERSION'"/' \
 970     -e "s/.* DEFAULT_AUDIOSINK$/#define DEFAULT_AUDIOSINK \"directsoundsink\"/" \
 971     -e "s/.* DEFAULT_VIDEOSINK$/#define DEFAULT_VIDEOSINK \"directdrawsink\"/" \
 972     -e "s/.* DEFAULT_VISUALIZER$/#define DEFAULT_VISUALIZER \"goom\"/" \
 973     config.h.in >win32/common/config.h-new
 974
 975
 976
 977 AC_OUTPUT
 978
 979 AG_GST_OUTPUT_PLUGINS
 980 ORC_OUTPUT
 981