configure.ac

   1 AC_PREREQ(2.52)
   2
   3 dnl initialize autoconf
   4 dnl when going to/from release please set the nano (fourth number) right !
   5 dnl releases only do Wall, cvs and prerelease does Werror too
   6 AC_INIT(GStreamer Base Plug-ins, 0.10.6,
   7     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
   8     gst-plugins-base)
   9
  10 dnl initialize automake
  11 AM_INIT_AUTOMAKE
  12
  13 dnl define PACKAGE_VERSION_* variables
  14 AS_VERSION
  15
  16 dnl check if this is a release version
  17 AS_NANO(GST_CVS="no", GST_CVS="yes")
  18
  19 dnl can autoconf find the source ?
  20 AC_CONFIG_SRCDIR([gst/audiotestsrc/gstaudiotestsrc.c])
  21
  22 dnl define the output header for config
  23 AM_CONFIG_HEADER([config.h])
  24
  25 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  26 AM_MAINTAINER_MODE
  27
  28 dnl sets host_* variables
  29 AC_CANONICAL_HOST
  30
  31 dnl our libraries and install dirs use major.minor as a version
  32 GST_MAJORMINOR=$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR
  33 dnl we override it here if we need to for the release candidate of new series
  34 GST_MAJORMINOR=0.10
  35 AC_SUBST(GST_MAJORMINOR)
  36
  37 dnl CURRENT, REVISION, AGE
  38 dnl - library source changed -> increment REVISION
  39 dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
  40 dnl - interfaces added -> increment AGE
  41 dnl - interfaces removed -> AGE = 0
  42 dnl sets GST_LT_LDFLAGS
  43 AS_LIBTOOL(GST, 4, 0, 4)
  44
  45 dnl FIXME: this macro doesn't actually work;
  46 dnl the generated libtool script has no support for the listed tags.
  47 dnl So this needs to be fixed first if we want to use this
  48 dnl AS_LIBTOOL_TAGS
  49
  50 AM_PROG_LIBTOOL
  51
  52 dnl *** required versions of GStreamer stuff ***
  53 GST_REQ=0.10.4.1
  54
  55 dnl *** autotools stuff ****
  56
  57 dnl allow for different autotools
  58 AS_AUTOTOOLS_ALTERNATE
  59
  60 dnl Add parameters for aclocal
  61 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  62
  63 dnl set up gettext
  64 dnl the version check needs to stay here because autopoint greps for it
  65 AM_GNU_GETTEXT_VERSION([0.11.5])
  66 AM_GNU_GETTEXT([external])
  67 GST_GETTEXT([gst-plugins-base-$GST_MAJORMINOR])
  68
  69 dnl *** check for arguments to configure ***
  70
  71 GST_ARG_DEBUG
  72 GST_ARG_PROFILING
  73 GST_ARG_VALGRIND
  74 GST_ARG_GCOV
  75
  76 GST_ARG_EXAMPLES
  77
  78 GST_ARG_WITH_PKG_CONFIG_PATH
  79 GST_ARG_WITH_PACKAGE_NAME
  80 GST_ARG_WITH_PACKAGE_ORIGIN
  81
  82 dnl these are all the gst plug-ins, compilable without additional libs
  83 GST_PLUGINS_ALL="\
  84         adder \
  85         audioconvert \
  86         audiorate \
  87         audioresample \
  88         audiotestsrc \
  89         ffmpegcolorspace \
  90         playback \
  91         typefind \
  92         videotestsrc \
  93         videorate \
  94         videoscale \
  95         volume \
  96         "
  97 AC_SUBST(GST_PLUGINS_ALL)
  98
  99 GST_PLUGINS_SELECTED=""
 100
 101 AC_ARG_WITH(plugins,
 102     AC_HELP_STRING([--with-plugins],
 103       [comma-separated list of plug-ins to compile]),
 104     [for i in `echo $withval | tr , ' '`; do
 105         if echo $GST_PLUGINS_ALL | grep $i > /dev/null
 106         then
 107             GST_PLUGINS_SELECTED="$GST_PLUGINS_SELECTED $i"
 108         else
 109             echo "plug-in $i not recognized, ignoring..."
 110         fi
 111     done],
 112     [GST_PLUGINS_SELECTED=$GST_PLUGINS_ALL])
 113
 114 AC_SUBST(GST_PLUGINS_SELECTED)
 115
 116 dnl ext plug-ins; plug-ins that have external dependencies
 117 GST_CHECK_FEATURE(EXTERNAL, [enable building of plug-ins with external deps],,
 118   [HAVE_EXTERNAL=yes], enabled,
 119   [
 120     AC_MSG_NOTICE(building external plug-ins)
 121     BUILD_EXTERNAL="yes"
 122   ],[
 123     AC_MSG_NOTICE(all plug-ins with external dependencies will not be built)
 124     BUILD_EXTERNAL="no"
 125   ])
 126 AM_CONDITIONAL(BUILD_EXTERNAL, test "x$BUILD_EXTERNAL" = "xyes")
 127
 128 dnl *** checks for platform ***
 129
 130 dnl * hardware/architecture *
 131
 132 dnl common/m4/gst-arch.m4
 133 dnl check CPU type
 134 GST_ARCH
 135
 136 dnl *** checks for programs ***
 137
 138 dnl find a compiler
 139 AC_PROG_CC
 140
 141 dnl determine c++ compiler
 142 AC_PROG_CXX
 143 dnl determine if c++ is available on this system
 144 AC_CHECK_PROG(HAVE_CXX, $CXX, yes, no)
 145
 146 dnl determine c++ preprocessor
 147 dnl FIXME: do we need this ?
 148 AC_PROG_CXXCPP
 149
 150 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 151 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 152
 153 dnl check for documentation tools
 154 GTK_DOC_CHECK([1.3])
 155 AS_PATH_PYTHON([2.1])
 156
 157 dnl *** checks for libraries ***
 158
 159 dnl For interactive UNIX (a Sun thing)
 160 dnl FIXME: this adds -lcposix to LIBS, but I doubt we use LIBS
 161 AC_ISC_POSIX
 162
 163 dnl *** checks for header files ***
 164
 165 dnl check if we have ANSI C header files
 166 AC_HEADER_STDC
 167
 168 dnl used in gst/ffmpegcolorspace/mem.c
 169 dnl FIXME: could be fixed by redefining av_malloc and av_free to GLib's
 170 AC_CHECK_HEADERS([malloc.h])
 171
 172 dnl used in gst/subparse/gstsubparse.c
 173 AC_CHECK_HEADERS([regex.h], HAVE_REGEX_H="yes", HAVE_REGEX_H="no")
 174 AM_CONDITIONAL(HAVE_REGEX_H, test "x$HAVE_REGEX_H" = "xyes")
 175
 176 dnl used in gst/tcp
 177 AC_CHECK_HEADERS([sys/socket.h],
 178   HAVE_SYS_SOCKET_H="yes", HAVE_SYS_SOCKET_H="no")
 179 AM_CONDITIONAL(HAVE_SYS_SOCKET_H, test "x$HAVE_SYS_SOCKET_H" = "xyes")
 180
 181 dnl ffmpegcolorspace includes _stdint.h
 182 dnl also, Windows does not have long long
 183 AX_CREATE_STDINT_H
 184
 185 dnl *** checks for types/defines ***
 186
 187 dnl Check for FIONREAD ioctl declaration
 188 dnl used in gst/tcp
 189 GST_CHECK_FIONREAD
 190
 191 dnl *** checks for structures ***
 192
 193 dnl *** checks for compiler characteristics ***
 194
 195 dnl make sure we can use "inline" from C code
 196 AC_C_INLINE
 197
 198 dnl *** checks for library functions ***
 199
 200 dnl Check for fast float to int casting as defined in C99
 201 dnl used in gst-libs/gst/floatcast/floatcast.h
 202 AC_C99_FUNC_LRINT
 203 AC_C99_FUNC_LRINTF
 204
 205 dnl Check for a way to display the function name in debug output
 206 GST_CHECK_FUNCTION
 207
 208 dnl *** checks for dependancy libraries ***
 209
 210 dnl GLib is required
 211 GST_GLIB_CHECK([2.6])
 212
 213 dnl liboil is required
 214 PKG_CHECK_MODULES(LIBOIL, liboil-0.3 >= 0.3.6, HAVE_LIBOIL=yes, HAVE_LIBOIL=no)
 215 if test "x$HAVE_LIBOIL" != "xyes"
 216 then
 217   AC_ERROR([liboil-0.3.6 or later is required])
 218 fi
 219
 220 dnl checks for gstreamer
 221 dnl uninstalled is selected preferentially -- see pkg-config(1)
 222 GST_CHECK_GST($GST_MAJORMINOR, [$GST_REQ])
 223 GST_CHECK_GST_BASE($GST_MAJORMINOR, [$GST_REQ])
 224 GST_CHECK_GST_GDP($GST_MAJORMINOR, [$GST_REQ])
 225 GST_CHECK_GST_CONTROLLER($GST_MAJORMINOR, [$GST_REQ])
 226 GST_CHECK_GST_CHECK($GST_MAJORMINOR, [$GST_REQ], no)
 227
 228 dnl FIXME: get rid of this by making sure gstreamer-check brings it in
 229 dnl check for "check", unit testing library/header
 230 AM_PATH_CHECK(0.9.2, HAVE_CHECK=yes, HAVE_CHECK=no)
 231 AM_CONDITIONAL(HAVE_CHECK, test "x$HAVE_CHECK" = "xyes")
 232
 233 dnl GTK is optional and used in examples
 234 HAVE_GTK=NO
 235 PKG_CHECK_MODULES(GTK2, gtk+-2.0 >= 2.2.0, HAVE_GTK_22=yes, HAVE_GTK_22=no)
 236 if test "x$HAVE_GTK_22" = "xyes"; then
 237   HAVE_GTK=yes
 238   GTK_VERSION=`$PKG_CONFIG --variable=gtk_binary_version gtk+-2.0`
 239   AC_SUBST(GTK_VERSION)
 240   GTK_PREFIX=`$PKG_CONFIG --variable=prefix gdk-pixbuf-2.0`
 241   AC_SUBST(GTK_BASE_DIR)
 242 else
 243   PKG_CHECK_MODULES(GTK2, gtk+-2.0, HAVE_GTK_20=yes, HAVE_GTK_20=no)
 244 fi
 245 if test "x$HAVE_GTK_20" = "xyes"; then
 246   HAVE_GTK=yes
 247 fi
 248 GTK_CFLAGS=$GTK2_CFLAGS
 249 GTK_LIBS=$GTK2_LIBS
 250 AC_SUBST(GTK_LIBS)
 251 AC_SUBST(GTK_CFLAGS)
 252 AC_SUBST(HAVE_GTK)
 253 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 254
 255 dnl *** set variables based on configure arguments ***
 256
 257 dnl set license and copyright notice
 258 GST_LICENSE="LGPL"
 259 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 260 AC_SUBST(GST_LICENSE)
 261
 262 dnl set location of plugin directory
 263 GST_SET_PLUGINDIR
 264
 265 dnl define an ERROR_CFLAGS Makefile variable
 266 GST_SET_ERROR_CFLAGS($GST_CVS)
 267
 268 dnl define correct level for debugging messages
 269 GST_SET_LEVEL_DEFAULT($GST_CVS)
 270
 271 dnl used in examples
 272 GST_DEFAULT_ELEMENTS
 273
 274 dnl *** sys plug-ins ***
 275
 276 echo
 277 AC_MSG_NOTICE([Checking libraries for plugins in sys/])
 278 echo
 279
 280 dnl *** X11 ***
 281 translit(dnm, m, l) AM_CONDITIONAL(USE_X, true)
 282 GST_CHECK_FEATURE(X, [X libraries and plugins],
 283                   [ximagesink], [
 284   AC_PATH_XTRA
 285   ac_cflags_save="$CFLAGS"
 286   ac_cppflags_save="$CPPFLAGS"
 287   CFLAGS="$CFLAGS $X_CFLAGS"
 288   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 289
 290   dnl now try to find the HEADER
 291   AC_CHECK_HEADER(X11/Xlib.h, HAVE_X="yes", HAVE_X="no")
 292
 293   if test "x$HAVE_X" = "xno"
 294   then
 295     AC_MSG_NOTICE([cannot find X11 development files])
 296   else
 297     dnl this is much more than we want
 298     X_LIBS="$X_LIBS $X_PRE_LIBS $X_EXTRA_LIBS"
 299     dnl AC_PATH_XTRA only defines the path needed to find the X libs,
 300     dnl it does not add the libs; therefore we add them here
 301     X_LIBS="$X_LIBS -lX11"
 302     AC_SUBST(X_CFLAGS)
 303     AC_SUBST(X_LIBS)
 304   fi
 305   AC_SUBST(HAVE_X)
 306   CFLAGS="$ac_cflags_save"
 307   CPPFLAGS="$ac_cppflags_save"
 308 ])
 309
 310
 311 dnl Check for Xv extension
 312 translit(dnm, m, l) AM_CONDITIONAL(USE_XVIDEO, true)
 313 GST_CHECK_FEATURE(XVIDEO, [X11 XVideo extensions],
 314                   [xvimagesink], [
 315   GST_CHECK_XV
 316 ])
 317
 318 dnl check for X Shm
 319 translit(dnm, m, l) AM_CONDITIONAL(USE_XSHM, true)
 320 GST_CHECK_FEATURE(XSHM, [X Shared Memory extension], xshm, [
 321   if test x$HAVE_X = xyes; then
 322     AC_CHECK_LIB(Xext, XShmAttach,
 323                  HAVE_XSHM="yes", HAVE_XSHM="no",
 324                  $X_LIBS)
 325     if test "x$HAVE_XSHM" = "xyes"; then
 326       XSHM_LIBS="-lXext"
 327     else
 328       dnl On AIX, it is in XextSam instead, but we still need -lXext
 329       AC_CHECK_LIB(XextSam, XShmAttach,
 330                    HAVE_XSHM="yes", HAVE_XSHM="no",
 331                    $X_LIBS)
 332       if test "x$HAVE_XSHM" = "xyes"; then
 333         XSHM_LIBS="-lXext -lXextSam"
 334       fi
 335     fi
 336   fi
 337 ], , [
 338   AC_SUBST(HAVE_XSHM)
 339   AC_SUBST(XSHM_LIBS)
 340 ] )
 341
 342 dnl v4l/v4l2 checks have been moved down because they require X
 343
 344 dnl *** Video 4 Linux ***
 345 dnl for information about the header/define, see sys/v4l/gstv4lelement.h
 346 dnl renamed to GST_V4L in accordance with V4L2 below
 347 translit(dnm, m, l) AM_CONDITIONAL(USE_GST_V4L, true)
 348 GST_CHECK_FEATURE(GST_V4L, [Video 4 Linux], v4lsrc v4lmjpegsrc v4lmjpegsink, [
 349   # first check X
 350   HAVE_GST_V4L="no"
 351   if test "$HAVE_X" = "yes"
 352   then
 353     AC_CHECK_DECL(VID_TYPE_MPEG_ENCODER, HAVE_GST_V4L="yes", HAVE_GST_V4L="no", [
 354 #include <sys/types.h>
 355 #define _LINUX_TIME_H
 356 #define __user
 357 #include <linux/videodev.h>
 358     ])
 359   fi
 360 ])
 361
 362 dnl *** ext plug-ins ***
 363 dnl keep this list sorted alphabetically !
 364
 365 if test "x$BUILD_EXTERNAL" = "xyes"; then
 366
 367 echo
 368 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 369 echo
 370
 371 dnl *** alsa ***
 372 translit(dnm, m, l) AM_CONDITIONAL(USE_ALSA, true)
 373 GST_CHECK_FEATURE(ALSA, [alsa plug-ins], gstalsa, [
 374   PKG_CHECK_MODULES(ALSA, alsa >= 0.9.1, [
 375     HAVE_ALSA="yes"
 376     AC_SUBST(ALSA_CFLAGS)
 377     AC_SUBST(ALSA_LIBS)
 378   ], [
 379     AM_PATH_ALSA(0.9.1, HAVE_ALSA="yes", HAVE_ALSA="no")
 380   ])
 381 ])
 382
 383 dnl *** CDParanoia ***
 384 translit(dnm, m, l) AM_CONDITIONAL(USE_CDPARANOIA, true)
 385 GST_CHECK_FEATURE(CDPARANOIA, [CDParanoia], cdparanoia, [
 386   GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 387                       cdda_open, -lm,
 388                       cdda_interface.h,
 389                       CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 390                       HEADER_DIR="no"
 391                       FOUND_CDPARANOIA="yes")
 392   if test "x$FOUND_CDPARANOIA" != "xyes";
 393   then
 394     GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 395                         cdda_open, -lm,
 396                         cdda/cdda_interface.h,
 397                         CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 398                         HEADER_DIR="yes"
 399                         FOUND_CDPARANOIA="yes")
 400   fi
 401   if test "x$HEADER_DIR" = "xyes";
 402   then
 403     AC_DEFINE_UNQUOTED(CDPARANOIA_HEADERS_IN_DIR, ,
 404                        defined if cdda headers are in a cdda/ directory)
 405   fi
 406   AC_SUBST(CDPARANOIA_LIBS)
 407 ])
 408 dnl FIXME : add second check somehow if that is necessary
 409 dnl AC_CHECK_LIB(cdda_paranoia, paranoia_init, : , HAVE_CDPARANOIA=no, -lcdda_interface )
 410 dnl AC_CHECK_HEADER(cdda_paranoia.h, :, HAVE_CDPARANOIA=no)
 411
 412 dnl *** Gnome VFS ***
 413 translit(dnm, m, l) AM_CONDITIONAL(USE_GNOME_VFS, true)
 414 GST_CHECK_FEATURE(GNOME_VFS, [Gnome VFS], gnomevfssrc, [
 415   PKG_CHECK_MODULES(GNOME_VFS, gnome-vfs-2.0, HAVE_GNOME_VFS="yes", HAVE_GNOME_VFS="no")
 416   AC_SUBST(GNOME_VFS_CFLAGS)
 417   AC_SUBST(GNOME_VFS_LIBS)
 418 ])
 419
 420 dnl *** libvisual ***
 421 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBVISUAL, true)
 422 GST_CHECK_FEATURE(LIBVISUAL, [libvisual visualization plugins], libvisual, [
 423   PKG_CHECK_MODULES(LIBVISUAL, libvisual = 0.2.0, HAVE_LIBVISUAL="yes", HAVE_LIBVISUAL="no")
 424   AC_SUBST(LIBVISUAL_CFLAGS)
 425   AC_SUBST(LIBVISUAL_LIBS)
 426 ])
 427
 428 dnl *** ogg ***
 429 translit(dnm, m, l) AM_CONDITIONAL(USE_OGG, true)
 430 GST_CHECK_FEATURE(OGG, [ogg de/encoder], oggdemux oggmux, [
 431   PKG_CHECK_MODULES(OGG, ogg >= 1.0, [
 432     HAVE_OGG="yes"
 433     AC_SUBST(OGG_CFLAGS)
 434     AC_SUBST(OGG_LIBS)
 435   ], [
 436     XIPH_PATH_OGG(HAVE_OGG="yes", HAVE_OGG="no")
 437     AS_SCRUB_INCLUDE(OGG_CFLAGS)
 438   ])
 439 ])
 440
 441 dnl *** pango ***
 442 translit(dnm, m, l) AM_CONDITIONAL(USE_PANGO, true)
 443 GST_CHECK_FEATURE(PANGO, [pango], pango, [
 444   PKG_CHECK_MODULES(PANGO, pango pangoft2,
 445       HAVE_PANGO="yes", HAVE_PANGO="no")
 446   AC_SUBST(PANGO_CFLAGS)
 447   AC_SUBST(PANGO_LIBS)
 448 ])
 449
 450 dnl *** theora ***
 451 translit(dnm, m, l) AM_CONDITIONAL(USE_THEORA, true)
 452 GST_CHECK_FEATURE(THEORA, [ogg theora codec], theoradec theoraenc, [
 453   PKG_CHECK_MODULES(THEORA, theora, [
 454     HAVE_THEORA="yes"
 455     AC_SUBST(THEORA_LIBS)
 456     AC_SUBST(THEORA_CFLAGS)
 457   ], [
 458     GST_CHECK_LIBHEADER(THEORA, theora, theora_version_string, "-logg", theora/theora.h, THEORA_LIBS="-ltheora -logg")
 459     AC_SUBST(THEORA_LIBS)
 460   ])
 461 ])
 462
 463 dnl *** vorbis ***
 464 dnl AM_PATH_VORBIS only takes two options
 465 translit(dnm, m, l) AM_CONDITIONAL(USE_VORBIS, true)
 466 GST_CHECK_FEATURE(VORBIS, [vorbis plug-in], vorbisenc vorbisdec, [
 467   PKG_CHECK_MODULES(VORBIS, vorbis >= 1.0 vorbisenc >= 1.0, [
 468     HAVE_VORBIS="yes"
 469   ], [
 470     XIPH_PATH_VORBIS(HAVE_VORBIS="yes", HAVE_VORBIS="no")
 471     AS_SCRUB_INCLUDE(VORBIS_CFLAGS)
 472   ])
 473 ])
 474 if test "x$HAVE_VORBIS" = "xyes"; then
 475   ac_cflags_save="$CFLAGS"
 476   dnl FIXME: does this work on non-gcc? -- Company
 477   dnl FIXME: no, it doesn't.  Why is this here in the first place ? -- thomasvs
 478   CFLAGS="-Wall -Werror"
 479   AC_COMPILE_IFELSE(
 480     AC_LANG_PROGRAM([
 481 #include <vorbis/codec.h>
 482                      ],[
 483 vorbis_dsp_state *v;
 484
 485 vorbis_synthesis_restart (v);
 486                      ]), HAVE_VSR=yes, HAVE_VSR=no)
 487   if test "x$HAVE_VSR" = "xyes"; then
 488     AC_DEFINE_UNQUOTED(HAVE_VORBIS_SYNTHESIS_RESTART, 1,
 489                        [defined if vorbis_synthesis_restart is present])
 490   fi
 491   CFLAGS="$ac_cflags_save"
 492 fi
 493
 494 fi dnl of EXT plugins
 495
 496 dnl seeking needs freetype, so check for it here
 497 PKG_CHECK_MODULES(FT2, freetype2 >= 2.0.9, HAVE_FT2="yes", [
 498   AC_CHECK_FT2(2.0.9, HAVE_FT2="yes", HAVE_FT2="no")
 499 ])
 500 dnl make the HAVE_FT2 variable available to automake and Makefile.am
 501 AM_CONDITIONAL(HAVE_FT2, test "x$HAVE_FT2" = "xyes")
 502 AC_SUBST(FT2_CFLAGS)
 503 AC_SUBST(FT2_LIBS)
 504
 505 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 506
 507 dnl Overview:
 508 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
 509 dnl GST_*:              flags shared by built objects to link against GStreamer
 510 dnl GST_ALL_LDFLAGS:    linker flags shared by all
 511 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 512 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 513 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 514
 515 dnl GST_OPTION_CFLAGS
 516 if test "x$USE_DEBUG" = xyes; then
 517    PROFILE_CFLAGS="-g"
 518 fi
 519 AC_SUBST(PROFILE_CFLAGS)
 520
 521 DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 522 AC_SUBST(DEPRECATED_CFLAGS)
 523
 524 dnl every flag in GST_OPTION_CFLAGS can be overridden at make time
 525 GST_OPTION_CFLAGS="\$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 526 AC_SUBST(GST_OPTION_CFLAGS)
 527
 528 dnl our libraries need to be versioned correctly
 529 AC_SUBST(GST_LT_LDFLAGS)
 530
 531 dnl FIXME: do we want to rename to GST_ALL_* ?
 532 dnl prefer internal headers to already installed ones
 533 dnl also add builddir include for enumtypes and marshal
 534 dnl add GST_OPTION_CFLAGS, but overridable
 535 GST_CFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs $GST_CFLAGS \$(GST_OPTION_CFLAGS)"
 536 AC_SUBST(GST_CFLAGS)
 537 AC_SUBST(GST_LIBS)
 538
 539 dnl LDFLAGS really should only contain flags, not libs - they get added before
 540 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 541 GST_ALL_LDFLAGS="-no-undefined"
 542 AC_SUBST(GST_ALL_LDFLAGS)
 543
 544 dnl GST_LIB_LDFLAGS
 545 dnl linker flags shared by all libraries
 546 dnl LDFLAGS modifier defining exported symbols from built libraries
 547 GST_LIB_LDFLAGS="-export-symbols-regex [_]*\(gst_\|Gst\|GST_\).*"
 548 AC_SUBST(GST_LIB_LDFLAGS)
 549
 550 dnl this really should only contain flags, not libs - they get added before
 551 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 552 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc\$\$' $GST_ALL_LDFLAGS"
 553 AC_SUBST(GST_PLUGIN_LDFLAGS)
 554
 555 dnl *** output files ***
 556
 557 AC_CONFIG_FILES(
 558 Makefile
 559 gst-plugins-base.spec
 560 gst/Makefile
 561 gst/adder/Makefile
 562 gst/audioconvert/Makefile
 563 gst/audiorate/Makefile
 564 gst/audioresample/Makefile
 565 gst/audiotestsrc/Makefile
 566 gst/ffmpegcolorspace/Makefile
 567 gst/playback/Makefile
 568 gst/subparse/Makefile
 569 gst/tcp/Makefile
 570 gst/typefind/Makefile
 571 gst/videotestsrc/Makefile
 572 gst/videorate/Makefile
 573 gst/videoscale/Makefile
 574 gst/volume/Makefile
 575 sys/Makefile
 576 sys/ximage/Makefile
 577 sys/xvimage/Makefile
 578 sys/v4l/Makefile
 579 ext/Makefile
 580 ext/alsa/Makefile
 581 ext/cdparanoia/Makefile
 582 ext/gnomevfs/Makefile
 583 ext/libvisual/Makefile
 584 ext/ogg/Makefile
 585 ext/pango/Makefile
 586 ext/theora/Makefile
 587 ext/vorbis/Makefile
 588 gst-libs/Makefile
 589 gst-libs/gst/Makefile
 590 gst-libs/gst/audio/Makefile
 591 gst-libs/gst/cdda/Makefile
 592 gst-libs/gst/floatcast/Makefile
 593 gst-libs/gst/interfaces/Makefile
 594 gst-libs/gst/netbuffer/Makefile
 595 gst-libs/gst/riff/Makefile
 596 gst-libs/gst/rtp/Makefile
 597 gst-libs/gst/tag/Makefile
 598 gst-libs/gst/video/Makefile
 599 tools/Makefile
 600 win32/common/config.h
 601 pkgconfig/Makefile
 602 pkgconfig/gstreamer-plugins-base.pc
 603 pkgconfig/gstreamer-plugins-base-uninstalled.pc
 604 tests/Makefile
 605 tests/check/Makefile
 606 tests/examples/Makefile
 607 tests/examples/seek/Makefile
 608 tests/examples/volume/Makefile
 609 tests/icles/Makefile
 610 docs/Makefile
 611 docs/libs/Makefile
 612 docs/plugins/Makefile
 613 docs/version.entities
 614 po/Makefile.in
 615 common/Makefile
 616 common/m4/Makefile
 617 m4/Makefile
 618 )
 619 AC_OUTPUT
 620
 621 GST_OUTPUT_PLUGINS