configure.ac

   1 AC_PREREQ(2.60)
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, git and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for git/prerelease
   8 AC_INIT(GStreamer Base Plug-ins, 0.11.0.2,
   9     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
  10     gst-plugins-base)
  11
  12 AG_GST_INIT
  13
  14 dnl initialize automake
  15 AM_INIT_AUTOMAKE([-Wno-portability 1.10])
  16
  17 dnl define PACKAGE_VERSION_* variables
  18 AS_VERSION
  19
  20 dnl check if this is a release version
  21 AS_NANO(GST_GIT="no", GST_GIT="yes")
  22
  23 dnl can autoconf find the source ?
  24 AC_CONFIG_SRCDIR([gst/audiotestsrc/gstaudiotestsrc.c])
  25
  26 dnl define the output header for config
  27 AM_CONFIG_HEADER([config.h])
  28
  29 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  30 AM_MAINTAINER_MODE
  31
  32 dnl sets host_* variables
  33 AC_CANONICAL_HOST
  34
  35 dnl use pretty build output with automake >= 1.11
  36 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],
  37   [AM_DEFAULT_VERBOSITY=1
  38    AC_SUBST(AM_DEFAULT_VERBOSITY)])
  39
  40 dnl our libraries and install dirs use major.minor as a version
  41 GST_MAJORMINOR=$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR
  42 dnl we override it here if we need to for the release candidate of new series
  43 GST_MAJORMINOR=0.11
  44 AC_SUBST(GST_MAJORMINOR)
  45
  46 dnl CURRENT, REVISION, AGE
  47 dnl - library source changed -> increment REVISION
  48 dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
  49 dnl - interfaces added -> increment AGE
  50 dnl - interfaces removed -> AGE = 0
  51 dnl sets GST_LT_LDFLAGS
  52 AS_LIBTOOL(GST, 25, 0, 0)
  53
  54 dnl FIXME: this macro doesn't actually work;
  55 dnl the generated libtool script has no support for the listed tags.
  56 dnl So this needs to be fixed first if we want to use this
  57 dnl AS_LIBTOOL_TAGS
  58
  59 AC_LIBTOOL_WIN32_DLL
  60 AM_PROG_LIBTOOL
  61
  62 dnl *** required versions of GStreamer stuff ***
  63 GST_REQ=0.11.0
  64
  65 dnl *** autotools stuff ****
  66
  67 dnl allow for different autotools
  68 AS_AUTOTOOLS_ALTERNATE
  69
  70 dnl Add parameters for aclocal
  71 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  72
  73 dnl set up gettext
  74 dnl the version check needs to stay here because autopoint greps for it
  75 AM_GNU_GETTEXT_VERSION([0.17])
  76 AM_GNU_GETTEXT([external])
  77 AG_GST_GETTEXT([gst-plugins-base-$GST_MAJORMINOR])
  78
  79 dnl *** check for arguments to configure ***
  80
  81 AG_GST_ARG_DEBUG
  82 AG_GST_ARG_PROFILING
  83 AG_GST_ARG_VALGRIND
  84 AG_GST_ARG_GCOV
  85
  86 AG_GST_ARG_EXAMPLES
  87
  88 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  89 AG_GST_ARG_WITH_PACKAGE_NAME
  90 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  91
  92 AG_GST_PKG_CONFIG_PATH
  93
  94 dnl let distro override plugin install helper path
  95 AC_ARG_WITH(install-plugins-helper,
  96   AC_HELP_STRING([--with-install-plugins-helper],
  97     [specify path of helper script to call to install plugins]),
  98   [
  99     case "${withval}" in
 100       yes) AC_MSG_ERROR(bad value ${withval} for --with-install-plugins-helper) ;;
 101       no)  AC_MSG_ERROR(bad value ${withval} for --with-install-plugins-helper) ;;
 102       *)   GST_INSTALL_PLUGINS_HELPER="${withval}" ;;
 103     esac
 104   ],
 105   [
 106     dnl Default value
 107     AS_AC_EXPAND(GST_INSTALL_PLUGINS_HELPER,${libexecdir}/gst-install-plugins-helper)
 108   ]
 109 )
 110 AC_MSG_NOTICE(Using $GST_INSTALL_PLUGINS_HELPER as plugin install helper)
 111 AC_DEFINE_UNQUOTED(GST_INSTALL_PLUGINS_HELPER, "$GST_INSTALL_PLUGINS_HELPER",
 112     [plugin install helper script])
 113 AC_SUBST(GST_INSTALL_PLUGINS_HELPER)
 114
 115 AG_GST_ARG_WITH_PLUGINS
 116
 117 AG_GST_ARG_ENABLE_EXTERNAL
 118
 119 AG_GST_ARG_ENABLE_EXPERIMENTAL
 120
 121 dnl *** checks for platform ***
 122
 123 dnl * hardware/architecture *
 124
 125 dnl common/m4/gst-arch.m4
 126 dnl check CPU type
 127 AG_GST_ARCH
 128
 129 dnl check for large file support
 130 dnl affected plugins must include config.h
 131 AC_SYS_LARGEFILE
 132
 133 dnl *** checks for programs ***
 134
 135 dnl find a compiler
 136 AC_PROG_CC
 137 AC_PROG_CC_STDC
 138
 139 dnl check if the compiler supports '-c' and '-o' options
 140 AM_PROG_CC_C_O
 141
 142 dnl determine if c++ is available on this system
 143 AC_PROG_CXX
 144 dnl CXX may be set to some default even if no c++ compiler is available
 145 dnl (thanks autotools!), so just try to compile some c++ code to make sure
 146 AC_LANG_PUSH([C++])
 147 AC_TRY_COMPILE([ class Foo { int bar; };], , working_cxx=yes, working_cxx=no)
 148 AC_LANG_POP([C++])
 149 AC_MSG_NOTICE([working c++ compiler found: $working_cxx])
 150 AM_CONDITIONAL(HAVE_CXX, test "x$working_cxx" = "xyes")
 151
 152 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 153 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 154
 155 dnl check for gobject-introspection
 156 GOBJECT_INTROSPECTION_CHECK([0.9.12])
 157
 158 dnl check for documentation tools
 159 GTK_DOC_CHECK([1.3])
 160 AS_PATH_PYTHON([2.1])
 161 AG_GST_PLUGIN_DOCS([1.3],[2.1])
 162
 163 dnl *** checks for libraries ***
 164
 165 dnl libm, for sin() etc.
 166 AC_CHECK_LIBM
 167 AC_SUBST(LIBM)
 168
 169 dnl *** checks for header files ***
 170
 171 dnl check if we have ANSI C header files
 172 AC_HEADER_STDC
 173
 174 ac_cppflags_save="$CPPFLAGS"
 175 CPPFLAGS="`$PKG_CONFIG --cflags libxml-2.0`"
 176 AC_COMPILE_IFELSE(
 177   AC_LANG_PROGRAM([
 178 #include <libxml/HTMLparser.h>
 179                      ],[
 180 #ifndef LIBXML_HTML_ENABLED
 181 #error libxml2 has no HTML support
 182 #endif /* LIBXML_HTML_ENABLED */
 183                    ]), HAVE_LIBXML_HTML="yes", HAVE_LIBXML_HTML="no")
 184 CPPFLAGS="$ac_cppflags_save"
 185 AM_CONDITIONAL(HAVE_LIBXML_HTML, test "x$HAVE_LIBXML_HTML" = "xyes")
 186
 187 dnl used in gst/tcp
 188 AC_CHECK_HEADERS([sys/socket.h],
 189   HAVE_SYS_SOCKET_H="yes", HAVE_SYS_SOCKET_H="no")
 190 AM_CONDITIONAL(HAVE_SYS_SOCKET_H, test "x$HAVE_SYS_SOCKET_H" = "xyes")
 191
 192 dnl used in gst-libs/gst/rtsp
 193 AC_CHECK_HEADERS([winsock2.h], HAVE_WINSOCK2_H=yes)
 194 if test "x$HAVE_WINSOCK2_H" = "xyes"; then
 195   WIN32_LIBS="-lws2_32"
 196   AC_SUBST(WIN32_LIBS)
 197 fi
 198
 199 dnl check for hstrerror, for gst-libs/gst/rtsp
 200 save_libs="$LIBS"
 201 AC_CHECK_FUNC(hstrerror, ,
 202     AC_CHECK_LIB(resolv, hstrerror, ,
 203         [AC_DEFINE(NO_HSTRERROR, 1,
 204              [Define if you have no native hstrerror() function.])]))
 205 HSTRERROR_LIBS=$LIBS
 206 AC_SUBST(HSTRERROR_LIBS)
 207 LIBS="$save_libs"
 208
 209 dnl used in gst-libs/gst/pbutils and associated unit test
 210 AC_CHECK_HEADERS([process.h sys/types.h sys/wait.h sys/stat.h])
 211
 212 dnl also, Windows does not have long long
 213 AX_CREATE_STDINT_H
 214
 215 dnl *** checks for functions ***
 216 AC_CHECK_FUNCS([localtime_r gmtime_r])
 217
 218 dnl *** checks for math functions ***
 219 LIBS_SAVE=$LIBS
 220 LIBS="$LIBS $LIBM"
 221 AC_CHECK_FUNCS(log2)
 222 LIBS=$LIBS_SAVE
 223
 224 dnl *** checks for types/defines ***
 225
 226 dnl Check for FIONREAD ioctl declaration
 227 dnl used in gst/tcp
 228 GST_CHECK_FIONREAD
 229
 230 dnl *** checks for structures ***
 231
 232 dnl *** checks for compiler characteristics ***
 233
 234 dnl *** checks for library functions ***
 235
 236 dnl check for fseeko()
 237 AC_FUNC_FSEEKO
 238
 239 dnl Check for fast float to int casting as defined in C99
 240 dnl used in gst-libs/gst/floatcast/floatcast.h
 241 save_libs=$LIBS
 242 LIBS="$LIBS $LIBM"
 243 AC_C99_FUNC_LRINT
 244 AC_C99_FUNC_LRINTF
 245 LIBS=$save_libs
 246
 247 dnl Check for a way to display the function name in debug output
 248 AG_GST_CHECK_FUNCTION
 249
 250 dnl *** checks for socket and nsl libraries ***
 251 AC_CHECK_FUNC(socket,,[AC_CHECK_LIB(socket,socket)])
 252 AC_CHECK_FUNC(gethostbyname,,[AC_CHECK_LIB(nsl,gethostbyname)])
 253
 254 dnl *** checks for dependency libraries ***
 255
 256 dnl GLib is required
 257 AG_GST_GLIB_CHECK([2.26])
 258
 259 ORC_CHECK([0.4.11])
 260
 261 dnl checks for gstreamer
 262 dnl uninstalled is selected preferentially -- see pkg-config(1)
 263 AG_GST_CHECK_GST($GST_MAJORMINOR, [$GST_REQ], yes)
 264 AG_GST_CHECK_GST_BASE($GST_MAJORMINOR, [$GST_REQ], yes)
 265 AG_GST_CHECK_GST_GDP($GST_MAJORMINOR, [$GST_REQ], yes)
 266 AG_GST_CHECK_GST_CONTROLLER($GST_MAJORMINOR, [$GST_REQ], yes)
 267 AG_GST_CHECK_GST_CHECK($GST_MAJORMINOR, [$GST_REQ], no)
 268 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 269
 270 dnl Check for documentation xrefs
 271 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 272 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_MAJORMINOR`"
 273 AC_SUBST(GLIB_PREFIX)
 274 AC_SUBST(GST_PREFIX)
 275
 276 dnl GTK is optional and only used in examples
 277 HAVE_GTK=no
 278 HAVE_GTK_X11=no
 279 GTK2_REQ=2.14.0
 280 GTK3_REQ=2.91.3
 281 if test "x$BUILD_EXAMPLES" = "xyes"; then
 282   AC_MSG_CHECKING([which gtk+ version to compile examples against (optional)])
 283   AC_ARG_WITH([gtk],
 284     AC_HELP_STRING([--with-gtk=3.0|2.0],
 285                    [which gtk+ version to compile against (default: 2.0)]),
 286     [case "$with_gtk" in
 287         2.0) GTK_REQ=$GTK2_REQ ;;
 288         3.0) GTK_REQ=$GTK3_REQ ;;
 289         *) AC_MSG_ERROR([invalid gtk+ version specified]);;
 290     esac],
 291     [with_gtk=2.0
 292      GTK_REQ=$GTK2_REQ])
 293   AC_MSG_RESULT([$with_gtk (>= $GTK_REQ)])
 294   PKG_CHECK_MODULES(GTK, gtk+-$with_gtk >= $GTK_REQ, HAVE_GTK=yes, HAVE_GTK=no)
 295   dnl some examples need gtk+-x11
 296   PKG_CHECK_MODULES(GTK_X11, gtk+-x11-$with_gtk >= $GTK_REQ, HAVE_GTK_X11=yes, HAVE_GTK_X11=no)
 297   AC_SUBST(GTK_LIBS)
 298   AC_SUBST(GTK_CFLAGS)
 299 fi
 300 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 301 AM_CONDITIONAL(HAVE_GTK_X11, test "x$HAVE_GTK_X11" = "xyes")
 302
 303 dnl QT is optional and only used in examples
 304 PKG_CHECK_MODULES(QT, QtGui >= 4.6, [
 305   HAVE_QT_GV=yes
 306   HAVE_QT=yes
 307 ], [
 308   HAVE_QT_GV=no
 309   PKG_CHECK_MODULES(QT, QtGui >= 4.0, HAVE_QT=yes, HAVE_QT=no)
 310 ])
 311 if test "x$HAVE_QT" = "xyes"; then
 312   AC_MSG_CHECKING([Qt moc])
 313   QT4_MOC=`$PKG_CONFIG --variable=moc_location QtGui`
 314   AC_MSG_RESULT($QT4_MOC)
 315   AC_SUBST(QT4_MOC)
 316 fi
 317 AM_CONDITIONAL(HAVE_QT, test "x$HAVE_QT" = "xyes")
 318 AM_CONDITIONAL(HAVE_QT_GV, test "x$HAVE_QT_GV" = "xyes")
 319
 320 dnl chck for linux headers needed by the joystick seek example
 321 AC_COMPILE_IFELSE(
 322 [
 323   AC_LANG_PROGRAM([
 324     #include <linux/input.h>
 325     #include <linux/joystick.h>
 326   ],[
 327     struct js_event js;
 328     js.type = JS_EVENT_AXIS;
 329   ])
 330 ], [
 331   HAVE_LINUX_JOYSTICK_HEADERS="yes"
 332 ], [
 333   HAVE_LINUX_JOYSTICK_HEADERS="no"
 334 ])
 335 AM_CONDITIONAL(HAVE_LINUX_JOYSTICK_HEADERS, test "x$HAVE_LINUX_JOYSTICK_HEADERS" = "xyes")
 336
 337 dnl Check for -Bsymbolic-functions linker flag used to avoid
 338 dnl intra-library PLT jumps, if available.
 339 AC_ARG_ENABLE(Bsymbolic,
 340               [AC_HELP_STRING([--disable-Bsymbolic],
 341                               [avoid linking with -Bsymbolic])],,
 342               [SAVED_LDFLAGS="${LDFLAGS}"
 343                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
 344                LDFLAGS=-Wl,-Bsymbolic-functions
 345                AC_TRY_LINK([], [int main (void) { return 0; }],
 346                            AC_MSG_RESULT(yes)
 347                            enable_Bsymbolic=yes,
 348                            AC_MSG_RESULT(no)
 349                            enable_Bsymbolic=no)
 350                LDFLAGS="${SAVED_LDFLAGS}"])
 351
 352
 353 dnl *** set variables based on configure arguments ***
 354
 355 dnl set license and copyright notice
 356 GST_LICENSE="LGPL"
 357 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 358 AC_SUBST(GST_LICENSE)
 359
 360 dnl set location of plugin directory
 361 AG_GST_SET_PLUGINDIR
 362
 363 dnl set release date/time
 364 AG_GST_SET_PACKAGE_RELEASE_DATETIME_WITH_NANO([$PACKAGE_VERSION_NANO],
 365   ["${srcdir}/gst-plugins-base.doap"],
 366   [$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_MICRO])
 367
 368 dnl define an ERROR_CFLAGS Makefile variable
 369 dnl -Wformat-nonliteral - see ext/pango/gstclockoverlay.c and http://gcc.gnu.org/bugzilla/show_bug.cgi?id=39438
 370 AG_GST_SET_ERROR_CFLAGS($GST_GIT, [
 371     -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls -Wundef
 372     -Wwrite-strings -Wformat-nonliteral -Wformat-security
 373     -Winit-self -Wmissing-include-dirs -Waddress -Waggregate-return
 374     -Wno-multichar -Wnested-externs ])
 375
 376 dnl define an ERROR_CXXFLAGS Makefile variable
 377 AG_GST_SET_ERROR_CXXFLAGS($GST_GIT, [
 378     -Wmissing-declarations -Wredundant-decls -Wundef
 379     -Wwrite-strings -Wformat-nonliteral -Wformat-security
 380     -Winit-self -Wmissing-include-dirs -Waddress -Waggregate-return
 381     -Wno-multichar])
 382
 383 dnl define correct level for debugging messages
 384 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 385
 386 dnl used in examples
 387 AG_GST_DEFAULT_ELEMENTS
 388
 389 dnl needed for encoding-target
 390 GST_DATADIR="$GST_PREFIX/share"
 391 AC_DEFINE_UNQUOTED(GST_DATADIR, "$GST_DATADIR", [system wide data directory])
 392 AC_DEFINE_UNQUOTED(GST_MAJORMINOR, "$GST_MAJORMINOR", [major/minor version])
 393
 394 dnl behaviour of speex based audio resampler
 395 AC_MSG_CHECKING(which audio resample format to use for integer)
 396 AC_ARG_WITH([audioresample_format],
 397         AS_HELP_STRING([--with-audioresample-format],[Which implementation should be used for integer audio resampling, int/float/auto, (default is auto)]),
 398         [ac_cv_audioresample_format=$withval], [ac_cv_audioresample_format=auto])dnl
 399 AC_MSG_RESULT($ac_cv_audioresample_format)
 400 case $ac_cv_audioresample_format in
 401   int)
 402     AC_DEFINE(AUDIORESAMPLE_FORMAT_INT,1,[The int implementation should be used for integer audio resampling])
 403     AC_SUBST(AUDIORESAMPLE_FORMAT_INT)
 404   ;;
 405   float)
 406     AC_DEFINE(AUDIORESAMPLE_FORMAT_FLOAT,1,[The float implementation should be used for integer audio resampling])
 407     AC_SUBST(AUDIORESAMPLE_FORMAT_FLOAT)
 408   ;;
 409   auto)
 410     AC_DEFINE(AUDIORESAMPLE_FORMAT_AUTO,1,[The implementation that should be used for integer audio resampling witll be benchmarked at runtime])
 411     AC_SUBST(AUDIORESAMPLE_FORMAT_AUTO)
 412 esac
 413
 414 dnl *** plug-ins to include ***
 415
 416 dnl these are all the gst plug-ins, compilable without additional libs
 417 AG_GST_CHECK_PLUGIN(adder)
 418 AG_GST_CHECK_PLUGIN(app)
 419 AG_GST_CHECK_PLUGIN(audioconvert)
 420 AG_GST_CHECK_PLUGIN(audiorate)
 421 AG_GST_CHECK_PLUGIN(audiotestsrc)
 422 AG_GST_CHECK_PLUGIN(encoding)
 423 AG_GST_CHECK_PLUGIN(videoconvert)
 424 AG_GST_CHECK_PLUGIN(gdp)
 425 AG_GST_CHECK_PLUGIN(playback)
 426 AG_GST_CHECK_PLUGIN(audioresample)
 427 AG_GST_CHECK_PLUGIN(subparse)
 428 AG_GST_CHECK_PLUGIN(tcp)
 429 AG_GST_CHECK_PLUGIN(typefind)
 430 AG_GST_CHECK_PLUGIN(videotestsrc)
 431 AG_GST_CHECK_PLUGIN(videorate)
 432 AG_GST_CHECK_PLUGIN(videoscale)
 433 AG_GST_CHECK_PLUGIN(volume)
 434
 435 dnl FIXME 0.11: check for libxml, split subparse and move libxml parts to ext/
 436 AM_CONDITIONAL(USE_XML, false)
 437 AC_DEFINE([GST_DISABLE_XML], [1], [set to disable libxml2-dependent code in subparse])
 438
 439 dnl disable plug-ins that require libxml2's HTML support if it is not available
 440 if test "x$HAVE_LIBXML_HTML" != "xyes"; then
 441   AG_GST_DISABLE_PLUGIN(subparse)
 442 fi
 443
 444 dnl disable plug-ins that require sys/socket.h if it is not available
 445 if test "x$HAVE_SYS_SOCKET_H" != "xyes"; then
 446   AG_GST_DISABLE_PLUGIN(tcp)
 447 fi
 448
 449 dnl iso-codes is optional, used by libgsttag
 450 AC_ARG_ENABLE(iso-codes,
 451 AC_HELP_STRING([--enable-iso-codes],[use iso-codes if installed]),
 452 [case "${enableval}" in
 453   yes) enable_iso_codes=yes ;;
 454   no)  enable_iso_codes=no ;;
 455   *) AC_MSG_ERROR(bad value ${enableval} for --enable-iso-codes) ;;
 456 esac
 457 ],
 458 [enable_iso_codes=yes]) dnl Default value
 459
 460 AC_MSG_CHECKING([whether to use iso-codes if they are available])
 461 if test "x$enable_iso_codes" = "xyes"; then
 462   AC_MSG_RESULT([yes])
 463   have_iso_codes=no
 464   AC_MSG_CHECKING([whether iso-codes are available on this system])
 465   if $PKG_CONFIG iso-codes; then
 466     AC_MSG_RESULT([yes])
 467     AC_MSG_CHECKING([whether iso-codes has iso-639 domain])
 468     if $PKG_CONFIG --variable=domains iso-codes | $GREP -q 639 ; then
 469       AC_MSG_RESULT([yes])
 470       AC_MSG_CHECKING([for iso-codes prefix])
 471       ISO_CODES_PREFIX=`$PKG_CONFIG --variable=prefix iso-codes`
 472       if test -d "$ISO_CODES_PREFIX"; then
 473         AC_MSG_RESULT([yes])
 474         AC_MSG_CHECKING([ISO_CODES_PREFIX])
 475         AC_MSG_RESULT([$ISO_CODES_PREFIX])
 476         ISO_639_DOMAIN="iso_639"
 477         AC_MSG_CHECKING([ISO_639_DOMAIN])
 478         AC_MSG_RESULT([$ISO_639_DOMAIN])
 479         have_iso_codes=yes
 480         AC_DEFINE([HAVE_ISO_CODES], [1], [make use of iso-codes for ISO-639])
 481         AC_DEFINE_UNQUOTED([ISO_CODES_PREFIX], ["$ISO_CODES_PREFIX"], [prefix])
 482         ISO_CODES_VERSION=`$PKG_CONFIG --modversion iso-codes`
 483         AC_DEFINE_UNQUOTED([ISO_CODES_VERSION], ["$ISO_CODES_VERSION"], [ ])
 484       else
 485         AC_MSG_RESULT([no])
 486       fi
 487     else
 488       AC_MSG_RESULT([no])
 489     fi
 490   else
 491     AC_MSG_RESULT([no])
 492   fi
 493   AM_CONDITIONAL(USE_ISO_CODES, test "x$have_iso_codes" = "xyes")
 494 else
 495   AC_MSG_RESULT([no (disabled via --disable-iso-codes)])
 496   AM_CONDITIONAL(USE_ISO_CODES, false)
 497 fi
 498
 499 dnl *** zlib is optionally used by id3 tag parsing in libgsttag ***
 500 translit(dnm, m, l) AM_CONDITIONAL(USE_ZLIB, true)
 501 AG_GST_CHECK_FEATURE(ZLIB, [zlib support for ID3 parsing in libgsttag],, [
 502   PKG_CHECK_MODULES(ZLIB, [ zlib ], [
 503       HAVE_ZLIB="yes"
 504     ], [
 505       AG_GST_CHECK_LIBHEADER(ZLIB, z, uncompress,, zlib.h, [
 506         HAVE_ZLIB="yes"
 507         ZLIB_LIBS="-lz"
 508         AC_SUBST(ZLIB_LIBS)
 509       ])
 510     ])
 511 ])
 512
 513 dnl *** sys plug-ins ***
 514
 515 echo
 516 AC_MSG_NOTICE([Checking libraries for plugins in sys/])
 517 echo
 518
 519 dnl *** X11 ***
 520 translit(dnm, m, l) AM_CONDITIONAL(USE_X, true)
 521 AG_GST_CHECK_FEATURE(X, [X libraries and plugins],
 522                   [ximagesink], [
 523   AC_PATH_XTRA
 524   ac_cflags_save="$CFLAGS"
 525   ac_cppflags_save="$CPPFLAGS"
 526   CFLAGS="$CFLAGS $X_CFLAGS"
 527   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 528
 529   dnl now try to find the HEADER
 530   AC_CHECK_HEADER(X11/Xlib.h, HAVE_X="yes", HAVE_X="no")
 531
 532   if test "x$HAVE_X" = "xno"
 533   then
 534     AC_MSG_NOTICE([cannot find X11 development files])
 535   else
 536     dnl this is much more than we want
 537     X_LIBS="$X_LIBS $X_PRE_LIBS $X_EXTRA_LIBS"
 538     dnl AC_PATH_XTRA only defines the path needed to find the X libs,
 539     dnl it does not add the libs; therefore we add them here
 540     X_LIBS="$X_LIBS -lX11"
 541     AC_SUBST(X_CFLAGS)
 542     AC_SUBST(X_LIBS)
 543   fi
 544   AC_SUBST(HAVE_X)
 545   CFLAGS="$ac_cflags_save"
 546   CPPFLAGS="$ac_cppflags_save"
 547 ])
 548
 549 dnl Check for Xv extension
 550 translit(dnm, m, l) AM_CONDITIONAL(USE_XVIDEO, true)
 551 AG_GST_CHECK_FEATURE(XVIDEO, [X11 XVideo extensions],
 552                   [xvimagesink], [
 553   AG_GST_CHECK_XV
 554 ])
 555
 556 dnl check for X Shm
 557 translit(dnm, m, l) AM_CONDITIONAL(USE_XSHM, true)
 558 AG_GST_CHECK_FEATURE(XSHM, [X Shared Memory extension], , [
 559   if test x$HAVE_X = xyes; then
 560     AC_CHECK_LIB(Xext, XShmAttach,
 561                  HAVE_XSHM="yes", HAVE_XSHM="no",
 562                  $X_LIBS)
 563     if test "x$HAVE_XSHM" = "xyes"; then
 564       XSHM_LIBS="-lXext"
 565     else
 566       dnl On AIX, it is in XextSam instead, but we still need -lXext
 567       AC_CHECK_LIB(XextSam, XShmAttach,
 568                    HAVE_XSHM="yes", HAVE_XSHM="no",
 569                    $X_LIBS)
 570       if test "x$HAVE_XSHM" = "xyes"; then
 571         XSHM_LIBS="-lXext -lXextSam"
 572       fi
 573     fi
 574   fi
 575 ], , [
 576   AC_SUBST(HAVE_XSHM)
 577   AC_SUBST(XSHM_LIBS)
 578 ])
 579
 580 dnl *** ext plug-ins ***
 581 dnl keep this list sorted alphabetically !
 582
 583 if test "x$BUILD_EXTERNAL" = "xyes"; then
 584
 585 echo
 586 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 587 echo
 588
 589 dnl *** alsa ***
 590 translit(dnm, m, l) AM_CONDITIONAL(USE_ALSA, true)
 591 AG_GST_CHECK_FEATURE(ALSA, [ALSA], alsa, [
 592   PKG_CHECK_MODULES(ALSA, alsa >= 0.9.1, [
 593     HAVE_ALSA="yes"
 594     AC_SUBST(ALSA_CFLAGS)
 595     AC_SUBST(ALSA_LIBS)
 596   ], [
 597     AM_PATH_ALSA(0.9.1, HAVE_ALSA="yes", HAVE_ALSA="no")
 598   ])
 599 ])
 600
 601 dnl *** CDParanoia ***
 602 dnl Note: upstream has a pkg-config file only in post-10.2 SVN so far
 603 translit(dnm, m, l) AM_CONDITIONAL(USE_CDPARANOIA, true)
 604 AG_GST_CHECK_FEATURE(CDPARANOIA, [CDParanoia], cdparanoia, [
 605   PKG_CHECK_MODULES(CDPARANOIA, cdparanoia-3 >= 10.2, [
 606     HAVE_CDPARANOIA="yes"
 607   ], [
 608     AG_GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 609                         cdda_open, -lm,
 610                         cdda_interface.h,
 611                         CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 612                         HEADER_DIR="no"
 613                         FOUND_CDPARANOIA="yes")
 614     if test "x$FOUND_CDPARANOIA" != "xyes";
 615     then
 616       AG_GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 617                           cdda_open, -lm,
 618                           cdda/cdda_interface.h,
 619                           CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 620                           HEADER_DIR="yes"
 621                           FOUND_CDPARANOIA="yes")
 622     fi
 623     if test "x$HEADER_DIR" = "xyes";
 624     then
 625       AC_DEFINE_UNQUOTED(CDPARANOIA_HEADERS_IN_DIR, ,
 626                          defined if cdda headers are in a cdda/ directory)
 627     fi
 628     if test "x$FOUND_CDPARANOIA" = "xyes";
 629     then
 630       AC_CHECK_LIB(cdda_paranoia,
 631                    paranoia_cachemodel_size,
 632                    : ,
 633                    HAVE_CDPARANOIA=no,
 634                  [-lcdda_interface])
 635     fi
 636
 637     AC_SUBST(CDPARANOIA_LIBS)
 638   ])
 639 ])
 640 dnl FIXME : add second check somehow if that is necessary
 641 dnl AC_CHECK_LIB(cdda_paranoia, paranoia_init, : , HAVE_CDPARANOIA=no, -lcdda_interface )
 642 dnl AC_CHECK_HEADER(cdda_paranoia.h, :, HAVE_CDPARANOIA=no)
 643
 644 dnl *** ivorbis ***
 645 dnl AM_PATH_IVORBIS only takes two options
 646 translit(dnm, m, l) AM_CONDITIONAL(USE_IVORBIS, true)
 647 AG_GST_CHECK_FEATURE(IVORBIS, [integer vorbis plug-in], ivorbisdec, [
 648   AG_GST_PKG_CHECK_MODULES(IVORBIS, vorbisidec)
 649   if test $HAVE_IVORBIS = no
 650   then
 651     IVORBIS_LIBS=
 652     IVORBIS_CFLAGS=
 653     AC_CHECK_LIB(vorbisidec, vorbis_block_init,
 654       [IVORBIS_LIBS=-lvorbisidec
 655       HAVE_IVORBIS=yes
 656       case $host in
 657       arm-*-*)
 658         IVORBIS_CFLAGS="-D_ARM_ASSEM_ $IVORBIS_CFLAGS"
 659       esac
 660       ],
 661       HAVE_IVORBIS=no)
 662     AC_SUBST(IVORBIS_LIBS)
 663     AC_SUBST(IVORBIS_CFLAGS)
 664   else
 665     AC_CHECK_LIB(vorbisidec, vorbis_dsp_pcmout,
 666       AC_DEFINE([USE_TREMOLO],1, "Define if building for android"),
 667       USE_TREMOLO=no)
 668   fi
 669 ])
 670
 671 dnl *** libgio ***
 672 translit(dnm, m, l) AM_CONDITIONAL(USE_GIO, true)
 673 AG_GST_CHECK_FEATURE(GIO, [GIO library], gio, [
 674   PKG_CHECK_MODULES(GIO, gio-2.0 >= 2.16, [
 675     HAVE_GIO="yes"
 676     GIO_MODULE_DIR="`$PKG_CONFIG --variable=giomoduledir gio-2.0`"
 677     AC_DEFINE_UNQUOTED(GIO_MODULE_DIR, "$GIO_MODULE_DIR",
 678            [The GIO modules directory.])
 679     GIO_LIBDIR="`$PKG_CONFIG --variable=libdir gio-2.0`"
 680     AC_DEFINE_UNQUOTED(GIO_LIBDIR, "$GIO_LIBDIR",
 681            [The GIO library directory.])
 682   ], [
 683     HAVE_GIO="no"
 684   ])
 685   AC_SUBST(GIO_CFLAGS)
 686   AC_SUBST(GIO_LIBS)
 687   AC_SUBST(GIO_LDFLAGS)
 688 ])
 689
 690 dnl *** libvisual ***
 691 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBVISUAL, true)
 692 AG_GST_CHECK_FEATURE(LIBVISUAL, [libvisual visualization library], libvisual, [
 693   AG_GST_PKG_CHECK_MODULES(LIBVISUAL, libvisual-0.4 >= 0.4.0)
 694   if test $HAVE_LIBVISUAL = no
 695   then
 696     AG_GST_PKG_CHECK_MODULES(LIBVISUAL, libvisual = 0.2.0)
 697     if test x$HAVE_LIBVISUAL = xyes; then
 698       LIBVIS_PLUGINSDIR="`$PKG_CONFIG --variable=pluginsbasedir libvisual-0.2`"
 699     fi
 700   else
 701     if test x$HAVE_LIBVISUAL = xyes; then
 702       LIBVIS_PLUGINSDIR="`$PKG_CONFIG --variable=pluginsbasedir libvisual-0.4`"
 703     fi
 704   fi
 705   AC_MSG_NOTICE([libvisual pluginsdir: $LIBVIS_PLUGINSDIR])
 706   if test x$LIBVIS_PLUGINSDIR != x; then
 707     AC_DEFINE_UNQUOTED(LIBVISUAL_PLUGINSBASEDIR,
 708         "$LIBVIS_PLUGINSDIR",
 709         [directory in which the detected libvisual's plugins are located])
 710   fi
 711 ])
 712
 713 dnl *** ogg ***
 714 translit(dnm, m, l) AM_CONDITIONAL(USE_OGG, true)
 715 AG_GST_CHECK_FEATURE(OGG, [Xiph Ogg library], ogg, [
 716   AG_GST_PKG_CHECK_MODULES(OGG, ogg >= 1.0)
 717   if test $HAVE_OGG = no
 718   then
 719     XIPH_PATH_OGG(HAVE_OGG="yes", HAVE_OGG="no")
 720     AS_SCRUB_INCLUDE(OGG_CFLAGS)
 721   fi
 722 ])
 723
 724 dnl *** pango ***
 725 translit(dnm, m, l) AM_CONDITIONAL(USE_PANGO, true)
 726 AG_GST_CHECK_FEATURE(PANGO, [Pango font rendering], pango, [
 727   AG_GST_PKG_CHECK_MODULES(PANGO, pango >= 1.16.0  pangocairo >= 1.16.0)
 728 ])
 729
 730 dnl *** theora ***
 731 translit(dnm, m, l) AM_CONDITIONAL(USE_THEORA, true)
 732 AG_GST_CHECK_FEATURE(THEORA, [Xiph Theora video codec], theora, [
 733   AG_GST_PKG_CHECK_MODULES(THEORA, theoradec >= 1.1 theoraenc >= 1.1)
 734 ])
 735
 736 dnl *** vorbis ***
 737 dnl AM_PATH_VORBIS only takes two options
 738 translit(dnm, m, l) AM_CONDITIONAL(USE_VORBIS, true)
 739 AG_GST_CHECK_FEATURE(VORBIS, [Xiph Vorbis audio codec], vorbis, [
 740   AG_GST_PKG_CHECK_MODULES(VORBIS, vorbis >= 1.0 vorbisenc >= 1.0)
 741   if test $HAVE_VORBIS = no
 742   then
 743     XIPH_PATH_VORBIS(HAVE_VORBIS="yes", HAVE_VORBIS="no")
 744     AS_SCRUB_INCLUDE(VORBIS_CFLAGS)
 745   fi
 746 ])
 747
 748 if test "x$HAVE_VORBIS" = "xyes"; then
 749   ac_cflags_save="$CFLAGS"
 750   AC_COMPILE_IFELSE(
 751     AC_LANG_PROGRAM([
 752 #include <vorbis/codec.h>
 753                      ],[
 754 vorbis_dsp_state *v;
 755
 756 vorbis_synthesis_restart (v);
 757                      ]), HAVE_VSR=yes, HAVE_VSR=no)
 758   if test "x$HAVE_VSR" = "xyes"; then
 759     AC_DEFINE_UNQUOTED(HAVE_VORBIS_SYNTHESIS_RESTART, 1,
 760                        [defined if vorbis_synthesis_restart is present])
 761   fi
 762   CFLAGS="$ac_cflags_save"
 763 fi
 764
 765 else
 766
 767 dnl not building plugins with external dependencies,
 768 dnl but we still need to set the conditionals
 769 AM_CONDITIONAL(USE_ALSA, false)
 770 AM_CONDITIONAL(USE_CDPARANOIA, false)
 771 AM_CONDITIONAL(USE_GIO, false)
 772 AM_CONDITIONAL(USE_IVORBIS, false)
 773 AM_CONDITIONAL(USE_LIBVISUAL, false)
 774 AM_CONDITIONAL(USE_OGG, false)
 775 AM_CONDITIONAL(USE_PANGO, false)
 776 AM_CONDITIONAL(USE_THEORA, false)
 777 AM_CONDITIONAL(USE_VORBIS, false)
 778
 779 fi dnl of EXT plugins
 780
 781 dnl seeking needs freetype, so check for it here
 782 PKG_CHECK_MODULES(FT2, freetype2 >= 2.0.9, HAVE_FT2="yes", [
 783   AC_CHECK_FT2(2.0.9, HAVE_FT2="yes", HAVE_FT2="no")
 784 ])
 785 dnl make the HAVE_FT2 variable available to automake and Makefile.am
 786 AM_CONDITIONAL(HAVE_FT2, test "x$HAVE_FT2" = "xyes")
 787 AC_SUBST(FT2_CFLAGS)
 788 AC_SUBST(FT2_LIBS)
 789
 790 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 791
 792 dnl Overview:
 793 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
 794 dnl GST_*:              flags shared by built objects to link against GStreamer
 795 dnl GST_PLUGINS_BASE_CFLAGS: to link internally against the plugins base libs
 796 dnl                          (compare to other modules) or for i18n
 797 dnl GST_ALL_LDFLAGS:    linker flags shared by all
 798 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 799 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 800 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 801
 802 dnl GST_OPTION_CFLAGS
 803 if test "x$USE_DEBUG" = xyes; then
 804    PROFILE_CFLAGS="-g"
 805 fi
 806 AC_SUBST(PROFILE_CFLAGS)
 807
 808 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
 809   dnl Define _only_ when compiling a git version (not pre-releases or releases)
 810   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 811 else
 812   DEPRECATED_CFLAGS=""
 813 fi
 814 AC_SUBST(DEPRECATED_CFLAGS)
 815
 816 dnl every flag in GST_OPTION_CFLAGS and GST_OPTION_CXXFLAGS can be overridden
 817 dnl at make time with e.g. make ERROR_CFLAGS=""
 818 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 819 GST_OPTION_CXXFLAGS="\$(WARNING_CXXFLAGS) \$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 820 AC_SUBST(GST_OPTION_CFLAGS)
 821 AC_SUBST(GST_OPTION_CXXFLAGS)
 822
 823 dnl our libraries need to be versioned correctly
 824 AC_SUBST(GST_LT_LDFLAGS)
 825
 826 dnl GST_PLUGINS_BASE_CFLAGS
 827 dnl prefer internal headers to already installed ones
 828 dnl also add builddir include for enumtypes and marshal
 829 GST_PLUGINS_BASE_CFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs"
 830 AC_SUBST(GST_PLUGINS_BASE_CFLAGS)
 831
 832 dnl FIXME: do we want to rename to GST_ALL_* ?
 833 dnl add GST_OPTION_CFLAGS, but overridable
 834 GST_CFLAGS="$GST_CFLAGS -DGST_USE_UNSTABLE_API"
 835 GST_CXXFLAGS="$GLIB_CFLAGS $GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_CXXFLAGS)"
 836 GST_CFLAGS="$GLIB_CFLAGS $GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_CFLAGS)"
 837 AC_SUBST(GST_CFLAGS)
 838 AC_SUBST(GST_CXXFLAGS)
 839 dnl add GCOV libs because libtool strips -fprofile-arcs -ftest-coverage
 840 GST_LIBS="$GST_LIBS \$(GCOV_LIBS)"
 841 AC_SUBST(GST_LIBS)
 842
 843 dnl LDFLAGS really should only contain flags, not libs - they get added before
 844 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 845 GST_ALL_LDFLAGS="-no-undefined"
 846 if test "x${enable_Bsymbolic}" = "xyes"; then
 847   GST_ALL_LDFLAGS="$GST_ALL_LDFLAGS -Wl,-Bsymbolic-functions"
 848 fi
 849 AC_SUBST(GST_ALL_LDFLAGS)
 850
 851 dnl GST_LIB_LDFLAGS
 852 dnl linker flags shared by all libraries
 853 dnl LDFLAGS modifier defining exported symbols from built libraries
 854 dnl (export _gst_foo but not __gst_foo)
 855 GST_LIB_LDFLAGS="-export-symbols-regex ^_?\(gst_\|Gst\|GST_\).*"
 856 AC_SUBST(GST_LIB_LDFLAGS)
 857
 858 dnl this really should only contain flags, not libs - they get added before
 859 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 860 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc.*' $GST_ALL_LDFLAGS"
 861 AC_SUBST(GST_PLUGIN_LDFLAGS)
 862
 863 dnl *** output files ***
 864
 865 AC_CONFIG_FILES(
 866 Makefile
 867 gst-plugins-base.spec
 868 gst/Makefile
 869 gst/adder/Makefile
 870 gst/app/Makefile
 871 gst/audioconvert/Makefile
 872 gst/audiorate/Makefile
 873 gst/audiotestsrc/Makefile
 874 gst/encoding/Makefile
 875 gst/videoconvert/Makefile
 876 gst/gdp/Makefile
 877 gst/playback/Makefile
 878 gst/audioresample/Makefile
 879 gst/subparse/Makefile
 880 gst/tcp/Makefile
 881 gst/typefind/Makefile
 882 gst/videotestsrc/Makefile
 883 gst/videorate/Makefile
 884 gst/videoscale/Makefile
 885 gst/volume/Makefile
 886 sys/Makefile
 887 sys/ximage/Makefile
 888 sys/xvimage/Makefile
 889 ext/Makefile
 890 ext/alsa/Makefile
 891 ext/cdparanoia/Makefile
 892 ext/gio/Makefile
 893 ext/libvisual/Makefile
 894 ext/ogg/Makefile
 895 ext/pango/Makefile
 896 ext/theora/Makefile
 897 ext/vorbis/Makefile
 898 gst-libs/Makefile
 899 gst-libs/gst/Makefile
 900 gst-libs/gst/audio/Makefile
 901 gst-libs/gst/app/Makefile
 902 gst-libs/gst/cdda/Makefile
 903 gst-libs/gst/fft/Makefile
 904 gst-libs/gst/floatcast/Makefile
 905 gst-libs/gst/interfaces/Makefile
 906 gst-libs/gst/netbuffer/Makefile
 907 gst-libs/gst/riff/Makefile
 908 gst-libs/gst/rtp/Makefile
 909 gst-libs/gst/rtsp/Makefile
 910 gst-libs/gst/sdp/Makefile
 911 gst-libs/gst/tag/Makefile
 912 gst-libs/gst/pbutils/Makefile
 913 gst-libs/gst/pbutils/gstpluginsbaseversion.h
 914 gst-libs/gst/video/Makefile
 915 tools/Makefile
 916 pkgconfig/Makefile
 917 pkgconfig/gstreamer-audio.pc
 918 pkgconfig/gstreamer-audio-uninstalled.pc
 919 pkgconfig/gstreamer-app.pc
 920 pkgconfig/gstreamer-app-uninstalled.pc
 921 pkgconfig/gstreamer-cdda.pc
 922 pkgconfig/gstreamer-cdda-uninstalled.pc
 923 pkgconfig/gstreamer-fft.pc
 924 pkgconfig/gstreamer-fft-uninstalled.pc
 925 pkgconfig/gstreamer-floatcast.pc
 926 pkgconfig/gstreamer-floatcast-uninstalled.pc
 927 pkgconfig/gstreamer-interfaces.pc
 928 pkgconfig/gstreamer-interfaces-uninstalled.pc
 929 pkgconfig/gstreamer-netbuffer.pc
 930 pkgconfig/gstreamer-netbuffer-uninstalled.pc
 931 pkgconfig/gstreamer-pbutils.pc
 932 pkgconfig/gstreamer-pbutils-uninstalled.pc
 933 pkgconfig/gstreamer-riff.pc
 934 pkgconfig/gstreamer-riff-uninstalled.pc
 935 pkgconfig/gstreamer-rtp.pc
 936 pkgconfig/gstreamer-rtp-uninstalled.pc
 937 pkgconfig/gstreamer-rtsp.pc
 938 pkgconfig/gstreamer-rtsp-uninstalled.pc
 939 pkgconfig/gstreamer-sdp.pc
 940 pkgconfig/gstreamer-sdp-uninstalled.pc
 941 pkgconfig/gstreamer-tag.pc
 942 pkgconfig/gstreamer-tag-uninstalled.pc
 943 pkgconfig/gstreamer-video.pc
 944 pkgconfig/gstreamer-video-uninstalled.pc
 945 pkgconfig/gstreamer-plugins-base.pc
 946 pkgconfig/gstreamer-plugins-base-uninstalled.pc
 947 tests/Makefile
 948 tests/check/Makefile
 949 tests/examples/Makefile
 950 tests/examples/app/Makefile
 951 tests/examples/audio/Makefile
 952 tests/examples/dynamic/Makefile
 953 tests/examples/encoding/Makefile
 954 tests/examples/gio/Makefile
 955 tests/examples/overlay/Makefile
 956 tests/examples/seek/Makefile
 957 tests/examples/snapshot/Makefile
 958 tests/examples/playrec/Makefile
 959 tests/examples/volume/Makefile
 960 tests/files/Makefile
 961 tests/icles/Makefile
 962 tests/icles/playback/Makefile
 963 docs/Makefile
 964 docs/design/Makefile
 965 docs/libs/Makefile
 966 docs/plugins/Makefile
 967 docs/version.entities
 968 po/Makefile.in
 969 common/Makefile
 970 common/m4/Makefile
 971 m4/Makefile
 972 )
 973
 974 dnl Create the config.h file for Visual Studio builds
 975 dnl Beware of spaces and /'s in some of the shell variable contents.
 976 sed \
 977     -e 's/.*config.h.in.*autoheader.*/\/* Autogenerated config.h created for win32 Visual Studio builds *\/\n\n\/* PREFIX -- specifically added for Windows for easier moving *\/\n#define PREFIX "C:\\\\gstreamer"/' \
 978     -e 's/.* GST_INSTALL_PLUGINS_HELPER/#define GST_INSTALL_PLUGINS_HELPER PREFIX "\\\\libexec\\\\gst-install-plugins-helper.exe"/' \
 979     -e 's/.* GETTEXT_PACKAGE$/#define GETTEXT_PACKAGE "'$GETTEXT_PACKAGE'"/' \
 980     -e 's/.* GST_DATADIR$/#define GST_DATADIR PREFIX "\\\\share"/' \
 981     -e 's/.* GST_LEVEL_DEFAULT$/#define GST_LEVEL_DEFAULT GST_LEVEL_ERROR/' \
 982     -e 's/.* GST_LICENSE$/#define GST_LICENSE "'$GST_LICENSE'"/' \
 983     -e 's/.* GST_MAJORMINOR$/#define GST_MAJORMINOR "'$GST_MAJORMINOR'"/' \
 984     -e "s,.* GST_PACKAGE_NAME$,#define GST_PACKAGE_NAME \"${GST_PACKAGE_NAME}\"," \
 985     -e 's/.* GST_PACKAGE_ORIGIN$/#define GST_PACKAGE_ORIGIN "Unknown package origin"/' \
 986     -e "s,.* GST_PACKAGE_RELEASE_DATETIME$,#define GST_PACKAGE_RELEASE_DATETIME \"${GST_PACKAGE_RELEASE_DATETIME}\"," \
 987     -e 's/.* HAVE_CPU_I386$/#define HAVE_CPU_I386 1/' \
 988     -e 's/.* HAVE_FGETPOS$/#define HAVE_FGETPOS 1/' \
 989     -e 's/.* HAVE_FSETPOS$/#define HAVE_FSETPOS 1/' \
 990     -e 's/.* HAVE_ISO_CODES$/#undef HAVE_ISO_CODES/' \
 991     -e 's/.* HAVE_LIBXML2$/#define HAVE_LIBXML2 1/' \
 992     -e 's/.* HAVE_PROCESS_H$/#define HAVE_PROCESS_H 1/' \
 993     -e 's/.* HAVE_STDLIB_H$/#define HAVE_STDLIB_H 1/' \
 994     -e 's/.* HAVE_STRING_H$/#define HAVE_STRING_H 1/' \
 995     -e 's/.* HAVE_SYS_STAT_H$/#define HAVE_SYS_STAT_H 1/' \
 996     -e 's/.* HAVE_SYS_TYPES_H$/#define HAVE_SYS_TYPES_H 1/' \
 997     -e 's/.* HAVE_WIN32$/#define HAVE_WIN32 1/' \
 998     -e 's/.* HAVE_WINSOCK2_H$/#define HAVE_WINSOCK2_H 1/' \
 999     -e 's/.* HOST_CPU$/#define HOST_CPU "i686"/' \
1000     -e 's/.* ISO_CODES_PREFIX$/#undef ISO_CODES_PREFIX/' \
1001     -e 's/.* ISO_CODES_VERSION$/#undef ISO_CODES_VERSION/' \
1002     -e 's/.* LIBDIR$/#ifdef _DEBUG\n#  define LIBDIR PREFIX "\\\\debug\\\\lib"\n#else\n#  define LIBDIR PREFIX "\\\\lib"\n#endif/' \
1003     -e 's/.* LOCALEDIR$/#define LOCALEDIR PREFIX "\\\\share\\\\locale"/' \
1004     -e "s/.* PACKAGE$/#define PACKAGE \"$PACKAGE\"/" \
1005     -e 's/.* PACKAGE_BUGREPORT$/#define PACKAGE_BUGREPORT "http:\/\/bugzilla.gnome.org\/enter_bug.cgi?product=GStreamer"/' \
1006     -e "s/.* PACKAGE_NAME$/#define PACKAGE_NAME \"$PACKAGE_NAME\"/" \
1007     -e "s/.* PACKAGE_STRING$/#define PACKAGE_STRING \"$PACKAGE_STRING\"/" \
1008     -e 's/.* PACKAGE_TARNAME$/#define PACKAGE_TARNAME "'$PACKAGE_TARNAME'"/' \
1009     -e 's/.* PACKAGE_VERSION$/#define PACKAGE_VERSION "'$PACKAGE_VERSION'"/' \
1010     -e 's/.* PLUGINDIR$/#ifdef _DEBUG\n#  define PLUGINDIR PREFIX "\\\\debug\\\\lib\\\\gstreamer-0.11"\n#else\n#  define PLUGINDIR PREFIX "\\\\lib\\\\gstreamer-0.11"\n#endif/' \
1011     -e 's/.* USE_BINARY_REGISTRY$/#define USE_BINARY_REGISTRY/' \
1012     -e 's/.* VERSION$/#define VERSION "'$VERSION'"/' \
1013     -e "s/.* DEFAULT_AUDIOSINK$/#define DEFAULT_AUDIOSINK \"directsoundsink\"/" \
1014     -e "s/.* DEFAULT_VIDEOSINK$/#define DEFAULT_VIDEOSINK \"directdrawsink\"/" \
1015     -e "s/.* DEFAULT_VISUALIZER$/#define DEFAULT_VISUALIZER \"goom\"/" \
1016     config.h.in >win32/common/config.h-new
1017
1018
1019
1020 AC_OUTPUT
1021
1022 AG_GST_OUTPUT_PLUGINS
1023 ORC_OUTPUT
1024