configure.ac

   1 AC_PREREQ(2.52)
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, cvs and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for cvs/prerelease
   8 AC_INIT(GStreamer Base Plug-ins, 0.10.14.1,
   9     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
  10     gst-plugins-base)
  11
  12 AG_GST_INIT
  13
  14 dnl initialize automake
  15 AM_INIT_AUTOMAKE
  16
  17 dnl define PACKAGE_VERSION_* variables
  18 AS_VERSION
  19
  20 dnl check if this is a release version
  21 AS_NANO(GST_CVS="no", GST_CVS="yes")
  22
  23 dnl can autoconf find the source ?
  24 AC_CONFIG_SRCDIR([gst/audiotestsrc/gstaudiotestsrc.c])
  25
  26 dnl define the output header for config
  27 AM_CONFIG_HEADER([config.h])
  28
  29 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  30 AM_MAINTAINER_MODE
  31
  32 dnl sets host_* variables
  33 AC_CANONICAL_HOST
  34
  35 dnl our libraries and install dirs use major.minor as a version
  36 GST_MAJORMINOR=$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR
  37 dnl we override it here if we need to for the release candidate of new series
  38 GST_MAJORMINOR=0.10
  39 AC_SUBST(GST_MAJORMINOR)
  40
  41 dnl CURRENT, REVISION, AGE
  42 dnl - library source changed -> increment REVISION
  43 dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
  44 dnl - interfaces added -> increment AGE
  45 dnl - interfaces removed -> AGE = 0
  46 dnl sets GST_LT_LDFLAGS
  47 AS_LIBTOOL(GST, 10, 0, 10)
  48
  49 dnl FIXME: this macro doesn't actually work;
  50 dnl the generated libtool script has no support for the listed tags.
  51 dnl So this needs to be fixed first if we want to use this
  52 dnl AS_LIBTOOL_TAGS
  53
  54 AM_PROG_LIBTOOL
  55
  56 dnl *** required versions of GStreamer stuff ***
  57 GST_REQ=0.10.13.1
  58
  59 dnl *** autotools stuff ****
  60
  61 dnl allow for different autotools
  62 AS_AUTOTOOLS_ALTERNATE
  63
  64 dnl Add parameters for aclocal
  65 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  66
  67 dnl set up gettext
  68 dnl the version check needs to stay here because autopoint greps for it
  69 AM_GNU_GETTEXT_VERSION([0.11.5])
  70 AM_GNU_GETTEXT([external])
  71 AG_GST_GETTEXT([gst-plugins-base-$GST_MAJORMINOR])
  72
  73 dnl *** check for arguments to configure ***
  74
  75 AG_GST_ARG_DEBUG
  76 AG_GST_ARG_PROFILING
  77 AG_GST_ARG_VALGRIND
  78 AG_GST_ARG_GCOV
  79
  80 AG_GST_ARG_EXAMPLES
  81
  82 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  83 AG_GST_ARG_WITH_PACKAGE_NAME
  84 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  85
  86 dnl let distro override plugin install helper path
  87 AC_ARG_WITH(install-plugins-helper,
  88   AC_HELP_STRING([--with-install-plugins-helper],
  89     [specify path of helper script to call to install plugins]),
  90   [
  91     case "${withval}" in
  92       yes) AC_MSG_ERROR(bad value ${withval} for --with-install-plugins-helper) ;;
  93       no)  AC_MSG_ERROR(bad value ${withval} for --with-install-plugins-helper) ;;
  94       *)   GST_INSTALL_PLUGINS_HELPER="${withval}" ;;
  95     esac
  96   ],
  97   [
  98     dnl Default value
  99     AS_AC_EXPAND(GST_INSTALL_PLUGINS_HELPER,${libexecdir}/gst-install-plugins-helper)
 100   ]
 101 )
 102 AC_MSG_NOTICE(Using $GST_INSTALL_PLUGINS_HELPER as plugin install helper)
 103 AC_DEFINE_UNQUOTED(GST_INSTALL_PLUGINS_HELPER, "$GST_INSTALL_PLUGINS_HELPER",
 104     [plugin install helper script])
 105 AC_SUBST(GST_INSTALL_PLUGINS_HELPER)
 106
 107
 108 dnl these are all the gst plug-ins, compilable without additional libs
 109 GST_PLUGINS_ALL="\
 110         adder \
 111         audioconvert \
 112         audiorate \
 113         audioresample \
 114         audiotestsrc \
 115         ffmpegcolorspace \
 116         gdp \
 117         playback \
 118         typefind \
 119         videotestsrc \
 120         videorate \
 121         videoscale \
 122         volume \
 123         "
 124 AC_SUBST(GST_PLUGINS_ALL)
 125
 126 GST_PLUGINS_SELECTED=""
 127
 128 AC_ARG_WITH(plugins,
 129     AC_HELP_STRING([--with-plugins],
 130       [comma-separated list of plug-ins to compile]),
 131     [for i in `echo $withval | tr , ' '`; do
 132         if echo $GST_PLUGINS_ALL | grep $i > /dev/null
 133         then
 134             GST_PLUGINS_SELECTED="$GST_PLUGINS_SELECTED $i"
 135         else
 136             echo "plug-in $i not recognized, ignoring..."
 137         fi
 138     done],
 139     [GST_PLUGINS_SELECTED=$GST_PLUGINS_ALL])
 140
 141 AC_SUBST(GST_PLUGINS_SELECTED)
 142
 143 dnl ext plug-ins; plug-ins that have external dependencies
 144 AG_GST_CHECK_FEATURE(EXTERNAL, [enable building of plug-ins with external deps],,
 145   [HAVE_EXTERNAL=yes], enabled,
 146   [
 147     AC_MSG_NOTICE(building external plug-ins)
 148     BUILD_EXTERNAL="yes"
 149   ],[
 150     AC_MSG_NOTICE(all plug-ins with external dependencies will not be built)
 151     BUILD_EXTERNAL="no"
 152   ])
 153 AM_CONDITIONAL(BUILD_EXTERNAL, test "x$BUILD_EXTERNAL" = "xyes")
 154
 155 dnl *** checks for platform ***
 156
 157 dnl * hardware/architecture *
 158
 159 dnl common/m4/gst-arch.m4
 160 dnl check CPU type
 161 AG_GST_ARCH
 162
 163 dnl check for large file support
 164 dnl affected plugins must include config.h
 165 AC_SYS_LARGEFILE
 166
 167 dnl *** checks for programs ***
 168
 169 dnl find a compiler
 170 AC_PROG_CC
 171
 172 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 173 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 174
 175 dnl check for documentation tools
 176 GTK_DOC_CHECK([1.3])
 177 AS_PATH_PYTHON([2.1])
 178 AG_GST_PLUGIN_DOCS([1.3],[2.1])
 179
 180 dnl *** checks for libraries ***
 181
 182 dnl For interactive UNIX (a Sun thing)
 183 dnl FIXME: this adds -lcposix to LIBS, but I doubt we use LIBS
 184 AC_ISC_POSIX
 185
 186 dnl libm, for sin() etc.
 187 AC_CHECK_LIBM
 188 AC_SUBST(LIBM)
 189
 190 dnl *** checks for header files ***
 191
 192 dnl check if we have ANSI C header files
 193 AC_HEADER_STDC
 194
 195 dnl used in gst/ffmpegcolorspace/mem.c
 196 dnl FIXME: could be fixed by redefining av_malloc and av_free to GLib's
 197 AC_CHECK_HEADERS([malloc.h])
 198
 199 dnl used in gst/subparse/gstsubparse.c
 200 AC_CHECK_HEADERS([regex.h], HAVE_REGEX_H="yes", HAVE_REGEX_H="no")
 201 AM_CONDITIONAL(HAVE_REGEX_H, test "x$HAVE_REGEX_H" = "xyes")
 202
 203 if test "x$HAVE_REGEX_H" = "xyes"; then
 204   ac_cppflags_save="$CPPFLAGS"
 205   CPPFLAGS="-Wall -Werror `$PKG_CONFIG --cflags libxml-2.0`"
 206   AC_COMPILE_IFELSE(
 207     AC_LANG_PROGRAM([
 208 #include <libxml/HTMLparser.h>
 209                      ],[
 210 #ifndef LIBXML_HTML_ENABLED
 211 #error libxml2 has no HTML support
 212 #endif /* LIBXML_HTML_ENABLED */
 213                      ]), HAVE_LIBXML_HTML=yes, HAVE_LIBXML_HTML=no)
 214   AM_CONDITIONAL(HAVE_LIBXML_HTML, test "x$HAVE_LIBXML_HTML" = "xyes")
 215   CPPFLAGS="$ac_cppflags_save"
 216
 217   if test "x$HAVE_LIBXML_HTML" = "xyes"; then
 218     GST_PLUGINS_SELECTED="$GST_PLUGINS_SELECTED subparse"
 219   else
 220     GST_PLUGINS_NO="\t[subparse]\n$GST_PLUGINS_NO"
 221   fi
 222 else
 223   GST_PLUGINS_NO="\t[subparse]\n$GST_PLUGINS_NO"
 224 fi
 225
 226 dnl used in gst/tcp
 227 AC_CHECK_HEADERS([sys/socket.h],
 228   HAVE_SYS_SOCKET_H="yes", HAVE_SYS_SOCKET_H="no")
 229 AM_CONDITIONAL(HAVE_SYS_SOCKET_H, test "x$HAVE_SYS_SOCKET_H" = "xyes")
 230 if test "x$HAVE_SYS_SOCKET_H" = "xyes"; then
 231   GST_PLUGINS_SELECTED="$GST_PLUGINS_SELECTED tcp"
 232 else
 233   GST_PLUGINS_NO="\t[tcp]\n$GST_PLUGINS_NO"
 234 fi
 235
 236 dnl used in gst-libs/gst/rtsp
 237 AC_CHECK_HEADERS([winsock2.h], HAVE_WINSOCK2_H=yes)
 238 if test "x$HAVE_WINSOCK2_H" = "xyes"; then
 239   WIN32_LIBS="-lws2_32"
 240   AC_SUBST(WIN32_LIBS)
 241 fi
 242
 243 dnl used in gst-libs/gst/pbutils and associated unit test
 244 AC_CHECK_HEADERS([process.h sys/types.h sys/wait.h sys/stat.h])
 245
 246 dnl ffmpegcolorspace includes _stdint.h
 247 dnl also, Windows does not have long long
 248 AX_CREATE_STDINT_H
 249
 250 dnl *** checks for functions ***
 251 AC_CHECK_FUNCS([localtime_r])
 252
 253 dnl *** checks for types/defines ***
 254
 255 dnl Check for FIONREAD ioctl declaration
 256 dnl used in gst/tcp
 257 GST_CHECK_FIONREAD
 258
 259 dnl *** checks for structures ***
 260
 261 dnl *** checks for compiler characteristics ***
 262
 263 dnl make sure we can use "inline" from C code
 264 AC_C_INLINE
 265
 266 dnl *** checks for library functions ***
 267
 268 dnl check for fseeko()
 269 AC_FUNC_FSEEKO
 270
 271 dnl Check for fast float to int casting as defined in C99
 272 dnl used in gst-libs/gst/floatcast/floatcast.h
 273 AC_C99_FUNC_LRINT
 274 AC_C99_FUNC_LRINTF
 275
 276 dnl Check for a way to display the function name in debug output
 277 AG_GST_CHECK_FUNCTION
 278
 279 dnl *** checks for dependency libraries ***
 280
 281 dnl GLib is required
 282 AG_GST_GLIB_CHECK([2.6])
 283
 284 dnl liboil is required
 285 PKG_CHECK_MODULES(LIBOIL, liboil-0.3 >= 0.3.8, HAVE_LIBOIL=yes, HAVE_LIBOIL=no)
 286 if test "x$HAVE_LIBOIL" != "xyes"
 287 then
 288   AC_ERROR([liboil-0.3.8 or later is required])
 289 fi
 290
 291 dnl checks for gstreamer
 292 dnl uninstalled is selected preferentially -- see pkg-config(1)
 293 AG_GST_CHECK_GST($GST_MAJORMINOR, [$GST_REQ])
 294 AG_GST_CHECK_GST_BASE($GST_MAJORMINOR, [$GST_REQ])
 295 AG_GST_CHECK_GST_GDP($GST_MAJORMINOR, [$GST_REQ])
 296 AG_GST_CHECK_GST_CONTROLLER($GST_MAJORMINOR, [$GST_REQ])
 297 AG_GST_CHECK_GST_CHECK($GST_MAJORMINOR, [$GST_REQ], no)
 298 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 299
 300 dnl Check for documentation xrefs
 301 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 302 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_MAJORMINOR`"
 303 AC_SUBST(GLIB_PREFIX)
 304 AC_SUBST(GST_PREFIX)
 305
 306 dnl GTK is optional and used in examples
 307 HAVE_GTK=NO
 308 PKG_CHECK_MODULES(GTK2, gtk+-2.0 >= 2.2.0, HAVE_GTK_22=yes, HAVE_GTK_22=no)
 309 if test "x$HAVE_GTK_22" = "xyes"; then
 310   HAVE_GTK=yes
 311   GTK_VERSION=`$PKG_CONFIG --variable=gtk_binary_version gtk+-2.0`
 312   AC_SUBST(GTK_VERSION)
 313   GTK_PREFIX=`$PKG_CONFIG --variable=prefix gdk-pixbuf-2.0`
 314   AC_SUBST(GTK_BASE_DIR)
 315 else
 316   PKG_CHECK_MODULES(GTK2, gtk+-2.0, HAVE_GTK_20=yes, HAVE_GTK_20=no)
 317 fi
 318 if test "x$HAVE_GTK_20" = "xyes"; then
 319   HAVE_GTK=yes
 320 fi
 321 GTK_CFLAGS=$GTK2_CFLAGS
 322 GTK_LIBS=$GTK2_LIBS
 323 AC_SUBST(GTK_LIBS)
 324 AC_SUBST(GTK_CFLAGS)
 325 AC_SUBST(HAVE_GTK)
 326 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 327
 328 dnl *** set variables based on configure arguments ***
 329
 330 dnl set license and copyright notice
 331 GST_LICENSE="LGPL"
 332 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 333 AC_SUBST(GST_LICENSE)
 334
 335 dnl set location of plugin directory
 336 AG_GST_SET_PLUGINDIR
 337
 338 dnl define an ERROR_CFLAGS Makefile variable
 339 AG_GST_SET_ERROR_CFLAGS($GST_CVS)
 340
 341 dnl define correct level for debugging messages
 342 AG_GST_SET_LEVEL_DEFAULT($GST_CVS)
 343
 344 dnl used in examples
 345 AG_GST_DEFAULT_ELEMENTS
 346
 347 dnl *** sys plug-ins ***
 348
 349 echo
 350 AC_MSG_NOTICE([Checking libraries for plugins in sys/])
 351 echo
 352
 353 dnl *** X11 ***
 354 translit(dnm, m, l) AM_CONDITIONAL(USE_X, true)
 355 AG_GST_CHECK_FEATURE(X, [X libraries and plugins],
 356                   [ximagesink], [
 357   AC_PATH_XTRA
 358   ac_cflags_save="$CFLAGS"
 359   ac_cppflags_save="$CPPFLAGS"
 360   CFLAGS="$CFLAGS $X_CFLAGS"
 361   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 362
 363   dnl now try to find the HEADER
 364   AC_CHECK_HEADER(X11/Xlib.h, HAVE_X="yes", HAVE_X="no")
 365
 366   if test "x$HAVE_X" = "xno"
 367   then
 368     AC_MSG_NOTICE([cannot find X11 development files])
 369   else
 370     dnl this is much more than we want
 371     X_LIBS="$X_LIBS $X_PRE_LIBS $X_EXTRA_LIBS"
 372     dnl AC_PATH_XTRA only defines the path needed to find the X libs,
 373     dnl it does not add the libs; therefore we add them here
 374     X_LIBS="$X_LIBS -lX11"
 375     AC_SUBST(X_CFLAGS)
 376     AC_SUBST(X_LIBS)
 377   fi
 378   AC_SUBST(HAVE_X)
 379   CFLAGS="$ac_cflags_save"
 380   CPPFLAGS="$ac_cppflags_save"
 381 ])
 382
 383 dnl Check for Xv extension
 384 translit(dnm, m, l) AM_CONDITIONAL(USE_XVIDEO, true)
 385 AG_GST_CHECK_FEATURE(XVIDEO, [X11 XVideo extensions],
 386                   [xvimagesink], [
 387   AG_GST_CHECK_XV
 388 ])
 389
 390 dnl check for X Shm
 391 translit(dnm, m, l) AM_CONDITIONAL(USE_XSHM, true)
 392 AG_GST_CHECK_FEATURE(XSHM, [X Shared Memory extension], , [
 393   if test x$HAVE_X = xyes; then
 394     AC_CHECK_LIB(Xext, XShmAttach,
 395                  HAVE_XSHM="yes", HAVE_XSHM="no",
 396                  $X_LIBS)
 397     if test "x$HAVE_XSHM" = "xyes"; then
 398       XSHM_LIBS="-lXext"
 399     else
 400       dnl On AIX, it is in XextSam instead, but we still need -lXext
 401       AC_CHECK_LIB(XextSam, XShmAttach,
 402                    HAVE_XSHM="yes", HAVE_XSHM="no",
 403                    $X_LIBS)
 404       if test "x$HAVE_XSHM" = "xyes"; then
 405         XSHM_LIBS="-lXext -lXextSam"
 406       fi
 407     fi
 408   fi
 409 ], , [
 410   AC_SUBST(HAVE_XSHM)
 411   AC_SUBST(XSHM_LIBS)
 412 ])
 413
 414 dnl v4l/v4l2 checks have been moved down because they require X
 415
 416 dnl *** Video 4 Linux ***
 417 dnl for information about the header/define, see sys/v4l/gstv4lelement.h
 418 dnl renamed to GST_V4L in accordance with V4L2 below
 419 translit(dnm, m, l) AM_CONDITIONAL(USE_GST_V4L, true)
 420 AG_GST_CHECK_FEATURE(GST_V4L, [Video 4 Linux], video4linux, [
 421   AC_CHECK_DECL(VID_TYPE_MPEG_ENCODER, HAVE_GST_V4L="yes", HAVE_GST_V4L="no", [
 422 #include <sys/types.h>
 423 #define _LINUX_TIME_H
 424 #define __user
 425 #include <linux/videodev.h>
 426   ])
 427
 428   dnl we can build v4l without Xv, but then we won't have XOverlay support
 429   if test "x$HAVE_GST_V4L" = "xyes" -a "x$HAVE_XVIDEO" != "xyes"
 430   then
 431     AC_MSG_NOTICE([NO XVIDEO FOUND, VIDEO4LINUX WILL BE BUILT])
 432     AC_MSG_NOTICE([WITHOUT XOVERLAY SUPPORT])
 433   fi
 434 ])
 435
 436 dnl *** ext plug-ins ***
 437 dnl keep this list sorted alphabetically !
 438
 439 if test "x$BUILD_EXTERNAL" = "xyes"; then
 440
 441 echo
 442 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 443 echo
 444
 445 dnl *** alsa ***
 446 translit(dnm, m, l) AM_CONDITIONAL(USE_ALSA, true)
 447 AG_GST_CHECK_FEATURE(ALSA, [ALSA], alsa, [
 448   PKG_CHECK_MODULES(ALSA, alsa >= 0.9.1, [
 449     HAVE_ALSA="yes"
 450     AC_SUBST(ALSA_CFLAGS)
 451     AC_SUBST(ALSA_LIBS)
 452   ], [
 453     AM_PATH_ALSA(0.9.1, HAVE_ALSA="yes", HAVE_ALSA="no")
 454   ])
 455 ])
 456
 457 dnl *** CDParanoia ***
 458 translit(dnm, m, l) AM_CONDITIONAL(USE_CDPARANOIA, true)
 459 AG_GST_CHECK_FEATURE(CDPARANOIA, [CDParanoia], cdparanoia, [
 460   AG_GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 461                       cdda_open, -lm,
 462                       cdda_interface.h,
 463                       CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 464                       HEADER_DIR="no"
 465                       FOUND_CDPARANOIA="yes")
 466   if test "x$FOUND_CDPARANOIA" != "xyes";
 467   then
 468     AG_GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 469                         cdda_open, -lm,
 470                         cdda/cdda_interface.h,
 471                         CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 472                         HEADER_DIR="yes"
 473                         FOUND_CDPARANOIA="yes")
 474   fi
 475   if test "x$HEADER_DIR" = "xyes";
 476   then
 477     AC_DEFINE_UNQUOTED(CDPARANOIA_HEADERS_IN_DIR, ,
 478                        defined if cdda headers are in a cdda/ directory)
 479   fi
 480   AC_SUBST(CDPARANOIA_LIBS)
 481 ])
 482 dnl FIXME : add second check somehow if that is necessary
 483 dnl AC_CHECK_LIB(cdda_paranoia, paranoia_init, : , HAVE_CDPARANOIA=no, -lcdda_interface )
 484 dnl AC_CHECK_HEADER(cdda_paranoia.h, :, HAVE_CDPARANOIA=no)
 485
 486 dnl *** GNOME VFS ***
 487 translit(dnm, m, l) AM_CONDITIONAL(USE_GNOME_VFS, true)
 488 AG_GST_CHECK_FEATURE(GNOME_VFS, [GNOME VFS], gnomevfs, [
 489   AG_GST_PKG_CHECK_MODULES(GNOME_VFS, gnome-vfs-2.0)
 490 ])
 491
 492 dnl *** libvisual ***
 493 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBVISUAL, true)
 494 AG_GST_CHECK_FEATURE(LIBVISUAL, [libvisual visualization library], libvisual, [
 495   AG_GST_PKG_CHECK_MODULES(LIBVISUAL, libvisual-0.4 >= 0.4.0)
 496   if test $HAVE_LIBVISUAL = no
 497   then
 498     AG_GST_PKG_CHECK_MODULES(LIBVISUAL, libvisual = 0.2.0)
 499   fi
 500 ])
 501
 502 dnl *** ogg ***
 503 translit(dnm, m, l) AM_CONDITIONAL(USE_OGG, true)
 504 AG_GST_CHECK_FEATURE(OGG, [Xiph Ogg library], ogg, [
 505   AG_GST_PKG_CHECK_MODULES(OGG, ogg >= 1.0)
 506   if test $HAVE_OGG = no
 507   then
 508     XIPH_PATH_OGG(HAVE_OGG="yes", HAVE_OGG="no")
 509     AS_SCRUB_INCLUDE(OGG_CFLAGS)
 510   fi
 511 ])
 512
 513 dnl *** pango ***
 514 translit(dnm, m, l) AM_CONDITIONAL(USE_PANGO, true)
 515 AG_GST_CHECK_FEATURE(PANGO, [Pango font rendering], pango, [
 516   AG_GST_PKG_CHECK_MODULES(PANGO, pango pangoft2)
 517 ])
 518
 519 dnl *** theora ***
 520 translit(dnm, m, l) AM_CONDITIONAL(USE_THEORA, true)
 521 AG_GST_CHECK_FEATURE(THEORA, [Xiph Theora video codec], theora, [
 522   dnl this check will work as long as theora uses 1.0.x or similar for the
 523   dnl first post-alpha release and not just 1.0
 524   AG_GST_PKG_CHECK_MODULES(THEORA, theora >= 1.0alpha5)
 525 ])
 526
 527 dnl *** vorbis ***
 528 dnl AM_PATH_VORBIS only takes two options
 529 translit(dnm, m, l) AM_CONDITIONAL(USE_VORBIS, true)
 530 AG_GST_CHECK_FEATURE(VORBIS, [Xiph Vorbis audio codec], vorbis, [
 531   AG_GST_PKG_CHECK_MODULES(VORBIS, vorbis >= 1.0 vorbisenc >= 1.0)
 532   if test $HAVE_VORBIS = no
 533   then
 534     XIPH_PATH_VORBIS(HAVE_VORBIS="yes", HAVE_VORBIS="no")
 535     AS_SCRUB_INCLUDE(VORBIS_CFLAGS)
 536   fi
 537 ])
 538
 539 if test "x$HAVE_VORBIS" = "xyes"; then
 540   ac_cflags_save="$CFLAGS"
 541   dnl FIXME: does this work on non-gcc? -- Company
 542   dnl FIXME: no, it doesn't.  Why is this here in the first place ? -- thomasvs
 543   CFLAGS="-Wall -Werror"
 544   AC_COMPILE_IFELSE(
 545     AC_LANG_PROGRAM([
 546 #include <vorbis/codec.h>
 547                      ],[
 548 vorbis_dsp_state *v;
 549
 550 vorbis_synthesis_restart (v);
 551                      ]), HAVE_VSR=yes, HAVE_VSR=no)
 552   if test "x$HAVE_VSR" = "xyes"; then
 553     AC_DEFINE_UNQUOTED(HAVE_VORBIS_SYNTHESIS_RESTART, 1,
 554                        [defined if vorbis_synthesis_restart is present])
 555   fi
 556   CFLAGS="$ac_cflags_save"
 557 fi
 558
 559 else
 560
 561 dnl not building plugins with external dependencies,
 562 dnl but we still need to set the conditionals
 563 AM_CONDITIONAL(USE_ALSA, false)
 564 AM_CONDITIONAL(USE_CDPARANOIA, false)
 565 AM_CONDITIONAL(USE_GNOME_VFS, false)
 566 AM_CONDITIONAL(USE_LIBVISUAL, false)
 567 AM_CONDITIONAL(USE_OGG, false)
 568 AM_CONDITIONAL(USE_PANGO, false)
 569 AM_CONDITIONAL(USE_THEORA, false)
 570 AM_CONDITIONAL(USE_VORBIS, false)
 571
 572 fi dnl of EXT plugins
 573
 574 dnl seeking needs freetype, so check for it here
 575 PKG_CHECK_MODULES(FT2, freetype2 >= 2.0.9, HAVE_FT2="yes", [
 576   AC_CHECK_FT2(2.0.9, HAVE_FT2="yes", HAVE_FT2="no")
 577 ])
 578 dnl make the HAVE_FT2 variable available to automake and Makefile.am
 579 AM_CONDITIONAL(HAVE_FT2, test "x$HAVE_FT2" = "xyes")
 580 AC_SUBST(FT2_CFLAGS)
 581 AC_SUBST(FT2_LIBS)
 582
 583 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 584
 585 dnl Overview:
 586 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
 587 dnl GST_*:              flags shared by built objects to link against GStreamer
 588 dnl GST_PLUGINS_BASE_CFLAGS: to link internally against the plugins base libs
 589 dnl                          (compare to other modules) or for i18n
 590 dnl GST_ALL_LDFLAGS:    linker flags shared by all
 591 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 592 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 593 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 594
 595 dnl GST_OPTION_CFLAGS
 596 if test "x$USE_DEBUG" = xyes; then
 597    PROFILE_CFLAGS="-g"
 598 fi
 599 AC_SUBST(PROFILE_CFLAGS)
 600
 601 DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 602 AC_SUBST(DEPRECATED_CFLAGS)
 603
 604 dnl every flag in GST_OPTION_CFLAGS can be overridden at make time
 605 GST_OPTION_CFLAGS="\$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 606 AC_SUBST(GST_OPTION_CFLAGS)
 607
 608 dnl our libraries need to be versioned correctly
 609 AC_SUBST(GST_LT_LDFLAGS)
 610
 611 dnl GST_PLUGINS_BASE_CFLAGS
 612 dnl prefer internal headers to already installed ones
 613 dnl also add builddir include for enumtypes and marshal
 614 GST_PLUGINS_BASE_CFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs"
 615 AC_SUBST(GST_PLUGINS_BASE_CFLAGS)
 616
 617 dnl FIXME: do we want to rename to GST_ALL_* ?
 618 dnl add GST_OPTION_CFLAGS, but overridable
 619 GST_CFLAGS="$GST_CFLAGS \$(GST_OPTION_CFLAGS)"
 620 AC_SUBST(GST_CFLAGS)
 621 dnl add GCOV libs because libtool strips -fprofile-arcs -ftest-coverage
 622 GST_LIBS="$GST_LIBS \$(GCOV_LIBS)"
 623 AC_SUBST(GST_LIBS)
 624
 625 dnl LDFLAGS really should only contain flags, not libs - they get added before
 626 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 627 GST_ALL_LDFLAGS="-no-undefined"
 628 AC_SUBST(GST_ALL_LDFLAGS)
 629
 630 dnl GST_LIB_LDFLAGS
 631 dnl linker flags shared by all libraries
 632 dnl LDFLAGS modifier defining exported symbols from built libraries
 633 GST_LIB_LDFLAGS="-export-symbols-regex [_]*\(gst_\|Gst\|GST_\).*"
 634 AC_SUBST(GST_LIB_LDFLAGS)
 635
 636 dnl this really should only contain flags, not libs - they get added before
 637 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 638 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc\$\$' $GST_ALL_LDFLAGS"
 639 AC_SUBST(GST_PLUGIN_LDFLAGS)
 640
 641 dnl *** output files ***
 642
 643 AC_CONFIG_FILES(
 644 Makefile
 645 gst-plugins-base.spec
 646 gst/Makefile
 647 gst/adder/Makefile
 648 gst/audioconvert/Makefile
 649 gst/audiorate/Makefile
 650 gst/audioresample/Makefile
 651 gst/audiotestsrc/Makefile
 652 gst/ffmpegcolorspace/Makefile
 653 gst/gdp/Makefile
 654 gst/playback/Makefile
 655 gst/subparse/Makefile
 656 gst/tcp/Makefile
 657 gst/typefind/Makefile
 658 gst/videotestsrc/Makefile
 659 gst/videorate/Makefile
 660 gst/videoscale/Makefile
 661 gst/volume/Makefile
 662 sys/Makefile
 663 sys/ximage/Makefile
 664 sys/xvimage/Makefile
 665 sys/v4l/Makefile
 666 ext/Makefile
 667 ext/alsa/Makefile
 668 ext/cdparanoia/Makefile
 669 ext/gnomevfs/Makefile
 670 ext/libvisual/Makefile
 671 ext/ogg/Makefile
 672 ext/pango/Makefile
 673 ext/theora/Makefile
 674 ext/vorbis/Makefile
 675 gst-libs/Makefile
 676 gst-libs/gst/Makefile
 677 gst-libs/gst/audio/Makefile
 678 gst-libs/gst/cdda/Makefile
 679 gst-libs/gst/floatcast/Makefile
 680 gst-libs/gst/interfaces/Makefile
 681 gst-libs/gst/netbuffer/Makefile
 682 gst-libs/gst/riff/Makefile
 683 gst-libs/gst/rtp/Makefile
 684 gst-libs/gst/rtsp/Makefile
 685 gst-libs/gst/sdp/Makefile
 686 gst-libs/gst/tag/Makefile
 687 gst-libs/gst/pbutils/Makefile
 688 gst-libs/gst/video/Makefile
 689 tools/Makefile
 690 win32/common/config.h
 691 pkgconfig/Makefile
 692 pkgconfig/gstreamer-plugins-base.pc
 693 pkgconfig/gstreamer-plugins-base-uninstalled.pc
 694 tests/Makefile
 695 tests/check/Makefile
 696 tests/examples/Makefile
 697 tests/examples/seek/Makefile
 698 tests/examples/volume/Makefile
 699 tests/icles/Makefile
 700 docs/Makefile
 701 docs/design/Makefile
 702 docs/libs/Makefile
 703 docs/plugins/Makefile
 704 docs/version.entities
 705 po/Makefile.in
 706 common/Makefile
 707 common/m4/Makefile
 708 m4/Makefile
 709 )
 710 AC_OUTPUT
 711
 712 AG_GST_OUTPUT_PLUGINS