configure.ac

   1 AC_PREREQ([2.68])
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, git and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for git/prerelease
   8 AC_INIT([GStreamer Base Plug-ins],[1.1.0.1],[http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer],[gst-plugins-base])
   9
  10 AG_GST_INIT
  11
  12 dnl initialize automake
  13 AM_INIT_AUTOMAKE([-Wno-portability 1.11 no-dist-gzip dist-xz tar-ustar])
  14
  15 dnl define PACKAGE_VERSION_* variables
  16 AS_VERSION
  17
  18 dnl check if this is a release version
  19 AS_NANO(GST_GIT="no", GST_GIT="yes")
  20
  21 dnl can autoconf find the source ?
  22 AC_CONFIG_SRCDIR([gst/audiotestsrc/gstaudiotestsrc.c])
  23
  24 dnl define the output header for config
  25 AC_CONFIG_HEADERS([config.h])
  26
  27 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  28 AM_MAINTAINER_MODE([enable])
  29
  30 dnl sets host_* variables
  31 AC_CANONICAL_HOST
  32
  33 dnl use pretty build output with automake >= 1.11
  34 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],
  35   [AM_DEFAULT_VERBOSITY=1
  36    AC_SUBST(AM_DEFAULT_VERBOSITY)])
  37
  38 dnl our libraries and install dirs use GST_API_VERSION in the filename
  39 dnl to allow side-by-side installation of different API versions
  40 GST_API_VERSION=1.0
  41 AC_SUBST(GST_API_VERSION)
  42 AC_DEFINE_UNQUOTED(GST_API_VERSION, "$GST_API_VERSION",
  43   [GStreamer API Version])
  44
  45 dnl CURRENT, REVISION, AGE
  46 dnl - library source changed -> increment REVISION
  47 dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
  48 dnl - interfaces added -> increment AGE
  49 dnl - interfaces removed -> AGE = 0
  50 dnl
  51 dnl Keep CURRENT as MINOR * 100 + MICRO
  52 dnl Ex : 1.0.0 => 0
  53 dnl      1.0.3 => 3
  54 dnl      1.1.0 => 100
  55 dnl      1.2.5 => 205
  56 dnl      1.10.9 (who knows) => 1009
  57 dnl
  58 dnl sets GST_LT_LDFLAGS
  59 AS_LIBTOOL(GST, 100, 0, 100)
  60
  61 dnl *** required versions of GStreamer stuff ***
  62 GST_REQ=1.1.0
  63
  64 dnl *** autotools stuff ****
  65
  66 dnl allow for different autotools
  67 AS_AUTOTOOLS_ALTERNATE
  68
  69 dnl Add parameters for aclocal
  70 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  71
  72 dnl set up gettext
  73 dnl the version check needs to stay here because autopoint greps for it
  74 AM_GNU_GETTEXT_VERSION([0.17])
  75 AM_GNU_GETTEXT([external])
  76 AG_GST_GETTEXT([gst-plugins-base-$GST_API_VERSION])
  77
  78 dnl *** check for arguments to configure ***
  79
  80 AG_GST_ARG_DISABLE_FATAL_WARNINGS
  81
  82 AG_GST_ARG_DEBUG
  83 AG_GST_ARG_PROFILING
  84 AG_GST_ARG_VALGRIND
  85 AG_GST_ARG_GCOV
  86
  87 AG_GST_ARG_EXAMPLES
  88
  89 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  90 AG_GST_ARG_WITH_PACKAGE_NAME
  91 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  92
  93 AG_GST_PKG_CONFIG_PATH
  94
  95 dnl let distro override plugin install helper path
  96 AC_ARG_WITH(install-plugins-helper,
  97   AS_HELP_STRING([--with-install-plugins-helper],[specify path of helper script to call to install plugins]),
  98   [
  99     case "${withval}" in
 100       yes) AC_MSG_ERROR(bad value ${withval} for --with-install-plugins-helper) ;;
 101       no)  AC_MSG_ERROR(bad value ${withval} for --with-install-plugins-helper) ;;
 102       *)   GST_INSTALL_PLUGINS_HELPER="${withval}" ;;
 103     esac
 104   ],
 105   [
 106     dnl Default value
 107     AS_AC_EXPAND(GST_INSTALL_PLUGINS_HELPER,${libexecdir}/gst-install-plugins-helper)
 108   ]
 109 )
 110 AC_MSG_NOTICE(Using $GST_INSTALL_PLUGINS_HELPER as plugin install helper)
 111 AC_DEFINE_UNQUOTED(GST_INSTALL_PLUGINS_HELPER, "$GST_INSTALL_PLUGINS_HELPER",
 112     [plugin install helper script])
 113 AC_SUBST(GST_INSTALL_PLUGINS_HELPER)
 114
 115 AG_GST_ARG_WITH_PLUGINS
 116
 117 AG_GST_ARG_ENABLE_EXTERNAL
 118
 119 AG_GST_ARG_ENABLE_EXPERIMENTAL
 120
 121 dnl *** checks for platform ***
 122 AG_GST_PLATFORM
 123
 124 dnl * hardware/architecture *
 125
 126 dnl common/m4/gst-arch.m4
 127 dnl check CPU type
 128 AG_GST_ARCH
 129
 130 dnl check for large file support
 131 dnl affected plugins must include config.h
 132 AC_SYS_LARGEFILE
 133
 134 dnl *** checks for programs ***
 135
 136 dnl find a compiler
 137 AC_PROG_CC
 138 AC_PROG_CC_STDC
 139
 140 dnl check if the compiler supports '-c' and '-o' options
 141 AM_PROG_CC_C_O
 142
 143 dnl determine if c++ is available on this system
 144 AC_PROG_CXX
 145 dnl CXX may be set to some default even if no c++ compiler is available
 146 dnl (thanks autotools!), so just try to compile some c++ code to make sure
 147 AC_LANG_PUSH([C++])
 148 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[ class Foo { int bar; };]], [[]])],[working_cxx=yes],[working_cxx=no])
 149 AC_LANG_POP([C++])
 150 AC_MSG_NOTICE([working c++ compiler found: $working_cxx])
 151 AM_CONDITIONAL(HAVE_CXX, test "x$working_cxx" = "xyes")
 152
 153 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 154 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 155
 156 dnl check for gobject-introspection
 157 GOBJECT_INTROSPECTION_CHECK([1.31.1])
 158
 159 dnl check for documentation tools
 160 GTK_DOC_CHECK([1.12])
 161 AG_GST_PLUGIN_DOCS([1.12])
 162
 163 dnl *** checks for libraries ***
 164
 165 dnl libm, for sin() etc.
 166 LT_LIB_M
 167 AC_SUBST(LIBM)
 168
 169 dnl *** checks for header files ***
 170
 171 dnl check if we have ANSI C header files
 172 AC_HEADER_STDC
 173
 174 dnl check for GCC specific SSE headers
 175 dnl these are used by the speex resampler code
 176 AC_CHECK_HEADERS([xmmintrin.h emmintrin.h])
 177
 178 ac_cppflags_save="$CPPFLAGS"
 179 CPPFLAGS="`$PKG_CONFIG --cflags libxml-2.0`"
 180 AC_COMPILE_IFELSE([
 181   AC_LANG_PROGRAM([[
 182 #include <libxml/HTMLparser.h>
 183 ]],[[
 184 #ifndef LIBXML_HTML_ENABLED
 185 #error libxml2 has no HTML support
 186 #endif /* LIBXML_HTML_ENABLED */
 187 ]])], [
 188   HAVE_LIBXML_HTML="yes"
 189 ], [
 190   HAVE_LIBXML_HTML="no"
 191 ])
 192 CPPFLAGS="$ac_cppflags_save"
 193 AM_CONDITIONAL(HAVE_LIBXML_HTML, test "x$HAVE_LIBXML_HTML" = "xyes")
 194
 195 dnl used in gst/tcp
 196 AC_CHECK_HEADERS([sys/socket.h],
 197   [HAVE_SYS_SOCKET_H="yes"], [HAVE_SYS_SOCKET_H="no"], [AC_INCLUDES_DEFAULT])
 198 AM_CONDITIONAL(HAVE_SYS_SOCKET_H, test "x$HAVE_SYS_SOCKET_H" = "xyes")
 199
 200 dnl used in gst-libs/gst/pbutils and associated unit test
 201 AC_CHECK_HEADERS([process.h sys/types.h sys/wait.h sys/stat.h], [], [], [AC_INCLUDES_DEFAULT])
 202
 203 dnl checks for ARM NEON support
 204 dnl this instruction set is used by the speex resampler code
 205 AC_MSG_CHECKING(for ARM NEON support in current arch/CFLAGS)
 206 AC_LINK_IFELSE([
 207 AC_LANG_PROGRAM([[
 208   #include <arm_neon.h>
 209   int32x4_t testfunc(int16_t *a, int16_t *b) {
 210       return vmull_s16(vld1_s16(a), vld1_s16(b));
 211   }
 212 ]])],
 213 [
 214   AC_DEFINE(HAVE_ARM_NEON,[],[ARM NEON support is enabled])
 215   AC_MSG_RESULT(yes)
 216 ],
 217 [
 218   AC_MSG_RESULT(no)
 219 ])
 220
 221 dnl also, Windows does not have long long
 222 AX_CREATE_STDINT_H
 223
 224 dnl *** checks for functions ***
 225 AC_CHECK_FUNCS([localtime_r gmtime_r])
 226
 227 dnl *** checks for math functions ***
 228 LIBS_SAVE=$LIBS
 229 LIBS="$LIBS $LIBM"
 230 AC_CHECK_FUNCS(log2)
 231 LIBS=$LIBS_SAVE
 232
 233 dnl *** checks for types/defines ***
 234
 235 dnl *** checks for structures ***
 236
 237 dnl *** checks for compiler characteristics ***
 238
 239 dnl *** checks for library functions ***
 240
 241 dnl check for fseeko()
 242 AC_FUNC_FSEEKO
 243
 244 dnl Check for fast float to int casting as defined in C99
 245 dnl used to be used in gst-libs/gst/floatcast/floatcast.h (FIXME: still needed?)
 246 save_libs=$LIBS
 247 LIBS="$LIBS $LIBM"
 248 AC_C99_FUNC_LRINT
 249 AC_C99_FUNC_LRINTF
 250 LIBS=$save_libs
 251
 252 dnl Check for a way to display the function name in debug output
 253 AG_GST_CHECK_FUNCTION
 254
 255 dnl *** checks for dependency libraries ***
 256
 257 dnl GLib
 258 GLIB_REQ=2.32
 259 AG_GST_GLIB_CHECK([$GLIB_REQ])
 260
 261 ORC_CHECK([0.4.16])
 262
 263 dnl checks for gstreamer
 264 dnl uninstalled is selected preferentially -- see pkg-config(1)
 265 AG_GST_CHECK_GST($GST_API_VERSION, [$GST_REQ], yes)
 266 AG_GST_CHECK_GST_BASE($GST_API_VERSION, [$GST_REQ], yes)
 267 AG_GST_CHECK_GST_CONTROLLER($GST_API_VERSION, [$GST_REQ], yes)
 268 AG_GST_CHECK_GST_CHECK($GST_API_VERSION, [$GST_REQ], no)
 269 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 270
 271 dnl Check for documentation xrefs
 272 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 273 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_API_VERSION`"
 274 AC_SUBST(GLIB_PREFIX)
 275 AC_SUBST(GST_PREFIX)
 276
 277 dnl GTK is optional and only used in examples
 278 HAVE_GTK=no
 279 HAVE_GTK_X11=no
 280 GTK_REQ=3.0.0
 281 if test "x$BUILD_EXAMPLES" = "xyes"; then
 282   PKG_CHECK_MODULES(GTK, gtk+-3.0 >= $GTK_REQ, HAVE_GTK=yes, HAVE_GTK=no)
 283   dnl some examples need gtk+-x11
 284   PKG_CHECK_MODULES(GTK_X11, gtk+-x11-3.0 >= $GTK_REQ, HAVE_GTK_X11=yes, HAVE_GTK_X11=no)
 285   PKG_CHECK_MODULES(GTK_QUARTZ, gtk+-quartz-3.0 >= $GTK_REQ, HAVE_GTK_QUARTZ=yes, HAVE_GTK_QUARTZ=no)
 286   AC_SUBST(GTK_LIBS)
 287   AC_SUBST(GTK_CFLAGS)
 288 fi
 289 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 290 AM_CONDITIONAL(HAVE_GTK_X11, test "x$HAVE_GTK_X11" = "xyes")
 291 AM_CONDITIONAL(HAVE_GTK_QUARTZ, test "x$HAVE_GTK_QUARTZ" = "xyes")
 292
 293 dnl QT is optional and only used in examples
 294 PKG_CHECK_MODULES(QT, QtGui >= 4.6, [
 295   HAVE_QT_GV=yes
 296   HAVE_QT=yes
 297 ], [
 298   HAVE_QT_GV=no
 299   PKG_CHECK_MODULES(QT, QtGui >= 4.0, HAVE_QT=yes, HAVE_QT=no)
 300 ])
 301 if test "x$HAVE_QT" = "xyes"; then
 302   AC_MSG_CHECKING([Qt moc])
 303   QT4_MOC=`$PKG_CONFIG --variable=moc_location QtGui`
 304   AC_MSG_RESULT($QT4_MOC)
 305   AC_SUBST(QT4_MOC)
 306 fi
 307 AM_CONDITIONAL(HAVE_QT, test "x$HAVE_QT" = "xyes")
 308 AM_CONDITIONAL(HAVE_QT_GV, test "x$HAVE_QT_GV" = "xyes")
 309
 310 dnl chck for linux headers needed by the joystick seek example
 311 AC_COMPILE_IFELSE(
 312 [
 313   AC_LANG_PROGRAM([
 314     #include <linux/input.h>
 315     #include <linux/joystick.h>
 316   ],[
 317     struct js_event js;
 318     js.type = JS_EVENT_AXIS;
 319   ])
 320 ], [
 321   HAVE_LINUX_JOYSTICK_HEADERS="yes"
 322 ], [
 323   HAVE_LINUX_JOYSTICK_HEADERS="no"
 324 ])
 325 AM_CONDITIONAL(HAVE_LINUX_JOYSTICK_HEADERS, test "x$HAVE_LINUX_JOYSTICK_HEADERS" = "xyes")
 326
 327 dnl Check for -Bsymbolic-functions linker flag used to avoid
 328 dnl intra-library PLT jumps, if available.
 329 AC_ARG_ENABLE(Bsymbolic,
 330               [AS_HELP_STRING([--disable-Bsymbolic],[avoid linking with -Bsymbolic])],,
 331               [SAVED_LDFLAGS="${LDFLAGS}"
 332                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
 333                LDFLAGS=-Wl,-Bsymbolic-functions
 334                AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [[int main (void) { return 0; }]])],[
 335                            AC_MSG_RESULT(yes)
 336                            enable_Bsymbolic=yes],[
 337                            AC_MSG_RESULT(no)
 338                            enable_Bsymbolic=no])
 339                LDFLAGS="${SAVED_LDFLAGS}"])
 340
 341
 342 dnl *** set variables based on configure arguments ***
 343
 344 dnl set license and copyright notice
 345 GST_LICENSE="LGPL"
 346 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 347 AC_SUBST(GST_LICENSE)
 348
 349 dnl set location of plugin directory
 350 AG_GST_SET_PLUGINDIR
 351
 352 dnl set release date/time
 353 AG_GST_SET_PACKAGE_RELEASE_DATETIME_WITH_NANO([$PACKAGE_VERSION_NANO],
 354   ["${srcdir}/gst-plugins-base.doap"],
 355   [$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_MICRO])
 356
 357 # set by AG_GST_PARSE_SUBSYSTEM_DISABLES above
 358 dnl make sure it doesn't complain about unused variables if debugging is disabled
 359 NO_WARNINGS=""
 360 AG_GST_CHECK_GST_DEBUG_DISABLED([NO_WARNINGS="-Wno-unused"], [NO_WARNINGS=""])
 361
 362 dnl define an ERROR_CFLAGS Makefile variable
 363 dnl -Wformat-nonliteral - see ext/pango/gstclockoverlay.c and http://gcc.gnu.org/bugzilla/show_bug.cgi?id=39438
 364 AG_GST_SET_ERROR_CFLAGS($FATAL_WARNINGS, [
 365     -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls -Wundef
 366     -Wwrite-strings -Wformat-nonliteral -Wformat-security
 367     -Winit-self -Wmissing-include-dirs -Waddress -Waggregate-return
 368     -Wno-multichar -Wnested-externs $NO_WARNINGS])
 369
 370 dnl define an ERROR_CXXFLAGS Makefile variable
 371 AG_GST_SET_ERROR_CXXFLAGS($FATAL_WARNINGS, [
 372     -Wmissing-declarations -Wredundant-decls -Wundef
 373     -Wwrite-strings -Wformat-nonliteral -Wformat-security
 374     -Winit-self -Wmissing-include-dirs -Waddress -Waggregate-return
 375     -Wno-multichar $NO_WARNINGS])
 376
 377 dnl define correct level for debugging messages
 378 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 379
 380 dnl used in examples
 381 AG_GST_DEFAULT_ELEMENTS
 382
 383 dnl needed for encoding-target
 384 GST_DATADIR="$GST_PREFIX/share"
 385 AC_DEFINE_UNQUOTED(GST_DATADIR, "$GST_DATADIR", [system wide data directory])
 386 AC_DEFINE_UNQUOTED(GST_API_VERSION, "$GST_API_VERSION", [major/minor version])
 387
 388 dnl behaviour of speex based audio resampler
 389 AC_MSG_CHECKING(which audio resample format to use for integer)
 390 AC_ARG_WITH([audioresample_format],
 391         AS_HELP_STRING([--with-audioresample-format],[Which implementation should be used for integer audio resampling, int/float/auto, (default is auto)]),
 392         [ac_cv_audioresample_format=$withval], [ac_cv_audioresample_format=auto])dnl
 393 AC_MSG_RESULT($ac_cv_audioresample_format)
 394 case $ac_cv_audioresample_format in
 395   int)
 396     AC_DEFINE(AUDIORESAMPLE_FORMAT_INT,1,[The int implementation should be used for integer audio resampling])
 397     AC_SUBST(AUDIORESAMPLE_FORMAT_INT)
 398   ;;
 399   float)
 400     AC_DEFINE(AUDIORESAMPLE_FORMAT_FLOAT,1,[The float implementation should be used for integer audio resampling])
 401     AC_SUBST(AUDIORESAMPLE_FORMAT_FLOAT)
 402   ;;
 403   auto)
 404     AC_DEFINE(AUDIORESAMPLE_FORMAT_AUTO,1,[The implementation that should be used for integer audio resampling witll be benchmarked at runtime])
 405     AC_SUBST(AUDIORESAMPLE_FORMAT_AUTO)
 406 esac
 407
 408 dnl Check for mmap (needed by allocators library)
 409 AC_MSG_CHECKING(if mmap is supported)
 410 AC_TRY_LINK(
 411   [#include <fcntl.h>
 412    #include <unistd.h>
 413    #include <sys/mman.h>],
 414   [char * p = (char *)mmap(NULL, 10, PROT_READ, MAP_SHARED, -1, 2);
 415    munmap(p,10);],
 416   [AC_MSG_RESULT(yes)
 417    AC_DEFINE(HAVE_MMAP, 1, [Defined if mmap is supported])],
 418   [AC_MSG_RESULT(no)] )
 419
 420 dnl *** plug-ins to include ***
 421
 422 dnl these are all the gst plug-ins, compilable without additional libs
 423 AG_GST_CHECK_PLUGIN(adder)
 424 AG_GST_CHECK_PLUGIN(app)
 425 AG_GST_CHECK_PLUGIN(audioconvert)
 426 AG_GST_CHECK_PLUGIN(audiorate)
 427 AG_GST_CHECK_PLUGIN(audiotestsrc)
 428 AG_GST_CHECK_PLUGIN(encoding)
 429 AG_GST_CHECK_PLUGIN(videoconvert)
 430 AG_GST_CHECK_PLUGIN(gio)
 431 AG_GST_CHECK_PLUGIN(playback)
 432 AG_GST_CHECK_PLUGIN(audioresample)
 433 AG_GST_CHECK_PLUGIN(subparse)
 434 AG_GST_CHECK_PLUGIN(tcp)
 435 AG_GST_CHECK_PLUGIN(typefind)
 436 AG_GST_CHECK_PLUGIN(videotestsrc)
 437 AG_GST_CHECK_PLUGIN(videorate)
 438 AG_GST_CHECK_PLUGIN(videoscale)
 439 AG_GST_CHECK_PLUGIN(volume)
 440
 441 dnl FIXME 0.11: check for libxml, split subparse and move libxml parts to ext/
 442 AM_CONDITIONAL(USE_XML, false)
 443 AC_DEFINE([GST_DISABLE_XML], [1], [set to disable libxml2-dependent code in subparse])
 444
 445 dnl disable plug-ins that require libxml2's HTML support if it is not available
 446 if test "x$HAVE_LIBXML_HTML" != "xyes"; then
 447   AG_GST_DISABLE_PLUGIN(subparse)
 448 fi
 449
 450 dnl iso-codes is optional, used by libgsttag
 451 AC_ARG_ENABLE(iso-codes,
 452 AS_HELP_STRING([--enable-iso-codes],[use iso-codes if installed]),
 453 [case "${enableval}" in
 454   yes) enable_iso_codes=yes ;;
 455   no)  enable_iso_codes=no ;;
 456   *) AC_MSG_ERROR(bad value ${enableval} for --enable-iso-codes) ;;
 457 esac
 458 ],
 459 [enable_iso_codes=yes]) dnl Default value
 460
 461 AC_MSG_CHECKING([whether to use iso-codes if they are available])
 462 if test "x$enable_iso_codes" = "xyes"; then
 463   AC_MSG_RESULT([yes])
 464   have_iso_codes=no
 465   AC_MSG_CHECKING([whether iso-codes are available on this system])
 466   if $PKG_CONFIG iso-codes; then
 467     AC_MSG_RESULT([yes])
 468     AC_MSG_CHECKING([whether iso-codes has iso-639 domain])
 469     if $PKG_CONFIG --variable=domains iso-codes | $GREP -q 639 ; then
 470       AC_MSG_RESULT([yes])
 471       AC_MSG_CHECKING([for iso-codes prefix])
 472       ISO_CODES_PREFIX=`$PKG_CONFIG --variable=prefix iso-codes`
 473       if test -d "$ISO_CODES_PREFIX"; then
 474         AC_MSG_RESULT([yes])
 475         AC_MSG_CHECKING([ISO_CODES_PREFIX])
 476         AC_MSG_RESULT([$ISO_CODES_PREFIX])
 477         ISO_639_DOMAIN="iso_639"
 478         AC_MSG_CHECKING([ISO_639_DOMAIN])
 479         AC_MSG_RESULT([$ISO_639_DOMAIN])
 480         have_iso_codes=yes
 481         AC_DEFINE([HAVE_ISO_CODES], [1], [make use of iso-codes for ISO-639])
 482         AC_DEFINE_UNQUOTED([ISO_CODES_PREFIX], ["$ISO_CODES_PREFIX"], [prefix])
 483         ISO_CODES_VERSION=`$PKG_CONFIG --modversion iso-codes`
 484         AC_DEFINE_UNQUOTED([ISO_CODES_VERSION], ["$ISO_CODES_VERSION"], [ ])
 485       else
 486         AC_MSG_RESULT([no])
 487       fi
 488     else
 489       AC_MSG_RESULT([no])
 490     fi
 491   else
 492     AC_MSG_RESULT([no])
 493   fi
 494   AM_CONDITIONAL(USE_ISO_CODES, test "x$have_iso_codes" = "xyes")
 495 else
 496   AC_MSG_RESULT([no (disabled via --disable-iso-codes)])
 497   AM_CONDITIONAL(USE_ISO_CODES, false)
 498 fi
 499
 500 dnl *** zlib is optionally used by id3 tag parsing in libgsttag ***
 501 translit(dnm, m, l) AM_CONDITIONAL(USE_ZLIB, true)
 502 AG_GST_CHECK_FEATURE(ZLIB, [zlib support for ID3 parsing in libgsttag],, [
 503   PKG_CHECK_MODULES(ZLIB, [ zlib ], [
 504       HAVE_ZLIB="yes"
 505     ], [
 506       AG_GST_CHECK_LIBHEADER(ZLIB, z, uncompress,, zlib.h, [
 507         HAVE_ZLIB="yes"
 508         ZLIB_LIBS="-lz"
 509         AC_SUBST(ZLIB_LIBS)
 510       ])
 511     ])
 512 ])
 513
 514 dnl *** sys plug-ins ***
 515
 516 echo
 517 AC_MSG_NOTICE([Checking libraries for plugins in sys/])
 518 echo
 519
 520 dnl *** X11 ***
 521 translit(dnm, m, l) AM_CONDITIONAL(USE_X, true)
 522 AG_GST_CHECK_FEATURE(X, [X libraries and plugins],
 523                   [ximagesink], [
 524   AC_PATH_XTRA
 525   ac_cflags_save="$CFLAGS"
 526   ac_cppflags_save="$CPPFLAGS"
 527   CFLAGS="$CFLAGS $X_CFLAGS"
 528   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 529
 530   dnl now try to find the HEADER
 531   AC_CHECK_HEADER([X11/Xlib.h], [HAVE_X="yes"], [HAVE_X="no"], [AC_INCLUDES_DEFAULT])
 532
 533   if test "x$HAVE_X" = "xno"
 534   then
 535     AC_MSG_NOTICE([cannot find X11 development files])
 536   else
 537     dnl this is much more than we want
 538     X_LIBS="$X_LIBS $X_PRE_LIBS $X_EXTRA_LIBS"
 539     dnl AC_PATH_XTRA only defines the path needed to find the X libs,
 540     dnl it does not add the libs; therefore we add them here
 541     X_LIBS="$X_LIBS -lX11"
 542     AC_SUBST(X_CFLAGS)
 543     AC_SUBST(X_LIBS)
 544   fi
 545   AC_SUBST(HAVE_X)
 546   CFLAGS="$ac_cflags_save"
 547   CPPFLAGS="$ac_cppflags_save"
 548 ])
 549
 550 dnl Check for Xv extension
 551 translit(dnm, m, l) AM_CONDITIONAL(USE_XVIDEO, true)
 552 AG_GST_CHECK_FEATURE(XVIDEO, [X11 XVideo extensions],
 553                   [xvimagesink], [
 554   AG_GST_CHECK_XV
 555 ])
 556
 557 dnl check for X Shm
 558 translit(dnm, m, l) AM_CONDITIONAL(USE_XSHM, true)
 559 AG_GST_CHECK_FEATURE(XSHM, [X Shared Memory extension], , [
 560   if test x$HAVE_X = xyes; then
 561     AC_CHECK_LIB(Xext, XShmAttach,
 562                  HAVE_XSHM="yes", HAVE_XSHM="no",
 563                  $X_LIBS)
 564     if test "x$HAVE_XSHM" = "xyes"; then
 565       XSHM_LIBS="-lXext"
 566     else
 567       dnl On AIX, it is in XextSam instead, but we still need -lXext
 568       AC_CHECK_LIB(XextSam, XShmAttach,
 569                    HAVE_XSHM="yes", HAVE_XSHM="no",
 570                    $X_LIBS)
 571       if test "x$HAVE_XSHM" = "xyes"; then
 572         XSHM_LIBS="-lXext -lXextSam"
 573       fi
 574     fi
 575   fi
 576 ], , [
 577   AC_SUBST(HAVE_XSHM)
 578   AC_SUBST(XSHM_LIBS)
 579 ])
 580
 581 dnl *** ext plug-ins ***
 582 dnl keep this list sorted alphabetically !
 583
 584 if test "x$BUILD_EXTERNAL" = "xyes"; then
 585
 586 echo
 587 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 588 echo
 589
 590 dnl *** alsa ***
 591 translit(dnm, m, l) AM_CONDITIONAL(USE_ALSA, true)
 592 AG_GST_CHECK_FEATURE(ALSA, [ALSA], alsa, [
 593   PKG_CHECK_MODULES(ALSA, alsa >= 0.9.1, [
 594     HAVE_ALSA="yes"
 595     AC_SUBST(ALSA_CFLAGS)
 596     AC_SUBST(ALSA_LIBS)
 597   ], [
 598     AM_PATH_ALSA(0.9.1, HAVE_ALSA="yes", HAVE_ALSA="no")
 599   ])
 600 ])
 601
 602 dnl *** CDParanoia ***
 603 dnl Note: upstream has a pkg-config file only in post-10.2 SVN so far
 604 translit(dnm, m, l) AM_CONDITIONAL(USE_CDPARANOIA, true)
 605 AG_GST_CHECK_FEATURE(CDPARANOIA, [CDParanoia], cdparanoia, [
 606   PKG_CHECK_MODULES(CDPARANOIA, cdparanoia-3 >= 10.2, [
 607     HAVE_CDPARANOIA="yes"
 608   ], [
 609     AG_GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 610                         cdda_open, -lm,
 611                         cdda_interface.h,
 612                         CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 613                         HEADER_DIR="no"
 614                         FOUND_CDPARANOIA="yes")
 615     if test "x$FOUND_CDPARANOIA" != "xyes";
 616     then
 617       AG_GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 618                           cdda_open, -lm,
 619                           cdda/cdda_interface.h,
 620                           CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 621                           HEADER_DIR="yes"
 622                           FOUND_CDPARANOIA="yes")
 623     fi
 624     if test "x$HEADER_DIR" = "xyes";
 625     then
 626       AC_DEFINE_UNQUOTED(CDPARANOIA_HEADERS_IN_DIR, ,
 627                          defined if cdda headers are in a cdda/ directory)
 628     fi
 629     if test "x$FOUND_CDPARANOIA" = "xyes";
 630     then
 631       AC_CHECK_LIB(cdda_paranoia,
 632                    paranoia_cachemodel_size,
 633                    : ,
 634                    HAVE_CDPARANOIA=no,
 635                  [-lcdda_interface])
 636     fi
 637
 638     AC_SUBST(CDPARANOIA_LIBS)
 639   ])
 640 ])
 641 dnl FIXME : add second check somehow if that is necessary
 642 dnl AC_CHECK_LIB(cdda_paranoia, paranoia_init, : , HAVE_CDPARANOIA=no, -lcdda_interface )
 643 dnl AC_CHECK_HEADER(cdda_paranoia.h, :, HAVE_CDPARANOIA=no)
 644
 645 dnl *** ivorbis ***
 646 dnl AM_PATH_IVORBIS only takes two options
 647 translit(dnm, m, l) AM_CONDITIONAL(USE_IVORBIS, true)
 648 AG_GST_CHECK_FEATURE(IVORBIS, [integer vorbis plug-in], ivorbisdec, [
 649   AG_GST_PKG_CHECK_MODULES(IVORBIS, vorbisidec)
 650   if test $HAVE_IVORBIS = no
 651   then
 652     IVORBIS_LIBS=
 653     IVORBIS_CFLAGS=
 654     AC_CHECK_LIB(vorbisidec, vorbis_block_init,
 655       [IVORBIS_LIBS=-lvorbisidec
 656       HAVE_IVORBIS=yes
 657       case $host in
 658       arm-*-*)
 659         IVORBIS_CFLAGS="-D_ARM_ASSEM_ $IVORBIS_CFLAGS"
 660       esac
 661       ],
 662       HAVE_IVORBIS=no)
 663     AC_SUBST(IVORBIS_LIBS)
 664     AC_SUBST(IVORBIS_CFLAGS)
 665   else
 666     AC_CHECK_LIB(vorbisidec, vorbis_dsp_pcmout,
 667       AC_DEFINE([USE_TREMOLO],1, "Define if building for android"),
 668       USE_TREMOLO=no)
 669   fi
 670 ])
 671
 672 dnl *** libvisual ***
 673 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBVISUAL, true)
 674 AG_GST_CHECK_FEATURE(LIBVISUAL, [libvisual visualization library], libvisual, [
 675   AG_GST_PKG_CHECK_MODULES(LIBVISUAL, libvisual-0.4 >= 0.4.0)
 676   if test $HAVE_LIBVISUAL = no
 677   then
 678     AG_GST_PKG_CHECK_MODULES(LIBVISUAL, libvisual = 0.2.0)
 679     if test x$HAVE_LIBVISUAL = xyes; then
 680       LIBVIS_PLUGINSDIR="`$PKG_CONFIG --variable=pluginsbasedir libvisual-0.2`"
 681     fi
 682   else
 683     if test x$HAVE_LIBVISUAL = xyes; then
 684       LIBVIS_PLUGINSDIR="`$PKG_CONFIG --variable=pluginsbasedir libvisual-0.4`"
 685     fi
 686   fi
 687   AC_MSG_NOTICE([libvisual pluginsdir: $LIBVIS_PLUGINSDIR])
 688   if test x$LIBVIS_PLUGINSDIR != x; then
 689     AC_DEFINE_UNQUOTED(LIBVISUAL_PLUGINSBASEDIR,
 690         "$LIBVIS_PLUGINSDIR",
 691         [directory in which the detected libvisual's plugins are located])
 692   fi
 693 ])
 694
 695 dnl *** ogg ***
 696 translit(dnm, m, l) AM_CONDITIONAL(USE_OGG, true)
 697 AG_GST_CHECK_FEATURE(OGG, [Xiph Ogg library], ogg, [
 698   AG_GST_PKG_CHECK_MODULES(OGG, ogg >= 1.0)
 699   if test $HAVE_OGG = no
 700   then
 701     XIPH_PATH_OGG(HAVE_OGG="yes", HAVE_OGG="no")
 702     AS_SCRUB_INCLUDE(OGG_CFLAGS)
 703   fi
 704 ])
 705
 706 dnl *** pango ***
 707 translit(dnm, m, l) AM_CONDITIONAL(USE_PANGO, true)
 708 AG_GST_CHECK_FEATURE(PANGO, [Pango font rendering], pango, [
 709   AG_GST_PKG_CHECK_MODULES(PANGO, pango >= 1.22.0  pangocairo >= 1.22.0)
 710 ])
 711
 712 dnl *** theora ***
 713 translit(dnm, m, l) AM_CONDITIONAL(USE_THEORA, true)
 714 AG_GST_CHECK_FEATURE(THEORA, [Xiph Theora video codec], theora, [
 715   AG_GST_PKG_CHECK_MODULES(THEORA, theoradec >= 1.1 theoraenc >= 1.1)
 716 ])
 717
 718 dnl *** vorbis ***
 719 dnl AM_PATH_VORBIS only takes two options
 720 translit(dnm, m, l) AM_CONDITIONAL(USE_VORBIS, true)
 721 AG_GST_CHECK_FEATURE(VORBIS, [Xiph Vorbis audio codec], vorbis, [
 722   AG_GST_PKG_CHECK_MODULES(VORBIS, vorbis >= 1.0 vorbisenc >= 1.0)
 723   if test $HAVE_VORBIS = no
 724   then
 725     XIPH_PATH_VORBIS(HAVE_VORBIS="yes", HAVE_VORBIS="no")
 726     AS_SCRUB_INCLUDE(VORBIS_CFLAGS)
 727   fi
 728 ])
 729
 730 if test "x$HAVE_VORBIS" = "xyes"; then
 731   ac_cflags_save="$CFLAGS"
 732   AC_COMPILE_IFELSE([
 733     AC_LANG_PROGRAM([[
 734 #include <vorbis/codec.h>
 735                      ]],[[
 736 vorbis_dsp_state *v;
 737
 738 vorbis_synthesis_restart (v);
 739                      ]])], HAVE_VSR=yes, HAVE_VSR=no)
 740   if test "x$HAVE_VSR" = "xyes"; then
 741     AC_DEFINE_UNQUOTED(HAVE_VORBIS_SYNTHESIS_RESTART, 1,
 742                        [defined if vorbis_synthesis_restart is present])
 743   fi
 744   CFLAGS="$ac_cflags_save"
 745 fi
 746
 747 else
 748
 749 dnl not building plugins with external dependencies,
 750 dnl but we still need to set the conditionals
 751 AM_CONDITIONAL(USE_ALSA, false)
 752 AM_CONDITIONAL(USE_CDPARANOIA, false)
 753 AM_CONDITIONAL(USE_IVORBIS, false)
 754 AM_CONDITIONAL(USE_LIBVISUAL, false)
 755 AM_CONDITIONAL(USE_OGG, false)
 756 AM_CONDITIONAL(USE_PANGO, false)
 757 AM_CONDITIONAL(USE_THEORA, false)
 758 AM_CONDITIONAL(USE_VORBIS, false)
 759
 760 fi dnl of EXT plugins
 761
 762 dnl seeking needs freetype, so check for it here
 763 PKG_CHECK_MODULES(FT2, freetype2 >= 2.0.9, HAVE_FT2="yes", [
 764   AC_CHECK_FT2(2.0.9, HAVE_FT2="yes", HAVE_FT2="no")
 765 ])
 766 dnl make the HAVE_FT2 variable available to automake and Makefile.am
 767 AM_CONDITIONAL(HAVE_FT2, test "x$HAVE_FT2" = "xyes")
 768 AC_SUBST(FT2_CFLAGS)
 769 AC_SUBST(FT2_LIBS)
 770
 771 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 772
 773 dnl Overview:
 774 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
 775 dnl GST_*:              flags shared by built objects to link against GStreamer
 776 dnl GST_PLUGINS_BASE_CFLAGS: to link internally against the plugins base libs
 777 dnl                          (compare to other modules) or for i18n
 778 dnl GST_ALL_LDFLAGS:    linker flags shared by all
 779 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 780 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 781 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 782
 783 dnl GST_OPTION_CFLAGS
 784 if test "x$USE_DEBUG" = xyes; then
 785    PROFILE_CFLAGS="-g"
 786 fi
 787 AC_SUBST(PROFILE_CFLAGS)
 788
 789 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
 790   dnl Define _only_ when compiling a git version (not pre-releases or releases)
 791   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 792 else
 793   DEPRECATED_CFLAGS=""
 794 fi
 795 AC_SUBST(DEPRECATED_CFLAGS)
 796
 797 dnl every flag in GST_OPTION_CFLAGS and GST_OPTION_CXXFLAGS can be overridden
 798 dnl at make time with e.g. make ERROR_CFLAGS=""
 799 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 800 GST_OPTION_CXXFLAGS="\$(WARNING_CXXFLAGS) \$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 801 AC_SUBST(GST_OPTION_CFLAGS)
 802 AC_SUBST(GST_OPTION_CXXFLAGS)
 803
 804 dnl our libraries need to be versioned correctly
 805 AC_SUBST(GST_LT_LDFLAGS)
 806
 807 dnl GST_PLUGINS_BASE_CFLAGS
 808 dnl prefer internal headers to already installed ones
 809 dnl also add builddir include for enumtypes and marshal
 810 GST_PLUGINS_BASE_CFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs"
 811 AC_SUBST(GST_PLUGINS_BASE_CFLAGS)
 812
 813 dnl FIXME: do we want to rename to GST_ALL_* ?
 814 dnl add GST_OPTION_CFLAGS, but overridable
 815 GST_CFLAGS="$GST_CFLAGS"
 816 GST_CXXFLAGS="$GLIB_CFLAGS $GST_CFLAGS \$(GLIB_EXTRA_CFLAGS) \$(GST_OPTION_CXXFLAGS)"
 817 GST_CFLAGS="$GLIB_CFLAGS $GST_CFLAGS \$(GLIB_EXTRA_CFLAGS) \$(GST_OPTION_CFLAGS)"
 818 AC_SUBST(GST_CFLAGS)
 819 AC_SUBST(GST_CXXFLAGS)
 820 dnl add GCOV libs because libtool strips -fprofile-arcs -ftest-coverage
 821 GST_LIBS="$GST_LIBS \$(GCOV_LIBS)"
 822 AC_SUBST(GST_LIBS)
 823
 824 dnl LDFLAGS really should only contain flags, not libs - they get added before
 825 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 826 GST_ALL_LDFLAGS="-no-undefined"
 827 if test "x${enable_Bsymbolic}" = "xyes"; then
 828   GST_ALL_LDFLAGS="$GST_ALL_LDFLAGS -Wl,-Bsymbolic-functions"
 829 fi
 830 AC_SUBST(GST_ALL_LDFLAGS)
 831
 832 dnl GST_LIB_LDFLAGS
 833 dnl linker flags shared by all libraries
 834 dnl LDFLAGS modifier defining exported symbols from built libraries
 835 dnl (export _gst_foo but not __gst_foo)
 836 GST_LIB_LDFLAGS="-export-symbols-regex ^_?\(gst_\|Gst\|GST_\).*"
 837 AC_SUBST(GST_LIB_LDFLAGS)
 838
 839 dnl this really should only contain flags, not libs - they get added before
 840 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 841 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc.*' $GST_ALL_LDFLAGS"
 842 AC_SUBST(GST_PLUGIN_LDFLAGS)
 843
 844 dnl *** output files ***
 845
 846 AC_CONFIG_FILES(
 847 Makefile
 848 gst-plugins-base.spec
 849 gst/Makefile
 850 gst/adder/Makefile
 851 gst/app/Makefile
 852 gst/audioconvert/Makefile
 853 gst/audiorate/Makefile
 854 gst/audiotestsrc/Makefile
 855 gst/encoding/Makefile
 856 gst/videoconvert/Makefile
 857 gst/gio/Makefile
 858 gst/playback/Makefile
 859 gst/audioresample/Makefile
 860 gst/subparse/Makefile
 861 gst/tcp/Makefile
 862 gst/typefind/Makefile
 863 gst/videotestsrc/Makefile
 864 gst/videorate/Makefile
 865 gst/videoscale/Makefile
 866 gst/volume/Makefile
 867 sys/Makefile
 868 sys/ximage/Makefile
 869 sys/xvimage/Makefile
 870 ext/Makefile
 871 ext/alsa/Makefile
 872 ext/cdparanoia/Makefile
 873 ext/libvisual/Makefile
 874 ext/ogg/Makefile
 875 ext/pango/Makefile
 876 ext/theora/Makefile
 877 ext/vorbis/Makefile
 878 gst-libs/Makefile
 879 gst-libs/gst/Makefile
 880 gst-libs/gst/allocators/Makefile
 881 gst-libs/gst/audio/Makefile
 882 gst-libs/gst/app/Makefile
 883 gst-libs/gst/fft/Makefile
 884 gst-libs/gst/riff/Makefile
 885 gst-libs/gst/rtp/Makefile
 886 gst-libs/gst/rtsp/Makefile
 887 gst-libs/gst/sdp/Makefile
 888 gst-libs/gst/tag/Makefile
 889 gst-libs/gst/pbutils/Makefile
 890 gst-libs/gst/pbutils/gstpluginsbaseversion.h
 891 gst-libs/gst/video/Makefile
 892 tools/Makefile
 893 pkgconfig/Makefile
 894 pkgconfig/gstreamer-allocators.pc
 895 pkgconfig/gstreamer-allocators-uninstalled.pc
 896 pkgconfig/gstreamer-audio.pc
 897 pkgconfig/gstreamer-audio-uninstalled.pc
 898 pkgconfig/gstreamer-app.pc
 899 pkgconfig/gstreamer-app-uninstalled.pc
 900 pkgconfig/gstreamer-fft.pc
 901 pkgconfig/gstreamer-fft-uninstalled.pc
 902 pkgconfig/gstreamer-pbutils.pc
 903 pkgconfig/gstreamer-pbutils-uninstalled.pc
 904 pkgconfig/gstreamer-riff.pc
 905 pkgconfig/gstreamer-riff-uninstalled.pc
 906 pkgconfig/gstreamer-rtp.pc
 907 pkgconfig/gstreamer-rtp-uninstalled.pc
 908 pkgconfig/gstreamer-rtsp.pc
 909 pkgconfig/gstreamer-rtsp-uninstalled.pc
 910 pkgconfig/gstreamer-sdp.pc
 911 pkgconfig/gstreamer-sdp-uninstalled.pc
 912 pkgconfig/gstreamer-tag.pc
 913 pkgconfig/gstreamer-tag-uninstalled.pc
 914 pkgconfig/gstreamer-video.pc
 915 pkgconfig/gstreamer-video-uninstalled.pc
 916 pkgconfig/gstreamer-plugins-base.pc
 917 pkgconfig/gstreamer-plugins-base-uninstalled.pc
 918 tests/Makefile
 919 tests/check/Makefile
 920 tests/examples/Makefile
 921 tests/examples/app/Makefile
 922 tests/examples/audio/Makefile
 923 tests/examples/dynamic/Makefile
 924 tests/examples/encoding/Makefile
 925 tests/examples/fft/Makefile
 926 tests/examples/gio/Makefile
 927 tests/examples/overlay/Makefile
 928 tests/examples/seek/Makefile
 929 tests/examples/snapshot/Makefile
 930 tests/examples/playback/Makefile
 931 tests/examples/playrec/Makefile
 932 tests/files/Makefile
 933 tests/icles/Makefile
 934 tests/icles/playback/Makefile
 935 docs/Makefile
 936 docs/design/Makefile
 937 docs/libs/Makefile
 938 docs/plugins/Makefile
 939 docs/version.entities
 940 po/Makefile.in
 941 common/Makefile
 942 common/m4/Makefile
 943 m4/Makefile
 944 )
 945
 946 dnl Create the config.h file for Visual Studio builds
 947 dnl Beware of spaces and /'s in some of the shell variable contents.
 948 sed \
 949     -e 's/.*config.h.in.*autoheader.*/\/* Autogenerated config.h created for win32 Visual Studio builds *\/\n\n\/* PREFIX -- specifically added for Windows for easier moving *\/\n#define PREFIX "C:\\\\gstreamer"/' \
 950     -e 's/.* GST_INSTALL_PLUGINS_HELPER/#define GST_INSTALL_PLUGINS_HELPER PREFIX "\\\\libexec\\\\gst-install-plugins-helper.exe"/' \
 951     -e 's/.* GETTEXT_PACKAGE$/#define GETTEXT_PACKAGE "'$GETTEXT_PACKAGE'"/' \
 952     -e 's/.* GST_DATADIR$/#define GST_DATADIR PREFIX "\\\\share"/' \
 953     -e 's/.* GST_LEVEL_DEFAULT$/#define GST_LEVEL_DEFAULT GST_LEVEL_ERROR/' \
 954     -e 's/.* GST_LICENSE$/#define GST_LICENSE "'$GST_LICENSE'"/' \
 955     -e 's/.* GST_API_VERSION$/#define GST_API_VERSION "'$GST_API_VERSION'"/' \
 956     -e "s,.* GST_PACKAGE_NAME$,#define GST_PACKAGE_NAME \"${GST_PACKAGE_NAME}\"," \
 957     -e 's/.* GST_PACKAGE_ORIGIN$/#define GST_PACKAGE_ORIGIN "Unknown package origin"/' \
 958     -e "s,.* GST_PACKAGE_RELEASE_DATETIME$,#define GST_PACKAGE_RELEASE_DATETIME \"${GST_PACKAGE_RELEASE_DATETIME}\"," \
 959     -e 's/.* HAVE_CPU_I386$/#define HAVE_CPU_I386 1/' \
 960     -e 's/.* HAVE_FGETPOS$/#define HAVE_FGETPOS 1/' \
 961     -e 's/.* HAVE_FSETPOS$/#define HAVE_FSETPOS 1/' \
 962     -e 's/.* HAVE_ISO_CODES$/#undef HAVE_ISO_CODES/' \
 963     -e 's/.* HAVE_LIBXML2$/#define HAVE_LIBXML2 1/' \
 964     -e 's/.* HAVE_PROCESS_H$/#define HAVE_PROCESS_H 1/' \
 965     -e 's/.* HAVE_STDLIB_H$/#define HAVE_STDLIB_H 1/' \
 966     -e 's/.* HAVE_STRING_H$/#define HAVE_STRING_H 1/' \
 967     -e 's/.* HAVE_SYS_STAT_H$/#define HAVE_SYS_STAT_H 1/' \
 968     -e 's/.* HAVE_SYS_TYPES_H$/#define HAVE_SYS_TYPES_H 1/' \
 969     -e 's/.* HAVE_WIN32$/#define HAVE_WIN32 1/' \
 970     -e 's/.* HOST_CPU$/#define HOST_CPU "i686"/' \
 971     -e 's/.* ISO_CODES_PREFIX$/#undef ISO_CODES_PREFIX/' \
 972     -e 's/.* ISO_CODES_VERSION$/#undef ISO_CODES_VERSION/' \
 973     -e 's/.* LIBDIR$/#ifdef _DEBUG\n#  define LIBDIR PREFIX "\\\\debug\\\\lib"\n#else\n#  define LIBDIR PREFIX "\\\\lib"\n#endif/' \
 974     -e 's/.* LOCALEDIR$/#define LOCALEDIR PREFIX "\\\\share\\\\locale"/' \
 975     -e "s/.* PACKAGE$/#define PACKAGE \"$PACKAGE\"/" \
 976     -e 's/.* PACKAGE_BUGREPORT$/#define PACKAGE_BUGREPORT "http:\/\/bugzilla.gnome.org\/enter_bug.cgi?product=GStreamer"/' \
 977     -e "s/.* PACKAGE_NAME$/#define PACKAGE_NAME \"$PACKAGE_NAME\"/" \
 978     -e "s/.* PACKAGE_STRING$/#define PACKAGE_STRING \"$PACKAGE_STRING\"/" \
 979     -e 's/.* PACKAGE_TARNAME$/#define PACKAGE_TARNAME "'$PACKAGE_TARNAME'"/' \
 980     -e 's/.* PACKAGE_VERSION$/#define PACKAGE_VERSION "'$PACKAGE_VERSION'"/' \
 981     -e 's/.* PLUGINDIR$/#ifdef _DEBUG\n#  define PLUGINDIR PREFIX "\\\\debug\\\\lib\\\\gstreamer-0.11"\n#else\n#  define PLUGINDIR PREFIX "\\\\lib\\\\gstreamer-0.11"\n#endif/' \
 982     -e 's/.* USE_BINARY_REGISTRY$/#define USE_BINARY_REGISTRY/' \
 983     -e 's/.* VERSION$/#define VERSION "'$VERSION'"/' \
 984     -e "s/.* DEFAULT_AUDIOSINK$/#define DEFAULT_AUDIOSINK \"directsoundsink\"/" \
 985     -e "s/.* DEFAULT_VIDEOSINK$/#define DEFAULT_VIDEOSINK \"directdrawsink\"/" \
 986     -e "s/.* DEFAULT_VISUALIZER$/#define DEFAULT_VISUALIZER \"goom\"/" \
 987     config.h.in >win32/common/config.h-new
 988
 989
 990
 991 AC_OUTPUT
 992
 993 AG_GST_OUTPUT_PLUGINS
 994 ORC_OUTPUT
 995