configure.ac

   1 dnl autoconf configuration file for gst-plugins
   2 AC_INIT
   3 AC_CANONICAL_TARGET([])
   4
   5 dnl We disable static building for development, for time savings
   6 dnl this goes before AS_LIBTOOL to appease autoconf
   7 dnl *NOTE*: dnl this line before release, so release does static too
   8 AM_DISABLE_STATIC
   9
  10 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  11 AM_MAINTAINER_MODE
  12
  13 dnl when going to/from release please set the nano (fourth number) right !
  14 dnl releases only do Wall, cvs and prerelease does Werror too
  15 AS_VERSION(gst-plugins, GST_PLUGINS_VERSION, 0, 8, 1, 1, GST_CVS="no", GST_CVS="yes")
  16
  17 AM_INIT_AUTOMAKE($PACKAGE,$VERSION)
  18
  19 dnl our libraries and install dirs use major.minor as a version
  20 GST_MAJORMINOR=$GST_PLUGINS_VERSION_MAJOR.$GST_PLUGINS_VERSION_MINOR
  21 dnl we override it here if we need to for the release candidate
  22 #GST_MAJORMINOR=0.8
  23 AC_SUBST(GST_MAJORMINOR)
  24
  25 dnl CURRENT, REVISION, AGE
  26 dnl - library source changed -> increment REVISION
  27 dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
  28 dnl - interfaces added -> increment AGE
  29 dnl - interfaces removed -> AGE = 0
  30 AS_LIBTOOL(GST_PLUGINS, 1, 0, 1)
  31 AM_PROG_LIBTOOL
  32
  33 dnl FIXME take something else ?
  34 AC_CONFIG_SRCDIR([gst/law/alaw.c])
  35 AM_CONFIG_HEADER(config.h)
  36
  37 dnl Add parameters for aclocal
  38 dnl (This must come after AM_INIT_AUTOMAKE, since it modifies ACLOCAL)
  39 ACLOCAL_FLAGS="-I m4 -I common/m4"
  40 AC_SUBST(ACLOCAL_AMFLAGS, $ACLOCAL_FLAGS)
  41
  42 AC_PROG_CC
  43 AM_PROG_CC_STDC
  44 AM_PROG_AS
  45 AS="${CC}"
  46
  47 dnl the gettext stuff needed
  48 AM_GNU_GETTEXT_VERSION(0.11.5)
  49 AM_GNU_GETTEXT([external])
  50
  51 GETTEXT_PACKAGE=gst-plugins-$GST_MAJORMINOR
  52 AC_SUBST(GETTEXT_PACKAGE)
  53 AC_DEFINE_UNQUOTED([GETTEXT_PACKAGE], "$GETTEXT_PACKAGE",
  54                    [gettext package name])
  55
  56 dnl define LOCALEDIR in config.h
  57 AS_AC_EXPAND(LOCALEDIR, $datadir/locale)
  58 AC_DEFINE_UNQUOTED([LOCALEDIR], "$LOCALEDIR",
  59                    [gettext locale dir])
  60
  61 dnl decide on error flags
  62 AS_COMPILER_FLAG(-Wall, GST_WALL="yes", GST_WALL="no")
  63
  64 if test "x$GST_WALL" = "xyes"; then
  65    GST_ERROR="$GST_ERROR -Wall -Wno-sign-compare"
  66
  67    if test "x$GST_CVS" = "xyes"; then
  68      AS_COMPILER_FLAG(-Werror,GST_ERROR="$GST_ERROR -Werror",GST_ERROR="$GST_ERROR")
  69      GST_ERROR="$GST_ERROR -DG_DISABLE_DEPRECATED"
  70    fi
  71 fi
  72
  73 dnl determine c++ compiler
  74 AC_PROG_CXX
  75 dnl determine if c++ is available on this system
  76 AC_CHECK_PROG(HAVE_CXX, $CXX, yes, no)
  77 dnl determine c++ preprocessor
  78 AC_PROG_CXXCPP
  79 AC_ISC_POSIX
  80
  81 AC_HEADER_STDC([])
  82 AC_C_INLINE
  83 AX_CREATE_STDINT_H
  84
  85 dnl Check for malloc.h
  86 AC_CHECK_HEADER(malloc.h,[
  87   AC_DEFINE(HAVE_MALLOC_H, 1, [whether malloc.h available])
  88 ])
  89
  90 dnl Check for a way to display the function name in debug output
  91 GST_CHECK_FUNCTION()
  92
  93 dnl define correct errorlevel for debugging messages. We want to have GST_ERROR
  94 dnl messages printed when running cvs builds
  95 if test "x$GST_CVS" = "xyes"; then
  96   AC_DEFINE(GST_LEVEL_DEFAULT, GST_LEVEL_ERROR, [Default errorlevel to use])
  97 fi
  98
  99 dnl ############################################
 100 dnl # Super Duper options for plug-in building #
 101 dnl ############################################
 102
 103 dnl ext plug-ins; plug-ins that have external dependencies
 104 GST_CHECK_FEATURE(EXTERNAL, [enable building of plug-ins with external deps],,
 105 [HAVE_EXTERNAL=yes],enabled,
 106 [
 107   AC_MSG_WARN(building external plug-ins)
 108   BUILD_EXTERNAL="yes"
 109 ],[
 110   AC_MSG_WARN(all plug-ins with external dependencies will not be built)
 111   BUILD_EXTERNAL="no"
 112 ])
 113 # make BUILD_EXTERNAL available to Makefile.am
 114 AM_CONDITIONAL(BUILD_EXTERNAL, test "x$BUILD_EXTERNAL" = "xyes")
 115
 116 dnl experimental plug-ins; stuff that hasn't had the dust settle yet
 117 dnl read 'builds, but might not work'UTO
 118 GST_CHECK_FEATURE(EXPERIMENTAL, [enable building of experimental plug-ins],,
 119 [HAVE_EXPERIMENTAL=yes],disabled,
 120 [
 121   AC_MSG_WARN(building experimental plug-ins)
 122   USE_TARKIN="yes"
 123   USE_SHOUT2="yes"
 124 ],[
 125   AC_MSG_NOTICE(not building experimental plug-ins)
 126   USE_TARKIN="no"
 127   USE_SHOUT2="no"
 128 ])
 129
 130 dnl broken plug-ins; stuff that doesn't seem to build at the moment
 131 GST_CHECK_FEATURE(BROKEN, [enable building of broken plug-ins],,
 132 HAVE_BROKEN=yes,disabled,
 133 [
 134   AC_MSG_WARN([building broken plug-ins -- no bug reports on these, only patches :)])
 135 ],[
 136   AC_MSG_NOTICE([not building broken plug-ins])
 137 ])
 138
 139 dnl ##############################
 140 dnl # Do automated configuration #
 141 dnl ##############################
 142
 143 dnl Check for tools:
 144 dnl ================
 145
 146 dnl allow for different autotools
 147 AS_AUTOTOOLS_ALTERNATE()
 148
 149 dnl modify pkg-config path
 150 AC_ARG_WITH(pkg-config-path,
 151    AC_HELP_STRING([--with-pkg-config-path],[colon-separated list of pkg-config(1) dirs]),
 152    [export PKG_CONFIG_PATH=${withval}])
 153
 154 dnl check architecture
 155 GST_ARCH()
 156
 157 dnl Check for nasm
 158 AC_PATH_PROG(NASM_PATH, nasm, no)
 159 AC_SUBST(NASM_PATH)
 160 if test x$NASM_PATH = xno; then
 161   AC_MSG_WARN(Couldn't find nasm)
 162   HAVE_NASM="no"
 163 else
 164   AC_DEFINE(HAVE_NASM, 1, [Define if NASM, the netwide assembler, is available])
 165   HAVE_NASM="yes"
 166 fi
 167
 168 dnl check for gconftool-2
 169 translit(dnm, m, l) AM_CONDITIONAL(USE_GCONFTOOL, true)
 170 GST_CHECK_FEATURE(GCONFTOOL, [GConf schemas], , [
 171   AC_PATH_PROG(GCONFTOOL, gconftool-2, no)
 172   if test x$GCONFTOOL = xno; then
 173     AC_MSG_WARN(Not installing GConf schemas)
 174     HAVE_GCONFTOOL="no"
 175   else
 176     AM_GCONF_SOURCE_2
 177     HAVE_GCONFTOOL="yes"
 178   fi
 179   AC_SUBST(HAVE_GCONFTOOL)
 180 ])
 181
 182 dnl check for GConf libraries
 183 translit(dnm, m, l) AM_CONDITIONAL(USE_GCONF, true)
 184 GST_CHECK_FEATURE(GCONF, [GConf libraries], , [
 185   PKG_CHECK_MODULES(GCONF, gconf-2.0, HAVE_GCONF="yes", HAVE_GCONF="no")
 186   AC_SUBST(GCONF_CFLAGS)
 187   AC_SUBST(GCONF_LIBS)
 188 ])
 189
 190 dnl check for gstreamer; uninstalled is selected preferentially -- see pkg-config(1)
 191 GST_REQ=0.8.1.1
 192 PKG_CHECK_MODULES(GST, gstreamer-$GST_MAJORMINOR >= $GST_REQ,
 193   HAVE_GST="yes", HAVE_GST="no")
 194
 195 if test "x$HAVE_GST" = "xno"; then
 196   AC_MSG_ERROR(no GStreamer found)
 197 fi
 198
 199 GST_TOOLS_DIR=`pkg-config --variable=toolsdir gstreamer-$GST_MAJORMINOR`
 200 if test -z $GST_TOOLS_DIR; then
 201   AC_MSG_ERROR([no tools dir defined in GStreamer pkg-config file; core upgrade needed.])
 202 fi
 203 AC_SUBST(GST_TOOLS_DIR)
 204
 205 dnl check for gstreamer-control; uninstalled is selected preferentially
 206 PKG_CHECK_MODULES(GST_CONTROL, gstreamer-control-$GST_MAJORMINOR >= $GST_REQ,
 207   HAVE_GST_CONTROL="yes", HAVE_GST_CONTROL="no")
 208
 209 if test "x$HAVE_GST_CONTROL" = "xno"; then
 210   AC_MSG_ERROR(no GStreamer Control Libs found)
 211 fi
 212
 213 AC_SUBST(GST_CONTROL_LIBS)
 214
 215 dnl Determine endianness
 216 AC_C_BIGENDIAN
 217
 218 dnl Check for fast float to int casting as defined in C99
 219 AC_C99_FUNC_LRINT()
 220 AC_C99_FUNC_LRINTF()
 221
 222 dnl Check for essential libraries first:
 223 dnl ====================================
 224
 225 GST_GLIB2_CHECK()
 226
 227 dnl Check for additional libraries that we might use:
 228 dnl =================================================
 229 dnl GTK
 230 HAVE_GTK=NO
 231 PKG_CHECK_MODULES(GTK2, gtk+-2.0 >= 2.2.0, HAVE_GTK_22=yes, HAVE_GTK_22=no)
 232 if test "x$HAVE_GTK_22" = "xyes"; then
 233   HAVE_GTK=yes
 234   GTK_VERSION=`$PKG_CONFIG --variable=gtk_binary_version gtk+-2.0`
 235   AC_SUBST(GTK_VERSION)
 236   GTK_PREFIX=`$PKG_CONFIG --variable=prefix gdk-pixbuf-2.0`
 237   GDK_PIXBUF_LIBDIR=`$PKG_CONFIG --variable=libdir gdk-pixbuf-2.0`
 238   GDK_PIXBUF_PREFIXDIR=`$PKG_CONFIG --variable=prefix gdk-pixbuf-2.0`
 239   AC_SUBST(GTK_BASE_DIR)
 240 else
 241   PKG_CHECK_MODULES(GTK2, gtk+-2.0, HAVE_GTK_20=yes, HAVE_GTK_20=no)
 242 fi
 243 if test "x$HAVE_GTK_20" = "xyes"; then
 244   HAVE_GTK=yes
 245 fi
 246 GTK_CFLAGS=$GTK2_CFLAGS
 247 GTK_LIBS=$GTK2_LIBS
 248 AC_SUBST(GTK_LIBS)
 249 AC_SUBST(GTK_CFLAGS)
 250 AC_SUBST(HAVE_GTK)
 251
 252 # gdk_pixbuf gstreamer loader is considered experimental, so disable
 253 # by default
 254 if test "x$HAVE_GTK_22" = "xyes"; then
 255   HAVE_GDK_LOADERS=yes
 256 else
 257   HAVE_GDK_LOADERS=no
 258 fi
 259
 260 # we set the defaults always to make sure we have non-empty variables
 261 # for the Makefile
 262
 263 # by default, stick to prefix
 264 GDK_PIXBUF_LOADER_DIR=${libdir}/gtk-2.0/\${GTK_VERSION}/loaders
 265 GDK_PIXBUF_CONF_DIR=${sysconfdir}/gtk-2.0
 266
 267
 268 AC_ARG_ENABLE(gdk-pixbuf-loader,
 269   AC_HELP_STRING([--enable-gdk-pixbuf-loader],
 270               [whether to enable building of gdk_pixbuf loader]),
 271               :, HAVE_GDK_LOADERS="no")
 272
 273 if test "x$HAVE_GDK_LOADERS" = "xyes"; then
 274   AC_PATH_PROG(QUERYLOADERS, gdk-pixbuf-query-loaders, no)
 275   # allow customization of pixbuf loader install location
 276   # when nothing specified, adhere to prefix settings
 277   # when called without any option with this argument, autodetect
 278   # when called with a path, set to the given path
 279
 280   AC_ARG_WITH(gdk-pixbuf-loader-dir,
 281      AC_HELP_STRING([--with-gdk-pixbuf-loader-dir],
 282         [directory to install the gdk_pixbuf loader (none for pkg-config default)]),
 283      [
 284       if test "x${withval}" != xyes ; then
 285         GDK_PIXBUF_LOADER_DIR="${withval}"
 286       else
 287         GDK_PIXBUF_LOADER_DIR="$GDK_PIXBUF_LIBDIR/gtk-2.0/\$GTK_VERSION/loaders"
 288       fi
 289      ]
 290   )
 291   AS_AC_EXPAND(GDK_PIXBUF_LOADER_DIR, $GDK_PIXBUF_LOADER_DIR)
 292   AC_SUBST(GDK_PIXBUF_LOADER_DIR)
 293   AC_MSG_NOTICE([Putting GTK+-2 pixbuf loaders in $GDK_PIXBUF_LOADER_DIR])
 294
 295   # allow customization of pixbuf loader configuration file
 296   # when nothing specified, adhere to prefix settings
 297   # when called without any option with this argument, autodetect
 298   # when called with a path, set to the given path
 299
 300   AC_ARG_WITH(gdk-pixbuf-conf-dir,
 301      AC_HELP_STRING([--with-gdk-pixbuf-conf-dir],
 302         [directory to install the gdk_pixbuf config (none for pkg-config default)]),
 303      [
 304       if test "x${withval}" != xyes ; then
 305         GDK_PIXBUF_CONF_DIR="${withval}"
 306       else
 307         GDK_PIXBUF_CONF_DIR="$GDK_PIXBUF_PREFIXDIR/etc/gtk-2.0/"
 308       fi
 309      ]
 310   )
 311   AS_AC_EXPAND(GDK_PIXBUF_CONF_DIR, $GDK_PIXBUF_CONF_DIR)
 312   AC_SUBST(GDK_PIXBUF_CONF_DIR)
 313   AC_MSG_NOTICE([Putting GTK+-2 pixbuf loader config in $GDK_PIXBUF_CONF_DIR])
 314 fi
 315 AM_CONDITIONAL(HAVE_GDK_LOADERS, test "x$HAVE_GDK_LOADERS" = "xyes")
 316
 317 PKG_CHECK_MODULES(LIBOIL, liboil-0.1, HAVE_LIBOIL=yes, HAVE_LIBOIL=no)
 318 AC_SUBST(LIBOIL_CFLAGS)
 319 AC_SUBST(LIBOIL_LIBS)
 320 if test "x${HAVE_LIBOIL}" = xyes ; then
 321   #AC_DEFINE_UNQUOTED(HAVE_LIBOIL, 1, [Define if liboil is being used])
 322   true
 323 fi
 324
 325 dnl ===========================================================================
 326 dnl ============================= gst plug-ins ================================
 327 dnl ===========================================================================
 328
 329 plugindir="\$(libdir)/gstreamer-$GST_MAJORMINOR"
 330 AC_SUBST(plugindir)
 331
 332 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '[_]*(gst_|Gst|GST_).*' $GST_LIBS"
 333 AC_SUBST(GST_PLUGIN_LDFLAGS)
 334
 335 dnl these are all the gst plug-ins, compilable without additional libs
 336 GST_PLUGINS_ALL="\
 337         ac3parse \
 338         adder \
 339         asfdemux \
 340         audioconvert \
 341         audioscale \
 342         auparse \
 343         avi \
 344         cdxaparse \
 345         chart \
 346         colorspace \
 347         cutter \
 348         debug \
 349         deinterlace \
 350         effectv \
 351         festival \
 352         ffmpegcolorspace \
 353         filter \
 354         flx \
 355         goom \
 356         interleave \
 357         law \
 358         level \
 359         matroska \
 360         median \
 361         mixmatrix \
 362         mpeg1sys \
 363         mpeg1videoparse \
 364         mpeg2sub \
 365         mpegaudio \
 366         mpegaudioparse \
 367         mpegstream \
 368         monoscope \
 369         overlay \
 370         passthrough \
 371         playondemand \
 372         qtdemux \
 373         realmedia \
 374         rtjpeg \
 375         rtp \
 376         silence \
 377         sine \
 378         smooth \
 379         smpte \
 380         spectrum \
 381         speed \
 382         stereo \
 383         switch \
 384         synaesthesia \
 385         tags \
 386         tcp \
 387         typefind \
 388         udp \
 389         vbidec \
 390         videocrop \
 391         videodrop \
 392         videoflip \
 393         videofilter \
 394         videoscale \
 395         videotestsrc \
 396         volenv \
 397         volume \
 398         wavenc \
 399         wavparse \
 400         y4m"
 401
 402 dnl see if we can build C++ plug-ins
 403 if test "x$HAVE_CXX" = "xyes"; then
 404   GST_PLUGINS_ALL="$GST_PLUGINS_ALL \
 405                   modplug"
 406 else
 407   AC_MSG_WARN([Not compiling plug-ins requiring C++ compiler])
 408 fi
 409
 410 AC_SUBST(GST_PLUGINS_ALL)
 411
 412 GST_PLUGINS_SELECTED=""
 413
 414 AC_ARG_WITH(plugins,
 415     AC_HELP_STRING([--with-plugins],[comma-separated list of plug-ins to compile]),
 416     [for i in `echo $withval | tr , ' '`; do
 417         if echo $GST_PLUGINS_ALL | grep $i > /dev/null
 418         then
 419             GST_PLUGINS_SELECTED="$GST_PLUGINS_SELECTED $i"
 420         else
 421             echo "plug-in $i not recognized, ignoring..."
 422         fi
 423     done],
 424     [GST_PLUGINS_SELECTED=$GST_PLUGINS_ALL])
 425
 426 AC_SUBST(GST_PLUGINS_SELECTED)
 427
 428 dnl ==========================================================================
 429 dnl ============================= sys plug-ins ================================
 430 dnl ==========================================================================
 431
 432 dnl *** DXR3 card ***
 433 translit(dnm, m, l) AM_CONDITIONAL(USE_DXR3, true)
 434 GST_CHECK_FEATURE(DXR3, [DXR3 hardware MPEG DVD decoder],
 435   dxr3videosink dxr3audiosink dxr3spusink, [
 436   HAVE_DXR3=yes
 437   AC_CHECK_HEADER(linux/em8300.h, ,
 438                   [ AC_MSG_WARN([DXR3/em8300 header file not found]) &&
 439                     HAVE_DXR3=no ] )
 440   AC_CHECK_HEADER(linux/soundcard.h, ,
 441                   [ AC_MSG_WARN([Generic sound header file not found]) &&
 442                     HAVE_DXR3=no ] )
 443 ])
 444
 445 dnl *** OSS audio ***
 446 translit(dnm, m, l) AM_CONDITIONAL(USE_OSS, true)
 447 GST_CHECK_FEATURE(OSS, [OSS audio], osssrc osssink, [
 448   AC_CHECK_HEADER(sys/soundcard.h, HAVE_OSS="yes", HAVE_OSS="no")
 449 ])
 450
 451 dnl *** QuickCam ***
 452 translit(dnm, m, l) AM_CONDITIONAL(USE_QCAM, true)
 453 GST_CHECK_FEATURE(QCAM, [QuickCam], qcamsrc, [
 454   if test "x$HAVE_CPU_I386" != "xyes";
 455   then
 456     HAVE_QCAM="no"
 457   else
 458     AC_CHECK_HEADER(sys/io.h, HAVE_QCAM="yes", HAVE_QCAM="no")
 459   fi
 460   if test "x$HAVE_QCAM" != "xyes";
 461   then
 462     AC_MSG_WARN([QuickCam only works on i386-linux])
 463   fi
 464 ])
 465
 466 dnl *** Video CD ***
 467 translit(dnm, m, l) AM_CONDITIONAL(USE_VCD, true)
 468 GST_CHECK_FEATURE(VCD, [Video CD], vcdsrc, [
 469   AC_CHECK_HEADER(linux/cdrom.h, HAVE_VCD="yes", HAVE_VCD="no")
 470 ])
 471
 472 dnl *** CDROM Audio ***
 473 translit(dnm, m, l) AM_CONDITIONAL(USE_CDROM, true)
 474 GST_CHECK_FEATURE(CDROM, [CDROM Audio], cdrom, [
 475   AC_CHECK_HEADERS(linux/cdrom.h) dnl linux
 476   AC_CHECK_HEADERS(sys/cdio.h) dnl almost everything else
 477 dnl  AC_CHECK_HEADERS(dmedia/cdaudio.h) dnl irix
 478
 479   if test "${ac_cv_header_linux_cdrom_h}" = "yes" || test "${ac_cv_header_sys_cdio_h}" = "yes" || test "${ac_cv_header_dmedia_cdaudio_h}" = "yes"; then
 480         case "$host" in
 481                 *-sun-* | *-*-linux*)
 482                         AC_DEFINE(HAVE_CDROM_SOLARIS,, [Define if cdrom access is in Solaris style])
 483                 ;;
 484                 *-*-freebsd*)
 485                         AC_DEFINE(HAVE_CDROM_BSD,, [Define if cdrom access is in BSD style])
 486                 ;;
 487                 *-*-netbsd* | *-*-openbsd*)
 488                         AC_DEFINE(HAVE_CDROM_BSD,, [Define if cdrom access is in BSD style])
 489                         AC_DEFINE(HAVE_CDROM_BSD_NETBSD,, [Define if cdrom access uses NetBSD variant])
 490                 ;;
 491                 *-*darwin*)
 492                         AC_DEFINE(HAVE_CDROM_BSD,, [Define if cdrom access is in BSD style])
 493                         AC_DEFINE(HAVE_CDROM_BSD_DARWIN,, [Define if cdrom access uses Darwin variant])
 494                 ;;
 495 dnl             *-irix-*)
 496 dnl                     AC_DEFINE(HAVE_CDROM_IRIX,, [Define if cdrom access is in Irix DMedia style])
 497 dnl             ;;
 498     esac
 499
 500         HAVE_CDROM="yes"
 501   else
 502         HAVE_CDROM="no"
 503   fi
 504 ])
 505
 506 dnl Check for X11
 507 translit(dnm, m, l) AM_CONDITIONAL(USE_X, true)
 508 GST_CHECK_FEATURE(X, [X libraries and plugins],
 509                   [ximagesink], [
 510   AC_PATH_XTRA
 511   dnl now try to find the HEADER
 512   AC_CHECK_HEADER(X11/Xlib.h, HAVE_X="yes", HAVE_X="no")
 513
 514   if test "x$HAVE_X" = "xno"
 515   then
 516     AC_MSG_NOTICE([cannot find X11 development files])
 517   else
 518     dnl this is much more than we want
 519     X_LIBS="$X_LIBS $X_PRE_LIBS $X_EXTRA_LIBS"
 520     dnl AC_PATH_XTRA only defines the path needed to find the X libs,
 521     dnl it does not add the libs; therefore we add them here
 522     X_LIBS="$X_LIBS -lX11"
 523     AC_SUBST(X_CFLAGS)
 524     AC_SUBST(X_LIBS)
 525   fi
 526   AC_SUBST(HAVE_X)
 527 ])
 528
 529 dnl *** XVideo ***
 530 dnl Look for the PIC library first, Debian requires it.
 531 dnl Check debian-devel archives for gory details.
 532 dnl 20020110:
 533 dnl At the moment XFree86 doesn't distribute shared libXv due
 534 dnl to unstable API.  On many platforms you CAN NOT link a shared
 535 dnl lib to a static non-PIC lib.  This is what the xvideo GStreamer
 536 dnl plug-in wants to do.  So Debian distributes a PIC compiled
 537 dnl version of the static lib for plug-ins to link to when it is
 538 dnl inappropriate to link the main application to libXv directly.
 539 dnl FIXME: add check if this platform can support linking to a
 540 dnl        non-PIC libXv, if not then don not use Xv.
 541 dnl FIXME: perhaps warn user if they have a shared libXv since
 542 dnl        this is an error until XFree86 starts shipping one
 543
 544 dnl Check for Xv extension
 545 translit(dnm, m, l) AM_CONDITIONAL(USE_XVIDEO, true)
 546 GST_CHECK_FEATURE(XVIDEO, [X11 XVideo extensions],
 547                   [xvimagesink], [
 548   if test x$HAVE_X = xyes; then
 549     AC_CHECK_LIB(Xv_pic, XvQueryExtension,
 550                  HAVE_XVIDEO="yes", HAVE_XVIDEO="no",
 551                  $X_LIBS -lXext)
 552
 553     if test x$HAVE_XVIDEO = xyes; then
 554       XVIDEO_LIBS="-lXv_pic -lXext"
 555       AC_SUBST(XVIDEO_LIBS)
 556     else
 557       dnl try again using something else if we didn't find it first
 558       if test x$HAVE_XVIDEO = xno; then
 559         AC_CHECK_LIB(Xv, XvQueryExtension,
 560                    HAVE_XVIDEO="yes", HAVE_XVIDEO="no",
 561                    $X_LIBS -lXext)
 562
 563         if test x$HAVE_XVIDEO = xyes; then
 564           XVIDEO_LIBS="-lXv -lXext"
 565           AC_SUBST(XVIDEO_LIBS)
 566         fi
 567       fi
 568     fi
 569   fi
 570 ])
 571
 572 dnl check for X Shm
 573 translit(dnm, m, l) AM_CONDITIONAL(USE_XSHM, true)
 574 GST_CHECK_FEATURE(XSHM, [X Shared Memory extension], xshm, [
 575   if test x$HAVE_X = xyes; then
 576     AC_CHECK_LIB(Xext, XShmAttach,
 577                  HAVE_XSHM="yes", HAVE_XSHM="no",
 578                  $X_LIBS)
 579     if test "x$HAVE_XSHM" = "xyes"; then
 580       XSHM_LIBS="-lXext"
 581     else
 582       dnl On AIX, it is in XextSam instead, but we still need -lXext
 583       AC_CHECK_LIB(XextSam, XShmAttach,
 584                    HAVE_XSHM="yes", HAVE_XSHM="no",
 585                    $X_LIBS)
 586       if test "x$HAVE_XSHM" = "xyes"; then
 587         XSHM_LIBS="-lXext -lXextSam"
 588       fi
 589     fi
 590   fi
 591 ], , [
 592   AC_SUBST(HAVE_XSHM)
 593   AC_SUBST(XSHM_LIBS)
 594 ] )
 595
 596 dnl v4l/v4l2 checks have been moved down because they require X
 597
 598 dnl *** Video 4 Linux ***
 599 dnl for information about the header/define, see sys/v4l/gstv4lelement.h
 600 translit(dnm, m, l) AM_CONDITIONAL(USE_V4L, true)
 601 GST_CHECK_FEATURE(V4L, [Video 4 Linux], v4lsrc v4lmjpegsrc v4lmjpegsink, [
 602   # first check X
 603   HAVE_V4L="no"
 604   if test "$HAVE_X" = "yes"
 605   then
 606     AC_CHECK_DECL(VID_TYPE_MPEG_ENCODER, HAVE_V4L="yes", HAVE_V4L="no", [
 607 #include <sys/types.h>
 608 #define _LINUX_TIME_H
 609 #include <linux/videodev.h>
 610     ])
 611   fi
 612 ])
 613
 614 dnl *** Video 4 Linux 2 ***
 615 dnl for information about the header/define, see sys/v4l2/gstv4l2element.h
 616 translit(dnm, m, l) AM_CONDITIONAL(USE_V4L2, true)
 617 GST_CHECK_FEATURE(V4L2, [Video 4 Linux 2], v4l2src, [
 618   HAVE_V4L2="no"
 619   if test "$HAVE_X" = "yes"
 620   then
 621     AC_MSG_CHECKING([Checking for uptodate v4l2 installation])
 622     AC_TRY_COMPILE([
 623 #include <sys/types.h>
 624 #include <linux/types.h>
 625 #define _LINUX_TIME_H
 626 #include <linux/videodev2.h>
 627 #if defined(V4L2_MAJOR_VERSION) || defined(V4L2_MINOR_VERSION)
 628 #error too early v4l2 version or no v4l2 at all
 629 #endif
 630     ], [
 631 return 0;
 632     ], [ HAVE_V4L2="yes" && AC_MSG_RESULT(yes)],
 633        [ HAVE_V4L2="no"  && AC_MSG_RESULT(no) &&
 634          AC_CHECK_HEADER(linux/videodev2.h,
 635                          [ AC_MSG_WARN([video4linux2 headers were found, but they're old. Please update v4l2 to compile the v4l2 plugins])],
 636                          [ AC_MSG_WARN([video4linux2 was not found])])
 637        ])
 638   fi
 639   dnl check for missing v4l2_buffer declaration (see #135919)
 640   if [ test x$HAVE_V4L2 = xyes ]; then
 641     MISSING_DECL=0
 642     AC_MSG_CHECKING(struct v4l2_buffer declaration)
 643     AC_TRY_COMPILE([
 644 #include <sys/types.h>
 645 #include <linux/types.h>
 646 #define _LINUX_TIME_H
 647 #include <linux/videodev2.h>
 648     ],[
 649 struct v4l2_buffer buf;
 650 return 0;
 651     ], [ AC_MSG_RESULT(yes) ], [ MISSING_DECL=1 && AC_MSG_RESULT(no) ])
 652     if [ test x$MISSING_DECL = x1 ]; then
 653       AC_DEFINE(GST_V4L2_MISSING_BUFDECL, 1, [struct v4l2_buffer missing])
 654     fi
 655   fi
 656 ])
 657
 658 dnl Next, check for the optional libraries:
 659 dnl These are all libraries used in building plug-ins
 660 dnl ================================================
 661 dnl let's try and sort them alphabetically, shall we ?
 662
 663 if test "x$BUILD_EXTERNAL" = "xyes"; then
 664
 665 AC_MSG_NOTICE(Checking for plug-in dependency libraries)
 666
 667 dnl *** a52dec ***
 668 translit(dnm, m, l) AM_CONDITIONAL(USE_A52DEC, true)
 669 GST_CHECK_FEATURE(A52DEC, [a52dec], a52dec, [
 670   AC_CHECK_A52DEC(HAVE_A52DEC=yes, HAVE_A52DEC=no)
 671 ])
 672
 673 dnl *** aalib ***
 674 translit(dnm, m, l) AM_CONDITIONAL(USE_AALIB, true)
 675 GST_CHECK_FEATURE(AALIB, [aasink plug-in], aasink, [
 676   AM_PATH_AALIB(, HAVE_AALIB=yes, HAVE_AALIB=no)
 677   AS_SCRUB_INCLUDE(AALIB_CFLAGS)
 678 ])
 679
 680 dnl *** alsa ***
 681 translit(dnm, m, l) AM_CONDITIONAL(USE_ALSA, true)
 682 GST_CHECK_FEATURE(ALSA, [alsa plug-ins], gstalsa, [
 683   PKG_CHECK_MODULES(ALSA, alsa >= 0.9.1, [
 684     HAVE_ALSA="yes"
 685     AC_SUBST(ALSA_CFLAGS)
 686     AC_SUBST(ALSA_LIBS)
 687   ], [
 688     AM_PATH_ALSA(0.9.1, HAVE_ALSA="yes", HAVE_ALSA="no")
 689   ])
 690 ])
 691
 692 dnl *** arts ***
 693 dnl if mcopidl can't be found there's no use in compiling it
 694 AC_CHECK_PROG(MCOPIDL, mcopidl, yes, no)
 695 if test "x$HAVE_MCOPIDL" = "xno";
 696 then
 697   USE_ARTS=no
 698 fi
 699
 700 translit(dnm, m, l) AM_CONDITIONAL(USE_ARTS, true)
 701 GST_CHECK_FEATURE(ARTS, [arts plug-ins], arts, [
 702   AM_PATH_ARTS(, HAVE_ARTS=yes, HAVE_ARTS=no)
 703 ])
 704
 705 dnl *** artsc ***
 706 translit(dnm, m, l) AM_CONDITIONAL(USE_ARTSC, true)
 707 GST_CHECK_FEATURE(ARTSC, [artsd plug-ins], artsdsink, [
 708   GST_CHECK_ARTSC()
 709 ])
 710
 711 dnl *** audiofile ***
 712 dnl this check uses the GST_CHECK_CONFIGPROG macro
 713 translit(dnm, m, l) AM_CONDITIONAL(USE_AUDIOFILE, true)
 714 GST_CHECK_FEATURE(AUDIOFILE, [audiofile], afsink afsrc, [
 715   translit(dnm, m, l) AC_SUBST(AUDIOFILE_LIBS)
 716   translit(dnm, m, l) AC_SUBST(AUDIOFILE_CFLAGS)
 717   dnl check with pkg-config first
 718   PKG_CHECK_MODULES(AUDIOFILE, audiofile, HAVE_AUDIOFILE="yes", HAVE_AUDIOFILE="no")
 719   if test "x$HAVE_AUDIOFILE" = "xno"; then
 720     GST_CHECK_CONFIGPROG(AUDIOFILE, audiofile-config)
 721     dnl we need this function
 722     AC_CHECK_LIB(audiofile, afOpenVirtualFile, , HAVE_AUDIOFILE="no")
 723   fi])
 724
 725 dnl *** CDParanoia ***
 726 translit(dnm, m, l) AM_CONDITIONAL(USE_CDPARANOIA, true)
 727 GST_CHECK_FEATURE(CDPARANOIA, [CDParanoia], cdparanoia, [
 728   GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 729                       cdda_open, -lm,
 730                       cdda_interface.h,
 731                       CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 732                       HEADER_DIR="no"
 733                       FOUND_CDPARANOIA="yes")
 734   if test "x$FOUND_CDPARANOIA" != "xyes";
 735   then
 736     GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 737                         cdda_open, -lm,
 738                         cdda/cdda_interface.h,
 739                         CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 740                         HEADER_DIR="yes"
 741                         FOUND_CDPARANOIA="yes")
 742   fi
 743   if test "x$HEADER_DIR" = "xyes";
 744   then
 745     AC_DEFINE_UNQUOTED(CDPARANOIA_HEADERS_IN_DIR, ,
 746                        defined if cdda headers are in a cdda/ directory)
 747   fi
 748   AC_SUBST(CDPARANOIA_LIBS)
 749 ])
 750 dnl FIXME : add second check somehow if that is necessary
 751 dnl AC_CHECK_LIB(cdda_paranoia, paranoia_init, : , HAVE_CDPARANOIA=no, -lcdda_interface )
 752 dnl AC_CHECK_HEADER(cdda_paranoia.h, :, HAVE_CDPARANOIA=no)
 753
 754 dnl *** dirac ***
 755 translit(dnm, m, l) AM_CONDITIONAL(USE_DIRAC, true)
 756 GST_CHECK_FEATURE(DIRAC, [dirac plug-ins], dirac, [
 757   PKG_CHECK_MODULES(DIRAC, dirac, HAVE_DIRAC="yes", HAVE_DIRAC="no")
 758   AC_SUBST(DIRAC_CFLAGS)
 759   AC_SUBST(DIRAC_LIBS)
 760 ])
 761
 762 dnl *** DIVX ***
 763 translit(dnm, m, l) AM_CONDITIONAL(USE_DIVX, true)
 764 GST_CHECK_FEATURE(DIVX, [divx plugins], divx, [
 765   HAVE_DIVX=yes
 766   AC_CHECK_HEADER(encore2.h, ,
 767                   [ AC_MSG_WARN([Divx4linux encore headers not found]) &&
 768                     HAVE_DIVX=no ] )
 769   if [ test x$HAVE_DIVX = xyes ]; then
 770     AC_MSG_CHECKING([Checking for valid divx4linux encore version])
 771     AC_TRY_COMPILE([
 772 #include <encore2.h>
 773 #if ENCORE_VERSION != 20021024
 774 #error Wrong version of divx encore libraries
 775 #endif
 776     ], [
 777 return 0;
 778     ], [ HAVE_DIVX=yes && AC_MSG_RESULT(yes)],
 779        [ HAVE_DIVX=no  && AC_MSG_RESULT(no) &&
 780          AC_MSG_WARN([Wrong version of divx4linux installed]) ])
 781   fi
 782   if [ test x$HAVE_DIVX = xyes ]; then
 783     AC_CHECK_HEADER(decore.h, ,
 784                     [ AC_MSG_WARN([Divx4linux decoder headers not found]) &&
 785                       HAVE_DIVX=no ] )
 786   fi
 787   if [ test x$HAVE_DIVX = xyes ]; then
 788     AC_MSG_CHECKING([Checking for valid divx4linux decore version])
 789     AC_TRY_COMPILE([
 790 #include <decore.h>
 791 #if DECORE_VERSION != 20021112
 792 #error Wrong version of divx decore libraries
 793 #endif
 794     ], [
 795 return 0;
 796     ], [ HAVE_DIVX=yes && AC_MSG_RESULT(yes)],
 797        [ HAVE_DIVX=no  && AC_MSG_RESULT(no) &&
 798          AC_MSG_WARN([Wrong version of divx4linux installed]) ])
 799   fi
 800   LIBS="-lm"
 801   if test x$HAVE_DIVX = xyes; then
 802     AC_CHECK_LIB(divxencore, encore, ,
 803                  [ AC_MSG_WARN([Divx4linux encore libs not found]) &&
 804                    HAVE_DIVX=no ] )
 805   fi
 806   if test x$HAVE_DIVX = xyes; then
 807     AC_CHECK_LIB(divxdecore, decore, ,
 808                  [ AC_MSG_WARN([Divx4linux decore libs not found]) &&
 809                    HAVE_DIVX=no ] )
 810   fi
 811   if test x$HAVE_DIVX = xyes; then
 812     DIVXENC_LIBS="-ldivxencore -lm"
 813     DIVXDEC_LIBS="-ldivxdecore -lm"
 814     AC_SUBST(DIVXENC_LIBS)
 815     AC_SUBST(DIVXDEC_LIBS)
 816   fi
 817 ])
 818
 819 dnl *** DTS ***
 820 translit(dnm, m, l) AM_CONDITIONAL(USE_DTS, true)
 821 GST_CHECK_FEATURE(DTS, [dts library], dtsdec, [
 822   GST_CHECK_LIBHEADER(DTS, dts_pic, dts_init, -lm, dts.h, DTS_LIBS="-ldts_pic -lm")
 823   AC_SUBST(DTS_LIBS)
 824 ])
 825
 826 dnl *** dvdread ***
 827 translit(dnm, m, l) AM_CONDITIONAL(USE_DVDREAD, true)
 828 GST_CHECK_FEATURE(DVDREAD, [dvdread library], dvdreadsrc, [
 829   GST_CHECK_LIBHEADER(DVDREAD, dvdread, DVDOpen, , dvdread/dvd_reader.h, DVDREAD_LIBS="-ldvdread")
 830   AC_SUBST(DVDREAD_LIBS)
 831 ])
 832
 833 dnl *** dvdnav ***
 834 translit(dnm, m, l) AM_CONDITIONAL(USE_DVDNAV, true)
 835 GST_CHECK_FEATURE(DVDNAV, [dvdnav library], dvdnavsrc, [
 836   translit(dnm, m, l) AC_SUBST(DVDNAV_LIBS)
 837   translit(dnm, m, l) AC_SUBST(DVDNAV_CFLAGS)
 838   GST_CHECK_CONFIGPROG(DVDNAV, dvdnav-config)
 839   if test x"$HAVE_DVDNAV" = x"yes"; then
 840     dnl check version
 841     DVDNAV_VERSION=`dvdnav-config --version|head -n 1|sed 's/^.*) //'|sed 's/ (.*)//'`
 842     DVDNAV_MAJOR=`echo $DVDNAV_VERSION | cut -d. -f1 | sed s/[a-zA-Z\-].*//g`
 843     DVDNAV_MINOR=`echo $DVDNAV_VERSION | cut -d. -f2 | sed s/[a-zA-Z\-].*//g`
 844     DVDNAV_MICRO=`echo $DVDNAV_VERSION | cut -d. -f3 | sed s/[a-zA-Z\-].*//g`
 845     if [[ "$DVDNAV_MAJOR" -eq "0" ]] && \
 846        [[ "$DVDNAV_MINOR" -lt "1" ]]; then
 847       AC_MSG_WARN([libdvdnav >= 0.1.7 is required, you have $DVDNAV_VERSION])
 848       HAVE_DVDNAV="no"
 849     elif [[ "$DVDNAV_MAJOR" -eq "0" ]] && \
 850          [[ "$DVDNAV_MINOR" -eq "1" ]] && \
 851          [[ "$DVDNAV_MICRO" -lt "7" ]]; then
 852       AC_MSG_WARN([libdvdnav >= 0.1.7 is required, you have $DVDNAV_VERSION])
 853       HAVE_DVDNAV="no"
 854       fi
 855     fi
 856   AS_SCRUB_INCLUDE(DVDNAV_CFLAGS)
 857 ])
 858
 859 dnl **** ESound ****
 860 translit(dnm, m, l) AM_CONDITIONAL(USE_ESD, true)
 861 GST_CHECK_FEATURE(ESD, [esound plug-ins], esdsink esdmon, [
 862   PKG_CHECK_MODULES(ESD, esound >= 0.2.12, [
 863     HAVE_ESD="yes"
 864     AC_SUBST(ESD_CFLAGS)
 865     AC_SUBST(ESD_LIBS)
 866   ], [
 867     AM_PATH_ESD(0.2.12, HAVE_ESD="yes", HAVE_ESD="no")
 868     AS_SCRUB_INCLUDE(ESD_CFLAGS)
 869   ])
 870 ])
 871
 872 dnl **** Free AAC Encoder (FAAC) ****
 873 translit(dnm, m, l) AM_CONDITIONAL(USE_FAAC, true)
 874 GST_CHECK_FEATURE(FAAC, [AAC encoder plug-in], faac, [
 875   GST_CHECK_LIBHEADER(FAAC, faac, faacEncOpen, -lm, faac.h, FAAC_LIBS="-lfaac -lm")
 876   AS_SCRUB_INCLUDE(FAAC_CFLAGS)
 877   AC_SUBST(FAAC_LIBS)
 878 ])
 879
 880 dnl **** Free AAC Decoder (FAAD) ****
 881 translit(dnm, m, l) AM_CONDITIONAL(USE_FAAD, true)
 882 GST_CHECK_FEATURE(FAAD, [AAC decoder plug-in], faad, [
 883   HAVE_FAAD="yes"
 884   GST_CHECK_LIBHEADER(FAAD, faad, faacDecOpen, -lm, faad.h, FAAD_LIBS="-lfaad -lm", HAVE_FAAD="no")
 885   if test $HAVE_FAAD = "yes"; then
 886     AC_MSG_CHECKING([Checking for FAAD >= 2])
 887     AC_TRY_COMPILE([
 888 #include <faad.h>
 889 #if !defined(FAAD2_VERSION) || !defined(FAAD_FMT_DOUBLE)
 890 #error Not faad2
 891 #endif
 892     ], [ return 0; ],
 893        [ HAVE_FAAD="yes" && AC_MSG_RESULT(yes)],
 894        [ HAVE_FAAD="no"  && AC_MSG_RESULT(no)])
 895   fi;
 896   AS_SCRUB_INCLUDE(FAAD_CFLAGS)
 897   AC_SUBST(FAAD_LIBS)
 898 ])
 899
 900 dnl **** festival ****
 901 dnl translit(dnm, m, l) AM_CONDITIONAL(USE_FESTIVAL, true)
 902 dnl GST_CHECK_FEATURE(FESTIVAL, [festival plug-ins], festivalsrc, [
 903   dnl NOTE: just using local net connection now, add this lib check
 904   dnl       in the future if needed
 905   dnl AC_LANG_PUSH(C++)
 906   dnl dnl FIXME: took out func to check for
 907   dnl dnl This check puts festival_tidy_up in extern "C".
 908   dnl dnl But, at least on Debian as of 20020110, it is compiled with name
 909   dnl dnl mangling C++ nonsense and symbols can't resolve
 910   dnl dnl GST_CHECK_LIBHEADER(FESTIVAL, Festival, festival_tidy_up, , festival/festival.h, FESTIVAL_LIBS="-lFestival")
 911   dnl GST_CHECK_LIBHEADER(FESTIVAL, Festival, , , festival/festival.h, FESTIVAL_LIBS="-lFestival")
 912   dnl AC_LANG_POP(C++)
 913   dnl AC_SUBST(FESTIVAL_LIBS)
 914 dnl  HAVE_FESTIVAL=yes
 915 dnl])
 916
 917 dnl *** FLAC ***
 918 translit(dnm, m, l) AM_CONDITIONAL(USE_FLAC, true)
 919 GST_CHECK_FEATURE(FLAC, [FLAC lossless audio], flacenc flacdec, [
 920   GST_CHECK_LIBHEADER(FLAC, FLAC, FLAC__seekable_stream_encoder_new, -lm, FLAC/all.h, FLAC_LIBS="-lFLAC")
 921   AC_SUBST(FLAC_LIBS)
 922 ])
 923
 924 dnl *** GDK pixbuf ***
 925 translit(dnm, m, l) AM_CONDITIONAL(USE_GDK_PIXBUF, true)
 926 GST_CHECK_FEATURE(GDK_PIXBUF, [GDK pixbuf], gdkpixbufsrc, [
 927   if test $HAVE_GTK_22 = "yes"; then HAVE_GDK_PIXBUF=yes; fi;
 928 ])
 929
 930 dnl *** Gnome VFS ***
 931 translit(dnm, m, l) AM_CONDITIONAL(USE_GNOME_VFS, true)
 932 GST_CHECK_FEATURE(GNOME_VFS, [Gnome VFS], gnomevfssrc, [
 933   PKG_CHECK_MODULES(GNOME_VFS, gnome-vfs-2.0, HAVE_GNOME_VFS="yes", HAVE_GNOME_VFS="no")
 934   AC_SUBST(GNOME_VFS_CFLAGS)
 935   AC_SUBST(GNOME_VFS_LIBS)
 936 ])
 937
 938 dnl *** gsm ***
 939 translit(dnm, m, l) AM_CONDITIONAL(USE_GSM, true)
 940 GST_CHECK_FEATURE(GSM, [GSM library], gsmenc gsmdec, [
 941   GST_CHECK_LIBHEADER(GSM, gsm, gsm_create, , gsm.h, GSM_LIBS="-lgsm")
 942   if test $HAVE_GSM != "yes"; then
 943     GST_CHECK_LIBHEADER(GSM, gsm, gsm_create, , gsm/gsm.h, GSM_LIBS="-lgsm")
 944     if test $HAVE_GSM = "yes"; then
 945       AC_DEFINE(GSM_HEADER_IN_SUBDIR, 1, [Define if GSM header in gsm/ subdir])
 946     fi
 947   fi
 948   AC_SUBST(GSM_LIBS)
 949 ])
 950
 951 dnl *** Hermes ***
 952 translit(dnm, m, l) AM_CONDITIONAL(USE_HERMES, true)
 953 GST_CHECK_FEATURE(HERMES, [Hermes library], hermescolorspace, [
 954   GST_CHECK_LIBHEADER(HERMES, Hermes, Hermes_ConverterInstance, , Hermes/Hermes.h, HERMES_LIBS="-lHermes")
 955 ], AC_SUBST(HERMES_LIBS))
 956
 957 dnl *** http ***
 958 dnl translit(dnm, m, l) AM_CONDITIONAL(USE_HTTP, true)
 959 dnl GST_CHECK_FEATURE(HTTP, [http plug-ins], gsthttpsrc, [
 960 dnl  dnl FIXME: need to check for header
 961 dnl  GHTTP_LIBS=
 962 dnl  GST_HTTPSRC_GET_TYPE=
 963 dnl  if test x$USE_GLIB2 = xyes; then
 964 dnl    AC_MSG_WARN(ghttp disabled for glib2.0)
 965 dnl  else
 966 dnl    AC_CHECK_LIB(ghttp, ghttp_request_new,
 967 dnl      [HTTP_LIBS="-lghttp"
 968 dnl       GST_HTTPSRC_GET_TYPE="gst_httpsrc_get_type"
 969 dnl       HAVE_HTTP=yes
 970 dnl      ], :, $LIBS)
 971 dnl  fi
 972 dnl  AC_SUBST(HTTP_LIBS)
 973 dnl  AC_SUBST(GST_HTTPSRC_GET_TYPE)
 974 dnl ])
 975
 976 dnl *** ivorbis ***
 977 dnl AM_PATH_IVORBIS only takes two options
 978 translit(dnm, m, l) AM_CONDITIONAL(USE_IVORBIS, true)
 979 GST_CHECK_FEATURE(IVORBIS, [integer vorbis plug-in], ivorbisdec, [
 980   IVORBIS_LIBS=
 981   IVORBIS_CFLAGS=
 982   AC_CHECK_LIB(vorbisidec, vorbis_block_init,
 983     [IVORBIS_LIBS=-lvorbisidec
 984      HAVE_IVORBIS=yes],
 985     HAVE_IVORBIS=no)
 986   AC_SUBST(IVORBIS_LIBS)
 987   AC_SUBST(IVORBIS_CFLAGS)
 988 ])
 989
 990 dnl *** Jack ***
 991 translit(dnm, m, l) AM_CONDITIONAL(USE_JACK, true)
 992 GST_CHECK_FEATURE(JACK, Jack, jack, [
 993   PKG_CHECK_MODULES(JACK, jack >= 0.29.0, HAVE_JACK="yes", HAVE_JACK="no")
 994   AC_SUBST(JACK_CFLAGS)
 995   AC_SUBST(JACK_LIBS)
 996 ])
 997
 998 dnl *** jpeg ***
 999 dnl FIXME: we could use header checks here as well IMO
1000 translit(dnm, m, l) AM_CONDITIONAL(USE_JPEG, true)
1001 GST_CHECK_FEATURE(JPEG, [jpeg], jpegenc jpegdec, [
1002   AC_ARG_WITH(jpeg-mmx,
1003     [  --with-jpeg-mmx, path to MMX'ified JPEG library])
1004   OLD_LIBS="$LIBS"
1005   if test x$with_jpeg_mmx != x; then
1006     LIBS="$LIBS -L$with_jpeg_mmx"
1007   fi
1008   AC_CHECK_LIB(jpeg-mmx, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
1009   JPEG_LIBS="$LIBS -ljpeg-mmx"
1010   LIBS="$OLD_LIBS"
1011   if test x$HAVE_JPEG != xyes; then
1012     AC_CHECK_LIB(jpeg, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
1013     JPEG_LIBS="-ljpeg"
1014   fi
1015   AC_SUBST(JPEG_LIBS)
1016 ])
1017
1018 dnl *** KDE / Qt ***
1019
1020 dnl * Qt *
1021
1022 qt_dirs="$QTDIR /usr/lib/qt3 /usr/lib/qt /usr/share/qt3 /usr/local/qt"
1023
1024 dnl Build include path search path from the list of Qt dirs
1025
1026 qt_include_dirs=""
1027 for dir in $qt_dirs; do
1028   qt_include_dirs="$qt_include_dirs $dir/include $dir"
1029 done
1030
1031 qt_include_dirs="$qt_include_dirs /usr/include/qt /usr/include /usr/X11R6/include/X11/qt /usr/X11R6/include/qt /usr/include/qt3"
1032
1033 for dir in $qt_include_dirs; do
1034   if test -r "$dir/qglobal.h"; then
1035     qt_include_dir=$dir
1036     break
1037   fi
1038 done
1039
1040 for dir in $qt_dirs; do
1041   qt_lib_dirs="$qt_lib_dirs $dir/lib $dir"
1042 done
1043
1044 qt_lib_dirs="$qt_lib_dirs /usr/X11R6/lib /usr/lib"
1045
1046 for dir in $qt_lib_dirs; do
1047   try="ls -1 $dir/libqt-mt.*"
1048   if test -n "`$try 2> /dev/null`"; then
1049     qt_lib_dir=$dir
1050     break
1051   fi
1052 done
1053
1054 dnl * KDE *
1055
1056 translit(dnm, m, l) AM_CONDITIONAL(USE_KIO, true)
1057 GST_CHECK_FEATURE(KIO, [kio], kio, [
1058   AC_PATH_PROG(KDE_CONFIG, kde-config, no)
1059
1060   if test x$KDE_CONFIG != xno; then
1061     KDE_PREFIX=`$KDE_CONFIG --prefix`
1062   fi
1063
1064   kde_include_dirs="/usr/lib/kde/include /usr/local/kde/include /usr/local/include /usr/kde/include /usr/include/kde /usr/include /opt/kde3/include /opt/kde/include"
1065   kde_lib_dirs="/usr/lib/kde/lib /usr/local/kde/lib /usr/kde/lib /usr/lib/kde /usr/lib/kde3 /usr/lib /usr/X11R6/lib /usr/local/lib /opt/kde3/lib /opt/kde/lib /usr/X11R6/kde/lib"
1066
1067   if test -n "$KDE_PREFIX"; then
1068     kde_include_dirs="$KDE_PREFIX/include $KDE_PREFIX/include/kde $KDE_PREFIX $kde_include_dirs"
1069     kde_lib_dirs="$KDE_PREFIX/lib $KDE_PREFIX $kde_lib_dirs"
1070   fi
1071   if test -n "$KDEDIR"; then
1072     kde_include_dirs="$KDEDIR/include $KDEDIR/include/kde $KDEDIR $kde_include_dirs"
1073     kde_lib_dirs="$KDEDIR/lib $KDEDIR $kde_lib_dirs"
1074   fi
1075
1076   for dir in $kde_include_dirs; do
1077     if test -r "$dir/kglobal.h" && test -r "$dir/kdemacros.h"; then
1078       kde_include_dir=$dir
1079       break
1080     fi
1081   done
1082
1083   for dir in $kde_lib_dirs; do
1084     try="ls -1 $dir/libkio.*"
1085     if test -n "`$try 2> /dev/null`"; then
1086       kde_lib_dir=$dir
1087       break
1088     fi
1089   done
1090
1091   if test -n $kde_include_dir && test -n $kde_lib_dir; then
1092     KIO_CFLAGS="-I$kde_include_dir -I$qt_include_dir"
1093     KIO_LIBS="-L$KDE_PREFIX/lib -L$qt_lib_dir -lkio -lqt-mt"
1094     AC_LANG_PUSH(C++)
1095     save_LIBS="$LIBS"
1096     save_CPPFLAGS="$CPPFLAGS"
1097     LIBS="$LIBS $KIO_LIBS"
1098     CPPFLAGS="$CPPFLAGS $KIO_CFLAGS"
1099     AC_TRY_LINK([
1100 #include <kio/job.h>
1101                  ], [
1102 KIO::get ("bla")
1103                  ], HAVE_KIO="yes", HAVE_KIO="no")
1104     LIBS="$save_LIBS"
1105     CPPFLAGS="$save_CPPFLAGS"
1106     AC_LANG_POP(C++)
1107     AC_SUBST(KIO_CFLAGS)
1108     AC_SUBST(KIO_LIBS)
1109   else
1110     HAVE_KIO="false"
1111   fi
1112 ])
1113
1114 dnl *** ladspa ***
1115 translit(dnm, m, l) AM_CONDITIONAL(USE_LADSPA, true)
1116 GST_CHECK_FEATURE(LADSPA, [ladspa], ladspa, [
1117   AC_CHECK_HEADER(ladspa.h, HAVE_LADSPA="yes", HAVE_LADSPA="no")
1118 ])
1119
1120 dnl *** lame ***
1121 translit(dnm, m, l) AM_CONDITIONAL(USE_LAME, true)
1122 GST_CHECK_FEATURE(LAME, [lame mp3 encoder library], lame, [
1123   GST_CHECK_LIBHEADER(LAME, mp3lame, lame_init, -lm, lame/lame.h, HAVE_LAME="yes" LAME_LIBS="-lmp3lame")
1124 ])
1125 AC_SUBST(LAME_LIBS)
1126
1127 dnl *** libcolorspace ***
1128 translit(dnm, m, l) AM_CONDITIONAL(USE_LCS, true)
1129 GST_CHECK_FEATURE(LCS, Lcs, lcs, [
1130   PKG_CHECK_MODULES(LCS, lcs, HAVE_LCS="yes", HAVE_LCS="no")
1131   AC_SUBST(LCS_CFLAGS)
1132   AC_SUBST(LCS_LIBS)
1133 ])
1134
1135 dnl *** libdv ***
1136 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBDV, true)
1137 GST_CHECK_FEATURE(LIBDV, [libdv DV/video decoder], dvdec, [
1138   PKG_CHECK_MODULES(LIBDV, libdv >= 0.98, HAVE_LIBDV="yes", HAVE_LIBDV="no")
1139   AC_SUBST(LIBDV_CFLAGS)
1140   AC_SUBST(LIBDV_LIBS)
1141 ])
1142
1143 dnl *** libcaca ***
1144 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBCACA, true)
1145 GST_CHECK_FEATURE(LIBCACA, [libcaca], libcaca, [
1146   GST_CHECK_CONFIGPROG(LIBCACA, caca-config)
1147   AC_SUBST(LIBCACA_CFLAGS)
1148   AC_SUBST(LIBCACA_LIBS)
1149 ])
1150
1151 dnl *** libfame ***
1152 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBFAME, true)
1153 GST_CHECK_FEATURE(LIBFAME, [libfame MPEG1/4 encoder], libfame, [
1154   AM_PATH_LIBFAME(0.9.0, HAVE_LIBFAME="yes", HAVE_LIBFAME="no")
1155   AC_SUBST(LIBFAME_CFLAGS)
1156   AC_SUBST(LIBFAME_LIBS)
1157 ])
1158
1159 dnl *** libpng ***
1160 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBPNG, true)
1161 GST_CHECK_FEATURE(LIBPNG, [libpng PNG encoder], pngenc, [
1162   PKG_CHECK_MODULES(LIBPNG, libpng12, HAVE_LIBPNG="yes", HAVE_LIBPNG="no")
1163   AC_SUBST(LIBPNG_CFLAGS)
1164   AC_SUBST(LIBPNG_LIBS)
1165 ])
1166
1167 dnl *** librfb ***
1168 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBRFB, true)
1169 GST_CHECK_FEATURE(LIBRFB, [librfb Remote Framebuffer], rfbsrc, [
1170   PKG_CHECK_MODULES(LIBRFB, librfb-0.1, HAVE_LIBRFB="yes", HAVE_LIBRFB="no")
1171   AC_SUBST(LIBRFB_CFLAGS)
1172   AC_SUBST(LIBRFB_LIBS)
1173 ])
1174
1175 dnl *** libvisual ***
1176 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBVISUAL, true)
1177 GST_CHECK_FEATURE(LIBVISUAL, [libvisual visualization plugins], libvisual, [
1178   PKG_CHECK_MODULES(LIBVISUAL, libvisual, HAVE_LIBVISUAL="yes", HAVE_LIBVISUAL="no")
1179   AC_SUBST(LIBVISUAL_CFLAGS)
1180   AC_SUBST(LIBVISUAL_LIBS)
1181 ])
1182
1183 dnl *** mad ***
1184 dnl *** mad ***
1185 dnl FIXME: we could use header checks here as well IMO
1186 translit(dnm, m, l) AM_CONDITIONAL(USE_MAD, true)
1187 GST_CHECK_FEATURE(MAD, [mad mp3 decoder], mad, [
1188   dnl check with pkg-config first
1189   PKG_CHECK_MODULES(MAD, mad >= 0.15 id3tag >= 0.15, HAVE_MAD="yes", HAVE_MAD="no")
1190   if test "x$HAVE_MAD" = "xno"; then
1191     dnl fall back to oldskool detection
1192     AC_CHECK_LIB(mad, mad_decoder_finish, HAVE_MAD="yes" MAD_LIBS="-lmad")
1193     if test "x$HAVE_MAD" = "xyes"; then
1194       HAVE_MAD="no"
1195       save_LIBS=$LIBS
1196       LIBS="-lz"
1197       AC_CHECK_LIB(id3tag, id3_tag_options, HAVE_MAD="yes" MAD_LIBS="-lmad -lid3tag -lz")
1198       LIBS=$save_LIBS
1199     fi
1200   fi
1201 ])
1202 AC_SUBST(MAD_LIBS)
1203
1204 dnl *** mikmod ***
1205 translit(dnm, m, l) AM_CONDITIONAL(USE_MIKMOD, true)
1206 GST_CHECK_FEATURE(MIKMOD, [mikmod plug-in], mikmod, [
1207   AM_PATH_LIBMIKMOD(, HAVE_MIKMOD=yes, HAVE_MIKMOD=no)
1208   AC_SUBST(MIKMOD_LIBS, "$LIBMIKMOD_LIBS")
1209   AC_SUBST(MIKMOD_CFLAGS, "$LIBMIKMODCFLAGS")
1210 ])
1211
1212 dnl *** mpeg2dec ***
1213 translit(dnm, m, l) AM_CONDITIONAL(USE_MPEG2DEC, true)
1214 GST_CHECK_FEATURE(MPEG2DEC, [mpeg2dec], mpeg2dec, [
1215   PKG_CHECK_MODULES(MPEG2DEC, libmpeg2 >= 0.4.0,
1216       HAVE_MPEG2DEC="yes", HAVE_MPEG2DEC="no")
1217   AC_SUBST(MPEG2DEC_CFLAGS)
1218   AC_SUBST(MPEG2DEC_LIBS)
1219 ])
1220
1221 dnl *** mpeg2enc ***
1222 translit(dnm, m, l) AM_CONDITIONAL(USE_MPEG2ENC, true)
1223 GST_CHECK_FEATURE(MPEG2ENC, [mpeg2enc], mpeg2enc, [
1224   HAVE_MPEG2ENC="no"
1225   dnl we require a c++ compiler for this one
1226   if [ test x$HAVE_CXX = xyes ]; then
1227     dnl libmpeg2enc was first included in mjpegtools-1.6.2-rc3 (1.6.1.92)
1228     dnl since many distros include mjpegtools specifically without mplex
1229     dnl and mpeg2enc, we check for mpeg2enc on its own, too.
1230     PKG_CHECK_MODULES(MPEG2ENC, mjpegtools >= 1.6.1.93, [
1231       dnl switch over to c++ to test things
1232       AC_LANG_CPLUSPLUS
1233       OLD_CPPFLAGS="$CPPFLAGS"
1234       CPPFLAGS="$CPPFLAGS $MPEG2ENC_CFLAGS"
1235       AC_CHECK_HEADER(mpeg2encoder.hh, [
1236         MPEG2ENC_LIBS="$MPEG2ENC_LIBS -lmpeg2encpp -lm -lpthread"
1237         OLD_LIBS="$LIBS"
1238         LIBS="$LIBS $MPEG2ENC_LIBS"
1239         AC_MSG_CHECKING([for valid mpeg2enc objects])
1240         AC_TRY_RUN([
1241 #include <mpeg2encoder.hh>
1242 #include <mpeg2encoptions.hh>
1243
1244 int
1245 main (int   argc,
1246       char *argv[])
1247 {
1248   MPEG2EncOptions *options = new MPEG2EncOptions ();
1249   MPEG2Encoder encoder (*options);
1250   return 0;
1251 }
1252         ],[
1253           HAVE_MPEG2ENC="yes"
1254           AC_SUBST(MPEG2ENC_CFLAGS)
1255           AC_SUBST(MPEG2ENC_LIBS)
1256           AC_MSG_RESULT(yes)
1257         ], AC_MSG_RESULT(no))
1258         LIBS="$OLD_LIBS"
1259       ])
1260       CPPFLAGS="$OLD_CPPFLAGS"
1261       AC_LANG_C
1262     ],
1263     HAVE_MPEG2ENC="no")
1264   fi
1265 ])
1266
1267 dnl *** mplex ***
1268 translit(dnm, m, l) AM_CONDITIONAL(USE_MPLEX, true)
1269 GST_CHECK_FEATURE(MPLEX, [mplex], mplex, [
1270   HAVE_MPLEX="no"
1271   dnl we require a c++ compiler for this one
1272   if [ test x$HAVE_CXX = xyes ]; then
1273     dnl libmplex was first included in mjpegtools-1.6.2-rc4 (1.6.1.93)
1274     dnl since many distros include mjpegtools specifically without mplex
1275     dnl and mpeg2enc, we check for mplex on its own, too.
1276     PKG_CHECK_MODULES(MPLEX, mjpegtools >= 1.6.1.93, [
1277       dnl switch over to c++ to test things
1278       AC_LANG_CPLUSPLUS
1279       OLD_CPPFLAGS="$CPPFLAGS"
1280       CPPFLAGS="$CPPFLAGS $MPLEX_CFLAGS"
1281       AC_CHECK_HEADER(interact.hpp, [
1282         MPLEX_LIBS="$MPLEX_LIBS -lmplex2 -lm"
1283         OLD_LIBS="$LIBS"
1284         LIBS="$LIBS $MPLEX_LIBS"
1285         AC_MSG_CHECKING([for valid mplex objects])
1286         AC_TRY_RUN([
1287 #include <interact.hpp>
1288 #include <outputstrm.hpp>
1289 #include <multiplexor.hpp>
1290
1291 int
1292 main (int   argc,
1293       char *argv[])
1294 {
1295   class TestOutputStream : public OutputStream {
1296   public:
1297     TestOutputStream () : OutputStream () { }
1298     void Write (uint8_t *a, unsigned int b) { }
1299     void NextSegment () { }
1300     off_t SegmentSize () { }
1301     void Close () { }
1302     int Open () { }
1303   };
1304   MultiplexJob *job = new MultiplexJob ();
1305   vector<IBitStream *> inputs;
1306   job->SetupInputStreams (inputs);
1307   TestOutputStream *out = new TestOutputStream ();
1308   Multiplexor mux (*job, *out);
1309   return 0;
1310 }
1311         ],[
1312           HAVE_MPLEX="yes"
1313           AC_SUBST(MPLEX_CFLAGS)
1314           AC_SUBST(MPLEX_LIBS)
1315           AC_MSG_RESULT(yes)
1316         ], AC_MSG_RESULT(no))
1317         LIBS="$OLD_LIBS"
1318       ])
1319       CPPFLAGS="$OLD_CPPFLAGS"
1320       AC_LANG_C
1321     ], HAVE_MPLEX="no")
1322   fi
1323 ])
1324
1325 dnl *** musicbrainz ***
1326 dnl libmusicbrainz <= 2.0.2 has symbol clashes with ffmpeg
1327 translit(dnm, m, l) AM_CONDITIONAL(USE_MUSICBRAINZ, true)
1328 GST_CHECK_FEATURE(MUSICBRAINZ, [musicbrainz], musicbrainz, [
1329   PKG_CHECK_MODULES(MUSICBRAINZ, libmusicbrainz > 2.0.2,
1330       HAVE_MUSICBRAINZ="yes", HAVE_MUSICBRAINZ="no")
1331   AC_SUBST(MUSICBRAINZ_CFLAGS)
1332   AC_SUBST(MUSICBRAINZ_LIBS)
1333 ])
1334
1335 dnl *** nas ***
1336 translit(dnm, m, l) AM_CONDITIONAL(USE_NAS, true)
1337 GST_CHECK_FEATURE(NAS, [nas plug-in], nassink, [
1338   HAVE_NAS="no"
1339   if test "x$HAVE_X" = "xyes"; then
1340     save_cppflags=$CFLAGS
1341     CPPFLAGS="$CPPFLAGS $X_CFLAGS"
1342     GST_CHECK_LIBHEADER(NAS, audio, AuOpenServer, $X_LIBS, audio/audiolib.h,
1343       NAS_LIBS="$X_LIBS -laudio" NAS_CFLAGS="$X_CFLAGS")
1344     CPPFLAGS="$save_cppflags"
1345   fi
1346   AC_SUBST(NAS_CFLAGS)
1347   AC_SUBST(NAS_LIBS)
1348 ])
1349
1350 dnl *** pango ***
1351 translit(dnm, m, l) AM_CONDITIONAL(USE_PANGO, true)
1352 GST_CHECK_FEATURE(PANGO, [pango], pango, [
1353   PKG_CHECK_MODULES(PANGO, pango pangoft2,
1354       HAVE_PANGO="yes", HAVE_PANGO="no")
1355   AC_SUBST(PANGO_CFLAGS)
1356   AC_SUBST(PANGO_LIBS)
1357 ])
1358
1359 dnl *** raw1394 ***
1360 translit(dnm, m, l) AM_CONDITIONAL(USE_RAW1394, true)
1361 GST_CHECK_FEATURE(RAW1394, [raw1394 library], dv1394src, [
1362   GST_CHECK_LIBHEADER(RAW1394, raw1394, raw1394_new_handle,, libraw1394/raw1394.h, RAW1394_LIBS="-lraw1394")
1363   AC_SUBST(RAW1394_LIBS)
1364 ])
1365
1366 dnl *** SDL ***
1367 translit(dnm, m, l) AM_CONDITIONAL(USE_SDL, true)
1368 GST_CHECK_FEATURE(SDL, [SDL plug-in], sdlvideosink, [
1369   dnl sdlvideosink depends on the xoverlay interface, which depends on X
1370   if test x$HAVE_X = xyes; then
1371     AM_PATH_SDL(, HAVE_SDL=yes, HAVE_SDL=no)
1372   fi
1373 ])
1374
1375 dnl *** shout ***
1376 translit(dnm, m, l) AM_CONDITIONAL(USE_SHOUT, true)
1377 GST_CHECK_FEATURE(SHOUT, [shout plug-in], icecastsend, [
1378   GST_CHECK_LIBHEADER(SHOUT, shout, shout_init_connection,, shout/shout.h, SHOUT_LIBS="-lshout")
1379   AC_SUBST(SHOUT_LIBS)
1380 ])
1381
1382 dnl *** shout2 ***
1383 translit(dnm, m, l) AM_CONDITIONAL(USE_SHOUT2, true)
1384 GST_CHECK_FEATURE(SHOUT2, [shout2 plug-in], shout2send, [
1385   PKG_CHECK_MODULES(SHOUT2, shout >= 2.0, [
1386     HAVE_SHOUT2="yes"
1387     AC_SUBST(SHOUT2_CFLAGS)
1388     AC_SUBST(SHOUT2_LIBS)
1389   ], [
1390     AM_PATH_SHOUT2(HAVE_SHOUT2="yes", HAVE_SHOUT2="no")
1391     AC_SUBST(SHOUT2_CFLAGS)
1392     AC_SUBST(SHOUT2_LIBS)
1393   ])
1394 ])
1395
1396 dnl *** sidplay ***
1397 translit(dnm, m, l) AM_CONDITIONAL(USE_SIDPLAY, true)
1398 GST_CHECK_FEATURE(SIDPLAY, [sidplay plug-in], sidplay, [
1399   GST_PATH_SIDPLAY()
1400 ])
1401
1402 dnl *** smoothwave ***
1403 translit(dnm, m, l) AM_CONDITIONAL(USE_SMOOTHWAVE, true)
1404 GST_CHECK_FEATURE(SMOOTHWAVE, [smoothwave plug-in], smoothwave, [
1405   if test $HAVE_GTK = "yes"; then HAVE_SMOOTHWAVE=yes; fi;
1406 ])
1407
1408
1409 dnl *** snapshot ***
1410 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBPNG, true)
1411 GST_CHECK_FEATURE(LIBPNG, [snapshot plug-in], snapshot, [
1412   GST_CHECK_LIBHEADER(LIBPNG, png, png_read_info, -lz -lm, png.h, LIBPNG_LIBS="-lpng -lz -lm")
1413   AC_SUBST(LIBPNG_LIBS)
1414 ])
1415
1416 dnl *** speex 1.0 only, not 1.1 ***
1417 dnl speex_jitter.h is 1.1 only
1418 translit(dnm, m, l) AM_CONDITIONAL(USE_SPEEX, true)
1419 GST_CHECK_FEATURE(SPEEX, [speex plug-in], speex, [
1420   GST_CHECK_LIBHEADER(SPEEX, speex, speex_bits_init, , speex.h, [
1421     AC_CHECK_HEADER(speex_jitter.h, HAVE_SPEEX="no", [
1422       HAVE_SPEEX="yes"
1423       SPEEX_LIBS="-lspeex"
1424       AC_SUBST(SPEEX_CFLAGS)
1425       AC_SUBST(SPEEX_LIBS)
1426     ])
1427   ])
1428 ])
1429
1430 dnl *** sndfile ***
1431 translit(dnm, m, l) AM_CONDITIONAL(USE_SNDFILE, true)
1432 GST_CHECK_FEATURE(SNDFILE, [sndfile plug-in], sfsrc sfsink, [
1433   PKG_CHECK_MODULES(SNDFILE, sndfile >= 1.0.0, HAVE_SNDFILE="yes", HAVE_SNDFILE="no")
1434   AC_SUBST(SNDFILE_CFLAGS)
1435   AC_SUBST(SNDFILE_LIBS)
1436 ])
1437
1438 dnl *** swfdec ***
1439 translit(dnm, m, l) AM_CONDITIONAL(USE_SWFDEC, true)
1440 GST_CHECK_FEATURE(SWFDEC, [swfdec plug-in], swfdec, [
1441   PKG_CHECK_MODULES(SWFDEC, swfdec >= 0.1.3.1, HAVE_SWFDEC=yes, HAVE_SWFDEC=no)
1442   AC_SUBST(SWFDEC_CFLAGS)
1443   AC_SUBST(SWFDEC_LIBS)
1444 ])
1445
1446 dnl *** tarkin ***
1447 dnl for now the sources are included in the plug-in
1448 dnl and should be moved to ext-libs/ perhaps
1449 translit(dnm, m, l) AM_CONDITIONAL(USE_TARKIN, true)
1450 GST_CHECK_FEATURE(TARKIN, [tarkinenc tarkindec], tarkin, [
1451   HAVE_TARKIN="yes"
1452 ])
1453
1454 dnl *** ogg ***
1455 translit(dnm, m, l) AM_CONDITIONAL(USE_OGG, true)
1456 GST_CHECK_FEATURE(OGG, [ogg de/encoder], oggdemux oggmux, [
1457   PKG_CHECK_MODULES(OGG, ogg >= 1.0, [
1458     HAVE_OGG="yes"
1459     AC_SUBST(OGG_CFLAGS)
1460     AC_SUBST(OGG_LIBS)
1461   ], [
1462     XIPH_PATH_OGG(HAVE_OGG="yes", HAVE_OGG="no")
1463     AS_SCRUB_INCLUDE(OGG_CFLAGS)
1464   ])
1465 ])
1466
1467 dnl *** theora ***
1468 dnl FIXME: theora doesn't have proper pc/m4 files yet, change this when this happens
1469 translit(dnm, m, l) AM_CONDITIONAL(USE_THEORA, true)
1470 GST_CHECK_FEATURE(THEORA, [ogg theora codec], theoradec, [
1471   GST_CHECK_LIBHEADER(THEORA, theora, theora_version_string, , theora/theora.h, THEORA_LIBS="-ltheora")
1472   AC_SUBST(THEORA_LIBS)
1473 ])
1474
1475 dnl *** vorbis ***
1476 dnl AM_PATH_VORBIS only takes two options
1477 translit(dnm, m, l) AM_CONDITIONAL(USE_VORBIS, true)
1478 GST_CHECK_FEATURE(VORBIS, [vorbis plug-in], vorbisenc vorbisdec, [
1479   PKG_CHECK_MODULES(VORBIS, vorbis >= 1.0 vorbisenc >= 1.0, [
1480     HAVE_VORBIS="yes"
1481   ], [
1482     XIPH_PATH_VORBIS(HAVE_VORBIS="yes", HAVE_VORBIS="no")
1483     AS_SCRUB_INCLUDE(VORBIS_CFLAGS)
1484   ])
1485 ])
1486 if test "x$HAVE_VORBIS" = "xyes"; then
1487   ac_cflags_save="$CFLAGS"
1488   dnl FIXME: does this work on non-gcc? -- Company
1489   CFLAGS="-Wall -Werror"
1490   AC_COMPILE_IFELSE(
1491     AC_LANG_PROGRAM([
1492 #include <vorbis/codec.h>
1493                      ],[
1494 vorbis_dsp_state *v;
1495
1496 vorbis_synthesis_restart (v);
1497                      ]), HAVE_VSR=yes, HAVE_VSR=no)
1498   if test "x$HAVE_VSR" = "xyes"; then
1499     AC_DEFINE_UNQUOTED(HAVE_VORBIS_SYNTHESIS_RESTART, 1,
1500                        [defined if vorbis_synthesis_restart is present])
1501   fi
1502   CFLAGS="$ac_cflags_save"
1503 fi
1504
1505 dnl *** xine ***
1506 translit(dnm, m, l) AM_CONDITIONAL(USE_XINE, true)
1507 GST_CHECK_FEATURE(XINE, [xine wrapper], xine, [
1508   PKG_CHECK_MODULES(XINE, libxine >= 1.0.0, HAVE_XINE=yes, HAVE_XINE=no)
1509   AC_SUBST(XINE_CFLAGS)
1510   AC_SUBST(XINE_LIBS)
1511 ],disabled)
1512
1513 dnl *** XVID ***
1514 translit(dnm, m, l) AM_CONDITIONAL(USE_XVID, true)
1515 GST_CHECK_FEATURE(XVID, [xvid plugins], xvid, [
1516   HAVE_XVID=no
1517   AC_CHECK_HEADER(xvid.h, [
1518     OLD_LIBS="$LIBS"
1519     LIBS="-lm"
1520     AC_CHECK_LIB(xvidcore, xvid_encore, [
1521       AC_CHECK_LIB(xvidcore, xvid_decore, [
1522         AC_CHECK_LIB(xvidcore, xvid_global, [
1523           AC_MSG_CHECKING([for uptodate XviD API version])
1524           AC_TRY_RUN([
1525 #include <xvid.h>
1526 #if XVID_API != XVID_MAKE_API(4,0)
1527 #error "Incompatible XviD API version"
1528 #endif
1529 int main () { return 0; }
1530           ],[ AC_MSG_RESULT(yes)
1531             XVID_LIBS="-lxvidcore -lm"
1532             AC_SUBST(XVID_LIBS)
1533             HAVE_XVID=yes
1534           ], AC_MSG_RESULT(no) )
1535         ], )
1536       ], )
1537     ], )
1538     LIBS="$OLD_LIBS"
1539   ], )
1540 ])
1541
1542
1543 fi dnl of EXT plugins
1544
1545 dnl Check for atomic.h
1546 dnl Note: use AC_CHECK_HEADER not AC_CHECK_HEADERS, because the latter
1547 dnl defines the wrong default symbol as well (HAVE_ASM_ATOMIC_H)
1548 AC_CHECK_HEADER(asm/atomic.h, HAVE_ATOMIC_H=yes, HAVE_ATOMIC_H=no)
1549 dnl Do a compile to check that it has atomic_set (eg, linux 2.0 didn't)
1550 if test x$HAVE_ATOMIC_H = xyes; then
1551   AC_TRY_RUN([
1552 #include "asm/atomic.h"
1553 main() { atomic_t t; atomic_set(&t,0); atomic_inc(&t); atomic_add(1,&t);return 0;}
1554   ],, [
1555     # Not successful
1556     if test x$HAVE_ATOMIC_H = xyes; then
1557       AC_MSG_WARN(Atomic reference counting is out of date: doing without.)
1558     fi
1559     HAVE_ATOMIC_H=no
1560   ], [
1561     # Cross compiling
1562     AC_MSG_RESULT(yes)
1563     AC_MSG_WARN(Can't check properly for atomic reference counting.  Assuming OK.)
1564   ])
1565 fi
1566
1567
1568 dnl ######################################################################
1569 dnl # Check command line parameters, and set shell variables accordingly #
1570 dnl ######################################################################
1571
1572 AC_ARG_ENABLE(libmmx,
1573   AC_HELP_STRING([--enable-libmmx],[use libmmx, if available]),
1574 [case "${enableval}" in
1575   yes) USE_LIBMMX=$HAVE_LIBMMX ;;
1576   no)  USE_LIBMMX=no ;;
1577   *) AC_MSG_ERROR(bad value ${enableval} for --enable-libmmx) ;;
1578 esac],
1579 [USE_LIBMMX=$HAVE_LIBMMX]) dnl Default value
1580
1581 AC_ARG_ENABLE(atomic,
1582   AC_HELP_STRING([--enable-atomic],[use atomic reference counting header]),
1583 [case "${enableval}" in
1584   yes) USE_ATOMIC_H=$HAVE_ATOMIC_H;;
1585   noset) USE_ATOMIC_H=$HAVE_ATOMIC_H;;
1586   no)  USE_ATOMIC_H=no;;
1587   *) AC_MSG_ERROR(bad value ${enableval} for --enable-atomic) ;;
1588 esac],
1589 [USE_ATOMIC_H=$HAVE_ATOMIC_H]) dnl Default value
1590
1591 AC_ARG_ENABLE(profiling,
1592   AC_HELP_STRING([--enable-profiling],
1593                  [-pg to compiler commandline, for profiling]),
1594 [case "${enableval}" in
1595   yes) USE_PROFILING=yes ;;
1596   no)  UES_PROFILING=no ;;
1597   *) AC_MSG_ERROR(bad value ${enableval} for --enable-profiling) ;;
1598 esac],
1599 [USE_PROFILING=no]) dnl Default value
1600
1601 AC_ARG_ENABLE(tests,
1602   AC_HELP_STRING([--disable-tests],[disable building test apps]),
1603 [case "${enableval}" in
1604   yes) BUILD_TESTS=yes ;;
1605   no)  BUILD_TESTS=no ;;
1606   *) AC_MSG_ERROR(bad value ${enableval} for --disable-tests) ;;
1607 esac],
1608 [BUILD_TESTS=yes]) dnl Default value
1609
1610 AC_ARG_ENABLE(examples,
1611   AC_HELP_STRING([--disable-examples],[disable building examples]),
1612 [case "${enableval}" in
1613   yes) BUILD_EXAMPLES=yes ;;
1614   no)  BUILD_EXAMPLES=no ;;
1615   *) AC_MSG_ERROR(bad value ${enableval} for --disable-examples) ;;
1616 esac],
1617 [BUILD_EXAMPLES=yes]) dnl Default value
1618
1619 dnl seeking needs freetype, so check for it here
1620 PKG_CHECK_MODULES(FT2, freetype2 >= 2.0.9, HAVE_FT2="yes", [
1621   AC_CHECK_FT2(2.0.9, HAVE_FT2="yes", HAVE_FT2="no")
1622 ])
1623 dnl make the HAVE_FT2 variable available to automake and Makefile.am
1624 AM_CONDITIONAL(HAVE_FT2, test "x$HAVE_FT2" = "xyes")
1625 AC_SUBST(FT2_CFLAGS)
1626 AC_SUBST(FT2_LIBS)
1627
1628 dnl ################################################
1629 dnl # Set defines according to variables set above #
1630 dnl ################################################
1631
1632
1633 if test "x$USE_LIBMMX" = xyes; then
1634   AC_DEFINE(HAVE_LIBMMX, 1, [Define if libmmx is available])
1635 fi
1636
1637 if test "x$USE_ATOMIC_H" = xyes; then
1638   AC_DEFINE(HAVE_ATOMIC_H, 1, [Define if atomic.h header file is available])
1639 fi
1640
1641 # do not use deprecated stuff
1642 GST_CFLAGS="$GST_CFLAGS -DGST_DISABLE_DEPRECATED"
1643
1644 if test "x$USE_DEBUG" = xyes; then
1645   GST_CFLAGS="$GST_CFLAGS -g"
1646 fi
1647
1648 dnl #############################
1649 dnl # Set automake conditionals #
1650 dnl #############################
1651
1652 dnl These should be "USE_*" instead of "HAVE_*", but some packages expect
1653 dnl HAVE_ and it is likely to be easier to stick with the old name
1654 AM_CONDITIONAL(HAVE_LIBMMX,         test "x$USE_LIBMMX" = "xyes")
1655
1656 AM_CONDITIONAL(HAVE_ATOMIC_H,       test "x$USE_ATOMIC_H" = "xyes")
1657
1658 AM_CONDITIONAL(EXPERIMENTAL,        test "$EXPERIMENTAL" = "$xyes")
1659 AM_CONDITIONAL(BROKEN,              test "$BROKEN" = "$xyes")
1660
1661 AM_CONDITIONAL(HAVE_NASM,           test "x$HAVE_NASM" = "xyes")
1662 AM_CONDITIONAL(HAVE_GTK,            test "x$HAVE_GTK" = "xyes")
1663 AM_CONDITIONAL(HAVE_GTK_DOC,        $HAVE_GTK_DOC)
1664 AM_CONDITIONAL(BUILD_DOCS,          test "x$BUILD_DOCS" = "xyes")
1665 AM_CONDITIONAL(BUILD_TESTS,         test "x$BUILD_TESTS" = "xyes")
1666 AM_CONDITIONAL(BUILD_EXAMPLES,      test "x$BUILD_EXAMPLES" = "xyes")
1667 AM_CONDITIONAL(BUILD_PLUGIN_DOCS,   test "x$BUILD_PLUGIN_DOCS" = "xyes")
1668 AM_CONDITIONAL(HAVE_FIG2DEV_PNG,    $HAVE_FIG2DEV_PNG)
1669 AM_CONDITIONAL(HAVE_FIG2DEV_PDF,    $HAVE_FIG2DEV_PDF)
1670 AM_CONDITIONAL(HAVE_RAW1394,        test "x$HAVE_RAW1394" = "xyes")
1671
1672 dnl prefer internal headers to already installed ones
1673 GST_CFLAGS="-I\$(top_srcdir)/gst-libs $GST_CFLAGS $GST_ERROR"
1674
1675 AC_SUBST(GST_LIBS)
1676 AC_SUBST(GST_CFLAGS)
1677
1678 dnl ###########################
1679 dnl # Configure external libs #
1680 dnl ###########################
1681
1682 dnl ############################
1683 dnl # Set up some more defines #
1684 dnl ############################
1685
1686 dnl set license and copyright notice
1687 AC_DEFINE(GST_LICENSE, "LGPL", [GStreamer license])
1688 dnl package name in plugins
1689 AC_ARG_WITH(package-name,
1690 AC_HELP_STRING([--with-package-name],[specify package name to use in plugins]),
1691 [case "${withval}" in
1692   yes) AC_MSG_ERROR(bad value ${withval} for --with-package-name) ;;
1693   no) AC_MSG_ERROR(bad value ${withval} for --with-package-name) ;;
1694   *) GST_PACKAGE="${withval}" ;;
1695 esac],
1696 [GST_PACKAGE="GStreamer Plugins"]) dnl Default value
1697 AC_MSG_NOTICE(Using $GST_PACKAGE as package name)
1698 AC_DEFINE_UNQUOTED(GST_PACKAGE, "$GST_PACKAGE", [package name in plugins])
1699 dnl package origin URL
1700 AC_ARG_WITH(package-origin,
1701 AC_HELP_STRING([--with-package-origin],[specify package origin URL to use in plugins]),
1702 [case "${withval}" in
1703   yes) AC_MSG_ERROR(bad value ${withval} for --with-package-origin) ;;
1704   no) AC_MSG_ERROR(bad value ${withval} for --with-package-origin) ;;
1705   *) GST_ORIGIN="${withval}" ;;
1706 esac],
1707 [GST_ORIGIN="http://gstreamer.net/"]) dnl Default value
1708 AC_MSG_NOTICE(Using $GST_ORIGIN as package origin)
1709 AC_DEFINE_UNQUOTED(GST_ORIGIN, "$GST_ORIGIN", [package origin])
1710
1711 dnl #########################
1712 dnl # Make the output files #
1713 dnl #########################
1714
1715 AC_CONFIG_FILES(
1716 Makefile
1717 gst-plugins.spec
1718 gst/Makefile
1719 gst/ac3parse/Makefile
1720 gst/adder/Makefile
1721 gst/audioconvert/Makefile
1722 gst/audioscale/Makefile
1723 gst/auparse/Makefile
1724 gst/avi/Makefile
1725 gst/asfdemux/Makefile
1726 gst/cdxaparse/Makefile
1727 gst/chart/Makefile
1728 gst/colorspace/Makefile
1729 gst/cutter/Makefile
1730 gst/debug/Makefile
1731 gst/deinterlace/Makefile
1732 gst/effectv/Makefile
1733 gst/festival/Makefile
1734 gst/ffmpegcolorspace/Makefile
1735 gst/filter/Makefile
1736 gst/flx/Makefile
1737 gst/goom/Makefile
1738 gst/interleave/Makefile
1739 gst/law/Makefile
1740 gst/level/Makefile
1741 gst/matroska/Makefile
1742 gst/median/Makefile
1743 gst/mixmatrix/Makefile
1744 gst/mpeg1sys/Makefile
1745 gst/mpeg1videoparse/Makefile
1746 gst/mpeg2sub/Makefile
1747 gst/mpegaudio/Makefile
1748 gst/mpegaudioparse/Makefile
1749 gst/mpegstream/Makefile
1750 gst/modplug/Makefile
1751 gst/modplug/libmodplug/Makefile
1752 gst/monoscope/Makefile
1753 gst/overlay/Makefile
1754 gst/passthrough/Makefile
1755 gst/playondemand/Makefile
1756 gst/qtdemux/Makefile
1757 gst/realmedia/Makefile
1758 gst/rtjpeg/Makefile
1759 gst/rtp/Makefile
1760 gst/silence/Makefile
1761 gst/sine/Makefile
1762 gst/smooth/Makefile
1763 gst/smpte/Makefile
1764 gst/spectrum/Makefile
1765 gst/speed/Makefile
1766 gst/stereo/Makefile
1767 gst/switch/Makefile
1768 gst/synaesthesia/Makefile
1769 gst/tags/Makefile
1770 gst/tcp/Makefile
1771 gst/typefind/Makefile
1772 gst/udp/Makefile
1773 gst/vbidec/Makefile
1774 gst/videocrop/Makefile
1775 gst/videodrop/Makefile
1776 gst/videofilter/Makefile
1777 gst/videoflip/Makefile
1778 gst/videoscale/Makefile
1779 gst/videotestsrc/Makefile
1780 gst/volenv/Makefile
1781 gst/volume/Makefile
1782 gst/wavenc/Makefile
1783 gst/wavparse/Makefile
1784 gst/y4m/Makefile
1785 sys/Makefile
1786 sys/cdrom/Makefile
1787 sys/dxr3/Makefile
1788 sys/glsink/Makefile
1789 sys/oss/Makefile
1790 sys/qcam/Makefile
1791 sys/v4l/Makefile
1792 sys/v4l2/Makefile
1793 sys/vcd/Makefile
1794 sys/ximage/Makefile
1795 sys/xvimage/Makefile
1796 ext/Makefile
1797 ext/a52dec/Makefile
1798 ext/aalib/Makefile
1799 ext/alsa/Makefile
1800 ext/arts/Makefile
1801 ext/artsd/Makefile
1802 ext/audiofile/Makefile
1803 ext/cdparanoia/Makefile
1804 ext/dirac/Makefile
1805 ext/divx/Makefile
1806 ext/dts/Makefile
1807 ext/dv/Makefile
1808 ext/dvdread/Makefile
1809 ext/dvdnav/Makefile
1810 ext/esd/Makefile
1811 ext/faac/Makefile
1812 ext/faad/Makefile
1813 ext/flac/Makefile
1814 ext/gdk_pixbuf/Makefile
1815 ext/gnomevfs/Makefile
1816 ext/gsm/Makefile
1817 ext/hermes/Makefile
1818 dnl ext/http/Makefile
1819 ext/jack/Makefile
1820 ext/jpeg/Makefile
1821 ext/kio/Makefile
1822 ext/ladspa/Makefile
1823 ext/lame/Makefile
1824 ext/ivorbis/Makefile
1825 ext/lcs/Makefile
1826 ext/libcaca/Makefile
1827 ext/libfame/Makefile
1828 ext/libpng/Makefile
1829 ext/librfb/Makefile
1830 ext/libvisual/Makefile
1831 ext/mad/Makefile
1832 ext/mikmod/Makefile
1833 ext/mpeg2dec/Makefile
1834 ext/mpeg2enc/Makefile
1835 ext/mplex/Makefile
1836 ext/musicbrainz/Makefile
1837 ext/nas/Makefile
1838 ext/ogg/Makefile
1839 ext/pango/Makefile
1840 ext/raw1394/Makefile
1841 ext/sdl/Makefile
1842 ext/shout/Makefile
1843 ext/shout2/Makefile
1844 ext/sidplay/Makefile
1845 ext/smoothwave/Makefile
1846 ext/snapshot/Makefile
1847 ext/speex/Makefile
1848 ext/sndfile/Makefile
1849 ext/swfdec/Makefile
1850 ext/tarkin/Makefile
1851 ext/theora/Makefile
1852 ext/vorbis/Makefile
1853 ext/xine/Makefile
1854 ext/xvid/Makefile
1855 gst-libs/Makefile
1856 gst-libs/gst/Makefile
1857 gst-libs/gst/audio/Makefile
1858 gst-libs/gst/colorbalance/Makefile
1859 gst-libs/gst/floatcast/Makefile
1860 gst-libs/gst/gconf/Makefile
1861 gst-libs/gst/idct/Makefile
1862 gst-libs/gst/media-info/Makefile
1863 gst-libs/gst/mixer/Makefile
1864 gst-libs/gst/navigation/Makefile
1865 gst-libs/gst/play/Makefile
1866 gst-libs/gst/propertyprobe/Makefile
1867 gst-libs/gst/resample/Makefile
1868 gst-libs/gst/riff/Makefile
1869 gst-libs/gst/tag/Makefile
1870 gst-libs/gst/tuner/Makefile
1871 gst-libs/gst/video/Makefile
1872 gst-libs/gst/xoverlay/Makefile
1873 gst-libs/gst/xwindowlistener/Makefile
1874 gst-libs/ext/Makefile
1875 examples/dynparams/Makefile
1876 examples/capsfilter/Makefile
1877 examples/seeking/Makefile
1878 examples/indexing/Makefile
1879 examples/gstplay/Makefile
1880 examples/switch/Makefile
1881 examples/Makefile
1882 testsuite/spider/Makefile
1883 testsuite/alsa/Makefile
1884 testsuite/Makefile
1885 tools/Makefile
1886 gconf/Makefile
1887 gconf/gstreamer.schemas
1888 pkgconfig/Makefile
1889 pkgconfig/gstreamer-gconf.pc
1890 pkgconfig/gstreamer-gconf-uninstalled.pc
1891 pkgconfig/gstreamer-interfaces.pc
1892 pkgconfig/gstreamer-interfaces-uninstalled.pc
1893 pkgconfig/gstreamer-libs.pc
1894 pkgconfig/gstreamer-libs-uninstalled.pc
1895 pkgconfig/gstreamer-media-info.pc
1896 pkgconfig/gstreamer-media-info-uninstalled.pc
1897 pkgconfig/gstreamer-play.pc
1898 pkgconfig/gstreamer-play-uninstalled.pc
1899 pkgconfig/gstreamer-plugins.pc
1900 pkgconfig/gstreamer-plugins-uninstalled.pc
1901 po/Makefile.in
1902 common/Makefile
1903 common/m4/Makefile
1904 m4/Makefile
1905 )
1906 AC_OUTPUT
1907
1908 echo -n "configure: *** Plug-ins that will be built :"
1909 echo -e "$GST_PLUGINS_YES" | sort
1910 echo
1911 echo -n "configure: *** Plug-ins that will not be built :"
1912 echo -e "$GST_PLUGINS_NO" | sort
1913 echo
1914 if test "x$BUILD_EXTERNAL" = "xno"; then
1915   echo "configure: *** No external plug-ins will be built"
1916 fi