configure.ac

   1 AC_PREREQ(2.52)
   2
   3 AC_INIT
   4 AC_CANONICAL_TARGET
   5
   6 dnl when going to/from release please set the nano (fourth number) right !
   7 dnl releases only do Wall, cvs and prerelease does Werror too
   8 AS_VERSION(gstreamer, GST_VERSION, 0, 9, 3, 1,
   9     GST_CVS="no", GST_CVS="yes")
  10
  11 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  12 AM_MAINTAINER_MODE
  13 AM_INIT_AUTOMAKE($PACKAGE,$VERSION)
  14
  15 dnl our libraries and install dirs use major.minor as a version
  16 GST_MAJORMINOR=$GST_VERSION_MAJOR.$GST_VERSION_MINOR
  17 dnl we override it here for release candidates for a new series
  18 # GST_MAJORMINOR=0.9
  19 AC_SUBST(GST_MAJORMINOR)
  20
  21 AC_PROG_CC
  22 dnl For interactive UNIX (a Sun thing)
  23 AC_ISC_POSIX
  24
  25 dnl CURRENT, REVISION, AGE
  26 dnl - library source changed -> increment REVISION
  27 dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
  28 dnl - interfaces added -> increment AGE
  29 dnl - interfaces removed -> AGE = 0
  30 AS_LIBTOOL(GST, 7, 0, 0)
  31 AS_LIBTOOL_TAGS([])
  32 AM_PROG_LIBTOOL
  33
  34 AC_CONFIG_SRCDIR([gst/gst.c])
  35 AM_CONFIG_HEADER(config.h)
  36
  37 dnl Add parameters for aclocal
  38 AC_SUBST(ACLOCAL_AMFLAGS, "-I common/m4 -I .")
  39
  40 AM_PROG_CC_STDC
  41 AM_PROG_AS
  42 AS="${CC}"
  43
  44 dnl the gettext stuff needed
  45 AM_GNU_GETTEXT_VERSION(0.11.5)
  46 AM_GNU_GETTEXT([external])
  47
  48 GETTEXT_PACKAGE=gstreamer-$GST_MAJORMINOR
  49 AC_SUBST(GETTEXT_PACKAGE)
  50 AC_DEFINE_UNQUOTED([GETTEXT_PACKAGE], "$GETTEXT_PACKAGE",
  51                    [gettext package name])
  52
  53 dnl define LOCALEDIR in config.h
  54 AS_AC_EXPAND(LOCALEDIR, $datadir/locale)
  55 AC_DEFINE_UNQUOTED([LOCALEDIR], "$LOCALEDIR",
  56                    [gettext locale dir])
  57
  58 dnl define LIBDIR so we can inform people where we live
  59 AS_AC_EXPAND(LIBDIR, $libdir)
  60 AC_DEFINE_UNQUOTED([LIBDIR], "$LIBDIR",
  61                    [library dir])
  62
  63 GST_SET_ERROR_CFLAGS($GST_CVS)
  64
  65 dnl We disable static building for development, for time savings
  66 dnl *NOTE*: dnl this line before release, so release does static too
  67 dnl AM_DISABLE_STATIC
  68
  69 AC_HEADER_STDC([])
  70 AC_C_INLINE
  71
  72 dnl define correct errorlevel for debugging messages. We want to have GST_ERROR
  73 dnl messages printed when running cvs builds
  74 if test "x$GST_CVS" = "xyes"; then
  75   AC_DEFINE(GST_LEVEL_DEFAULT, GST_LEVEL_ERROR, [Default errorlevel to use])
  76 fi
  77
  78 dnl subsystems - can influence other decisions so needs to be high up
  79 dnl we need to do AM_CONDITIONAL them here for automake 1.6.x compatibility
  80 GST_CHECK_SUBSYSTEM_DISABLE(GST_DEBUG,[debugging subsystem])
  81 AM_CONDITIONAL(GST_DISABLE_GST_DEBUG, test "x$GST_GST_DISABLE_DEBUG" = "xyes")
  82 GST_CHECK_SUBSYSTEM_DISABLE(LOADSAVE,[pipeline XML load/save])
  83 AM_CONDITIONAL(GST_DISABLE_LOADSAVE, test "x$GST_DISABLE_LOADSAVE" = "xyes")
  84 GST_CHECK_SUBSYSTEM_DISABLE(PARSE,[command-line parser])
  85 AM_CONDITIONAL(GST_DISABLE_PARSE, test "x$GST_DISABLE_PARSE" = "xyes")
  86 GST_CHECK_SUBSYSTEM_DISABLE(TRACE,[tracing subsystem])
  87 AM_CONDITIONAL(GST_DISABLE_TRACE, test "x$GST_DISABLE_TRACE" = "xyes")
  88 GST_CHECK_SUBSYSTEM_DISABLE(ALLOC_TRACE,[allocation tracing])
  89 AM_CONDITIONAL(GST_DISABLE_ALLOC_TRACE, test "x$GST_DISABLE_ALLOC_TRACE" = "xyes")
  90 GST_CHECK_SUBSYSTEM_DISABLE(REGISTRY,[plugin registry])
  91 AM_CONDITIONAL(GST_DISABLE_REGISTRY, test "x$GST_DISABLE_REGISTRY" = "xyes")
  92 GST_CHECK_SUBSYSTEM_DISABLE(ENUMTYPES,[enum types])
  93 AM_CONDITIONAL(GST_DISABLE_ENUMTYPES, test "x$GST_DISABLE_ENUMTYPES" = "xyes")
  94 GST_CHECK_SUBSYSTEM_DISABLE(INDEX,[index])
  95 AM_CONDITIONAL(GST_DISABLE_INDEX, test "x$GST_DISABLE_INDEX" = "xyes")
  96 GST_CHECK_SUBSYSTEM_DISABLE(PLUGIN,[plugin])
  97 AM_CONDITIONAL(GST_DISABLE_PLUGIN, test "x$GST_DISABLE_PLUGIN" = "xyes")
  98 GST_CHECK_SUBSYSTEM_DISABLE(URI,[uri handlers])
  99 AM_CONDITIONAL(GST_DISABLE_URI, test "x$GST_DISABLE_URI" = "xyes")
 100
 101 dnl ##############################
 102 dnl # Do automated configuration #
 103 dnl ##############################
 104
 105 dnl Check for tools:
 106 dnl ================
 107
 108 dnl allow for different autotools
 109 AS_AUTOTOOLS_ALTERNATE()
 110
 111 dnl modify pkg-config path
 112 AC_ARG_WITH(pkg-config-path,
 113    AC_HELP_STRING([--with-pkg-config-path],
 114                   [colon-separated list of pkg-config(1) dirs]),
 115    [export PKG_CONFIG_PATH=${withval}])
 116
 117 GST_ARCH()
 118
 119 dnl ### Documentation checks
 120
 121 dnl Perl is used in building documentation
 122 AC_PATH_PROG(PERL_PATH, perl, no)
 123 if test x$PERL_PATH = xno; then
 124   AC_MSG_ERROR(Could not find perl)
 125 fi
 126
 127 GST_DOCBOOK_CHECK
 128 GTK_DOC_CHECK([1.3])
 129
 130 AC_PROG_AWK
 131
 132 dnl we require bison for building the parser
 133 dnl FIXME: check if AC_PROG_YACC is suitable here
 134 AC_PATH_PROG(BISON_PATH, bison, no)
 135 if test x$BISON_PATH = xno; then
 136   AC_MSG_ERROR(Could not find bison)
 137 fi
 138
 139 dnl check bison version
 140 AC_MSG_CHECKING([bison version])
 141
 142 if $BISON_PATH --version | head -n 1 | $AWK '{ if ($4 < 1.35) exit 1; else exit 0;}';
 143 then
 144   AC_MSG_RESULT([ok])
 145 else
 146   AC_MSG_RESULT([too old.])
 147   AC_MSG_ERROR([Your bison version is too old, v1.35 or later is required.])
 148 fi
 149
 150 dnl we require flex for building the parser
 151 dnl FIXME: check if AC_PROG_LEX is suitable here
 152 AC_PATH_PROG(FLEX_PATH, flex, no)
 153 if test x$FLEX_PATH = xno; then
 154   AC_MSG_ERROR(Could not find flex)
 155 fi
 156
 157 dnl check for large file support (affected
 158 dnl plugins must include config.h for this)
 159 AC_SYS_LARGEFILE
 160
 161 dnl check for mmap
 162 AC_FUNC_MMAP()
 163
 164 dnl check for makecontext and define HAVE_MAKECONTEXT if we have it
 165 AC_CHECK_MCSC()
 166 if test "$ac_cv_check_mcsc" = "yes"; then
 167   AC_DEFINE_UNQUOTED(HAVE_MAKECONTEXT, $HAVE_MAKECONTEXT,
 168                      [defined if we have makecontext ()])
 169 fi
 170
 171 dnl Check for a way to display the function name in debug output
 172 GST_CHECK_FUNCTION()
 173
 174 dnl check if we should use -Wa,-mregnames on PowerPC, so we can use
 175 dnl symbolic register names in inline asm
 176 if test x$HAVE_CPU_PPC = xyes ; then
 177   AS_COMPILER_FLAG(["-Wa,-mregnames"],
 178     [GST_INT_CFLAGS="$GST_INT_CFLAGS -Wa,-mregnames"],
 179     true)
 180 fi
 181
 182 AC_ARG_ENABLE(gcov,
 183   AC_HELP_STRING([--enable-gcov],[compile with coverage profiling instrumentation (gcc only)]),
 184   enable_gcov=$enableval,enable_gcov=no)
 185 if test x$enable_gcov = xyes ; then
 186   AS_COMPILER_FLAG(["-fprofile-arcs"],
 187     [GST_INT_CFLAGS="$GST_INT_CFLAGS -fprofile-arcs"],
 188     true)
 189   AS_COMPILER_FLAG(["-ftest-coverage"],
 190     [GST_INT_CFLAGS="$GST_INT_CFLAGS -ftest-coverage"],
 191     true)
 192   GST_INT_CFLAGS=`echo "$GST_INT_CFLAGS" | sed -e 's/-O[0-9]*//g'`
 193
 194   AC_DEFINE_UNQUOTED(GST_GCOV_ENABLED, 1, [Defined if gcov is enabled to force a rebuild due to config.h changing])
 195 fi
 196 AM_CONDITIONAL(GST_GCOV_ENABLED, test x$enable_gcov = xyes)
 197
 198 dnl Check for some compiler flags that optimize our code.
 199 if test "x$GCC" = xyes; then
 200   AS_COMPILER_FLAG(-fno-common,GST_INT_CFLAGS="$GST_INT_CFLAGS -fno-common",)
 201 fi
 202
 203 dnl HAVE_WIN32 currently means "disable POSIXisms".
 204 case "$host" in
 205   *-*-mingw*)
 206     AC_DEFINE_UNQUOTED(HAVE_WIN32, 1, [Defined if compiling for Windows])
 207     ;;
 208   *)
 209     ;;
 210 esac
 211
 212 GST_UNALIGNED_ACCESS()
 213 if test x${as_cv_unaligned_access} = xyes ; then
 214   GST_HAVE_UNALIGNED_ACCESS_DEFINE="#define GST_HAVE_UNALIGNED_ACCESS 1"
 215 else
 216   GST_HAVE_UNALIGNED_ACCESS_DEFINE="#define GST_HAVE_UNALIGNED_ACCESS 0"
 217 fi
 218 AC_SUBST(GST_HAVE_UNALIGNED_ACCESS_DEFINE)
 219
 220 dnl Check for essential libraries first:
 221 dnl ====================================
 222
 223 dnl === GLib 2 ===
 224 dnl Minimum required version of GLib2
 225 dnl required for compilation without warnings
 226 GLIB2_REQ="2.6"
 227 AC_SUBST(GLIB2_REQ)
 228
 229 dnl Check for glib2 with sugar on top
 230 PKG_CHECK_MODULES(GLIB2, glib-2.0 >= $GLIB2_REQ gobject-2.0 gthread-2.0 gmodule-2.0,HAVE_GLIB2=yes,HAVE_GLIB2=no)
 231 dnl for the poor souls who for example have glib in /usr/local
 232 AS_SCRUB_INCLUDE(GLIB2_CFLAGS)
 233 GLIB_LIBS=$GLIB2_LIBS
 234 GLIB_CFLAGS=$GLIB2_CFLAGS
 235 AC_SUBST(GLIB_LIBS)
 236 AC_SUBST(GLIB_CFLAGS)
 237
 238 AC_MSG_CHECKING([glib version >= 2.8])
 239 if pkg-config --atleast-version=2.8 glib-2.0; then
 240   AC_MSG_RESULT(yes)
 241   GST_HAVE_GLIB_2_8_DEFINE="#define GST_HAVE_GLIB_2_8 1"
 242 else
 243   AC_MSG_RESULT(no)
 244   GST_HAVE_GLIB_2_8_DEFINE="/* #undef GST_HAVE_GLIB_2_8 */"
 245 fi
 246 AC_SUBST(GST_HAVE_GLIB_2_8_DEFINE)
 247
 248 if test "x$HAVE_GLIB2" = "xno"; then
 249   AC_MSG_ERROR([GStreamer requires GLib $GLIB2_REQ to compile.])
 250 fi
 251
 252 dnl Check for glib2 without extra fat, useful for the unversioned tool frontends
 253 PKG_CHECK_MODULES(GLIB_ONLY, glib-2.0 >= $GLIB2_REQ)
 254 AC_SUBST(GLIB_ONLY_CFLAGS)
 255 AC_SUBST(GLIB_ONLY_LIBS)
 256
 257 dnl === libxml 2 ===
 258 if test "x$GST_DISABLE_LOADSAVE" = "xyes" && test "x$GST_DISABLE_REGISTRY" = "xyes"
 259 then
 260   AC_MSG_NOTICE([Registry and load/save are disabled, not checking for libxml2])
 261 else
 262   dnl check for libxml2 with minimum req version
 263   GST_LIBXML2_CHECK(2.4.9)
 264 fi
 265
 266 dnl Check for ucontext.h
 267 AC_CHECK_HEADER(ucontext.h, AC_DEFINE(HAVE_UCONTEXT_H, 1, [defined if we have ucontext.h]))
 268
 269 dnl check for "check", unit testing library/header
 270 AM_PATH_CHECK(0.9.2,
 271     [
 272         HAVE_CHECK=yes
 273         AC_MSG_NOTICE(CHECK_CFLAGS: $CHECK_CFLAGS)
 274         AC_MSG_NOTICE(CHECK_LIBS: $CHECK_LIBS)
 275     ],
 276     HAVE_CHECK=no)
 277 AM_CONDITIONAL(HAVE_CHECK, test "x$HAVE_CHECK" = "xyes")
 278
 279 dnl ######################################################################
 280 dnl # Check command line parameters, and set shell variables accordingly #
 281 dnl ######################################################################
 282
 283 dnl FIXME: simplify all this down using a few m4 macros
 284
 285 AC_ARG_ENABLE(fast-stack-trash,
 286 AC_HELP_STRING([--enable-fast-stack-trash],[use fast memory allocator (i586 or above)]),
 287 [case "${enableval}" in
 288   yes) USE_FAST_STACK_TRASH=yes;;
 289   noset) USE_FAST_STACK_TRASH=no;;
 290   no)  USE_FAST_STACK_TRASH=no;;
 291   *) AC_MSG_ERROR(bad value ${enableval} for --enable-atomic) ;;
 292 esac],
 293 [USE_FAST_STACK_TRASH=yes]) dnl Default value
 294
 295 AC_ARG_ENABLE(profiling,
 296 AC_HELP_STRING([--enable-profiling],[adds -pg to compiler commandline, for profiling]),
 297 [case "${enableval}" in
 298   yes) USE_PROFILING=yes ;;
 299   no)  USE_PROFILING=no ;;
 300   *) AC_MSG_ERROR(bad value ${enableval} for --enable-profiling) ;;
 301 esac],
 302 [USE_PROFILING=no]) dnl Default value
 303
 304 dnl use a cache dir for storing element registry info.
 305 GST_CACHE_DIR=${localstatedir}/cache/gstreamer-$GST_MAJORMINOR
 306
 307 AC_ARG_WITH(cachedir,
 308 AC_HELP_STRING([--with-cachedir],[specify path to use for plugin and command completion registries]),
 309 [case "${withval}" in
 310   yes) AC_MSG_ERROR(bad value ${withval} for --with-cachedir) ;;
 311   no) AC_MSG_ERROR(bad value ${withval} for --with-cachedir) ;;
 312   *) GST_CACHE_DIR="${withval}" ;;
 313 esac],
 314 [:]) dnl Default value
 315
 316 AS_AC_EXPAND(GST_CACHE_DIR, $GST_CACHE_DIR)
 317 AC_DEFINE_UNQUOTED(GST_CACHE_DIR, "$GST_CACHE_DIR", [Location of registry])
 318 AC_MSG_NOTICE(Using $GST_CACHE_DIR as registry cache dir)
 319
 320 dnl building of tests
 321 AC_ARG_ENABLE(tests,
 322 AC_HELP_STRING([--disable-tests],[disable building test apps]),
 323 [case "${enableval}" in
 324   yes) BUILD_TESTS=yes ;;
 325   no)  BUILD_TESTS=no ;;
 326   *) AC_MSG_ERROR(bad value ${enableval} for --disable-tests) ;;
 327 esac],
 328 [BUILD_TESTS=yes]) dnl Default value
 329 AM_CONDITIONAL(BUILD_TESTS,         test "x$BUILD_TESTS" = "xyes")
 330
 331 dnl tests known to fail
 332 AC_ARG_ENABLE(failing-tests,
 333 AC_HELP_STRING([--disable-failing-tests],[disable building tests known to fail]),
 334 [case "${enableval}" in
 335   yes) BUILD_FAILING_TESTS=yes ;;
 336   no)  BUILD_FAILING_TESTS=no ;;
 337   *) AC_MSG_ERROR(bad value ${enableval} for --disable-failing-tests) ;;
 338 esac],
 339 [BUILD_FAILING_TESTS=no]) dnl Default value
 340 AM_CONDITIONAL(BUILD_FAILING_TESTS, test "x$BUILD_FAILING_TESTS" = "xyes")
 341 if test x$BUILD_FAILING_TESTS = xyes; then
 342   AC_MSG_WARN([building tests known to fail, use --disable-failing-tests to disable])
 343 else
 344   AC_MSG_WARN([Sissy ! By asking to not build the tests known to fail, you hereby waive your right to customer support.  If you do not agree with this EULA, please press Ctrl-C before the next line is printed.  By allowing the next line to be printed, you expressly acknowledge your acceptance of this EULA.])
 345 fi
 346
 347 AC_ARG_ENABLE(examples,
 348 AC_HELP_STRING([--disable-examples],[disable building examples]),
 349 [case "${enableval}" in
 350   yes) BUILD_EXAMPLES=yes ;;
 351   no)  BUILD_EXAMPLES=no ;;
 352   *) AC_MSG_ERROR(bad value ${enableval} for --disable-examples) ;;
 353 esac],
 354 [BUILD_EXAMPLES=yes]) dnl Default value
 355 AM_CONDITIONAL(BUILD_EXAMPLES,      test "x$BUILD_EXAMPLES" = "xyes")
 356
 357 dnl poison destroyed objects
 358 AC_ARG_ENABLE(poisoning,
 359 AC_HELP_STRING([--enable-poisoning],[enable poisoning of deallocated objects]),
 360 [case "${enableval}" in
 361   yes) USE_POISONING=yes ;;
 362   no)  USE_POISONING=no ;;
 363   *) AC_MSG_ERROR(bad value ${enableval} for --enable-poisoning) ;;
 364 esac],
 365 [USE_POISONING=no]) dnl Default value
 366
 367 dnl Next, check for the optional components:
 368 dnl ========================================
 369
 370 dnl debugging stuff
 371 AC_ARG_ENABLE(debug,
 372 AC_HELP_STRING([--disable-debug],[disable addition of -g debugging info]),
 373 [case "${enableval}" in
 374   yes) USE_DEBUG=yes ;;
 375   no)  USE_DEBUG=no ;;
 376   *) AC_MSG_ERROR(bad value ${enableval} for --enable-debug) ;;
 377 esac],
 378 [USE_DEBUG=yes]) dnl Default value
 379
 380 dnl valgrind inclusion
 381 AC_ARG_ENABLE(valgrind,
 382 AC_HELP_STRING([--disable-valgrind],[disable run-time valgrind detection]),
 383 [case "${enableval}" in
 384   yes) USE_VALGRIND="$USE_DEBUG" ;;
 385   no)  USE_VALGRIND=no ;;
 386   *) AC_MSG_ERROR(bad value ${enableval} for --enable-valgrind) ;;
 387 esac],
 388 [USE_VALGRIND="$USE_DEBUG"]) dnl Default value
 389 VALGRIND_REQ="2.1"
 390 if test "x$USE_VALGRIND" = xyes; then
 391
 392   PKG_CHECK_MODULES(VALGRIND, valgrind > $VALGRIND_REQ, USE_VALGRIND="yes", USE_VALGRIND="no")
 393 fi
 394 if test "x$USE_VALGRIND" = xyes; then
 395   AC_DEFINE(HAVE_VALGRIND, 1, [Define if valgrind should be used])
 396   AC_MSG_NOTICE(Using extra code paths for valgrind)
 397 fi
 398 AC_SUBST(VALGRIND_CFLAGS)
 399 AC_SUBST(VALGRIND_LIBS)
 400
 401 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 402 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 403
 404 dnl ################################################
 405 dnl # Set defines according to variables set above #
 406 dnl ################################################
 407
 408
 409 dnl These should be "USE_*" instead of "HAVE_*", but some packages expect
 410 dnl HAVE_ and it is likely to be easier to stick with the old name
 411 if test "x$USE_FAST_STACK_TRASH" = xyes; then
 412   AC_DEFINE(USE_FAST_STACK_TRASH, 1, [Define if we should use i586 optimized stack functions])
 413 fi
 414
 415 if test "x$USE_POISONING" = xyes; then
 416   AC_DEFINE(USE_POISONING, 1, [Define if we should poison deallocated memory])
 417 fi
 418
 419 dnl test for sigaction()
 420 AC_CHECK_FUNC(sigaction,
 421    AC_DEFINE(HAVE_SIGACTION, 1,
 422              [Defined if we have sigaction ()]))
 423
 424 dnl test for register_printf_function
 425 AC_CHECK_FUNC(register_printf_function,
 426   [
 427     GST_PRINTF_EXTENSION_FORMAT_DEFINE="#define GST_PTR_FORMAT \"P\""
 428     AC_DEFINE(HAVE_PRINTF_EXTENSION, 1,
 429              [Defined if we have register_printf_function ()])
 430   ],
 431   GST_PRINTF_EXTENSION_FORMAT_DEFINE="#define GST_PTR_FORMAT \"p\""
 432 )
 433 AC_SUBST(GST_PRINTF_EXTENSION_FORMAT_DEFINE)
 434
 435 dnl test if we have dladdr(); we use it for debugging
 436 save_cflags="$CFLAGS"
 437 CFLAGS="$CFLAGS -D_GNU_SOURCE"
 438 AC_CHECK_LIB(dl, dladdr,
 439    AC_DEFINE(HAVE_DLADDR, 1,
 440              [Defined if we have dladdr ()]))
 441 CFLAGS="$save_cflags"
 442
 443 if test "x$USE_DEBUG" = xyes; then
 444    GST_INT_CFLAGS="$GST_INT_CFLAGS -g"
 445 fi
 446
 447 dnl #############################
 448 dnl # Set automake conditionals #
 449 dnl #############################
 450
 451 dnl These should be "USE_*" instead of "HAVE_*", but some packages expect
 452 dnl HAVE_ and it is likely to be easier to stick with the old name
 453 AM_CONDITIONAL(EXPERIMENTAL,        test "x$EXPERIMENTAL" = "xyes")
 454 AM_CONDITIONAL(BROKEN,              test "x$BROKEN" = "xyes")
 455
 456 dnl ############################
 457 dnl # Set up some more defines #
 458 dnl ############################
 459
 460 dnl set license and copyright notice
 461 AC_DEFINE(GST_LICENSE, "LGPL", [GStreamer license])
 462
 463 dnl package name in plugins
 464 AC_ARG_WITH(package-name,
 465 AC_HELP_STRING([--with-package-name],[specify package name to use in plugins]),
 466 [case "${withval}" in
 467   yes) AC_MSG_ERROR(bad value ${withval} for --with-package-name) ;;
 468   no) AC_MSG_ERROR(bad value ${withval} for --with-package-name) ;;
 469   *) GST_PACKAGE="${withval}" ;;
 470 esac],
 471 [
 472 dnl default value
 473 if test "x$GST_CVS" = "xyes"
 474 then
 475   dnl nano >= 1
 476   GST_PACKAGE="GStreamer CVS/prerelease"
 477 else
 478   GST_PACKAGE="GStreamer source release"
 479 fi
 480 ]
 481 )
 482 AC_MSG_NOTICE(Using $GST_PACKAGE as package name)
 483 AC_DEFINE_UNQUOTED(GST_PACKAGE, "$GST_PACKAGE", [package name in plugins])
 484
 485 dnl package origin URL
 486 AC_ARG_WITH(package-origin,
 487 AC_HELP_STRING([--with-package-origin],[specify package origin URL to use in plugins]),
 488 [case "${withval}" in
 489   yes) AC_MSG_ERROR(bad value ${withval} for --with-package-origin) ;;
 490   no) AC_MSG_ERROR(bad value ${withval} for --with-package-origin) ;;
 491   *) GST_ORIGIN="${withval}" ;;
 492 esac],
 493 [GST_ORIGIN="http://gstreamer.freedesktop.org/"]) dnl Default value
 494 AC_MSG_NOTICE(Using $GST_ORIGIN as package origin)
 495 AC_DEFINE_UNQUOTED(GST_ORIGIN, "$GST_ORIGIN", [package origin])
 496
 497 dnl Set location of plugin directory
 498 AS_AC_EXPAND(PLUGINS_DIR, ${libdir}/gstreamer-$GST_MAJORMINOR)
 499 AC_DEFINE_UNQUOTED(PLUGINS_DIR, "$PLUGINS_DIR", [Define the plugin directory])
 500 AC_SUBST(PLUGINS_DIR)
 501 AC_MSG_NOTICE([Using $PLUGINS_DIR as the plugin install location])
 502
 503 dnl LDFLAGS modifier defining exported symbols from built objects
 504 EXPORT_LDFLAGS="-export-symbols-regex [_]*\(gst_\|Gst\|GST_\).*"
 505
 506 dnl GST_PKG_*:    the flags we use that are also used
 507 dnl               for external applications/.pc file
 508 dnl GST_LIB_*:    used for the main library
 509 dnl GST_OBJ_*:    the flags we use for all the objects internal to the core
 510 dnl GST_PLUGIN_*: additional flags we use for all plugins
 511
 512 dnl finalize _CFLAGS and _LIBS
 513 dnl flags exported for external applications and use in our pkg-config .pc files
 514 dnl since glib and xml are package deps, there's no need to include their cflags
 515 dnl in the pkg-config file
 516
 517 GST_PKG_DEPS="glib-2.0, gobject-2.0, gmodule-2.0, gthread-2.0"
 518 AC_SUBST(GST_PKG_CFLAGS)
 519 AC_SUBST(GST_PKG_LIBS)
 520 AC_SUBST(GST_PKG_DEPS)
 521
 522 dnl flags shared for all internal objects (core libs, elements, applications)
 523 dnl we disable deprecated internally
 524 dnl XML, GLib, popt, GST_INT, VALGRIND, and the right include for CFLAGS
 525 dnl no need to add XML, GLib, popt explicitly since libgstreamer pulls them in
 526 GST_INT_CFLAGS="$GLIB_CFLAGS $XML_CFLAGS $GST_PKG_CFLAGS \
 527  $GST_INT_CFLAGS \$(ERROR_CFLAGS) -DGST_DISABLE_DEPRECATED"
 528
 529 dnl Private vars for libgst only
 530 GST_LIB_CFLAGS="$GST_PKG_CFLAGS $GST_INT_CFLAGS \
 531   $VALGRIND_CFLAGS -I\$(top_srcdir)"
 532 GST_LIB_LIBS="$XML_LIBS $GLIB_LIBS -lpopt $GST_PKG_LIBS $LTLIBINTL $VALGRIND_LIBS"
 533 GST_LIB_LDFLAGS="$GST_LT_LDFLAGS -version-info $GST_LIBVERSION -no-undefined $EXPORT_LDFLAGS"
 534 AC_SUBST(GST_LIB_CFLAGS)
 535 AC_SUBST(GST_LIB_LIBS)
 536 AC_SUBST(GST_LIB_LDFLAGS)
 537
 538 dnl Vars for all internal objects built on libgstreamer
 539 GST_OBJ_CFLAGS="$GST_INT_CFLAGS -I\$(top_srcdir)/libs -I\$(top_srcdir)"
 540 GST_OBJ_LIBS="\$(top_builddir)/gst/libgstreamer-$GST_MAJORMINOR.la"
 541
 542 AC_SUBST(GST_OBJ_CFLAGS, "$GST_OBJ_CFLAGS")
 543 AC_SUBST(GST_OBJ_LIBS, "$GST_OBJ_LIBS")
 544
 545 dnl specific additional LDFLAGS for plugins
 546 GST_PLUGIN_LDFLAGS="-module -avoid-version -no-undefined $EXPORT_LDFLAGS"
 547 AC_SUBST(GST_PLUGIN_LDFLAGS, "$GST_PLUGIN_LDFLAGS")
 548
 549 plugindir="\$(libdir)/gstreamer-$GST_MAJORMINOR"
 550 AC_SUBST(plugindir)
 551
 552 dnl ##################################################
 553 dnl # deps for examples from manual                  #
 554 dnl ##################################################
 555
 556 PKG_CHECK_MODULES(LIBGNOMEUI, libgnomeui-2.0,
 557                   HAVE_LIBGNOMEUI="yes", HAVE_LIBGNOMEUI="no")
 558 AC_SUBST(LIBGNOMEUI_CFLAGS)
 559 AC_SUBST(LIBGNOMEUI_LIBS)
 560 AM_CONDITIONAL(HAVE_LIBGNOMEUI, test "x$HAVE_LIBGNOMEUI" = "xyes")
 561
 562 dnl ##################################################
 563 dnl # Prepare informative messages to display at end #
 564 dnl ##################################################
 565
 566 infomessages=
 567
 568 dnl #########################
 569 dnl # Make the output files #
 570 dnl #########################
 571
 572 dnl libs/ext/Makefile
 573 dnl nothing there yet !
 574 AC_OUTPUT(
 575 Makefile
 576 gst/Makefile
 577 gst/gstconfig.h
 578 gst/gstversion.h
 579 gst/base/Makefile
 580 gst/check/Makefile
 581 gst/indexers/Makefile
 582 gst/elements/Makefile
 583 gst/parse/Makefile
 584 libs/Makefile
 585 libs/gst/Makefile
 586 libs/gst/controller/Makefile
 587 libs/gst/dataprotocol/Makefile
 588 po/Makefile.in
 589 check/Makefile
 590 tests/Makefile
 591 tests/instantiate/Makefile
 592 tests/muxing/Makefile
 593 tests/seeking/Makefile
 594 tests/sched/Makefile
 595 tests/threadstate/Makefile
 596 testsuite/Makefile
 597 testsuite/bytestream/Makefile
 598 testsuite/caps/Makefile
 599 testsuite/cleanup/Makefile
 600 testsuite/controller/Makefile
 601 testsuite/debug/Makefile
 602 testsuite/dlopen/Makefile
 603 testsuite/elements/Makefile
 604 testsuite/indexers/Makefile
 605 testsuite/negotiation/Makefile
 606 testsuite/pad/Makefile
 607 testsuite/parse/Makefile
 608 testsuite/plugin/Makefile
 609 testsuite/refcounting/Makefile
 610 testsuite/schedulers/Makefile
 611 testsuite/states/Makefile
 612 testsuite/threads/Makefile
 613 testsuite/trigger/Makefile
 614 examples/Makefile
 615 examples/controller/Makefile
 616 examples/cutter/Makefile
 617 examples/helloworld/Makefile
 618 examples/launch/Makefile
 619 examples/manual/Makefile
 620 examples/mixer/Makefile
 621 examples/metadata/Makefile
 622 examples/pingpong/Makefile
 623 examples/plugins/Makefile
 624 examples/pwg/Makefile
 625 examples/queue/Makefile
 626 examples/retag/Makefile
 627 examples/thread/Makefile
 628 examples/typefind/Makefile
 629 examples/xml/Makefile
 630 tools/Makefile
 631 common/Makefile
 632 common/m4/Makefile
 633 docs/Makefile
 634 docs/faq/Makefile
 635 docs/gst/Makefile
 636 docs/libs/Makefile
 637 docs/manual/Makefile
 638 docs/pwg/Makefile
 639 docs/xsl/Makefile
 640 docs/version.entities
 641 pkgconfig/Makefile
 642 stamp.h
 643 pkgconfig/gstreamer.pc
 644 pkgconfig/gstreamer-uninstalled.pc
 645 pkgconfig/gstreamer-base.pc
 646 pkgconfig/gstreamer-base-uninstalled.pc
 647 pkgconfig/gstreamer-check.pc
 648 pkgconfig/gstreamer-check-uninstalled.pc
 649 pkgconfig/gstreamer-controller.pc
 650 pkgconfig/gstreamer-controller-uninstalled.pc
 651 pkgconfig/gstreamer-dataprotocol.pc
 652 pkgconfig/gstreamer-dataprotocol-uninstalled.pc
 653 gstreamer.spec,
 654 echo "$infomessages", infomessages="$infomessages"
 655 )