configure.ac

   1 dnl autoconf configuration file for gst-plugins
   2 AC_INIT
   3 AC_CANONICAL_TARGET
   4
   5 dnl We disable static building for development, for time savings
   6 dnl this goes before AS_LIBTOOL to appease autoconf
   7 dnl *NOTE*: dnl this line before release, so release does static too
   8 AM_DISABLE_STATIC
   9
  10 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  11 AM_MAINTAINER_MODE
  12
  13 dnl when going to/from release please set the nano (fourth number) right !
  14 dnl releases only do Wall, cvs and prerelease does Werror too
  15 AS_VERSION(gst-plugins-base, GST_PLUGINS_BASE_VERSION, 0, 9, 2, 1,
  16     GST_CVS="no", GST_CVS="yes")
  17
  18 AM_INIT_AUTOMAKE($PACKAGE,$VERSION)
  19
  20 dnl our libraries and install dirs use major.minor as a version
  21 GST_MAJORMINOR=$GST_PLUGINS_BASE_VERSION_MAJOR.$GST_PLUGINS_BASE_VERSION_MINOR
  22 dnl we override it here if we need to for the release candidate of new series
  23 GST_MAJORMINOR=0.9
  24 AC_SUBST(GST_MAJORMINOR)
  25
  26 dnl CURRENT, REVISION, AGE
  27 dnl - library source changed -> increment REVISION
  28 dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
  29 dnl - interfaces added -> increment AGE
  30 dnl - interfaces removed -> AGE = 0
  31 AS_LIBTOOL(GST_PLUGINS, 1, 0, 1)
  32 AS_LIBTOOL_TAGS([])
  33 AM_PROG_LIBTOOL
  34
  35 dnl FIXME take something else ?
  36 AC_CONFIG_SRCDIR([gst/sine/gstsinesrc.c])
  37 AM_CONFIG_HEADER(config.h)
  38
  39 dnl Add parameters for aclocal
  40 dnl (This must come after AM_INIT_AUTOMAKE, since it modifies ACLOCAL)
  41 ACLOCAL_FLAGS="-I m4 -I common/m4"
  42 AC_SUBST(ACLOCAL_AMFLAGS, $ACLOCAL_FLAGS)
  43
  44 AC_PROG_CC
  45 AM_PROG_CC_STDC
  46 AM_PROG_AS
  47 AS="${CC}"
  48 AS_PROG_OBJC
  49
  50 dnl the gettext stuff needed
  51 AM_GNU_GETTEXT_VERSION(0.11.5)
  52 AM_GNU_GETTEXT([external])
  53
  54 GETTEXT_PACKAGE=gst-plugins-base-$GST_MAJORMINOR
  55 AC_SUBST(GETTEXT_PACKAGE)
  56 AC_DEFINE_UNQUOTED([GETTEXT_PACKAGE], "$GETTEXT_PACKAGE",
  57                    [gettext package name])
  58
  59 dnl define LOCALEDIR in config.h
  60 AS_AC_EXPAND(LOCALEDIR, $datadir/locale)
  61 AC_DEFINE_UNQUOTED([LOCALEDIR], "$LOCALEDIR",
  62                    [gettext locale dir])
  63
  64 GST_SET_ERROR_CFLAGS($GST_CVS)
  65
  66 dnl determine c++ compiler
  67 AC_PROG_CXX
  68 dnl determine if c++ is available on this system
  69 AC_CHECK_PROG(HAVE_CXX, $CXX, yes, no)
  70 dnl determine c++ preprocessor
  71 AC_PROG_CXXCPP
  72 AC_ISC_POSIX
  73
  74 AC_HEADER_STDC([])
  75 AC_C_INLINE
  76 AX_CREATE_STDINT_H
  77
  78 dnl Check for malloc.h
  79 AC_CHECK_HEADER(malloc.h,[
  80   AC_DEFINE(HAVE_MALLOC_H, 1, [whether malloc.h available])
  81 ])
  82
  83 dnl Check for a way to display the function name in debug output
  84 GST_CHECK_FUNCTION()
  85
  86 dnl define correct errorlevel for debugging messages. We want to have GST_ERROR
  87 dnl messages printed when running cvs builds
  88 if test "x$GST_CVS" = "xyes"; then
  89   AC_DEFINE(GST_LEVEL_DEFAULT, GST_LEVEL_ERROR, [Default errorlevel to use])
  90 fi
  91
  92 dnl Check for FIONREAD ioctl declaration :
  93 GST_CHECK_FIONREAD()
  94
  95 DEFAULT_AUDIOSINK="alsasink"
  96 DEFAULT_VIDEOSINK="xvimagesink"
  97 DEFAULT_AUDIOSRC="alsasrc"
  98 DEFAULT_VIDEOSRC="v4lsrc"
  99 DEFAULT_VISUALIZER="goom"
 100 case "$host" in
 101   *-sun-* | *pc-solaris* )
 102     DEFAULT_AUDIOSINK="sunaudiosink"
 103     DEFAULT_VIDEOSINK="ximagesink"
 104     DEFAULT_AUDIOSRC="sunaudiosrc"
 105     ;;
 106   *-darwin* )
 107     DEFAULT_AUDIOSINK="osxaudiosink"
 108     DEFAULT_AUDIOSRC="osxaudiosrc"
 109     DEFAULT_VIDEOSINK="osxvideosink"
 110     ;;
 111 esac
 112
 113 AC_SUBST(DEFAULT_AUDIOSINK)
 114 AC_DEFINE_UNQUOTED(DEFAULT_AUDIOSINK,"$DEFAULT_AUDIOSINK",[Default audio sink])
 115 AC_SUBST(DEFAULT_AUDIOSRC)
 116 AC_DEFINE_UNQUOTED(DEFAULT_AUDIOSRC,"$DEFAULT_AUDIOSRC",[Default audio source])
 117 AC_SUBST(DEFAULT_VIDEOSINK)
 118 AC_DEFINE_UNQUOTED(DEFAULT_VIDEOSINK,"$DEFAULT_VIDEOSINK",[Default video sink])
 119 AC_SUBST(DEFAULT_VIDEOSRC)
 120 AC_DEFINE_UNQUOTED(DEFAULT_VIDEOSRC,"$DEFAULT_VIDEOSRC",[Default video source])
 121 AC_SUBST(DEFAULT_VISUALIZER)
 122 AC_DEFINE_UNQUOTED(DEFAULT_VISUALIZER,"$DEFAULT_VISUALIZER",[Default visualizer])
 123
 124 dnl ############################################
 125 dnl # Super Duper options for plug-in building #
 126 dnl ############################################
 127
 128 dnl ext plug-ins; plug-ins that have external dependencies
 129 GST_CHECK_FEATURE(EXTERNAL, [enable building of plug-ins with external deps],,
 130 [HAVE_EXTERNAL=yes],enabled,
 131 [
 132   AC_MSG_WARN(building external plug-ins)
 133   BUILD_EXTERNAL="yes"
 134 ],[
 135   AC_MSG_WARN(all plug-ins with external dependencies will not be built)
 136   BUILD_EXTERNAL="no"
 137 ])
 138 # make BUILD_EXTERNAL available to Makefile.am
 139 AM_CONDITIONAL(BUILD_EXTERNAL, test "x$BUILD_EXTERNAL" = "xyes")
 140
 141 dnl experimental plug-ins; stuff that hasn't had the dust settle yet
 142 dnl read 'builds, but might not work'UTO
 143 GST_CHECK_FEATURE(EXPERIMENTAL, [enable building of experimental plug-ins],,
 144 [HAVE_EXPERIMENTAL=yes],disabled,
 145 [
 146   AC_MSG_WARN(building experimental plug-ins)
 147   USE_TARKIN="yes"
 148 ],[
 149   AC_MSG_NOTICE(not building experimental plug-ins)
 150   USE_TARKIN="no"
 151 ])
 152
 153 dnl broken plug-ins; stuff that doesn't seem to build at the moment
 154 GST_CHECK_FEATURE(BROKEN, [enable building of broken plug-ins],,
 155 HAVE_BROKEN=yes,disabled,
 156 [
 157   AC_MSG_WARN([building broken plug-ins -- no bug reports on these, only patches :)])
 158 ],[
 159   AC_MSG_NOTICE([not building broken plug-ins])
 160 ])
 161
 162 dnl ##############################
 163 dnl # Do automated configuration #
 164 dnl ##############################
 165
 166 dnl Check for tools:
 167 dnl ================
 168
 169 dnl allow for different autotools
 170 AS_AUTOTOOLS_ALTERNATE()
 171
 172 dnl modify pkg-config path
 173 AC_ARG_WITH(pkg-config-path,
 174    AC_HELP_STRING([--with-pkg-config-path],[colon-separated list of pkg-config(1) dirs]),
 175    [export PKG_CONFIG_PATH=${withval}])
 176
 177 dnl check architecture
 178 GST_ARCH()
 179
 180 dnl check for gstreamer
 181 dnl uninstalled is selected preferentially -- see pkg-config(1)
 182 GST_REQ=0.9.0
 183 PKG_CHECK_MODULES(GST, gstreamer-$GST_MAJORMINOR >= $GST_REQ,
 184   HAVE_GST="yes", HAVE_GST="no")
 185
 186 if test "x$HAVE_GST" = "xno"; then
 187   AC_MSG_ERROR(no GStreamer found)
 188 fi
 189
 190 GST_TOOLS_DIR=`pkg-config --variable=toolsdir gstreamer-$GST_MAJORMINOR`
 191 if test -z $GST_TOOLS_DIR; then
 192   AC_MSG_ERROR([no tools dir defined in GStreamer pkg-config file; core upgrade needed.])
 193 fi
 194 AC_SUBST(GST_TOOLS_DIR)
 195
 196 GST_PLUGINS_DIR=`pkg-config --variable=pluginsdir gstreamer-$GST_MAJORMINOR`
 197 if test -z $GST_PLUGINS_DIR; then
 198   AC_MSG_ERROR([no plugins dir defined in GStreamer pkg-config file; core upgrade needed.])
 199 fi
 200 AC_SUBST(GST_PLUGINS_DIR)
 201
 202
 203 dnl check for gstreamer-dataprotocol; uninstalled is selected preferentially
 204 PKG_CHECK_MODULES(GST_GDP, gstreamer-dataprotocol-$GST_MAJORMINOR >= $GST_REQ,
 205   HAVE_GST_GDP="yes", HAVE_GST_GDP="no")
 206
 207 if test "x$HAVE_GST_GDP" = "xno"; then
 208   AC_MSG_ERROR(no GStreamer Dataprotocol Libs found)
 209 fi
 210
 211 AC_SUBST(GST_GDP_LIBS)
 212
 213 dnl check for gstreamer-controller; uninstalled is selected preferentially
 214 PKG_CHECK_MODULES(GST_CTRL, gstreamer-controller-$GST_MAJORMINOR >= $GST_REQ,
 215   HAVE_GST_CTRL="yes", HAVE_GST_CTRL="no")
 216
 217 if test "x$HAVE_GST_CTRL" = "xno"; then
 218   AC_MSG_ERROR(no GStreamer Controller Libs found)
 219 fi
 220
 221 AC_SUBST(GST_CTRL_LIBS)
 222
 223 PKG_CHECK_MODULES(GST_BASE, gstreamer-base-$GST_MAJORMINOR >= $GST_REQ,
 224   HAVE_GST_BASE="yes", HAVE_GST_BASE="no")
 225
 226 if test "x$HAVE_GST_BASE" = "xno"; then
 227   AC_MSG_ERROR(no libgstbase found)
 228 fi
 229
 230 AC_SUBST(GST_BASE_LIBS)
 231
 232 PKG_CHECK_MODULES(GST_CHECK, gstreamer-check-$GST_MAJORMINOR >= $GST_REQ,
 233   HAVE_GST_CHECK="yes", HAVE_GST_CHECK="no")
 234
 235 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 236 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 237
 238 dnl Determine endianness
 239 AC_C_BIGENDIAN
 240
 241 dnl Check for fast float to int casting as defined in C99
 242 AC_C99_FUNC_LRINT()
 243 AC_C99_FUNC_LRINTF()
 244
 245 dnl Check for essential libraries first:
 246 dnl ====================================
 247
 248 GST_GLIB2_CHECK()
 249
 250 dnl Check for additional libraries that we might use:
 251 dnl =================================================
 252 dnl GTK
 253 HAVE_GTK=NO
 254 PKG_CHECK_MODULES(GTK2, gtk+-2.0 >= 2.2.0, HAVE_GTK_22=yes, HAVE_GTK_22=no)
 255 if test "x$HAVE_GTK_22" = "xyes"; then
 256   HAVE_GTK=yes
 257   GTK_VERSION=`$PKG_CONFIG --variable=gtk_binary_version gtk+-2.0`
 258   AC_SUBST(GTK_VERSION)
 259   GTK_PREFIX=`$PKG_CONFIG --variable=prefix gdk-pixbuf-2.0`
 260   AC_SUBST(GTK_BASE_DIR)
 261 else
 262   PKG_CHECK_MODULES(GTK2, gtk+-2.0, HAVE_GTK_20=yes, HAVE_GTK_20=no)
 263 fi
 264 if test "x$HAVE_GTK_20" = "xyes"; then
 265   HAVE_GTK=yes
 266 fi
 267 GTK_CFLAGS=$GTK2_CFLAGS
 268 GTK_LIBS=$GTK2_LIBS
 269 AC_SUBST(GTK_LIBS)
 270 AC_SUBST(GTK_CFLAGS)
 271 AC_SUBST(HAVE_GTK)
 272
 273 PKG_CHECK_MODULES(LIBOIL, liboil-0.3 >= 0.3.2, HAVE_LIBOIL=yes, HAVE_LIBOIL=no)
 274 AC_SUBST(LIBOIL_CFLAGS)
 275 AC_SUBST(LIBOIL_LIBS)
 276 if test "x${HAVE_LIBOIL}" != xyes ; then
 277   AC_ERROR([liboil-0.3 is required])
 278 fi
 279
 280 dnl ===========================================================================
 281 dnl ============================= gst plug-ins ================================
 282 dnl ===========================================================================
 283
 284 plugindir="\$(libdir)/gstreamer-$GST_MAJORMINOR"
 285 AC_SUBST(plugindir)
 286
 287 dnl this really should only contain flags, not libs - they get added before
 288 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 289 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc\$' -no-undefined"
 290 AC_SUBST(GST_PLUGIN_LDFLAGS)
 291
 292 dnl these are all the gst plug-ins, compilable without additional libs
 293 GST_PLUGINS_ALL="\
 294         adder \
 295         audioconvert \
 296         audiorate \
 297         audioresample \
 298         ffmpegcolorspace \
 299         playback \
 300         sine \
 301         subparse \
 302         tcp \
 303         typefind \
 304         videotestsrc \
 305         videorate \
 306         videoscale \
 307         volume \
 308         "
 309
 310 dnl see if we can build C++ plug-ins
 311 if test "x$HAVE_CXX" = "xyes"; then
 312   GST_PLUGINS_ALL="$GST_PLUGINS_ALL"
 313 else
 314   AC_MSG_WARN([Not compiling plug-ins requiring C++ compiler])
 315 fi
 316
 317 AC_SUBST(GST_PLUGINS_ALL)
 318
 319 GST_PLUGINS_SELECTED=""
 320
 321 AC_ARG_WITH(plugins,
 322     AC_HELP_STRING([--with-plugins],[comma-separated list of plug-ins to compile]),
 323     [for i in `echo $withval | tr , ' '`; do
 324         if echo $GST_PLUGINS_ALL | grep $i > /dev/null
 325         then
 326             GST_PLUGINS_SELECTED="$GST_PLUGINS_SELECTED $i"
 327         else
 328             echo "plug-in $i not recognized, ignoring..."
 329         fi
 330     done],
 331     [GST_PLUGINS_SELECTED=$GST_PLUGINS_ALL])
 332
 333 AC_SUBST(GST_PLUGINS_SELECTED)
 334
 335 dnl ==========================================================================
 336 dnl ============================= sys plug-ins ================================
 337 dnl ==========================================================================
 338
 339 echo
 340 AC_MSG_NOTICE([Checking libraries for plugins in sys/])
 341 echo
 342
 343 dnl Check for X11
 344 translit(dnm, m, l) AM_CONDITIONAL(USE_X, true)
 345 GST_CHECK_FEATURE(X, [X libraries and plugins],
 346                   [ximagesink], [
 347   AC_PATH_XTRA
 348   ac_cflags_save="$CFLAGS"
 349   ac_cppflags_save="$CPPFLAGS"
 350   CFLAGS="$CFLAGS $X_CFLAGS"
 351   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 352
 353   dnl now try to find the HEADER
 354   AC_CHECK_HEADER(X11/Xlib.h, HAVE_X="yes", HAVE_X="no")
 355
 356   if test "x$HAVE_X" = "xno"
 357   then
 358     AC_MSG_NOTICE([cannot find X11 development files])
 359   else
 360     dnl this is much more than we want
 361     X_LIBS="$X_LIBS $X_PRE_LIBS $X_EXTRA_LIBS"
 362     dnl AC_PATH_XTRA only defines the path needed to find the X libs,
 363     dnl it does not add the libs; therefore we add them here
 364     X_LIBS="$X_LIBS -lX11"
 365     AC_SUBST(X_CFLAGS)
 366     AC_SUBST(X_LIBS)
 367   fi
 368   AC_SUBST(HAVE_X)
 369   CFLAGS="$ac_cflags_save"
 370   CPPFLAGS="$ac_cppflags_save"
 371 ])
 372
 373 dnl *** XVideo ***
 374 dnl Look for the PIC library first, Debian requires it.
 375 dnl Check debian-devel archives for gory details.
 376 dnl 20020110:
 377 dnl At the moment XFree86 doesn't distribute shared libXv due
 378 dnl to unstable API.  On many platforms you CAN NOT link a shared
 379 dnl lib to a static non-PIC lib.  This is what the xvideo GStreamer
 380 dnl plug-in wants to do.  So Debian distributes a PIC compiled
 381 dnl version of the static lib for plug-ins to link to when it is
 382 dnl inappropriate to link the main application to libXv directly.
 383 dnl FIXME: add check if this platform can support linking to a
 384 dnl        non-PIC libXv, if not then don not use Xv.
 385 dnl FIXME: perhaps warn user if they have a shared libXv since
 386 dnl        this is an error until XFree86 starts shipping one
 387
 388 dnl Check for Xv extension
 389 translit(dnm, m, l) AM_CONDITIONAL(USE_XVIDEO, true)
 390 GST_CHECK_FEATURE(XVIDEO, [X11 XVideo extensions],
 391                   [xvimagesink], [
 392   if test x$HAVE_X = xyes; then
 393     AC_CHECK_LIB(Xv_pic, XvQueryExtension,
 394                  HAVE_XVIDEO="yes", HAVE_XVIDEO="no",
 395                  $X_LIBS -lXext)
 396
 397     if test x$HAVE_XVIDEO = xyes; then
 398       XVIDEO_LIBS="-lXv_pic -lXext"
 399       AC_SUBST(XVIDEO_LIBS)
 400     else
 401       dnl try again using something else if we didn't find it first
 402       if test x$HAVE_XVIDEO = xno; then
 403         AC_CHECK_LIB(Xv, XvQueryExtension,
 404                    HAVE_XVIDEO="yes", HAVE_XVIDEO="no",
 405                    $X_LIBS -lXext)
 406
 407         if test x$HAVE_XVIDEO = xyes; then
 408           XVIDEO_LIBS="-lXv -lXext"
 409           AC_SUBST(XVIDEO_LIBS)
 410         fi
 411       fi
 412     fi
 413   fi
 414 ])
 415
 416 dnl check for X Shm
 417 translit(dnm, m, l) AM_CONDITIONAL(USE_XSHM, true)
 418 GST_CHECK_FEATURE(XSHM, [X Shared Memory extension], xshm, [
 419   if test x$HAVE_X = xyes; then
 420     AC_CHECK_LIB(Xext, XShmAttach,
 421                  HAVE_XSHM="yes", HAVE_XSHM="no",
 422                  $X_LIBS)
 423     if test "x$HAVE_XSHM" = "xyes"; then
 424       XSHM_LIBS="-lXext"
 425     else
 426       dnl On AIX, it is in XextSam instead, but we still need -lXext
 427       AC_CHECK_LIB(XextSam, XShmAttach,
 428                    HAVE_XSHM="yes", HAVE_XSHM="no",
 429                    $X_LIBS)
 430       if test "x$HAVE_XSHM" = "xyes"; then
 431         XSHM_LIBS="-lXext -lXextSam"
 432       fi
 433     fi
 434   fi
 435 ], , [
 436   AC_SUBST(HAVE_XSHM)
 437   AC_SUBST(XSHM_LIBS)
 438 ] )
 439
 440 dnl v4l/v4l2 checks have been moved down because they require X
 441
 442 dnl *** Video 4 Linux ***
 443 dnl for information about the header/define, see sys/v4l/gstv4lelement.h
 444 dnl renamed to GST_V4L in accordance with V4L2 below
 445 translit(dnm, m, l) AM_CONDITIONAL(USE_GST_V4L, true)
 446 GST_CHECK_FEATURE(GST_V4L, [Video 4 Linux], v4lsrc v4lmjpegsrc v4lmjpegsink, [
 447   # first check X
 448   HAVE_GST_V4L="no"
 449   if test "$HAVE_X" = "yes"
 450   then
 451     AC_CHECK_DECL(VID_TYPE_MPEG_ENCODER, HAVE_GST_V4L="yes", HAVE_GST_V4L="no", [
 452 #include <sys/types.h>
 453 #define _LINUX_TIME_H
 454 #define __user
 455 #include <linux/videodev.h>
 456     ])
 457   fi
 458 ])
 459
 460 dnl Next, check for the optional libraries:
 461 dnl These are all libraries used in building plug-ins
 462 dnl ================================================
 463 dnl let's try and sort them alphabetically, shall we ?
 464
 465 if test "x$BUILD_EXTERNAL" = "xyes"; then
 466
 467 echo
 468 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 469 echo
 470
 471 dnl *** alsa ***
 472 translit(dnm, m, l) AM_CONDITIONAL(USE_ALSA, true)
 473 GST_CHECK_FEATURE(ALSA, [alsa plug-ins], gstalsa, [
 474   PKG_CHECK_MODULES(ALSA, alsa >= 0.9.1, [
 475     HAVE_ALSA="yes"
 476     AC_SUBST(ALSA_CFLAGS)
 477     AC_SUBST(ALSA_LIBS)
 478   ], [
 479     AM_PATH_ALSA(0.9.1, HAVE_ALSA="yes", HAVE_ALSA="no")
 480   ])
 481 ])
 482
 483 dnl *** CDParanoia ***
 484 translit(dnm, m, l) AM_CONDITIONAL(USE_CDPARANOIA, true)
 485 GST_CHECK_FEATURE(CDPARANOIA, [CDParanoia], cdparanoia, [
 486   GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 487                       cdda_open, -lm,
 488                       cdda_interface.h,
 489                       CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 490                       HEADER_DIR="no"
 491                       FOUND_CDPARANOIA="yes")
 492   if test "x$FOUND_CDPARANOIA" != "xyes";
 493   then
 494     GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 495                         cdda_open, -lm,
 496                         cdda/cdda_interface.h,
 497                         CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 498                         HEADER_DIR="yes"
 499                         FOUND_CDPARANOIA="yes")
 500   fi
 501   if test "x$HEADER_DIR" = "xyes";
 502   then
 503     AC_DEFINE_UNQUOTED(CDPARANOIA_HEADERS_IN_DIR, ,
 504                        defined if cdda headers are in a cdda/ directory)
 505   fi
 506   AC_SUBST(CDPARANOIA_LIBS)
 507 ])
 508 dnl FIXME : add second check somehow if that is necessary
 509 dnl AC_CHECK_LIB(cdda_paranoia, paranoia_init, : , HAVE_CDPARANOIA=no, -lcdda_interface )
 510 dnl AC_CHECK_HEADER(cdda_paranoia.h, :, HAVE_CDPARANOIA=no)
 511
 512 dnl *** Gnome VFS ***
 513 translit(dnm, m, l) AM_CONDITIONAL(USE_GNOME_VFS, true)
 514 GST_CHECK_FEATURE(GNOME_VFS, [Gnome VFS], gnomevfssrc, [
 515   PKG_CHECK_MODULES(GNOME_VFS, gnome-vfs-2.0, HAVE_GNOME_VFS="yes", HAVE_GNOME_VFS="no")
 516   AC_SUBST(GNOME_VFS_CFLAGS)
 517   AC_SUBST(GNOME_VFS_LIBS)
 518 ])
 519
 520 dnl *** libvisual ***
 521 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBVISUAL, true)
 522 GST_CHECK_FEATURE(LIBVISUAL, [libvisual visualization plugins], libvisual, [
 523   PKG_CHECK_MODULES(LIBVISUAL, libvisual = 0.2.0, HAVE_LIBVISUAL="yes", HAVE_LIBVISUAL="no")
 524   AC_SUBST(LIBVISUAL_CFLAGS)
 525   AC_SUBST(LIBVISUAL_LIBS)
 526 ])
 527
 528 dnl *** ogg ***
 529 translit(dnm, m, l) AM_CONDITIONAL(USE_OGG, true)
 530 GST_CHECK_FEATURE(OGG, [ogg de/encoder], oggdemux oggmux, [
 531   PKG_CHECK_MODULES(OGG, ogg >= 1.0, [
 532     HAVE_OGG="yes"
 533     AC_SUBST(OGG_CFLAGS)
 534     AC_SUBST(OGG_LIBS)
 535   ], [
 536     XIPH_PATH_OGG(HAVE_OGG="yes", HAVE_OGG="no")
 537     AS_SCRUB_INCLUDE(OGG_CFLAGS)
 538   ])
 539 ])
 540
 541 dnl *** theora ***
 542 translit(dnm, m, l) AM_CONDITIONAL(USE_THEORA, true)
 543 GST_CHECK_FEATURE(THEORA, [ogg theora codec], theoradec theoraenc, [
 544   PKG_CHECK_MODULES(THEORA, theora, [
 545     HAVE_THEORA="yes"
 546     AC_SUBST(THEORA_LIBS)
 547     AC_SUBST(THEORA_CFLAGS)
 548   ], [
 549     GST_CHECK_LIBHEADER(THEORA, theora, theora_version_string, "-logg", theora/theora.h, THEORA_LIBS="-ltheora -logg")
 550     AC_SUBST(THEORA_LIBS)
 551   ])
 552 ])
 553
 554 dnl *** vorbis ***
 555 dnl AM_PATH_VORBIS only takes two options
 556 translit(dnm, m, l) AM_CONDITIONAL(USE_VORBIS, true)
 557 GST_CHECK_FEATURE(VORBIS, [vorbis plug-in], vorbisenc vorbisdec, [
 558   PKG_CHECK_MODULES(VORBIS, vorbis >= 1.0 vorbisenc >= 1.0, [
 559     HAVE_VORBIS="yes"
 560   ], [
 561     XIPH_PATH_VORBIS(HAVE_VORBIS="yes", HAVE_VORBIS="no")
 562     AS_SCRUB_INCLUDE(VORBIS_CFLAGS)
 563   ])
 564 ])
 565 if test "x$HAVE_VORBIS" = "xyes"; then
 566   ac_cflags_save="$CFLAGS"
 567   dnl FIXME: does this work on non-gcc? -- Company
 568   dnl FIXME: no, it doesn't.  Why is this here in the first place ? -- thomasvs
 569   CFLAGS="-Wall -Werror"
 570   AC_COMPILE_IFELSE(
 571     AC_LANG_PROGRAM([
 572 #include <vorbis/codec.h>
 573                      ],[
 574 vorbis_dsp_state *v;
 575
 576 vorbis_synthesis_restart (v);
 577                      ]), HAVE_VSR=yes, HAVE_VSR=no)
 578   if test "x$HAVE_VSR" = "xyes"; then
 579     AC_DEFINE_UNQUOTED(HAVE_VORBIS_SYNTHESIS_RESTART, 1,
 580                        [defined if vorbis_synthesis_restart is present])
 581   fi
 582   CFLAGS="$ac_cflags_save"
 583 fi
 584
 585 fi dnl of EXT plugins
 586
 587 dnl Check for atomic.h
 588 dnl Note: use AC_CHECK_HEADER not AC_CHECK_HEADERS, because the latter
 589 dnl defines the wrong default symbol as well (HAVE_ASM_ATOMIC_H)
 590 AC_CHECK_HEADER(asm/atomic.h, HAVE_ATOMIC_H=yes, HAVE_ATOMIC_H=no)
 591 dnl Do a compile to check that it has atomic_set (eg, linux 2.0 didn't)
 592 if test x$HAVE_ATOMIC_H = xyes; then
 593   AC_TRY_RUN([
 594 #include "asm/atomic.h"
 595 main() { atomic_t t; atomic_set(&t,0); atomic_inc(&t); atomic_add(1,&t);return 0;}
 596   ],, [
 597     # Not successful
 598     if test x$HAVE_ATOMIC_H = xyes; then
 599       AC_MSG_WARN(Atomic reference counting is out of date: doing without.)
 600     fi
 601     HAVE_ATOMIC_H=no
 602   ], [
 603     # Cross compiling
 604     AC_MSG_RESULT(yes)
 605     AC_MSG_WARN(Can't check properly for atomic reference counting.  Assuming OK.)
 606   ])
 607 fi
 608
 609 dnl check for "check", unit testing library/header
 610 AM_PATH_CHECK(0.9.2, HAVE_CHECK=yes, HAVE_CHECK=no)
 611 AM_CONDITIONAL(HAVE_CHECK, test "x$HAVE_CHECK" = "xyes")
 612
 613 dnl ######################################################################
 614 dnl # Check command line parameters, and set shell variables accordingly #
 615 dnl ######################################################################
 616
 617 AC_ARG_ENABLE(atomic,
 618   AC_HELP_STRING([--enable-atomic],[use atomic reference counting header]),
 619 [case "${enableval}" in
 620   yes) USE_ATOMIC_H=$HAVE_ATOMIC_H;;
 621   noset) USE_ATOMIC_H=$HAVE_ATOMIC_H;;
 622   no)  USE_ATOMIC_H=no;;
 623   *) AC_MSG_ERROR(bad value ${enableval} for --enable-atomic) ;;
 624 esac],
 625 [USE_ATOMIC_H=$HAVE_ATOMIC_H]) dnl Default value
 626
 627 AC_ARG_ENABLE(profiling,
 628   AC_HELP_STRING([--enable-profiling],
 629                  [-pg to compiler commandline, for profiling]),
 630 [case "${enableval}" in
 631   yes) USE_PROFILING=yes ;;
 632   no)  UES_PROFILING=no ;;
 633   *) AC_MSG_ERROR(bad value ${enableval} for --enable-profiling) ;;
 634 esac],
 635 [USE_PROFILING=no]) dnl Default value
 636
 637 AC_ARG_ENABLE(tests,
 638   AC_HELP_STRING([--disable-tests],[disable building test apps]),
 639 [case "${enableval}" in
 640   yes) BUILD_TESTS=yes ;;
 641   no)  BUILD_TESTS=no ;;
 642   *) AC_MSG_ERROR(bad value ${enableval} for --disable-tests) ;;
 643 esac],
 644 [BUILD_TESTS=yes]) dnl Default value
 645
 646 AC_ARG_ENABLE(examples,
 647   AC_HELP_STRING([--disable-examples],[disable building examples]),
 648 [case "${enableval}" in
 649   yes) BUILD_EXAMPLES=yes ;;
 650   no)  BUILD_EXAMPLES=no ;;
 651   *) AC_MSG_ERROR(bad value ${enableval} for --disable-examples) ;;
 652 esac],
 653 [BUILD_EXAMPLES=yes]) dnl Default value
 654
 655 dnl seeking needs freetype, so check for it here
 656 PKG_CHECK_MODULES(FT2, freetype2 >= 2.0.9, HAVE_FT2="yes", [
 657   AC_CHECK_FT2(2.0.9, HAVE_FT2="yes", HAVE_FT2="no")
 658 ])
 659 dnl make the HAVE_FT2 variable available to automake and Makefile.am
 660 AM_CONDITIONAL(HAVE_FT2, test "x$HAVE_FT2" = "xyes")
 661 AC_SUBST(FT2_CFLAGS)
 662 AC_SUBST(FT2_LIBS)
 663
 664 dnl ################################################
 665 dnl # Set defines according to variables set above #
 666 dnl ################################################
 667
 668
 669 if test "x$USE_ATOMIC_H" = xyes; then
 670   AC_DEFINE(HAVE_ATOMIC_H, 1, [Define if atomic.h header file is available])
 671 fi
 672
 673 # do not use deprecated stuff
 674 GST_CFLAGS="$GST_CFLAGS -DGST_DISABLE_DEPRECATED"
 675
 676 if test "x$USE_DEBUG" = xyes; then
 677   GST_CFLAGS="$GST_CFLAGS -g"
 678 fi
 679
 680 dnl ############################
 681 dnl # Checks for documentation #
 682 dnl ############################
 683
 684 GTK_DOC_CHECK([1.3])
 685 AS_PATH_PYTHON([2.1])
 686
 687 dnl #############################
 688 dnl # Set automake conditionals #
 689 dnl #############################
 690
 691 dnl These should be "USE_*" instead of "HAVE_*", but some packages expect
 692 dnl HAVE_ and it is likely to be easier to stick with the old name
 693 AM_CONDITIONAL(HAVE_ATOMIC_H,       test "x$USE_ATOMIC_H" = "xyes")
 694
 695 AM_CONDITIONAL(EXPERIMENTAL,        test "$EXPERIMENTAL" = "$xyes")
 696 AM_CONDITIONAL(BROKEN,              test "$BROKEN" = "$xyes")
 697
 698 AM_CONDITIONAL(HAVE_NASM,           test "x$HAVE_NASM" = "xyes")
 699 AM_CONDITIONAL(HAVE_GTK,            test "x$HAVE_GTK" = "xyes")
 700 AM_CONDITIONAL(BUILD_TESTS,         test "x$BUILD_TESTS" = "xyes")
 701 AM_CONDITIONAL(BUILD_EXAMPLES,      test "x$BUILD_EXAMPLES" = "xyes")
 702 AM_CONDITIONAL(HAVE_FIG2DEV_PNG,    $HAVE_FIG2DEV_PNG)
 703 AM_CONDITIONAL(HAVE_FIG2DEV_PDF,    $HAVE_FIG2DEV_PDF)
 704 AM_CONDITIONAL(HAVE_RAW1394,        test "x$HAVE_RAW1394" = "xyes")
 705
 706 dnl prefer internal headers to already installed ones
 707 dnl also add builddir include for enumtypes and marshal
 708 dnl add ERROR_CFLAGS, but overridable
 709 GST_CFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs $GST_CFLAGS \$(ERROR_CFLAGS)"
 710
 711 AC_SUBST(GST_LIBS)
 712 AC_SUBST(GST_CFLAGS)
 713
 714 dnl ###########################
 715 dnl # Configure external libs #
 716 dnl ###########################
 717
 718 dnl ############################
 719 dnl # Set up some more defines #
 720 dnl ############################
 721
 722 dnl set license and copyright notice
 723 AC_DEFINE(GST_LICENSE, "LGPL", [GStreamer license])
 724
 725 dnl package name in plugins
 726 AC_ARG_WITH(package-name,
 727 AC_HELP_STRING([--with-package-name],[specify package name to use in plugins]),
 728 [case "${withval}" in
 729   yes) AC_MSG_ERROR(bad value ${withval} for --with-package-name) ;;
 730   no) AC_MSG_ERROR(bad value ${withval} for --with-package-name) ;;
 731   *) GST_PACKAGE="${withval}" ;;
 732 esac],
 733 [
 734 dnl default value
 735 if test "x$GST_CVS" = "xyes"
 736 then
 737   dnl nano >= 1
 738   GST_PACKAGE="GStreamer CVS/prerelease"
 739 else
 740   GST_PACKAGE="GStreamer source release"
 741 fi
 742 ]
 743 )
 744 AC_MSG_NOTICE(Using $GST_PACKAGE as package name)
 745 AC_DEFINE_UNQUOTED(GST_PACKAGE, "$GST_PACKAGE", [package name in plugins])
 746
 747 dnl package origin URL
 748 AC_ARG_WITH(package-origin,
 749 AC_HELP_STRING([--with-package-origin],[specify package origin URL to use in plugins]),
 750 [case "${withval}" in
 751   yes) AC_MSG_ERROR(bad value ${withval} for --with-package-origin) ;;
 752   no) AC_MSG_ERROR(bad value ${withval} for --with-package-origin) ;;
 753   *) GST_ORIGIN="${withval}" ;;
 754 esac],
 755 [GST_ORIGIN="http://gstreamer.freedesktop.org/"]) dnl Default value
 756 AC_MSG_NOTICE(Using $GST_ORIGIN as package origin)
 757 AC_DEFINE_UNQUOTED(GST_ORIGIN, "$GST_ORIGIN", [package origin])
 758
 759 dnl #########################
 760 dnl # Make the output files #
 761 dnl #########################
 762
 763 AC_CONFIG_FILES(
 764 Makefile
 765 gst-plugins-base.spec
 766 gst/Makefile
 767 gst/adder/Makefile
 768 gst/audioconvert/Makefile
 769 gst/audiorate/Makefile
 770 gst/audioresample/Makefile
 771 gst/ffmpegcolorspace/Makefile
 772 gst/playback/Makefile
 773 gst/sine/Makefile
 774 gst/subparse/Makefile
 775 gst/tcp/Makefile
 776 gst/typefind/Makefile
 777 gst/videotestsrc/Makefile
 778 gst/videorate/Makefile
 779 gst/videoscale/Makefile
 780 gst/volume/Makefile
 781 sys/Makefile
 782 sys/ximage/Makefile
 783 sys/xvimage/Makefile
 784 sys/v4l/Makefile
 785 ext/Makefile
 786 ext/alsa/Makefile
 787 ext/cdparanoia/Makefile
 788 ext/gnomevfs/Makefile
 789 ext/libvisual/Makefile
 790 ext/ogg/Makefile
 791 ext/theora/Makefile
 792 ext/vorbis/Makefile
 793 gst-libs/Makefile
 794 gst-libs/gst/Makefile
 795 gst-libs/gst/audio/Makefile
 796 gst-libs/gst/floatcast/Makefile
 797 gst-libs/gst/interfaces/Makefile
 798 gst-libs/gst/net/Makefile
 799 gst-libs/gst/riff/Makefile
 800 gst-libs/gst/rtp/Makefile
 801 gst-libs/gst/tag/Makefile
 802 gst-libs/gst/video/Makefile
 803 gst-libs/ext/Makefile
 804 examples/seeking/Makefile
 805 examples/Makefile
 806 tools/Makefile
 807 pkgconfig/Makefile
 808 pkgconfig/gstreamer-plugins-base.pc
 809 pkgconfig/gstreamer-plugins-base-uninstalled.pc
 810 check/Makefile
 811 docs/Makefile
 812 docs/libs/Makefile
 813 docs/plugins/Makefile
 814 docs/version.entities
 815 po/Makefile.in
 816 common/Makefile
 817 common/m4/Makefile
 818 m4/Makefile
 819 )
 820 AC_OUTPUT
 821
 822 echo "configure: *** Core plug-ins, always built:"
 823 ( for i in $GST_PLUGINS_ALL; do echo -e '\t'$i; done ) | sort
 824 echo
 825 echo -n "configure: *** Plug-ins relying on libraries that will be built:"
 826 echo -e "$GST_PLUGINS_YES" | sort
 827 echo
 828 echo -n "configure: *** Plug-ins relying on libraries that will NOT be built:"
 829 echo -e "$GST_PLUGINS_NO" | sort
 830 echo
 831 if test "x$BUILD_EXTERNAL" = "xno"; then
 832   echo "configure: *** No external plug-ins will be built"
 833 fi