configure.ac

   1 AC_PREREQ(2.62)
   2
   3 dnl initialize autoconf
   4 dnl when going to/from release please set the nano (fourth number) right !
   5 dnl releases only do Wall, git and prerelease does Werror too
   6 AC_INIT(GStreamer, 0.11.92.1,
   7     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
   8     gstreamer)
   9 AG_GST_INIT
  10
  11 dnl initialize automake (we require GNU make)
  12 AM_INIT_AUTOMAKE([-Wno-portability 1.11 no-dist-gzip dist-xz tar-ustar])
  13
  14 dnl define PACKAGE_VERSION_* variables
  15 AS_VERSION
  16
  17 dnl check if this is a release version
  18 AS_NANO(GST_GIT="no", GST_GIT="yes")
  19
  20 dnl can autoconf find the source ?
  21 AC_CONFIG_SRCDIR([gst/gst.c])
  22
  23 dnl define the output header for config
  24 AM_CONFIG_HEADER([config.h])
  25
  26 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  27 AM_MAINTAINER_MODE([enable])
  28
  29 dnl sets host_* variables
  30 AC_CANONICAL_HOST
  31
  32 dnl use pretty build output with automake >= 1.11
  33 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],
  34   [AM_DEFAULT_VERBOSITY=1
  35    AC_SUBST(AM_DEFAULT_VERBOSITY)])
  36
  37 dnl GStreamer versioning, this is mostly informational
  38 dnl GST_VERSION_MAJOR=$PACKAGE_VERSION_MAJOR
  39 dnl GST_VERSION_MINOR=$PACKAGE_VERSION_MINOR
  40 dnl GST_VERSION_MICRO=$PACKAGE_VERSION_MICRO
  41 dnl GST_VERSION_NANO=$PACKAGE_VERSION_NANO
  42 dnl Change this to the above for non-pre
  43 GST_VERSION_MAJOR=1
  44 GST_VERSION_MINOR=0
  45 GST_VERSION_MICRO=0
  46 GST_VERSION_NANO=0
  47 AC_SUBST(GST_VERSION_MAJOR)
  48 AC_SUBST(GST_VERSION_MINOR)
  49 AC_SUBST(GST_VERSION_MICRO)
  50 AC_SUBST(GST_VERSION_NANO)
  51
  52 dnl our libraries and install dirs use GST_API_VERSION in the filename
  53 dnl to allow side-by-side installation of different API versions
  54 GST_API_VERSION=1.0
  55 AC_SUBST(GST_API_VERSION)
  56 AC_DEFINE_UNQUOTED(GST_API_VERSION, "$GST_API_VERSION",
  57   [GStreamer API Version])
  58
  59 dnl CURRENT, REVISION, AGE
  60 dnl - library source changed -> increment REVISION
  61 dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
  62 dnl - interfaces added -> increment AGE
  63 dnl - interfaces removed -> AGE = 0
  64 dnl sets GST_LT_LDFLAGS
  65 AS_LIBTOOL(GST, 0, 0, 0)
  66
  67 dnl *** autotools stuff ****
  68
  69 dnl allow for different autotools
  70 AS_AUTOTOOLS_ALTERNATE
  71
  72 dnl Add parameters for aclocal (keep in sync with Makefile.am)
  73 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  74
  75 dnl set up gettext
  76 dnl the version check needs to stay here because autopoint greps for it
  77 AM_GNU_GETTEXT_VERSION([0.17])
  78 AM_GNU_GETTEXT([external])
  79 AG_GST_GETTEXT([gstreamer-$GST_API_VERSION])
  80
  81 dnl *** check for arguments to configure ***
  82
  83 AG_GST_ARG_DISABLE_FATAL_WARNINGS
  84
  85 dnl subsystems - can influence other decisions so needs to be high up
  86 dnl we need to AM_CONDITIONAL them here for automake 1.6.x compatibility
  87 AG_GST_CHECK_SUBSYSTEM_DISABLE(GST_DEBUG,[debugging subsystem])
  88 AM_CONDITIONAL(GST_DISABLE_GST_DEBUG, test "x$GST_DISABLE_GST_DEBUG" = "xyes")
  89 AG_GST_CHECK_SUBSYSTEM_DISABLE(PARSE,[command-line parser])
  90 AM_CONDITIONAL(GST_DISABLE_PARSE, test "x$GST_DISABLE_PARSE" = "xyes")
  91 if test "x$GST_DISABLE_PARSE" = xyes; then
  92   AC_DEFINE(GST_DISABLE_PARSE, 1,
  93     [Define if pipeline parsing code is disabled])
  94 fi
  95 AG_GST_CHECK_SUBSYSTEM_DISABLE(OPTION_PARSING,[option parsing when gst_init])
  96 AM_CONDITIONAL(GST_DISABLE_OPTION_PARSING, test "x$GST_DISABLE_OPTION_PARSING" = "xyes")
  97 if test "x$GST_DISABLE_OPTION_PARSING" = xyes; then
  98   AC_DEFINE(GST_DISABLE_OPTION_PARSING, 1,
  99     [Define if option parsing is disabled])
 100 fi
 101 AG_GST_CHECK_SUBSYSTEM_DISABLE(TRACE,[tracing subsystem])
 102 AM_CONDITIONAL(GST_DISABLE_TRACE, test "x$GST_DISABLE_TRACE" = "xyes")
 103 AG_GST_CHECK_SUBSYSTEM_DISABLE(ALLOC_TRACE,[allocation tracing])
 104 AM_CONDITIONAL(GST_DISABLE_ALLOC_TRACE, test "x$GST_DISABLE_ALLOC_TRACE" = "xyes")
 105 AG_GST_CHECK_SUBSYSTEM_DISABLE(REGISTRY,[plugin registry])
 106 AM_CONDITIONAL(GST_DISABLE_REGISTRY, test "x$GST_DISABLE_REGISTRY" = "xyes")
 107 dnl define a substitution to use in docs/gst/gstreamer.types
 108 if test "x$GST_DISABLE_REGISTRY" = "xyes"
 109 then
 110   GST_REGISTRY_DOC_TYPES="%"
 111 else
 112   GST_REGISTRY_DOC_TYPES=
 113 fi
 114 AC_SUBST(GST_REGISTRY_DOC_TYPES)
 115 AG_GST_CHECK_SUBSYSTEM_DISABLE(PLUGIN,[plugin])
 116 AM_CONDITIONAL(GST_DISABLE_PLUGIN, test "x$GST_DISABLE_PLUGIN" = "xyes")
 117
 118 AG_GST_ARG_DEBUG
 119 AG_GST_ARG_PROFILING
 120 AG_GST_ARG_VALGRIND
 121 AG_GST_ARG_GCOV
 122
 123 AG_GST_ARG_EXAMPLES
 124
 125 AG_GST_ARG_WITH_PKG_CONFIG_PATH
 126 AG_GST_ARG_WITH_PACKAGE_NAME
 127 AG_GST_ARG_WITH_PACKAGE_ORIGIN
 128
 129 AG_GST_PKG_CONFIG_PATH
 130
 131 AG_GST_SET_PACKAGE_RELEASE_DATETIME_WITH_NANO([$PACKAGE_VERSION_NANO],
 132   ["${srcdir}/gstreamer.doap"],
 133   [$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_MICRO])
 134
 135 dnl building of tests
 136 AC_ARG_ENABLE(tests,
 137   AC_HELP_STRING([--disable-tests], [disable building test apps]),
 138   [
 139     case "${enableval}" in
 140       yes) BUILD_TESTS=yes ;;
 141       no)  BUILD_TESTS=no ;;
 142       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-tests) ;;
 143     esac
 144   ],
 145 [BUILD_TESTS=yes]) dnl Default value
 146 AM_CONDITIONAL(BUILD_TESTS,         test "x$BUILD_TESTS" = "xyes")
 147
 148 dnl tests known to fail
 149 AC_ARG_ENABLE(failing-tests,
 150   AC_HELP_STRING([--disable-failing-tests],
 151     [disable building tests known to fail]),
 152   [
 153     case "${enableval}" in
 154       yes) BUILD_FAILING_TESTS=yes ;;
 155       no)  BUILD_FAILING_TESTS=no ;;
 156       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-failing-tests) ;;
 157     esac
 158   ],
 159   [BUILD_FAILING_TESTS=no]) dnl Default value
 160 AM_CONDITIONAL(BUILD_FAILING_TESTS, test "x$BUILD_FAILING_TESTS" = "xyes")
 161 if test x$BUILD_FAILING_TESTS = xyes; then
 162   AC_MSG_WARN([building tests known to fail, use --disable-failing-tests to disable])
 163 else
 164   AC_MSG_WARN([Sissy ! By asking to not build the tests known to fail, you hereby waive your right to customer support.  If you do not agree with this EULA, please press Ctrl-C before the next line is printed.  By allowing the next line to be printed, you expressly acknowledge your acceptance of this EULA.])
 165 fi
 166
 167 dnl building of benchmarks
 168 AC_ARG_ENABLE(benchmarks,
 169   AC_HELP_STRING([--disable-benchmarks], [disable building benchmarks apps]),
 170   [
 171     case "${enableval}" in
 172       yes) BUILD_BENCHMARKS=yes ;;
 173       no)  BUILD_BENCHMARKS=no ;;
 174       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-benchmarks) ;;
 175     esac
 176   ],
 177 [BUILD_BENCHMARKS=yes]) dnl Default value
 178 AM_CONDITIONAL(BUILD_BENCHMARKS, test "x$BUILD_BENCHMARKS" = "xyes")
 179
 180 dnl building of tools
 181 AC_ARG_ENABLE(tools,
 182   AC_HELP_STRING([--disable-tools], [disable building tools]),
 183   [
 184     case "${enableval}" in
 185       yes) BUILD_TOOLS=yes ;;
 186       no)  BUILD_TOOLS=no ;;
 187       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-tools) ;;
 188     esac
 189   ],
 190 [BUILD_TOOLS=yes]) dnl Default value
 191 AM_CONDITIONAL(BUILD_TOOLS, test "x$BUILD_TOOLS" = "xyes")
 192
 193 dnl poison destroyed objects
 194 AC_ARG_ENABLE(poisoning,
 195   AC_HELP_STRING([--enable-poisoning],
 196     [enable poisoning of deallocated objects]),
 197   [
 198     case "${enableval}" in
 199       yes) USE_POISONING=yes ;;
 200       no)  USE_POISONING=no ;;
 201       *)   AC_MSG_ERROR(bad value ${enableval} for --enable-poisoning) ;;
 202     esac
 203   ],
 204   [USE_POISONING=no]) dnl Default value
 205 if test "x$USE_POISONING" = xyes; then
 206   AC_DEFINE(USE_POISONING, 1,
 207     [Define if we should poison deallocated memory])
 208 fi
 209
 210 dnl *** checks for platform ***
 211
 212 dnl * hardware/architecture *
 213
 214 dnl common/m4/gst-arch.m4
 215 dnl check CPU type
 216 AG_GST_ARCH
 217 dnl substitution for win32/common/config.h
 218 HOST_CPU=$host_cpu
 219 AC_SUBST(HOST_CPU)
 220
 221 dnl common/m4/gst-arch.m4
 222 dnl check for unaligned access
 223 AG_GST_UNALIGNED_ACCESS
 224 dnl create a configure variable for gst/gstconfig.h
 225 if test x${as_cv_unaligned_access} = xyes ; then
 226   GST_HAVE_UNALIGNED_ACCESS_DEFINE="#define GST_HAVE_UNALIGNED_ACCESS 1"
 227 else
 228   GST_HAVE_UNALIGNED_ACCESS_DEFINE="#define GST_HAVE_UNALIGNED_ACCESS 0"
 229 fi
 230 AC_SUBST(GST_HAVE_UNALIGNED_ACCESS_DEFINE)
 231
 232 dnl check for platform specific settings
 233 AG_GST_PLATFORM
 234
 235 dnl * software *
 236
 237 dnl check for large file support
 238 dnl affected plugins must include config.h
 239 AC_SYS_LARGEFILE
 240
 241 dnl *** checks for programs ***
 242
 243 dnl find a compiler
 244 AC_PROG_CC
 245 AC_PROG_CC_STDC
 246
 247 dnl check if the compiler supports '-c' and '-o' options
 248 AM_PROG_CC_C_O
 249
 250 dnl find an assembler
 251 AM_PROG_AS
 252
 253 dnl determine if c++ is available on this system
 254 AC_PROG_CXX
 255 dnl CXX may be set to some default even if no c++ compiler is available
 256 dnl (thanks autotools!), so just try to compile some c++ code to make sure
 257 AC_LANG_PUSH([C++])
 258 AC_TRY_COMPILE([ class Foo { int bar; };], , working_cxx=yes, working_cxx=no)
 259 AC_LANG_POP([C++])
 260 AC_MSG_NOTICE([working c++ compiler found: $working_cxx])
 261 AM_CONDITIONAL(HAVE_CXX, test "x$working_cxx" = "xyes")
 262
 263 dnl Perl is used in building documentation and in the version checks
 264 AC_PATH_PROG(PERL_PATH, perl, no)
 265 if test x$PERL_PATH = xno; then
 266   AC_MSG_ERROR(Could not find perl)
 267 fi
 268
 269 dnl we require flex and bison for building the parser
 270 if test "x$GST_DISABLE_PARSE" != xyes; then
 271   AG_GST_BISON_CHECK
 272   AG_GST_FLEX_CHECK
 273 fi
 274
 275 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 276 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 277
 278 dnl check for gobject-introspection
 279 GOBJECT_INTROSPECTION_CHECK([1.31.1])
 280
 281 dnl check for documentation tools
 282 AG_GST_DOCBOOK_CHECK
 283 GTK_DOC_CHECK([1.3])
 284 AS_PATH_PYTHON([2.1])
 285 AG_GST_PLUGIN_DOCS([1.3],[2.1])
 286
 287 dnl *** checks for libraries ***
 288
 289 dnl check for libm, for sin()
 290 LT_LIB_M
 291 AC_SUBST(LIBM)
 292
 293 dnl *** checks for header files ***
 294
 295 dnl check if we have ANSI C header files
 296 AC_HEADER_STDC
 297
 298 dnl Check for ucontext.h
 299 AC_CHECK_HEADERS([ucontext.h], [], [], [AC_INCLUDES_DEFAULT])
 300
 301 dnl Check for sys/socket.h
 302 AC_CHECK_HEADERS([sys/socket.h], [HAVE_SYS_SOCKET_H=yes], [HAVE_SYS_SOCKET_H=no], [AC_INCLUDES_DEFAULT])
 303 AM_CONDITIONAL(HAVE_SYS_SOCKET_H, test "x$HAVE_SYS_SOCKET_H" = "xyes")
 304
 305 dnl check for sys/times.h for tests/examples/adapter/
 306 AC_CHECK_HEADERS([sys/times.h], [HAVE_SYS_TIMES_H=yes], [HAVE_SYS_TIME_H=no], [AC_INCLUDES_DEFAULT])
 307 AC_CHECK_HEADERS([unistd.h], [HAVE_UNISTD_H=yes], [HAVE_UNISTD_H=no], [AC_INCLUDES_DEFAULT])
 308 AM_CONDITIONAL(HAVE_SYS_TIMES_H_AND_UNISTD_H, test "x$HAVE_SYS_TIMES_H" = "xyes" -a "x$HAVE_UNISTD_H" = "xyes")
 309
 310 dnl Check for process.h for getpid() on win32
 311 AC_CHECK_HEADERS([process.h], [], [], [AC_INCLUDES_DEFAULT])
 312
 313 dnl Check for sys/utsname.h for uname
 314 AC_CHECK_HEADERS([sys/utsname.h], [], [], [AC_INCLUDES_DEFAULT])
 315
 316 dnl Check for stdio_ext.f for __fbufsize
 317 AC_CHECK_HEADERS([stdio_ext.h], [], [], [AC_INCLUDES_DEFAULT])
 318
 319 dnl check for pthreads
 320 AC_CHECK_HEADERS([pthread.h], [HAVE_PTHREAD_H=yes], [HAVE_PTHREAD_H=no], [AC_INCLUDES_DEFAULT])
 321 AM_CONDITIONAL(HAVE_PTHREAD_H, test "x$HAVE_PTHREAD_H" = "xyes")
 322
 323 dnl check for sys/prctl for setting thread name on Linux
 324 AC_CHECK_HEADERS([sys/prctl.h], [], [], [AC_INCLUDES_DEFAULT])
 325
 326 dnl Check for valgrind.h
 327 dnl separate from HAVE_VALGRIND because you can have the program, but not
 328 dnl the dev package
 329 AC_CHECK_HEADERS([valgrind/valgrind.h], [], [], [AC_INCLUDES_DEFAULT])
 330
 331 dnl used in gst/gstpoll.c
 332 AC_CHECK_HEADERS([winsock2.h], [HAVE_WINSOCK2_H=yes], [HAVE_WINSOCK2_H=no], [AC_INCLUDES_DEFAULT])
 333 AM_CONDITIONAL(HAVE_WINSOCK2_H, test "x$HAVE_WINSOCK2_H" = "xyes")
 334 if test "x$HAVE_WINSOCK2_H" = "xyes"; then
 335   WIN32_LIBS="-lws2_32"
 336   AC_SUBST(WIN32_LIBS)
 337 fi
 338
 339 dnl check for GMP/GSL, used by the gst_util_uint64_scale unit test only
 340 if test "x$BUILD_TESTS" = "xyes"; then
 341   AG_GST_CHECK_LIBHEADER(GMP, gmp,
 342                          __gmpz_init_set_d, ,
 343                          gmp.h,
 344                          GMP_LIBS="-lgmp"
 345                          AC_SUBST(GMP_LIBS)
 346                          AC_DEFINE(HAVE_GMP, [1],[Have GMP library]))
 347   AG_GST_CHECK_LIBHEADER(GSL, gsl,
 348                          gsl_rng_uniform_int, -lgslcblas,
 349                          gsl/gsl_rng.h,
 350                          GSL_LIBS="-lgsl -lgslcblas"
 351                          AC_SUBST(GSL_LIBS)
 352                          AC_DEFINE(HAVE_GSL, [1],[Have GSL library]))
 353 fi
 354
 355 dnl *** checks for types/defines ***
 356
 357 dnl *** checks for structures ***
 358
 359 dnl *** checks for compiler characteristics ***
 360
 361 dnl check if the compiler supports __uint128_t (gcc)
 362 dnl Actually check for 128-bit division, since that's what we use
 363 dnl uint128_t for.
 364 AC_CACHE_CHECK(for __uint128_t, gst_cv_uint128_t,
 365     AC_TRY_LINK([ ], [
 366       static __uint128_t v1 = 100;
 367       static __uint128_t v2 = 10;
 368       static __uint128_t u;
 369       u = v1 / v2;
 370     ], [
 371       gst_cv_uint128_t=yes
 372     ], [
 373       gst_cv_uint128_t=no
 374     ])
 375 )
 376 if test x$gst_cv_uint128_t = xyes; then
 377   AC_DEFINE(HAVE_UINT128_T, 1, [Have __uint128_t type])
 378 fi
 379
 380 dnl *** checking for tm_gmtoff ***
 381 AC_MSG_CHECKING([for tm_gmtoff])
 382 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 383         #include <time.h>
 384         int main(void) {
 385           struct tm t;
 386           t.tm_gmtoff = 0;
 387           exit(0);
 388         }]])],
 389   [have_tm_gmtoff=yes
 390    AC_DEFINE(HAVE_TM_GMTOFF,1,[Have tm_gmtoff field in struct tm])],
 391   [have_tm_gmtoff=no],
 392   [have_tm_gmtoff="no (cross compiling)"])
 393 AC_MSG_RESULT($have_tm_gmtoff)
 394
 395
 396 dnl *** checks for library functions ***
 397
 398 AC_CHECK_FUNCS([gmtime_r])
 399 AC_CHECK_FUNCS([localtime_r])
 400 AC_CHECK_FUNCS([sigaction])
 401
 402 dnl check for fseeko()
 403 AC_FUNC_FSEEKO
 404 dnl check for ftello()
 405 AC_CHECK_FUNCS([ftello])
 406
 407 AC_CHECK_FUNCS([fgetpos])
 408 AC_CHECK_FUNCS([fsetpos])
 409
 410 dnl check for poll(), ppoll() and pselect()
 411 AC_CHECK_HEADERS([sys/poll.h], [], [], [AC_INCLUDES_DEFAULT])
 412 AC_CHECK_HEADERS([poll.h], [], [], [AC_INCLUDES_DEFAULT])
 413 AC_CHECK_FUNCS([poll])
 414 AC_CHECK_FUNCS([ppoll])
 415 AC_CHECK_FUNCS([pselect])
 416
 417 dnl ****************************************
 418 dnl *** GLib POLL* compatibility defines ***
 419 dnl ****************************************
 420
 421 AC_MSG_CHECKING([for broken poll])
 422 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 423         #include <stdlib.h>
 424         #include <fcntl.h>
 425         #ifdef HAVE_SYS_POLL_H
 426         #include <sys/poll.h>
 427         #endif
 428         #ifdef HAVE_POLL_H
 429         #include <poll.h>
 430         #endif
 431         int main(void) {
 432           struct pollfd fds[1];
 433           int fd;
 434           fd = open("/dev/null", 1);
 435           fds[0].fd = fd;
 436           fds[0].events = POLLIN;
 437           fds[0].revents = 0;
 438           if (poll(fds, 1, 0) < 0 || (fds[0].revents & POLLNVAL) != 0) {
 439                 exit(1);  /* Does not work for devices -- fail */
 440           }
 441           exit(0);
 442         }]])],
 443   [broken_poll=no],
 444   [broken_poll=yes
 445    AC_DEFINE(BROKEN_POLL,1,[poll doesn't work on devices])],
 446   [broken_poll="no (cross compiling)"])
 447 AC_MSG_RESULT($broken_poll)
 448
 449 dnl check for mmap()
 450 AC_FUNC_MMAP
 451 AM_CONDITIONAL(HAVE_MMAP, test "x$ac_cv_func_mmap_fixed_mapped" = "xyes")
 452
 453 dnl check for posix_memalign(), getpagesize()
 454 AC_CHECK_FUNCS([posix_memalign])
 455 AC_CHECK_FUNCS([getpagesize])
 456
 457 dnl Check for POSIX timers
 458 AC_CHECK_FUNCS(clock_gettime, [], [
 459   AC_CHECK_LIB(rt, clock_gettime, [
 460     AC_DEFINE(HAVE_CLOCK_GETTIME, 1)
 461     LIBS="$LIBS -lrt"
 462   ])
 463 ])
 464
 465 AC_CACHE_CHECK(for posix timers, gst_cv_posix_timers,
 466     AC_TRY_COMPILE([
 467 #include <time.h>
 468 #ifdef HAVE_UNISTD_H
 469 #include <unistd.h>
 470 #endif
 471     ], [
 472 #if !defined(_POSIX_TIMERS) || _POSIX_TIMERS < 0 || !defined(CLOCK_REALTIME)
 473 #error Either _POSIX_TIMERS or CLOCK_REALTIME not defined
 474 #endif
 475     ], [
 476       gst_cv_posix_timers=yes
 477     ], [
 478       gst_cv_posix_timers=no
 479     ])
 480 )
 481
 482 if test "$gst_cv_posix_timers" = "yes"; then
 483   AC_DEFINE(HAVE_POSIX_TIMERS,1,[Have posix timers])
 484   GST_HAVE_POSIX_TIMERS_DEFINE="#define GST_HAVE_POSIX_TIMERS 1"
 485 else
 486   GST_HAVE_POSIX_TIMERS_DEFINE="#define GST_HAVE_POSIX_TIMERS 0"
 487 fi
 488 AC_SUBST(GST_HAVE_POSIX_TIMERS_DEFINE)
 489 AM_CONDITIONAL(GST_HAVE_POSIX_TIMERS, test "$gst_cv_posix_timers" = "yes")
 490
 491 AC_CACHE_CHECK(for monotonic clock, gst_cv_monotonic_clock,
 492     AC_TRY_COMPILE([
 493 #include <time.h>
 494 #ifdef HAVE_UNISTD_H
 495 #include <unistd.h>
 496 #endif
 497     ], [
 498 #if !defined(_POSIX_MONOTONIC_CLOCK) || _POSIX_MONOTONIC_CLOCK < 0 || !defined(CLOCK_MONOTONIC)
 499 #error Either _POSIX_MONOTONIC_CLOCK or CLOCK_MONOTONIC not defined
 500 #endif
 501     ], [
 502       gst_cv_monotonic_clock=yes
 503     ], [
 504       gst_cv_monotonic_clock=no
 505     ])
 506 )
 507
 508 if test "$gst_cv_monotonic_clock" = "yes"; then
 509   AC_DEFINE(HAVE_MONOTONIC_CLOCK,1,[Have a monotonic clock])
 510   GST_HAVE_MONOTONIC_CLOCK_DEFINE="#define GST_HAVE_MONOTONIC_CLOCK 1"
 511 else
 512   GST_HAVE_MONOTONIC_CLOCK_DEFINE="#define GST_HAVE_MONOTONIC_CLOCK 0"
 513 fi
 514 AC_SUBST(GST_HAVE_MONOTONIC_CLOCK_DEFINE)
 515 AM_CONDITIONAL(GST_HAVE_MONOTONIC_CLOCK, test "$gst_cv_monotonic_clock" = "yes")
 516
 517 dnl Check for a way to display the function name in debug output
 518 AG_GST_CHECK_FUNCTION
 519
 520 dnl test for register_printf_specifier or register_printf_function
 521 AC_CHECK_FUNCS([register_printf_specifier register_printf_function],
 522     [HAVE_PRINTF_EXTENSION=yes])
 523
 524 if test "$HAVE_PRINTF_EXTENSION" = yes; then
 525   GST_PRINTF_EXTENSION_POINTER_FORMAT_DEFINE="#define GST_PTR_FORMAT \"P\""
 526   GST_PRINTF_EXTENSION_SEGMENT_FORMAT_DEFINE="#define GST_SEGMENT_FORMAT \"Q\""
 527   GST_USING_PRINTF_EXTENSION_DEFINE="#define GST_USING_PRINTF_EXTENSION"
 528   AC_DEFINE(HAVE_PRINTF_EXTENSION, 1,
 529       [Defined if we have printf specifier extensions available])
 530 else
 531     GST_PRINTF_EXTENSION_POINTER_FORMAT_DEFINE="#define GST_PTR_FORMAT \"p\""
 532     GST_PRINTF_EXTENSION_SEGMENT_FORMAT_DEFINE="#define GST_SEGMENT_FORMAT \"p\""
 533     GST_USING_PRINTF_EXTENSION_DEFINE="#undef GST_USING_PRINTF_EXTENSION"
 534 fi
 535 AC_SUBST(GST_PRINTF_EXTENSION_POINTER_FORMAT_DEFINE)
 536 AC_SUBST(GST_PRINTF_EXTENSION_SEGMENT_FORMAT_DEFINE)
 537 AC_SUBST(GST_USING_PRINTF_EXTENSION_DEFINE)
 538
 539 dnl test if we have dladdr(); we use it for debugging; see gst/gstinfo.c
 540 save_cflags="$CFLAGS"
 541 CFLAGS="$CFLAGS -D_GNU_SOURCE"
 542 AC_CHECK_LIB(dl, dladdr,
 543    AC_DEFINE(HAVE_DLADDR, 1, [Defined if we have dladdr ()])
 544    LIBS="$LIBS -ldl")
 545 CFLAGS="$save_cflags"
 546
 547 dnl *** checks for dependency libraries ***
 548
 549 dnl GLib
 550 GLIB_REQ=2.32.0
 551 AG_GST_GLIB_CHECK([$GLIB_REQ])
 552
 553 dnl Check for documentation xrefs
 554 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 555 AC_SUBST(GLIB_PREFIX)
 556
 557 dnl building of unit test libraries
 558 AC_ARG_ENABLE(check,
 559   AC_HELP_STRING([--disable-check], [disable building unit test libraries]),
 560   [
 561     case "${enableval}" in
 562       yes) BUILD_CHECK=yes ;;
 563       no)  BUILD_CHECK=no ;;
 564       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-check) ;;
 565     esac
 566   ], [
 567     dnl Default value
 568     case $host_os in
 569       mingw* | msvc* | mks*) BUILD_CHECK=no ;;
 570       *) BUILD_CHECK=yes ;;
 571     esac
 572 ])
 573 dnl bit of a misnomer, but keep the conditional named like this so we don't
 574 dnl have to change too much elsewhere
 575 AM_CONDITIONAL(HAVE_CHECK, test "x$BUILD_CHECK" = "xyes")
 576
 577 dnl configure the desired memory alignment
 578 AC_ARG_WITH([memory-alignment],
 579   AS_HELP_STRING([--with-memory-alignment],[8,N,malloc,pagesize (default is 32)]),
 580   [
 581     if test "x$withval" = "xyes"
 582     then
 583       AC_DEFINE(MEMORY_ALIGNMENT, 32, [Memory alignment to use])
 584     else
 585       case "${withval}" in
 586         malloc) AC_DEFINE(MEMORY_ALIGNMENT_MALLOC, 1, [Memory alignment by malloc default]) ;;
 587         pagesize)  AC_DEFINE(MEMORY_ALIGNMENT_PAGESIZE, 1, [Memory alignment by pagesize]) ;;
 588         *)   AC_DEFINE_UNQUOTED(MEMORY_ALIGNMENT, ${withval}, [Memory alignment to use]) ;;
 589       esac
 590     fi
 591   ], [
 592     AC_DEFINE(MEMORY_ALIGNMENT_MALLOC, 1, [Memory alignment by malloc default])
 593   ]
 594 )
 595
 596 dnl Check for -Bsymbolic-functions linker flag used to avoid
 597 dnl intra-library PLT jumps, if available.
 598 AC_ARG_ENABLE(Bsymbolic,
 599               [AC_HELP_STRING([--disable-Bsymbolic],
 600                               [avoid linking with -Bsymbolic])],,
 601               [SAVED_LDFLAGS="${LDFLAGS}"
 602                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
 603                LDFLAGS=-Wl,-Bsymbolic-functions
 604                AC_TRY_LINK([], [int main (void) { return 0; }],
 605                            AC_MSG_RESULT(yes)
 606                            enable_Bsymbolic=yes,
 607                            AC_MSG_RESULT(no)
 608                            enable_Bsymbolic=no)
 609                LDFLAGS="${SAVED_LDFLAGS}"])
 610
 611
 612 dnl *** set variables based on configure arguments
 613
 614 dnl set license and copyright notice
 615 GST_LICENSE="LGPL"
 616 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 617 AC_SUBST(GST_LICENSE)
 618
 619 dnl define LIBDIR, GST_DATADIR so we can inform people where we live
 620 AS_AC_EXPAND(LIBDIR, $libdir)
 621 AC_DEFINE_UNQUOTED(LIBDIR, "$LIBDIR", [library dir])
 622 AS_AC_EXPAND(DATADIR, $datadir)
 623 AC_DEFINE_UNQUOTED(GST_DATADIR, "$DATADIR", [data dir])
 624
 625 dnl set location of plugin directory
 626 AG_GST_SET_PLUGINDIR
 627
 628 GST_PKG_DEPS="glib-2.0, gobject-2.0, gmodule-no-export-2.0, gthread-2.0"
 629 AC_SUBST(GST_PKG_DEPS)
 630
 631 dnl make sure it doesn't complain about unused variables if debugging is disabled
 632 NO_WARNINGS=""
 633 if test "x${GST_DISABLE_GST_DEBUG}" = "xyes"; then
 634   NO_WARNINGS="-Wno-unused"
 635 fi
 636
 637 dnl define an ERROR_CFLAGS Makefile variable
 638 AG_GST_SET_ERROR_CFLAGS($FATAL_WARNINGS, [-Wmissing-declarations -Wmissing-prototypes -Wredundant-decls -Wundef -Wwrite-strings -Wformat-nonliteral -Wformat-security -Wold-style-definition -Winit-self -Wmissing-include-dirs -Waddress -Waggregate-return -Wno-multichar -Wnested-externs $NO_WARNINGS])
 639
 640 dnl define correct level for debugging messages
 641 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 642
 643 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 644
 645 dnl Overview:
 646 dnl GST_OPTION_CFLAGS:  common cflags for profiling, debugging, errors, ...
 647 dnl GST_ALL_*:          vars shared by all built objects
 648 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 649 dnl GST_OBJ_*:          additional vars to link to the core library
 650 dnl                     include GST_ALL_*
 651 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 652 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 653
 654 dnl GST_OPTION_CFLAGS
 655 if test "x$USE_DEBUG" = xyes; then
 656    PROFILE_CFLAGS="-g"
 657 fi
 658 AC_SUBST(PROFILE_CFLAGS)
 659
 660 # GST_DISABLE_DEPRECATED: hide the visibility of deprecated
 661 # functionality from the API that gstreamer uses
 662 # GST_REMOVE_DEPRECATED: don't compile deprecated functionality (breaks ABI)
 663 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
 664   dnl Define _only_ when compiling from git (not for pre-releases or releases)
 665   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 666 else
 667   DEPRECATED_CFLAGS=""
 668 fi
 669 AC_SUBST(DEPRECATED_CFLAGS)
 670
 671 dnl every flag in GST_OPTION_CFLAGS can be overridden at make time via e.g.
 672 dnl make DEPRECATED_CFLAGS=''
 673 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 674 GST_OPTION_CXXFLAGS="\$(WARNING_CXXFLAGS) \$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 675 GST_OPTION_CFLAGS="$GST_OPTION_CFLAGS -DGST_USE_UNSTABLE_API"
 676 GST_OPTION_CXXFLAGS="$GST_OPTION_CXXFLAGS -DGST_USE_UNSTABLE_API"
 677 AC_SUBST(GST_OPTION_CFLAGS)
 678 AC_SUBST(GST_OPTION_CXXFLAGS)
 679
 680 dnl GST_ALL_*
 681 dnl vars common to for all internal objects (core libs, elements, applications)
 682 dnl CFLAGS:
 683 dnl - src and build dirs need to be added because every piece that gets built
 684 dnl   will need the GStreamer source and generated headers
 685 dnl LIBS: XML doesn't need to be added because we don't explicitly use symbols
 686 dnl       from LibXML except for in the core library
 687 GST_ALL_CXXFLAGS="-I\$(top_srcdir)/libs -I\$(top_srcdir) -I\$(top_builddir)/libs -I\$(top_builddir) $GLIB_CFLAGS \$(GLIB_EXTRA_CFLAGS) $XML_CFLAGS \$(GST_OPTION_CXXFLAGS) \$(ERROR_CXXFLAGS)"
 688 GST_ALL_CFLAGS="-I\$(top_srcdir)/libs -I\$(top_srcdir) -I\$(top_builddir)/libs -I\$(top_builddir) $GLIB_CFLAGS \$(GLIB_EXTRA_CFLAGS) $XML_CFLAGS \$(GST_OPTION_CFLAGS) \$(ERROR_CFLAGS)"
 689
 690 dnl FIXME: check if LTLIBINTL is needed everywhere
 691 dnl I presume it is given that it contains the symbols that _() stuff maps to
 692 GST_ALL_LIBS="$GLIB_LIBS $LTLIBINTL \$(GCOV_LIBS)"
 693
 694 dnl LDFLAGS really should only contain flags, not libs - they get added before
 695 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 696 GST_ALL_LDFLAGS="-no-undefined"
 697 if test "x${enable_Bsymbolic}" = "xyes"; then
 698   GST_ALL_LDFLAGS="$GST_ALL_LDFLAGS -Wl,-Bsymbolic-functions"
 699 fi
 700
 701 AC_SUBST(GST_ALL_CFLAGS)
 702 AC_SUBST(GST_ALL_CXXFLAGS)
 703 AC_SUBST(GST_ALL_LIBS)
 704 AC_SUBST(GST_ALL_LDFLAGS)
 705
 706 dnl GST_LIB_LDFLAGS
 707 dnl linker flags shared by all libraries
 708 dnl LDFLAGS modifier defining exported symbols from built libraries
 709 GST_LIB_LDFLAGS="-export-symbols-regex \^[_]?\(gst_\|Gst\|GST_\).*"
 710 AC_SUBST(GST_LIB_LDFLAGS)
 711
 712 dnl GST_OBJ_*
 713 dnl default vars for all internal objects built on libgstreamer
 714 dnl includes GST_ALL_*
 715 GST_OBJ_CFLAGS="\$(GST_ALL_CFLAGS)"
 716 GST_OBJ_CXXFLAGS="\$(GST_ALL_CXXFLAGS)"
 717 GST_OBJ_LIBS="\$(top_builddir)/gst/libgstreamer-$GST_API_VERSION.la \$(GST_ALL_LIBS)"
 718 AC_SUBST(GST_OBJ_CFLAGS)
 719 AC_SUBST(GST_OBJ_CXXFLAGS)
 720 AC_SUBST(GST_OBJ_LIBS)
 721
 722 dnl GST_PLUGIN_LDFLAGS
 723 dnl LDFLAGS for plugins; includes GST_ALL_LDFLAGS
 724 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc.*' $GST_ALL_LDFLAGS"
 725 AC_SUBST(GST_PLUGIN_LDFLAGS, "$GST_PLUGIN_LDFLAGS")
 726
 727 dnl plugin scanner locations
 728 AS_AC_EXPAND(GST_PLUGIN_SCANNER_INSTALLED,${libexecdir}/gstreamer-$GST_API_VERSION/gst-plugin-scanner)
 729 AC_DEFINE_UNQUOTED(GST_PLUGIN_SCANNER_INSTALLED,
 730     "$GST_PLUGIN_SCANNER_INSTALLED", [location of the installed gst-plugin-scanner])
 731 AC_SUBST(GST_PLUGIN_SCANNER_INSTALLED)
 732
 733 dnl things for our internal libcheck (must be called even if building
 734 dnl libcheck is disabled because it defines conditionals)
 735 AG_GST_CHECK_CHECKS()
 736
 737 AC_CONFIG_FILES(
 738 Makefile
 739 gst/Makefile
 740 gst/gstconfig.h
 741 gst/gstversion.h
 742 gst/parse/Makefile
 743 libs/Makefile
 744 libs/gst/Makefile
 745 libs/gst/base/Makefile
 746 libs/gst/check/Makefile
 747 libs/gst/check/libcheck/Makefile
 748 libs/gst/check/libcheck/check.h
 749 libs/gst/controller/Makefile
 750 libs/gst/helpers/Makefile
 751 libs/gst/net/Makefile
 752 plugins/Makefile
 753 plugins/elements/Makefile
 754 po/Makefile.in
 755 tests/Makefile
 756 tests/benchmarks/Makefile
 757 tests/check/Makefile
 758 tests/misc/Makefile
 759 tests/examples/Makefile
 760 tests/examples/adapter/Makefile
 761 tests/examples/controller/Makefile
 762 tests/examples/stepping/Makefile
 763 tests/examples/helloworld/Makefile
 764 tests/examples/launch/Makefile
 765 tests/examples/manual/Makefile
 766 tests/examples/memory/Makefile
 767 tests/examples/metadata/Makefile
 768 tests/examples/queue/Makefile
 769 tests/examples/streams/Makefile
 770 tests/examples/typefind/Makefile
 771 tools/Makefile
 772 common/Makefile
 773 common/m4/Makefile
 774 docs/Makefile
 775 docs/design/Makefile
 776 docs/faq/Makefile
 777 docs/gst/Makefile
 778 docs/gst/gstreamer.types
 779 docs/libs/Makefile
 780 docs/plugins/Makefile
 781 docs/manual/Makefile
 782 docs/pwg/Makefile
 783 docs/slides/Makefile
 784 docs/xsl/Makefile
 785 docs/version.entities
 786 m4/Makefile
 787 pkgconfig/Makefile
 788 stamp.h
 789 pkgconfig/gstreamer.pc
 790 pkgconfig/gstreamer-uninstalled.pc
 791 pkgconfig/gstreamer-base.pc
 792 pkgconfig/gstreamer-base-uninstalled.pc
 793 pkgconfig/gstreamer-check.pc
 794 pkgconfig/gstreamer-check-uninstalled.pc
 795 pkgconfig/gstreamer-controller.pc
 796 pkgconfig/gstreamer-controller-uninstalled.pc
 797 pkgconfig/gstreamer-net.pc
 798 pkgconfig/gstreamer-net-uninstalled.pc
 799 gst-element-check.m4
 800 gstreamer.spec
 801 )
 802
 803 dnl Create the config.h file for Visual Studio builds
 804 dnl Beware of spaces and /'s in some of the shell variable contents.
 805 sed \
 806     -e 's/.*config.h.in.*autoheader.*/\/* Autogenerated config.h created for win32 Visual Studio builds *\/\n\n\/* PREFIX -- specifically added for Windows for easier moving *\/\n#define PREFIX "C:\\\\gstreamer"/' \
 807     -e 's/.* GETTEXT_PACKAGE$/#define GETTEXT_PACKAGE "'$GETTEXT_PACKAGE'"/' \
 808     -e 's/.* GST_DATADIR$/#define GST_DATADIR PREFIX "\\\\share"/' \
 809     -e 's/.* GST_LEVEL_DEFAULT$/#define GST_LEVEL_DEFAULT GST_LEVEL_ERROR/' \
 810     -e 's/.* GST_LICENSE$/#define GST_LICENSE "'$GST_LICENSE'"/' \
 811     -e 's/.* GST_API_VERSION$/#define GST_API_VERSION "'$GST_API_VERSION'"/' \
 812     -e "s,.* GST_PACKAGE_NAME$,#define GST_PACKAGE_NAME \"${GST_PACKAGE_NAME}\"," \
 813     -e 's/.* GST_PACKAGE_ORIGIN$/#define GST_PACKAGE_ORIGIN "Unknown package origin"/' \
 814     -e "s,.* GST_PACKAGE_RELEASE_DATETIME$,#define GST_PACKAGE_RELEASE_DATETIME \"${GST_PACKAGE_RELEASE_DATETIME}\"," \
 815     -e 's/.* HAVE_CPU_I386$/#define HAVE_CPU_I386 1/' \
 816     -e 's/.* HAVE_FGETPOS$/#define HAVE_FGETPOS 1/' \
 817     -e 's/.* HAVE_FSETPOS$/#define HAVE_FSETPOS 1/' \
 818     -e 's/.* HAVE_PROCESS_H$/#define HAVE_PROCESS_H 1/' \
 819     -e 's/.* HAVE_STDLIB_H$/#define HAVE_STDLIB_H 1/' \
 820     -e 's/.* HAVE_STRING_H$/#define HAVE_STRING_H 1/' \
 821     -e 's/.* HAVE_SYS_STAT_H$/#define HAVE_SYS_STAT_H 1/' \
 822     -e 's/.* HAVE_SYS_TYPES_H$/#define HAVE_SYS_TYPES_H 1/' \
 823     -e 's/.* HAVE_WIN32$/#define HAVE_WIN32 1/' \
 824     -e 's/.* HAVE_WINSOCK2_H$/#define HAVE_WINSOCK2_H 1/' \
 825     -e 's/.* HOST_CPU$/#define HOST_CPU "i686"/' \
 826     -e 's/.* MEMORY_ALIGNMENT_MALLOC/#define MEMORY_ALIGNMENT_MALLOC 1/' \
 827     -e 's/.* LIBDIR$/#ifdef _DEBUG\n#  define LIBDIR PREFIX "\\\\debug\\\\lib"\n#else\n#  define LIBDIR PREFIX "\\\\lib"\n#endif/' \
 828     -e 's/.* LOCALEDIR$/#define LOCALEDIR PREFIX "\\\\share\\\\locale"/' \
 829     -e 's/.* PACKAGE$/#define PACKAGE "gstreamer"/' \
 830     -e 's/.* PACKAGE_BUGREPORT$/#define PACKAGE_BUGREPORT "http:\/\/bugzilla.gnome.org\/enter_bug.cgi?product=GStreamer"/' \
 831     -e 's/.* PACKAGE_NAME$/#define PACKAGE_NAME "'$PACKAGE_NAME'"/' \
 832     -e "s/.* PACKAGE_STRING$/#define PACKAGE_STRING \"$PACKAGE_STRING\"/" \
 833     -e 's/.* PACKAGE_TARNAME$/#define PACKAGE_TARNAME "'$PACKAGE_TARNAME'"/' \
 834     -e 's/.* PACKAGE_VERSION$/#define PACKAGE_VERSION "'$PACKAGE_VERSION'"/' \
 835     -e 's/.* PLUGINDIR$/#ifdef _DEBUG\n#  define PLUGINDIR PREFIX "\\\\debug\\\\lib\\\\gstreamer-1.0"\n#else\n#  define PLUGINDIR PREFIX "\\\\lib\\\\gstreamer-1.0"\n#endif/' \
 836     -e 's/.* GST_PLUGIN_SCANNER_INSTALLED$/#define GST_PLUGIN_SCANNER_INSTALLED LIBDIR "\\\\gst-plugin-scanner"/' \
 837     -e 's/.* VERSION$/#define VERSION "'$VERSION'"/' \
 838     config.h.in >win32/common/config.h-new
 839
 840 AC_OUTPUT
 841
 842 dnl negate for output
 843 if test "x${GST_DISABLE_GST_DEBUG}" = "xno"; then enable_gst_debug="yes"; fi
 844 if test "x${GST_DISABLE_PARSE}" = "xno"; then enable_parse="yes"; fi
 845 if test "x${GST_DISABLE_OPTION_PARSING}" = "xno"; then enable_option_parsing="yes"; fi
 846 if test "x${GST_DISABLE_TRACE}" = "xno"; then enable_trace="yes"; fi
 847 if test "x${GST_DISABLE_ALLOC_TRACE}" = "xno"; then enable_alloc_trace="yes"; fi
 848 if test "x${GST_DISABLE_PLUGIN}" = "xno"; then enable_plugin="yes"; fi
 849 if test "x${GST_DISABLE_REGISTRY}" = "xno"; then enable_registry="yes"; fi
 850
 851 echo "
 852
 853 Configuration
 854         Version                    : ${VERSION}
 855         Source code location       : ${srcdir}
 856         Prefix                     : ${prefix}
 857         Compiler                   : ${CC}
 858         Package name               : ${GST_PACKAGE_NAME}
 859         Package origin             : ${GST_PACKAGE_ORIGIN}
 860
 861         Documentation (manuals)    : ${enable_docbook}
 862         Documentation (API)        : ${enable_gtk_doc}
 863
 864         Debug Logging              : ${enable_gst_debug}
 865         Command-line parser        : ${enable_parse}
 866         Option parsing in gst_init : ${enable_option_parsing}
 867         Tracing subsystem          : ${enable_trace}
 868         Allocation tracing         : ${enable_alloc_trace}
 869         Plugin registry            : ${enable_registry}
 870         Plugin support             : ${enable_plugin}
 871         Unit testing support       : ${BUILD_CHECK}
 872
 873         Debug                      : ${USE_DEBUG}
 874         Profiling                  : ${USE_PROFILING}
 875
 876         Building benchmarks        : ${BUILD_BENCHMARKS}
 877         Building examples          : ${BUILD_EXAMPLES}
 878         Building test apps         : ${BUILD_TESTS}
 879         Building tests that fail   : ${BUILD_FAILING_TESTS}
 880         Building tools             : ${BUILD_TOOLS}
 881 "