configure.ac

   1 AC_PREREQ(2.62)
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, git and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for git/prerelease
   8 AC_INIT(GStreamer Base Plug-ins, 0.11.93,
   9     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
  10     gst-plugins-base)
  11
  12 AG_GST_INIT
  13
  14 dnl initialize automake
  15 AM_INIT_AUTOMAKE([-Wno-portability 1.11 no-dist-gzip dist-xz tar-ustar])
  16
  17 dnl define PACKAGE_VERSION_* variables
  18 AS_VERSION
  19
  20 dnl check if this is a release version
  21 AS_NANO(GST_GIT="no", GST_GIT="yes")
  22
  23 dnl can autoconf find the source ?
  24 AC_CONFIG_SRCDIR([gst/audiotestsrc/gstaudiotestsrc.c])
  25
  26 dnl define the output header for config
  27 AM_CONFIG_HEADER([config.h])
  28
  29 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  30 AM_MAINTAINER_MODE([enable])
  31
  32 dnl sets host_* variables
  33 AC_CANONICAL_HOST
  34
  35 dnl use pretty build output with automake >= 1.11
  36 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],
  37   [AM_DEFAULT_VERBOSITY=1
  38    AC_SUBST(AM_DEFAULT_VERBOSITY)])
  39
  40 dnl our libraries and install dirs use GST_API_VERSION in the filename
  41 dnl to allow side-by-side installation of different API versions
  42 GST_API_VERSION=1.0
  43 AC_SUBST(GST_API_VERSION)
  44 AC_DEFINE_UNQUOTED(GST_API_VERSION, "$GST_API_VERSION",
  45   [GStreamer API Version])
  46
  47 dnl CURRENT, REVISION, AGE
  48 dnl - library source changed -> increment REVISION
  49 dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
  50 dnl - interfaces added -> increment AGE
  51 dnl - interfaces removed -> AGE = 0
  52 dnl sets GST_LT_LDFLAGS
  53 AS_LIBTOOL(GST, 0, 0, 0)
  54
  55 dnl *** required versions of GStreamer stuff ***
  56 GST_REQ=0.11.93
  57
  58 dnl *** autotools stuff ****
  59
  60 dnl allow for different autotools
  61 AS_AUTOTOOLS_ALTERNATE
  62
  63 dnl Add parameters for aclocal
  64 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  65
  66 dnl set up gettext
  67 dnl the version check needs to stay here because autopoint greps for it
  68 AM_GNU_GETTEXT_VERSION([0.17])
  69 AM_GNU_GETTEXT([external])
  70 AG_GST_GETTEXT([gst-plugins-base-$GST_API_VERSION])
  71
  72 dnl *** check for arguments to configure ***
  73
  74 AG_GST_ARG_DISABLE_FATAL_WARNINGS
  75
  76 AG_GST_ARG_DEBUG
  77 AG_GST_ARG_PROFILING
  78 AG_GST_ARG_VALGRIND
  79 AG_GST_ARG_GCOV
  80
  81 AG_GST_ARG_EXAMPLES
  82
  83 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  84 AG_GST_ARG_WITH_PACKAGE_NAME
  85 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  86
  87 AG_GST_PKG_CONFIG_PATH
  88
  89 dnl let distro override plugin install helper path
  90 AC_ARG_WITH(install-plugins-helper,
  91   AC_HELP_STRING([--with-install-plugins-helper],
  92     [specify path of helper script to call to install plugins]),
  93   [
  94     case "${withval}" in
  95       yes) AC_MSG_ERROR(bad value ${withval} for --with-install-plugins-helper) ;;
  96       no)  AC_MSG_ERROR(bad value ${withval} for --with-install-plugins-helper) ;;
  97       *)   GST_INSTALL_PLUGINS_HELPER="${withval}" ;;
  98     esac
  99   ],
 100   [
 101     dnl Default value
 102     AS_AC_EXPAND(GST_INSTALL_PLUGINS_HELPER,${libexecdir}/gst-install-plugins-helper)
 103   ]
 104 )
 105 AC_MSG_NOTICE(Using $GST_INSTALL_PLUGINS_HELPER as plugin install helper)
 106 AC_DEFINE_UNQUOTED(GST_INSTALL_PLUGINS_HELPER, "$GST_INSTALL_PLUGINS_HELPER",
 107     [plugin install helper script])
 108 AC_SUBST(GST_INSTALL_PLUGINS_HELPER)
 109
 110 AG_GST_ARG_WITH_PLUGINS
 111
 112 AG_GST_ARG_ENABLE_EXTERNAL
 113
 114 AG_GST_ARG_ENABLE_EXPERIMENTAL
 115
 116 dnl *** checks for platform ***
 117 AG_GST_PLATFORM
 118
 119 dnl * hardware/architecture *
 120
 121 dnl common/m4/gst-arch.m4
 122 dnl check CPU type
 123 AG_GST_ARCH
 124
 125 dnl check for large file support
 126 dnl affected plugins must include config.h
 127 AC_SYS_LARGEFILE
 128
 129 dnl *** checks for programs ***
 130
 131 dnl find a compiler
 132 AC_PROG_CC
 133 AC_PROG_CC_STDC
 134
 135 dnl check if the compiler supports '-c' and '-o' options
 136 AM_PROG_CC_C_O
 137
 138 dnl determine if c++ is available on this system
 139 AC_PROG_CXX
 140 dnl CXX may be set to some default even if no c++ compiler is available
 141 dnl (thanks autotools!), so just try to compile some c++ code to make sure
 142 AC_LANG_PUSH([C++])
 143 AC_TRY_COMPILE([ class Foo { int bar; };], , working_cxx=yes, working_cxx=no)
 144 AC_LANG_POP([C++])
 145 AC_MSG_NOTICE([working c++ compiler found: $working_cxx])
 146 AM_CONDITIONAL(HAVE_CXX, test "x$working_cxx" = "xyes")
 147
 148 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 149 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 150
 151 dnl check for gobject-introspection
 152 GOBJECT_INTROSPECTION_CHECK([1.31.1])
 153
 154 dnl check for documentation tools
 155 GTK_DOC_CHECK([1.3])
 156 AS_PATH_PYTHON([2.1])
 157 AG_GST_PLUGIN_DOCS([1.3],[2.1])
 158
 159 dnl *** checks for libraries ***
 160
 161 dnl libm, for sin() etc.
 162 LT_LIB_M
 163 AC_SUBST(LIBM)
 164
 165 dnl *** checks for header files ***
 166
 167 dnl check if we have ANSI C header files
 168 AC_HEADER_STDC
 169
 170 ac_cppflags_save="$CPPFLAGS"
 171 CPPFLAGS="`$PKG_CONFIG --cflags libxml-2.0`"
 172 AC_COMPILE_IFELSE([
 173   AC_LANG_PROGRAM([[
 174 #include <libxml/HTMLparser.h>
 175 ]],[[
 176 #ifndef LIBXML_HTML_ENABLED
 177 #error libxml2 has no HTML support
 178 #endif /* LIBXML_HTML_ENABLED */
 179 ]])], [
 180   HAVE_LIBXML_HTML="yes"
 181 ], [
 182   HAVE_LIBXML_HTML="no"
 183 ])
 184 CPPFLAGS="$ac_cppflags_save"
 185 AM_CONDITIONAL(HAVE_LIBXML_HTML, test "x$HAVE_LIBXML_HTML" = "xyes")
 186
 187 dnl used in gst/tcp
 188 AC_CHECK_HEADERS([sys/socket.h],
 189   [HAVE_SYS_SOCKET_H="yes"], [HAVE_SYS_SOCKET_H="no"], [AC_INCLUDES_DEFAULT])
 190 AM_CONDITIONAL(HAVE_SYS_SOCKET_H, test "x$HAVE_SYS_SOCKET_H" = "xyes")
 191
 192 dnl used in gst-libs/gst/pbutils and associated unit test
 193 AC_CHECK_HEADERS([process.h sys/types.h sys/wait.h sys/stat.h], [], [], [AC_INCLUDES_DEFAULT])
 194
 195 dnl also, Windows does not have long long
 196 AX_CREATE_STDINT_H
 197
 198 dnl *** checks for functions ***
 199 AC_CHECK_FUNCS([localtime_r gmtime_r])
 200
 201 dnl *** checks for math functions ***
 202 LIBS_SAVE=$LIBS
 203 LIBS="$LIBS $LIBM"
 204 AC_CHECK_FUNCS(log2)
 205 LIBS=$LIBS_SAVE
 206
 207 dnl *** checks for types/defines ***
 208
 209 dnl *** checks for structures ***
 210
 211 dnl *** checks for compiler characteristics ***
 212
 213 dnl *** checks for library functions ***
 214
 215 dnl check for fseeko()
 216 AC_FUNC_FSEEKO
 217
 218 dnl Check for fast float to int casting as defined in C99
 219 dnl used to be used in gst-libs/gst/floatcast/floatcast.h (FIXME: still needed?)
 220 save_libs=$LIBS
 221 LIBS="$LIBS $LIBM"
 222 AC_C99_FUNC_LRINT
 223 AC_C99_FUNC_LRINTF
 224 LIBS=$save_libs
 225
 226 dnl Check for a way to display the function name in debug output
 227 AG_GST_CHECK_FUNCTION
 228
 229 dnl *** checks for dependency libraries ***
 230
 231 dnl GLib
 232 GLIB_REQ=2.32
 233 AG_GST_GLIB_CHECK([$GLIB_REQ])
 234
 235 ORC_CHECK([0.4.16])
 236
 237 dnl checks for gstreamer
 238 dnl uninstalled is selected preferentially -- see pkg-config(1)
 239 AG_GST_CHECK_GST($GST_API_VERSION, [$GST_REQ], yes)
 240 AG_GST_CHECK_GST_BASE($GST_API_VERSION, [$GST_REQ], yes)
 241 AG_GST_CHECK_GST_CONTROLLER($GST_API_VERSION, [$GST_REQ], yes)
 242 AG_GST_CHECK_GST_CHECK($GST_API_VERSION, [$GST_REQ], no)
 243 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 244
 245 dnl Check for documentation xrefs
 246 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 247 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_API_VERSION`"
 248 AC_SUBST(GLIB_PREFIX)
 249 AC_SUBST(GST_PREFIX)
 250
 251 dnl GTK is optional and only used in examples
 252 HAVE_GTK=no
 253 HAVE_GTK_X11=no
 254 GTK_REQ=3.0.0
 255 if test "x$BUILD_EXAMPLES" = "xyes"; then
 256   PKG_CHECK_MODULES(GTK, gtk+-3.0 >= $GTK_REQ, HAVE_GTK=yes, HAVE_GTK=no)
 257   dnl some examples need gtk+-x11
 258   PKG_CHECK_MODULES(GTK_X11, gtk+-x11-3.0 >= $GTK_REQ, HAVE_GTK_X11=yes, HAVE_GTK_X11=no)
 259   PKG_CHECK_MODULES(GTK_QUARTZ, gtk+-quartz-3.0 >= $GTK_REQ, HAVE_GTK_QUARTZ=yes, HAVE_GTK_QUARTZ=no)
 260   AC_SUBST(GTK_LIBS)
 261   AC_SUBST(GTK_CFLAGS)
 262 fi
 263 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 264 AM_CONDITIONAL(HAVE_GTK_X11, test "x$HAVE_GTK_X11" = "xyes")
 265 AM_CONDITIONAL(HAVE_GTK_QUARTZ, test "x$HAVE_GTK_QUARTZ" = "xyes")
 266
 267 dnl QT is optional and only used in examples
 268 PKG_CHECK_MODULES(QT, QtGui >= 4.6, [
 269   HAVE_QT_GV=yes
 270   HAVE_QT=yes
 271 ], [
 272   HAVE_QT_GV=no
 273   PKG_CHECK_MODULES(QT, QtGui >= 4.0, HAVE_QT=yes, HAVE_QT=no)
 274 ])
 275 if test "x$HAVE_QT" = "xyes"; then
 276   AC_MSG_CHECKING([Qt moc])
 277   QT4_MOC=`$PKG_CONFIG --variable=moc_location QtGui`
 278   AC_MSG_RESULT($QT4_MOC)
 279   AC_SUBST(QT4_MOC)
 280 fi
 281 AM_CONDITIONAL(HAVE_QT, test "x$HAVE_QT" = "xyes")
 282 AM_CONDITIONAL(HAVE_QT_GV, test "x$HAVE_QT_GV" = "xyes")
 283
 284 dnl chck for linux headers needed by the joystick seek example
 285 AC_COMPILE_IFELSE(
 286 [
 287   AC_LANG_PROGRAM([
 288     #include <linux/input.h>
 289     #include <linux/joystick.h>
 290   ],[
 291     struct js_event js;
 292     js.type = JS_EVENT_AXIS;
 293   ])
 294 ], [
 295   HAVE_LINUX_JOYSTICK_HEADERS="yes"
 296 ], [
 297   HAVE_LINUX_JOYSTICK_HEADERS="no"
 298 ])
 299 AM_CONDITIONAL(HAVE_LINUX_JOYSTICK_HEADERS, test "x$HAVE_LINUX_JOYSTICK_HEADERS" = "xyes")
 300
 301 dnl Check for -Bsymbolic-functions linker flag used to avoid
 302 dnl intra-library PLT jumps, if available.
 303 AC_ARG_ENABLE(Bsymbolic,
 304               [AC_HELP_STRING([--disable-Bsymbolic],
 305                               [avoid linking with -Bsymbolic])],,
 306               [SAVED_LDFLAGS="${LDFLAGS}"
 307                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
 308                LDFLAGS=-Wl,-Bsymbolic-functions
 309                AC_TRY_LINK([], [int main (void) { return 0; }],
 310                            AC_MSG_RESULT(yes)
 311                            enable_Bsymbolic=yes,
 312                            AC_MSG_RESULT(no)
 313                            enable_Bsymbolic=no)
 314                LDFLAGS="${SAVED_LDFLAGS}"])
 315
 316
 317 dnl *** set variables based on configure arguments ***
 318
 319 dnl set license and copyright notice
 320 GST_LICENSE="LGPL"
 321 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 322 AC_SUBST(GST_LICENSE)
 323
 324 dnl set location of plugin directory
 325 AG_GST_SET_PLUGINDIR
 326
 327 dnl set release date/time
 328 AG_GST_SET_PACKAGE_RELEASE_DATETIME_WITH_NANO([$PACKAGE_VERSION_NANO],
 329   ["${srcdir}/gst-plugins-base.doap"],
 330   [$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_MICRO])
 331
 332 # set by AG_GST_PARSE_SUBSYSTEM_DISABLES above
 333 dnl make sure it doesn't complain about unused variables if debugging is disabled
 334 NO_WARNINGS=""
 335 AG_GST_CHECK_GST_DEBUG_DISABLED([NO_WARNINGS="-Wno-unused"], [NO_WARNINGS=""])
 336
 337 dnl define an ERROR_CFLAGS Makefile variable
 338 dnl -Wformat-nonliteral - see ext/pango/gstclockoverlay.c and http://gcc.gnu.org/bugzilla/show_bug.cgi?id=39438
 339 AG_GST_SET_ERROR_CFLAGS($FATAL_WARNINGS, [
 340     -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls -Wundef
 341     -Wwrite-strings -Wformat-nonliteral -Wformat-security
 342     -Winit-self -Wmissing-include-dirs -Waddress -Waggregate-return
 343     -Wno-multichar -Wnested-externs $NO_WARNINGS])
 344
 345 dnl define an ERROR_CXXFLAGS Makefile variable
 346 AG_GST_SET_ERROR_CXXFLAGS($FATAL_WARNINGS, [
 347     -Wmissing-declarations -Wredundant-decls -Wundef
 348     -Wwrite-strings -Wformat-nonliteral -Wformat-security
 349     -Winit-self -Wmissing-include-dirs -Waddress -Waggregate-return
 350     -Wno-multichar $NO_WARNINGS])
 351
 352 dnl define correct level for debugging messages
 353 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 354
 355 dnl used in examples
 356 AG_GST_DEFAULT_ELEMENTS
 357
 358 dnl needed for encoding-target
 359 GST_DATADIR="$GST_PREFIX/share"
 360 AC_DEFINE_UNQUOTED(GST_DATADIR, "$GST_DATADIR", [system wide data directory])
 361 AC_DEFINE_UNQUOTED(GST_API_VERSION, "$GST_API_VERSION", [major/minor version])
 362
 363 dnl behaviour of speex based audio resampler
 364 AC_MSG_CHECKING(which audio resample format to use for integer)
 365 AC_ARG_WITH([audioresample_format],
 366         AS_HELP_STRING([--with-audioresample-format],[Which implementation should be used for integer audio resampling, int/float/auto, (default is auto)]),
 367         [ac_cv_audioresample_format=$withval], [ac_cv_audioresample_format=auto])dnl
 368 AC_MSG_RESULT($ac_cv_audioresample_format)
 369 case $ac_cv_audioresample_format in
 370   int)
 371     AC_DEFINE(AUDIORESAMPLE_FORMAT_INT,1,[The int implementation should be used for integer audio resampling])
 372     AC_SUBST(AUDIORESAMPLE_FORMAT_INT)
 373   ;;
 374   float)
 375     AC_DEFINE(AUDIORESAMPLE_FORMAT_FLOAT,1,[The float implementation should be used for integer audio resampling])
 376     AC_SUBST(AUDIORESAMPLE_FORMAT_FLOAT)
 377   ;;
 378   auto)
 379     AC_DEFINE(AUDIORESAMPLE_FORMAT_AUTO,1,[The implementation that should be used for integer audio resampling witll be benchmarked at runtime])
 380     AC_SUBST(AUDIORESAMPLE_FORMAT_AUTO)
 381 esac
 382
 383 dnl *** plug-ins to include ***
 384
 385 dnl these are all the gst plug-ins, compilable without additional libs
 386 AG_GST_CHECK_PLUGIN(adder)
 387 AG_GST_CHECK_PLUGIN(app)
 388 AG_GST_CHECK_PLUGIN(audioconvert)
 389 AG_GST_CHECK_PLUGIN(audiorate)
 390 AG_GST_CHECK_PLUGIN(audiotestsrc)
 391 AG_GST_CHECK_PLUGIN(encoding)
 392 AG_GST_CHECK_PLUGIN(videoconvert)
 393 AG_GST_CHECK_PLUGIN(gdp)
 394 AG_GST_CHECK_PLUGIN(gio)
 395 AG_GST_CHECK_PLUGIN(playback)
 396 AG_GST_CHECK_PLUGIN(audioresample)
 397 AG_GST_CHECK_PLUGIN(subparse)
 398 AG_GST_CHECK_PLUGIN(tcp)
 399 AG_GST_CHECK_PLUGIN(typefind)
 400 AG_GST_CHECK_PLUGIN(videotestsrc)
 401 AG_GST_CHECK_PLUGIN(videorate)
 402 AG_GST_CHECK_PLUGIN(videoscale)
 403 AG_GST_CHECK_PLUGIN(volume)
 404
 405 dnl FIXME 0.11: check for libxml, split subparse and move libxml parts to ext/
 406 AM_CONDITIONAL(USE_XML, false)
 407 AC_DEFINE([GST_DISABLE_XML], [1], [set to disable libxml2-dependent code in subparse])
 408
 409 dnl disable plug-ins that require libxml2's HTML support if it is not available
 410 if test "x$HAVE_LIBXML_HTML" != "xyes"; then
 411   AG_GST_DISABLE_PLUGIN(subparse)
 412 fi
 413
 414 dnl iso-codes is optional, used by libgsttag
 415 AC_ARG_ENABLE(iso-codes,
 416 AC_HELP_STRING([--enable-iso-codes],[use iso-codes if installed]),
 417 [case "${enableval}" in
 418   yes) enable_iso_codes=yes ;;
 419   no)  enable_iso_codes=no ;;
 420   *) AC_MSG_ERROR(bad value ${enableval} for --enable-iso-codes) ;;
 421 esac
 422 ],
 423 [enable_iso_codes=yes]) dnl Default value
 424
 425 AC_MSG_CHECKING([whether to use iso-codes if they are available])
 426 if test "x$enable_iso_codes" = "xyes"; then
 427   AC_MSG_RESULT([yes])
 428   have_iso_codes=no
 429   AC_MSG_CHECKING([whether iso-codes are available on this system])
 430   if $PKG_CONFIG iso-codes; then
 431     AC_MSG_RESULT([yes])
 432     AC_MSG_CHECKING([whether iso-codes has iso-639 domain])
 433     if $PKG_CONFIG --variable=domains iso-codes | $GREP -q 639 ; then
 434       AC_MSG_RESULT([yes])
 435       AC_MSG_CHECKING([for iso-codes prefix])
 436       ISO_CODES_PREFIX=`$PKG_CONFIG --variable=prefix iso-codes`
 437       if test -d "$ISO_CODES_PREFIX"; then
 438         AC_MSG_RESULT([yes])
 439         AC_MSG_CHECKING([ISO_CODES_PREFIX])
 440         AC_MSG_RESULT([$ISO_CODES_PREFIX])
 441         ISO_639_DOMAIN="iso_639"
 442         AC_MSG_CHECKING([ISO_639_DOMAIN])
 443         AC_MSG_RESULT([$ISO_639_DOMAIN])
 444         have_iso_codes=yes
 445         AC_DEFINE([HAVE_ISO_CODES], [1], [make use of iso-codes for ISO-639])
 446         AC_DEFINE_UNQUOTED([ISO_CODES_PREFIX], ["$ISO_CODES_PREFIX"], [prefix])
 447         ISO_CODES_VERSION=`$PKG_CONFIG --modversion iso-codes`
 448         AC_DEFINE_UNQUOTED([ISO_CODES_VERSION], ["$ISO_CODES_VERSION"], [ ])
 449       else
 450         AC_MSG_RESULT([no])
 451       fi
 452     else
 453       AC_MSG_RESULT([no])
 454     fi
 455   else
 456     AC_MSG_RESULT([no])
 457   fi
 458   AM_CONDITIONAL(USE_ISO_CODES, test "x$have_iso_codes" = "xyes")
 459 else
 460   AC_MSG_RESULT([no (disabled via --disable-iso-codes)])
 461   AM_CONDITIONAL(USE_ISO_CODES, false)
 462 fi
 463
 464 dnl *** zlib is optionally used by id3 tag parsing in libgsttag ***
 465 translit(dnm, m, l) AM_CONDITIONAL(USE_ZLIB, true)
 466 AG_GST_CHECK_FEATURE(ZLIB, [zlib support for ID3 parsing in libgsttag],, [
 467   PKG_CHECK_MODULES(ZLIB, [ zlib ], [
 468       HAVE_ZLIB="yes"
 469     ], [
 470       AG_GST_CHECK_LIBHEADER(ZLIB, z, uncompress,, zlib.h, [
 471         HAVE_ZLIB="yes"
 472         ZLIB_LIBS="-lz"
 473         AC_SUBST(ZLIB_LIBS)
 474       ])
 475     ])
 476 ])
 477
 478 dnl *** sys plug-ins ***
 479
 480 echo
 481 AC_MSG_NOTICE([Checking libraries for plugins in sys/])
 482 echo
 483
 484 dnl *** X11 ***
 485 translit(dnm, m, l) AM_CONDITIONAL(USE_X, true)
 486 AG_GST_CHECK_FEATURE(X, [X libraries and plugins],
 487                   [ximagesink], [
 488   AC_PATH_XTRA
 489   ac_cflags_save="$CFLAGS"
 490   ac_cppflags_save="$CPPFLAGS"
 491   CFLAGS="$CFLAGS $X_CFLAGS"
 492   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 493
 494   dnl now try to find the HEADER
 495   AC_CHECK_HEADER([X11/Xlib.h], [HAVE_X="yes"], [HAVE_X="no"], [AC_INCLUDES_DEFAULT])
 496
 497   if test "x$HAVE_X" = "xno"
 498   then
 499     AC_MSG_NOTICE([cannot find X11 development files])
 500   else
 501     dnl this is much more than we want
 502     X_LIBS="$X_LIBS $X_PRE_LIBS $X_EXTRA_LIBS"
 503     dnl AC_PATH_XTRA only defines the path needed to find the X libs,
 504     dnl it does not add the libs; therefore we add them here
 505     X_LIBS="$X_LIBS -lX11"
 506     AC_SUBST(X_CFLAGS)
 507     AC_SUBST(X_LIBS)
 508   fi
 509   AC_SUBST(HAVE_X)
 510   CFLAGS="$ac_cflags_save"
 511   CPPFLAGS="$ac_cppflags_save"
 512 ])
 513
 514 dnl Check for Xv extension
 515 translit(dnm, m, l) AM_CONDITIONAL(USE_XVIDEO, true)
 516 AG_GST_CHECK_FEATURE(XVIDEO, [X11 XVideo extensions],
 517                   [xvimagesink], [
 518   AG_GST_CHECK_XV
 519 ])
 520
 521 dnl check for X Shm
 522 translit(dnm, m, l) AM_CONDITIONAL(USE_XSHM, true)
 523 AG_GST_CHECK_FEATURE(XSHM, [X Shared Memory extension], , [
 524   if test x$HAVE_X = xyes; then
 525     AC_CHECK_LIB(Xext, XShmAttach,
 526                  HAVE_XSHM="yes", HAVE_XSHM="no",
 527                  $X_LIBS)
 528     if test "x$HAVE_XSHM" = "xyes"; then
 529       XSHM_LIBS="-lXext"
 530     else
 531       dnl On AIX, it is in XextSam instead, but we still need -lXext
 532       AC_CHECK_LIB(XextSam, XShmAttach,
 533                    HAVE_XSHM="yes", HAVE_XSHM="no",
 534                    $X_LIBS)
 535       if test "x$HAVE_XSHM" = "xyes"; then
 536         XSHM_LIBS="-lXext -lXextSam"
 537       fi
 538     fi
 539   fi
 540 ], , [
 541   AC_SUBST(HAVE_XSHM)
 542   AC_SUBST(XSHM_LIBS)
 543 ])
 544
 545 dnl *** ext plug-ins ***
 546 dnl keep this list sorted alphabetically !
 547
 548 if test "x$BUILD_EXTERNAL" = "xyes"; then
 549
 550 echo
 551 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 552 echo
 553
 554 dnl *** alsa ***
 555 translit(dnm, m, l) AM_CONDITIONAL(USE_ALSA, true)
 556 AG_GST_CHECK_FEATURE(ALSA, [ALSA], alsa, [
 557   PKG_CHECK_MODULES(ALSA, alsa >= 0.9.1, [
 558     HAVE_ALSA="yes"
 559     AC_SUBST(ALSA_CFLAGS)
 560     AC_SUBST(ALSA_LIBS)
 561   ], [
 562     AM_PATH_ALSA(0.9.1, HAVE_ALSA="yes", HAVE_ALSA="no")
 563   ])
 564 ])
 565
 566 dnl *** CDParanoia ***
 567 dnl Note: upstream has a pkg-config file only in post-10.2 SVN so far
 568 translit(dnm, m, l) AM_CONDITIONAL(USE_CDPARANOIA, true)
 569 AG_GST_CHECK_FEATURE(CDPARANOIA, [CDParanoia], cdparanoia, [
 570   PKG_CHECK_MODULES(CDPARANOIA, cdparanoia-3 >= 10.2, [
 571     HAVE_CDPARANOIA="yes"
 572   ], [
 573     AG_GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 574                         cdda_open, -lm,
 575                         cdda_interface.h,
 576                         CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 577                         HEADER_DIR="no"
 578                         FOUND_CDPARANOIA="yes")
 579     if test "x$FOUND_CDPARANOIA" != "xyes";
 580     then
 581       AG_GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 582                           cdda_open, -lm,
 583                           cdda/cdda_interface.h,
 584                           CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 585                           HEADER_DIR="yes"
 586                           FOUND_CDPARANOIA="yes")
 587     fi
 588     if test "x$HEADER_DIR" = "xyes";
 589     then
 590       AC_DEFINE_UNQUOTED(CDPARANOIA_HEADERS_IN_DIR, ,
 591                          defined if cdda headers are in a cdda/ directory)
 592     fi
 593     if test "x$FOUND_CDPARANOIA" = "xyes";
 594     then
 595       AC_CHECK_LIB(cdda_paranoia,
 596                    paranoia_cachemodel_size,
 597                    : ,
 598                    HAVE_CDPARANOIA=no,
 599                  [-lcdda_interface])
 600     fi
 601
 602     AC_SUBST(CDPARANOIA_LIBS)
 603   ])
 604 ])
 605 dnl FIXME : add second check somehow if that is necessary
 606 dnl AC_CHECK_LIB(cdda_paranoia, paranoia_init, : , HAVE_CDPARANOIA=no, -lcdda_interface )
 607 dnl AC_CHECK_HEADER(cdda_paranoia.h, :, HAVE_CDPARANOIA=no)
 608
 609 dnl *** ivorbis ***
 610 dnl AM_PATH_IVORBIS only takes two options
 611 translit(dnm, m, l) AM_CONDITIONAL(USE_IVORBIS, true)
 612 AG_GST_CHECK_FEATURE(IVORBIS, [integer vorbis plug-in], ivorbisdec, [
 613   AG_GST_PKG_CHECK_MODULES(IVORBIS, vorbisidec)
 614   if test $HAVE_IVORBIS = no
 615   then
 616     IVORBIS_LIBS=
 617     IVORBIS_CFLAGS=
 618     AC_CHECK_LIB(vorbisidec, vorbis_block_init,
 619       [IVORBIS_LIBS=-lvorbisidec
 620       HAVE_IVORBIS=yes
 621       case $host in
 622       arm-*-*)
 623         IVORBIS_CFLAGS="-D_ARM_ASSEM_ $IVORBIS_CFLAGS"
 624       esac
 625       ],
 626       HAVE_IVORBIS=no)
 627     AC_SUBST(IVORBIS_LIBS)
 628     AC_SUBST(IVORBIS_CFLAGS)
 629   else
 630     AC_CHECK_LIB(vorbisidec, vorbis_dsp_pcmout,
 631       AC_DEFINE([USE_TREMOLO],1, "Define if building for android"),
 632       USE_TREMOLO=no)
 633   fi
 634 ])
 635
 636 dnl *** libvisual ***
 637 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBVISUAL, true)
 638 AG_GST_CHECK_FEATURE(LIBVISUAL, [libvisual visualization library], libvisual, [
 639   AG_GST_PKG_CHECK_MODULES(LIBVISUAL, libvisual-0.4 >= 0.4.0)
 640   if test $HAVE_LIBVISUAL = no
 641   then
 642     AG_GST_PKG_CHECK_MODULES(LIBVISUAL, libvisual = 0.2.0)
 643     if test x$HAVE_LIBVISUAL = xyes; then
 644       LIBVIS_PLUGINSDIR="`$PKG_CONFIG --variable=pluginsbasedir libvisual-0.2`"
 645     fi
 646   else
 647     if test x$HAVE_LIBVISUAL = xyes; then
 648       LIBVIS_PLUGINSDIR="`$PKG_CONFIG --variable=pluginsbasedir libvisual-0.4`"
 649     fi
 650   fi
 651   AC_MSG_NOTICE([libvisual pluginsdir: $LIBVIS_PLUGINSDIR])
 652   if test x$LIBVIS_PLUGINSDIR != x; then
 653     AC_DEFINE_UNQUOTED(LIBVISUAL_PLUGINSBASEDIR,
 654         "$LIBVIS_PLUGINSDIR",
 655         [directory in which the detected libvisual's plugins are located])
 656   fi
 657 ])
 658
 659 dnl *** ogg ***
 660 translit(dnm, m, l) AM_CONDITIONAL(USE_OGG, true)
 661 AG_GST_CHECK_FEATURE(OGG, [Xiph Ogg library], ogg, [
 662   AG_GST_PKG_CHECK_MODULES(OGG, ogg >= 1.0)
 663   if test $HAVE_OGG = no
 664   then
 665     XIPH_PATH_OGG(HAVE_OGG="yes", HAVE_OGG="no")
 666     AS_SCRUB_INCLUDE(OGG_CFLAGS)
 667   fi
 668 ])
 669
 670 dnl *** pango ***
 671 translit(dnm, m, l) AM_CONDITIONAL(USE_PANGO, true)
 672 AG_GST_CHECK_FEATURE(PANGO, [Pango font rendering], pango, [
 673   AG_GST_PKG_CHECK_MODULES(PANGO, pango >= 1.22.0  pangocairo >= 1.22.0)
 674 ])
 675
 676 dnl *** theora ***
 677 translit(dnm, m, l) AM_CONDITIONAL(USE_THEORA, true)
 678 AG_GST_CHECK_FEATURE(THEORA, [Xiph Theora video codec], theora, [
 679   AG_GST_PKG_CHECK_MODULES(THEORA, theoradec >= 1.1 theoraenc >= 1.1)
 680 ])
 681
 682 dnl *** vorbis ***
 683 dnl AM_PATH_VORBIS only takes two options
 684 translit(dnm, m, l) AM_CONDITIONAL(USE_VORBIS, true)
 685 AG_GST_CHECK_FEATURE(VORBIS, [Xiph Vorbis audio codec], vorbis, [
 686   AG_GST_PKG_CHECK_MODULES(VORBIS, vorbis >= 1.0 vorbisenc >= 1.0)
 687   if test $HAVE_VORBIS = no
 688   then
 689     XIPH_PATH_VORBIS(HAVE_VORBIS="yes", HAVE_VORBIS="no")
 690     AS_SCRUB_INCLUDE(VORBIS_CFLAGS)
 691   fi
 692 ])
 693
 694 if test "x$HAVE_VORBIS" = "xyes"; then
 695   ac_cflags_save="$CFLAGS"
 696   AC_COMPILE_IFELSE([
 697     AC_LANG_PROGRAM([[
 698 #include <vorbis/codec.h>
 699                      ]],[[
 700 vorbis_dsp_state *v;
 701
 702 vorbis_synthesis_restart (v);
 703                      ]])], HAVE_VSR=yes, HAVE_VSR=no)
 704   if test "x$HAVE_VSR" = "xyes"; then
 705     AC_DEFINE_UNQUOTED(HAVE_VORBIS_SYNTHESIS_RESTART, 1,
 706                        [defined if vorbis_synthesis_restart is present])
 707   fi
 708   CFLAGS="$ac_cflags_save"
 709 fi
 710
 711 else
 712
 713 dnl not building plugins with external dependencies,
 714 dnl but we still need to set the conditionals
 715 AM_CONDITIONAL(USE_ALSA, false)
 716 AM_CONDITIONAL(USE_CDPARANOIA, false)
 717 AM_CONDITIONAL(USE_IVORBIS, false)
 718 AM_CONDITIONAL(USE_LIBVISUAL, false)
 719 AM_CONDITIONAL(USE_OGG, false)
 720 AM_CONDITIONAL(USE_PANGO, false)
 721 AM_CONDITIONAL(USE_THEORA, false)
 722 AM_CONDITIONAL(USE_VORBIS, false)
 723
 724 fi dnl of EXT plugins
 725
 726 dnl seeking needs freetype, so check for it here
 727 PKG_CHECK_MODULES(FT2, freetype2 >= 2.0.9, HAVE_FT2="yes", [
 728   AC_CHECK_FT2(2.0.9, HAVE_FT2="yes", HAVE_FT2="no")
 729 ])
 730 dnl make the HAVE_FT2 variable available to automake and Makefile.am
 731 AM_CONDITIONAL(HAVE_FT2, test "x$HAVE_FT2" = "xyes")
 732 AC_SUBST(FT2_CFLAGS)
 733 AC_SUBST(FT2_LIBS)
 734
 735 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 736
 737 dnl Overview:
 738 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
 739 dnl GST_*:              flags shared by built objects to link against GStreamer
 740 dnl GST_PLUGINS_BASE_CFLAGS: to link internally against the plugins base libs
 741 dnl                          (compare to other modules) or for i18n
 742 dnl GST_ALL_LDFLAGS:    linker flags shared by all
 743 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 744 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 745 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 746
 747 dnl GST_OPTION_CFLAGS
 748 if test "x$USE_DEBUG" = xyes; then
 749    PROFILE_CFLAGS="-g"
 750 fi
 751 AC_SUBST(PROFILE_CFLAGS)
 752
 753 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
 754   dnl Define _only_ when compiling a git version (not pre-releases or releases)
 755   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 756 else
 757   DEPRECATED_CFLAGS=""
 758 fi
 759 AC_SUBST(DEPRECATED_CFLAGS)
 760
 761 dnl every flag in GST_OPTION_CFLAGS and GST_OPTION_CXXFLAGS can be overridden
 762 dnl at make time with e.g. make ERROR_CFLAGS=""
 763 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 764 GST_OPTION_CXXFLAGS="\$(WARNING_CXXFLAGS) \$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 765 AC_SUBST(GST_OPTION_CFLAGS)
 766 AC_SUBST(GST_OPTION_CXXFLAGS)
 767
 768 dnl our libraries need to be versioned correctly
 769 AC_SUBST(GST_LT_LDFLAGS)
 770
 771 dnl GST_PLUGINS_BASE_CFLAGS
 772 dnl prefer internal headers to already installed ones
 773 dnl also add builddir include for enumtypes and marshal
 774 GST_PLUGINS_BASE_CFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs"
 775 AC_SUBST(GST_PLUGINS_BASE_CFLAGS)
 776
 777 dnl FIXME: do we want to rename to GST_ALL_* ?
 778 dnl add GST_OPTION_CFLAGS, but overridable
 779 GST_CFLAGS="$GST_CFLAGS -DGST_USE_UNSTABLE_API"
 780 GST_CXXFLAGS="$GLIB_CFLAGS $GST_CFLAGS \$(GLIB_EXTRA_CFLAGS) \$(GST_OPTION_CXXFLAGS)"
 781 GST_CFLAGS="$GLIB_CFLAGS $GST_CFLAGS \$(GLIB_EXTRA_CFLAGS) \$(GST_OPTION_CFLAGS)"
 782 AC_SUBST(GST_CFLAGS)
 783 AC_SUBST(GST_CXXFLAGS)
 784 dnl add GCOV libs because libtool strips -fprofile-arcs -ftest-coverage
 785 GST_LIBS="$GST_LIBS \$(GCOV_LIBS)"
 786 AC_SUBST(GST_LIBS)
 787
 788 dnl LDFLAGS really should only contain flags, not libs - they get added before
 789 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 790 GST_ALL_LDFLAGS="-no-undefined"
 791 if test "x${enable_Bsymbolic}" = "xyes"; then
 792   GST_ALL_LDFLAGS="$GST_ALL_LDFLAGS -Wl,-Bsymbolic-functions"
 793 fi
 794 AC_SUBST(GST_ALL_LDFLAGS)
 795
 796 dnl GST_LIB_LDFLAGS
 797 dnl linker flags shared by all libraries
 798 dnl LDFLAGS modifier defining exported symbols from built libraries
 799 dnl (export _gst_foo but not __gst_foo)
 800 GST_LIB_LDFLAGS="-export-symbols-regex ^_?\(gst_\|Gst\|GST_\).*"
 801 AC_SUBST(GST_LIB_LDFLAGS)
 802
 803 dnl this really should only contain flags, not libs - they get added before
 804 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 805 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc.*' $GST_ALL_LDFLAGS"
 806 AC_SUBST(GST_PLUGIN_LDFLAGS)
 807
 808 dnl *** output files ***
 809
 810 AC_CONFIG_FILES(
 811 Makefile
 812 gst-plugins-base.spec
 813 gst/Makefile
 814 gst/adder/Makefile
 815 gst/app/Makefile
 816 gst/audioconvert/Makefile
 817 gst/audiorate/Makefile
 818 gst/audiotestsrc/Makefile
 819 gst/encoding/Makefile
 820 gst/videoconvert/Makefile
 821 gst/gdp/Makefile
 822 gst/gio/Makefile
 823 gst/playback/Makefile
 824 gst/audioresample/Makefile
 825 gst/subparse/Makefile
 826 gst/tcp/Makefile
 827 gst/typefind/Makefile
 828 gst/videotestsrc/Makefile
 829 gst/videorate/Makefile
 830 gst/videoscale/Makefile
 831 gst/volume/Makefile
 832 sys/Makefile
 833 sys/ximage/Makefile
 834 sys/xvimage/Makefile
 835 ext/Makefile
 836 ext/alsa/Makefile
 837 ext/cdparanoia/Makefile
 838 ext/libvisual/Makefile
 839 ext/ogg/Makefile
 840 ext/pango/Makefile
 841 ext/theora/Makefile
 842 ext/vorbis/Makefile
 843 gst-libs/Makefile
 844 gst-libs/gst/Makefile
 845 gst-libs/gst/audio/Makefile
 846 gst-libs/gst/app/Makefile
 847 gst-libs/gst/fft/Makefile
 848 gst-libs/gst/riff/Makefile
 849 gst-libs/gst/rtp/Makefile
 850 gst-libs/gst/rtsp/Makefile
 851 gst-libs/gst/sdp/Makefile
 852 gst-libs/gst/tag/Makefile
 853 gst-libs/gst/pbutils/Makefile
 854 gst-libs/gst/pbutils/gstpluginsbaseversion.h
 855 gst-libs/gst/video/Makefile
 856 tools/Makefile
 857 pkgconfig/Makefile
 858 pkgconfig/gstreamer-audio.pc
 859 pkgconfig/gstreamer-audio-uninstalled.pc
 860 pkgconfig/gstreamer-app.pc
 861 pkgconfig/gstreamer-app-uninstalled.pc
 862 pkgconfig/gstreamer-fft.pc
 863 pkgconfig/gstreamer-fft-uninstalled.pc
 864 pkgconfig/gstreamer-pbutils.pc
 865 pkgconfig/gstreamer-pbutils-uninstalled.pc
 866 pkgconfig/gstreamer-riff.pc
 867 pkgconfig/gstreamer-riff-uninstalled.pc
 868 pkgconfig/gstreamer-rtp.pc
 869 pkgconfig/gstreamer-rtp-uninstalled.pc
 870 pkgconfig/gstreamer-rtsp.pc
 871 pkgconfig/gstreamer-rtsp-uninstalled.pc
 872 pkgconfig/gstreamer-sdp.pc
 873 pkgconfig/gstreamer-sdp-uninstalled.pc
 874 pkgconfig/gstreamer-tag.pc
 875 pkgconfig/gstreamer-tag-uninstalled.pc
 876 pkgconfig/gstreamer-video.pc
 877 pkgconfig/gstreamer-video-uninstalled.pc
 878 pkgconfig/gstreamer-plugins-base.pc
 879 pkgconfig/gstreamer-plugins-base-uninstalled.pc
 880 tests/Makefile
 881 tests/check/Makefile
 882 tests/examples/Makefile
 883 tests/examples/app/Makefile
 884 tests/examples/audio/Makefile
 885 tests/examples/dynamic/Makefile
 886 tests/examples/encoding/Makefile
 887 tests/examples/fft/Makefile
 888 tests/examples/gio/Makefile
 889 tests/examples/overlay/Makefile
 890 tests/examples/seek/Makefile
 891 tests/examples/snapshot/Makefile
 892 tests/examples/playback/Makefile
 893 tests/examples/playrec/Makefile
 894 tests/files/Makefile
 895 tests/icles/Makefile
 896 tests/icles/playback/Makefile
 897 docs/Makefile
 898 docs/design/Makefile
 899 docs/libs/Makefile
 900 docs/plugins/Makefile
 901 docs/version.entities
 902 po/Makefile.in
 903 common/Makefile
 904 common/m4/Makefile
 905 m4/Makefile
 906 )
 907
 908 dnl Create the config.h file for Visual Studio builds
 909 dnl Beware of spaces and /'s in some of the shell variable contents.
 910 sed \
 911     -e 's/.*config.h.in.*autoheader.*/\/* Autogenerated config.h created for win32 Visual Studio builds *\/\n\n\/* PREFIX -- specifically added for Windows for easier moving *\/\n#define PREFIX "C:\\\\gstreamer"/' \
 912     -e 's/.* GST_INSTALL_PLUGINS_HELPER/#define GST_INSTALL_PLUGINS_HELPER PREFIX "\\\\libexec\\\\gst-install-plugins-helper.exe"/' \
 913     -e 's/.* GETTEXT_PACKAGE$/#define GETTEXT_PACKAGE "'$GETTEXT_PACKAGE'"/' \
 914     -e 's/.* GST_DATADIR$/#define GST_DATADIR PREFIX "\\\\share"/' \
 915     -e 's/.* GST_LEVEL_DEFAULT$/#define GST_LEVEL_DEFAULT GST_LEVEL_ERROR/' \
 916     -e 's/.* GST_LICENSE$/#define GST_LICENSE "'$GST_LICENSE'"/' \
 917     -e 's/.* GST_API_VERSION$/#define GST_API_VERSION "'$GST_API_VERSION'"/' \
 918     -e "s,.* GST_PACKAGE_NAME$,#define GST_PACKAGE_NAME \"${GST_PACKAGE_NAME}\"," \
 919     -e 's/.* GST_PACKAGE_ORIGIN$/#define GST_PACKAGE_ORIGIN "Unknown package origin"/' \
 920     -e "s,.* GST_PACKAGE_RELEASE_DATETIME$,#define GST_PACKAGE_RELEASE_DATETIME \"${GST_PACKAGE_RELEASE_DATETIME}\"," \
 921     -e 's/.* HAVE_CPU_I386$/#define HAVE_CPU_I386 1/' \
 922     -e 's/.* HAVE_FGETPOS$/#define HAVE_FGETPOS 1/' \
 923     -e 's/.* HAVE_FSETPOS$/#define HAVE_FSETPOS 1/' \
 924     -e 's/.* HAVE_ISO_CODES$/#undef HAVE_ISO_CODES/' \
 925     -e 's/.* HAVE_LIBXML2$/#define HAVE_LIBXML2 1/' \
 926     -e 's/.* HAVE_PROCESS_H$/#define HAVE_PROCESS_H 1/' \
 927     -e 's/.* HAVE_STDLIB_H$/#define HAVE_STDLIB_H 1/' \
 928     -e 's/.* HAVE_STRING_H$/#define HAVE_STRING_H 1/' \
 929     -e 's/.* HAVE_SYS_STAT_H$/#define HAVE_SYS_STAT_H 1/' \
 930     -e 's/.* HAVE_SYS_TYPES_H$/#define HAVE_SYS_TYPES_H 1/' \
 931     -e 's/.* HAVE_WIN32$/#define HAVE_WIN32 1/' \
 932     -e 's/.* HOST_CPU$/#define HOST_CPU "i686"/' \
 933     -e 's/.* ISO_CODES_PREFIX$/#undef ISO_CODES_PREFIX/' \
 934     -e 's/.* ISO_CODES_VERSION$/#undef ISO_CODES_VERSION/' \
 935     -e 's/.* LIBDIR$/#ifdef _DEBUG\n#  define LIBDIR PREFIX "\\\\debug\\\\lib"\n#else\n#  define LIBDIR PREFIX "\\\\lib"\n#endif/' \
 936     -e 's/.* LOCALEDIR$/#define LOCALEDIR PREFIX "\\\\share\\\\locale"/' \
 937     -e "s/.* PACKAGE$/#define PACKAGE \"$PACKAGE\"/" \
 938     -e 's/.* PACKAGE_BUGREPORT$/#define PACKAGE_BUGREPORT "http:\/\/bugzilla.gnome.org\/enter_bug.cgi?product=GStreamer"/' \
 939     -e "s/.* PACKAGE_NAME$/#define PACKAGE_NAME \"$PACKAGE_NAME\"/" \
 940     -e "s/.* PACKAGE_STRING$/#define PACKAGE_STRING \"$PACKAGE_STRING\"/" \
 941     -e 's/.* PACKAGE_TARNAME$/#define PACKAGE_TARNAME "'$PACKAGE_TARNAME'"/' \
 942     -e 's/.* PACKAGE_VERSION$/#define PACKAGE_VERSION "'$PACKAGE_VERSION'"/' \
 943     -e 's/.* PLUGINDIR$/#ifdef _DEBUG\n#  define PLUGINDIR PREFIX "\\\\debug\\\\lib\\\\gstreamer-0.11"\n#else\n#  define PLUGINDIR PREFIX "\\\\lib\\\\gstreamer-0.11"\n#endif/' \
 944     -e 's/.* USE_BINARY_REGISTRY$/#define USE_BINARY_REGISTRY/' \
 945     -e 's/.* VERSION$/#define VERSION "'$VERSION'"/' \
 946     -e "s/.* DEFAULT_AUDIOSINK$/#define DEFAULT_AUDIOSINK \"directsoundsink\"/" \
 947     -e "s/.* DEFAULT_VIDEOSINK$/#define DEFAULT_VIDEOSINK \"directdrawsink\"/" \
 948     -e "s/.* DEFAULT_VISUALIZER$/#define DEFAULT_VISUALIZER \"goom\"/" \
 949     config.h.in >win32/common/config.h-new
 950
 951
 952
 953 AC_OUTPUT
 954
 955 AG_GST_OUTPUT_PLUGINS
 956 ORC_OUTPUT
 957