configure.ac

   1 AC_PREREQ(2.60)
   2
   3 dnl initialize autoconf
   4 dnl when going to/from release please set the nano (fourth number) right !
   5 dnl releases only do Wall, git and prerelease does Werror too
   6 AC_INIT(GStreamer, 0.11.1.1,
   7     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
   8     gstreamer)
   9 AG_GST_INIT
  10
  11 dnl initialize automake (we require GNU make)
  12 AM_INIT_AUTOMAKE([-Wno-portability 1.10])
  13
  14 dnl define PACKAGE_VERSION_* variables
  15 AS_VERSION
  16
  17 dnl check if this is a release version
  18 AS_NANO(GST_GIT="no", GST_GIT="yes")
  19
  20 dnl can autoconf find the source ?
  21 AC_CONFIG_SRCDIR([gst/gst.c])
  22
  23 dnl define the output header for config
  24 AM_CONFIG_HEADER([config.h])
  25
  26 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  27 AM_MAINTAINER_MODE
  28
  29 dnl sets host_* variables
  30 AC_CANONICAL_HOST
  31
  32 dnl use pretty build output with automake >= 1.11
  33 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],
  34   [AM_DEFAULT_VERBOSITY=1
  35    AC_SUBST(AM_DEFAULT_VERBOSITY)])
  36
  37 dnl our libraries and install dirs use major.minor as a version
  38 GST_MAJORMINOR=$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR
  39 dnl we override it here for release candidates for a new series
  40 GST_MAJORMINOR=0.11
  41 AC_SUBST(GST_MAJORMINOR)
  42 AC_DEFINE_UNQUOTED(GST_MAJORMINOR, "$GST_MAJORMINOR",
  43   [library major.minor version])
  44
  45 dnl CURRENT, REVISION, AGE
  46 dnl - library source changed -> increment REVISION
  47 dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
  48 dnl - interfaces added -> increment AGE
  49 dnl - interfaces removed -> AGE = 0
  50 dnl sets GST_LT_LDFLAGS
  51 AS_LIBTOOL(GST, 31, 0, 0)
  52
  53 dnl FIXME: this macro doesn't actually work;
  54 dnl the generated libtool script has no support for the listed tags.
  55 dnl So this needs to be fixed first if we want to use this
  56 dnl AS_LIBTOOL_TAGS
  57
  58 AC_LIBTOOL_WIN32_DLL
  59 AM_PROG_LIBTOOL
  60
  61 dnl *** autotools stuff ****
  62
  63 dnl allow for different autotools
  64 AS_AUTOTOOLS_ALTERNATE
  65
  66 dnl Add parameters for aclocal (keep in sync with Makefile.am)
  67 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  68
  69 dnl set up gettext
  70 dnl the version check needs to stay here because autopoint greps for it
  71 AM_GNU_GETTEXT_VERSION([0.17])
  72 AM_GNU_GETTEXT([external])
  73 AG_GST_GETTEXT([gstreamer-$GST_MAJORMINOR])
  74
  75 dnl *** check for arguments to configure ***
  76
  77 dnl subsystems - can influence other decisions so needs to be high up
  78 dnl we need to AM_CONDITIONAL them here for automake 1.6.x compatibility
  79 AG_GST_CHECK_SUBSYSTEM_DISABLE(GST_DEBUG,[debugging subsystem])
  80 AM_CONDITIONAL(GST_DISABLE_GST_DEBUG, test "x$GST_DISABLE_GST_DEBUG" = "xyes")
  81 AG_GST_CHECK_SUBSYSTEM_DISABLE(PARSE,[command-line parser])
  82 AM_CONDITIONAL(GST_DISABLE_PARSE, test "x$GST_DISABLE_PARSE" = "xyes")
  83 if test "x$GST_DISABLE_PARSE" = xyes; then
  84   AC_DEFINE(GST_DISABLE_PARSE, 1,
  85     [Define if pipeline parsing code is disabled])
  86 fi
  87 AG_GST_CHECK_SUBSYSTEM_DISABLE(OPTION_PARSING,[option parsing when gst_init])
  88 AM_CONDITIONAL(GST_DISABLE_OPTION_PARSING, test "x$GST_DISABLE_OPTION_PARSING" = "xyes")
  89 if test "x$GST_DISABLE_OPTION_PARSING" = xyes; then
  90   AC_DEFINE(GST_DISABLE_OPTION_PARSING, 1,
  91     [Define if option parsing is disabled])
  92 fi
  93 AG_GST_CHECK_SUBSYSTEM_DISABLE(TRACE,[tracing subsystem])
  94 AM_CONDITIONAL(GST_DISABLE_TRACE, test "x$GST_DISABLE_TRACE" = "xyes")
  95 AG_GST_CHECK_SUBSYSTEM_DISABLE(ALLOC_TRACE,[allocation tracing])
  96 AM_CONDITIONAL(GST_DISABLE_ALLOC_TRACE, test "x$GST_DISABLE_ALLOC_TRACE" = "xyes")
  97 AG_GST_CHECK_SUBSYSTEM_DISABLE(REGISTRY,[plugin registry])
  98 AM_CONDITIONAL(GST_DISABLE_REGISTRY, test "x$GST_DISABLE_REGISTRY" = "xyes")
  99 dnl define a substitution to use in docs/gst/gstreamer.types
 100 if test "x$GST_DISABLE_REGISTRY" = "xyes"
 101 then
 102   GST_REGISTRY_DOC_TYPES="%"
 103 else
 104   GST_REGISTRY_DOC_TYPES=
 105 fi
 106 AC_SUBST(GST_REGISTRY_DOC_TYPES)
 107 AG_GST_CHECK_SUBSYSTEM_DISABLE(PLUGIN,[plugin])
 108 AM_CONDITIONAL(GST_DISABLE_PLUGIN, test "x$GST_DISABLE_PLUGIN" = "xyes")
 109
 110 AG_GST_ARG_DEBUG
 111 AG_GST_ARG_PROFILING
 112 AG_GST_ARG_VALGRIND
 113 AG_GST_ARG_GCOV
 114
 115 AG_GST_ARG_EXAMPLES
 116
 117 AG_GST_ARG_WITH_PKG_CONFIG_PATH
 118 AG_GST_ARG_WITH_PACKAGE_NAME
 119 AG_GST_ARG_WITH_PACKAGE_ORIGIN
 120
 121 AG_GST_PKG_CONFIG_PATH
 122
 123 AG_GST_SET_PACKAGE_RELEASE_DATETIME_WITH_NANO([$PACKAGE_VERSION_NANO],
 124   ["${srcdir}/gstreamer.doap"],
 125   [$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_MICRO])
 126
 127 dnl building of tests
 128 AC_ARG_ENABLE(tests,
 129   AC_HELP_STRING([--disable-tests], [disable building test apps]),
 130   [
 131     case "${enableval}" in
 132       yes) BUILD_TESTS=yes ;;
 133       no)  BUILD_TESTS=no ;;
 134       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-tests) ;;
 135     esac
 136   ],
 137 [BUILD_TESTS=yes]) dnl Default value
 138 AM_CONDITIONAL(BUILD_TESTS,         test "x$BUILD_TESTS" = "xyes")
 139
 140 dnl tests known to fail
 141 AC_ARG_ENABLE(failing-tests,
 142   AC_HELP_STRING([--disable-failing-tests],
 143     [disable building tests known to fail]),
 144   [
 145     case "${enableval}" in
 146       yes) BUILD_FAILING_TESTS=yes ;;
 147       no)  BUILD_FAILING_TESTS=no ;;
 148       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-failing-tests) ;;
 149     esac
 150   ],
 151   [BUILD_FAILING_TESTS=no]) dnl Default value
 152 AM_CONDITIONAL(BUILD_FAILING_TESTS, test "x$BUILD_FAILING_TESTS" = "xyes")
 153 if test x$BUILD_FAILING_TESTS = xyes; then
 154   AC_MSG_WARN([building tests known to fail, use --disable-failing-tests to disable])
 155 else
 156   AC_MSG_WARN([Sissy ! By asking to not build the tests known to fail, you hereby waive your right to customer support.  If you do not agree with this EULA, please press Ctrl-C before the next line is printed.  By allowing the next line to be printed, you expressly acknowledge your acceptance of this EULA.])
 157 fi
 158
 159 dnl poison destroyed objects
 160 AC_ARG_ENABLE(poisoning,
 161   AC_HELP_STRING([--enable-poisoning],
 162     [enable poisoning of deallocated objects]),
 163   [
 164     case "${enableval}" in
 165       yes) USE_POISONING=yes ;;
 166       no)  USE_POISONING=no ;;
 167       *)   AC_MSG_ERROR(bad value ${enableval} for --enable-poisoning) ;;
 168     esac
 169   ],
 170   [USE_POISONING=no]) dnl Default value
 171 if test "x$USE_POISONING" = xyes; then
 172   AC_DEFINE(USE_POISONING, 1,
 173     [Define if we should poison deallocated memory])
 174 fi
 175
 176 dnl *** checks for platform ***
 177
 178 dnl * hardware/architecture *
 179
 180 dnl common/m4/gst-arch.m4
 181 dnl check CPU type
 182 AG_GST_ARCH
 183 dnl substitution for win32/common/config.h
 184 HOST_CPU=$host_cpu
 185 AC_SUBST(HOST_CPU)
 186
 187 dnl common/m4/gst-arch.m4
 188 dnl check for unaligned access
 189 AG_GST_UNALIGNED_ACCESS
 190 dnl create a configure variable for gst/gstconfig.h
 191 if test x${as_cv_unaligned_access} = xyes ; then
 192   GST_HAVE_UNALIGNED_ACCESS_DEFINE="#define GST_HAVE_UNALIGNED_ACCESS 1"
 193 else
 194   GST_HAVE_UNALIGNED_ACCESS_DEFINE="#define GST_HAVE_UNALIGNED_ACCESS 0"
 195 fi
 196 AC_SUBST(GST_HAVE_UNALIGNED_ACCESS_DEFINE)
 197
 198 dnl check for platform specific settings
 199 AG_GST_PLATFORM
 200
 201 dnl * software *
 202
 203 dnl check for large file support
 204 dnl affected plugins must include config.h
 205 AC_SYS_LARGEFILE
 206
 207 dnl *** checks for programs ***
 208
 209 dnl find a compiler
 210 AC_PROG_CC
 211 AC_PROG_CC_STDC
 212
 213 dnl check if the compiler supports '-c' and '-o' options
 214 AM_PROG_CC_C_O
 215
 216 dnl find an assembler
 217 AM_PROG_AS
 218
 219 dnl determine if c++ is available on this system
 220 AC_PROG_CXX
 221 dnl CXX may be set to some default even if no c++ compiler is available
 222 dnl (thanks autotools!), so just try to compile some c++ code to make sure
 223 AC_LANG_PUSH([C++])
 224 AC_TRY_COMPILE([ class Foo { int bar; };], , working_cxx=yes, working_cxx=no)
 225 AC_LANG_POP([C++])
 226 AC_MSG_NOTICE([working c++ compiler found: $working_cxx])
 227 AM_CONDITIONAL(HAVE_CXX, test "x$working_cxx" = "xyes")
 228
 229 dnl Perl is used in building documentation and in the version checks
 230 AC_PATH_PROG(PERL_PATH, perl, no)
 231 if test x$PERL_PATH = xno; then
 232   AC_MSG_ERROR(Could not find perl)
 233 fi
 234
 235 dnl we require flex and bison for building the parser
 236 if test "x$GST_DISABLE_PARSE" != xyes; then
 237   AG_GST_BISON_CHECK
 238   AG_GST_FLEX_CHECK
 239 fi
 240
 241 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 242 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 243
 244 dnl check for gobject-introspection
 245 GOBJECT_INTROSPECTION_CHECK([1.31.1])
 246
 247 dnl check for documentation tools
 248 AG_GST_DOCBOOK_CHECK
 249 GTK_DOC_CHECK([1.3])
 250 AS_PATH_PYTHON([2.1])
 251 AG_GST_PLUGIN_DOCS([1.3],[2.1])
 252
 253 dnl *** checks for libraries ***
 254
 255 dnl check for libm, for sin()
 256 AC_CHECK_LIBM
 257 AC_SUBST(LIBM)
 258
 259 dnl *** checks for header files ***
 260
 261 dnl check if we have ANSI C header files
 262 AC_HEADER_STDC
 263
 264 dnl Check for ucontext.h
 265 AC_CHECK_HEADERS([ucontext.h])
 266
 267 dnl Check for sys/socket.h
 268 AC_CHECK_HEADERS([sys/socket.h], HAVE_SYS_SOCKET_H=yes)
 269 AM_CONDITIONAL(HAVE_SYS_SOCKET_H, test "x$HAVE_SYS_SOCKET_H" = "xyes")
 270
 271 dnl check for sys/times.h for tests/examples/adapter/
 272 AC_CHECK_HEADERS([sys/times.h], HAVE_SYS_TIMES_H=yes)
 273 AC_CHECK_HEADERS([unistd.h], HAVE_UNISTD_H=yes)
 274 AM_CONDITIONAL(HAVE_SYS_TIMES_H_AND_UNISTD_H, test "x$HAVE_SYS_TIMES_H" = "xyes" -a "x$HAVE_UNISTD_H" = "xyes")
 275
 276 dnl Check for process.h for getpid() on win32
 277 AC_CHECK_HEADERS([process.h])
 278
 279 dnl Check for sys/utsname.h for uname
 280 AC_CHECK_HEADERS([sys/utsname.h])
 281
 282 dnl Check for stdio_ext.f for __fbufsize
 283 AC_CHECK_HEADERS([stdio_ext.h])
 284
 285 dnl check for pthreads
 286 AC_CHECK_HEADERS([pthread.h], HAVE_PTHREAD_H=yes)
 287 AM_CONDITIONAL(HAVE_PTHREAD_H, test "x$HAVE_PTHREAD_H" = "xyes")
 288
 289 dnl check for sys/prctl for setting thread name on Linux
 290 AC_CHECK_HEADERS([sys/prctl.h], HAVE_SYS_PRCTL_H=yes)
 291
 292 dnl Check for valgrind.h
 293 dnl separate from HAVE_VALGRIND because you can have the program, but not
 294 dnl the dev package
 295 AC_CHECK_HEADERS([valgrind/valgrind.h], HAVE_VALGRIND_H=yes)
 296
 297 dnl used in gst/gstpoll.c
 298 AC_CHECK_HEADERS([winsock2.h], HAVE_WINSOCK2_H=yes)
 299 AM_CONDITIONAL(HAVE_WINSOCK2_H, test "x$HAVE_WINSOCK2_H" = "xyes")
 300 if test "x$HAVE_WINSOCK2_H" = "xyes"; then
 301   WIN32_LIBS="-lws2_32"
 302   AC_SUBST(WIN32_LIBS)
 303 fi
 304
 305 dnl check for GMP/GSL, used by the gst_util_uint64_scale unit test only
 306 if test "x$BUILD_TESTS" = "xyes"; then
 307   AG_GST_CHECK_LIBHEADER(GMP, gmp,
 308                          __gmpz_init_set_d, ,
 309                          gmp.h,
 310                          GMP_LIBS="-lgmp"
 311                          AC_SUBST(GMP_LIBS)
 312                          AC_DEFINE(HAVE_GMP, [1],[Have GMP library]))
 313   AG_GST_CHECK_LIBHEADER(GSL, gsl,
 314                          gsl_rng_uniform_int, -lgslcblas,
 315                          gsl/gsl_rng.h,
 316                          GSL_LIBS="-lgsl -lgslcblas"
 317                          AC_SUBST(GSL_LIBS)
 318                          AC_DEFINE(HAVE_GSL, [1],[Have GSL library]))
 319 fi
 320
 321 dnl *** checks for types/defines ***
 322
 323 dnl *** checks for structures ***
 324
 325 dnl *** checks for compiler characteristics ***
 326
 327 dnl check if the compiler supports __uint128_t (gcc)
 328 dnl Actually check for 128-bit division, since that's what we use
 329 dnl uint128_t for.
 330 AC_CACHE_CHECK(for __uint128_t, gst_cv_uint128_t,
 331     AC_TRY_LINK([ ], [
 332       static __uint128_t v1 = 100;
 333       static __uint128_t v2 = 10;
 334       static __uint128_t u;
 335       u = v1 / v2;
 336     ], [
 337       gst_cv_uint128_t=yes
 338     ], [
 339       gst_cv_uint128_t=no
 340     ])
 341 )
 342 if test x$gst_cv_uint128_t = xyes; then
 343   AC_DEFINE(HAVE_UINT128_T, 1, [Have __uint128_t type])
 344 fi
 345
 346 dnl *** checking for tm_gmtoff ***
 347 AC_MSG_CHECKING([for tm_gmtoff])
 348 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 349         #include <time.h>
 350         int main(void) {
 351           struct tm t;
 352           t.tm_gmtoff = 0;
 353           exit(0);
 354         }]])],
 355   [have_tm_gmtoff=yes
 356    AC_DEFINE(HAVE_TM_GMTOFF,1,[Have tm_gmtoff field in struct tm])],
 357   [have_tm_gmtoff=no],
 358   [have_tm_gmtoff="no (cross compiling)"])
 359 AC_MSG_RESULT($have_tm_gmtoff)
 360
 361
 362 dnl *** checks for library functions ***
 363
 364 AC_CHECK_FUNCS([gmtime_r])
 365 AC_CHECK_FUNCS([localtime_r])
 366 AC_CHECK_FUNCS([sigaction])
 367
 368 dnl check for fseeko()
 369 AC_FUNC_FSEEKO
 370 dnl check for ftello()
 371 AC_CHECK_FUNCS([ftello])
 372
 373 AC_CHECK_FUNCS([fgetpos])
 374 AC_CHECK_FUNCS([fsetpos])
 375
 376 dnl check for poll(), ppoll() and pselect()
 377 AC_CHECK_FUNCS([poll])
 378 AC_CHECK_FUNCS([ppoll])
 379 AC_CHECK_FUNCS([pselect])
 380
 381 AC_CHECK_HEADERS([sys/poll.h])
 382
 383 dnl ****************************************
 384 dnl *** GLib POLL* compatibility defines ***
 385 dnl ****************************************
 386
 387 AC_MSG_CHECKING([for broken poll])
 388 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 389         #include <stdlib.h>
 390         #include <fcntl.h>
 391         #include <poll.h>
 392         #ifdef HAVE_SYS_POLL_H
 393         #include <sys/poll.h>
 394         #endif
 395         int main(void) {
 396           struct pollfd fds[1];
 397           int fd;
 398           fd = open("/dev/null", 1);
 399           fds[0].fd = fd;
 400           fds[0].events = POLLIN;
 401           fds[0].revents = 0;
 402           if (poll(fds, 1, 0) < 0 || (fds[0].revents & POLLNVAL) != 0) {
 403                 exit(1);  /* Does not work for devices -- fail */
 404           }
 405           exit(0);
 406         }]])],
 407   [broken_poll=no],
 408   [broken_poll=yes
 409    AC_DEFINE(BROKEN_POLL,1,[poll doesn't work on devices])],
 410   [broken_poll="no (cross compiling)"])
 411 AC_MSG_RESULT($broken_poll)
 412
 413 dnl check for mmap()
 414 AC_FUNC_MMAP
 415 AM_CONDITIONAL(HAVE_MMAP, test "x$ac_cv_func_mmap_fixed_mapped" = "xyes")
 416
 417 dnl check for posix_memalign(), getpagesize()
 418 AC_CHECK_FUNCS([posix_memalign])
 419 AC_CHECK_FUNCS([getpagesize])
 420
 421 dnl Check for POSIX timers
 422 AC_CHECK_FUNCS(clock_gettime, [], [
 423   AC_CHECK_LIB(rt, clock_gettime, [
 424     AC_DEFINE(HAVE_CLOCK_GETTIME, 1)
 425     LIBS="$LIBS -lrt"
 426   ])
 427 ])
 428
 429 AC_CACHE_CHECK(for posix timers, gst_cv_posix_timers,
 430     AC_TRY_COMPILE([
 431 #include <time.h>
 432 #ifdef HAVE_UNISTD_H
 433 #include <unistd.h>
 434 #endif
 435     ], [
 436 #if !defined(_POSIX_TIMERS) || _POSIX_TIMERS < 0 || !defined(CLOCK_REALTIME)
 437 #error Either _POSIX_TIMERS or CLOCK_REALTIME not defined
 438 #endif
 439     ], [
 440       gst_cv_posix_timers=yes
 441     ], [
 442       gst_cv_posix_timers=no
 443     ])
 444 )
 445
 446 if test "$gst_cv_posix_timers" = "yes"; then
 447   AC_DEFINE(HAVE_POSIX_TIMERS,1,[Have posix timers])
 448   GST_HAVE_POSIX_TIMERS_DEFINE="#define GST_HAVE_POSIX_TIMERS 1"
 449 else
 450   GST_HAVE_POSIX_TIMERS_DEFINE="#define GST_HAVE_POSIX_TIMERS 0"
 451 fi
 452 AC_SUBST(GST_HAVE_POSIX_TIMERS_DEFINE)
 453 AM_CONDITIONAL(GST_HAVE_POSIX_TIMERS, test "$gst_cv_posix_timers" = "yes")
 454
 455 AC_CACHE_CHECK(for monotonic clock, gst_cv_monotonic_clock,
 456     AC_TRY_COMPILE([
 457 #include <time.h>
 458 #ifdef HAVE_UNISTD_H
 459 #include <unistd.h>
 460 #endif
 461     ], [
 462 #if !defined(_POSIX_MONOTONIC_CLOCK) || _POSIX_MONOTONIC_CLOCK < 0 || !defined(CLOCK_MONOTONIC)
 463 #error Either _POSIX_MONOTONIC_CLOCK or CLOCK_MONOTONIC not defined
 464 #endif
 465     ], [
 466       gst_cv_monotonic_clock=yes
 467     ], [
 468       gst_cv_monotonic_clock=no
 469     ])
 470 )
 471
 472 if test "$gst_cv_monotonic_clock" = "yes"; then
 473   AC_DEFINE(HAVE_MONOTONIC_CLOCK,1,[Have a monotonic clock])
 474   GST_HAVE_MONOTONIC_CLOCK_DEFINE="#define GST_HAVE_MONOTONIC_CLOCK 1"
 475 else
 476   GST_HAVE_MONOTONIC_CLOCK_DEFINE="#define GST_HAVE_MONOTONIC_CLOCK 0"
 477 fi
 478 AC_SUBST(GST_HAVE_MONOTONIC_CLOCK_DEFINE)
 479 AM_CONDITIONAL(GST_HAVE_MONOTONIC_CLOCK, test "$gst_cv_monotonic_clock" = "yes")
 480
 481 dnl Check for a way to display the function name in debug output
 482 AG_GST_CHECK_FUNCTION
 483
 484 dnl test for register_printf_specifier or register_printf_function
 485 AC_CHECK_FUNCS([register_printf_specifier register_printf_function],
 486     [HAVE_PRINTF_EXTENSION=yes])
 487
 488 if test "$HAVE_PRINTF_EXTENSION" = yes; then
 489   GST_PRINTF_EXTENSION_POINTER_FORMAT_DEFINE="#define GST_PTR_FORMAT \"P\""
 490   GST_PRINTF_EXTENSION_SEGMENT_FORMAT_DEFINE="#define GST_SEGMENT_FORMAT \"Q\""
 491   GST_USING_PRINTF_EXTENSION_DEFINE="#define GST_USING_PRINTF_EXTENSION"
 492   AC_DEFINE(HAVE_PRINTF_EXTENSION, 1,
 493       [Defined if we have printf specifier extensions available])
 494 else
 495     GST_PRINTF_EXTENSION_POINTER_FORMAT_DEFINE="#define GST_PTR_FORMAT \"p\""
 496     GST_PRINTF_EXTENSION_SEGMENT_FORMAT_DEFINE="#define GST_SEGMENT_FORMAT \"p\""
 497     GST_USING_PRINTF_EXTENSION_DEFINE="#undef GST_USING_PRINTF_EXTENSION"
 498 fi
 499 AC_SUBST(GST_PRINTF_EXTENSION_POINTER_FORMAT_DEFINE)
 500 AC_SUBST(GST_PRINTF_EXTENSION_SEGMENT_FORMAT_DEFINE)
 501 AC_SUBST(GST_USING_PRINTF_EXTENSION_DEFINE)
 502
 503 dnl test if we have dladdr(); we use it for debugging; see gst/gstinfo.c
 504 save_cflags="$CFLAGS"
 505 CFLAGS="$CFLAGS -D_GNU_SOURCE"
 506 AC_CHECK_LIB(dl, dladdr,
 507    AC_DEFINE(HAVE_DLADDR, 1, [Defined if we have dladdr ()])
 508    LIBS="$LIBS -ldl")
 509 CFLAGS="$save_cflags"
 510
 511 dnl *** checks for dependency libraries ***
 512
 513 dnl GLib
 514 GLIB_REQ=2.31.10
 515
 516 AG_GST_GLIB_CHECK([$GLIB_REQ])
 517
 518 dnl Check for GIO
 519 PKG_CHECK_MODULES(GIO, gio-2.0 >= $GLIB_REQ)
 520 GIO_MODULE_DIR="`$PKG_CONFIG --variable=giomoduledir gio-2.0`"
 521 AC_DEFINE_UNQUOTED(GIO_MODULE_DIR, "$GIO_MODULE_DIR",
 522     [The GIO modules directory.])
 523 GIO_LIBDIR="`$PKG_CONFIG --variable=libdir gio-2.0`"
 524     AC_DEFINE_UNQUOTED(GIO_LIBDIR, "$GIO_LIBDIR",
 525         [The GIO library directory.])
 526
 527 AC_SUBST(GIO_CFLAGS)
 528 AC_SUBST(GIO_LIBS)
 529 AC_SUBST(GIO_LDFLAGS)
 530
 531 dnl Check for documentation xrefs
 532 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 533 AC_SUBST(GLIB_PREFIX)
 534
 535 dnl building of unit test libraries
 536 AC_ARG_ENABLE(check,
 537   AC_HELP_STRING([--disable-check], [disable building unit test libraries]),
 538   [
 539     case "${enableval}" in
 540       yes) BUILD_CHECK=yes ;;
 541       no)  BUILD_CHECK=no ;;
 542       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-check) ;;
 543     esac
 544   ], [
 545     dnl Default value
 546     case $host_os in
 547       mingw* | msvc* | mks*) BUILD_CHECK=no ;;
 548       *) BUILD_CHECK=yes ;;
 549     esac
 550 ])
 551 dnl bit of a misnomer, but keep the conditional named like this so we don't
 552 dnl have to change too much elsewhere
 553 AM_CONDITIONAL(HAVE_CHECK, test "x$BUILD_CHECK" = "xyes")
 554
 555 dnl configure the desired memory alignment
 556 AC_ARG_WITH([memory-alignment],
 557   AS_HELP_STRING([--with-memory-alignment],[8,N,malloc,pagesize (default is 32)]),
 558   [
 559     if test "x$withval" = "xyes"
 560     then
 561       AC_DEFINE(MEMORY_ALIGNMENT, 32, [Memory alignment to use])
 562     else
 563       case "${withval}" in
 564         malloc) AC_DEFINE(MEMORY_ALIGNMENT_MALLOC, 1, [Memory alignment by malloc default]) ;;
 565         pagesize)  AC_DEFINE(MEMORY_ALIGNMENT_PAGESIZE, 1, [Memory alignment by pagesize]) ;;
 566         *)   AC_DEFINE_UNQUOTED(MEMORY_ALIGNMENT, ${withval}, [Memory alignment to use]) ;;
 567       esac
 568     fi
 569   ], [
 570     AC_DEFINE(MEMORY_ALIGNMENT_MALLOC, 1, [Memory alignment by malloc default])
 571   ]
 572 )
 573
 574 dnl Check for -Bsymbolic-functions linker flag used to avoid
 575 dnl intra-library PLT jumps, if available.
 576 AC_ARG_ENABLE(Bsymbolic,
 577               [AC_HELP_STRING([--disable-Bsymbolic],
 578                               [avoid linking with -Bsymbolic])],,
 579               [SAVED_LDFLAGS="${LDFLAGS}"
 580                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
 581                LDFLAGS=-Wl,-Bsymbolic-functions
 582                AC_TRY_LINK([], [int main (void) { return 0; }],
 583                            AC_MSG_RESULT(yes)
 584                            enable_Bsymbolic=yes,
 585                            AC_MSG_RESULT(no)
 586                            enable_Bsymbolic=no)
 587                LDFLAGS="${SAVED_LDFLAGS}"])
 588
 589
 590 dnl *** set variables based on configure arguments
 591
 592 dnl set license and copyright notice
 593 GST_LICENSE="LGPL"
 594 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 595 AC_SUBST(GST_LICENSE)
 596
 597 dnl define LIBDIR, GST_DATADIR so we can inform people where we live
 598 AS_AC_EXPAND(LIBDIR, $libdir)
 599 AC_DEFINE_UNQUOTED(LIBDIR, "$LIBDIR", [library dir])
 600 AS_AC_EXPAND(DATADIR, $datadir)
 601 AC_DEFINE_UNQUOTED(GST_DATADIR, "$DATADIR", [data dir])
 602
 603 dnl set location of plugin directory
 604 AG_GST_SET_PLUGINDIR
 605
 606 GST_PKG_DEPS="glib-2.0, gobject-2.0, gmodule-no-export-2.0, gthread-2.0"
 607 AC_SUBST(GST_PKG_DEPS)
 608
 609 dnl make sure it doesn't complain about unused variables if debugging is disabled
 610 NO_WARNINGS=""
 611 if test "x${GST_DISABLE_GST_DEBUG}" = "xyes"; then
 612   NO_WARNINGS="-Wno-unused"
 613 fi
 614
 615 dnl define an ERROR_CFLAGS Makefile variable
 616 AG_GST_SET_ERROR_CFLAGS($GST_GIT, [-Wmissing-declarations -Wmissing-prototypes -Wredundant-decls -Wundef -Wwrite-strings -Wformat-nonliteral -Wformat-security -Wold-style-definition -Winit-self -Wmissing-include-dirs -Waddress -Waggregate-return -Wno-multichar -Wnested-externs $NO_WARNINGS])
 617
 618 dnl define correct level for debugging messages
 619 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 620
 621 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 622
 623 dnl Overview:
 624 dnl GST_OPTION_CFLAGS:  common cflags for profiling, debugging, errors, ...
 625 dnl GST_ALL_*:          vars shared by all built objects
 626 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 627 dnl GST_OBJ_*:          additional vars to link to the core library
 628 dnl                     include GST_ALL_*
 629 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 630 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 631
 632 dnl GST_OPTION_CFLAGS
 633 if test "x$USE_DEBUG" = xyes; then
 634    PROFILE_CFLAGS="-g"
 635 fi
 636 AC_SUBST(PROFILE_CFLAGS)
 637
 638 # GST_DISABLE_DEPRECATED: hide the visibility of deprecated
 639 # functionality from the API that gstreamer uses
 640 # GST_REMOVE_DEPRECATED: don't compile deprecated functionality (breaks ABI)
 641 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
 642   dnl Define _only_ when compiling from git (not for pre-releases or releases)
 643   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 644 else
 645   DEPRECATED_CFLAGS=""
 646 fi
 647 AC_SUBST(DEPRECATED_CFLAGS)
 648
 649 dnl every flag in GST_OPTION_CFLAGS can be overridden at make time via e.g.
 650 dnl make DEPRECATED_CFLAGS=''
 651 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 652 GST_OPTION_CXXFLAGS="\$(WARNING_CXXFLAGS) \$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 653 GST_OPTION_CFLAGS="$GST_OPTION_CFLAGS -DGST_USE_UNSTABLE_API"
 654 GST_OPTION_CXXFLAGS="$GST_OPTION_CXXFLAGS -DGST_USE_UNSTABLE_API"
 655 AC_SUBST(GST_OPTION_CFLAGS)
 656 AC_SUBST(GST_OPTION_CXXFLAGS)
 657
 658 dnl GST_ALL_*
 659 dnl vars common to for all internal objects (core libs, elements, applications)
 660 dnl CFLAGS:
 661 dnl - src and build dirs need to be added because every piece that gets built
 662 dnl   will need the GStreamer source and generated headers
 663 dnl LIBS: XML doesn't need to be added because we don't explicitly use symbols
 664 dnl       from LibXML except for in the core library
 665 GST_ALL_CXXFLAGS="-I\$(top_srcdir)/libs -I\$(top_srcdir) -I\$(top_builddir)/libs -I\$(top_builddir) $GLIB_CFLAGS \$(GLIB_EXTRA_CFLAGS) $XML_CFLAGS \$(GST_OPTION_CXXFLAGS) \$(ERROR_CXXFLAGS)"
 666 GST_ALL_CFLAGS="-I\$(top_srcdir)/libs -I\$(top_srcdir) -I\$(top_builddir)/libs -I\$(top_builddir) $GLIB_CFLAGS \$(GLIB_EXTRA_CFLAGS) $XML_CFLAGS \$(GST_OPTION_CFLAGS) \$(ERROR_CFLAGS)"
 667
 668 dnl FIXME: check if LTLIBINTL is needed everywhere
 669 dnl I presume it is given that it contains the symbols that _() stuff maps to
 670 GST_ALL_LIBS="$GLIB_LIBS $LTLIBINTL \$(GCOV_LIBS)"
 671
 672 dnl LDFLAGS really should only contain flags, not libs - they get added before
 673 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 674 GST_ALL_LDFLAGS="-no-undefined"
 675 if test "x${enable_Bsymbolic}" = "xyes"; then
 676   GST_ALL_LDFLAGS="$GST_ALL_LDFLAGS -Wl,-Bsymbolic-functions"
 677 fi
 678
 679 AC_SUBST(GST_ALL_CFLAGS)
 680 AC_SUBST(GST_ALL_CXXFLAGS)
 681 AC_SUBST(GST_ALL_LIBS)
 682 AC_SUBST(GST_ALL_LDFLAGS)
 683
 684 dnl GST_LIB_LDFLAGS
 685 dnl linker flags shared by all libraries
 686 dnl LDFLAGS modifier defining exported symbols from built libraries
 687 GST_LIB_LDFLAGS="-export-symbols-regex \^[_]?\(gst_\|Gst\|GST_\).*"
 688 AC_SUBST(GST_LIB_LDFLAGS)
 689
 690 dnl GST_OBJ_*
 691 dnl default vars for all internal objects built on libgstreamer
 692 dnl includes GST_ALL_*
 693 GST_OBJ_CFLAGS="\$(GST_ALL_CFLAGS)"
 694 GST_OBJ_CXXFLAGS="\$(GST_ALL_CXXFLAGS)"
 695 GST_OBJ_LIBS="\$(top_builddir)/gst/libgstreamer-$GST_MAJORMINOR.la \$(GST_ALL_LIBS)"
 696 AC_SUBST(GST_OBJ_CFLAGS)
 697 AC_SUBST(GST_OBJ_CXXFLAGS)
 698 AC_SUBST(GST_OBJ_LIBS)
 699
 700 dnl GST_PLUGIN_LDFLAGS
 701 dnl LDFLAGS for plugins; includes GST_ALL_LDFLAGS
 702 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc.*' $GST_ALL_LDFLAGS"
 703 AC_SUBST(GST_PLUGIN_LDFLAGS, "$GST_PLUGIN_LDFLAGS")
 704
 705 dnl plugin scanner locations
 706 AS_AC_EXPAND(GST_PLUGIN_SCANNER_INSTALLED,${libexecdir}/gstreamer-$GST_MAJORMINOR/gst-plugin-scanner)
 707 AC_DEFINE_UNQUOTED(GST_PLUGIN_SCANNER_INSTALLED,
 708     "$GST_PLUGIN_SCANNER_INSTALLED", [location of the installed gst-plugin-scanner])
 709 AC_SUBST(GST_PLUGIN_SCANNER_INSTALLED)
 710
 711 dnl things for our internal libcheck (must be called even if building
 712 dnl libcheck is disabled because it defines conditionals)
 713 AG_GST_CHECK_CHECKS()
 714
 715 AC_CONFIG_FILES(
 716 Makefile
 717 gst/Makefile
 718 gst/gstconfig.h
 719 gst/gstversion.h
 720 gst/parse/Makefile
 721 libs/Makefile
 722 libs/gst/Makefile
 723 libs/gst/base/Makefile
 724 libs/gst/check/Makefile
 725 libs/gst/check/libcheck/Makefile
 726 libs/gst/check/libcheck/check.h
 727 libs/gst/controller/Makefile
 728 libs/gst/helpers/Makefile
 729 libs/gst/net/Makefile
 730 plugins/Makefile
 731 plugins/elements/Makefile
 732 po/Makefile.in
 733 tests/Makefile
 734 tests/benchmarks/Makefile
 735 tests/check/Makefile
 736 tests/misc/Makefile
 737 tests/examples/Makefile
 738 tests/examples/adapter/Makefile
 739 tests/examples/controller/Makefile
 740 tests/examples/stepping/Makefile
 741 tests/examples/helloworld/Makefile
 742 tests/examples/launch/Makefile
 743 tests/examples/manual/Makefile
 744 tests/examples/metadata/Makefile
 745 tests/examples/queue/Makefile
 746 tests/examples/streams/Makefile
 747 tests/examples/typefind/Makefile
 748 tools/Makefile
 749 common/Makefile
 750 common/m4/Makefile
 751 docs/Makefile
 752 docs/design/Makefile
 753 docs/faq/Makefile
 754 docs/gst/Makefile
 755 docs/gst/gstreamer.types
 756 docs/libs/Makefile
 757 docs/plugins/Makefile
 758 docs/manual/Makefile
 759 docs/pwg/Makefile
 760 docs/slides/Makefile
 761 docs/xsl/Makefile
 762 docs/version.entities
 763 m4/Makefile
 764 pkgconfig/Makefile
 765 stamp.h
 766 pkgconfig/gstreamer.pc
 767 pkgconfig/gstreamer-uninstalled.pc
 768 pkgconfig/gstreamer-base.pc
 769 pkgconfig/gstreamer-base-uninstalled.pc
 770 pkgconfig/gstreamer-check.pc
 771 pkgconfig/gstreamer-check-uninstalled.pc
 772 pkgconfig/gstreamer-controller.pc
 773 pkgconfig/gstreamer-controller-uninstalled.pc
 774 pkgconfig/gstreamer-net.pc
 775 pkgconfig/gstreamer-net-uninstalled.pc
 776 gst-element-check.m4
 777 gstreamer.spec
 778 )
 779
 780 dnl Create the config.h file for Visual Studio builds
 781 dnl Beware of spaces and /'s in some of the shell variable contents.
 782 sed \
 783     -e 's/.*config.h.in.*autoheader.*/\/* Autogenerated config.h created for win32 Visual Studio builds *\/\n\n\/* PREFIX -- specifically added for Windows for easier moving *\/\n#define PREFIX "C:\\\\gstreamer"/' \
 784     -e 's/.* GETTEXT_PACKAGE$/#define GETTEXT_PACKAGE "'$GETTEXT_PACKAGE'"/' \
 785     -e 's/.* GST_DATADIR$/#define GST_DATADIR PREFIX "\\\\share"/' \
 786     -e 's/.* GST_LEVEL_DEFAULT$/#define GST_LEVEL_DEFAULT GST_LEVEL_ERROR/' \
 787     -e 's/.* GST_LICENSE$/#define GST_LICENSE "'$GST_LICENSE'"/' \
 788     -e 's/.* GST_MAJORMINOR$/#define GST_MAJORMINOR "'$GST_MAJORMINOR'"/' \
 789     -e "s,.* GST_PACKAGE_NAME$,#define GST_PACKAGE_NAME \"${GST_PACKAGE_NAME}\"," \
 790     -e 's/.* GST_PACKAGE_ORIGIN$/#define GST_PACKAGE_ORIGIN "Unknown package origin"/' \
 791     -e "s,.* GST_PACKAGE_RELEASE_DATETIME$,#define GST_PACKAGE_RELEASE_DATETIME \"${GST_PACKAGE_RELEASE_DATETIME}\"," \
 792     -e 's/.* HAVE_CPU_I386$/#define HAVE_CPU_I386 1/' \
 793     -e 's/.* HAVE_FGETPOS$/#define HAVE_FGETPOS 1/' \
 794     -e 's/.* HAVE_FSETPOS$/#define HAVE_FSETPOS 1/' \
 795     -e 's/.* HAVE_PROCESS_H$/#define HAVE_PROCESS_H 1/' \
 796     -e 's/.* HAVE_STDLIB_H$/#define HAVE_STDLIB_H 1/' \
 797     -e 's/.* HAVE_STRING_H$/#define HAVE_STRING_H 1/' \
 798     -e 's/.* HAVE_SYS_STAT_H$/#define HAVE_SYS_STAT_H 1/' \
 799     -e 's/.* HAVE_SYS_TYPES_H$/#define HAVE_SYS_TYPES_H 1/' \
 800     -e 's/.* HAVE_WIN32$/#define HAVE_WIN32 1/' \
 801     -e 's/.* HAVE_WINSOCK2_H$/#define HAVE_WINSOCK2_H 1/' \
 802     -e 's/.* HOST_CPU$/#define HOST_CPU "i686"/' \
 803     -e 's/.* MEMORY_ALIGNMENT_MALLOC/#define MEMORY_ALIGNMENT_MALLOC 1/' \
 804     -e 's/.* LIBDIR$/#ifdef _DEBUG\n#  define LIBDIR PREFIX "\\\\debug\\\\lib"\n#else\n#  define LIBDIR PREFIX "\\\\lib"\n#endif/' \
 805     -e 's/.* LOCALEDIR$/#define LOCALEDIR PREFIX "\\\\share\\\\locale"/' \
 806     -e 's/.* PACKAGE$/#define PACKAGE "gstreamer"/' \
 807     -e 's/.* PACKAGE_BUGREPORT$/#define PACKAGE_BUGREPORT "http:\/\/bugzilla.gnome.org\/enter_bug.cgi?product=GStreamer"/' \
 808     -e 's/.* PACKAGE_NAME$/#define PACKAGE_NAME "'$PACKAGE_NAME'"/' \
 809     -e "s/.* PACKAGE_STRING$/#define PACKAGE_STRING \"$PACKAGE_STRING\"/" \
 810     -e 's/.* PACKAGE_TARNAME$/#define PACKAGE_TARNAME "'$PACKAGE_TARNAME'"/' \
 811     -e 's/.* PACKAGE_VERSION$/#define PACKAGE_VERSION "'$PACKAGE_VERSION'"/' \
 812     -e 's/.* PLUGINDIR$/#ifdef _DEBUG\n#  define PLUGINDIR PREFIX "\\\\debug\\\\lib\\\\gstreamer-0.11"\n#else\n#  define PLUGINDIR PREFIX "\\\\lib\\\\gstreamer-0.11"\n#endif/' \
 813     -e 's/.* GST_PLUGIN_SCANNER_INSTALLED$/#define GST_PLUGIN_SCANNER_INSTALLED LIBDIR "\\\\gst-plugin-scanner"/' \
 814     -e 's/.* VERSION$/#define VERSION "'$VERSION'"/' \
 815     config.h.in >win32/common/config.h-new
 816
 817 AC_OUTPUT
 818
 819 dnl negate for output
 820 if test "x${GST_DISABLE_GST_DEBUG}" = "xno"; then enable_gst_debug="yes"; fi
 821 if test "x${GST_DISABLE_PARSE}" = "xno"; then enable_parse="yes"; fi
 822 if test "x${GST_DISABLE_OPTION_PARSING}" = "xno"; then enable_option_parsing="yes"; fi
 823 if test "x${GST_DISABLE_TRACE}" = "xno"; then enable_trace="yes"; fi
 824 if test "x${GST_DISABLE_ALLOC_TRACE}" = "xno"; then enable_alloc_trace="yes"; fi
 825 if test "x${GST_DISABLE_PLUGIN}" = "xno"; then enable_plugin="yes"; fi
 826 if test "x${GST_DISABLE_REGISTRY}" = "xno"; then enable_registry="yes"; fi
 827
 828 echo "
 829
 830 Configuration
 831         Version                    : ${VERSION}
 832         Source code location       : ${srcdir}
 833         Prefix                     : ${prefix}
 834         Compiler                   : ${CC}
 835         Package name               : ${GST_PACKAGE_NAME}
 836         Package origin             : ${GST_PACKAGE_ORIGIN}
 837
 838         Documentation (manuals)    : ${enable_docbook}
 839         Documentation (API)        : ${enable_gtk_doc}
 840
 841         Debug Logging              : ${enable_gst_debug}
 842         Command-line parser        : ${enable_parse}
 843         Option parsing in gst_init : ${enable_option_parsing}
 844         Tracing subsystem          : ${enable_trace}
 845         Allocation tracing         : ${enable_alloc_trace}
 846         Plugin registry            : ${enable_registry}
 847         Plugin support             : ${enable_plugin}
 848         Unit testing support       : ${BUILD_CHECK}
 849
 850         Debug                      : ${USE_DEBUG}
 851         Profiling                  : ${USE_PROFILING}
 852
 853         Building examples          : ${BUILD_EXAMPLES}
 854         Building test apps         : ${BUILD_TESTS}
 855         Building tests that fail   : ${BUILD_FAILING_TESTS}
 856 "