configure.ac

   1 AC_PREREQ([2.69])
   2
   3 dnl initialize autoconf
   4 dnl when going to/from release please set the nano (fourth number) right !
   5 dnl releases only do Wall, git and prerelease does Werror too
   6 dnl
   7 AC_INIT([GStreamer],[1.13.0.1],[http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer],[gstreamer])
   8 AG_GST_INIT
   9
  10 dnl initialize automake (we require GNU make)
  11 AM_INIT_AUTOMAKE([-Wno-portability 1.14 no-dist-gzip dist-xz tar-ustar subdir-objects])
  12
  13 dnl define PACKAGE_VERSION_* variables
  14 AS_VERSION
  15
  16 dnl check if this is a release version
  17 AS_NANO(GST_GIT="no", GST_GIT="yes")
  18
  19 dnl can autoconf find the source ?
  20 AC_CONFIG_SRCDIR([gst/gst.c])
  21
  22 dnl define the output header for config
  23 AC_CONFIG_HEADERS([config.h])
  24
  25 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  26 AM_MAINTAINER_MODE([enable])
  27
  28 dnl sets host_* variables
  29 AC_CANONICAL_HOST
  30
  31 dnl use pretty build output by default
  32 AM_SILENT_RULES([yes])
  33
  34 dnl GStreamer versioning, this is mostly informational
  35 GST_VERSION_MAJOR=$PACKAGE_VERSION_MAJOR
  36 GST_VERSION_MINOR=$PACKAGE_VERSION_MINOR
  37 GST_VERSION_MICRO=$PACKAGE_VERSION_MICRO
  38 GST_VERSION_NANO=$PACKAGE_VERSION_NANO
  39 AC_SUBST(GST_VERSION_MAJOR)
  40 AC_SUBST(GST_VERSION_MINOR)
  41 AC_SUBST(GST_VERSION_MICRO)
  42 AC_SUBST(GST_VERSION_NANO)
  43
  44 dnl our libraries and install dirs use GST_API_VERSION in the filename
  45 dnl to allow side-by-side installation of different API versions
  46 GST_API_VERSION=1.0
  47 AC_SUBST(GST_API_VERSION)
  48 AC_DEFINE_UNQUOTED(GST_API_VERSION, "$GST_API_VERSION",
  49   [GStreamer API Version])
  50
  51 dnl CURRENT, REVISION, AGE
  52 dnl - library source changed -> increment REVISION
  53 dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
  54 dnl - interfaces added -> increment AGE
  55 dnl - interfaces removed -> AGE = 0
  56 dnl
  57 dnl Keep CURRENT as MINOR * 100 + MICRO
  58 dnl Ex : 1.0.0 => 0
  59 dnl      1.0.3 => 3
  60 dnl      1.1.0 => 100
  61 dnl      1.2.5 => 205
  62 dnl      1.10.9 (who knows) => 1009
  63 dnl
  64 dnl sets GST_LT_LDFLAGS
  65 AS_LIBTOOL(GST, 1300, 0, 1300)
  66
  67 dnl *** autotools stuff ****
  68
  69 dnl allow for different autotools
  70 AS_AUTOTOOLS_ALTERNATE
  71
  72 dnl Add parameters for aclocal (keep in sync with Makefile.am)
  73 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  74
  75 dnl set up gettext
  76 dnl the version check needs to stay here because autopoint greps for it
  77 AM_GNU_GETTEXT_VERSION([0.17])
  78 AM_GNU_GETTEXT([external])
  79 AG_GST_GETTEXT([gstreamer-$GST_API_VERSION])
  80
  81 dnl *** check for arguments to configure ***
  82
  83 AG_GST_ARG_DISABLE_FATAL_WARNINGS
  84 AG_GST_ARG_ENABLE_EXTRA_CHECKS
  85
  86 dnl subsystems - can influence other decisions so needs to be high up
  87 dnl we need to AM_CONDITIONAL them here for automake 1.6.x compatibility
  88 AG_GST_CHECK_SUBSYSTEM_DISABLE(GST_DEBUG,[debugging subsystem])
  89 AM_CONDITIONAL(GST_DISABLE_GST_DEBUG, test "x$GST_DISABLE_GST_DEBUG" = "xyes")
  90 AG_GST_CHECK_SUBSYSTEM_DISABLE(GST_TRACER_HOOKS,[tracing subsystem hooks])
  91 AM_CONDITIONAL(GST_DISABLE_GST_TRACER_HOOKS, test "x$GST_DISABLE_GST_TRACER_HOOKS" = "xyes")
  92 AG_GST_CHECK_SUBSYSTEM_DISABLE(PARSE,[command-line parser])
  93 AM_CONDITIONAL(GST_DISABLE_PARSE, test "x$GST_DISABLE_PARSE" = "xyes")
  94 if test "x$GST_DISABLE_PARSE" = xyes; then
  95   AC_DEFINE(GST_DISABLE_PARSE, 1,
  96     [Define if pipeline parsing code is disabled])
  97 fi
  98 AG_GST_CHECK_SUBSYSTEM_DISABLE(OPTION_PARSING,[option parsing when gst_init])
  99 AM_CONDITIONAL(GST_DISABLE_OPTION_PARSING, test "x$GST_DISABLE_OPTION_PARSING" = "xyes")
 100 if test "x$GST_DISABLE_OPTION_PARSING" = xyes; then
 101   AC_DEFINE(GST_DISABLE_OPTION_PARSING, 1,
 102     [Define if option parsing is disabled])
 103 fi
 104 AG_GST_CHECK_SUBSYSTEM_DISABLE(REGISTRY,[plugin registry])
 105 AM_CONDITIONAL(GST_DISABLE_REGISTRY, test "x$GST_DISABLE_REGISTRY" = "xyes")
 106 dnl define a substitution to use in docs/gst/gstreamer.types
 107 if test "x$GST_DISABLE_REGISTRY" = "xyes"
 108 then
 109   GST_REGISTRY_DOC_TYPES="%"
 110 else
 111   GST_REGISTRY_DOC_TYPES=
 112 fi
 113 AC_SUBST(GST_REGISTRY_DOC_TYPES)
 114 AG_GST_CHECK_SUBSYSTEM_DISABLE(PLUGIN,[plugin])
 115 AM_CONDITIONAL(GST_DISABLE_PLUGIN, test "x$GST_DISABLE_PLUGIN" = "xyes")
 116
 117 AG_GST_ARG_DEBUG
 118 AG_GST_ARG_PROFILING
 119 AG_GST_ARG_VALGRIND
 120 AG_GST_ARG_GCOV
 121
 122 AG_GST_ARG_EXAMPLES
 123
 124 AG_GST_ARG_WITH_PKG_CONFIG_PATH
 125 AG_GST_ARG_WITH_PACKAGE_NAME
 126 AG_GST_ARG_WITH_PACKAGE_ORIGIN
 127
 128 AG_GST_PKG_CONFIG_PATH
 129
 130 AG_GST_SET_PACKAGE_RELEASE_DATETIME_WITH_NANO([$PACKAGE_VERSION_NANO],
 131   ["${srcdir}/gstreamer.doap"],
 132   [$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_MICRO])
 133
 134 # We only use this when building with MSVC, which is only done with the
 135 # alternate Meson build system files
 136 GSTCONFIG_BUILT_WITH_MSVC=0
 137 AC_SUBST(GSTCONFIG_BUILT_WITH_MSVC)
 138
 139 dnl check for bash completion
 140 AC_ARG_WITH([bash-completion-dir],
 141     AS_HELP_STRING([--with-bash-completion-dir[=PATH]],
 142         [Install the bash auto-completion script in this directory. @<:@default=yes@:>@]),
 143     [],
 144     [with_bash_completion_dir=yes])
 145
 146 if test "x$with_bash_completion_dir" = "xyes"
 147 then
 148     extra_args=
 149
 150     if test "x$prefix" != "xNONE"
 151     then
 152         extra_args="--define-variable=prefix=\"$prefix\""
 153     fi
 154
 155     PKG_CHECK_MODULES([BASH_COMPLETION], [bash-completion >= 2.0],
 156         [
 157           BASH_COMPLETION_DIR="`eval pkg-config $extra_args --variable=completionsdir bash-completion`"
 158           BASH_HELPERS_DIR="`eval pkg-config $extra_args --variable=helpersdir bash-completion`"
 159         ],
 160         [
 161           BASH_COMPLETION_DIR="$datadir/bash-completion/completions"
 162           BASH_HELPERS_DIR="$datadir/bash-completion/helpers"
 163         ])
 164 else
 165     BASH_COMPLETION_DIR="$with_bash_completion_dir/completions"
 166     BASH_HELPERS_DIR="$with_bash_completion_dir/helpers"
 167 fi
 168
 169 AC_SUBST([BASH_COMPLETION_DIR])
 170 AC_SUBST([BASH_HELPERS_DIR])
 171 AM_CONDITIONAL([ENABLE_BASH_COMPLETION],[test "x$with_bash_completion_dir" != "xno"])
 172
 173 dnl If only building static libraries, define GST_STATIC_COMPILATION. This is
 174 dnl needed only on Windows, but it doesn't hurt to have it everywhere.
 175 if test x$enable_static = xyes -a x$enable_shared = xno; then
 176   GST_OBJ_STATIC_CFLAGS="-DGST_STATIC_COMPILATION"
 177 fi
 178
 179 dnl building of tests
 180 AC_ARG_ENABLE(tests,
 181   AS_HELP_STRING([--disable-tests],[disable building test apps]),
 182   [
 183     case "${enableval}" in
 184       yes) BUILD_TESTS=yes ;;
 185       no)  BUILD_TESTS=no ;;
 186       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-tests) ;;
 187     esac
 188   ],
 189 [BUILD_TESTS=yes]) dnl Default value
 190 AM_CONDITIONAL(BUILD_TESTS,         test "x$BUILD_TESTS" = "xyes")
 191
 192 dnl tests known to fail
 193 AC_ARG_ENABLE(failing-tests,
 194   AS_HELP_STRING([--disable-failing-tests],[disable building tests known to fail]),
 195   [
 196     case "${enableval}" in
 197       yes) BUILD_FAILING_TESTS=yes ;;
 198       no)  BUILD_FAILING_TESTS=no ;;
 199       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-failing-tests) ;;
 200     esac
 201   ],
 202   [BUILD_FAILING_TESTS=no]) dnl Default value
 203 AM_CONDITIONAL(BUILD_FAILING_TESTS, test "x$BUILD_FAILING_TESTS" = "xyes")
 204 if test x$BUILD_FAILING_TESTS = xyes; then
 205   AC_MSG_WARN([building tests known to fail, use --disable-failing-tests to disable])
 206 else
 207   AC_MSG_WARN([Sissy ! By asking to not build the tests known to fail, you hereby waive your right to customer support.  If you do not agree with this EULA, please press Ctrl-C before the next line is printed.  By allowing the next line to be printed, you expressly acknowledge your acceptance of this EULA.])
 208 fi
 209
 210 dnl building of benchmarks
 211 AC_ARG_ENABLE(benchmarks,
 212   AS_HELP_STRING([--disable-benchmarks],[disable building benchmarks apps]),
 213   [
 214     case "${enableval}" in
 215       yes) BUILD_BENCHMARKS=yes ;;
 216       no)  BUILD_BENCHMARKS=no ;;
 217       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-benchmarks) ;;
 218     esac
 219   ],
 220 [BUILD_BENCHMARKS=yes]) dnl Default value
 221 AM_CONDITIONAL(BUILD_BENCHMARKS, test "x$BUILD_BENCHMARKS" = "xyes")
 222
 223 dnl building of tools
 224 AC_ARG_ENABLE(tools,
 225   AS_HELP_STRING([--disable-tools],[disable building tools]),
 226   [
 227     case "${enableval}" in
 228       yes) BUILD_TOOLS=yes ;;
 229       no)  BUILD_TOOLS=no ;;
 230       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-tools) ;;
 231     esac
 232   ],
 233 [BUILD_TOOLS=yes]) dnl Default value
 234 AM_CONDITIONAL(BUILD_TOOLS, test "x$BUILD_TOOLS" = "xyes")
 235
 236 dnl poison destroyed objects
 237 AC_ARG_ENABLE(poisoning,
 238   AS_HELP_STRING([--enable-poisoning],[enable poisoning of deallocated objects]),
 239   [
 240     case "${enableval}" in
 241       yes) USE_POISONING=yes ;;
 242       no)  USE_POISONING=no ;;
 243       *)   AC_MSG_ERROR(bad value ${enableval} for --enable-poisoning) ;;
 244     esac
 245   ],
 246   [USE_POISONING=no]) dnl Default value
 247 if test "x$USE_POISONING" = xyes; then
 248   AC_DEFINE(USE_POISONING, 1,
 249     [Define if we should poison deallocated memory])
 250 fi
 251
 252 dnl PTP support parts
 253 AC_MSG_CHECKING([whether PTP support can be enabled])
 254 case "$host_os" in
 255   *android*)
 256     dnl Can't run on Android because of permissions
 257     HAVE_PTP=no
 258     ;;
 259   mingw*|pw32*|cygwin*)
 260     dnl Not ported to Windows yet
 261     HAVE_PTP=no
 262     ;;
 263   darwin*)
 264     dnl Can't run on iOS because of permissions
 265     AC_CHECK_HEADER(MobileCoreServices/MobileCoreServices.h, HAVE_PTP="no", HAVE_PTP="yes", [-])
 266     ;;
 267   linux*|darwin*|solaris*|netbsd*|freebsd*|openbsd*|kfreebsd*|dragonfly*|gnu*)
 268     HAVE_PTP=yes
 269     ;;
 270   *)
 271     HAVE_PTP=no
 272     ;;
 273 esac
 274 AC_MSG_RESULT([$HAVE_PTP])
 275
 276 dnl user/group to change to in gst-ptp-helper
 277 AC_ARG_WITH([ptp-helper-setuid-user],
 278   AS_HELP_STRING([--with-ptp-helper-setuid-user],[User to switch to when installing gst-ptp-helper setuid root]),
 279   [
 280     if test "x$withval" != "x"
 281     then
 282       AC_DEFINE_UNQUOTED(HAVE_PTP_HELPER_SETUID_USER, "$withval", [PTP helper setuid user])
 283     fi
 284   ], []
 285 )
 286
 287 dnl group/group to change to in gst-ptp-helper
 288 AC_ARG_WITH([ptp-helper-setuid-group],
 289   AS_HELP_STRING([--with-ptp-helper-setuid-group],[Group to switch to when installing gst-ptp-helper setuid root]),
 290   [
 291     if test "x$withval" != "x"
 292     then
 293       AC_DEFINE_UNQUOTED(HAVE_PTP_HELPER_SETUID_GROUP, "$withval", [PTP helper setuid group])
 294     fi
 295   ], []
 296 )
 297
 298 AC_ARG_WITH(
 299   ptp-helper-permissions,
 300   AC_HELP_STRING(
 301     [--with-ptp-helper-permissions],
 302     [how to gain PTP permissions (none, setuid-root, capabilities, auto)]),
 303     [],
 304     [with_ptp_helper_permissions=auto])
 305
 306 gst_ptp_have_cap=no
 307 AG_GST_CHECK_LIBHEADER(CAP, cap,
 308                        cap_init, ,
 309                        sys/capability.h,
 310                        CAP_LIBS="-lcap"
 311                        AC_SUBST(CAP_LIBS)
 312                        gst_ptp_have_cap=yes)
 313
 314 AC_PATH_PROG([SETCAP], [setcap], [no], [$PATH:/usr/bin:/bin:/usr/sbin:/sbin])
 315
 316 if test "x$HAVE_PTP" = "xyes"; then
 317 AC_DEFINE(HAVE_PTP, 1, [PTP support available])
 318
 319 AC_MSG_CHECKING([for SIOCGIFCONF, SIOCGIFFLAGS and SIOCGIFHWADDR])
 320 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
 321     [[
 322         #include <sys/ioctl.h>
 323         #include <net/if.h>
 324     ]],
 325     [[
 326         struct ifreq ifr;
 327         struct ifconf ifc;
 328         ioctl(0, SIOCGIFCONF, &ifc);
 329         ioctl(0, SIOCGIFFLAGS, &ifr);
 330         ioctl(0, SIOCGIFHWADDR, &ifr);
 331         int dummy = ifr.ifr_hwaddr.sa_data[0];
 332     ]])], [
 333         AC_MSG_RESULT(yes)
 334         AC_DEFINE(HAVE_SIOCGIFCONF_SIOCGIFFLAGS_SIOCGIFHWADDR, 1, [SIOCGIFCONF, SIOCGIFFLAGS and SIOCGIFHWADDR is available])
 335     ], [
 336         AC_MSG_RESULT(no)
 337 ])
 338
 339 AC_MSG_CHECKING([for getifaddrs() and AF_LINK])
 340 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
 341     [[
 342         #include <ifaddrs.h>
 343         #include <net/if.h>
 344         #include <net/if_dl.h>
 345     ]],
 346     [[
 347         struct ifaddrs *ifaddr;
 348         getifaddrs(&ifaddr);
 349         int dummy = (ifaddr->ifa_flags & IFF_LOOPBACK) && ifaddr->ifa_addr->sa_family != AF_LINK;
 350     ]])], [
 351         AC_MSG_RESULT(yes)
 352         AC_DEFINE(HAVE_GETIFADDRS_AF_LINK, 1, [getifaddrs() and AF_LINK is available])
 353     ], [
 354         AC_MSG_RESULT(no)
 355     ])
 356
 357 AC_MSG_CHECKING([how to install gst-ptp-helper])
 358 if test "x$with_ptp_helper_permissions" = "xauto"; then
 359     if test "x$gst_ptp_have_cap" = "xyes" -a "x$SETCAP" != "xno"; then
 360         with_ptp_helper_permissions="capabilities"
 361     else
 362         with_ptp_helper_permissions="setuid-root"
 363     fi
 364 fi
 365 AC_MSG_RESULT([$with_ptp_helper_permissions])
 366
 367 case "$with_ptp_helper_permissions" in
 368   none)
 369     ;;
 370   setuid-root)
 371      AC_DEFINE(HAVE_PTP_HELPER_SETUID, 1,
 372         [Use setuid-root for permissions in PTP helper])
 373     ;;
 374   capabilities)
 375      AC_DEFINE(HAVE_PTP_HELPER_CAPABILITIES, 1,
 376         [Use capabilities for permissions in PTP helper])
 377     ;;
 378   *)
 379     AC_MSG_ERROR(Invalid parameter [$with_ptp_helper_permissions])
 380     ;;
 381 esac
 382
 383 fi
 384
 385 AM_CONDITIONAL(HAVE_PTP, test "x$HAVE_PTP" = "xyes")
 386 AM_CONDITIONAL(HAVE_PTP_HELPER_SETUID, test "x$with_ptp_helper_permissions" = "xsetuid-root")
 387 AM_CONDITIONAL(HAVE_PTP_HELPER_CAPABILITIES, test "x$with_ptp_helper_permissions" = "xcapabilities")
 388
 389 dnl *** checks for platform ***
 390
 391 dnl * hardware/architecture *
 392
 393 dnl common/m4/gst-arch.m4
 394 dnl check CPU type
 395 AG_GST_ARCH
 396
 397 dnl check for platform specific settings
 398 AG_GST_PLATFORM
 399
 400 dnl * software *
 401
 402 dnl check for large file support
 403 dnl affected plugins must include config.h
 404 AC_SYS_LARGEFILE
 405
 406 dnl *** checks for programs ***
 407
 408 dnl find a compiler
 409 AC_PROG_CC
 410 AC_PROG_CC_STDC
 411
 412 dnl check if the compiler supports '-c' and '-o' options
 413 AM_PROG_CC_C_O
 414
 415 dnl find an assembler
 416 AM_PROG_AS
 417
 418 dnl determine if c++ is available on this system
 419 AC_PROG_CXX
 420 dnl CXX may be set to some default even if no c++ compiler is available
 421 dnl (thanks autotools!), so just try to compile some c++ code to make sure
 422 AC_LANG_PUSH([C++])
 423 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[ class Foo { int bar; };]], [[]])],[working_cxx=yes],[working_cxx=no])
 424 AC_LANG_POP([C++])
 425 AC_MSG_NOTICE([working c++ compiler found: $working_cxx])
 426 AM_CONDITIONAL(HAVE_CXX, test "x$working_cxx" = "xyes")
 427
 428 dnl Perl is used in building documentation and in the version checks
 429 AC_PATH_PROG(PERL_PATH, perl, no)
 430 if test x$PERL_PATH = xno; then
 431   AC_MSG_ERROR(Could not find perl)
 432 fi
 433
 434 dnl we require flex and bison for building the parser
 435 if test "x$GST_DISABLE_PARSE" != xyes; then
 436   AG_GST_BISON_CHECK
 437   AG_GST_FLEX_CHECK
 438 fi
 439
 440 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 441 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 442
 443 dnl check for gobject-introspection
 444 GOBJECT_INTROSPECTION_CHECK([1.31.1])
 445
 446 dnl check for documentation tools
 447 GTK_DOC_CHECK([1.12])
 448 AG_GST_PLUGIN_DOCS([1.12])
 449
 450 dnl *** checks for libraries ***
 451
 452 dnl check for libm, for sin()
 453 LT_LIB_M
 454 AC_SUBST(LIBM)
 455
 456 dnl *** checks for header files ***
 457
 458 dnl check if we have ANSI C header files
 459 AC_HEADER_STDC
 460
 461 dnl Check for ucontext.h
 462 AC_CHECK_HEADERS([ucontext.h], [], [], [AC_INCLUDES_DEFAULT])
 463
 464 dnl Check for sys/socket.h
 465 AC_CHECK_HEADERS([sys/socket.h], [HAVE_SYS_SOCKET_H=yes], [HAVE_SYS_SOCKET_H=no], [AC_INCLUDES_DEFAULT])
 466 AM_CONDITIONAL(HAVE_SYS_SOCKET_H, test "x$HAVE_SYS_SOCKET_H" = "xyes")
 467
 468 dnl check for sys/times.h for tests/examples/adapter/
 469 AC_CHECK_HEADERS([sys/times.h], [HAVE_SYS_TIMES_H=yes], [HAVE_SYS_TIME_H=no], [AC_INCLUDES_DEFAULT])
 470 AC_CHECK_HEADERS([unistd.h], [HAVE_UNISTD_H=yes], [HAVE_UNISTD_H=no], [AC_INCLUDES_DEFAULT])
 471 AM_CONDITIONAL(HAVE_SYS_TIMES_H_AND_UNISTD_H, test "x$HAVE_SYS_TIMES_H" = "xyes" -a "x$HAVE_UNISTD_H" = "xyes")
 472
 473 dnl Check for process.h for getpid() on win32
 474 AC_CHECK_HEADERS([process.h], [], [], [AC_INCLUDES_DEFAULT])
 475
 476 dnl Check for sys/utsname.h for uname
 477 AC_CHECK_HEADERS([sys/utsname.h], [], [], [AC_INCLUDES_DEFAULT])
 478
 479 dnl Check for stdio_ext.f for __fbufsize
 480 AC_CHECK_HEADERS([stdio_ext.h], [], [], [AC_INCLUDES_DEFAULT])
 481
 482 dnl check for pthreads
 483 dnl without arguments AX_PTHREAD() will do AC_DEFINE(HAVE_PTHREAD)
 484 dnl which later checks use in their test code
 485 AX_PTHREAD()
 486 AM_CONDITIONAL(HAVE_PTHREAD, test "x$ax_pthread_ok" = "xyes")
 487
 488 dnl check for sys/prctl for setting thread name on Linux
 489 AC_CHECK_HEADERS([sys/prctl.h], [], [], [AC_INCLUDES_DEFAULT])
 490
 491 dnl check for pthread_setname_np(const char*)
 492 dnl which is present on OS X 10.6, iOS 3.2 and above
 493 AC_MSG_CHECKING(for pthread_setname_np(const char*))
 494 AC_LINK_IFELSE(
 495     [AC_LANG_PROGRAM(
 496         [#include <pthread.h>],
 497         [pthread_setname_np("example")])],
 498     [AC_MSG_RESULT(yes)
 499      AC_DEFINE(HAVE_PTHREAD_SETNAME_NP_WITHOUT_TID,1,
 500         [Have function pthread_setname_np(const char*)])],
 501     [AC_MSG_RESULT(no)])
 502
 503 dnl check for sys/uio.h for writev()
 504 AC_CHECK_HEADERS([sys/uio.h], [], [], [AC_INCLUDES_DEFAULT])
 505
 506 dnl Check for valgrind.h
 507 dnl separate from HAVE_VALGRIND because you can have the program, but not
 508 dnl the dev package
 509 AC_CHECK_HEADERS([valgrind/valgrind.h], [], [], [AC_INCLUDES_DEFAULT])
 510
 511 dnl used in gst/gstpoll.c
 512 AC_CHECK_HEADERS([winsock2.h], [HAVE_WINSOCK2_H=yes], [HAVE_WINSOCK2_H=no], [AC_INCLUDES_DEFAULT])
 513 AM_CONDITIONAL(HAVE_WINSOCK2_H, test "x$HAVE_WINSOCK2_H" = "xyes")
 514 if test "x$HAVE_WINSOCK2_H" = "xyes"; then
 515   WIN32_LIBS="-lws2_32"
 516   AC_SUBST(WIN32_LIBS)
 517 fi
 518
 519 dnl check for GMP/GSL, used by the gst_util_uint64_scale unit test only
 520 if test "x$BUILD_TESTS" = "xyes"; then
 521   AG_GST_CHECK_LIBHEADER(GMP, gmp,
 522                          __gmpz_init_set_d, ,
 523                          gmp.h,
 524                          GMP_LIBS="-lgmp"
 525                          AC_SUBST(GMP_LIBS)
 526                          AC_DEFINE(HAVE_GMP, [1],[Have GMP library]))
 527   AG_GST_CHECK_LIBHEADER(GSL, gsl,
 528                          gsl_rng_uniform_int, -lgslcblas,
 529                          gsl/gsl_rng.h,
 530                          GSL_LIBS="-lgsl -lgslcblas"
 531                          AC_SUBST(GSL_LIBS)
 532                          AC_DEFINE(HAVE_GSL, [1],[Have GSL library]))
 533 fi
 534
 535 dnl *** checks for types/defines ***
 536
 537 dnl *** checks for structures ***
 538
 539 dnl *** checks for compiler characteristics ***
 540
 541 dnl check if the compiler supports __uint128_t (gcc)
 542 dnl Actually check for 128-bit division, since that's what we use
 543 dnl uint128_t for.
 544 AC_CACHE_CHECK(for __uint128_t, gst_cv_uint128_t,
 545     AC_LINK_IFELSE([AC_LANG_PROGRAM([[ ]], [[
 546       static __uint128_t v1 = 100;
 547       static __uint128_t v2 = 10;
 548       static __uint128_t u;
 549       u = v1 / v2;
 550     ]])],[
 551       gst_cv_uint128_t=yes
 552     ],[
 553       gst_cv_uint128_t=no
 554     ])
 555 )
 556 if test x$gst_cv_uint128_t = xyes; then
 557   AC_DEFINE(HAVE_UINT128_T, 1, [Have __uint128_t type])
 558 fi
 559
 560 dnl *** checking for tm_gmtoff ***
 561 AC_MSG_CHECKING([for tm_gmtoff])
 562 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 563         #include <time.h>
 564         int main(void) {
 565           struct tm t;
 566           t.tm_gmtoff = 0;
 567           exit(0);
 568         }]])],
 569   [have_tm_gmtoff=yes
 570    AC_DEFINE(HAVE_TM_GMTOFF,1,[Have tm_gmtoff field in struct tm])],
 571   [have_tm_gmtoff=no],
 572   [have_tm_gmtoff="no (cross compiling)"])
 573 AC_MSG_RESULT($have_tm_gmtoff)
 574
 575
 576 dnl *** checks for library functions ***
 577
 578 AC_CHECK_FUNCS([strcasestr])
 579
 580 AC_CHECK_FUNCS([gmtime_r])
 581 AC_CHECK_FUNCS([localtime_r])
 582 AC_CHECK_FUNCS([sigaction])
 583 AC_CHECK_FUNCS([getrusage])
 584 AM_CONDITIONAL(HAVE_GETRUSAGE, test "x$ac_cv_func_getrusage" = "xyes")
 585 AC_CHECK_HEADERS([sys/resource.h])
 586
 587 dnl check for fseeko()
 588 AC_FUNC_FSEEKO
 589 dnl check for ftello()
 590 AC_CHECK_FUNCS([ftello])
 591
 592 AC_CHECK_FUNCS([fgetpos])
 593 AC_CHECK_FUNCS([fsetpos])
 594
 595 dnl check for poll(), ppoll() and pselect()
 596 AC_CHECK_HEADERS([sys/poll.h], [], [], [AC_INCLUDES_DEFAULT])
 597 AC_CHECK_HEADERS([poll.h], [], [], [AC_INCLUDES_DEFAULT])
 598 AC_CHECK_FUNCS([poll])
 599 AC_CHECK_FUNCS([ppoll])
 600 AC_CHECK_FUNCS([pselect])
 601
 602 dnl check for socketpair()
 603 AC_CHECK_FUNC(socketpair, [], [
 604   AC_CHECK_LIB(socket, socketpair, [
 605     SOCKET_LIBS="-lsocket"
 606     AC_SUBST(SOCKET_LIBS)
 607   ])
 608 ])
 609
 610 dnl ****************************************
 611 dnl *** GLib POLL* compatibility defines ***
 612 dnl ****************************************
 613
 614 AC_MSG_CHECKING([for broken poll])
 615 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 616         #include <stdlib.h>
 617         #include <fcntl.h>
 618         #ifdef HAVE_SYS_POLL_H
 619         #include <sys/poll.h>
 620         #endif
 621         #ifdef HAVE_POLL_H
 622         #include <poll.h>
 623         #endif
 624         int main(void) {
 625           struct pollfd fds[1];
 626           int fd;
 627           fd = open("/dev/null", 1);
 628           fds[0].fd = fd;
 629           fds[0].events = POLLIN;
 630           fds[0].revents = 0;
 631           if (poll(fds, 1, 0) < 0 || (fds[0].revents & POLLNVAL) != 0) {
 632                 exit(1);  /* Does not work for devices -- fail */
 633           }
 634           exit(0);
 635         }]])],
 636   [broken_poll=no],
 637   [broken_poll=yes
 638    AC_DEFINE(BROKEN_POLL,1,[poll doesn't work on devices])],
 639   [broken_poll="no (cross compiling)"])
 640 AC_MSG_RESULT($broken_poll)
 641
 642 dnl check for getpagesize()
 643 AC_CHECK_FUNCS([getpagesize])
 644
 645 dnl Check for POSIX timers
 646 CLOCK_GETTIME_FOUND="no"
 647 AC_CHECK_FUNC(clock_gettime, [CLOCK_GETTIME_FOUND="yes"], [
 648   AC_CHECK_LIB(rt, clock_gettime, [
 649     CLOCK_GETTIME_FOUND="yes"
 650     LIBS="$LIBS -lrt"
 651   ], [
 652     AC_CHECK_LIB(pthread, clock_gettime, [
 653       CLOCK_GETTIME_FOUND="yes"
 654       LIBS="$LIBS -lpthread"
 655     ])
 656   ])
 657 ])
 658
 659 # With XCode 8, clock_gettime will be incorrectly detected as being available
 660 # regardless of what version of OS X you target because the symbol is available
 661 # in the .tbd file as a weak symbol.
 662 # See: https://bugzilla.gnome.org/show_bug.cgi?id=772451
 663 #
 664 # We cannot simply do AC_CHECK_FUNCS with -Wl,-no_weak_imports because the
 665 # autoconf check does its own prototype declaration that doesn't trigger that
 666 # compiler flag.
 667 #
 668 # It's only starting from macOS 10.12 and iOS 10.0 that clock_gettime is
 669 # actually available, so we can unconditionally disable it for older versions.
 670 case "$host_os" in
 671   darwin*)
 672     AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 673 #include <AvailabilityMacros.h>
 674 #include <TargetConditionals.h>
 675 #if defined(TARGET_OS_MAC)
 676 #  if MAC_OS_X_VERSION_MIN_REQUIRED < MAC_OS_X_VERSION_10_12
 677 #    error "Not compiling for OS X 10.12 or later"
 678 #  endif
 679 #else
 680 #  if __IPHONE_OS_VERSION_MIN_REQUIRED < __IPHONE_10_0
 681 #    error "Not compiling for iOS 10.0 or later"
 682 #  endif
 683 #endif
 684     ]])], [], [
 685     if test "$CLOCK_GETTIME_FOUND" = "yes"; then
 686       AC_MSG_NOTICE([Disabling incorrectly detected clock_gettime on OS X])
 687     fi
 688     CLOCK_GETTIME_FOUND="no"
 689     ])
 690     ;;
 691 esac
 692
 693 if test "$CLOCK_GETTIME_FOUND" = "yes"; then
 694   AC_DEFINE(HAVE_CLOCK_GETTIME, 1, [Have clock_gettime])
 695 fi
 696
 697 AC_CACHE_CHECK(for posix timers, gst_cv_posix_timers,
 698     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 699 #include <time.h>
 700 #ifdef HAVE_UNISTD_H
 701 #include <unistd.h>
 702 #endif
 703     ]], [[
 704 #if !defined(_POSIX_TIMERS) || _POSIX_TIMERS < 0 || !defined(CLOCK_REALTIME)
 705 #error Either _POSIX_TIMERS or CLOCK_REALTIME not defined
 706 #endif
 707     ]])],[
 708       gst_cv_posix_timers=yes
 709     ],[
 710       gst_cv_posix_timers=no
 711     ])
 712 )
 713
 714 if test "$gst_cv_posix_timers" = "yes"; then
 715   AC_DEFINE(HAVE_POSIX_TIMERS,1,[Have posix timers])
 716   GST_HAVE_POSIX_TIMERS_DEFINE="#define GST_HAVE_POSIX_TIMERS 1"
 717 else
 718   GST_HAVE_POSIX_TIMERS_DEFINE="#define GST_HAVE_POSIX_TIMERS 0"
 719 fi
 720 AC_SUBST(GST_HAVE_POSIX_TIMERS_DEFINE)
 721 AM_CONDITIONAL(GST_HAVE_POSIX_TIMERS, test "$gst_cv_posix_timers" = "yes")
 722
 723 AC_CACHE_CHECK(for monotonic clock, gst_cv_monotonic_clock,
 724     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 725 #include <time.h>
 726 #ifdef HAVE_UNISTD_H
 727 #include <unistd.h>
 728 #endif
 729     ]], [[
 730 #if !defined(_POSIX_MONOTONIC_CLOCK) || _POSIX_MONOTONIC_CLOCK < 0 || !defined(CLOCK_MONOTONIC)
 731 #error Either _POSIX_MONOTONIC_CLOCK or CLOCK_MONOTONIC not defined
 732 #endif
 733     ]])],[
 734       gst_cv_monotonic_clock=yes
 735     ],[
 736       gst_cv_monotonic_clock=no
 737     ])
 738 )
 739
 740 if test "$gst_cv_monotonic_clock" = "yes"; then
 741   AC_DEFINE(HAVE_MONOTONIC_CLOCK,1,[Have a monotonic clock])
 742   GST_HAVE_MONOTONIC_CLOCK_DEFINE="#define GST_HAVE_MONOTONIC_CLOCK 1"
 743 else
 744   GST_HAVE_MONOTONIC_CLOCK_DEFINE="#define GST_HAVE_MONOTONIC_CLOCK 0"
 745 fi
 746 AC_SUBST(GST_HAVE_MONOTONIC_CLOCK_DEFINE)
 747 AM_CONDITIONAL(GST_HAVE_MONOTONIC_CLOCK, test "$gst_cv_monotonic_clock" = "yes")
 748
 749 dnl Check for a way to display the function name in debug output
 750 AG_GST_CHECK_FUNCTION
 751
 752 dnl test if we have dladdr(); we use it for debugging; see gst/gstinfo.c
 753 save_cflags="$CFLAGS"
 754 CFLAGS="$CFLAGS -D_GNU_SOURCE"
 755 AC_CHECK_LIB(dl, dladdr,
 756    AC_DEFINE(HAVE_DLADDR, 1, [Defined if we have dladdr ()])
 757    LIBS="$LIBS -ldl")
 758 CFLAGS="$save_cflags"
 759
 760 dnl Check printf stuff
 761 if test "x${GST_DISABLE_GST_DEBUG}" != "xyes"; then
 762   AC_TYPE_LONG_LONG_INT
 763   AC_TYPE_UNSIGNED_LONG_LONG_INT
 764
 765   if test x$ac_cv_type_long_long_int$ac_cv_type_unsigned_long_long_int = xyesyes; then
 766     AC_DEFINE([HAVE_LONG_LONG], [1], [Define to 1 if the system has the type long long])
 767   fi
 768
 769   dnl /usr/share/aclocal/inttypes_h.m4 - ships with gettext apparently
 770   gl_AC_HEADER_INTTYPES_H
 771
 772   dnl /usr/share/aclocal/stdint_h.m4 - ships with gettext apparently
 773   gl_AC_HEADER_STDINT_H
 774
 775   AC_CHECK_TYPES(ptrdiff_t)
 776
 777   AC_TYPE_INTMAX_T
 778   AC_TYPE_SIZE_T
 779 fi
 780
 781 dnl *** checks for dependency libraries ***
 782
 783 dnl GLib
 784 GLIB_REQ=2.40.0
 785 AG_GST_GLIB_CHECK([$GLIB_REQ])
 786
 787 dnl Check for documentation xrefs
 788 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 789 AC_SUBST(GLIB_PREFIX)
 790
 791 dnl GTK is optional and only used in examples
 792 HAVE_GTK=no
 793 GTK_REQ=3.10
 794 if test "x$BUILD_EXAMPLES" = "xyes"; then
 795   PKG_CHECK_MODULES(GTK, gtk+-3.0 >= $GTK_REQ, HAVE_GTK=yes, HAVE_GTK=no)
 796   AC_SUBST(GTK_LIBS)
 797   AC_SUBST(GTK_CFLAGS)
 798 fi
 799 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 800
 801 dnl libunwind is optionally used by the leaks tracer
 802 PKG_CHECK_MODULES(UNWIND, libunwind, HAVE_UNWIND=yes, HAVE_UNWIND=no)
 803 if test "x$HAVE_UNWIND" = "xyes"; then
 804   AC_DEFINE(HAVE_UNWIND, 1, [libunwind available])
 805   UNWIND_REQUIRE=libunwind
 806   AC_SUBST(UNWIND_REQUIRE)
 807 fi
 808
 809 dnl libdw is optionally used to add source lines and numbers to backtraces
 810 PKG_CHECK_MODULES(DW, libdw, HAVE_DW=yes, HAVE_DW=no)
 811 if test "x$HAVE_DW" = "xyes"; then
 812   AC_DEFINE(HAVE_DW, 1, [libdw available])
 813   DW_REQUIRE=libdw
 814   AC_SUBST(DW_REQUIRE)
 815 fi
 816
 817 dnl Check for backtrace() from libc
 818 AC_CHECK_FUNC(backtrace, [
 819   AC_CHECK_HEADERS([execinfo.h], [
 820     AC_DEFINE(HAVE_BACKTRACE,1,[Have backtrace])
 821   ], [], [])
 822 ])
 823
 824 dnl building of unit test libraries
 825 AC_ARG_ENABLE(check,
 826   AS_HELP_STRING([--disable-check],[disable building unit test libraries]),
 827   [
 828     case "${enableval}" in
 829       yes) BUILD_CHECK=yes ;;
 830       no)  BUILD_CHECK=no ;;
 831       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-check) ;;
 832     esac
 833   ], [
 834     dnl Default value
 835     case $host_os in
 836       mingw* | msvc* | mks*) BUILD_CHECK=no ;;
 837       *) BUILD_CHECK=yes ;;
 838     esac
 839 ])
 840 dnl bit of a misnomer, but keep the conditional named like this so we don't
 841 dnl have to change too much elsewhere
 842 AM_CONDITIONAL(HAVE_CHECK, test "x$BUILD_CHECK" = "xyes")
 843
 844 dnl configure the desired memory alignment
 845 AC_ARG_WITH([memory-alignment],
 846   AS_HELP_STRING([--with-memory-alignment],[8,N,malloc,pagesize (default is 32)]),
 847   [
 848     if test "x$withval" = "xyes"
 849     then
 850       AC_DEFINE(MEMORY_ALIGNMENT, 32, [Memory alignment to use])
 851     else
 852       case "${withval}" in
 853         malloc) AC_DEFINE(MEMORY_ALIGNMENT_MALLOC, 1, [Memory alignment by malloc default]) ;;
 854         pagesize)  AC_DEFINE(MEMORY_ALIGNMENT_PAGESIZE, 1, [Memory alignment by pagesize]) ;;
 855         *)   AC_DEFINE_UNQUOTED(MEMORY_ALIGNMENT, ${withval}, [Memory alignment to use]) ;;
 856       esac
 857     fi
 858   ], [
 859     AC_DEFINE(MEMORY_ALIGNMENT_MALLOC, 1, [Memory alignment by malloc default])
 860   ]
 861 )
 862
 863 dnl Check for -Bsymbolic-functions linker flag used to avoid
 864 dnl intra-library PLT jumps, if available.
 865 AC_ARG_ENABLE(Bsymbolic,
 866               [AS_HELP_STRING([--disable-Bsymbolic],[avoid linking with -Bsymbolic])],,
 867               [SAVED_LDFLAGS="${LDFLAGS}" SAVED_LIBS="${LIBS}"
 868                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
 869                LDFLAGS=-Wl,-Bsymbolic-functions
 870                LIBS=
 871                AC_TRY_LINK([], [return 0],
 872                            AC_MSG_RESULT(yes)
 873                            enable_Bsymbolic=yes,
 874                            AC_MSG_RESULT(no)
 875                            enable_Bsymbolic=no)
 876                LDFLAGS="${SAVED_LDFLAGS}" LIBS="${SAVED_LIBS}"])
 877
 878
 879 dnl *** set variables based on configure arguments
 880
 881 dnl set license and copyright notice
 882 GST_LICENSE="LGPL"
 883 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 884 AC_SUBST(GST_LICENSE)
 885
 886 dnl define LIBDIR, GST_DATADIR so we can inform people where we live
 887 AS_AC_EXPAND(LIBDIR, $libdir)
 888 AC_DEFINE_UNQUOTED(LIBDIR, "$LIBDIR", [library dir])
 889 AS_AC_EXPAND(DATADIR, $datadir)
 890 AC_DEFINE_UNQUOTED(GST_DATADIR, "$DATADIR", [data dir])
 891
 892 dnl set location of plugin directory
 893 AG_GST_SET_PLUGINDIR
 894
 895 dnl make sure it doesn't complain about unused variables if debugging is disabled
 896 NO_WARNINGS=""
 897 if test "x${GST_DISABLE_GST_DEBUG}" = "xyes"; then
 898   NO_WARNINGS="-Wno-unused"
 899 fi
 900
 901 dnl define an ERROR_CFLAGS Makefile variable
 902 AG_GST_SET_ERROR_CFLAGS($FATAL_WARNINGS, [-Wmissing-declarations -Wmissing-prototypes -Wredundant-decls -Wundef -Wwrite-strings -Wformat-nonliteral -Wformat-security -Wold-style-definition -Winit-self -Wmissing-include-dirs -Waddress -Waggregate-return -Wno-multichar -Wnested-externs $NO_WARNINGS])
 903
 904 dnl special warning flags for gst/printf
 905 AS_COMPILER_FLAG([-Wno-format-nonliteral], [PRINTF_CFLAGS="-Wno-format-nonliteral"])
 906 AC_SUBST(PRINTF_CFLAGS)
 907
 908 dnl define correct level for debugging messages
 909 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 910
 911 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 912
 913 dnl Overview:
 914 dnl GST_OPTION_CFLAGS:  common cflags for profiling, debugging, errors, ...
 915 dnl GST_ALL_*:          vars shared by all built objects
 916 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 917 dnl GST_OBJ_*:          additional vars to link to the core library
 918 dnl                     include GST_ALL_*
 919 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 920 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 921
 922 dnl GST_OPTION_CFLAGS
 923 if test "x$USE_DEBUG" = xyes; then
 924    PROFILE_CFLAGS="-g"
 925 fi
 926 AC_SUBST(PROFILE_CFLAGS)
 927
 928 # GST_DISABLE_DEPRECATED: hide the visibility of deprecated
 929 # functionality from the API that gstreamer uses
 930 # GST_REMOVE_DEPRECATED: don't compile deprecated functionality (breaks ABI)
 931 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
 932   dnl Define _only_ when compiling from git (not for pre-releases or releases)
 933   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 934 else
 935   DEPRECATED_CFLAGS=""
 936 fi
 937 AC_SUBST(DEPRECATED_CFLAGS)
 938
 939 dnl every flag in GST_OPTION_CFLAGS can be overridden at make time via e.g.
 940 dnl make DEPRECATED_CFLAGS=''
 941 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 942 GST_OPTION_CXXFLAGS="\$(WARNING_CXXFLAGS) \$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 943 GST_OPTION_CFLAGS="$GST_OPTION_CFLAGS"
 944 GST_OPTION_CXXFLAGS="$GST_OPTION_CXXFLAGS"
 945 AC_SUBST(GST_OPTION_CFLAGS)
 946 AC_SUBST(GST_OPTION_CXXFLAGS)
 947
 948 dnl GST_ALL_*
 949 dnl vars common to for all internal objects (core libs, elements, applications)
 950 dnl CFLAGS:
 951 dnl - src and build dirs need to be added because every piece that gets built
 952 dnl   will need the GStreamer source and generated headers
 953 dnl LIBS: XML doesn't need to be added because we don't explicitly use symbols
 954 dnl       from LibXML except for in the core library
 955 GST_ALL_CXXFLAGS="-I\$(top_srcdir)/libs -I\$(top_srcdir) -I\$(top_builddir)/libs -I\$(top_builddir) $GLIB_CFLAGS \$(GLIB_EXTRA_CFLAGS) $XML_CFLAGS \$(GST_OPTION_CXXFLAGS) \$(ERROR_CXXFLAGS)"
 956 GST_ALL_CFLAGS="-I\$(top_srcdir)/libs -I\$(top_srcdir) -I\$(top_builddir)/libs -I\$(top_builddir) $GLIB_CFLAGS \$(GLIB_EXTRA_CFLAGS) $XML_CFLAGS \$(GST_OPTION_CFLAGS) \$(ERROR_CFLAGS)"
 957
 958 dnl FIXME: check if LTLIBINTL is needed everywhere
 959 dnl I presume it is given that it contains the symbols that _() stuff maps to
 960 GST_ALL_LIBS="$GLIB_LIBS $LTLIBINTL \$(GCOV_LIBS)"
 961
 962 dnl LDFLAGS really should only contain flags, not libs - they get added before
 963 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 964 GST_ALL_LDFLAGS="-no-undefined"
 965 if test "x${enable_Bsymbolic}" = "xyes"; then
 966   GST_ALL_LDFLAGS="$GST_ALL_LDFLAGS -Wl,-Bsymbolic-functions"
 967 fi
 968
 969 AC_SUBST(GST_ALL_CFLAGS)
 970 AC_SUBST(GST_ALL_CXXFLAGS)
 971 AC_SUBST(GST_ALL_LIBS)
 972 AC_SUBST(GST_ALL_LDFLAGS)
 973
 974 dnl GST_LIB_LDFLAGS
 975 dnl linker flags shared by all libraries
 976 dnl LDFLAGS modifier defining exported symbols from built libraries
 977 GST_LIB_LDFLAGS="-export-symbols-regex \^[_]?\(gst_\|Gst\|GST_\).*"
 978 AC_SUBST(GST_LIB_LDFLAGS)
 979
 980 dnl GST_OBJ_*
 981 dnl default vars for all internal objects built on libgstreamer
 982 dnl includes GST_ALL_*
 983 GST_OBJ_CFLAGS="\$(GST_ALL_CFLAGS) $GST_OBJ_STATIC_CFLAGS"
 984 GST_OBJ_CXXFLAGS="\$(GST_ALL_CXXFLAGS) $GST_OBJ_STATIC_CFLAGS"
 985 GST_OBJ_LIBS="\$(top_builddir)/gst/libgstreamer-$GST_API_VERSION.la \$(GST_ALL_LIBS)"
 986 AC_SUBST(GST_OBJ_CFLAGS)
 987 AC_SUBST(GST_OBJ_CXXFLAGS)
 988 AC_SUBST(GST_OBJ_LIBS)
 989
 990 dnl GST_PLUGIN_LDFLAGS
 991 dnl LDFLAGS for plugins; includes GST_ALL_LDFLAGS
 992 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_.*' $GST_ALL_LDFLAGS"
 993 AC_SUBST(GST_PLUGIN_LDFLAGS, "$GST_PLUGIN_LDFLAGS")
 994
 995 dnl plugin scanner locations
 996 AS_AC_EXPAND(GST_PLUGIN_SCANNER_INSTALLED,${libexecdir}/gstreamer-$GST_API_VERSION/gst-plugin-scanner)
 997 AC_DEFINE_UNQUOTED(GST_PLUGIN_SCANNER_INSTALLED,
 998     "$GST_PLUGIN_SCANNER_INSTALLED", [location of the installed gst-plugin-scanner])
 999 AC_SUBST(GST_PLUGIN_SCANNER_INSTALLED)
1000
1001 case "${libexecdir}" in
1002   *libexec)
1003     GST_PLUGIN_SCANNER_SUBDIR="libexec";;
1004   *lib)
1005     GST_PLUGIN_SCANNER_SUBDIR="lib";;
1006   *)
1007     GST_PLUGIN_SCANNER_SUBDIR=`basename ${libexecdir}`;
1008     if test -z "$GST_PLUGIN_SCANNER_SUBDIR"; then
1009       AC_MSG_WARN([Couldn't determined libexecdir suffix, using "lib"])
1010       GST_PLUGIN_SCANNER_SUBDIR="lib";
1011     fi
1012     ;;
1013 esac
1014 AC_DEFINE_UNQUOTED(GST_PLUGIN_SCANNER_SUBDIR,
1015     "$GST_PLUGIN_SCANNER_SUBDIR", [libexecdir path component, used to find plugin-scanner on relocatable builds on windows])
1016
1017
1018 dnl completion helper locations
1019 AS_AC_EXPAND(GST_COMPLETION_HELPER_INSTALLED,${libexecdir}/gstreamer-$GST_API_VERSION/gst-completion-helper)
1020 AC_DEFINE_UNQUOTED(GST_COMPLETION_HELPER_INSTALLED,
1021     "$GST_COMPLETION_HELPER_INSTALLED", [location of the installed gst-completion-helper])
1022 AC_SUBST(GST_COMPLETION_HELPER_INSTALLED)
1023
1024 dnl ptp helper locations
1025 AS_AC_EXPAND(GST_PTP_HELPER_INSTALLED,${libexecdir}/gstreamer-$GST_API_VERSION/gst-ptp-helper)
1026 AC_DEFINE_UNQUOTED(GST_PTP_HELPER_INSTALLED,
1027     "$GST_PTP_HELPER_INSTALLED", [location of the installed gst-ptp-helper])
1028 AC_SUBST(GST_PTP_HELPER_INSTALLED)
1029
1030 dnl things for our internal libcheck (must be called even if building
1031 dnl libcheck is disabled because it defines conditionals)
1032 AG_GST_CHECK_CHECKS
1033
1034 AC_CONFIG_FILES(
1035 Makefile
1036 data/Makefile
1037 data/bash-completion/helpers/gst
1038 gst/Makefile
1039 gst/gstconfig.h
1040 gst/gstversion.h
1041 gst/parse/Makefile
1042 gst/printf/Makefile
1043 libs/Makefile
1044 libs/gst/Makefile
1045 libs/gst/base/Makefile
1046 libs/gst/check/Makefile
1047 libs/gst/check/libcheck/Makefile
1048 libs/gst/check/internal-check.h:libs/gst/check/libcheck/check.h.in
1049 libs/gst/controller/Makefile
1050 libs/gst/helpers/Makefile
1051 libs/gst/net/Makefile
1052 plugins/Makefile
1053 plugins/elements/Makefile
1054 plugins/tracers/Makefile
1055 po/Makefile.in
1056 tests/Makefile
1057 tests/benchmarks/Makefile
1058 tests/check/Makefile
1059 tests/misc/Makefile
1060 tests/examples/Makefile
1061 tests/examples/adapter/Makefile
1062 tests/examples/controller/Makefile
1063 tests/examples/stepping/Makefile
1064 tests/examples/helloworld/Makefile
1065 tests/examples/memory/Makefile
1066 tests/examples/netclock/Makefile
1067 tests/examples/ptp/Makefile
1068 tests/examples/streamiddemux/Makefile
1069 tests/examples/streams/Makefile
1070 tools/Makefile
1071 common/Makefile
1072 common/m4/Makefile
1073 docs/Makefile
1074 docs/gst/Makefile
1075 docs/gst/gstreamer.types
1076 docs/libs/Makefile
1077 docs/plugins/Makefile
1078 docs/version.entities
1079 m4/Makefile
1080 pkgconfig/Makefile
1081 stamp.h
1082 pkgconfig/gstreamer.pc
1083 pkgconfig/gstreamer-uninstalled.pc
1084 pkgconfig/gstreamer-base.pc
1085 pkgconfig/gstreamer-base-uninstalled.pc
1086 pkgconfig/gstreamer-check.pc
1087 pkgconfig/gstreamer-check-uninstalled.pc
1088 pkgconfig/gstreamer-controller.pc
1089 pkgconfig/gstreamer-controller-uninstalled.pc
1090 pkgconfig/gstreamer-net.pc
1091 pkgconfig/gstreamer-net-uninstalled.pc
1092 )
1093
1094 AC_OUTPUT
1095
1096 dnl negate for output
1097 if test "x${GST_DISABLE_GST_DEBUG}" = "xno"; then enable_gst_debug="yes"; fi
1098 if test "x${GST_DISABLE_GST_TRACER_HOOKS}" = "xno"; then enable_gst_tracer_hooks="yes"; fi
1099 if test "x${GST_DISABLE_PARSE}" = "xno"; then enable_parse="yes"; fi
1100 if test "x${GST_DISABLE_OPTION_PARSING}" = "xno"; then enable_option_parsing="yes"; fi
1101 if test "x${GST_DISABLE_PLUGIN}" = "xno"; then enable_plugin="yes"; fi
1102 if test "x${GST_DISABLE_REGISTRY}" = "xno"; then enable_registry="yes"; fi
1103
1104 echo "
1105
1106 Configuration
1107         Version                    : ${VERSION}
1108         Source code location       : ${srcdir}
1109         Prefix                     : ${prefix}
1110         Compiler                   : ${CC}
1111         Package name               : ${GST_PACKAGE_NAME}
1112         Package origin             : ${GST_PACKAGE_ORIGIN}
1113
1114         API Documentation          : ${enable_gtk_doc}
1115
1116         Debug logging              : ${enable_gst_debug}
1117         Tracing subsystem hooks    : ${enable_gst_tracer_hooks}
1118         Command-line parser        : ${enable_parse}
1119         Option parsing in gst_init : ${enable_option_parsing}
1120         Plugin registry            : ${enable_registry}
1121         Plugin support             : ${enable_plugin}
1122         Static plugins             : ${enable_static_plugins}
1123         Unit testing support       : ${BUILD_CHECK}
1124         PTP clock support          : ${HAVE_PTP}
1125         libunwind support          : ${HAVE_UNWIND}
1126         libdw support              : ${HAVE_DW}
1127
1128         Debug                      : ${USE_DEBUG}
1129         Profiling                  : ${USE_PROFILING}
1130
1131         Building benchmarks        : ${BUILD_BENCHMARKS}
1132         Building examples          : ${BUILD_EXAMPLES}
1133         Building test apps         : ${BUILD_TESTS}
1134         Building tests that fail   : ${BUILD_FAILING_TESTS}
1135         Building tools             : ${BUILD_TOOLS}
1136 "