configure.ac

   1 AC_PREREQ(2.60)
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, git and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for git/pre
   8 AC_INIT(GStreamer Good Plug-ins, 0.11.2.1,
   9     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
  10     gst-plugins-good)
  11
  12 AG_GST_INIT
  13
  14 dnl initialize automake
  15 AM_INIT_AUTOMAKE([-Wno-portability 1.10])
  16
  17 dnl define PACKAGE_VERSION_* variables
  18 AS_VERSION
  19
  20 dnl check if this is a release version
  21 AS_NANO(GST_GIT="no", GST_GIT="yes")
  22
  23 dnl can autoconf find the source ?
  24 AC_CONFIG_SRCDIR([gst/law/alaw.c])
  25
  26 dnl define the output header for config
  27 AM_CONFIG_HEADER([config.h])
  28
  29 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  30 AM_MAINTAINER_MODE
  31
  32 dnl sets host_* variables
  33 AC_CANONICAL_HOST
  34
  35 dnl use pretty build output with automake >= 1.11
  36 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],
  37   [AM_DEFAULT_VERBOSITY=1
  38    AC_SUBST(AM_DEFAULT_VERBOSITY)])
  39
  40 dnl our libraries and install dirs use major.minor as a version
  41 GST_MAJORMINOR=$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR
  42 dnl we override it here if we need to for the release candidate of new series
  43 GST_MAJORMINOR=0.11
  44 AC_SUBST(GST_MAJORMINOR)
  45
  46 AG_GST_LIBTOOL_PREPARE
  47
  48 dnl FIXME: this macro doesn't actually work;
  49 dnl the generated libtool script has no support for the listed tags.
  50 dnl So this needs to be fixed first if we want to use this
  51 dnl AS_LIBTOOL_TAGS
  52
  53 AC_LIBTOOL_WIN32_DLL
  54 AM_PROG_LIBTOOL
  55
  56 dnl *** required versions of GStreamer stuff ***
  57 GST_REQ=0.11.3
  58 GSTPB_REQ=0.11.3
  59
  60 dnl *** autotools stuff ****
  61
  62 dnl allow for different autotools
  63 AS_AUTOTOOLS_ALTERNATE
  64
  65 dnl Add parameters for aclocal
  66 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  67
  68 dnl set up gettext
  69 dnl the version check needs to stay here because autopoint greps for it
  70 AM_GNU_GETTEXT_VERSION([0.17])
  71 AM_GNU_GETTEXT([external])
  72 AG_GST_GETTEXT([gst-plugins-good-$GST_MAJORMINOR])
  73
  74 dnl *** check for arguments to configure ***
  75
  76 AG_GST_ARG_DISABLE_FATAL_WARNINGS
  77
  78 AG_GST_ARG_DEBUG
  79 AG_GST_ARG_PROFILING
  80 AG_GST_ARG_VALGRIND
  81 AG_GST_ARG_GCOV
  82
  83 AG_GST_ARG_EXAMPLES
  84
  85 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  86 AG_GST_ARG_WITH_PACKAGE_NAME
  87 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  88
  89 AG_GST_ARG_WITH_PLUGINS
  90
  91 AG_GST_ARG_ENABLE_EXTERNAL
  92
  93 AG_GST_ARG_ENABLE_EXPERIMENTAL
  94
  95 dnl *** checks for platform ***
  96
  97 dnl * hardware/architecture *
  98
  99 dnl common/m4/gst-arch.m4
 100 dnl check CPU type
 101 AG_GST_ARCH
 102
 103 dnl Determine endianness
 104 AC_C_BIGENDIAN
 105
 106 dnl *** checks for programs ***
 107
 108 dnl find a compiler
 109 AC_PROG_CC
 110 AC_PROG_CC_STDC
 111
 112 dnl determine c++ compiler
 113 AC_PROG_CXX
 114 dnl determine if c++ is available on this system
 115 AC_CHECK_PROG(HAVE_CXX, $CXX, yes, no)
 116
 117 dnl determine c++ preprocessor
 118 dnl FIXME: do we need this ?
 119 AC_PROG_CXXCPP
 120
 121 AS_PROG_OBJC
 122
 123 dnl check if the compiler supports '-c' and '-o' options
 124 AM_PROG_CC_C_O
 125
 126 dnl find an assembler
 127 AM_PROG_AS
 128
 129 dnl check if the compiler supports do while(0) macros
 130 AG_GST_CHECK_DOWHILE_MACROS
 131
 132 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 133 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 134
 135 dnl check for documentation tools
 136 GTK_DOC_CHECK([1.3])
 137 AS_PATH_PYTHON([2.1])
 138 AG_GST_PLUGIN_DOCS([1.3],[2.1])
 139
 140 dnl *** checks for libraries ***
 141
 142 dnl check for libm, for sin()
 143 AC_CHECK_LIBM
 144 AC_SUBST(LIBM)
 145
 146 dnl *** checks for header files ***
 147
 148 dnl check if we have ANSI C header files
 149 AC_HEADER_STDC
 150
 151 dnl used by ext/wavpack
 152 AX_CREATE_STDINT_H
 153
 154 dnl used in gst/udp
 155 AC_CHECK_HEADERS([sys/time.h])
 156
 157 dnl used in gst/udp
 158 AC_CHECK_HEADERS([sys/socket.h])
 159
 160 dnl *** checks for types/defines ***
 161
 162 dnl Check for FIONREAD ioctl declaration.  This check is needed
 163 dnl for the UDP plugin to build on Solaris
 164 GST_CHECK_FIONREAD
 165
 166 dnl *** checks for structures ***
 167
 168 dnl *** checks for compiler characteristics ***
 169
 170 dnl check if we have GCC inline-asm
 171 AS_GCC_INLINE_ASSEMBLY([HAVE_GCC_ASM=yes], [HAVE_GCC_ASM=no])
 172 if test x$HAVE_GCC_ASM = xyes ; then
 173   AC_DEFINE(HAVE_GCC_ASM, 1,
 174     [Define if compiler supports gcc inline assembly])
 175 fi
 176 AM_CONDITIONAL(HAVE_GCC_ASM, test "x$HAVE_GCC_ASM" = "xyes")
 177
 178 dnl *** checks for library functions ***
 179
 180 LIBS_SAVE=$LIBS
 181 LIBS="$LIBS $LIBM"
 182 AC_CHECK_FUNCS(rint sinh cosh asinh fpclass)
 183 LIBS=$LIBS_SAVE
 184
 185 dnl Check whether isinf() is defined by math.h
 186 AC_CACHE_CHECK([for isinf], ac_cv_have_isinf,
 187     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>]], [[float f = 0.0; int i=isinf(f)]])],[ac_cv_have_isinf="yes"],[ac_cv_have_isinf="no"]))
 188 if test "$ac_cv_have_isinf" = "yes"
 189 then
 190     AC_DEFINE(HAVE_ISINF, 1, [Define to 1 if you have the `isinf' function.])
 191 fi
 192
 193 dnl Check for mmap (needed by electricfence plugin)
 194 AC_FUNC_MMAP
 195 AM_CONDITIONAL(GST_HAVE_MMAP, test "x$ac_cv_func_mmap_fixed_mapped" = "xyes")
 196
 197 dnl Check for mmap (needed by electricfence plugin)
 198
 199 AC_CHECK_TYPE([struct ip_mreqn], [
 200               AC_DEFINE(HAVE_IP_MREQN,, [Define if we have struct ip_mreqn])],,
 201               [#include <netinet/in.h>])
 202
 203 dnl *** checks for dependency libraries ***
 204
 205
 206 dnl GLib
 207 GLIB_REQ=2.31.14
 208 AG_GST_GLIB_CHECK([$GLIB_REQ])
 209
 210 dnl Orc
 211 ORC_CHECK([0.4.11])
 212
 213 dnl checks for gstreamer
 214 dnl uninstalled is selected preferentially -- see pkg-config(1)
 215 AG_GST_CHECK_GST($GST_MAJORMINOR, [$GST_REQ], yes)
 216 AG_GST_CHECK_GST_BASE($GST_MAJORMINOR, [$GST_REQ], yes)
 217 AG_GST_CHECK_GST_CONTROLLER($GST_MAJORMINOR, [$GST_REQ], yes)
 218 AG_GST_CHECK_GST_NET($GST_MAJORMINOR, [$GST_REQ], yes)
 219 AG_GST_CHECK_GST_CHECK($GST_MAJORMINOR, [$GST_REQ], no)
 220 AG_GST_CHECK_GST_PLUGINS_BASE($GST_MAJORMINOR, [$GSTPB_REQ], yes)
 221
 222 GST_TOOLS_DIR=`$PKG_CONFIG --variable=toolsdir gstreamer-$GST_MAJORMINOR`
 223 if test -z $GST_TOOLS_DIR; then
 224   AC_MSG_ERROR([no tools dir defined in GStreamer pkg-config file; core upgrade needed.])
 225 fi
 226 AC_SUBST(GST_TOOLS_DIR)
 227
 228 AC_MSG_NOTICE(Using GStreamer Core Plugins in $GST_PLUGINS_DIR)
 229 AC_MSG_NOTICE(Using GStreamer Base Plugins in $GSTPB_PLUGINS_DIR)
 230
 231 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 232
 233 dnl Check for documentation xrefs
 234 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 235 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_MAJORMINOR`"
 236 GSTPB_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-plugins-base-$GST_MAJORMINOR`"
 237 AC_SUBST(GLIB_PREFIX)
 238 AC_SUBST(GST_PREFIX)
 239 AC_SUBST(GSTPB_PREFIX)
 240
 241 dnl GTK is optional and used in examples
 242 HAVE_GTK=no
 243 GTK2_REQ=2.14.0
 244 GTK3_REQ=2.91.3
 245 if test "x$BUILD_EXAMPLES" = "xyes"; then
 246   AC_MSG_CHECKING([which gtk+ version to compile examples against (optional)])
 247   AC_ARG_WITH([gtk],
 248     AC_HELP_STRING([--with-gtk=3.0|2.0],
 249                    [which gtk+ version to compile against (default: 2.0)]),
 250     [case "$with_gtk" in
 251         2.0) GTK_REQ=$GTK2_REQ ;;
 252         3.0) GTK_REQ=$GTK3_REQ ;;
 253         *) AC_MSG_ERROR([invalid gtk+ version specified]);;
 254     esac],
 255     [with_gtk=2.0
 256      GTK_REQ=$GTK2_REQ])
 257   AC_MSG_RESULT([$with_gtk (>= $GTK_REQ)])
 258   PKG_CHECK_MODULES(GTK, gtk+-$with_gtk >= $GTK_REQ, HAVE_GTK=yes, HAVE_GTK=no)
 259   dnl some examples need gtk+-x11
 260   PKG_CHECK_MODULES(GTK_X11, gtk+-x11-$with_gtk >= $GTK_REQ, HAVE_GTK_X11=yes, HAVE_GTK_X11=no)
 261   AC_SUBST(GTK_LIBS)
 262   AC_SUBST(GTK_CFLAGS)
 263 fi
 264 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 265 AM_CONDITIONAL(HAVE_GTK_X11, test "x$HAVE_GTK_X11" = "xyes")
 266
 267 dnl *** set variables based on configure arguments ***
 268
 269 dnl set license and copyright notice
 270 GST_LICENSE="LGPL"
 271 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 272 AC_SUBST(GST_LICENSE)
 273
 274 dnl set location of plugin directory
 275 AG_GST_SET_PLUGINDIR
 276
 277 dnl set release date/time
 278 AG_GST_SET_PACKAGE_RELEASE_DATETIME_WITH_NANO([$PACKAGE_VERSION_NANO],
 279   ["${srcdir}/gst-plugins-good.doap"],
 280   [$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_MICRO])
 281
 282 dnl define an ERROR_CFLAGS Makefile variable
 283 dnl -Wundef: too many broken headers
 284 if test "x$HAVE_OSX_VIDEO" != "xyes"; then
 285   AG_GST_SET_ERROR_CFLAGS($FATAL_WARNINGS, [
 286         -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls
 287         -Wwrite-strings -Wold-style-definition -Waggregate-return
 288         -Winit-self -Wmissing-include-dirs -Waddress -Wno-multichar
 289         -Wnested-externs ])
 290 else
 291   dnl work-around for us passing GST_CFLAGS to the ObjC-compiler, which
 292   dnl doesn't understand all warning flags that the C compiler knows about
 293   dnl (e.g. -Waddress) or causes problems with some flags (-Waggregate-return)
 294   AG_GST_SET_ERROR_CFLAGS($FATAL_WARNINGS, [
 295         -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls
 296         -Wwrite-strings -Wold-style-definition
 297         -Winit-self -Wmissing-include-dirs -Wno-multichar
 298         -Wnested-externs ])
 299 fi
 300
 301 dnl define an ERROR_CXXFLAGS Makefile variable
 302 AG_GST_SET_ERROR_CXXFLAGS($FATAL_WARNINGS, [
 303         -Wmissing-declarations -Wredundant-decls
 304         -Wwrite-strings
 305         -Winit-self -Wmissing-include-dirs -Waddress -Wno-multichar ])
 306
 307 dnl define correct level for debugging messages
 308 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 309
 310 dnl used in examples
 311 AG_GST_DEFAULT_ELEMENTS
 312
 313 dnl *** plug-ins to include ***
 314
 315 dnl Non ported plugins (non-dependant, then dependant)
 316 dnl Make sure you have a space before and after all plugins
 317 GST_PLUGINS_NONPORTED="deinterlace interleave flx \
 318  videobox \
 319  cairo cairo_gobject dv1394 gdk_pixbuf \
 320  oss oss4 \
 321  osx_video osx_audio "
 322 AC_SUBST(GST_PLUGINS_NONPORTED)
 323
 324 dnl these are all the gst plug-ins, compilable without additional libs
 325 dnl videofilter is at the top because others depend on it
 326 AG_GST_CHECK_PLUGIN(alpha)
 327 AG_GST_CHECK_PLUGIN(apetag)
 328 AG_GST_CHECK_PLUGIN(audiofx)
 329 AG_GST_CHECK_PLUGIN(audioparsers)
 330 AG_GST_CHECK_PLUGIN(auparse)
 331 AG_GST_CHECK_PLUGIN(autodetect)
 332 AG_GST_CHECK_PLUGIN(avi)
 333 AG_GST_CHECK_PLUGIN(cutter)
 334 AG_GST_CHECK_PLUGIN(debugutils)
 335 AG_GST_CHECK_PLUGIN(deinterlace)
 336 AG_GST_CHECK_PLUGIN(effectv)
 337 AG_GST_CHECK_PLUGIN(equalizer)
 338 AG_GST_CHECK_PLUGIN(flv)
 339 AG_GST_CHECK_PLUGIN(flx)
 340 AG_GST_CHECK_PLUGIN(goom)
 341 AG_GST_CHECK_PLUGIN(goom2k1)
 342 AG_GST_CHECK_PLUGIN(icydemux)
 343 AG_GST_CHECK_PLUGIN(id3demux)
 344 AG_GST_CHECK_PLUGIN(imagefreeze)
 345 AG_GST_CHECK_PLUGIN(interleave)
 346 AG_GST_CHECK_PLUGIN(isomp4)
 347 AG_GST_CHECK_PLUGIN(law)
 348 AG_GST_CHECK_PLUGIN(level)
 349 AG_GST_CHECK_PLUGIN(matroska)
 350 AG_GST_CHECK_PLUGIN(monoscope)
 351 AG_GST_CHECK_PLUGIN(multifile)
 352 AG_GST_CHECK_PLUGIN(multipart)
 353 AG_GST_CHECK_PLUGIN(replaygain)
 354 AG_GST_CHECK_PLUGIN(rtp)
 355 AG_GST_CHECK_PLUGIN(rtpmanager)
 356 AG_GST_CHECK_PLUGIN(rtsp)
 357 AG_GST_CHECK_PLUGIN(shapewipe)
 358 AG_GST_CHECK_PLUGIN(smpte)
 359 AG_GST_CHECK_PLUGIN(spectrum)
 360 AG_GST_CHECK_PLUGIN(udp)
 361 AG_GST_CHECK_PLUGIN(videobox)
 362 AG_GST_CHECK_PLUGIN(videocrop)
 363 AG_GST_CHECK_PLUGIN(videofilter)
 364 AG_GST_CHECK_PLUGIN(videomixer)
 365 AG_GST_CHECK_PLUGIN(wavenc)
 366 AG_GST_CHECK_PLUGIN(wavparse)
 367 AG_GST_CHECK_PLUGIN(y4m)
 368
 369 dnl disable experimental plug-ins
 370 if test "x$BUILD_EXPERIMENTAL" != "xyes"; then
 371   AG_GST_DISABLE_PLUGIN(monoscope)
 372 fi
 373
 374 dnl *** sys plug-ins ***
 375
 376 echo
 377 AC_MSG_NOTICE([Checking libraries for plugins in sys/])
 378 echo
 379
 380 dnl DirectSound
 381 translit(dnm, m, l) AM_CONDITIONAL(USE_DIRECTSOUND, true)
 382 AG_GST_CHECK_FEATURE(DIRECTSOUND, [DirectSound plug-in], directsoundsink, [
 383   HAVE_DIRECTSOUND="no"
 384   save_CFLAGS="$CFLAGS"
 385   save_LDFLAGS="$LDFLAGS"
 386   save_LIBS="$LIBS"
 387   CFLAGS="$CFLAGS $DIRECTSOUND_CFLAGS"
 388   LDFLAGS="$LDFLAGS $DIRECTSOUND_LDFLAGS"
 389   LIBS="$LIBS -ldsound -ldxerr9 -luser32"
 390   AC_MSG_CHECKING(for DirectSound LDFLAGS)
 391   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 392 #include <windows.h>
 393 #include <dxerr9.h>
 394 #include <dsound.h>
 395 ]], [[
 396   DXGetErrorString9 (0);
 397   DirectSoundCreate(NULL, NULL, NULL);
 398 ]])
 399 ],
 400     [HAVE_DIRECTSOUND="yes"],
 401     [HAVE_DIRECTSOUND="no"])
 402   AC_MSG_RESULT($HAVE_DIRECTSOUND)
 403   CFLAGS=$save_CFLAGS
 404   LDFLAGS=$save_LDFLAGS
 405   LIBS=$save_LIBS
 406
 407   if test "x$HAVE_DIRECTSOUND" = "xyes";  then
 408     dnl this is much more than we want
 409     DIRECTSOUND_LIBS="-ldsound -ldxerr9 -luser32"
 410     AC_SUBST(DIRECTSOUND_CFLAGS)
 411     AC_SUBST(DIRECTSOUND_LDFLAGS)
 412     AC_SUBST(DIRECTSOUND_LIBS)
 413   fi
 414   AC_SUBST(HAVE_DIRECTSOUND)
 415 ])
 416
 417 dnl *** Win32 WaveOut ***
 418 translit(dnm, m, l) AM_CONDITIONAL(USE_WAVEFORM, true)
 419 AG_GST_CHECK_FEATURE(WAVEFORM, [Win32 WaveForm], waveformsink, [
 420   AC_CHECK_HEADER(mmsystem.h, HAVE_WAVEFORM="yes", HAVE_WAVEFORM="no", [#include <windows.h>])
 421 ])
 422
 423 dnl *** OSS audio *** (Linux, *BSD)
 424 translit(dnm, m, l) AM_CONDITIONAL(USE_OSS, true)
 425 AG_GST_CHECK_FEATURE(OSS, [OSS audio], ossaudio, [
 426  HAVE_OSS="yes"
 427 dnl Linux and newer BSD versions :
 428  AC_CHECK_HEADER(sys/soundcard.h, [
 429    AC_DEFINE(HAVE_OSS_INCLUDE_IN_SYS,, [Define if OSS includes are in /sys/])
 430    ] , [
 431 dnl Some old BSD versions and also newer OpenBSD versions :
 432    AC_CHECK_HEADER(soundcard.h, [
 433      AC_DEFINE(HAVE_OSS_INCLUDE_IN_ROOT,, [Define if OSS includes are in /])
 434      ], [
 435   dnl Some old BSD versions :
 436      AC_CHECK_HEADER(machine/soundcard.h, [
 437        AC_DEFINE(HAVE_OSS_INCLUDE_IN_MACHINE,,
 438          [Define if OSS includes are in /machine/])
 439        ], [
 440        HAVE_OSS="no"
 441      ])
 442    ])
 443  ])
 444 ])
 445
 446 dnl *** oss4 ***
 447 translit(dnm, m, l) AM_CONDITIONAL(USE_OSS4, true)
 448 AG_GST_CHECK_FEATURE(OSS4, [Open Sound System 4], oss4, [
 449   AC_MSG_CHECKING([Checking if we can build the OSS4 elements])
 450   AC_CHECK_HEADERS([fcntl.h sys/ioctl.h sys/stat.h sys/types.h],
 451       [test -z "$OSS4_MISSING_HEADER" && HAVE_OSS4="yes"],
 452       [OSS4_MISSING_HEADER="yes";HAVE_OSS4="no"])
 453 ])
 454
 455 dnl *** Sun Audio ***
 456 translit(dnm, m, l) AM_CONDITIONAL(USE_SUNAUDIO, true)
 457 AG_GST_CHECK_FEATURE(SUNAUDIO, [Sun Audio], sunaudio, [
 458   AC_CHECK_HEADER(sys/audioio.h, HAVE_SUNAUDIO="yes", HAVE_SUNAUDIO="no")
 459 ])
 460
 461 dnl *** OSX Audio ***
 462 translit(dnm, m, l) AM_CONDITIONAL(USE_OSX_AUDIO, true)
 463 AG_GST_CHECK_FEATURE(OSX_AUDIO, [OSX audio], osxaudio, [
 464   AC_CHECK_HEADER(CoreAudio/CoreAudio.h, HAVE_OSX_AUDIO="yes", HAVE_OSX_AUDIO="no")
 465 ])
 466
 467 dnl *** OS X video ***
 468 translit(dnm, m, l) AM_CONDITIONAL(USE_OSX_VIDEO, true)
 469 HAVE_OSX_VIDEO="no"
 470 AG_GST_CHECK_FEATURE(OSX_VIDEO, [OSX video], osxvideosink, [
 471   AC_CHECK_HEADER(OpenGL/gl.h, HAVE_OSX_VIDEO="yes", HAVE_OSX_VIDEO="no")
 472 ])
 473 dnl in case header OpenGL/gl.h is found on other platforms
 474 case "$host" in
 475   *-*darwin*)
 476     dnl do nothing
 477     ;;
 478   *)
 479     HAVE_OSX_VIDEO="no"
 480     ;;
 481 esac
 482
 483
 484 dnl *** Video 4 Linux 2 ***
 485 dnl for information about the header/define, see sys/v4l2/gstv4l2element.h
 486 dnl renamed to GST_V4L2 because of some conflict with kernel headers
 487 translit(dnm, m, l) AM_CONDITIONAL(USE_GST_V4L2, true)
 488 AG_GST_CHECK_FEATURE(GST_V4L2, [Video 4 Linux 2], v4l2src, [
 489   AC_MSG_CHECKING([Checking for up to date v4l2 installation])
 490   AC_TRY_COMPILE([
 491 #include <sys/types.h>
 492 #ifdef __sun /* Solaris */
 493 #include <sys/types.h>
 494 #include <sys/videodev2.h>
 495 #else /* Linux */
 496 #include <linux/types.h>
 497 #define _LINUX_TIME_H
 498 #define __user
 499 #include <linux/videodev2.h>
 500 #endif
 501 #if defined(V4L2_MAJOR_VERSION) || defined(V4L2_MINOR_VERSION)
 502 #error too early v4l2 version or no v4l2 at all
 503 #endif
 504     ], [
 505 return 0;
 506     ], [
 507       HAVE_GST_V4L2="yes"
 508       AC_MSG_RESULT(yes)
 509     ], [
 510       HAVE_GST_V4L2="no"
 511       AC_MSG_RESULT(no)
 512
 513       HAVE_VIDEODEV=no
 514       AC_CHECK_HEADER(linux/videodev2.h, [ HAVE_VIDEODEV=yes ],
 515       [
 516         AC_CHECK_HEADER(sys/videodev2.h, [ HAVE_VIDEODEV=yes ])
 517       ])
 518
 519       if test "x$HAVE_VIDEODEV" = "xyes"; then
 520         AC_MSG_WARN([video4linux2 headers were found, but they're old.])
 521         AC_MSG_WARN([Please update v4l2 to compile the v4l2 plugins])
 522       else
 523         AC_MSG_WARN([video4linux2 was not found])
 524       fi
 525     ])
 526
 527   if [ test x$HAVE_GST_V4L2 = xyes ]; then
 528     dnl check for missing v4l2_buffer declaration (see #135919)
 529     MISSING_DECL=0
 530     AC_MSG_CHECKING(struct v4l2_buffer declaration)
 531     AC_TRY_COMPILE([
 532 #include <sys/types.h>
 533 #ifdef __sun /* Solaris */
 534 #include <sys/types.h>
 535 #include <sys/videodev2.h>
 536 #else /* Linux */
 537 #include <linux/types.h>
 538 #define _LINUX_TIME_H
 539 #define __user
 540 #include <linux/videodev2.h>
 541 #endif
 542     ],[
 543 struct v4l2_buffer buf;
 544 buf.index = 0;
 545 return 0;
 546     ], [ AC_MSG_RESULT(yes) ], [ MISSING_DECL=1 && AC_MSG_RESULT(no) ])
 547     if [ test x$MISSING_DECL = x1 ]; then
 548       AC_DEFINE(GST_V4L2_MISSING_BUFDECL, 1, [struct v4l2_buffer missing])
 549     fi
 550
 551     dnl check for XOverlay libraries
 552     AG_GST_CHECK_XV
 553   fi
 554 ])
 555
 556 # Optional gudev for device probing
 557 AC_ARG_WITH([gudev],
 558   AC_HELP_STRING([--with-gudev],
 559     [device detection with gudev]),
 560   [],
 561   [with_gudev=check])
 562 if test x$HAVE_GST_V4L2 = xyes; then
 563   if test x$with_gudev != xno; then
 564       PKG_CHECK_MODULES(GUDEV, [ gudev-1.0 >= 143 ],
 565           [ have_gudev=yes
 566             AC_DEFINE(HAVE_GUDEV, 1,
 567                [Whether gudev is available for device detection])
 568             AC_DEFINE([G_UDEV_API_IS_SUBJECT_TO_CHANGE], 1, [I know the API is subject to change.])
 569           ], [
 570           have_gudev=no
 571           ])
 572   else
 573     have_gudev=no
 574   fi
 575 fi
 576 AC_SUBST(GUDEV_CFLAGS)
 577 AC_SUBST(GUDEV_LIBS)
 578
 579 # Make libv4l2 non-automagic
 580 AC_ARG_WITH([libv4l2],
 581   AC_HELP_STRING([--with-libv4l2],
 582     [support video buffer conversion using libv4l2]),
 583   [],
 584   [with_libv4l2=check])
 585 if test x$HAVE_GST_V4L2 = xyes; then
 586   if test x$with_libv4l2 != xno; then
 587       PKG_CHECK_MODULES(LIBV4L2, libv4l2,
 588           [ have_libv4l2=yes
 589             AC_DEFINE(HAVE_LIBV4L2, 1,
 590                 [Whether libv4l2 is available for video buffer conversion])
 591           ], [
 592           have_libv4l2=no
 593           ])
 594   else
 595     have_libv4l2=no
 596   fi
 597 fi
 598
 599 dnl Check for X11
 600 translit(dnm, m, l) AM_CONDITIONAL(USE_X, true)
 601 AG_GST_CHECK_FEATURE(X, [X libraries and plugins],
 602                   [ximagesrc], [
 603   AC_PATH_XTRA
 604
 605   dnl now try to find the HEADER
 606   ac_cflags_save="$CFLAGS"
 607   ac_cppflags_save="$CPPFLAGS"
 608   CFLAGS="$CFLAGS $X_CFLAGS"
 609   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 610   AC_CHECK_HEADER(X11/Xlib.h, HAVE_X="yes", HAVE_X="no")
 611
 612   if test "x$HAVE_X" = "xno"
 613   then
 614     AC_MSG_NOTICE([cannot find X11 development files])
 615   else
 616     dnl this is much more than we want
 617     X_LIBS="$X_LIBS $X_PRE_LIBS $X_EXTRA_LIBS"
 618     dnl AC_PATH_XTRA only defines the path needed to find the X libs,
 619     dnl it does not add the libs; therefore we add them here
 620     X_LIBS="$X_LIBS -lX11"
 621     AC_SUBST(X_CFLAGS)
 622     AC_SUBST(X_LIBS)
 623
 624     dnl check for Xfixes
 625     PKG_CHECK_MODULES(XFIXES, xfixes, HAVE_XFIXES="yes", HAVE_XFIXES="no")
 626     if test "x$HAVE_XFIXES" = "xyes"
 627     then
 628         XFIXES_CFLAGS="-DHAVE_XFIXES $XFIXES_CFLAGS"
 629     fi
 630     AC_SUBST(XFIXES_LIBS)
 631     AC_SUBST(XFIXES_CFLAGS)
 632
 633     dnl check for Xdamage
 634     PKG_CHECK_MODULES(XDAMAGE, xdamage, HAVE_XDAMAGE="yes", HAVE_XDAMAGE="no")
 635     if test "x$HAVE_XDAMAGE" = "xyes"
 636     then
 637         XDAMAGE_CFLAGS="-DHAVE_XDAMAGE $XDAMAGE_CFLAGS"
 638     fi
 639     AC_SUBST(XDAMAGE_LIBS)
 640     AC_SUBST(XDAMAGE_CFLAGS)
 641   fi
 642   AC_SUBST(HAVE_X)
 643   CFLAGS="$ac_cflags_save"
 644   CPPFLAGS="$ac_cppflags_save"
 645 ])
 646
 647 dnl FIXME: this should be rolled into the test above, it's just an additional
 648 dnl feature of the ximagesrc plug-in
 649 dnl This is the same as in gst-plugins-base
 650 dnl check for X Shm
 651 translit(dnm, m, l) AM_CONDITIONAL(USE_XSHM, true)
 652 AG_GST_CHECK_FEATURE(XSHM, [X Shared Memory extension], , [
 653   if test x$HAVE_X = xyes; then
 654     AC_CHECK_LIB(Xext, XShmAttach,
 655                  HAVE_XSHM="yes", HAVE_XSHM="no",
 656                  $X_LIBS)
 657     if test "x$HAVE_XSHM" = "xyes"; then
 658       XSHM_LIBS="-lXext"
 659     else
 660       dnl On AIX, it is in XextSam instead, but we still need -lXext
 661       AC_CHECK_LIB(XextSam, XShmAttach,
 662                    HAVE_XSHM="yes", HAVE_XSHM="no",
 663                    $X_LIBS)
 664       if test "x$HAVE_XSHM" = "xyes"; then
 665         XSHM_LIBS="-lXext -lXextSam"
 666       fi
 667     fi
 668   fi
 669 ], ,[
 670   AC_SUBST(HAVE_XSHM)
 671   AC_SUBST(XSHM_LIBS)
 672 ])
 673
 674 dnl for V4L2, we also need to know if we have XVIDEO
 675 translit(dnm, m, l) AM_CONDITIONAL(USE_XVIDEO, true)
 676 AG_GST_CHECK_FEATURE(XVIDEO, [X11 XVideo extensions],
 677                   [], [
 678   AG_GST_CHECK_XV
 679 ])
 680
 681 dnl *** ext plug-ins ***
 682 dnl keep this list sorted alphabetically !
 683
 684 if test "x$BUILD_EXTERNAL" = "xyes"; then
 685
 686 echo
 687 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 688 echo
 689
 690 dnl *** aalib ***
 691 translit(dnm, m, l) AM_CONDITIONAL(USE_AALIB, true)
 692 AG_GST_CHECK_FEATURE(AALIB, [aalib ASCII Art library], aasink, [
 693   AM_PATH_AALIB(, HAVE_AALIB=yes, HAVE_AALIB=no)
 694   AS_SCRUB_INCLUDE(AALIB_CFLAGS)
 695 ])
 696
 697 dnl *** annodex ***
 698 translit(dnm, m, l) AM_CONDITIONAL(USE_ANNODEX, true)
 699 AG_GST_CHECK_FEATURE(ANNODEX, [XML library], annodex, [
 700   AG_GST_PKG_CHECK_MODULES(ANNODEX, libxml-2.0 >= 2.4.9)
 701 ])
 702
 703 dnl *** cairo ***
 704 translit(dnm, m, l) AM_CONDITIONAL(USE_CAIRO, true)
 705 AG_GST_CHECK_FEATURE(CAIRO, [Cairo graphics rendering], cairo, [
 706   AG_GST_PKG_CHECK_MODULES(CAIRO, cairo >= 1.0.0)
 707 ])
 708
 709 dnl *** cairo-gobject ***
 710 translit(dnm, m, l) AM_CONDITIONAL(USE_CAIRO_GOBJECT, true)
 711 AG_GST_CHECK_FEATURE(CAIRO_GOBJECT,
 712   [Cairo graphics rendering gobject bindings], cairooverlay, [
 713   AG_GST_PKG_CHECK_MODULES(CAIRO_GOBJECT, cairo-gobject >= 1.10.0)
 714 ])
 715
 716 dnl *** FLAC ***
 717 translit(dnm, m, l) AM_CONDITIONAL(USE_FLAC, true)
 718 AG_GST_CHECK_FEATURE(FLAC, [FLAC lossless audio], flac, [
 719   AG_GST_PKG_CHECK_MODULES(FLAC, flac >= 1.1.4)
 720 ])
 721
 722 dnl *** GDK pixbuf ***
 723 translit(dnm, m, l) AM_CONDITIONAL(USE_GDK_PIXBUF, true)
 724 AG_GST_CHECK_FEATURE(GDK_PIXBUF, [GDK pixbuf], gdkpixbuf, [
 725   AG_GST_PKG_CHECK_MODULES(GDK_PIXBUF, gdk-pixbuf-2.0 >= 2.8.0)
 726 ])
 727
 728 dnl *** Jack ***
 729 translit(dnm, m, l) AM_CONDITIONAL(USE_JACK, true)
 730 AG_GST_CHECK_FEATURE(JACK, Jack, jack, [
 731   PKG_CHECK_MODULES(JACK, jack >= 0.99.10, HAVE_JACK="yes", HAVE_JACK="no")
 732   AC_SUBST(JACK_CFLAGS)
 733   AC_SUBST(JACK_LIBS)
 734
 735   AG_GST_PKG_CHECK_MODULES(JACK_0_120_1, jack >= 0.120.1 jack < 1.0)
 736   if test x$HAVE_JACK_0_120_1 = xyes; then
 737     AC_DEFINE(HAVE_JACK_0_120_1, 1, [defined if jack >= 0.120.1 is available])
 738   fi
 739   AG_GST_PKG_CHECK_MODULES(JACK_1_9_7, jack >= 1.9.7)
 740   if test x$HAVE_JACK_1_9_7 = xyes; then
 741     AC_DEFINE(HAVE_JACK_1_9_7, 1, [defined if jack >= 1.9.7 is available])
 742   fi
 743
 744 ])
 745
 746 dnl *** jpeg ***
 747 dnl FIXME: we could use header checks here as well IMO
 748 translit(dnm, m, l) AM_CONDITIONAL(USE_JPEG, true)
 749 AG_GST_CHECK_FEATURE(JPEG, [jpeg library], jpeg, [
 750   AC_ARG_WITH(jpeg-mmx,
 751     [  --with-jpeg-mmx, path to MMX'ified JPEG library])
 752   OLD_LIBS="$LIBS"
 753   if test x$with_jpeg_mmx != x; then
 754     LIBS="$LIBS -L$with_jpeg_mmx"
 755   fi
 756   AC_CHECK_LIB(jpeg-mmx, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
 757   JPEG_LIBS="$LIBS -ljpeg-mmx"
 758   LIBS="$OLD_LIBS"
 759   if test x$HAVE_JPEG != xyes; then
 760     AC_CHECK_LIB(jpeg, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
 761     JPEG_LIBS="-ljpeg"
 762   fi
 763   AC_SUBST(JPEG_LIBS)
 764 ])
 765
 766 dnl *** libcaca ***
 767 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBCACA, true)
 768 AG_GST_CHECK_FEATURE(LIBCACA, [libcaca coloured ASCII art], cacasink, [
 769   AG_GST_PKG_CHECK_MODULES(LIBCACA, caca)
 770 ])
 771
 772 dnl *** libdv ***
 773 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBDV, true)
 774 AG_GST_CHECK_FEATURE(LIBDV, [libdv DV demuxer/decoder], dv, [
 775   AG_GST_PKG_CHECK_MODULES(LIBDV, libdv >= 0.100)
 776 ])
 777
 778 dnl *** libpng ***
 779 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBPNG, true)
 780 AG_GST_CHECK_FEATURE(LIBPNG, [Portable Network Graphics library], png, [
 781   AG_GST_PKG_CHECK_MODULES(LIBPNG, libpng >= 1.2)
 782 ])
 783
 784 dnl *** pulseaudio ***
 785 translit(dnm, m, l) AM_CONDITIONAL(USE_PULSE, true)
 786 AG_GST_CHECK_FEATURE(PULSE, [pulseaudio plug-in], pulseaudio, [
 787
 788   dnl used in ext/pulse/pulseutil.c
 789   AC_CHECK_HEADERS([process.h])
 790
 791   AG_GST_PKG_CHECK_MODULES(PULSE, libpulse >= 1.0)
 792 ])
 793
 794 dnl *** dv1394 ***
 795 translit(dnm, m, l) AM_CONDITIONAL(USE_DV1394, true)
 796 AG_GST_CHECK_FEATURE(DV1394, [raw1394 and avc1394 library], 1394, [
 797   dnl first test for libraw1394 >= 2.0.0
 798   AG_GST_PKG_CHECK_MODULES(RAW1394, libraw1394 >= 2.0.0)
 799   AG_GST_PKG_CHECK_MODULES(LIBIEC61883, libiec61883 >= 1.0.0)
 800   dnl now see how far we got
 801   if test x$HAVE_RAW1394 = xyes && \
 802      test x$HAVE_LIBIEC61883 = xyes; then
 803        AG_GST_CHECK_LIBHEADER(AVC1394,
 804         avc1394, avc1394_send_command, $RAW1394_LIBS,
 805         libavc1394/avc1394.h, AVC1394_LIBS="-lavc1394")
 806        AG_GST_CHECK_LIBHEADER(ROM1394,
 807         rom1394, rom1394_free_directory, $RAW1394_LIBS,
 808         libavc1394/rom1394.h, ROM1394_LIBS="-lrom1394")
 809        if test x$HAVE_AVC1394 = xyes && \
 810           test x$HAVE_AVC1394 = xyes && \
 811           test x$HAVE_ROM1394 = xyes; then
 812           HAVE_DV1394=yes
 813           DV1394_LIBS="$RAW1394_LIBS $AVC1394_LIBS $ROM1394_LIBS $LIBIEC61883_LIBS"
 814           DV1394_CFLAGS="$RAW1394_CFLAGS $LIBIEC61883_CFLAGS -DHAVE_LIBIEC61883"
 815           AC_SUBST(DV1394_CFLAGS)
 816           AC_SUBST(DV1394_LIBS)
 817         fi
 818   else
 819        if test x$HAVE_RAW1394 = xno; then
 820           AG_GST_PKG_CHECK_MODULES(RAW1394, libraw1394 >= 1.1.0)
 821           AG_GST_CHECK_LIBHEADER(AVC1394,
 822            avc1394, avc1394_send_command, $RAW1394_LIBS,
 823            libavc1394/avc1394.h, AVC1394_LIBS="-lavc1394")
 824           AG_GST_CHECK_LIBHEADER(ROM1394,
 825            rom1394, rom1394_free_directory, $RAW1394_LIBS,
 826            libavc1394/rom1394.h, ROM1394_LIBS="-lrom1394")
 827           if test x$HAVE_RAW1394 = xyes && \
 828              test x$HAVE_AVC1394 = xyes && \
 829              test x$HAVE_ROM1394 = xyes; then
 830              HAVE_DV1394=yes
 831              DV1394_LIBS="$RAW1394_LIBS $AVC1394_LIBS $ROM1394_LIBS"
 832              DV1394_CFLAGS="$RAW1394_CFLAGS"
 833              if test x$HAVE_LIBIEC61883 = xyes; then
 834                DV1394_CFLAGS="$RAW1394_CFLAGS $LIBIEC61883_CFLAGS -DHAVE_LIBIEC61883"
 835                DV1394_LIBS="$DV1394_LIBS $LIBIEC61883_LIBS"
 836              fi
 837              AC_SUBST(DV1394_CFLAGS)
 838              AC_SUBST(DV1394_LIBS)
 839            fi
 840          fi
 841   fi
 842 ])
 843 AM_CONDITIONAL(USE_LIBIEC61883, [ test "x${HAVE_LIBIEC61883}" = xyes ] )
 844
 845 dnl *** shout2 ***
 846 translit(dnm, m, l) AM_CONDITIONAL(USE_SHOUT2, true)
 847 AG_GST_CHECK_FEATURE(SHOUT2, [Shoutcast/Icecast client library], shout2, [
 848   AG_GST_PKG_CHECK_MODULES(SHOUT2, shout >= 2.0)
 849 ])
 850
 851 dnl *** soup ***
 852 translit(dnm, m, l) AM_CONDITIONAL(USE_SOUP, true)
 853 AG_GST_CHECK_FEATURE(SOUP, [soup http client plugin (2.4)], souphttpsrc, [
 854   PKG_CHECK_MODULES(SOUP, libsoup-gnome-2.4 >= 2.3.2, [
 855     HAVE_SOUP="yes"
 856     AC_DEFINE(HAVE_LIBSOUP_GNOME, 1, [soup gnome integration])
 857   ],[
 858     PKG_CHECK_MODULES(SOUP, libsoup-2.4 >= 2.26, HAVE_SOUP="yes", [
 859       HAVE_SOUP="no"
 860     ])
 861   ])
 862   AC_SUBST(SOUP_CFLAGS)
 863   AC_SUBST(SOUP_LIBS)
 864 ])
 865
 866 dnl *** speex >= 1.0.4 or >= 1.1.5 ***
 867 dnl   1.1.4 and earlier were not API/ABI compatible with 1.0
 868 dnl   1.1.6 is the first to use a .pc/pkg-config file ***
 869 dnl   speex_jitter.h is 1.1.x only
 870 translit(dnm, m, l) AM_CONDITIONAL(USE_SPEEX, true)
 871 AG_GST_CHECK_FEATURE(SPEEX, [speex speech codec], speex, [
 872   AG_GST_PKG_CHECK_MODULES(SPEEX, speex >= 1.1.6)
 873   if test $HAVE_SPEEX = no
 874   then
 875     AG_GST_CHECK_LIBHEADER(SPEEX, speex, speex_bits_init, , speex/speex.h, [
 876       AC_CHECK_HEADER(speex/speex_jitter.h, [
 877         dnl speex 1.1.x :
 878         AG_GST_CHECK_LIBHEADER(SPEEX, speex, speex_encode_int, , speex/speex.h, [
 879           dnl speex 1.1.5 or + :
 880           HAVE_SPEEX="yes"
 881           SPEEX_LIBS="-lspeex"
 882           AC_SUBST(SPEEX_CFLAGS)
 883           AC_SUBST(SPEEX_LIBS)
 884         ],[
 885           HAVE_SPEEX="no"
 886         ])
 887       ],[
 888         dnl speex 1.0.x :
 889           AC_CHECK_DECL(SPEEX_GET_LOOKAHEAD, [
 890             dnl speex 1.0.4
 891             HAVE_SPEEX="yes"
 892             SPEEX_LIBS="-lspeex"
 893             AC_SUBST(SPEEX_CFLAGS)
 894             AC_SUBST(SPEEX_LIBS)
 895
 896             AC_DEFINE_UNQUOTED(SPEEX_1_0, 1,
 897               [defined if speex 1.0.x API detected])
 898         ],[
 899             HAVE_SPEEX="no"
 900             AC_MSG_NOTICE(You need at least 1.0.4 to compile the speex plugin)
 901         ], [
 902 #include <speex/speex.h>
 903         ])
 904       ])
 905     ])
 906   fi
 907 ])
 908
 909 dnl *** taglib ***
 910 translit(dnm, m, l) AM_CONDITIONAL(USE_TAGLIB, true)
 911 AG_GST_CHECK_FEATURE(TAGLIB, [taglib tagging library], taglib, [
 912   AG_GST_PKG_CHECK_MODULES(TAGLIB, taglib >= 1.5)
 913   if test "x$HAVE_CXX" != "xyes"; then
 914     USE_TAGLIB=false
 915     AC_MSG_NOTICE([Not building taglib plugin: no C++ compiler found])
 916   else
 917     dnl work around bug in taglib 1.5 headers, remove once there is a 1.6
 918     AS_CXX_COMPILER_FLAG([-Wno-attributes], [
 919         TAGLIB_CXXFLAGS="$TAGLIB_CFLAGS -Wno-attributes"
 920       ], [
 921         TAGLIB_CXXFLAGS="$TAGLIB_CFLAGS"
 922     ])
 923     AC_SUBST(TAGLIB_CXXFLAGS)
 924   fi
 925 ])
 926
 927 dnl *** wavpack ***
 928 translit(dnm, m, l) AM_CONDITIONAL(USE_WAVPACK, true)
 929 AG_GST_CHECK_FEATURE(WAVPACK, [wavpack plug-in], wavpack, [
 930   PKG_CHECK_MODULES(WAVPACK, wavpack >= 4.40.0, HAVE_WAVPACK=yes, [
 931     PKG_CHECK_MODULES(WAVPACK, wavpack >= 4.20, [
 932       HAVE_WAVPACK=yes
 933       AC_DEFINE(WAVPACK_OLD_API, 1, [old wavpack API])
 934     ],[
 935       HAVE_WAVPACK=no
 936     ])
 937   ])
 938   AC_SUBST(WAVPACK_CFLAGS)
 939   AC_SUBST(WAVPACK_LIBS)
 940 ])
 941
 942 dnl *** qtdemux & matroska prefer to have zlib ***
 943 translit(dnm, m, l) AM_CONDITIONAL(USE_ZLIB, true)
 944 AG_GST_CHECK_FEATURE(ZLIB, [zlib support for qtdemux/matroska],, [
 945   AG_GST_CHECK_LIBHEADER(ZLIB,
 946     z, uncompress,, zlib.h, [
 947     HAVE_ZLIB="yes"
 948     ZLIB_LIBS="-lz"
 949     AC_SUBST(ZLIB_LIBS)
 950   ])
 951 ])
 952
 953 dnl *** matroska prefers to have bz2 ***
 954 translit(dnm, m, l) AM_CONDITIONAL(USE_BZ2, true)
 955 AG_GST_CHECK_FEATURE(BZ2, [bz2 library for matroska ],, [
 956   AG_GST_CHECK_LIBHEADER(BZ2, bz2, BZ2_bzCompress, ,bzlib.h, BZ2_LIBS="-lbz2")
 957   AC_SUBST(BZ2_LIBS)
 958 ])
 959
 960 else
 961
 962 dnl not building plugins with external dependencies,
 963 dnl but we still need to set the conditionals
 964 AM_CONDITIONAL(USE_AALIB, false)
 965 AM_CONDITIONAL(USE_ANNODEX, false)
 966 AM_CONDITIONAL(USE_BZ2, false)
 967 AM_CONDITIONAL(USE_CAIRO, false)
 968 AM_CONDITIONAL(USE_CAIRO_GOBJECT, false)
 969 AM_CONDITIONAL(USE_DIRECTSOUND, false)
 970 AM_CONDITIONAL(USE_DV1394, false)
 971 AM_CONDITIONAL(USE_FLAC, false)
 972 AM_CONDITIONAL(USE_GDK_PIXBUF, false)
 973 AM_CONDITIONAL(USE_GST_V4L2, false)
 974 AM_CONDITIONAL(USE_JACK, false)
 975 AM_CONDITIONAL(USE_JPEG, false)
 976 AM_CONDITIONAL(USE_LIBCACA, false)
 977 AM_CONDITIONAL(USE_LIBDV, false)
 978 AM_CONDITIONAL(USE_LIBIEC61883, false)
 979 AM_CONDITIONAL(USE_LIBPNG, false)
 980 AM_CONDITIONAL(USE_OSS, false)
 981 AM_CONDITIONAL(USE_OSS4, false)
 982 AM_CONDITIONAL(USE_OSX_AUDIO, false)
 983 AM_CONDITIONAL(USE_OSX_VIDEO, false)
 984 AM_CONDITIONAL(USE_PULSE, false)
 985 AM_CONDITIONAL(USE_SHOUT2, false)
 986 AM_CONDITIONAL(USE_SOUP, false)
 987 AM_CONDITIONAL(USE_SPEEX, false)
 988 AM_CONDITIONAL(USE_SUNAUDIO, false)
 989 AM_CONDITIONAL(USE_TAGLIB, false)
 990 AM_CONDITIONAL(USE_WAVEFORM, false)
 991 AM_CONDITIONAL(USE_WAVPACK, false)
 992 AM_CONDITIONAL(USE_X, false)
 993 AM_CONDITIONAL(USE_XSHM, false)
 994 AM_CONDITIONAL(USE_XVIDEO, false)
 995 AM_CONDITIONAL(USE_ZLIB, false)
 996
 997 fi dnl of EXT plugins
 998
 999 dnl *** finalize CFLAGS, LDFLAGS, LIBS
1000
1001 dnl Overview:
1002 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
1003 dnl GST_*:              flags shared by all built objects
1004 dnl GST_ALL_LDFLAGS:    linker flags shared by all
1005 dnl GST_LIB_LDFLAGS:    not needed, we don't install libraries
1006 dnl GST_LT_LDFLAGS:     library versioning of our libraries
1007 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
1008
1009 dnl GST_OPTION_CFLAGS
1010 if test "x$USE_DEBUG" = xyes; then
1011    PROFILE_CFLAGS="-g"
1012 fi
1013 AC_SUBST(PROFILE_CFLAGS)
1014
1015 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
1016   dnl Define _only_ for git (not pre-releases or releases)
1017   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
1018 else
1019   DEPRECATED_CFLAGS=""
1020 fi
1021 AC_SUBST(DEPRECATED_CFLAGS)
1022
1023 dnl every flag in GST_OPTION_CFLAGS and GST_OPTION_CXXFLAGS can be overridden
1024 dnl at make time with e.g. make ERROR_CFLAGS=""
1025 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
1026 GST_OPTION_CXXFLAGS="\$(WARNING_CXXFLAGS) \$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
1027 AC_SUBST(GST_OPTION_CFLAGS)
1028 AC_SUBST(GST_OPTION_CXXFLAGS)
1029
1030 dnl our libraries need to be versioned correctly
1031 AC_SUBST(GST_LT_LDFLAGS)
1032
1033 dnl FIXME: do we want to rename to GST_ALL_* ?
1034 dnl prefer internal headers to already installed ones
1035 dnl also add builddir include for enumtypes and marshal
1036 dnl add ERROR_CFLAGS, but overridable
1037 GST_CFLAGS="$GST_CFLAGS -DGST_USE_UNSTABLE_API"
1038 GST_CXXFLAGS="-I\$(top_srcdir)/gst-libs $GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_CXXFLAGS)"
1039 GST_CFLAGS="-I\$(top_srcdir)/gst-libs $GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_CFLAGS)"
1040 AC_SUBST(GST_CFLAGS)
1041 AC_SUBST(GST_CXXFLAGS)
1042 AC_SUBST(GST_LIBS)
1043
1044 dnl LDFLAGS really should only contain flags, not libs - they get added before
1045 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
1046 GST_ALL_LDFLAGS="-no-undefined"
1047 AC_SUBST(GST_ALL_LDFLAGS)
1048
1049 dnl this really should only contain flags, not libs - they get added before
1050 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
1051 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc.*' $GST_ALL_LDFLAGS"
1052 AC_SUBST(GST_PLUGIN_LDFLAGS)
1053
1054 dnl *** output files ***
1055
1056 dnl keep this alphabetic per directory, please
1057 AC_CONFIG_FILES(
1058 Makefile
1059 gst/Makefile
1060 gst/alpha/Makefile
1061 gst/apetag/Makefile
1062 gst/audiofx/Makefile
1063 gst/audioparsers/Makefile
1064 gst/auparse/Makefile
1065 gst/autodetect/Makefile
1066 gst/avi/Makefile
1067 gst/cutter/Makefile
1068 gst/deinterlace/Makefile
1069 gst/debugutils/Makefile
1070 gst/effectv/Makefile
1071 gst/equalizer/Makefile
1072 gst/flv/Makefile
1073 gst/goom/Makefile
1074 gst/goom2k1/Makefile
1075 gst/id3demux/Makefile
1076 gst/icydemux/Makefile
1077 gst/imagefreeze/Makefile
1078 gst/interleave/Makefile
1079 gst/isomp4/Makefile
1080 gst/law/Makefile
1081 gst/level/Makefile
1082 gst/matroska/Makefile
1083 gst/monoscope/Makefile
1084 gst/multifile/Makefile
1085 gst/multipart/Makefile
1086 gst/replaygain/Makefile
1087 gst/rtp/Makefile
1088 gst/rtpmanager/Makefile
1089 gst/rtsp/Makefile
1090 gst/shapewipe/Makefile
1091 gst/smpte/Makefile
1092 gst/spectrum/Makefile
1093 gst/udp/Makefile
1094 gst/videobox/Makefile
1095 gst/videocrop/Makefile
1096 gst/videofilter/Makefile
1097 gst/videomixer/Makefile
1098 gst/wavenc/Makefile
1099 gst/wavparse/Makefile
1100 gst/flx/Makefile
1101 gst/y4m/Makefile
1102 ext/Makefile
1103 ext/aalib/Makefile
1104 ext/annodex/Makefile
1105 ext/cairo/Makefile
1106 ext/dv/Makefile
1107 ext/flac/Makefile
1108 ext/gdk_pixbuf/Makefile
1109 ext/jack/Makefile
1110 ext/jpeg/Makefile
1111 ext/libcaca/Makefile
1112 ext/libpng/Makefile
1113 ext/pulse/Makefile
1114 ext/raw1394/Makefile
1115 ext/shout2/Makefile
1116 ext/soup/Makefile
1117 ext/speex/Makefile
1118 ext/taglib/Makefile
1119 ext/wavpack/Makefile
1120 sys/Makefile
1121 sys/directsound/Makefile
1122 sys/oss/Makefile
1123 sys/oss4/Makefile
1124 sys/osxaudio/Makefile
1125 sys/osxvideo/Makefile
1126 sys/sunaudio/Makefile
1127 sys/v4l2/Makefile
1128 sys/waveform/Makefile
1129 sys/ximage/Makefile
1130 po/Makefile.in
1131 tests/Makefile
1132 tests/check/Makefile
1133 tests/examples/Makefile
1134 tests/examples/audiofx/Makefile
1135 tests/examples/cairo/Makefile
1136 tests/examples/equalizer/Makefile
1137 tests/examples/jack/Makefile
1138 tests/examples/level/Makefile
1139 tests/examples/pulse/Makefile
1140 tests/examples/rtp/Makefile
1141 tests/examples/shapewipe/Makefile
1142 tests/examples/spectrum/Makefile
1143 tests/examples/v4l2/Makefile
1144 tests/files/Makefile
1145 tests/icles/Makefile
1146 common/Makefile
1147 common/m4/Makefile
1148 m4/Makefile
1149 docs/Makefile
1150 docs/plugins/Makefile
1151 docs/version.entities
1152 pkgconfig/Makefile
1153 pkgconfig/gstreamer-plugins-good-uninstalled.pc
1154 gst-plugins-good.spec
1155 )
1156
1157 dnl Create the config.h file for Visual Studio builds
1158 dnl Beware of spaces and /'s in some of the shell variable contents.
1159 sed \
1160     -e 's/.*config.h.in.*autoheader.*/\/* Autogenerated config.h created for win32 Visual Studio builds *\/\n\n\/* PREFIX -- specifically added for Windows for easier moving *\/\n#define PREFIX "C:\\\\gstreamer"\n\n#define GST_INSTALL_PLUGINS_HELPER PREFIX "\\\\libexec\\\\gst-install-plugins-helper.exe"/' \
1161     -e 's/.* GETTEXT_PACKAGE$/#define GETTEXT_PACKAGE "'$GETTEXT_PACKAGE'"/' \
1162     -e 's/.* GST_DATADIR$/#define GST_DATADIR PREFIX "\\\\share"/' \
1163     -e 's/.* GST_LEVEL_DEFAULT$/#define GST_LEVEL_DEFAULT GST_LEVEL_ERROR/' \
1164     -e 's/.* GST_LICENSE$/#define GST_LICENSE "'$GST_LICENSE'"/' \
1165     -e 's/.* GST_MAJORMINOR$/#define GST_MAJORMINOR "'$GST_MAJORMINOR'"/' \
1166     -e "s,.* GST_PACKAGE_NAME$,#define GST_PACKAGE_NAME \"${GST_PACKAGE_NAME}\"," \
1167     -e 's/.* GST_PACKAGE_ORIGIN$/#define GST_PACKAGE_ORIGIN "Unknown package origin"/' \
1168     -e "s,.* GST_PACKAGE_RELEASE_DATETIME$,#define GST_PACKAGE_RELEASE_DATETIME \"${GST_PACKAGE_RELEASE_DATETIME}\"," \
1169     -e 's/.* HAVE_CPU_I386$/#define HAVE_CPU_I386 1/' \
1170     -e 's/.* HAVE_FGETPOS$/#define HAVE_FGETPOS 1/' \
1171     -e 's/.* HAVE_FSETPOS$/#define HAVE_FSETPOS 1/' \
1172     -e 's/.* HAVE_LIBXML2$/#define HAVE_LIBXML2 1/' \
1173     -e 's/.* HAVE_PROCESS_H$/#define HAVE_PROCESS_H 1/' \
1174     -e 's/.* HAVE_STDLIB_H$/#define HAVE_STDLIB_H 1/' \
1175     -e 's/.* HAVE_STRING_H$/#define HAVE_STRING_H 1/' \
1176     -e 's/.* HAVE_SYS_STAT_H$/#define HAVE_SYS_STAT_H 1/' \
1177     -e 's/.* HAVE_SYS_TYPES_H$/#define HAVE_SYS_TYPES_H 1/' \
1178     -e 's/.* HAVE_WIN32$/#define HAVE_WIN32 1/' \
1179     -e 's/.* HOST_CPU$/#define HOST_CPU "i686"/' \
1180     -e 's/.* LIBDIR$/#ifdef _DEBUG\n#  define LIBDIR PREFIX "\\\\debug\\\\lib"\n#else\n#  define LIBDIR PREFIX "\\\\lib"\n#endif/' \
1181     -e 's/.* LOCALEDIR$/#define LOCALEDIR PREFIX "\\\\share\\\\locale"/' \
1182     -e "s/.* PACKAGE$/#define PACKAGE \"$PACKAGE\"/" \
1183     -e 's/.* PACKAGE_BUGREPORT$/#define PACKAGE_BUGREPORT "http:\/\/bugzilla.gnome.org\/enter_bug.cgi?product=GStreamer"/' \
1184     -e "s/.* PACKAGE_NAME$/#define PACKAGE_NAME \"$PACKAGE_NAME\"/" \
1185     -e "s/.* PACKAGE_STRING$/#define PACKAGE_STRING \"$PACKAGE_STRING\"/" \
1186     -e 's/.* PACKAGE_TARNAME$/#define PACKAGE_TARNAME "'$PACKAGE_TARNAME'"/' \
1187     -e 's/.* PACKAGE_VERSION$/#define PACKAGE_VERSION "'$PACKAGE_VERSION'"/' \
1188     -e 's/.* PLUGINDIR$/#ifdef _DEBUG\n#  define PLUGINDIR PREFIX "\\\\debug\\\\lib\\\\gstreamer-0.11"\n#else\n#  define PLUGINDIR PREFIX "\\\\lib\\\\gstreamer-0.11"\n#endif/' \
1189     -e 's/.* USE_BINARY_REGISTRY$/#define USE_BINARY_REGISTRY/' \
1190     -e 's/.* VERSION$/#define VERSION "'$VERSION'"/' \
1191     -e "s/.* DEFAULT_AUDIOSINK$/#define DEFAULT_AUDIOSINK \"directsoundsink\"/" \
1192     -e "s/.* DEFAULT_AUDIOSRC$/#define DEFAULT_AUDIOSRC \"audiotestsrc\"/" \
1193     -e "s/.* DEFAULT_VIDEOSRC$/#define DEFAULT_VIDEOSRC \"videotestsrc\"/" \
1194     -e "s/.* DEFAULT_VISUALIZER$/#define DEFAULT_VISUALIZER \"goom\"/" \
1195     config.h.in >win32/common/config.h-new
1196
1197 AC_OUTPUT
1198
1199 AG_GST_OUTPUT_PLUGINS
1200 ORC_OUTPUT
1201