configure.ac

   1 dnl autoconf configuration file for gst-plugins
   2 AC_INIT
   3 AC_CANONICAL_TARGET([])
   4
   5 dnl We disable static building for development, for time savings
   6 dnl this goes before AS_LIBTOOL to appease autoconf
   7 dnl *NOTE*: dnl this line before release, so release does static too
   8 AM_DISABLE_STATIC
   9
  10 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  11 AM_MAINTAINER_MODE
  12
  13 dnl when going to/from release please set the nano (fourth number) right !
  14 dnl releases only do Wall, cvs and prerelease does Werror too
  15 AS_VERSION(gst-plugins, GST_PLUGINS_VERSION, 0, 4, 1, 1, GST_ERROR="-Wall", GST_ERROR="-Wall -Werror")
  16 AM_INIT_AUTOMAKE($PACKAGE,$VERSION)
  17 AS_LIBTOOL(GST_PLUGINS, 0, 0, 0, yes)
  18
  19 dnl FIXME take something else ?
  20 AC_CONFIG_SRCDIR([gst/law/alaw.c])
  21 AM_CONFIG_HEADER(config.h)
  22
  23 dnl Add parameters for aclocal
  24 dnl (This must come after AM_INIT_AUTOMAKE, since it modifies ACLOCAL)
  25 ACLOCAL_FLAGS="-I m4 -I common/m4"
  26 AC_SUBST(ACLOCAL_AMFLAGS, $ACLOCAL_FLAGS)
  27
  28 AC_PROG_CC
  29 AM_PROG_CC_STDC
  30 AM_PROG_AS
  31 AS="${CC}"
  32 dnl determine c++ compiler
  33 AC_PROG_CXX
  34 dnl determine if c++ is available on this system
  35 AC_CHECK_PROG(HAVE_CXX, $CXX, yes, no)
  36 dnl determine c++ preprocessor
  37 AC_PROG_CXXCPP
  38 AC_ISC_POSIX
  39
  40 AC_HEADER_STDC([])
  41
  42 dnl ############################################
  43 dnl # Super Duper options for plug-in building #
  44 dnl ############################################
  45
  46 dnl ext plug-ins; plug-ins that have external dependencies
  47 GST_CHECK_FEATURE(EXTERNAL, [enable building of plug-ins with external deps],,
  48 [HAVE_EXTERNAL=yes],enabled,
  49 [
  50   AC_MSG_WARN(building external plug-ins)
  51   BUILD_EXTERNAL="yes"
  52 ],[
  53   AC_MSG_WARN(all plug-ins with external dependencies will not be built)
  54   BUILD_EXTERNAL="no"
  55 ])
  56 # make BUILD_EXTERNAL available to Makefile.am
  57 AM_CONDITIONAL(BUILD_EXTERNAL, test "x$BUILD_EXTERNAL" = "xyes")
  58
  59 dnl experimental plug-ins; stuff that hasn't had the dust settle yet
  60 dnl read 'builds, but might not work'UTO
  61 GST_CHECK_FEATURE(EXPERIMENTAL, [enable building of experimental plug-ins],,
  62 [HAVE_EXPERIMENTAL=yes],disabled,
  63 [
  64   AC_MSG_WARN(building experimental plug-ins)
  65   USE_TARKIN="yes"
  66   USE_RTP="yes"
  67 ],[
  68   AC_MSG_NOTICE(not building experimental plug-ins)
  69   USE_TARKIN="no"
  70   USE_RTP="no"
  71 ])
  72
  73 dnl broken plug-ins; stuff that doesn't seem to build at the moment
  74 GST_CHECK_FEATURE(BROKEN, [enable building of broken plug-ins],,
  75 HAVE_BROKEN=yes,disabled,
  76 [
  77   AC_MSG_WARN([building broken plug-ins -- no bug reports on these, only patches :)])
  78   USE_SMOOTHWAVE="yes"
  79   USE_VGA="yes"
  80   USE_XMMS="yes"
  81 ],[
  82   USE_SMOOTHWAVE="no"
  83   USE_VGA="no"
  84   USE_XMMS="no"
  85   AC_MSG_NOTICE([not building broken plug-ins])
  86 ])
  87
  88 dnl ##############################
  89 dnl # Do automated configuration #
  90 dnl ##############################
  91
  92 dnl Check for tools:
  93 dnl ================
  94
  95 dnl allow for different autotools
  96 AS_AUTOTOOLS_ALTERNATE()
  97
  98 dnl modify pkg-config path
  99 AC_ARG_WITH(pkg-config-path,
 100    AC_HELP_STRING([--with-pkg-config-path],[colon-separated list of pkg-config(1) dirs]),
 101    [export PKG_CONFIG_PATH=${withval}])
 102
 103 dnl Check for nasm
 104 AC_PATH_PROG(NASM_PATH, nasm, no)
 105 AC_SUBST(NASM_PATH)
 106 if test x$NASM_PATH = xno; then
 107   AC_MSG_WARN(Couldn't find nasm)
 108   HAVE_NASM="no"
 109 else
 110   AC_DEFINE(HAVE_NASM, 1, [Define if NASM, the netwide assembler, is available])
 111   HAVE_NASM="yes"
 112 fi
 113
 114 dnl check for gconftool-2
 115 translit(dnm, m, l) AM_CONDITIONAL(USE_GCONFTOOL, true)
 116 GST_CHECK_FEATURE(GCONFTOOL, [GConf schemas], , [
 117   AC_PATH_PROG(GCONFTOOL, gconftool-2, no)
 118   if test x$GCONFTOOL = xno; then
 119     AC_MSG_WARN(Not installing GConf schemas)
 120     HAVE_GCONFTOOL="no"
 121   else
 122     AM_GCONF_SOURCE_2
 123     HAVE_GCONFTOOL="yes"
 124   fi
 125   AC_SUBST(HAVE_GCONFTOOL)
 126 ])
 127
 128 dnl check for GConf libraries
 129 translit(dnm, m, l) AM_CONDITIONAL(USE_GCONF, true)
 130 GST_CHECK_FEATURE(GCONF, [GConf libraries], , [
 131   PKG_CHECK_MODULES(GCONF, gconf-2.0, HAVE_GCONF="yes", HAVE_GCONF="no")
 132   AC_SUBST(GCONF_CFLAGS)
 133   AC_SUBST(GCONF_LIBS)
 134 ])
 135
 136 dnl check for gstreamer; uninstalled is selected preferentially -- see pkg-config(1)
 137 PKG_CHECK_MODULES(GST, gstreamer >= $GST_PLUGINS_VERSION_MAJOR.$GST_PLUGINS_VERSION_MINOR.$GST_PLUGINS_VERSION_MICRO,
 138   HAVE_GST="yes", HAVE_GST="no")
 139
 140 if test "x$HAVE_GST" = "xno"; then
 141   AC_MSG_ERROR(no GStreamer found)
 142 fi
 143
 144 GST_TOOLS_DIR=`pkg-config --variable=toolsdir gstreamer`
 145 if test -z $GST_TOOLS_DIR; then
 146   AC_MSG_ERROR([no tools dir defined in GStreamer pkg-config file; core upgrade needed.])
 147 fi
 148 AC_SUBST(GST_TOOLS_DIR)
 149
 150 dnl Set up conditionals for (target) architecture:
 151 dnl ==============================================
 152
 153 dnl Determine CPU
 154 case "x${target_cpu}" in
 155   xi?86 | k?) HAVE_CPU_I386=yes
 156               AC_DEFINE(HAVE_CPU_I386, 1, [Define if the target CPU is an x86])
 157               dnl FIXME could use some better detection
 158               dnl       (ie CPUID)
 159               case "x${target_cpu}" in
 160                 xi386 | xi486) ;;
 161                 *)             AC_DEFINE(HAVE_RDTSC, 1, [Define if RDTSC is available]) ;;
 162               esac ;;
 163   xpowerpc)   HAVE_CPU_PPC=yes
 164               AC_DEFINE(HAVE_CPU_PPC, 1, [Define if the target CPU is a PPC]) ;;
 165   xalpha)     HAVE_CPU_ALPHA=yes
 166               AC_DEFINE(HAVE_CPU_ALPHA, 1, [Define if the target CPU is an Alpha]) ;;
 167   xarm*)      HAVE_CPU_ARM=yes
 168               AC_DEFINE(HAVE_CPU_ARM, 1, [Define if the target CPU is an ARM]) ;;
 169   xsparc*)    HAVE_CPU_SPARC=yes
 170               AC_DEFINE(HAVE_CPU_SPARC, 1, [Define if the target CPU is a PPC]) ;;
 171   xmips*)     HAVE_CPU_MIPS=yes
 172               AC_DEFINE(HAVE_CPU_MIPS, 1, [Define if the target CPU is a MIPS]) ;;
 173   xhppa*)     HAVE_CPU_HPPA=yes
 174               AC_DEFINE(HAVE_CPU_HPPA, 1, [Define if the target CPU is a HPPA]) ;;
 175 esac
 176
 177 dnl Determine endianness
 178 AC_C_BIGENDIAN
 179
 180 dnl Check for fast float to int casting as defined in C99
 181 AC_C99_FUNC_LRINT()
 182 AC_C99_FUNC_LRINTF()
 183
 184 dnl Check for essential libraries first:
 185 dnl ====================================
 186
 187 GST_GLIB2_CHECK()
 188 PKG_CHECK_MODULES(GTK2, gtk+-2.0, HAVE_GTK=yes, HAVE_GTK=no)
 189 GTK_CFLAGS=$GTK2_CFLAGS
 190 GTK_LIBS=$GTK2_LIBS
 191 AC_SUBST(GTK_LIBS)
 192 AC_SUBST(GTK_CFLAGS)
 193
 194 dnl Check for X11 extensions
 195 AC_PATH_XTRA
 196 if test "-DX_DISPLAY_MISSING" = "$X_CFLAGS"; then
 197   AC_MSG_NOTICE([cannot find X11, the build system needs fixage])
 198 fi
 199 AC_SUBST(X_CFLAGS)
 200 AC_SUBST(X_PRE_LIBS)
 201 AC_SUBST(X_EXTRA_LIBS)
 202 AC_SUBST(X_LIBS)
 203
 204 dnl ===========================================================================
 205 dnl ============================= gst plug-ins ================================
 206 dnl ===========================================================================
 207
 208 GST_PLUGIN_LDFLAGS='-module -avoid-version'
 209 AC_SUBST(GST_PLUGIN_LDFLAGS)
 210
 211 dnl these are all the gst plug-ins, compilable without additional libs
 212 GST_PLUGINS_ALL="\
 213         ac3parse adder audioscale auparse avi cdxaparse chart\
 214         cutter deinterlace effectv festival filter flx goom\
 215         intfloat law level\
 216         median mixmatrix mpeg1enc mpeg1sys mpeg1videoparse mpeg2enc mpeg2sub\
 217         mpegaudio mpegaudioparse mpegstream mpegtypes\
 218         monoscope passthrough playondemand qtdemux rtjpeg silence sine\
 219         smooth spectrum speed stereo stereomono synaesthesia\
 220         udp videocrop videoscale videotestsrc volenv volume\
 221         vumeter wavenc wavparse y4m"
 222
 223 dnl see if we can build C++ plug-ins
 224 if test "x$HAVE_CXX" = "xyes"; then
 225   GST_PLUGINS_ALL="$GST_PLUGINS_ALL \
 226                   modplug"
 227 else
 228   AC_MSG_WARN([Not compiling plug-ins requiring C++ compiler])
 229 fi
 230
 231 AC_SUBST(GST_PLUGINS_ALL)
 232
 233 GST_PLUGINS_SELECTED=""
 234
 235 AC_ARG_WITH(plugins,
 236     AC_HELP_STRING([--with-plugins],[comma-separated list of plug-ins to compile]),
 237     [for i in `echo $withval | tr , ' '`; do
 238         if test -n `echo $i | grep $GST_PLUGINS_ALL`; then
 239             GST_PLUGINS_SELECTED="$GST_PLUGINS_SELECTED $i"
 240         else
 241             echo "plug-in $i not recognized, ignoring..."
 242         fi
 243     done],
 244     [GST_PLUGINS_SELECTED=$GST_PLUGINS_ALL])
 245
 246 AC_SUBST(GST_PLUGINS_SELECTED)
 247
 248 dnl ==========================================================================
 249 dnl ============================= sys plug-ins ================================
 250 dnl ==========================================================================
 251
 252 dnl *** DXR3 card ***
 253 translit(dnm, m, l) AM_CONDITIONAL(USE_DXR3, true)
 254 GST_CHECK_FEATURE(DXR3, [DXR3 hardware mpeg video decoder], dxr3videosink, [
 255   AC_CHECK_HEADER(linux/em8300.h, HAVE_DXR3="yes", HAVE_DXR3="no")
 256 ])
 257
 258 dnl *** OSS audio ***
 259 translit(dnm, m, l) AM_CONDITIONAL(USE_OSS, true)
 260 GST_CHECK_FEATURE(OSS, [OSS audio], osssrc osssink, [
 261   AC_CHECK_HEADER(sys/soundcard.h, HAVE_OSS="yes", HAVE_OSS="no")
 262 ])
 263
 264 dnl *** QuickCam ***
 265 translit(dnm, m, l) AM_CONDITIONAL(USE_QCAM, true)
 266 GST_CHECK_FEATURE(QCAM, [QuickCam], qcamsrc, [
 267 dnl this one is for hadess, no qcam when no nasm found
 268   if test "x$HAVE_NASM" = "xno";
 269   then
 270     HAVE_QCAM="no"
 271     AC_MSG_WARN([QuickCam needs nasm])
 272   else
 273     HAVE_QCAM="yes"
 274   fi
 275 ])
 276
 277 dnl *** Video 4 Linux ***
 278 translit(dnm, m, l) AM_CONDITIONAL(USE_V4L, true)
 279 GST_CHECK_FEATURE(V4L, [Video 4 Linux], v4lsrc v4lmjpegsrc v4lmjpegsink, [
 280   AC_CHECK_DECL(VID_TYPE_MPEG_ENCODER, HAVE_V4L="yes", HAVE_V4L="no", [#include <linux/videodev.h>])
 281 ])
 282
 283 dnl *** Video 4 Linux 2***
 284 translit(dnm, m, l) AM_CONDITIONAL(USE_V4L2, true)
 285 GST_CHECK_FEATURE(V4L2, [Video 4 Linux 2], v4l2src, [
 286   AC_CHECK_HEADER(linux/videodev2.h, HAVE_V4L2="yes", HAVE_V4L2="no")
 287 ])
 288
 289 dnl *** Video CD ***
 290 translit(dnm, m, l) AM_CONDITIONAL(USE_VCD, true)
 291 GST_CHECK_FEATURE(VCD, [Video CD], vcdsrc, [
 292   AC_CHECK_HEADER(linux/cdrom.h, HAVE_VCD="yes", HAVE_VCD="no")
 293 ])
 294
 295 dnl *** VGA ***
 296 translit(dnm, m, l) AM_CONDITIONAL(USE_VGA, true)
 297 GST_CHECK_FEATURE(VGA, [VGA], vgavideosink, [
 298   AC_CHECK_HEADER(asm/vga.h, HAVE_VGA="yes", HAVE_VGA="no")
 299 ])
 300
 301 dnl *** CDROM Audio ***
 302 translit(dnm, m, l) AM_CONDITIONAL(USE_CDROM, true)
 303 GST_CHECK_FEATURE(CDROM, [CDROM Audio], cdrom, [
 304   AC_CHECK_HEADERS(linux/cdrom.h) dnl linux
 305   AC_CHECK_HEADERS(sys/cdio.h) dnl almost everything else
 306 dnl  AC_CHECK_HEADERS(dmedia/cdaudio.h) dnl irix
 307
 308   if test "${ac_cv_header_linux_cdrom_h}" = "yes" || test "${ac_cv_header_sys_cdio_h}" = "yes" || test "${ac_cv_header_dmedia_cdaudio_h}" = "yes"; then
 309         case "$host" in
 310                 *-sun-* | *-*-linux*)
 311                         AC_DEFINE(HAVE_CDROM_SOLARIS,, [Define if cdrom access is in Solaris style])
 312                 ;;
 313                 *-*-freebsd*)
 314                         AC_DEFINE(HAVE_CDROM_BSD,, [Define if cdrom access is in BSD style])
 315                 ;;
 316                 *-*-netbsd* | *-*-openbsd*)
 317                         AC_DEFINE(HAVE_CDROM_BSD,, [Define if cdrom access is in BSD style])
 318                         AC_DEFINE(HAVE_CDROM_BSD_NETBSD,, [Define if cdrom access uses NetBSD variant])
 319                 ;;
 320                 *-*darwin*)
 321                         AC_DEFINE(HAVE_CDROM_BSD,, [Define if cdrom access is in BSD style])
 322                         AC_DEFINE(HAVE_CDROM_BSD_DARWIN,, [Define if cdrom access uses Darwin variant])
 323                 ;;
 324 dnl             *-irix-*)
 325 dnl                     AC_DEFINE(HAVE_CDROM_IRIX,, [Define if cdrom access is in Irix DMedia style])
 326 dnl             ;;
 327     esac
 328
 329         HAVE_CDROM="yes"
 330   else
 331         HAVE_CDROM="no"
 332   fi
 333 ])
 334
 335 dnl *** XVideo ***
 336 dnl Look for the PIC library first, Debian requires it.
 337 dnl Check debian-devel archives for gory details.
 338 dnl 20020110:
 339 dnl At the moment XFree86 doesn't distribute shared libXv due
 340 dnl to unstable API.  On many platforms you CAN NOT link a shared
 341 dnl lib to a static non-PIC lib.  This is what the xvideo GStreamer
 342 dnl plug-in wants to do.  So Debian distributes a PIC compiled
 343 dnl version of the static lib for plug-ins to link to when it is
 344 dnl inappropriate to link the main application to libXv directly.
 345 dnl FIXME: add check if this platform can support linking to a
 346 dnl        non-PIC libXv, if not then don not use Xv.
 347 dnl FIXME: perhaps warn user if they have a shared libXv since
 348 dnl        this is an error until XFree86 starts shipping one
 349 translit(dnm, m, l) AM_CONDITIONAL(USE_XVIDEO, true)
 350 GST_CHECK_FEATURE(XVIDEO, [X11 XVideo extensions], xvideosink videosink, [
 351   dnl check for PIC static lib
 352   GST_CHECK_LIBHEADER(XVIDEO, Xv_pic, XvQueryExtension, $X_LIBS $X_PRE_LIBS -lXext -lX11 $X_EXTRA_LIBS, X11/extensions/Xvlib.h, XVIDEO_LIBS="-lXv_pic -lXext")
 353   if test x$HAVE_XVIDEO = xno; then
 354     dnl PIC lib not found, check for regular lib
 355     GST_CHECK_LIBHEADER(XVIDEO, Xv, XvQueryExtension, $X_LIBS $X_PRE_LIBS -lXext -lX11 $X_EXTRA_LIBS, X11/extensions/Xvlib.h, XVIDEO_LIBS="-lXv -lXext")
 356   fi
 357   AC_SUBST(XVIDEO_LIBS)
 358 ])
 359
 360 dnl Next, check for the optional libraries:
 361 dnl These are all libraries used in building plug-ins
 362 dnl ================================================
 363 dnl let's try and sort them alphabetically, shall we ?
 364
 365 if test "x$BUILD_EXTERNAL" = "xyes"; then
 366
 367 AC_MSG_NOTICE(Checking for plug-in dependency libraries)
 368
 369 dnl *** a52dec ***
 370 translit(dnm, m, l) AM_CONDITIONAL(USE_A52DEC, true)
 371 GST_CHECK_FEATURE(A52DEC, [a52dec], a52dec, [
 372   AC_CHECK_A52DEC(HAVE_A52DEC=yes, HAVE_A52DEC=no)
 373 ])
 374
 375 dnl *** aalib ***
 376 translit(dnm, m, l) AM_CONDITIONAL(USE_AALIB, true)
 377 GST_CHECK_FEATURE(AALIB, [aasink plug-in], aasink, [
 378   AM_PATH_AALIB(, HAVE_AALIB=yes, HAVE_AALIB=no)
 379   AS_SCRUB_INCLUDE(AALIB_CFLAGS)
 380 ])
 381
 382 dnl *** alsa ***
 383 translit(dnm, m, l) AM_CONDITIONAL(USE_ALSA, true)
 384 GST_CHECK_FEATURE(ALSA, [alsa plug-ins], gstalsa, [
 385    AM_PATH_ALSA(0.9.0, HAVE_ALSA=yes, HAVE_ALSA=no)
 386 ])
 387
 388 dnl *** arts ***
 389 dnl if mcopidl can't be found there's no use in compiling it
 390 AC_CHECK_PROG(MCOPIDL, mcopidl, yes, no)
 391 if test "xHAVE_MCOPIDL" = "xno";
 392 then
 393   USE_ARTS=no
 394 fi
 395
 396 translit(dnm, m, l) AM_CONDITIONAL(USE_ARTS, true)
 397 GST_CHECK_FEATURE(ARTS, [arts plug-ins], arts, [
 398   AM_PATH_ARTS(, HAVE_ARTS=yes, HAVE_ARTS=no)
 399 ])
 400
 401 dnl *** artsc ***
 402 translit(dnm, m, l) AM_CONDITIONAL(USE_ARTSC, true)
 403 GST_CHECK_FEATURE(ARTSC, [artsd plug-ins], artsdsink, [
 404   GST_CHECK_ARTSC()
 405 ])
 406
 407 dnl *** audiofile ***
 408 dnl this check uses the GST_CHECK_CONFIGPROG macro
 409 translit(dnm, m, l) AM_CONDITIONAL(USE_AUDIOFILE, true)
 410 GST_CHECK_FEATURE(AUDIOFILE, [audiofile], afsink afsrc, [
 411   translit(dnm, m, l) AC_SUBST(AUDIOFILE_LIBS)
 412   translit(dnm, m, l) AC_SUBST(AUDIOFILE_CFLAGS)
 413   GST_CHECK_CONFIGPROG(AUDIOFILE, audiofile-config)
 414   dnl we need this function
 415   AC_CHECK_LIB(audiofile, afOpenVirtualFile, , HAVE_AUDIOFILE="no")
 416 ])
 417
 418 dnl *** avifile ***
 419 translit(dnm, m, l) AM_CONDITIONAL(USE_AVIFILE, true)
 420 GST_CHECK_FEATURE(AVIFILE, [avifile], winenc windec, [
 421   if test "x$no_x" = "xyes"; then
 422     AC_MSG_WARN([No X libraries found, avifile test might fail compilation])
 423   fi
 424   if test "x$HAVE_CXX" != "xyes"; then
 425     AC_MSG_WARN([No C++ compiler found, avifile test will fail compilation])
 426   fi
 427   AC_CHECK_LIB(stdc++, cout,,
 428                [AC_MSG_WARN([no libstdc++ found, avifile test will fail])]
 429               )
 430   AS_AVIFILE(0.7.0)
 431 ])
 432
 433 dnl *** CDParanoia ***
 434 translit(dnm, m, l) AM_CONDITIONAL(USE_CDPARANOIA, true)
 435 GST_CHECK_FEATURE(CDPARANOIA, [CDParanoia], cdparanoia, [
 436   GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 437                       cdda_open, -lm,
 438                       cdda_interface.h,
 439                       CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 440                       HEADER_DIR="no"
 441                       FOUND_CDPARANOIA="yes")
 442   if test "x$FOUND_CDPARANOIA" != "xyes";
 443   then
 444     GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 445                         cdda_open, -lm,
 446                         cdda/cdda_interface.h,
 447                         CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 448                         HEADER_DIR="yes"
 449                         FOUND_CDPARANOIA="yes")
 450   fi
 451   if test "x$HEADER_DIR" = "xyes";
 452   then
 453     AC_DEFINE_UNQUOTED(CDPARANOIA_HEADERS_IN_DIR, ,
 454                        defined if cdda headers are in a cdda/ directory)
 455   fi
 456   AC_SUBST(CDPARANOIA_LIBS)
 457 ])
 458 dnl FIXME : add second check somehow if that is necessary
 459 dnl AC_CHECK_LIB(cdda_paranoia, paranoia_init, : , HAVE_CDPARANOIA=no, -lcdda_interface )
 460 dnl AC_CHECK_HEADER(cdda_paranoia.h, :, HAVE_CDPARANOIA=no)
 461
 462 dnl *** libdv ***
 463 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBDV, true)
 464 GST_CHECK_FEATURE(LIBDV, [libdv DV/video decoder], dvdec, [
 465   PKG_CHECK_MODULES(LIBDV, libdv >= 0.98, HAVE_LIBDV="yes", HAVE_LIBDV="no")
 466   AC_SUBST(LIBDV_CFLAGS)
 467   AC_SUBST(LIBDV_LIBS)
 468 ])
 469
 470 dnl *** dvdread ***
 471 translit(dnm, m, l) AM_CONDITIONAL(USE_DVDREAD, true)
 472 GST_CHECK_FEATURE(DVDREAD, [dvdread library], dvdreadsrc, [
 473   GST_CHECK_LIBHEADER(DVDREAD, dvdread, DVDOpen, , dvdread/dvd_reader.h, DVDREAD_LIBS="-ldvdread")
 474   AC_SUBST(DVDREAD_LIBS)
 475 ])
 476
 477 dnl *** dvdnav ***
 478 translit(dnm, m, l) AM_CONDITIONAL(USE_DVDNAV, true)
 479 GST_CHECK_FEATURE(DVDNAV, [dvdnav library], dvdnavsrc, [
 480   translit(dnm, m, l) AC_SUBST(DVDNAV_LIBS)
 481   translit(dnm, m, l) AC_SUBST(DVDNAV_CFLAGS)
 482   GST_CHECK_CONFIGPROG(DVDNAV, dvdnav-config)
 483   AS_SCRUB_INCLUDE(DVDNAV_CFLAGS)
 484 ])
 485
 486 dnl **** ESound ****
 487 translit(dnm, m, l) AM_CONDITIONAL(USE_ESD, true)
 488 GST_CHECK_FEATURE(ESD, [esound plug-ins], esdsink esdmon, [
 489   AM_PATH_ESD(0.2.12, HAVE_ESD=yes, HAVE_ESD=no)
 490 ])
 491
 492 dnl **** festival ****
 493 dnl translit(dnm, m, l) AM_CONDITIONAL(USE_FESTIVAL, true)
 494 dnl GST_CHECK_FEATURE(FESTIVAL, [festival plug-ins], festivalsrc, [
 495   dnl NOTE: just using local net connection now, add this lib check
 496   dnl       in the future if needed
 497   dnl AC_LANG_PUSH(C++)
 498   dnl dnl FIXME: took out func to check for
 499   dnl dnl This check puts festival_tidy_up in extern "C".
 500   dnl dnl But, at least on Debian as of 20020110, it is compiled with name
 501   dnl dnl mangling C++ nonsense and symbols can't resolve
 502   dnl dnl GST_CHECK_LIBHEADER(FESTIVAL, Festival, festival_tidy_up, , festival/festival.h, FESTIVAL_LIBS="-lFestival")
 503   dnl GST_CHECK_LIBHEADER(FESTIVAL, Festival, , , festival/festival.h, FESTIVAL_LIBS="-lFestival")
 504   dnl AC_LANG_POP(C++)
 505   dnl AC_SUBST(FESTIVAL_LIBS)
 506 dnl  HAVE_FESTIVAL=yes
 507 dnl])
 508
 509 dnl *** FLAC ***
 510 translit(dnm, m, l) AM_CONDITIONAL(USE_FLAC, true)
 511 GST_CHECK_FEATURE(FLAC, [FLAC lossless audio], flacenc flacdec, [
 512   GST_CHECK_LIBHEADER(FLAC, FLAC, FLAC__stream_decoder_new, -lm, FLAC/all.h, FLAC_LIBS="-lFLAC")
 513   AC_SUBST(FLAC_LIBS)
 514 ])
 515
 516 dnl *** Gnome VFS ***
 517 translit(dnm, m, l) AM_CONDITIONAL(USE_GNOME_VFS, true)
 518 GST_CHECK_FEATURE(GNOME_VFS, [Gnome VFS], gnomevfssrc, [
 519   PKG_CHECK_MODULES(GNOME_VFS, gnome-vfs-2.0, HAVE_GNOME_VFS="yes", HAVE_GNOME_VFS="no")
 520   AC_SUBST(GNOME_VFS_CFLAGS)
 521   AC_SUBST(GNOME_VFS_LIBS)
 522 ])
 523
 524 dnl *** gsm ***
 525 translit(dnm, m, l) AM_CONDITIONAL(USE_GSM, true)
 526 GST_CHECK_FEATURE(GSM, [GSM library], gsmenc gsmdec, [
 527   GST_CHECK_LIBHEADER(GSM, gsm, gsm_create, , gsm.h, GSM_LIBS="-lgsm")
 528   if test $HAVE_GSM != "yes"; then
 529     GST_CHECK_LIBHEADER(GSM, gsm, gsm_create, , gsm/gsm.h, GSM_LIBS="-lgsm")
 530     if test $HAVE_GSM = "yes"; then
 531       AC_DEFINE(GSM_HEADER_IN_SUBDIR, 1, [Define if GSM header in gsm/ subdir])
 532     fi
 533   fi
 534   AC_SUBST(GSM_LIBS)
 535 ])
 536
 537 dnl *** Hermes ***
 538 translit(dnm, m, l) AM_CONDITIONAL(USE_HERMES, true)
 539 GST_CHECK_FEATURE(HERMES, [Hermes library], colorspace, [
 540   GST_CHECK_LIBHEADER(HERMES, Hermes, Hermes_ConverterInstance, , Hermes/Hermes.h, HERMES_LIBS="-lHermes")
 541 ], AC_SUBST(HERMES_LIBS))
 542
 543 dnl *** http ***
 544 translit(dnm, m, l) AM_CONDITIONAL(USE_HTTP, true)
 545 GST_CHECK_FEATURE(HTTP, [http plug-ins], gsthttpsrc, [
 546   dnl FIXME: need to check for header
 547   GHTTP_LIBS=
 548   GST_HTTPSRC_GET_TYPE=
 549   if test x$USE_GLIB2 = xyes; then
 550     AC_MSG_WARN(ghttp disabled for glib2.0)
 551   else
 552     AC_CHECK_LIB(ghttp, ghttp_request_new,
 553       [HTTP_LIBS="-lghttp"
 554        GST_HTTPSRC_GET_TYPE="gst_httpsrc_get_type"
 555        HAVE_HTTP=yes
 556       ], :, $LIBS)
 557   fi
 558   AC_SUBST(HTTP_LIBS)
 559   AC_SUBST(GST_HTTPSRC_GET_TYPE)
 560 ])
 561
 562 dnl *** Jack ***
 563 translit(dnm, m, l) AM_CONDITIONAL(USE_JACK, true)
 564 GST_CHECK_FEATURE(JACK, Jack, jack, [
 565   PKG_CHECK_MODULES(JACK, jack >= 0.29.0, HAVE_JACK="yes", HAVE_JACK="no")
 566   AC_SUBST(JACK_CFLAGS)
 567   AC_SUBST(JACK_LIBS)
 568 ])
 569
 570 dnl *** jpeg ***
 571 dnl FIXME: we could use header checks here as well IMO
 572 translit(dnm, m, l) AM_CONDITIONAL(USE_JPEG, true)
 573 GST_CHECK_FEATURE(JPEG, [jpeg], jpegenc jpegdec, [
 574   AC_CHECK_LIB(jpeg, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
 575   JPEG_LIBS="-ljpeg"
 576   AC_SUBST(JPEG_LIBS)
 577 ])
 578
 579 dnl *** ladspa ***
 580 translit(dnm, m, l) AM_CONDITIONAL(USE_LADSPA, true)
 581 GST_CHECK_FEATURE(LADSPA, [ladspa], ladspa, [
 582   AC_CHECK_HEADER(ladspa.h, HAVE_LADSPA="yes", HAVE_LADSPA="no")
 583 ])
 584
 585 dnl *** lame ***
 586 translit(dnm, m, l) AM_CONDITIONAL(USE_LAME, true)
 587 GST_CHECK_FEATURE(LAME, [lame mp3 encoder library], lame, [
 588   GST_CHECK_LIBHEADER(LAME, mp3lame, lame_init, -lm, lame/lame.h, HAVE_LAME="yes" LAME_LIBS="-lmp3lame")
 589 ])
 590 AC_SUBST(LAME_LIBS)
 591
 592 dnl *** libcolorspace ***
 593 translit(dnm, m, l) AM_CONDITIONAL(USE_LCS, true)
 594 GST_CHECK_FEATURE(LCS, Lcs, lcs, [
 595   PKG_CHECK_MODULES(LCS, lcs, HAVE_LCS="yes", HAVE_LCS="no")
 596   AC_SUBST(LCS_CFLAGS)
 597   AC_SUBST(LCS_LIBS)
 598 ])
 599
 600 dnl *** libfame ***
 601 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBFAME, true)
 602 GST_CHECK_FEATURE(LIBFAME, [libfame MPEG1/4 encoder], libfame, [
 603   AM_PATH_LIBFAME(0.9.0, HAVE_LIBFAME="yes", HAVE_LIBFAME="no")
 604   AC_SUBST(LIBFAME_CFLAGS)
 605   AC_SUBST(LIBFAME_LIBS)
 606 ])
 607
 608 dnl *** mad ***
 609 dnl FIXME: we could use header checks here as well IMO
 610 translit(dnm, m, l) AM_CONDITIONAL(USE_MAD, true)
 611 GST_CHECK_FEATURE(MAD, [mad mp3 decoder], mad, [
 612   AC_CHECK_LIB(mad, mad_decoder_finish, HAVE_MAD="yes" MAD_LIBS="-lmad")
 613   if test "x$HAVE_MAD" = "xyes"; then
 614     # installed with mad >= 0.14
 615     HAVE_MAD="no"
 616     save_libs=$LIBS
 617     LIBS="-lz"
 618     AC_CHECK_LIB(id3tag, id3_tag_query, HAVE_MAD="yes" MAD_LIBS="$MAD_LIBS -lid3tag")
 619     LIBS=$save_LIBS
 620   fi
 621 ])
 622 AC_SUBST(MAD_LIBS)
 623
 624 dnl *** mikmod ***
 625 translit(dnm, m, l) AM_CONDITIONAL(USE_MIKMOD, true)
 626 GST_CHECK_FEATURE(MIKMOD, [mikmod plug-in], mikmod, [
 627   AM_PATH_LIBMIKMOD(, HAVE_MIKMOD=yes, HAVE_MIKMOD=no)
 628   AC_SUBST(MIKMOD_LIBS, "$LIBMIKMOD_LIBS")
 629   AC_SUBST(MIKMOD_CFLAGS, "$LIBMIKMODCFLAGS")
 630 ])
 631
 632 dnl *** mjpegtools ***
 633 translit(dnm, m, l) AM_CONDITIONAL(USE_MJPEGTOOLS, true)
 634 GST_CHECK_FEATURE(MJPEGTOOLS, [mjpegtools], jpegmmxenc jpegmmxdec, [
 635   PKG_CHECK_MODULES(MJPEGTOOLS, mjpegtools, HAVE_MJPEGTOOLS="yes", HAVE_MJPEGTOOLS="no")
 636
 637   if [ test x$HAVE_MJPEGTOOLS = x"yes" ]; then
 638     dnl some headers we might want to need
 639     AC_CHECK_HEADERS(stdint.h, HAVE_STDINT_H="yes", HAVE_STDINT_H="no")
 640     if [ test x$HAVE_STDINT_H = x"no" ]; then
 641       AC_CHECK_HEADERS(inttypes.h sys/types.h, HAVE_INTTYPES_H="yes", [
 642         AC_MSG_WARN(No valid header files found, mjpegtools plugins disabled)
 643         HAVE_INTTYPES_H="no" HAVE_MJPEGTOOLS="no"
 644       ])
 645     fi
 646     AC_CHECK_HEADERS(stdbool.h, HAVE_STDBOOL_H="yes", HAVE_STDBOOL_H="no")
 647
 648     dnl sizeof PRId64 etc...
 649     AC_CHECK_SIZEOF(int)
 650     AC_CHECK_SIZEOF(long)
 651     AC_CHECK_SIZEOF(long long)
 652     case 8 in
 653     $ac_cv_sizeof_int)
 654       PRID64_STRING_FORMAT="d"
 655       ;;
 656     $ac_cv_sizeof_long)
 657       PRID64_STRING_FORMAT="ld"
 658       ;;
 659     $ac_cv_sizeof_long_long)
 660       PRID64_STRING_FORMAT="lld"
 661       ;;
 662     *)
 663       AC_MSG_WARN(No suitable variant for 64bits integers found, mjpegtools plugins disabled)
 664       HAVE_MJPEGTOOLS="no"
 665       ;;
 666     esac
 667
 668     AC_DEFINE_UNQUOTED(PRID64_STRING_FORMAT, "$PRID64_STRING_FORMAT",
 669       [ A printf type definition for 64 bit integers ])
 670     AC_SUBST(MJPEGTOOLS_LIBS)
 671     AC_SUBST(MJPEGTOOLS_CFLAGS)
 672   fi
 673 ])
 674
 675 dnl *** mpeg2dec ***
 676 translit(dnm, m, l) AM_CONDITIONAL(USE_MPEG2DEC, true)
 677 GST_CHECK_FEATURE(MPEG2DEC, [mpeg2dec], mpeg2dec, [
 678   AC_CHECK_MPEG2DEC(HAVE_MPEG2DEC=yes, HAVE_MPEG2DEC=no)
 679 ])
 680
 681 dnl *** openquicktime ***
 682 translit(dnm, m, l) AM_CONDITIONAL(USE_OPENQUICKTIME, true)
 683 GST_CHECK_FEATURE(OPENQUICKTIME, [Open Quicktime], quicktime_parser quicktime_decoder quicktime_demux,[
 684   GST_CHECK_LIBHEADER(OPENQUICKTIME, openquicktime, quicktime_init,, openquicktime/openquicktime.h, OPENQUICKTIME_LIBS="-lopenquicktime")
 685   AC_SUBST(OPENQUICKTIME_LIBS)
 686 ])
 687
 688 dnl *** raw1394 ***
 689 translit(dnm, m, l) AM_CONDITIONAL(USE_RAW1394, true)
 690 GST_CHECK_FEATURE(RAW1394, [raw1394 library], dv1394src, [
 691   GST_CHECK_LIBHEADER(RAW1394, raw1394, raw1394_get_handle,, libraw1394/raw1394.h, RAW1394_LIBS="-raw1394")
 692   AC_SUBST(RAW1394_LIBS)
 693 ])
 694
 695 dnl *** rtp ***
 696 dnl FIXME : adapt and make it work
 697 translit(dnm, m, l) AM_CONDITIONAL(USE_RTP, true)
 698 GST_CHECK_FEATURE(RTP, [RTP library], rtpenc rtpdec,[
 699   AC_CHECK_LIB(ortp, ortp_init, HAVE_RTP=yes, HAVE_RTP=no, $GST_CFLAGS $GST_LIBS)
 700   RTP_LIBS="-lortp"
 701   AC_SUBST(RTP_LIBS)
 702 ])
 703
 704 dnl FIXME header check needs to use GLIB_CFLAGS in order to succeed for rtp
 705 dnl can use GST_* which should have GLIB_* info
 706 dnl AC_CHECK_HEADERS(rtp/rtp.h, HAVE_LIBRTP=yes, HAVE_LIBRTP=no)
 707 dnl AC_CHECK_HEADERS(rtp/rtp-packet.h, :, HAVE_LIBRTP=no)
 708 dnl AC_CHECK_HEADERS(rtp/rtcp-packet.h, :, HAVE_LIBRTP=no)
 709 dnl AC_CHECK_HEADERS(rtp/rtp-audio.h, :, HAVE_LIBRTP=no)
 710
 711 dnl *** SDL ***
 712 translit(dnm, m, l) AM_CONDITIONAL(USE_SDL, true)
 713 GST_CHECK_FEATURE(SDL, [SDL plug-in], sdlvideosink, [
 714  AM_PATH_SDL(, HAVE_SDL=yes, HAVE_SDL=no)
 715 ])
 716
 717 dnl *** shout ***
 718 translit(dnm, m, l) AM_CONDITIONAL(USE_SHOUT, true)
 719 GST_CHECK_FEATURE(SHOUT, [shout plug-in], icecastsend, [
 720   GST_CHECK_LIBHEADER(SHOUT, shout, shout_init_connection,, shout/shout.h, SHOUT_LIBS="-lshout")
 721   AC_SUBST(SHOUT_LIBS)
 722 ])
 723
 724 dnl *** sidplay ***
 725 translit(dnm, m, l) AM_CONDITIONAL(USE_SIDPLAY, true)
 726 GST_CHECK_FEATURE(SIDPLAY, [sidplay plug-in], sidplay, [
 727   GST_PATH_SIDPLAY()
 728 ])
 729
 730 dnl *** smoothwave ***
 731 translit(dnm, m, l) AM_CONDITIONAL(USE_SMOOTHWAVE, true)
 732 GST_CHECK_FEATURE(SMOOTHWAVE, [smoothwave plug-in], smoothwave, [
 733   if test $HAVE_GTK = "yes"; then HAVE_SMOOTHWAVE=yes; fi;
 734 ])
 735
 736
 737 dnl *** snapshot ***
 738 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBPNG, true)
 739 GST_CHECK_FEATURE(LIBPNG, [snapshot plug-in], snapshot, [
 740   GST_CHECK_LIBHEADER(LIBPNG, png, png_read_info, -lz, png.h, LIBPNG_LIBS="-lpng -lz")
 741   AC_SUBST(LIBPNG_LIBS)
 742 ])
 743
 744 dnl *** swfdec ***
 745 translit(dnm, m, l) AM_CONDITIONAL(USE_SWFDEC, true)
 746 GST_CHECK_FEATURE(SWFDEC, [swfdec plug-in], swfdec, [
 747   PKG_CHECK_MODULES(SWFDEC, libswfdec, HAVE_SWFDEC="yes", HAVE_SWFDEC="no")
 748   AC_SUBST(SWFDEC_CFLAGS)
 749   AC_SUBST(SWFDEC_LIBS)
 750 ])
 751
 752 dnl *** tarkin ***
 753 dnl for now the sources are included in the plug-in
 754 dnl and should be moved to ext-libs/ perhaps
 755 translit(dnm, m, l) AM_CONDITIONAL(USE_TARKIN, true)
 756 GST_CHECK_FEATURE(TARKIN, [tarkinenc tarkindec], tarkin, [
 757   HAVE_TARKIN="yes"
 758 ])
 759
 760 dnl *** vorbis ***
 761 dnl AM_PATH_VORBIS only takes two options
 762 translit(dnm, m, l) AM_CONDITIONAL(USE_VORBIS, true)
 763 GST_CHECK_FEATURE(VORBIS, [vorbis plug-in], vorbisenc vorbisdec, [
 764   XIPH_PATH_VORBIS(HAVE_VORBIS=yes, HAVE_VORBIS=no)
 765   AS_SCRUB_INCLUDE(VORBIS_CFLAGS)
 766 ])
 767
 768 dnl *** XMMS ***
 769 translit(dnm, m, l) AM_CONDITIONAL(USE_XMMS, true)
 770 GST_CHECK_FEATURE(XMMS, [xmms plug-in], xmms, [
 771   AM_PATH_XMMS(0.1.0, HAVE_XMMS=yes, HAVE_XMMS=no)
 772 ])
 773
 774 fi dnl of EXT plugins
 775
 776 dnl Check for atomic.h
 777 dnl Note: use AC_CHECK_HEADER not AC_CHECK_HEADERS, because the latter
 778 dnl defines the wrong default symbol as well (HAVE_ASM_ATOMIC_H)
 779 AC_CHECK_HEADER(asm/atomic.h, HAVE_ATOMIC_H=yes, HAVE_ATOMIC_H=no)
 780 dnl Do a compile to check that it has atomic_set (eg, linux 2.0 didn't)
 781 if test x$HAVE_ATOMIC_H = xyes; then
 782   AC_TRY_RUN([
 783 #include "asm/atomic.h"
 784 main() { atomic_t t; atomic_set(&t,0); atomic_inc(&t); atomic_add(1,&t);return 0;}
 785   ],, [
 786     # Not successful
 787     if test x$HAVE_ATOMIC_H = xyes; then
 788       AC_MSG_WARN(Atomic reference counting is out of date: doing without.)
 789     fi
 790     HAVE_ATOMIC_H=no
 791   ], [
 792     # Cross compiling
 793     AC_MSG_RESULT(yes)
 794     AC_MSG_WARN(Can't check properly for atomic reference counting.  Assuming OK.)
 795   ])
 796 fi
 797
 798
 799 dnl ######################################################################
 800 dnl # Check command line parameters, and set shell variables accordingly #
 801 dnl ######################################################################
 802
 803 GST_DEBUGINFO
 804
 805 AC_ARG_ENABLE(libmmx,
 806   AC_HELP_STRING([--enable-libmmx],[use libmmx, if available]),
 807 [case "${enableval}" in
 808   yes) USE_LIBMMX=$HAVE_LIBMMX ;;
 809   no)  USE_LIBMMX=no ;;
 810   *) AC_MSG_ERROR(bad value ${enableval} for --enable-libmmx) ;;
 811 esac],
 812 [USE_LIBMMX=$HAVE_LIBMMX]) dnl Default value
 813
 814 AC_ARG_ENABLE(atomic,
 815   AC_HELP_STRING([--enable-atomic],[use atomic reference counting header]),
 816 [case "${enableval}" in
 817   yes) USE_ATOMIC_H=$HAVE_ATOMIC_H;;
 818   noset) USE_ATOMIC_H=$HAVE_ATOMIC_H;;
 819   no)  USE_ATOMIC_H=no;;
 820   *) AC_MSG_ERROR(bad value ${enableval} for --enable-atomic) ;;
 821 esac],
 822 [USE_ATOMIC_H=$HAVE_ATOMIC_H]) dnl Default value
 823
 824 AC_ARG_ENABLE(profiling,
 825   AC_HELP_STRING([--enable-profiling],
 826                  [-pg to compiler commandline, for profiling]),
 827 [case "${enableval}" in
 828   yes) USE_PROFILING=yes ;;
 829   no)  UES_PROFILING=no ;;
 830   *) AC_MSG_ERROR(bad value ${enableval} for --enable-profiling) ;;
 831 esac],
 832 [USE_PROFILING=no]) dnl Default value
 833
 834 AC_ARG_ENABLE(tests,
 835   AC_HELP_STRING([--disable-tests],[disable building test apps]),
 836 [case "${enableval}" in
 837   yes) BUILD_TESTS=yes ;;
 838   no)  BUILD_TESTS=no ;;
 839   *) AC_MSG_ERROR(bad value ${enableval} for --disable-tests) ;;
 840 esac],
 841 [BUILD_TESTS=yes]) dnl Default value
 842
 843 AC_ARG_ENABLE(examples,
 844   AC_HELP_STRING([--disable-examples],[disable building examples]),
 845 [case "${enableval}" in
 846   yes) BUILD_EXAMPLES=yes ;;
 847   no)  BUILD_EXAMPLES=no ;;
 848   *) AC_MSG_ERROR(bad value ${enableval} for --disable-examples) ;;
 849 esac],
 850 [BUILD_EXAMPLES=yes]) dnl Default value
 851
 852 dnl seeking needs freetype, so check for it here
 853 AC_CHECK_FT2(2.0.9,HAVE_FT2=yes,HAVE_FT2=no)
 854 dnl make the HAVE_FT2 variable available to automake and Makefile.am
 855 AM_CONDITIONAL(HAVE_FT2, test "x$HAVE_FT2" = "xyes")
 856 AC_SUBST(FT2_CFLAGS)
 857 AC_SUBST(FT2_LIBS)
 858
 859 dnl ################################################
 860 dnl # Set defines according to variables set above #
 861 dnl ################################################
 862
 863
 864 if test "x$USE_LIBMMX" = xyes; then
 865   AC_DEFINE(HAVE_LIBMMX, 1, [Define if libmmx is available])
 866 fi
 867
 868 if test "x$USE_ATOMIC_H" = xyes; then
 869   AC_DEFINE(HAVE_ATOMIC_H, 1, [Define if atomic.h header file is available])
 870 fi
 871
 872 if test "x$USE_DEBUG" = xyes; then
 873   GST_CFLAGS="$GST_CFLAGS -g"
 874 fi
 875
 876 if test "x$USE_PROFILING" = xyes; then
 877 dnl  CFLAGS="$CFLAGS -pg -fprofile-arcs"
 878   FOMIT_FRAME_POINTER=""
 879 else
 880   FOMIT_FRAME_POINTER="-fomit-frame-pointer"
 881 fi
 882
 883 dnl
 884 dnl AC_SUBST(FOMIT_FRAME_POINTER)
 885 dnl
 886
 887 dnl #############################
 888 dnl # Set automake conditionals #
 889 dnl #############################
 890
 891 dnl These should be "USE_*" instead of "HAVE_*", but some packages expect
 892 dnl HAVE_ and it is likely to be easier to stick with the old name
 893 AM_CONDITIONAL(HAVE_CPU_I386,       test "x$HAVE_CPU_I386" = "xyes")
 894 AM_CONDITIONAL(HAVE_CPU_PPC,        test "x$HAVE_CPU_PPC" = "xyes")
 895 AM_CONDITIONAL(HAVE_CPU_ALPHA,      test "x$HAVE_CPU_ALPHA" = "xyes")
 896 AM_CONDITIONAL(HAVE_CPU_ARM,        test "x$HAVE_CPU_ARM" = "xyes")
 897 AM_CONDITIONAL(HAVE_CPU_SPARC,      test "x$HAVE_CPU_SPARC" = "xyes")
 898 AM_CONDITIONAL(HAVE_LIBMMX,         test "x$USE_LIBMMX" = "xyes")
 899
 900 AM_CONDITIONAL(HAVE_ATOMIC_H,       test "x$USE_ATOMIC_H" = "xyes")
 901
 902 AM_CONDITIONAL(EXPERIMENTAL,        test "$EXPERIMENTAL" = "$xyes")
 903 AM_CONDITIONAL(BROKEN,              test "$BROKEN" = "$xyes")
 904
 905 AM_CONDITIONAL(HAVE_NASM,           test "x$HAVE_NASM" = "xyes")
 906 AM_CONDITIONAL(HAVE_GTK,            test "x$HAVE_GTK" = "xyes")
 907 AM_CONDITIONAL(HAVE_GTK_DOC,        $HAVE_GTK_DOC)
 908 AM_CONDITIONAL(BUILD_DOCS,          test "x$BUILD_DOCS" = "xyes")
 909 AM_CONDITIONAL(BUILD_TESTS,         test "x$BUILD_TESTS" = "xyes")
 910 AM_CONDITIONAL(BUILD_EXAMPLES,      test "x$BUILD_EXAMPLES" = "xyes")
 911 AM_CONDITIONAL(BUILD_PLUGIN_DOCS,   test "x$BUILD_PLUGIN_DOCS" = "xyes")
 912 AM_CONDITIONAL(HAVE_FIG2DEV_PNG,    $HAVE_FIG2DEV_PNG)
 913 AM_CONDITIONAL(HAVE_FIG2DEV_PDF,    $HAVE_FIG2DEV_PDF)
 914 AM_CONDITIONAL(HAVE_RAW1394,        test "x$HAVE_RAW1394" = "xyes")
 915
 916 GST_CFLAGS="$GST_CFLAGS -I\$(top_srcdir)/gst-libs $GST_ERROR"
 917 AC_SUBST(GST_LIBS)
 918 AC_SUBST(GST_CFLAGS)
 919
 920 dnl #########################
 921 dnl # Make the output files #
 922 dnl #########################
 923
 924 AC_CONFIG_FILES(
 925 Makefile
 926 gstreamer-libs.pc
 927 gstreamer-libs-uninstalled.pc
 928 gst-plugins.spec
 929 gst/Makefile
 930 gst/ac3parse/Makefile
 931 gst/adder/Makefile
 932 gst/audioscale/Makefile
 933 gst/auparse/Makefile
 934 gst/avi/Makefile
 935 gst/cdxaparse/Makefile
 936 gst/chart/Makefile
 937 gst/cutter/Makefile
 938 gst/deinterlace/Makefile
 939 gst/effectv/Makefile
 940 gst/festival/Makefile
 941 gst/filter/Makefile
 942 gst/flx/Makefile
 943 gst/goom/Makefile
 944 gst/intfloat/Makefile
 945 gst/law/Makefile
 946 gst/level/Makefile
 947 gst/median/Makefile
 948 gst/mixmatrix/Makefile
 949 gst/mpeg1enc/Makefile
 950 gst/mpeg1sys/Makefile
 951 gst/mpeg1videoparse/Makefile
 952 gst/mpeg2enc/Makefile
 953 gst/mpeg2sub/Makefile
 954 gst/mpegaudio/Makefile
 955 gst/mpegaudioparse/Makefile
 956 gst/mpegstream/Makefile
 957 gst/mpegtypes/Makefile
 958 gst/modplug/Makefile
 959 gst/modplug/libmodplug/Makefile
 960 gst/monoscope/Makefile
 961 gst/passthrough/Makefile
 962 gst/playondemand/Makefile
 963 gst/qtdemux/Makefile
 964 gst/rtjpeg/Makefile
 965 gst/silence/Makefile
 966 gst/sine/Makefile
 967 gst/smooth/Makefile
 968 gst/spectrum/Makefile
 969 gst/speed/Makefile
 970 gst/stereo/Makefile
 971 gst/stereomono/Makefile
 972 gst/synaesthesia/Makefile
 973 gst/udp/Makefile
 974 gst/videoscale/Makefile
 975 gst/videotestsrc/Makefile
 976 gst/videocrop/Makefile
 977 gst/volenv/Makefile
 978 gst/volume/Makefile
 979 gst/vumeter/Makefile
 980 gst/wavenc/Makefile
 981 gst/wavparse/Makefile
 982 gst/y4m/Makefile
 983 sys/Makefile
 984 sys/cdrom/Makefile
 985 sys/dxr3/Makefile
 986 sys/oss/Makefile
 987 sys/qcam/Makefile
 988 sys/v4l/Makefile
 989 sys/v4l2/Makefile
 990 sys/vcd/Makefile
 991 sys/vga/Makefile
 992 sys/xvideo/Makefile
 993 sys/videosink/Makefile
 994 ext/Makefile
 995 ext/a52dec/Makefile
 996 ext/aalib/Makefile
 997 ext/alsa/Makefile
 998 ext/arts/Makefile
 999 ext/artsd/Makefile
1000 ext/audiofile/Makefile
1001 ext/avifile/Makefile
1002 ext/cdparanoia/Makefile
1003 ext/dv/Makefile
1004 ext/dvdread/Makefile
1005 ext/dvdnav/Makefile
1006 ext/esd/Makefile
1007 ext/ffmpeg/Makefile
1008 ext/flac/Makefile
1009 ext/gnomevfs/Makefile
1010 ext/gsm/Makefile
1011 ext/hermes/Makefile
1012 ext/http/Makefile
1013 ext/jack/Makefile
1014 ext/jpeg/Makefile
1015 ext/ladspa/Makefile
1016 ext/lame/Makefile
1017 ext/lcs/Makefile
1018 ext/libfame/Makefile
1019 ext/mad/Makefile
1020 ext/mikmod/Makefile
1021 ext/mjpegtools/Makefile
1022 ext/mpeg2dec/Makefile
1023 ext/openquicktime/Makefile
1024 ext/raw1394/Makefile
1025 ext/rtp/Makefile
1026 ext/sdl/Makefile
1027 ext/shout/Makefile
1028 ext/sidplay/Makefile
1029 ext/smoothwave/Makefile
1030 ext/snapshot/Makefile
1031 ext/swfdec/Makefile
1032 ext/vorbis/Makefile
1033 ext/tarkin/Makefile
1034 ext/xmms/Makefile
1035 gst-libs/Makefile
1036 gst-libs/gst/Makefile
1037 gst-libs/gst/audio/Makefile
1038 gst-libs/gst/floatcast/Makefile
1039 gst-libs/gst/gconf/Makefile
1040 gst-libs/gst/idct/Makefile
1041 gst-libs/gst/resample/Makefile
1042 gst-libs/gst/riff/Makefile
1043 gst-libs/gst/video/Makefile
1044 examples/dynparams/Makefile
1045 examples/capsfilter/Makefile
1046 examples/seeking/Makefile
1047 examples/Makefile
1048 testsuite/autoplug/Makefile
1049 testsuite/spider/Makefile
1050 testsuite/Makefile
1051 tools/Makefile
1052 gconf/Makefile
1053 )
1054
1055 AC_OUTPUT
1056
1057 echo -e "configure: *** Plug-ins that will be built : $GST_PLUGINS_YES"
1058 echo
1059 echo -e "configure: *** Plug-ins that will not be built : $GST_PLUGINS_NO"
1060 echo
1061 if test "x$BUILD_EXTERNAL" = "xno"; then
1062   echo "configure: *** No external plug-ins will be built"
1063 fi