configure.ac

   1 AC_PREREQ(2.60)
   2
   3 dnl initialize autoconf
   4 dnl when going to/from release please set the nano (fourth number) right !
   5 dnl releases only do Wall, git and prerelease does Werror too
   6 AC_INIT(GStreamer, 0.10.28.1,
   7     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
   8     gstreamer)
   9 AG_GST_INIT
  10
  11 dnl initialize automake (we require GNU make)
  12 AM_INIT_AUTOMAKE([-Wno-portability])
  13
  14 dnl define PACKAGE_VERSION_* variables
  15 AS_VERSION
  16
  17 dnl check if this is a release version
  18 AS_NANO(GST_GIT="no", GST_GIT="yes")
  19
  20 dnl can autoconf find the source ?
  21 AC_CONFIG_SRCDIR([gst/gst.c])
  22
  23 dnl define the output header for config
  24 AM_CONFIG_HEADER([config.h])
  25
  26 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  27 AM_MAINTAINER_MODE
  28
  29 dnl sets host_* variables
  30 AC_CANONICAL_HOST
  31
  32 dnl use pretty build output with automake >= 1.11
  33 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],
  34   [AM_DEFAULT_VERBOSITY=1
  35    AC_SUBST(AM_DEFAULT_VERBOSITY)])
  36
  37 dnl our libraries and install dirs use major.minor as a version
  38 GST_MAJORMINOR=$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR
  39 dnl we override it here for release candidates for a new series
  40 GST_MAJORMINOR=0.10
  41 AC_SUBST(GST_MAJORMINOR)
  42 AC_DEFINE_UNQUOTED(GST_MAJORMINOR, "$GST_MAJORMINOR",
  43   [library major.minor version])
  44
  45 dnl CURRENT, REVISION, AGE
  46 dnl - library source changed -> increment REVISION
  47 dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
  48 dnl - interfaces added -> increment AGE
  49 dnl - interfaces removed -> AGE = 0
  50 dnl sets GST_LT_LDFLAGS
  51 AS_LIBTOOL(GST, 24, 1, 24)
  52
  53 dnl FIXME: this macro doesn't actually work;
  54 dnl the generated libtool script has no support for the listed tags.
  55 dnl So this needs to be fixed first if we want to use this
  56 dnl AS_LIBTOOL_TAGS
  57
  58 AC_LIBTOOL_WIN32_DLL
  59 AM_PROG_LIBTOOL
  60
  61 dnl *** autotools stuff ****
  62
  63 dnl allow for different autotools
  64 AS_AUTOTOOLS_ALTERNATE
  65
  66 dnl Add parameters for aclocal (keep in sync with Makefile.am)
  67 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  68
  69 dnl set up gettext
  70 dnl the version check needs to stay here because autopoint greps for it
  71 AM_GNU_GETTEXT_VERSION([0.17])
  72 AM_GNU_GETTEXT([external])
  73 AG_GST_GETTEXT([gstreamer-$GST_MAJORMINOR])
  74
  75 dnl *** check for arguments to configure ***
  76
  77 dnl subsystems - can influence other decisions so needs to be high up
  78 dnl we need to AM_CONDITIONAL them here for automake 1.6.x compatibility
  79 AG_GST_CHECK_SUBSYSTEM_DISABLE(GST_DEBUG,[debugging subsystem])
  80 AM_CONDITIONAL(GST_DISABLE_GST_DEBUG, test "x$GST_DISABLE_GST_DEBUG" = "xyes")
  81 AG_GST_CHECK_SUBSYSTEM_DISABLE(LOADSAVE,[pipeline XML load/save])
  82 AM_CONDITIONAL(GST_DISABLE_LOADSAVE, test "x$GST_DISABLE_LOADSAVE" = "xyes")
  83 dnl define a substitution to use in docs/gst/gstreamer.types
  84 if test "x$GST_DISABLE_LOADSAVE" = "xyes"
  85 then
  86   GST_LOADSAVE_DOC_TYPES="%"
  87 else
  88   GST_LOADSAVE_DOC_TYPES=
  89 fi
  90 AC_SUBST(GST_LOADSAVE_DOC_TYPES)
  91 AG_GST_CHECK_SUBSYSTEM_DISABLE(PARSE,[command-line parser])
  92 AM_CONDITIONAL(GST_DISABLE_PARSE, test "x$GST_DISABLE_PARSE" = "xyes")
  93 if test "x$GST_DISABLE_PARSE" = xyes; then
  94   AC_DEFINE(GST_DISABLE_PARSE, 1,
  95     [Define if pipeline parsing code is disabled])
  96 fi
  97 AG_GST_CHECK_SUBSYSTEM_DISABLE(OPTION_PARSING,[option parsing when gst_init])
  98 AM_CONDITIONAL(GST_DISABLE_OPTION_PARSING, test "x$GST_DISABLE_OPTION_PARSING" = "xyes")
  99 if test "x$GST_DISABLE_OPTION_PARSING" = xyes; then
 100   AC_DEFINE(GST_DISABLE_OPTION_PARSING, 1,
 101     [Define if option parsing is disabled])
 102 fi
 103 AG_GST_CHECK_SUBSYSTEM_DISABLE(TRACE,[tracing subsystem])
 104 AM_CONDITIONAL(GST_DISABLE_TRACE, test "x$GST_DISABLE_TRACE" = "xyes")
 105 AG_GST_CHECK_SUBSYSTEM_DISABLE(ALLOC_TRACE,[allocation tracing])
 106 AM_CONDITIONAL(GST_DISABLE_ALLOC_TRACE, test "x$GST_DISABLE_ALLOC_TRACE" = "xyes")
 107 AG_GST_CHECK_SUBSYSTEM_DISABLE(REGISTRY,[plugin registry])
 108 AM_CONDITIONAL(GST_DISABLE_REGISTRY, test "x$GST_DISABLE_REGISTRY" = "xyes")
 109 dnl define a substitution to use in docs/gst/gstreamer.types
 110 if test "x$GST_DISABLE_REGISTRY" = "xyes"
 111 then
 112   GST_REGISTRY_DOC_TYPES="%"
 113 else
 114   GST_REGISTRY_DOC_TYPES=
 115 fi
 116 AC_SUBST(GST_REGISTRY_DOC_TYPES)
 117 AG_GST_CHECK_SUBSYSTEM_DISABLE(NET,[network distribution])
 118 AM_CONDITIONAL(GST_DISABLE_NET, test "x$GST_DISABLE_NET" = "xyes")
 119 AG_GST_CHECK_SUBSYSTEM_DISABLE(PLUGIN,[plugin])
 120 AM_CONDITIONAL(GST_DISABLE_PLUGIN, test "x$GST_DISABLE_PLUGIN" = "xyes")
 121
 122 AG_GST_ARG_DEBUG
 123 AG_GST_ARG_PROFILING
 124 AG_GST_ARG_VALGRIND
 125 AG_GST_ARG_GCOV
 126
 127 AG_GST_ARG_EXAMPLES
 128
 129 AG_GST_ARG_WITH_PKG_CONFIG_PATH
 130 AG_GST_ARG_WITH_PACKAGE_NAME
 131 AG_GST_ARG_WITH_PACKAGE_ORIGIN
 132
 133 dnl building of tests
 134 AC_ARG_ENABLE(tests,
 135   AC_HELP_STRING([--disable-tests], [disable building test apps]),
 136   [
 137     case "${enableval}" in
 138       yes) BUILD_TESTS=yes ;;
 139       no)  BUILD_TESTS=no ;;
 140       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-tests) ;;
 141     esac
 142   ],
 143 [BUILD_TESTS=yes]) dnl Default value
 144 AM_CONDITIONAL(BUILD_TESTS,         test "x$BUILD_TESTS" = "xyes")
 145
 146 dnl tests known to fail
 147 AC_ARG_ENABLE(failing-tests,
 148   AC_HELP_STRING([--disable-failing-tests],
 149     [disable building tests known to fail]),
 150   [
 151     case "${enableval}" in
 152       yes) BUILD_FAILING_TESTS=yes ;;
 153       no)  BUILD_FAILING_TESTS=no ;;
 154       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-failing-tests) ;;
 155     esac
 156   ],
 157   [BUILD_FAILING_TESTS=no]) dnl Default value
 158 AM_CONDITIONAL(BUILD_FAILING_TESTS, test "x$BUILD_FAILING_TESTS" = "xyes")
 159 if test x$BUILD_FAILING_TESTS = xyes; then
 160   AC_MSG_WARN([building tests known to fail, use --disable-failing-tests to disable])
 161 else
 162   AC_MSG_WARN([Sissy ! By asking to not build the tests known to fail, you hereby waive your right to customer support.  If you do not agree with this EULA, please press Ctrl-C before the next line is printed.  By allowing the next line to be printed, you expressly acknowledge your acceptance of this EULA.])
 163 fi
 164
 165 dnl poison destroyed objects
 166 AC_ARG_ENABLE(poisoning,
 167   AC_HELP_STRING([--enable-poisoning],
 168     [enable poisoning of deallocated objects]),
 169   [
 170     case "${enableval}" in
 171       yes) USE_POISONING=yes ;;
 172       no)  USE_POISONING=no ;;
 173       *)   AC_MSG_ERROR(bad value ${enableval} for --enable-poisoning) ;;
 174     esac
 175   ],
 176   [USE_POISONING=no]) dnl Default value
 177 if test "x$USE_POISONING" = xyes; then
 178   AC_DEFINE(USE_POISONING, 1,
 179     [Define if we should poison deallocated memory])
 180 fi
 181
 182 dnl *** checks for platform ***
 183
 184 dnl * hardware/architecture *
 185
 186 dnl common/m4/gst-arch.m4
 187 dnl check CPU type
 188 AG_GST_ARCH
 189 dnl substitution for win32/common/config.h
 190 HOST_CPU=$host_cpu
 191 AC_SUBST(HOST_CPU)
 192
 193 dnl common/m4/gst-arch.m4
 194 dnl check for unaligned access
 195 AG_GST_UNALIGNED_ACCESS
 196 dnl create a configure variable for gst/gstconfig.h
 197 if test x${as_cv_unaligned_access} = xyes ; then
 198   GST_HAVE_UNALIGNED_ACCESS_DEFINE="#define GST_HAVE_UNALIGNED_ACCESS 1"
 199 else
 200   GST_HAVE_UNALIGNED_ACCESS_DEFINE="#define GST_HAVE_UNALIGNED_ACCESS 0"
 201 fi
 202 AC_SUBST(GST_HAVE_UNALIGNED_ACCESS_DEFINE)
 203
 204 dnl check for platform specific settings
 205 AG_GST_PLATFORM
 206
 207 dnl * software *
 208
 209 dnl check for large file support
 210 dnl affected plugins must include config.h
 211 AC_SYS_LARGEFILE
 212
 213 dnl *** checks for programs ***
 214
 215 dnl find a compiler
 216 AC_PROG_CC
 217
 218 dnl check if the compiler supports '-c' and '-o' options
 219 AM_PROG_CC_C_O
 220
 221 dnl find an assembler
 222 AM_PROG_AS
 223
 224 dnl Perl is used in building documentation and in the version checks
 225 AC_PATH_PROG(PERL_PATH, perl, no)
 226 if test x$PERL_PATH = xno; then
 227   AC_MSG_ERROR(Could not find perl)
 228 fi
 229
 230 dnl we require flex and bison for building the parser
 231 if test "x$GST_DISABLE_PARSE" != xyes; then
 232   AG_GST_BISON_CHECK
 233   AG_GST_FLEX_CHECK
 234 fi
 235
 236 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 237 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 238
 239 dnl check for gobject-introspection
 240 GOBJECT_INTROSPECTION_CHECK([0.6.3])
 241
 242 dnl check for documentation tools
 243 AG_GST_DOCBOOK_CHECK
 244 GTK_DOC_CHECK([1.3])
 245 AS_PATH_PYTHON([2.1])
 246 AG_GST_PLUGIN_DOCS([1.3],[2.1])
 247
 248 dnl *** checks for libraries ***
 249
 250 dnl check for libm, for sin()
 251 AC_CHECK_LIBM
 252 AC_SUBST(LIBM)
 253
 254 dnl *** checks for header files ***
 255
 256 dnl check if we have ANSI C header files
 257 AC_HEADER_STDC
 258
 259 dnl Check for ucontext.h
 260 AC_CHECK_HEADERS([ucontext.h])
 261
 262 dnl Check for sys/socket.h
 263 AC_CHECK_HEADERS([sys/socket.h], HAVE_SYS_SOCKET_H=yes)
 264 AM_CONDITIONAL(HAVE_SYS_SOCKET_H, test "x$HAVE_SYS_SOCKET_H" = "xyes")
 265
 266 dnl check for sys/times.h for tests/examples/adapter/
 267 AC_CHECK_HEADERS([sys/times.h], HAVE_SYS_TIMES_H=yes)
 268 AC_CHECK_HEADERS([unistd.h], HAVE_UNISTD_H=yes)
 269 AM_CONDITIONAL(HAVE_SYS_TIMES_H_AND_UNISTD_H, test "x$HAVE_SYS_TIMES_H" = "xyes" -a "x$HAVE_UNISTD_H" = "xyes")
 270
 271 dnl Check for process.h for getpid() on win32
 272 AC_CHECK_HEADERS([process.h])
 273
 274 dnl Check for sys/utsname.h for uname
 275 AC_CHECK_HEADERS([sys/utsname.h])
 276
 277 dnl Check for stdio_ext.f for __fbufsize
 278 AC_CHECK_HEADERS([stdio_ext.h])
 279
 280 dnl check for pthreads
 281 AC_CHECK_HEADERS([pthread.h], HAVE_PTHREAD_H=yes)
 282 AM_CONDITIONAL(HAVE_PTHREAD_H, test "x$HAVE_PTHREAD_H" = "xyes")
 283
 284 dnl check for sys/prctl for setting thread name on Linux
 285 AC_CHECK_HEADERS([sys/prctl.h], HAVE_SYS_PRCTL_H=yes)
 286
 287 dnl Check for valgrind.h
 288 dnl separate from HAVE_VALGRIND because you can have the program, but not
 289 dnl the dev package
 290 AC_CHECK_HEADERS([valgrind/valgrind.h], HAVE_VALGRIND_H=yes)
 291
 292 dnl used in gst/gstpoll.c
 293 AC_CHECK_HEADERS([winsock2.h], HAVE_WINSOCK2_H=yes)
 294 AM_CONDITIONAL(HAVE_WINSOCK2_H, test "x$HAVE_WINSOCK2_H" = "xyes")
 295 if test "x$HAVE_WINSOCK2_H" = "xyes"; then
 296   WIN32_LIBS="-lws2_32"
 297   AC_SUBST(WIN32_LIBS)
 298 fi
 299
 300 dnl check for GMP/GSL, used by the gst_util_uint64_scale unit test only
 301 if test "x$BUILD_TESTS" = "xyes"; then
 302   AG_GST_CHECK_LIBHEADER(GMP, gmp,
 303                          __gmpz_init_set_d, ,
 304                          gmp.h,
 305                          GMP_LIBS="-lgmp"
 306                          AC_SUBST(GMP_LIBS)
 307                          AC_DEFINE(HAVE_GMP, [1],[Have GMP library]))
 308   AG_GST_CHECK_LIBHEADER(GSL, gsl,
 309                          gsl_rng_uniform_int, -lgslcblas,
 310                          gsl/gsl_rng.h,
 311                          GSL_LIBS="-lgsl -lgslcblas"
 312                          AC_SUBST(GSL_LIBS)
 313                          AC_DEFINE(HAVE_GSL, [1],[Have GSL library]))
 314 fi
 315
 316 dnl *** checks for types/defines ***
 317
 318 dnl *** checks for structures ***
 319
 320 dnl *** checks for compiler characteristics ***
 321
 322 dnl check if the compiler supports __uint128_t (gcc)
 323 dnl Actually check for 128-bit division, since that's what we use
 324 dnl uint128_t for.
 325 AC_CACHE_CHECK(for __uint128_t, gst_cv_uint128_t,
 326     AC_TRY_LINK([ ], [
 327       static __uint128_t v1 = 100;
 328       static __uint128_t v2 = 10;
 329       static __uint128_t u;
 330       u = v1 / v2;
 331       return 0;
 332     ], [
 333       gst_cv_uint128_t=yes
 334     ], [
 335       gst_cv_uint128_t=no
 336     ])
 337 )
 338 if test x$gst_cv_uint128_t = xyes; then
 339   AC_DEFINE(HAVE_UINT128_T, 1, [Have __uint128_t type])
 340 fi
 341
 342 dnl *** checks for library functions ***
 343
 344 AC_CHECK_FUNCS([sigaction])
 345
 346 dnl check for fseeko()
 347 AC_FUNC_FSEEKO
 348 dnl check for ftello()
 349 AC_CHECK_FUNCS([ftello])
 350
 351 AC_CHECK_FUNCS([fgetpos])
 352 AC_CHECK_FUNCS([fsetpos])
 353
 354 dnl check for poll(), ppoll() and pselect()
 355 AC_CHECK_FUNCS([poll])
 356 AC_CHECK_FUNCS([ppoll])
 357 AC_CHECK_FUNCS([pselect])
 358
 359 dnl ****************************************
 360 dnl *** GLib POLL* compatibility defines ***
 361 dnl ****************************************
 362
 363 AC_MSG_CHECKING([for broken poll])
 364 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 365         #include <stdlib.h>
 366         #include <fcntl.h>
 367         #include <poll.h>
 368         #ifdef HAVE_SYS_POLL_H
 369         #include <sys/poll.h>
 370         #endif
 371         int main(void) {
 372           struct pollfd fds[1];
 373           int fd;
 374           fd = open("/dev/null", 1);
 375           fds[0].fd = fd;
 376           fds[0].events = POLLIN;
 377           fds[0].revents = 0;
 378           if (poll(fds, 1, 0) < 0 || (fds[0].revents & POLLNVAL) != 0) {
 379                 exit(1);  /* Does not work for devices -- fail */
 380           }
 381           exit(0);
 382         }]])],
 383   [broken_poll=no],
 384   [broken_poll=yes
 385    AC_DEFINE(BROKEN_POLL,1,[poll doesn't work on devices])],
 386   [broken_poll="no (cross compiling)"])
 387 AC_MSG_RESULT($broken_poll)
 388
 389 dnl check for mmap()
 390 AC_FUNC_MMAP
 391 AM_CONDITIONAL(HAVE_MMAP, test "x$ac_cv_func_mmap_fixed_mapped" = "xyes")
 392
 393 dnl check for posix_memalign(), getpagesize()
 394 AC_CHECK_FUNCS([posix_memalign])
 395 AC_CHECK_FUNCS([getpagesize])
 396
 397 dnl Check for POSIX timers
 398 AC_CHECK_FUNCS(clock_gettime, [], [
 399   AC_CHECK_LIB(rt, clock_gettime, [
 400     AC_DEFINE(HAVE_CLOCK_GETTIME, 1)
 401     LIBS="$LIBS -lrt"
 402   ])
 403 ])
 404
 405 AC_CACHE_CHECK(for posix timers, gst_cv_posix_timers,
 406     AC_TRY_COMPILE([
 407 #include <time.h>
 408 #ifdef HAVE_UNISTD_H
 409 #include <unistd.h>
 410 #endif
 411     ], [
 412 #if !defined(_POSIX_TIMERS) || _POSIX_TIMERS < 0 || !defined(CLOCK_REALTIME)
 413 #error Either _POSIX_TIMERS or CLOCK_REALTIME not defined
 414 #endif
 415       return 0;
 416     ], [
 417       gst_cv_posix_timers=yes
 418     ], [
 419       gst_cv_posix_timers=no
 420     ])
 421 )
 422
 423 if test "$gst_cv_posix_timers" = "yes"; then
 424   AC_DEFINE(HAVE_POSIX_TIMERS,1,[Have posix timers])
 425   GST_HAVE_POSIX_TIMERS_DEFINE="#define GST_HAVE_POSIX_TIMERS 1"
 426 else
 427   GST_HAVE_POSIX_TIMERS_DEFINE="#define GST_HAVE_POSIX_TIMERS 0"
 428 fi
 429 AC_SUBST(GST_HAVE_POSIX_TIMERS_DEFINE)
 430 AM_CONDITIONAL(GST_HAVE_POSIX_TIMERS, test "$gst_cv_posix_timers" = "yes")
 431
 432 AC_CACHE_CHECK(for monotonic clock, gst_cv_monotonic_clock,
 433     AC_TRY_COMPILE([
 434 #include <time.h>
 435 #ifdef HAVE_UNISTD_H
 436 #include <unistd.h>
 437 #endif
 438     ], [
 439 #if !defined(_POSIX_MONOTONIC_CLOCK) || _POSIX_MONOTONIC_CLOCK < 0 || !defined(CLOCK_MONOTONIC)
 440 #error Either _POSIX_MONOTONIC_CLOCK or CLOCK_MONOTONIC not defined
 441 #endif
 442       return 0;
 443     ], [
 444       gst_cv_monotonic_clock=yes
 445     ], [
 446       gst_cv_monotonic_clock=no
 447     ])
 448 )
 449
 450 if test "$gst_cv_monotonic_clock" = "yes"; then
 451   AC_DEFINE(HAVE_MONOTONIC_CLOCK,1,[Have a monotonic clock])
 452   GST_HAVE_MONOTONIC_CLOCK_DEFINE="#define GST_HAVE_MONOTONIC_CLOCK 1"
 453 else
 454   GST_HAVE_MONOTONIC_CLOCK_DEFINE="#define GST_HAVE_MONOTONIC_CLOCK 0"
 455 fi
 456 AC_SUBST(GST_HAVE_MONOTONIC_CLOCK_DEFINE)
 457 AM_CONDITIONAL(GST_HAVE_MONOTONIC_CLOCK, test "$gst_cv_monotonic_clock" = "yes")
 458
 459 dnl Check for a way to display the function name in debug output
 460 AG_GST_CHECK_FUNCTION
 461
 462 dnl test for register_printf_specifier or register_printf_function
 463 AC_CHECK_FUNCS([register_printf_specifier register_printf_function],
 464     [HAVE_PRINTF_EXTENSION=yes])
 465
 466 if test "$HAVE_PRINTF_EXTENSION" = yes; then
 467   GST_PRINTF_EXTENSION_POINTER_FORMAT_DEFINE="#define GST_PTR_FORMAT \"P\""
 468   GST_PRINTF_EXTENSION_SEGMENT_FORMAT_DEFINE="#define GST_SEGMENT_FORMAT \"Q\""
 469   GST_USING_PRINTF_EXTENSION_DEFINE="#define GST_USING_PRINTF_EXTENSION"
 470   AC_DEFINE(HAVE_PRINTF_EXTENSION, 1,
 471       [Defined if we have printf specifier extensions available])
 472 else
 473     GST_PRINTF_EXTENSION_POINTER_FORMAT_DEFINE="#define GST_PTR_FORMAT \"p\""
 474     GST_PRINTF_EXTENSION_SEGMENT_FORMAT_DEFINE="#define GST_SEGMENT_FORMAT \"p\""
 475     GST_USING_PRINTF_EXTENSION_DEFINE="#undef GST_USING_PRINTF_EXTENSION"
 476 fi
 477 AC_SUBST(GST_PRINTF_EXTENSION_POINTER_FORMAT_DEFINE)
 478 AC_SUBST(GST_PRINTF_EXTENSION_SEGMENT_FORMAT_DEFINE)
 479 AC_SUBST(GST_USING_PRINTF_EXTENSION_DEFINE)
 480
 481 dnl test if we have dladdr(); we use it for debugging; see gst/gstinfo.c
 482 save_cflags="$CFLAGS"
 483 CFLAGS="$CFLAGS -D_GNU_SOURCE"
 484 AC_CHECK_LIB(dl, dladdr,
 485    AC_DEFINE(HAVE_DLADDR, 1, [Defined if we have dladdr ()])
 486    LIBS="$LIBS -ldl")
 487 CFLAGS="$save_cflags"
 488
 489 dnl *** checks for socket and nsl libraries ***
 490 AC_CHECK_FUNC(socket,,[AC_CHECK_LIB(socket,socket)])
 491 AC_CHECK_FUNC(gethostbyname,,[AC_CHECK_LIB(nsl,gethostbyname)])
 492
 493 dnl check for inet_aton()
 494 save_libs="$LIBS"
 495 AC_CHECK_FUNC(inet_aton, ,
 496    AC_CHECK_LIB(nsl, inet_aton, ,
 497       AC_CHECK_LIB(socket, inet_aton, ,
 498          AC_CHECK_LIB(resolv, inet_aton, ,[AC_DEFINE(NO_INET_ATON, 1, [Define if you have no native inet_aton() function.])]))))
 499 INET_ATON_LIBS=$LIBS
 500 AC_SUBST(INET_ATON_LIBS)
 501 LIBS="$save_libs"
 502
 503 dnl *** checks for dependency libraries ***
 504
 505 dnl GLib
 506 GLIB_REQ=2.18
 507
 508 AG_GST_GLIB_CHECK([$GLIB_REQ])
 509
 510 dnl FIXME: 0.11: Guess we need to keep this around until 0.11
 511 GST_HAVE_GLIB_2_8_DEFINE="#define GST_HAVE_GLIB_2_8 1"
 512 AC_SUBST(GST_HAVE_GLIB_2_8_DEFINE)
 513
 514 dnl Check for glib2 without extra fat, useful for the unversioned tool frontends
 515 PKG_CHECK_MODULES(GLIB_ONLY, glib-2.0 >= $GLIB_REQ)
 516
 517 dnl Check for documentation xrefs
 518 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 519 AC_SUBST(GLIB_PREFIX)
 520
 521 dnl libxml2 is only needed for xml loading/saving of pipelines these days
 522 if test "x$GST_DISABLE_LOADSAVE" = "xyes"
 523 then
 524   AC_MSG_NOTICE([XML registry and load/save are disabled, not checking for libxml2])
 525   GST_DISABLE_XML_DEFINE="#define GST_DISABLE_XML 1"
 526 else
 527   dnl check for libxml2 with minimum req version
 528   AG_GST_LIBXML2_CHECK(2.4.9)
 529   GST_DISABLE_XML_DEFINE="/* #undef GST_DISABLE_XML */"
 530 fi
 531 AC_SUBST(GST_DISABLE_XML_DEFINE)
 532
 533 dnl building of unit test libraries
 534 AC_ARG_ENABLE(check,
 535   AC_HELP_STRING([--disable-check], [disable building unit test libraries]),
 536   [
 537     case "${enableval}" in
 538       yes) BUILD_CHECK=yes ;;
 539       no)  BUILD_CHECK=no ;;
 540       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-check) ;;
 541     esac
 542   ], [
 543     dnl Default value
 544     case $host_os in
 545       mingw* | msvc* | mks*) BUILD_CHECK=no ;;
 546       *) BUILD_CHECK=yes ;;
 547     esac
 548 ])
 549 dnl bit of a misnomer, but keep the conditional named like this so we don't
 550 dnl have to change too much elsewhere
 551 AM_CONDITIONAL(HAVE_CHECK, test "x$BUILD_CHECK" = "xyes")
 552
 553 dnl configure the desired buffer alignment
 554 AC_ARG_WITH([buffer-alignment],
 555   AS_HELP_STRING([--with-buffer-alignment],[8,N,malloc,pagesize (default is 32)]),
 556   [
 557     if test "x$withval" = "xyes"
 558     then
 559       AC_DEFINE(BUFFER_ALIGNMENT, 32, [Buffer alignment to use])
 560     else
 561       case "${withval}" in
 562         malloc) AC_DEFINE(BUFFER_ALIGNMENT_MALLOC, 1, [Buffer alignment by malloc default]) ;;
 563         pagesize)  AC_DEFINE(BUFFER_ALIGNMENT_PAGESIZE, 1, [Buffer alignment by pagesize]) ;;
 564         *)   AC_DEFINE_UNQUOTED(BUFFER_ALIGNMENT, ${withval}, [Buffer alignment to use]) ;;
 565       esac
 566     fi
 567   ], [
 568     AC_DEFINE(BUFFER_ALIGNMENT_MALLOC, 1, [Buffer alignment by malloc default])
 569   ]
 570 )
 571
 572 dnl *** set variables based on configure arguments
 573
 574 dnl set license and copyright notice
 575 GST_LICENSE="LGPL"
 576 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 577 AC_SUBST(GST_LICENSE)
 578
 579 dnl define LIBDIR, GST_DATADIR so we can inform people where we live
 580 AS_AC_EXPAND(LIBDIR, $libdir)
 581 AC_DEFINE_UNQUOTED(LIBDIR, "$LIBDIR", [library dir])
 582 AS_AC_EXPAND(DATADIR, $datadir)
 583 AC_DEFINE_UNQUOTED(GST_DATADIR, "$DATADIR", [data dir])
 584
 585 dnl set location of plugin directory
 586 AG_GST_SET_PLUGINDIR
 587
 588 dnl FIXME: add LIBXML_PKG here if we use it
 589 GST_PKG_DEPS="glib-2.0, gobject-2.0, gmodule-no-export-2.0, gthread-2.0"
 590 AC_SUBST(GST_PKG_DEPS)
 591
 592 dnl define an ERROR_CFLAGS Makefile variable
 593 AG_GST_SET_ERROR_CFLAGS($GST_GIT, [-Wmissing-declarations -Wmissing-prototypes -Wredundant-decls -Wundef -Wwrite-strings -Wformat-nonliteral -Wformat-security -Wold-style-definition -Wcast-align -Winit-self -Wmissing-include-dirs -Waddress -Waggregate-return -Wno-multichar -Wnested-externs])
 594
 595 dnl define correct level for debugging messages
 596 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 597
 598 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 599
 600 dnl Overview:
 601 dnl GST_OPTION_CFLAGS:  common cflags for profiling, debugging, errors, ...
 602 dnl GST_ALL_*:          vars shared by all built objects
 603 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 604 dnl GST_OBJ_*:          additional vars to link to the core library
 605 dnl                     include GST_ALL_*
 606 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 607 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 608
 609 dnl GST_OPTION_CFLAGS
 610 if test "x$USE_DEBUG" = xyes; then
 611    PROFILE_CFLAGS="-g"
 612 fi
 613 AC_SUBST(PROFILE_CFLAGS)
 614
 615 # GST_DISABLE_DEPRECATED: hide the visibility of deprecated
 616 # functionality from the API that gstreamer uses
 617 # GST_REMOVE_DEPRECATED: don't compile deprecated functionality (breaks ABI)
 618 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
 619   dnl Define _only_ when compiling from git (not for pre-releases or releases)
 620   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 621 else
 622   DEPRECATED_CFLAGS=""
 623 fi
 624 AC_SUBST(DEPRECATED_CFLAGS)
 625
 626 dnl every flag in GST_OPTION_CFLAGS can be overridden at make time via e.g.
 627 dnl make DEPRECATED_CFLAGS=''
 628 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 629 AC_SUBST(GST_OPTION_CFLAGS)
 630
 631 dnl GST_ALL_*
 632 dnl vars common to for all internal objects (core libs, elements, applications)
 633 dnl CFLAGS:
 634 dnl - XML needs to be added because xmlPtr is used in core
 635 dnl - src and build dirs need to be added because every piece that gets built
 636 dnl   will need the GStreamer source and generated headers
 637 dnl LIBS: XML doesn't need to be added because we don't explicitly use symbols
 638 dnl       from LibXML except for in the core library
 639 GST_ALL_CFLAGS="-I\$(top_srcdir)/libs -I\$(top_srcdir) -I\$(top_builddir)/libs -I\$(top_builddir) $GLIB_CFLAGS $XML_CFLAGS \$(GST_OPTION_CFLAGS) \$(ERROR_CFLAGS) -DG_THREADS_MANDATORY"
 640
 641 dnl FIXME: check if LTLIBINTL is needed everywhere
 642 dnl I presume it is given that it contains the symbols that _() stuff maps to
 643 GST_ALL_LIBS="$GLIB_LIBS $LTLIBINTL \$(GCOV_LIBS)"
 644
 645 dnl LDFLAGS really should only contain flags, not libs - they get added before
 646 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 647 GST_ALL_LDFLAGS="-no-undefined"
 648
 649 AC_SUBST(GST_ALL_CFLAGS)
 650 AC_SUBST(GST_ALL_LIBS)
 651 AC_SUBST(GST_ALL_LDFLAGS)
 652
 653 dnl GST_LIB_LDFLAGS
 654 dnl linker flags shared by all libraries
 655 dnl LDFLAGS modifier defining exported symbols from built libraries
 656 GST_LIB_LDFLAGS="-export-symbols-regex \^[_]*\(gst_\|Gst\|GST_\).*"
 657 AC_SUBST(GST_LIB_LDFLAGS)
 658
 659 dnl GST_OBJ_*
 660 dnl default vars for all internal objects built on libgstreamer
 661 dnl includes GST_ALL_*
 662 GST_OBJ_CFLAGS="\$(GST_ALL_CFLAGS)"
 663 GST_OBJ_LIBS="\$(top_builddir)/gst/libgstreamer-$GST_MAJORMINOR.la \$(GST_ALL_LIBS)"
 664 AC_SUBST(GST_OBJ_CFLAGS)
 665 AC_SUBST(GST_OBJ_LIBS)
 666
 667 dnl GST_PLUGIN_LDFLAGS
 668 dnl LDFLAGS for plugins; includes GST_ALL_LDFLAGS
 669 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc\$\$' $GST_ALL_LDFLAGS"
 670 AC_SUBST(GST_PLUGIN_LDFLAGS, "$GST_PLUGIN_LDFLAGS")
 671
 672 dnl plugin scanner locations
 673 AS_AC_EXPAND(GST_PLUGIN_SCANNER_INSTALLED,${libexecdir}/gstreamer-$GST_MAJORMINOR/gst-plugin-scanner)
 674 AC_DEFINE_UNQUOTED(GST_PLUGIN_SCANNER_INSTALLED,
 675     "$GST_PLUGIN_SCANNER_INSTALLED", [location of the installed gst-plugin-scanner])
 676 AC_SUBST(GST_PLUGIN_SCANNER_INSTALLED)
 677
 678 dnl things for our internal libcheck (must be called even if building
 679 dnl libcheck is disabled because it defines conditionals)
 680 AG_GST_CHECK_CHECKS()
 681
 682 AC_CONFIG_FILES(
 683 Makefile
 684 gst/Makefile
 685 gst/gstconfig.h
 686 gst/gstversion.h
 687 gst/parse/Makefile
 688 libs/Makefile
 689 libs/gst/Makefile
 690 libs/gst/base/Makefile
 691 libs/gst/check/Makefile
 692 libs/gst/check/libcheck/Makefile
 693 libs/gst/check/libcheck/check.h
 694 libs/gst/controller/Makefile
 695 libs/gst/dataprotocol/Makefile
 696 libs/gst/helpers/Makefile
 697 libs/gst/net/Makefile
 698 plugins/Makefile
 699 plugins/indexers/Makefile
 700 plugins/elements/Makefile
 701 po/Makefile.in
 702 tests/Makefile
 703 tests/benchmarks/Makefile
 704 tests/check/Makefile
 705 tests/misc/Makefile
 706 tests/examples/Makefile
 707 tests/examples/adapter/Makefile
 708 tests/examples/controller/Makefile
 709 tests/examples/stepping/Makefile
 710 tests/examples/helloworld/Makefile
 711 tests/examples/launch/Makefile
 712 tests/examples/manual/Makefile
 713 tests/examples/metadata/Makefile
 714 tests/examples/queue/Makefile
 715 tests/examples/streams/Makefile
 716 tests/examples/typefind/Makefile
 717 tests/examples/xml/Makefile
 718 tools/Makefile
 719 common/Makefile
 720 common/m4/Makefile
 721 docs/Makefile
 722 docs/design/Makefile
 723 docs/faq/Makefile
 724 docs/gst/Makefile
 725 docs/gst/gstreamer.types
 726 docs/libs/Makefile
 727 docs/plugins/Makefile
 728 docs/manual/Makefile
 729 docs/pwg/Makefile
 730 docs/slides/Makefile
 731 docs/xsl/Makefile
 732 docs/version.entities
 733 m4/Makefile
 734 pkgconfig/Makefile
 735 stamp.h
 736 pkgconfig/gstreamer.pc
 737 pkgconfig/gstreamer-uninstalled.pc
 738 pkgconfig/gstreamer-base.pc
 739 pkgconfig/gstreamer-base-uninstalled.pc
 740 pkgconfig/gstreamer-check.pc
 741 pkgconfig/gstreamer-check-uninstalled.pc
 742 pkgconfig/gstreamer-controller.pc
 743 pkgconfig/gstreamer-controller-uninstalled.pc
 744 pkgconfig/gstreamer-dataprotocol.pc
 745 pkgconfig/gstreamer-dataprotocol-uninstalled.pc
 746 pkgconfig/gstreamer-net.pc
 747 pkgconfig/gstreamer-net-uninstalled.pc
 748 gst-element-check.m4
 749 gstreamer.spec
 750 )
 751
 752 dnl Create the config.h file for Visual Studio builds
 753 dnl Beware of spaces and /'s in some of the shell variable contents.
 754 sed \
 755     -e 's/.*config.h.in.*autoheader.*/\/* Autogenerated config.h created for win32 Visual Studio builds *\/\n\n\/* PREFIX -- specifically added for Windows for easier moving *\/\n#define PREFIX "C:\\\\gstreamer"/' \
 756     -e 's/.* GETTEXT_PACKAGE$/#define GETTEXT_PACKAGE "'$GETTEXT_PACKAGE'"/' \
 757     -e 's/.* GST_DATADIR$/#define GST_DATADIR PREFIX "\\\\share"/' \
 758     -e 's/.* GST_LEVEL_DEFAULT$/#define GST_LEVEL_DEFAULT GST_LEVEL_ERROR/' \
 759     -e 's/.* GST_LICENSE$/#define GST_LICENSE "'$GST_LICENSE'"/' \
 760     -e 's/.* GST_MAJORMINOR$/#define GST_MAJORMINOR "'$GST_MAJORMINOR'"/' \
 761     -e "s,.* GST_PACKAGE_NAME$,#define GST_PACKAGE_NAME \"${GST_PACKAGE_NAME}\"," \
 762     -e 's/.* GST_PACKAGE_ORIGIN$/#define GST_PACKAGE_ORIGIN "Unknown package origin"/' \
 763     -e 's/.* HAVE_CPU_I386$/#define HAVE_CPU_I386 1/' \
 764     -e 's/.* HAVE_FGETPOS$/#define HAVE_FGETPOS 1/' \
 765     -e 's/.* HAVE_FSETPOS$/#define HAVE_FSETPOS 1/' \
 766     -e 's/.* HAVE_LIBXML2$/#define HAVE_LIBXML2 1/' \
 767     -e 's/.* HAVE_PROCESS_H$/#define HAVE_PROCESS_H 1/' \
 768     -e 's/.* HAVE_STDLIB_H$/#define HAVE_STDLIB_H 1/' \
 769     -e 's/.* HAVE_STRING_H$/#define HAVE_STRING_H 1/' \
 770     -e 's/.* HAVE_SYS_STAT_H$/#define HAVE_SYS_STAT_H 1/' \
 771     -e 's/.* HAVE_SYS_TYPES_H$/#define HAVE_SYS_TYPES_H 1/' \
 772     -e 's/.* HAVE_WIN32$/#define HAVE_WIN32 1/' \
 773     -e 's/.* HAVE_WINSOCK2_H$/#define HAVE_WINSOCK2_H 1/' \
 774     -e 's/.* HOST_CPU$/#define HOST_CPU "i686"/' \
 775     -e 's/.* LIBDIR$/#ifdef _DEBUG\n#  define LIBDIR PREFIX "\\\\debug\\\\lib"\n#else\n#  define LIBDIR PREFIX "\\\\lib"\n#endif/' \
 776     -e 's/.* LOCALEDIR$/#define LOCALEDIR PREFIX "\\\\share\\\\locale"/' \
 777     -e 's/.* PACKAGE$/#define PACKAGE "gstreamer"/' \
 778     -e 's/.* PACKAGE_BUGREPORT$/#define PACKAGE_BUGREPORT "http:\/\/bugzilla.gnome.org\/enter_bug.cgi?product=GStreamer"/' \
 779     -e 's/.* PACKAGE_NAME$/#define PACKAGE_NAME "'$PACKAGE_NAME'"/' \
 780     -e "s/.* PACKAGE_STRING$/#define PACKAGE_STRING \"$PACKAGE_STRING\"/" \
 781     -e 's/.* PACKAGE_TARNAME$/#define PACKAGE_TARNAME "'$PACKAGE_TARNAME'"/' \
 782     -e 's/.* PACKAGE_VERSION$/#define PACKAGE_VERSION "'$PACKAGE_VERSION'"/' \
 783     -e 's/.* PLUGINDIR$/#ifdef _DEBUG\n#  define PLUGINDIR PREFIX "\\\\debug\\\\lib\\\\gstreamer-0.10"\n#else\n#  define PLUGINDIR PREFIX "\\\\lib\\\\gstreamer-0.10"\n#endif/' \
 784     -e 's/.* GST_PLUGIN_SCANNER_INSTALLED$/#define GST_PLUGIN_SCANNER_INSTALLED LIBDIR "\\\\gst-plugin-scanner"/' \
 785     -e 's/.* VERSION$/#define VERSION "'$VERSION'"/' \
 786     config.h.in >win32/common/config.h-new
 787
 788 AC_OUTPUT
 789
 790 dnl negate for output
 791 if test "x${GST_DISABLE_GST_DEBUG}" = "xno"; then enable_gst_debug="yes"; fi
 792 if test "x${GST_DISABLE_LOADSAVE}" = "xno"; then enable_loadsave="yes"; fi
 793 if test "x${GST_DISABLE_PARSE}" = "xno"; then enable_parse="yes"; fi
 794 if test "x${GST_DISABLE_OPTION_PARSING}" = "xno"; then enable_option_parsing="yes"; fi
 795 if test "x${GST_DISABLE_TRACE}" = "xno"; then enable_trace="yes"; fi
 796 if test "x${GST_DISABLE_ALLOC_TRACE}" = "xno"; then enable_alloc_trace="yes"; fi
 797 if test "x${GST_DISABLE_PLUGIN}" = "xno"; then enable_plugin="yes"; fi
 798 if test "x${GST_DISABLE_REGISTRY}" = "xno"; then enable_registry="yes"; fi
 799 if test "x${GST_DISABLE_NET}" = "xno"; then enable_net="yes"; fi
 800
 801 echo "
 802
 803 Configuration
 804         Version                    : ${VERSION}
 805         Source code location       : ${srcdir}
 806         Prefix                     : ${prefix}
 807         Compiler                   : ${CC}
 808         Package name               : ${GST_PACKAGE_NAME}
 809         Package origin             : ${GST_PACKAGE_ORIGIN}
 810
 811         Documentation (manuals)    : ${enable_docbook}
 812         Documentation (API)        : ${enable_gtk_doc}
 813
 814         Debug Logging              : ${enable_gst_debug}
 815         Pipeline XML load/save     : ${enable_loadsave}
 816         Command-line parser        : ${enable_parse}
 817         Option parsing in gst_init : ${enable_option_parsing}
 818         Tracing subsystem          : ${enable_trace}
 819         Allocation tracing         : ${enable_alloc_trace}
 820         Plugin registry            : ${enable_registry}
 821         Plugin support             : ${enable_plugin}
 822         Network support            : ${enable_net}
 823         Unit testing support       : ${BUILD_CHECK}
 824
 825         Debug                      : ${USE_DEBUG}
 826         Profiling                  : ${USE_PROFILING}
 827
 828         Building examples          : ${BUILD_EXAMPLES}
 829         Building test apps         : ${BUILD_TESTS}
 830         Building tests that fail   : ${BUILD_FAILING_TESTS}
 831 "