configure.ac

   1 AC_PREREQ(2.62)
   2 dnl initialize autoconf
   3 dnl when going to/from release please set the nano (fourth number) right !
   4 dnl releases only do Wall, cvs and prerelease does Werror too
   5 AC_INIT(Gst-RTSP, 0.11.90.1,
   6     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
   7     gst-rtsp)
   8 AG_GST_INIT
   9
  10 dnl initialize automake
  11 AM_INIT_AUTOMAKE([-Wno-portability 1.11 no-dist-gzip dist-xz tar-ustar])
  12
  13 dnl define PACKAGE_VERSION_* variables
  14 AS_VERSION
  15
  16 dnl check if this is a release version
  17 AS_NANO(GST_GIT="no", GST_GIT="yes")
  18
  19 dnl can autoconf find the source ?
  20 AC_CONFIG_SRCDIR([gst/rtsp-server/rtsp-server.c])
  21
  22 dnl define the output header for config
  23 AM_CONFIG_HEADER([config.h])
  24
  25 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  26 AM_MAINTAINER_MODE([enable])
  27
  28 dnl sets host_* variables
  29 AC_CANONICAL_HOST
  30
  31 dnl use pretty build output with automake >= 1.11
  32 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],
  33   [AM_DEFAULT_VERBOSITY=1
  34    AC_SUBST(AM_DEFAULT_VERBOSITY)])
  35
  36 dnl our libraries and install dirs use major.minor as a version
  37 dnl GST_API_VERSION=$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR
  38 dnl we override it here if we need to for the release candidate of new series
  39 GST_API_VERSION=1.0
  40 AC_SUBST(GST_API_VERSION)
  41
  42 AS_LIBTOOL(GST, 0, 0, 0)
  43
  44 dnl *** required versions of GStreamer stuff ***
  45 GST_REQ=1.0.0
  46 GSTPB_REQ=1.0.0
  47 GSTPG_REQ=1.0.0
  48
  49 dnl *** autotools stuff ****
  50
  51 dnl allow for different autotools
  52 AS_AUTOTOOLS_ALTERNATE
  53
  54 dnl Add parameters for aclocal
  55 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  56 AC_CONFIG_MACRO_DIR([m4])
  57
  58 dnl set up gettext
  59 dnl the version check needs to stay here because autopoint greps for it
  60 AM_GNU_GETTEXT_VERSION([0.17])
  61 AM_GNU_GETTEXT([external])
  62 AG_GST_GETTEXT([gstreamer-$GST_API_VERSION])
  63
  64 dnl *** check for arguments to configure ***
  65
  66 AG_GST_ARG_DEBUG
  67 AG_GST_ARG_VALGRIND
  68 AG_GST_ARG_GCOV
  69 AG_GST_ARG_WITH_PACKAGE_NAME
  70 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  71
  72 AG_GST_PKG_CONFIG_PATH
  73
  74 dnl *** checks for platform ***
  75
  76 dnl * hardware/architecture *
  77
  78 dnl *** checks for programs ***
  79
  80 dnl find a compiler
  81 AC_PROG_CC
  82 AM_PROG_CC_C_O
  83
  84 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
  85 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
  86
  87 dnl check for gobject-introspection
  88 GOBJECT_INTROSPECTION_CHECK([0.6.3])
  89
  90 dnl check for documentation tools
  91 AG_GST_DOCBOOK_CHECK
  92 GTK_DOC_CHECK([1.3])
  93
  94 dnl Check for Vala
  95 AC_ARG_ENABLE([vala],
  96   AC_HELP_STRING([--enable-vala],[enable Vala bindings (default=yes)]),
  97   [case "${enableval}" in
  98     yes) enable_vala=yes ;;
  99     no)  enable_vala=no ;;
 100     *) AC_MSG_ERROR(bad value ${enableval} for --enable-vala) ;;
 101    esac
 102   ],
 103   [enable_vala=yes]) dnl Default value
 104 AM_CONDITIONAL(WITH_VALA, [test "x$enable_vala" = "xyes"])
 105
 106 dnl *** checks for libraries ***
 107
 108 dnl *** checks for header files ***
 109
 110 dnl *** checks for types/defines ***
 111
 112 dnl *** checks for structures ***
 113
 114 dnl *** checks for compiler characteristics ***
 115
 116 dnl *** checks for library functions ***
 117
 118 dnl *** checks for dependancy libraries ***
 119
 120 dnl GLib is required (GStreamer is ok with GLib-2.8, but we want at least 2.10)
 121 GLIB_REQ=2.10.0
 122 AC_SUBST([GLIB_REQ])
 123 AG_GST_GLIB_CHECK([$GLIB_REQ])
 124
 125 dnl checks for gstreamer
 126 dnl uninstalled is selected preferentially -- see pkg-config(1)
 127 AG_GST_CHECK_GST($GST_API_VERSION, [$GST_REQ], [yes])
 128
 129 GST_TOOLS_DIR=`$PKG_CONFIG --variable=toolsdir gstreamer-$GST_API_VERSION`
 130 if test -z $GST_TOOLS_DIR; then
 131   AC_MSG_ERROR([no tools dir defined in GStreamer pkg-config file; core upgrade needed.])
 132 fi
 133 AC_SUBST(GST_TOOLS_DIR)
 134
 135 GST_PLUGINS_DIR=`$PKG_CONFIG gstreamer-$GST_API_VERSION --variable pluginsdir`
 136 AC_SUBST(GST_PLUGINS_DIR)
 137 AC_MSG_NOTICE(Using GStreamer Core Plugins in $GST_PLUGINS_DIR)
 138
 139 AG_GST_CHECK_GST_BASE($GST_API_VERSION, [$GST_REQ], [yes])
 140
 141 AG_GST_CHECK_GST_PLUGINS_BASE($GST_API_VERSION, [$GSTPB_REQ], [yes])
 142 GSTPB_PLUGINS_DIR=`$PKG_CONFIG gstreamer-plugins-base-$GST_API_VERSION --variable pluginsdir`
 143 AC_SUBST(GSTPB_PLUGINS_DIR)
 144 AC_MSG_NOTICE(Using GStreamer Base Plugins in $GSTPB_PLUGINS_DIR)
 145
 146 AG_GST_CHECK_GST_PLUGINS_GOOD($GST_API_VERSION, [$GSTPG_REQ], [yes])
 147 GSTPG_PLUGINS_DIR=`$PKG_CONFIG gstreamer-plugins-good-$GST_API_VERSION --variable pluginsdir`
 148 AC_SUBST(GSTPG_PLUGINS_DIR)
 149 AC_MSG_NOTICE(Using GStreamer Good Plugins in $GSTPG_PLUGINS_DIR)
 150
 151 AG_GST_CHECK_GST_CHECK($GST_API_VERSION, [$GST_REQ], no)
 152
 153 dnl FIXME: get rid of this by making sure gstreamer-check brings it in
 154 dnl check for "check", unit testing library/header
 155 AM_PATH_CHECK(0.9.2, HAVE_CHECK=yes, HAVE_CHECK=no)
 156 AM_CONDITIONAL(HAVE_CHECK, test "x$HAVE_CHECK" = "xyes")
 157
 158 dnl *** set variables based on configure arguments ***
 159
 160 dnl set license and copyright notice
 161 GST_LICENSE="LGPL"
 162 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 163 AC_SUBST(GST_LICENSE)
 164
 165 dnl set location of plugin directory
 166 AG_GST_SET_PLUGINDIR
 167
 168 # set by AG_GST_PARSE_SUBSYSTEM_DISABLES above
 169 dnl make sure it doesn't complain about unused variables if debugging is disabled
 170 NO_WARNINGS=""
 171 AG_GST_CHECK_GST_DEBUG_DISABLED([NO_WARNINGS="-Wno-unused"], [NO_WARNINGS=""])
 172
 173 dnl define an ERROR_CFLAGS Makefile variable
 174 AG_GST_SET_ERROR_CFLAGS($GST_GIT, [$NO_WARNINGS])
 175
 176 dnl define correct level for debugging messages
 177 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 178
 179 dnl used in examples
 180 AG_GST_DEFAULT_ELEMENTS
 181
 182 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 183
 184 dnl Overview:
 185 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
 186 dnl GST_*:              flags shared by built objects to link against GStreamer
 187 dnl GST_ALL_LDFLAGS:    linker flags shared by all
 188 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 189 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 190 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 191
 192 dnl GST_OPTION_CFLAGS
 193 if test "x$USE_DEBUG" = xyes; then
 194    PROFILE_CFLAGS="-g"
 195 fi
 196 AC_SUBST(PROFILE_CFLAGS)
 197
 198 DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 199 AC_SUBST(DEPRECATED_CFLAGS)
 200
 201 dnl every flag in GST_OPTION_CFLAGS can be overridden at make time
 202 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 203 AC_SUBST(GST_OPTION_CFLAGS)
 204
 205 dnl FIXME: do we want to rename to GST_ALL_* ?
 206 dnl prefer internal headers to already installed ones
 207 dnl add GST_OPTION_CFLAGS, but overridable
 208 GST_CFLAGS="$GST_CFLAGS -DGST_USE_UNSTABLE_API \$(GST_OPTION_CFLAGS)"
 209 AC_SUBST(GST_CFLAGS)
 210 AC_SUBST(GST_LIBS)
 211
 212 dnl GST_ALL_*
 213 dnl vars common to for all internal objects (core libs, elements, applications)
 214 dnl CFLAGS:
 215 dnl - src and build dirs need to be added because every piece that gets built
 216 dnl   will need the GStreamer source and generated headers
 217 GST_ALL_CFLAGS="-I\$(top_srcdir) -I\$(top_builddir) $GST_PLUGINS_BASE_CFLAGS $GST_CFLAGS \$(GST_OPTION_CFLAGS)"
 218 AC_SUBST([GST_ALL_CFLAGS])
 219
 220 dnl FIXME: check if LTLIBINTL is needed everywhere
 221 dnl I presume it is given that it contains the symbols that _() stuff maps to
 222 GST_ALL_LIBS="$GST_LIBS $LTLIBINTL \$(GCOV_LIBS)"
 223 AC_SUBST([GST_ALL_LIBS])
 224
 225 dnl LDFLAGS really should only contain flags, not libs - they get added before
 226 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 227 GST_ALL_LDFLAGS="-no-undefined"
 228 AC_SUBST(GST_ALL_LDFLAGS)
 229
 230 dnl GST_LIB_LDFLAGS
 231 dnl linker flags shared by all libraries
 232 dnl LDFLAGS modifier defining exported symbols from built libraries
 233 GST_LIB_LDFLAGS="-export-symbols-regex \^[_]?\(gst_\|Gst\|GST_\).*"
 234 AC_SUBST(GST_LIB_LDFLAGS)
 235
 236 dnl GST_OBJ_*
 237 dnl default vars for all internal objects built on libgstrtspserver
 238 dnl includes GST_ALL_*
 239 GST_OBJ_CFLAGS="\$(GST_ALL_CFLAGS)"
 240 AC_SUBST([GST_OBJ_CFLAGS])
 241 GST_OBJ_LIBS="\$(top_builddir)/gst/rtsp-server/libgstrtspserver-$GST_API_VERSION.la \$(GST_ALL_LIBS)"
 242 AC_SUBST([GST_OBJ_LIBS])
 243
 244 dnl this really should only contain flags, not libs - they get added before
 245 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 246
 247 dnl *** output files ***
 248
 249 dnl keep this alphabetic per directory, please
 250 AC_CONFIG_FILES([
 251 Makefile
 252 gst-rtsp.spec
 253 common/Makefile
 254 common/m4/Makefile
 255 gst/Makefile
 256 gst/rtsp-server/Makefile
 257 examples/Makefile
 258 tests/Makefile
 259 tests/check/Makefile
 260 bindings/Makefile
 261 bindings/vala/Makefile
 262 pkgconfig/Makefile
 263 pkgconfig/gstreamer-rtsp-server.pc
 264 pkgconfig/gstreamer-rtsp-server-uninstalled.pc
 265 docs/Makefile
 266 docs/version.entities
 267 docs/libs/Makefile
 268 ])
 269 AC_OUTPUT
 270
 271 echo "
 272
 273 Configuration
 274         Version                    : ${VERSION}
 275         Source code location       : ${srcdir}
 276         Prefix                     : ${prefix}
 277         Compiler                   : ${CC}
 278         Vala bindings              : ${enable_vala}
 279
 280 gst-rtsp-server configured. Type 'make' to build.
 281 "