configure.ac

   1 AC_PREREQ(2.60)
   2
   3 dnl initialize autoconf
   4 dnl when going to/from release please set the nano (fourth number) right !
   5 dnl releases only do Wall, git and prerelease does Werror too
   6 AC_INIT(GStreamer, 0.10.36.1,
   7     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
   8     gstreamer)
   9 AG_GST_INIT
  10
  11 dnl initialize automake (we require GNU make)
  12 AM_INIT_AUTOMAKE([-Wno-portability 1.10])
  13
  14 dnl define PACKAGE_VERSION_* variables
  15 AS_VERSION
  16
  17 dnl check if this is a release version
  18 AS_NANO(GST_GIT="no", GST_GIT="yes")
  19
  20 dnl can autoconf find the source ?
  21 AC_CONFIG_SRCDIR([gst/gst.c])
  22
  23 dnl define the output header for config
  24 AM_CONFIG_HEADER([config.h])
  25
  26 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  27 AM_MAINTAINER_MODE
  28
  29 dnl sets host_* variables
  30 AC_CANONICAL_HOST
  31
  32 dnl use pretty build output with automake >= 1.11
  33 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],
  34   [AM_DEFAULT_VERBOSITY=1
  35    AC_SUBST(AM_DEFAULT_VERBOSITY)])
  36
  37 dnl our libraries and install dirs use major.minor as a version
  38 GST_MAJORMINOR=$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR
  39 dnl we override it here for release candidates for a new series
  40 GST_MAJORMINOR=0.10
  41 AC_SUBST(GST_MAJORMINOR)
  42 AC_DEFINE_UNQUOTED(GST_MAJORMINOR, "$GST_MAJORMINOR",
  43   [library major.minor version])
  44
  45 dnl CURRENT, REVISION, AGE
  46 dnl - library source changed -> increment REVISION
  47 dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
  48 dnl - interfaces added -> increment AGE
  49 dnl - interfaces removed -> AGE = 0
  50 dnl sets GST_LT_LDFLAGS
  51 AS_LIBTOOL(GST, 31, 0, 31)
  52
  53 dnl FIXME: this macro doesn't actually work;
  54 dnl the generated libtool script has no support for the listed tags.
  55 dnl So this needs to be fixed first if we want to use this
  56 dnl AS_LIBTOOL_TAGS
  57
  58 AC_LIBTOOL_WIN32_DLL
  59 AM_PROG_LIBTOOL
  60
  61 dnl *** autotools stuff ****
  62
  63 dnl allow for different autotools
  64 AS_AUTOTOOLS_ALTERNATE
  65
  66 dnl Add parameters for aclocal (keep in sync with Makefile.am)
  67 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  68
  69 dnl set up gettext
  70 dnl the version check needs to stay here because autopoint greps for it
  71 AM_GNU_GETTEXT_VERSION([0.17])
  72 AM_GNU_GETTEXT([external])
  73 AG_GST_GETTEXT([gstreamer-$GST_MAJORMINOR])
  74
  75 dnl *** check for arguments to configure ***
  76
  77 AG_GST_ARG_DISABLE_FATAL_WARNINGS
  78
  79 dnl subsystems - can influence other decisions so needs to be high up
  80 dnl we need to AM_CONDITIONAL them here for automake 1.6.x compatibility
  81 AG_GST_CHECK_SUBSYSTEM_DISABLE(GST_DEBUG,[debugging subsystem])
  82 AM_CONDITIONAL(GST_DISABLE_GST_DEBUG, test "x$GST_DISABLE_GST_DEBUG" = "xyes")
  83 AG_GST_CHECK_SUBSYSTEM_DISABLE(LOADSAVE,[pipeline XML load/save])
  84 AM_CONDITIONAL(GST_DISABLE_LOADSAVE, test "x$GST_DISABLE_LOADSAVE" = "xyes")
  85 dnl define a substitution to use in docs/gst/gstreamer.types
  86 if test "x$GST_DISABLE_LOADSAVE" = "xyes"
  87 then
  88   GST_LOADSAVE_DOC_TYPES="%"
  89 else
  90   GST_LOADSAVE_DOC_TYPES=
  91 fi
  92 AC_SUBST(GST_LOADSAVE_DOC_TYPES)
  93 AG_GST_CHECK_SUBSYSTEM_DISABLE(PARSE,[command-line parser])
  94 AM_CONDITIONAL(GST_DISABLE_PARSE, test "x$GST_DISABLE_PARSE" = "xyes")
  95 if test "x$GST_DISABLE_PARSE" = xyes; then
  96   AC_DEFINE(GST_DISABLE_PARSE, 1,
  97     [Define if pipeline parsing code is disabled])
  98 fi
  99 AG_GST_CHECK_SUBSYSTEM_DISABLE(OPTION_PARSING,[option parsing when gst_init])
 100 AM_CONDITIONAL(GST_DISABLE_OPTION_PARSING, test "x$GST_DISABLE_OPTION_PARSING" = "xyes")
 101 if test "x$GST_DISABLE_OPTION_PARSING" = xyes; then
 102   AC_DEFINE(GST_DISABLE_OPTION_PARSING, 1,
 103     [Define if option parsing is disabled])
 104 fi
 105 AG_GST_CHECK_SUBSYSTEM_DISABLE(TRACE,[tracing subsystem])
 106 AM_CONDITIONAL(GST_DISABLE_TRACE, test "x$GST_DISABLE_TRACE" = "xyes")
 107 AG_GST_CHECK_SUBSYSTEM_DISABLE(ALLOC_TRACE,[allocation tracing])
 108 AM_CONDITIONAL(GST_DISABLE_ALLOC_TRACE, test "x$GST_DISABLE_ALLOC_TRACE" = "xyes")
 109 AG_GST_CHECK_SUBSYSTEM_DISABLE(REGISTRY,[plugin registry])
 110 AM_CONDITIONAL(GST_DISABLE_REGISTRY, test "x$GST_DISABLE_REGISTRY" = "xyes")
 111 dnl define a substitution to use in docs/gst/gstreamer.types
 112 if test "x$GST_DISABLE_REGISTRY" = "xyes"
 113 then
 114   GST_REGISTRY_DOC_TYPES="%"
 115 else
 116   GST_REGISTRY_DOC_TYPES=
 117 fi
 118 AC_SUBST(GST_REGISTRY_DOC_TYPES)
 119 AG_GST_CHECK_SUBSYSTEM_DISABLE(NET,[network distribution])
 120 AM_CONDITIONAL(GST_DISABLE_NET, test "x$GST_DISABLE_NET" = "xyes")
 121 AG_GST_CHECK_SUBSYSTEM_DISABLE(PLUGIN,[plugin])
 122 AM_CONDITIONAL(GST_DISABLE_PLUGIN, test "x$GST_DISABLE_PLUGIN" = "xyes")
 123
 124 AG_GST_ARG_DEBUG
 125 AG_GST_ARG_PROFILING
 126 AG_GST_ARG_VALGRIND
 127 AG_GST_ARG_GCOV
 128
 129 AG_GST_ARG_EXAMPLES
 130
 131 AG_GST_ARG_WITH_PKG_CONFIG_PATH
 132 AG_GST_ARG_WITH_PACKAGE_NAME
 133 AG_GST_ARG_WITH_PACKAGE_ORIGIN
 134
 135 AG_GST_PKG_CONFIG_PATH
 136
 137 AG_GST_SET_PACKAGE_RELEASE_DATETIME_WITH_NANO([$PACKAGE_VERSION_NANO],
 138   ["${srcdir}/gstreamer.doap"],
 139   [$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_MICRO])
 140
 141 dnl building of tests
 142 AC_ARG_ENABLE(tests,
 143   AC_HELP_STRING([--disable-tests], [disable building test apps]),
 144   [
 145     case "${enableval}" in
 146       yes) BUILD_TESTS=yes ;;
 147       no)  BUILD_TESTS=no ;;
 148       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-tests) ;;
 149     esac
 150   ],
 151 [BUILD_TESTS=yes]) dnl Default value
 152 AM_CONDITIONAL(BUILD_TESTS,         test "x$BUILD_TESTS" = "xyes")
 153
 154 dnl tests known to fail
 155 AC_ARG_ENABLE(failing-tests,
 156   AC_HELP_STRING([--disable-failing-tests],
 157     [disable building tests known to fail]),
 158   [
 159     case "${enableval}" in
 160       yes) BUILD_FAILING_TESTS=yes ;;
 161       no)  BUILD_FAILING_TESTS=no ;;
 162       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-failing-tests) ;;
 163     esac
 164   ],
 165   [BUILD_FAILING_TESTS=no]) dnl Default value
 166 AM_CONDITIONAL(BUILD_FAILING_TESTS, test "x$BUILD_FAILING_TESTS" = "xyes")
 167 if test x$BUILD_FAILING_TESTS = xyes; then
 168   AC_MSG_WARN([building tests known to fail, use --disable-failing-tests to disable])
 169 else
 170   AC_MSG_WARN([Sissy ! By asking to not build the tests known to fail, you hereby waive your right to customer support.  If you do not agree with this EULA, please press Ctrl-C before the next line is printed.  By allowing the next line to be printed, you expressly acknowledge your acceptance of this EULA.])
 171 fi
 172
 173 dnl poison destroyed objects
 174 AC_ARG_ENABLE(poisoning,
 175   AC_HELP_STRING([--enable-poisoning],
 176     [enable poisoning of deallocated objects]),
 177   [
 178     case "${enableval}" in
 179       yes) USE_POISONING=yes ;;
 180       no)  USE_POISONING=no ;;
 181       *)   AC_MSG_ERROR(bad value ${enableval} for --enable-poisoning) ;;
 182     esac
 183   ],
 184   [USE_POISONING=no]) dnl Default value
 185 if test "x$USE_POISONING" = xyes; then
 186   AC_DEFINE(USE_POISONING, 1,
 187     [Define if we should poison deallocated memory])
 188 fi
 189
 190 dnl *** checks for platform ***
 191
 192 dnl * hardware/architecture *
 193
 194 dnl common/m4/gst-arch.m4
 195 dnl check CPU type
 196 AG_GST_ARCH
 197 dnl substitution for win32/common/config.h
 198 HOST_CPU=$host_cpu
 199 AC_SUBST(HOST_CPU)
 200
 201 dnl common/m4/gst-arch.m4
 202 dnl check for unaligned access
 203 AG_GST_UNALIGNED_ACCESS
 204 dnl create a configure variable for gst/gstconfig.h
 205 if test x${as_cv_unaligned_access} = xyes ; then
 206   GST_HAVE_UNALIGNED_ACCESS_DEFINE="#define GST_HAVE_UNALIGNED_ACCESS 1"
 207 else
 208   GST_HAVE_UNALIGNED_ACCESS_DEFINE="#define GST_HAVE_UNALIGNED_ACCESS 0"
 209 fi
 210 AC_SUBST(GST_HAVE_UNALIGNED_ACCESS_DEFINE)
 211
 212 dnl check for platform specific settings
 213 AG_GST_PLATFORM
 214
 215 dnl * software *
 216
 217 dnl check for large file support
 218 dnl affected plugins must include config.h
 219 AC_SYS_LARGEFILE
 220
 221 dnl *** checks for programs ***
 222
 223 dnl find a compiler
 224 AC_PROG_CC
 225 AC_PROG_CC_STDC
 226
 227 dnl check if the compiler supports '-c' and '-o' options
 228 AM_PROG_CC_C_O
 229
 230 dnl find an assembler
 231 AM_PROG_AS
 232
 233 dnl determine if c++ is available on this system
 234 AC_PROG_CXX
 235 dnl CXX may be set to some default even if no c++ compiler is available
 236 dnl (thanks autotools!), so just try to compile some c++ code to make sure
 237 AC_LANG_PUSH([C++])
 238 AC_TRY_COMPILE([ class Foo { int bar; };], , working_cxx=yes, working_cxx=no)
 239 AC_LANG_POP([C++])
 240 AC_MSG_NOTICE([working c++ compiler found: $working_cxx])
 241 AM_CONDITIONAL(HAVE_CXX, test "x$working_cxx" = "xyes")
 242
 243 dnl Perl is used in building documentation and in the version checks
 244 AC_PATH_PROG(PERL_PATH, perl, no)
 245 if test x$PERL_PATH = xno; then
 246   AC_MSG_ERROR(Could not find perl)
 247 fi
 248
 249 dnl we require flex and bison for building the parser
 250 if test "x$GST_DISABLE_PARSE" != xyes; then
 251   AG_GST_BISON_CHECK
 252   AG_GST_FLEX_CHECK
 253 fi
 254
 255 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 256 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 257
 258 dnl check for gobject-introspection
 259 GOBJECT_INTROSPECTION_CHECK([0.6.8])
 260
 261 dnl check for documentation tools
 262 AG_GST_DOCBOOK_CHECK
 263 GTK_DOC_CHECK([1.3])
 264 AS_PATH_PYTHON([2.1])
 265 AG_GST_PLUGIN_DOCS([1.3],[2.1])
 266
 267 dnl *** checks for libraries ***
 268
 269 dnl check for libm, for sin()
 270 AC_CHECK_LIBM
 271 AC_SUBST(LIBM)
 272
 273 dnl *** checks for header files ***
 274
 275 dnl check if we have ANSI C header files
 276 AC_HEADER_STDC
 277
 278 dnl Check for ucontext.h
 279 AC_CHECK_HEADERS([ucontext.h])
 280
 281 dnl Check for sys/socket.h
 282 AC_CHECK_HEADERS([sys/socket.h], HAVE_SYS_SOCKET_H=yes)
 283 AM_CONDITIONAL(HAVE_SYS_SOCKET_H, test "x$HAVE_SYS_SOCKET_H" = "xyes")
 284
 285 dnl check for sys/times.h for tests/examples/adapter/
 286 AC_CHECK_HEADERS([sys/times.h], HAVE_SYS_TIMES_H=yes)
 287 AC_CHECK_HEADERS([unistd.h], HAVE_UNISTD_H=yes)
 288 AM_CONDITIONAL(HAVE_SYS_TIMES_H_AND_UNISTD_H, test "x$HAVE_SYS_TIMES_H" = "xyes" -a "x$HAVE_UNISTD_H" = "xyes")
 289
 290 dnl Check for process.h for getpid() on win32
 291 AC_CHECK_HEADERS([process.h])
 292
 293 dnl Check for sys/utsname.h for uname
 294 AC_CHECK_HEADERS([sys/utsname.h])
 295
 296 dnl Check for stdio_ext.f for __fbufsize
 297 AC_CHECK_HEADERS([stdio_ext.h])
 298
 299 dnl check for pthreads
 300 AC_CHECK_HEADERS([pthread.h], HAVE_PTHREAD_H=yes)
 301 AM_CONDITIONAL(HAVE_PTHREAD_H, test "x$HAVE_PTHREAD_H" = "xyes")
 302
 303 dnl check for sys/prctl for setting thread name on Linux
 304 AC_CHECK_HEADERS([sys/prctl.h], HAVE_SYS_PRCTL_H=yes)
 305
 306 dnl Check for valgrind.h
 307 dnl separate from HAVE_VALGRIND because you can have the program, but not
 308 dnl the dev package
 309 AC_CHECK_HEADERS([valgrind/valgrind.h], HAVE_VALGRIND_H=yes)
 310
 311 dnl used in gst/gstpoll.c
 312 AC_CHECK_HEADERS([winsock2.h], HAVE_WINSOCK2_H=yes)
 313 AM_CONDITIONAL(HAVE_WINSOCK2_H, test "x$HAVE_WINSOCK2_H" = "xyes")
 314 if test "x$HAVE_WINSOCK2_H" = "xyes"; then
 315   WIN32_LIBS="-lws2_32"
 316   AC_SUBST(WIN32_LIBS)
 317 fi
 318
 319 dnl check for GMP/GSL, used by the gst_util_uint64_scale unit test only
 320 if test "x$BUILD_TESTS" = "xyes"; then
 321   AG_GST_CHECK_LIBHEADER(GMP, gmp,
 322                          __gmpz_init_set_d, ,
 323                          gmp.h,
 324                          GMP_LIBS="-lgmp"
 325                          AC_SUBST(GMP_LIBS)
 326                          AC_DEFINE(HAVE_GMP, [1],[Have GMP library]))
 327   AG_GST_CHECK_LIBHEADER(GSL, gsl,
 328                          gsl_rng_uniform_int, -lgslcblas,
 329                          gsl/gsl_rng.h,
 330                          GSL_LIBS="-lgsl -lgslcblas"
 331                          AC_SUBST(GSL_LIBS)
 332                          AC_DEFINE(HAVE_GSL, [1],[Have GSL library]))
 333 fi
 334
 335 dnl *** checks for types/defines ***
 336
 337 dnl *** checks for structures ***
 338
 339 dnl *** checks for compiler characteristics ***
 340
 341 dnl check if the compiler supports __uint128_t (gcc)
 342 dnl Actually check for 128-bit division, since that's what we use
 343 dnl uint128_t for.
 344 AC_CACHE_CHECK(for __uint128_t, gst_cv_uint128_t,
 345     AC_TRY_LINK([ ], [
 346       static __uint128_t v1 = 100;
 347       static __uint128_t v2 = 10;
 348       static __uint128_t u;
 349       u = v1 / v2;
 350     ], [
 351       gst_cv_uint128_t=yes
 352     ], [
 353       gst_cv_uint128_t=no
 354     ])
 355 )
 356 if test x$gst_cv_uint128_t = xyes; then
 357   AC_DEFINE(HAVE_UINT128_T, 1, [Have __uint128_t type])
 358 fi
 359
 360 dnl *** checking for tm_gmtoff ***
 361 AC_MSG_CHECKING([for tm_gmtoff])
 362 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 363         #include <time.h>
 364         int main(void) {
 365           struct tm t;
 366           t.tm_gmtoff = 0;
 367           exit(0);
 368         }]])],
 369   [have_tm_gmtoff=yes
 370    AC_DEFINE(HAVE_TM_GMTOFF,1,[Have tm_gmtoff field in struct tm])],
 371   [have_tm_gmtoff=no],
 372   [have_tm_gmtoff="no (cross compiling)"])
 373 AC_MSG_RESULT($have_tm_gmtoff)
 374
 375
 376 dnl *** checks for library functions ***
 377
 378 AC_CHECK_FUNCS([gmtime_r])
 379 AC_CHECK_FUNCS([localtime_r])
 380 AC_CHECK_FUNCS([sigaction])
 381
 382 dnl check for fseeko()
 383 AC_FUNC_FSEEKO
 384 dnl check for ftello()
 385 AC_CHECK_FUNCS([ftello])
 386
 387 AC_CHECK_FUNCS([fgetpos])
 388 AC_CHECK_FUNCS([fsetpos])
 389
 390 dnl check for poll(), ppoll() and pselect()
 391 AC_CHECK_FUNCS([poll])
 392 AC_CHECK_FUNCS([ppoll])
 393 AC_CHECK_FUNCS([pselect])
 394
 395 AC_CHECK_HEADERS([sys/poll.h])
 396
 397 dnl ****************************************
 398 dnl *** GLib POLL* compatibility defines ***
 399 dnl ****************************************
 400
 401 AC_MSG_CHECKING([for broken poll])
 402 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 403         #include <stdlib.h>
 404         #include <fcntl.h>
 405         #include <poll.h>
 406         #ifdef HAVE_SYS_POLL_H
 407         #include <sys/poll.h>
 408         #endif
 409         int main(void) {
 410           struct pollfd fds[1];
 411           int fd;
 412           fd = open("/dev/null", 1);
 413           fds[0].fd = fd;
 414           fds[0].events = POLLIN;
 415           fds[0].revents = 0;
 416           if (poll(fds, 1, 0) < 0 || (fds[0].revents & POLLNVAL) != 0) {
 417                 exit(1);  /* Does not work for devices -- fail */
 418           }
 419           exit(0);
 420         }]])],
 421   [broken_poll=no],
 422   [broken_poll=yes
 423    AC_DEFINE(BROKEN_POLL,1,[poll doesn't work on devices])],
 424   [broken_poll="no (cross compiling)"])
 425 AC_MSG_RESULT($broken_poll)
 426
 427 dnl check for mmap()
 428 AC_FUNC_MMAP
 429 AM_CONDITIONAL(HAVE_MMAP, test "x$ac_cv_func_mmap_fixed_mapped" = "xyes")
 430
 431 dnl check for posix_memalign(), getpagesize()
 432 AC_CHECK_FUNCS([posix_memalign])
 433 AC_CHECK_FUNCS([getpagesize])
 434
 435 dnl Check for POSIX timers
 436 AC_CHECK_FUNCS(clock_gettime, [], [
 437   AC_CHECK_LIB(rt, clock_gettime, [
 438     AC_DEFINE(HAVE_CLOCK_GETTIME, 1)
 439     LIBS="$LIBS -lrt"
 440   ])
 441 ])
 442
 443 AC_CACHE_CHECK(for posix timers, gst_cv_posix_timers,
 444     AC_TRY_COMPILE([
 445 #include <time.h>
 446 #ifdef HAVE_UNISTD_H
 447 #include <unistd.h>
 448 #endif
 449     ], [
 450 #if !defined(_POSIX_TIMERS) || _POSIX_TIMERS < 0 || !defined(CLOCK_REALTIME)
 451 #error Either _POSIX_TIMERS or CLOCK_REALTIME not defined
 452 #endif
 453     ], [
 454       gst_cv_posix_timers=yes
 455     ], [
 456       gst_cv_posix_timers=no
 457     ])
 458 )
 459
 460 if test "$gst_cv_posix_timers" = "yes"; then
 461   AC_DEFINE(HAVE_POSIX_TIMERS,1,[Have posix timers])
 462   GST_HAVE_POSIX_TIMERS_DEFINE="#define GST_HAVE_POSIX_TIMERS 1"
 463 else
 464   GST_HAVE_POSIX_TIMERS_DEFINE="#define GST_HAVE_POSIX_TIMERS 0"
 465 fi
 466 AC_SUBST(GST_HAVE_POSIX_TIMERS_DEFINE)
 467 AM_CONDITIONAL(GST_HAVE_POSIX_TIMERS, test "$gst_cv_posix_timers" = "yes")
 468
 469 AC_CACHE_CHECK(for monotonic clock, gst_cv_monotonic_clock,
 470     AC_TRY_COMPILE([
 471 #include <time.h>
 472 #ifdef HAVE_UNISTD_H
 473 #include <unistd.h>
 474 #endif
 475     ], [
 476 #if !defined(_POSIX_MONOTONIC_CLOCK) || _POSIX_MONOTONIC_CLOCK < 0 || !defined(CLOCK_MONOTONIC)
 477 #error Either _POSIX_MONOTONIC_CLOCK or CLOCK_MONOTONIC not defined
 478 #endif
 479     ], [
 480       gst_cv_monotonic_clock=yes
 481     ], [
 482       gst_cv_monotonic_clock=no
 483     ])
 484 )
 485
 486 if test "$gst_cv_monotonic_clock" = "yes"; then
 487   AC_DEFINE(HAVE_MONOTONIC_CLOCK,1,[Have a monotonic clock])
 488   GST_HAVE_MONOTONIC_CLOCK_DEFINE="#define GST_HAVE_MONOTONIC_CLOCK 1"
 489 else
 490   GST_HAVE_MONOTONIC_CLOCK_DEFINE="#define GST_HAVE_MONOTONIC_CLOCK 0"
 491 fi
 492 AC_SUBST(GST_HAVE_MONOTONIC_CLOCK_DEFINE)
 493 AM_CONDITIONAL(GST_HAVE_MONOTONIC_CLOCK, test "$gst_cv_monotonic_clock" = "yes")
 494
 495 dnl Check for a way to display the function name in debug output
 496 AG_GST_CHECK_FUNCTION
 497
 498 dnl test for register_printf_specifier or register_printf_function
 499 AC_CHECK_FUNCS([register_printf_specifier register_printf_function],
 500     [HAVE_PRINTF_EXTENSION=yes])
 501
 502 if test "$HAVE_PRINTF_EXTENSION" = yes; then
 503   GST_PRINTF_EXTENSION_POINTER_FORMAT_DEFINE="#define GST_PTR_FORMAT \"P\""
 504   GST_PRINTF_EXTENSION_SEGMENT_FORMAT_DEFINE="#define GST_SEGMENT_FORMAT \"Q\""
 505   GST_USING_PRINTF_EXTENSION_DEFINE="#define GST_USING_PRINTF_EXTENSION"
 506   AC_DEFINE(HAVE_PRINTF_EXTENSION, 1,
 507       [Defined if we have printf specifier extensions available])
 508 else
 509     GST_PRINTF_EXTENSION_POINTER_FORMAT_DEFINE="#define GST_PTR_FORMAT \"p\""
 510     GST_PRINTF_EXTENSION_SEGMENT_FORMAT_DEFINE="#define GST_SEGMENT_FORMAT \"p\""
 511     GST_USING_PRINTF_EXTENSION_DEFINE="#undef GST_USING_PRINTF_EXTENSION"
 512 fi
 513 AC_SUBST(GST_PRINTF_EXTENSION_POINTER_FORMAT_DEFINE)
 514 AC_SUBST(GST_PRINTF_EXTENSION_SEGMENT_FORMAT_DEFINE)
 515 AC_SUBST(GST_USING_PRINTF_EXTENSION_DEFINE)
 516
 517 dnl test if we have dladdr(); we use it for debugging; see gst/gstinfo.c
 518 save_cflags="$CFLAGS"
 519 CFLAGS="$CFLAGS -D_GNU_SOURCE"
 520 AC_CHECK_LIB(dl, dladdr,
 521    AC_DEFINE(HAVE_DLADDR, 1, [Defined if we have dladdr ()])
 522    LIBS="$LIBS -ldl")
 523 CFLAGS="$save_cflags"
 524
 525 dnl *** checks for socket and nsl libraries ***
 526 AC_CHECK_FUNC(socket,,[AC_CHECK_LIB(socket,socket)])
 527 AC_CHECK_FUNC(gethostbyname,,[AC_CHECK_LIB(nsl,gethostbyname)])
 528
 529 dnl check for inet_aton()
 530 save_libs="$LIBS"
 531 AC_CHECK_FUNC(inet_aton, ,
 532    AC_CHECK_LIB(nsl, inet_aton, ,
 533       AC_CHECK_LIB(socket, inet_aton, ,
 534          AC_CHECK_LIB(resolv, inet_aton, ,[AC_DEFINE(NO_INET_ATON, 1, [Define if you have no native inet_aton() function.])]))))
 535 INET_ATON_LIBS=$LIBS
 536 AC_SUBST(INET_ATON_LIBS)
 537 LIBS="$save_libs"
 538
 539 dnl *** checks for dependency libraries ***
 540
 541 dnl GLib
 542 GLIB_REQ=2.24
 543
 544 AG_GST_GLIB_CHECK([$GLIB_REQ])
 545
 546 dnl FIXME: 0.11: Guess we need to keep this around until 0.11
 547 GST_HAVE_GLIB_2_8_DEFINE="#define GST_HAVE_GLIB_2_8 1"
 548 AC_SUBST(GST_HAVE_GLIB_2_8_DEFINE)
 549
 550 dnl Check for glib2 without extra fat, useful for the unversioned tool frontends
 551 PKG_CHECK_MODULES(GLIB_ONLY, glib-2.0 >= $GLIB_REQ)
 552
 553 dnl Check for documentation xrefs
 554 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 555 AC_SUBST(GLIB_PREFIX)
 556
 557 dnl libxml2 is only needed for xml loading/saving of pipelines these days
 558 if test "x$GST_DISABLE_LOADSAVE" = "xyes"
 559 then
 560   AC_MSG_NOTICE([XML registry and load/save are disabled, not checking for libxml2])
 561   GST_DISABLE_XML_DEFINE="#define GST_DISABLE_XML 1"
 562 else
 563   dnl check for libxml2 with minimum req version
 564   AG_GST_LIBXML2_CHECK(2.4.9)
 565   GST_DISABLE_XML_DEFINE="/* #undef GST_DISABLE_XML */"
 566 fi
 567 AC_SUBST(GST_DISABLE_XML_DEFINE)
 568
 569 dnl building of unit test libraries
 570 AC_ARG_ENABLE(check,
 571   AC_HELP_STRING([--disable-check], [disable building unit test libraries]),
 572   [
 573     case "${enableval}" in
 574       yes) BUILD_CHECK=yes ;;
 575       no)  BUILD_CHECK=no ;;
 576       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-check) ;;
 577     esac
 578   ], [
 579     dnl Default value
 580     case $host_os in
 581       mingw* | msvc* | mks*) BUILD_CHECK=no ;;
 582       *) BUILD_CHECK=yes ;;
 583     esac
 584 ])
 585 dnl bit of a misnomer, but keep the conditional named like this so we don't
 586 dnl have to change too much elsewhere
 587 AM_CONDITIONAL(HAVE_CHECK, test "x$BUILD_CHECK" = "xyes")
 588
 589 dnl configure the desired buffer alignment
 590 AC_ARG_WITH([buffer-alignment],
 591   AS_HELP_STRING([--with-buffer-alignment],[8,N,malloc,pagesize (default is 32)]),
 592   [
 593     if test "x$withval" = "xyes"
 594     then
 595       AC_DEFINE(BUFFER_ALIGNMENT, 32, [Buffer alignment to use])
 596     else
 597       case "${withval}" in
 598         malloc) AC_DEFINE(BUFFER_ALIGNMENT_MALLOC, 1, [Buffer alignment by malloc default]) ;;
 599         pagesize)  AC_DEFINE(BUFFER_ALIGNMENT_PAGESIZE, 1, [Buffer alignment by pagesize]) ;;
 600         *)   AC_DEFINE_UNQUOTED(BUFFER_ALIGNMENT, ${withval}, [Buffer alignment to use]) ;;
 601       esac
 602     fi
 603   ], [
 604     AC_DEFINE(BUFFER_ALIGNMENT_MALLOC, 1, [Buffer alignment by malloc default])
 605   ]
 606 )
 607
 608 dnl Check for -Bsymbolic-functions linker flag used to avoid
 609 dnl intra-library PLT jumps, if available.
 610 AC_ARG_ENABLE(Bsymbolic,
 611               [AC_HELP_STRING([--disable-Bsymbolic],
 612                               [avoid linking with -Bsymbolic])],,
 613               [SAVED_LDFLAGS="${LDFLAGS}"
 614                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
 615                LDFLAGS=-Wl,-Bsymbolic-functions
 616                AC_TRY_LINK([], [int main (void) { return 0; }],
 617                            AC_MSG_RESULT(yes)
 618                            enable_Bsymbolic=yes,
 619                            AC_MSG_RESULT(no)
 620                            enable_Bsymbolic=no)
 621                LDFLAGS="${SAVED_LDFLAGS}"])
 622
 623
 624 dnl *** set variables based on configure arguments
 625
 626 dnl set license and copyright notice
 627 GST_LICENSE="LGPL"
 628 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 629 AC_SUBST(GST_LICENSE)
 630
 631 dnl define LIBDIR, GST_DATADIR so we can inform people where we live
 632 AS_AC_EXPAND(LIBDIR, $libdir)
 633 AC_DEFINE_UNQUOTED(LIBDIR, "$LIBDIR", [library dir])
 634 AS_AC_EXPAND(DATADIR, $datadir)
 635 AC_DEFINE_UNQUOTED(GST_DATADIR, "$DATADIR", [data dir])
 636
 637 dnl set location of plugin directory
 638 AG_GST_SET_PLUGINDIR
 639
 640 dnl FIXME: add LIBXML_PKG here if we use it
 641 GST_PKG_DEPS="glib-2.0, gobject-2.0, gmodule-no-export-2.0, gthread-2.0"
 642 AC_SUBST(GST_PKG_DEPS)
 643
 644 dnl make sure it doesn't complain about unused variables if debugging is disabled
 645 NO_WARNINGS=""
 646 if test "x${GST_DISABLE_GST_DEBUG}" = "xyes"; then
 647   NO_WARNINGS="-Wno-unused"
 648 fi
 649
 650 dnl define an ERROR_CFLAGS Makefile variable
 651 AG_GST_SET_ERROR_CFLAGS($FATAL_WARNINGS, [-Wmissing-declarations -Wmissing-prototypes -Wredundant-decls -Wundef -Wwrite-strings -Wformat-nonliteral -Wformat-security -Wold-style-definition -Winit-self -Wmissing-include-dirs -Waddress -Waggregate-return -Wno-multichar -Wnested-externs $NO_WARNINGS])
 652
 653 dnl define correct level for debugging messages
 654 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 655
 656 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 657
 658 dnl Overview:
 659 dnl GST_OPTION_CFLAGS:  common cflags for profiling, debugging, errors, ...
 660 dnl GST_ALL_*:          vars shared by all built objects
 661 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 662 dnl GST_OBJ_*:          additional vars to link to the core library
 663 dnl                     include GST_ALL_*
 664 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 665 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 666
 667 dnl GST_OPTION_CFLAGS
 668 if test "x$USE_DEBUG" = xyes; then
 669    PROFILE_CFLAGS="-g"
 670 fi
 671 AC_SUBST(PROFILE_CFLAGS)
 672
 673 # GST_DISABLE_DEPRECATED: hide the visibility of deprecated
 674 # functionality from the API that gstreamer uses
 675 # GST_REMOVE_DEPRECATED: don't compile deprecated functionality (breaks ABI)
 676 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
 677   dnl Define _only_ when compiling from git (not for pre-releases or releases)
 678   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 679 else
 680   DEPRECATED_CFLAGS=""
 681 fi
 682 AC_SUBST(DEPRECATED_CFLAGS)
 683
 684 dnl every flag in GST_OPTION_CFLAGS can be overridden at make time via e.g.
 685 dnl make DEPRECATED_CFLAGS=''
 686 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 687 GST_OPTION_CXXFLAGS="\$(WARNING_CXXFLAGS) \$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 688 AC_SUBST(GST_OPTION_CFLAGS)
 689 AC_SUBST(GST_OPTION_CXXFLAGS)
 690
 691 dnl GST_ALL_*
 692 dnl vars common to for all internal objects (core libs, elements, applications)
 693 dnl CFLAGS:
 694 dnl - XML needs to be added because xmlPtr is used in core
 695 dnl - src and build dirs need to be added because every piece that gets built
 696 dnl   will need the GStreamer source and generated headers
 697 dnl LIBS: XML doesn't need to be added because we don't explicitly use symbols
 698 dnl       from LibXML except for in the core library
 699 GST_ALL_CXXFLAGS="-I\$(top_srcdir)/libs -I\$(top_srcdir) -I\$(top_builddir)/libs -I\$(top_builddir) $GLIB_CFLAGS \$(GLIB_EXTRA_CFLAGS) $XML_CFLAGS \$(GST_OPTION_CXXFLAGS) \$(ERROR_CXXFLAGS)"
 700 GST_ALL_CFLAGS="-I\$(top_srcdir)/libs -I\$(top_srcdir) -I\$(top_builddir)/libs -I\$(top_builddir) $GLIB_CFLAGS \$(GLIB_EXTRA_CFLAGS) $XML_CFLAGS \$(GST_OPTION_CFLAGS) \$(ERROR_CFLAGS)"
 701
 702 dnl FIXME: check if LTLIBINTL is needed everywhere
 703 dnl I presume it is given that it contains the symbols that _() stuff maps to
 704 GST_ALL_LIBS="$GLIB_LIBS $LTLIBINTL \$(GCOV_LIBS)"
 705
 706 dnl LDFLAGS really should only contain flags, not libs - they get added before
 707 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 708 GST_ALL_LDFLAGS="-no-undefined"
 709 if test "x${enable_Bsymbolic}" = "xyes"; then
 710   GST_ALL_LDFLAGS="$GST_ALL_LDFLAGS -Wl,-Bsymbolic-functions"
 711 fi
 712
 713 AC_SUBST(GST_ALL_CFLAGS)
 714 AC_SUBST(GST_ALL_CXXFLAGS)
 715 AC_SUBST(GST_ALL_LIBS)
 716 AC_SUBST(GST_ALL_LDFLAGS)
 717
 718 dnl GST_LIB_LDFLAGS
 719 dnl linker flags shared by all libraries
 720 dnl LDFLAGS modifier defining exported symbols from built libraries
 721 GST_LIB_LDFLAGS="-export-symbols-regex \^[_]*\(gst_\|Gst\|GST_\).*"
 722 AC_SUBST(GST_LIB_LDFLAGS)
 723
 724 dnl GST_OBJ_*
 725 dnl default vars for all internal objects built on libgstreamer
 726 dnl includes GST_ALL_*
 727 GST_OBJ_CFLAGS="\$(GST_ALL_CFLAGS)"
 728 GST_OBJ_CXXFLAGS="\$(GST_ALL_CXXFLAGS)"
 729 GST_OBJ_LIBS="\$(top_builddir)/gst/libgstreamer-$GST_MAJORMINOR.la \$(GST_ALL_LIBS)"
 730 AC_SUBST(GST_OBJ_CFLAGS)
 731 AC_SUBST(GST_OBJ_CXXFLAGS)
 732 AC_SUBST(GST_OBJ_LIBS)
 733
 734 dnl GST_PLUGIN_LDFLAGS
 735 dnl LDFLAGS for plugins; includes GST_ALL_LDFLAGS
 736 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc.*' $GST_ALL_LDFLAGS"
 737 AC_SUBST(GST_PLUGIN_LDFLAGS, "$GST_PLUGIN_LDFLAGS")
 738
 739 dnl plugin scanner locations
 740 AS_AC_EXPAND(GST_PLUGIN_SCANNER_INSTALLED,${libexecdir}/gstreamer-$GST_MAJORMINOR/gst-plugin-scanner)
 741 AC_DEFINE_UNQUOTED(GST_PLUGIN_SCANNER_INSTALLED,
 742     "$GST_PLUGIN_SCANNER_INSTALLED", [location of the installed gst-plugin-scanner])
 743 AC_SUBST(GST_PLUGIN_SCANNER_INSTALLED)
 744
 745 dnl things for our internal libcheck (must be called even if building
 746 dnl libcheck is disabled because it defines conditionals)
 747 AG_GST_CHECK_CHECKS()
 748
 749 AC_CONFIG_FILES(
 750 Makefile
 751 gst/Makefile
 752 gst/gstconfig.h
 753 gst/gstversion.h
 754 gst/parse/Makefile
 755 libs/Makefile
 756 libs/gst/Makefile
 757 libs/gst/base/Makefile
 758 libs/gst/check/Makefile
 759 libs/gst/check/libcheck/Makefile
 760 libs/gst/check/libcheck/check.h
 761 libs/gst/controller/Makefile
 762 libs/gst/dataprotocol/Makefile
 763 libs/gst/helpers/Makefile
 764 libs/gst/net/Makefile
 765 plugins/Makefile
 766 plugins/indexers/Makefile
 767 plugins/elements/Makefile
 768 po/Makefile.in
 769 tests/Makefile
 770 tests/benchmarks/Makefile
 771 tests/check/Makefile
 772 tests/misc/Makefile
 773 tests/examples/Makefile
 774 tests/examples/adapter/Makefile
 775 tests/examples/controller/Makefile
 776 tests/examples/stepping/Makefile
 777 tests/examples/helloworld/Makefile
 778 tests/examples/launch/Makefile
 779 tests/examples/manual/Makefile
 780 tests/examples/metadata/Makefile
 781 tests/examples/queue/Makefile
 782 tests/examples/streams/Makefile
 783 tests/examples/typefind/Makefile
 784 tools/Makefile
 785 common/Makefile
 786 common/m4/Makefile
 787 docs/Makefile
 788 docs/design/Makefile
 789 docs/faq/Makefile
 790 docs/gst/Makefile
 791 docs/gst/gstreamer.types
 792 docs/libs/Makefile
 793 docs/plugins/Makefile
 794 docs/manual/Makefile
 795 docs/pwg/Makefile
 796 docs/slides/Makefile
 797 docs/xsl/Makefile
 798 docs/version.entities
 799 m4/Makefile
 800 pkgconfig/Makefile
 801 stamp.h
 802 pkgconfig/gstreamer.pc
 803 pkgconfig/gstreamer-uninstalled.pc
 804 pkgconfig/gstreamer-base.pc
 805 pkgconfig/gstreamer-base-uninstalled.pc
 806 pkgconfig/gstreamer-check.pc
 807 pkgconfig/gstreamer-check-uninstalled.pc
 808 pkgconfig/gstreamer-controller.pc
 809 pkgconfig/gstreamer-controller-uninstalled.pc
 810 pkgconfig/gstreamer-dataprotocol.pc
 811 pkgconfig/gstreamer-dataprotocol-uninstalled.pc
 812 pkgconfig/gstreamer-net.pc
 813 pkgconfig/gstreamer-net-uninstalled.pc
 814 gst-element-check.m4
 815 gstreamer.spec
 816 )
 817
 818 dnl Create the config.h file for Visual Studio builds
 819 dnl Beware of spaces and /'s in some of the shell variable contents.
 820 sed \
 821     -e 's/.*config.h.in.*autoheader.*/\/* Autogenerated config.h created for win32 Visual Studio builds *\/\n\n\/* PREFIX -- specifically added for Windows for easier moving *\/\n#define PREFIX "C:\\\\gstreamer"/' \
 822     -e 's/.* GETTEXT_PACKAGE$/#define GETTEXT_PACKAGE "'$GETTEXT_PACKAGE'"/' \
 823     -e 's/.* GST_DATADIR$/#define GST_DATADIR PREFIX "\\\\share"/' \
 824     -e 's/.* GST_LEVEL_DEFAULT$/#define GST_LEVEL_DEFAULT GST_LEVEL_ERROR/' \
 825     -e 's/.* GST_LICENSE$/#define GST_LICENSE "'$GST_LICENSE'"/' \
 826     -e 's/.* GST_MAJORMINOR$/#define GST_MAJORMINOR "'$GST_MAJORMINOR'"/' \
 827     -e "s,.* GST_PACKAGE_NAME$,#define GST_PACKAGE_NAME \"${GST_PACKAGE_NAME}\"," \
 828     -e 's/.* GST_PACKAGE_ORIGIN$/#define GST_PACKAGE_ORIGIN "Unknown package origin"/' \
 829     -e "s,.* GST_PACKAGE_RELEASE_DATETIME$,#define GST_PACKAGE_RELEASE_DATETIME \"${GST_PACKAGE_RELEASE_DATETIME}\"," \
 830     -e 's/.* HAVE_CPU_I386$/#define HAVE_CPU_I386 1/' \
 831     -e 's/.* HAVE_FGETPOS$/#define HAVE_FGETPOS 1/' \
 832     -e 's/.* HAVE_FSETPOS$/#define HAVE_FSETPOS 1/' \
 833     -e 's/.* HAVE_LIBXML2$/#define HAVE_LIBXML2 1/' \
 834     -e 's/.* HAVE_PROCESS_H$/#define HAVE_PROCESS_H 1/' \
 835     -e 's/.* HAVE_STDLIB_H$/#define HAVE_STDLIB_H 1/' \
 836     -e 's/.* HAVE_STRING_H$/#define HAVE_STRING_H 1/' \
 837     -e 's/.* HAVE_SYS_STAT_H$/#define HAVE_SYS_STAT_H 1/' \
 838     -e 's/.* HAVE_SYS_TYPES_H$/#define HAVE_SYS_TYPES_H 1/' \
 839     -e 's/.* HAVE_WIN32$/#define HAVE_WIN32 1/' \
 840     -e 's/.* HAVE_WINSOCK2_H$/#define HAVE_WINSOCK2_H 1/' \
 841     -e 's/.* HOST_CPU$/#define HOST_CPU "i686"/' \
 842     -e 's/.* BUFFER_ALIGNMENT_MALLOC/#define BUFFER_ALIGNMENT_MALLOC 1/' \
 843     -e 's/.* LIBDIR$/#ifdef _DEBUG\n#  define LIBDIR PREFIX "\\\\debug\\\\lib"\n#else\n#  define LIBDIR PREFIX "\\\\lib"\n#endif/' \
 844     -e 's/.* LOCALEDIR$/#define LOCALEDIR PREFIX "\\\\share\\\\locale"/' \
 845     -e 's/.* PACKAGE$/#define PACKAGE "gstreamer"/' \
 846     -e 's/.* PACKAGE_BUGREPORT$/#define PACKAGE_BUGREPORT "http:\/\/bugzilla.gnome.org\/enter_bug.cgi?product=GStreamer"/' \
 847     -e 's/.* PACKAGE_NAME$/#define PACKAGE_NAME "'$PACKAGE_NAME'"/' \
 848     -e "s/.* PACKAGE_STRING$/#define PACKAGE_STRING \"$PACKAGE_STRING\"/" \
 849     -e 's/.* PACKAGE_TARNAME$/#define PACKAGE_TARNAME "'$PACKAGE_TARNAME'"/' \
 850     -e 's/.* PACKAGE_VERSION$/#define PACKAGE_VERSION "'$PACKAGE_VERSION'"/' \
 851     -e 's/.* PLUGINDIR$/#ifdef _DEBUG\n#  define PLUGINDIR PREFIX "\\\\debug\\\\lib\\\\gstreamer-0.10"\n#else\n#  define PLUGINDIR PREFIX "\\\\lib\\\\gstreamer-0.10"\n#endif/' \
 852     -e 's/.* GST_PLUGIN_SCANNER_INSTALLED$/#define GST_PLUGIN_SCANNER_INSTALLED LIBDIR "\\\\gst-plugin-scanner"/' \
 853     -e 's/.* VERSION$/#define VERSION "'$VERSION'"/' \
 854     config.h.in >win32/common/config.h-new
 855
 856 AC_OUTPUT
 857
 858 dnl negate for output
 859 if test "x${GST_DISABLE_GST_DEBUG}" = "xno"; then enable_gst_debug="yes"; fi
 860 if test "x${GST_DISABLE_LOADSAVE}" = "xno"; then enable_loadsave="yes"; fi
 861 if test "x${GST_DISABLE_PARSE}" = "xno"; then enable_parse="yes"; fi
 862 if test "x${GST_DISABLE_OPTION_PARSING}" = "xno"; then enable_option_parsing="yes"; fi
 863 if test "x${GST_DISABLE_TRACE}" = "xno"; then enable_trace="yes"; fi
 864 if test "x${GST_DISABLE_ALLOC_TRACE}" = "xno"; then enable_alloc_trace="yes"; fi
 865 if test "x${GST_DISABLE_PLUGIN}" = "xno"; then enable_plugin="yes"; fi
 866 if test "x${GST_DISABLE_REGISTRY}" = "xno"; then enable_registry="yes"; fi
 867 if test "x${GST_DISABLE_NET}" = "xno"; then enable_net="yes"; fi
 868
 869 echo "
 870
 871 Configuration
 872         Version                    : ${VERSION}
 873         Source code location       : ${srcdir}
 874         Prefix                     : ${prefix}
 875         Compiler                   : ${CC}
 876         Package name               : ${GST_PACKAGE_NAME}
 877         Package origin             : ${GST_PACKAGE_ORIGIN}
 878
 879         Documentation (manuals)    : ${enable_docbook}
 880         Documentation (API)        : ${enable_gtk_doc}
 881
 882         Debug Logging              : ${enable_gst_debug}
 883         Pipeline XML load/save     : ${enable_loadsave}
 884         Command-line parser        : ${enable_parse}
 885         Option parsing in gst_init : ${enable_option_parsing}
 886         Tracing subsystem          : ${enable_trace}
 887         Allocation tracing         : ${enable_alloc_trace}
 888         Plugin registry            : ${enable_registry}
 889         Plugin support             : ${enable_plugin}
 890         Network support            : ${enable_net}
 891         Unit testing support       : ${BUILD_CHECK}
 892
 893         Debug                      : ${USE_DEBUG}
 894         Profiling                  : ${USE_PROFILING}
 895
 896         Building examples          : ${BUILD_EXAMPLES}
 897         Building test apps         : ${BUILD_TESTS}
 898         Building tests that fail   : ${BUILD_FAILING_TESTS}
 899 "