configure.ac

   1 AC_PREREQ(2.52)
   2
   3 AC_INIT
   4 AC_CANONICAL_TARGET
   5
   6 dnl when going to/from release please set the nano (fourth number) right !
   7 dnl releases only do Wall, cvs and prerelease does Werror too
   8 AS_VERSION(gstreamer, GST_VERSION, 0, 9, 2, 1,
   9     GST_CVS="no", GST_CVS="yes")
  10
  11 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  12 AM_MAINTAINER_MODE
  13 AM_INIT_AUTOMAKE($PACKAGE,$VERSION)
  14
  15 dnl our libraries and install dirs use major.minor as a version
  16 GST_MAJORMINOR=$GST_VERSION_MAJOR.$GST_VERSION_MINOR
  17 dnl we override it here for release candidates for a new series
  18 # GST_MAJORMINOR=0.9
  19 AC_SUBST(GST_MAJORMINOR)
  20
  21 AC_PROG_CC
  22 dnl For interactive UNIX (a Sun thing)
  23 AC_ISC_POSIX
  24
  25 dnl CURRENT, REVISION, AGE
  26 dnl - library source changed -> increment REVISION
  27 dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
  28 dnl - interfaces added -> increment AGE
  29 dnl - interfaces removed -> AGE = 0
  30 AS_LIBTOOL(GST, 6, 0, 0)
  31 AS_LIBTOOL_TAGS([])
  32 AM_PROG_LIBTOOL
  33
  34 AC_CONFIG_SRCDIR([gst/gst.c])
  35 AM_CONFIG_HEADER(config.h)
  36
  37 dnl Add parameters for aclocal
  38 AC_SUBST(ACLOCAL_AMFLAGS, "-I common/m4 -I .")
  39
  40 AM_PROG_CC_STDC
  41 AM_PROG_AS
  42 AS="${CC}"
  43
  44 dnl the gettext stuff needed
  45 AM_GNU_GETTEXT_VERSION(0.11.5)
  46 AM_GNU_GETTEXT([external])
  47
  48 GETTEXT_PACKAGE=gstreamer-$GST_MAJORMINOR
  49 AC_SUBST(GETTEXT_PACKAGE)
  50 AC_DEFINE_UNQUOTED([GETTEXT_PACKAGE], "$GETTEXT_PACKAGE",
  51                    [gettext package name])
  52
  53 dnl define LOCALEDIR in config.h
  54 AS_AC_EXPAND(LOCALEDIR, $datadir/locale)
  55 AC_DEFINE_UNQUOTED([LOCALEDIR], "$LOCALEDIR",
  56                    [gettext locale dir])
  57
  58 dnl define LIBDIR so we can inform people where we live
  59 AS_AC_EXPAND(LIBDIR, $libdir)
  60 AC_DEFINE_UNQUOTED([LIBDIR], "$LIBDIR",
  61                    [library dir])
  62
  63 GST_SET_ERROR_CFLAGS($GST_CVS)
  64
  65 dnl We disable static building for development, for time savings
  66 dnl *NOTE*: dnl this line before release, so release does static too
  67 dnl AM_DISABLE_STATIC
  68
  69 AC_HEADER_STDC([])
  70 AC_C_INLINE
  71
  72 dnl define correct errorlevel for debugging messages. We want to have GST_ERROR
  73 dnl messages printed when running cvs builds
  74 if test "x$GST_CVS" = "xyes"; then
  75   AC_DEFINE(GST_LEVEL_DEFAULT, GST_LEVEL_ERROR, [Default errorlevel to use])
  76 fi
  77
  78 dnl subsystems - can influence other decisions so needs to be high up
  79 dnl we need to do AM_CONDITIONAL them here for automake 1.6.x compatibility
  80 GST_CHECK_SUBSYSTEM_DISABLE(GST_DEBUG,[debugging subsystem])
  81 AM_CONDITIONAL(GST_DISABLE_GST_DEBUG, test "x$GST_DISABLE_GST_DEBUG" = "xyes")
  82 GST_CHECK_SUBSYSTEM_DISABLE(LOADSAVE,[pipeline XML load/save])
  83 AM_CONDITIONAL(GST_DISABLE_LOADSAVE, test "x$GST_DISABLE_LOADSAVE" = "xyes")
  84 GST_CHECK_SUBSYSTEM_DISABLE(PARSE,[command-line parser])
  85 AM_CONDITIONAL(GST_DISABLE_PARSE, test "x$GST_DISABLE_PARSE" = "xyes")
  86 GST_CHECK_SUBSYSTEM_DISABLE(TRACE,[tracing subsystem])
  87 AM_CONDITIONAL(GST_DISABLE_TRACE, test "x$GST_DISABLE_TRACE" = "xyes")
  88 GST_CHECK_SUBSYSTEM_DISABLE(ALLOC_TRACE,[allocation tracing])
  89 AM_CONDITIONAL(GST_DISABLE_ALLOC_TRACE, test "x$GST_DISABLE_ALLOC_TRACE" = "xyes")
  90 GST_CHECK_SUBSYSTEM_DISABLE(REGISTRY,[plugin registry])
  91 AM_CONDITIONAL(GST_DISABLE_REGISTRY, test "x$GST_DISABLE_REGISTRY" = "xyes")
  92 GST_CHECK_SUBSYSTEM_DISABLE(ENUMTYPES,[enum types])
  93 AM_CONDITIONAL(GST_DISABLE_ENUMTYPES, test "x$GST_DISABLE_ENUMTYPES" = "xyes")
  94 GST_CHECK_SUBSYSTEM_DISABLE(INDEX,[index])
  95 AM_CONDITIONAL(GST_DISABLE_INDEX, test "x$GST_DISABLE_INDEX" = "xyes")
  96 GST_CHECK_SUBSYSTEM_DISABLE(PLUGIN,[plugin])
  97 AM_CONDITIONAL(GST_DISABLE_PLUGIN, test "x$GST_DISABLE_PLUGIN" = "xyes")
  98 GST_CHECK_SUBSYSTEM_DISABLE(URI,[uri handlers])
  99 AM_CONDITIONAL(GST_DISABLE_URI, test "x$GST_DISABLE_URI" = "xyes")
 100
 101 dnl ##############################
 102 dnl # Do automated configuration #
 103 dnl ##############################
 104
 105 dnl Check for tools:
 106 dnl ================
 107
 108 dnl allow for different autotools
 109 AS_AUTOTOOLS_ALTERNATE()
 110
 111 dnl modify pkg-config path
 112 AC_ARG_WITH(pkg-config-path,
 113    AC_HELP_STRING([--with-pkg-config-path],
 114                   [colon-separated list of pkg-config(1) dirs]),
 115    [export PKG_CONFIG_PATH=${withval}])
 116
 117 GST_ARCH()
 118
 119 dnl ### Documentation checks
 120
 121 dnl Perl is used in building documentation
 122 AC_PATH_PROG(PERL_PATH, perl, no)
 123 if test x$PERL_PATH = xno; then
 124   AC_MSG_ERROR(Could not find perl)
 125 fi
 126
 127 GST_DOCBOOK_CHECK
 128 GTK_DOC_CHECK([1.3])
 129
 130 AC_PROG_AWK
 131
 132 dnl we require bison for building the parser
 133 dnl FIXME: check if AC_PROG_YACC is suitable here
 134 AC_PATH_PROG(BISON_PATH, bison, no)
 135 if test x$BISON_PATH = xno; then
 136   AC_MSG_ERROR(Could not find bison)
 137 fi
 138
 139 dnl check bison version
 140 AC_MSG_CHECKING([bison version])
 141
 142 if $BISON_PATH --version | head -n 1 | $AWK '{ if ($4 < 1.35) exit 1; else exit 0;}';
 143 then
 144   AC_MSG_RESULT([ok])
 145 else
 146   AC_MSG_RESULT([too old.])
 147   AC_MSG_ERROR([Your bison version is too old, v1.35 or later is required.])
 148 fi
 149
 150 dnl we require flex for building the parser
 151 dnl FIXME: check if AC_PROG_LEX is suitable here
 152 AC_PATH_PROG(FLEX_PATH, flex, no)
 153 if test x$FLEX_PATH = xno; then
 154   AC_MSG_ERROR(Could not find flex)
 155 fi
 156
 157 dnl check for large file support (affected
 158 dnl plugins must include config.h for this)
 159 AC_SYS_LARGEFILE
 160
 161 dnl check for mmap
 162 AC_FUNC_MMAP()
 163
 164 dnl check for makecontext and define HAVE_MAKECONTEXT if we have it
 165 AC_CHECK_MCSC()
 166 if test "$ac_cv_check_mcsc" = "yes"; then
 167   AC_DEFINE_UNQUOTED(HAVE_MAKECONTEXT, $HAVE_MAKECONTEXT,
 168                      [defined if we have makecontext ()])
 169 fi
 170
 171 dnl Check for a way to display the function name in debug output
 172 GST_CHECK_FUNCTION()
 173
 174 dnl check if we should use -Wa,-mregnames on PowerPC, so we can use
 175 dnl symbolic register names in inline asm
 176 if test x$HAVE_CPU_PPC = xyes ; then
 177   AS_COMPILER_FLAG(["-Wa,-mregnames"],
 178     [GST_INT_CFLAGS="$GST_INT_CFLAGS -Wa,-mregnames"],
 179     true)
 180 fi
 181
 182 AC_ARG_ENABLE(gcov,
 183   AC_HELP_STRING([--enable-gcov],[compile with coverage profiling instrumentation (gcc only)]),
 184   enable_gcov=$enableval,enable_gcov=no)
 185 if test x$enable_gcov = xyes ; then
 186   AS_COMPILER_FLAG(["-fprofile-arcs"],
 187     [GST_INT_CFLAGS="$GST_INT_CFLAGS -fprofile-arcs"],
 188     true)
 189   AS_COMPILER_FLAG(["-ftest-coverage"],
 190     [GST_INT_CFLAGS="$GST_INT_CFLAGS -ftest-coverage"],
 191     true)
 192   GST_INT_CFLAGS=`echo "$GST_INT_CFLAGS" | sed -e 's/-O[0-9]*//g'`
 193
 194   AC_DEFINE_UNQUOTED(GST_GCOV_ENABLED, 1, [Defined if gcov is enabled to force a rebuild due to config.h changing])
 195 fi
 196 AM_CONDITIONAL(GST_GCOV_ENABLED, test x$enable_gcov = xyes)
 197
 198 dnl Check for some compiler flags that optimize our code.
 199 if test "x$GCC" = xyes; then
 200   AS_COMPILER_FLAG(-fno-common,GST_INT_CFLAGS="$GST_INT_CFLAGS -fno-common",)
 201 fi
 202
 203 dnl HAVE_WIN32 currently means "disable POSIXisms".
 204 case "$host" in
 205   *-*-mingw*)
 206     AC_DEFINE_UNQUOTED(HAVE_WIN32, 1, [Defined if compiling for Windows])
 207     ;;
 208   *)
 209     ;;
 210 esac
 211
 212 GST_UNALIGNED_ACCESS()
 213 if test x${as_cv_unaligned_access} = xyes ; then
 214   GST_HAVE_UNALIGNED_ACCESS_DEFINE="#define GST_HAVE_UNALIGNED_ACCESS 1"
 215 else
 216   GST_HAVE_UNALIGNED_ACCESS_DEFINE="#define GST_HAVE_UNALIGNED_ACCESS 0"
 217 fi
 218 AC_SUBST(GST_HAVE_UNALIGNED_ACCESS_DEFINE)
 219
 220 dnl Check for essential libraries first:
 221 dnl ====================================
 222
 223 dnl === GLib 2 ===
 224 dnl Minimum required version of GLib2
 225 dnl required for compilation without warnings
 226 GLIB2_REQ="2.4"
 227 AC_SUBST(GLIB2_REQ)
 228
 229 dnl Check for glib2 with sugar on top
 230 PKG_CHECK_MODULES(GLIB2, glib-2.0 >= $GLIB2_REQ gobject-2.0 gthread-2.0 gmodule-2.0,HAVE_GLIB2=yes,HAVE_GLIB2=no)
 231 dnl for the poor souls who for example have glib in /usr/local
 232 AS_SCRUB_INCLUDE(GLIB2_CFLAGS)
 233 GLIB_LIBS=$GLIB2_LIBS
 234 GLIB_CFLAGS=$GLIB2_CFLAGS
 235 AC_SUBST(GLIB_LIBS)
 236 AC_SUBST(GLIB_CFLAGS)
 237
 238 AC_MSG_CHECKING([glib version >= 2.8])
 239 if pkg-config --atleast-version=2.8 glib-2.0; then
 240   AC_MSG_RESULT(yes)
 241   AC_DEFINE(HAVE_GLIB_2_8, [1], [Define to 1 if we can use API new in glib-2.8])
 242 else
 243   AC_MSG_RESULT(no)
 244 fi
 245
 246 if test "x$HAVE_GLIB2" = "xno"; then
 247   AC_MSG_ERROR([GStreamer requires GLib $GLIB2_REQ to compile.])
 248 fi
 249
 250 dnl Check for glib2 without extra fat, useful for the unversioned tool frontends
 251 PKG_CHECK_MODULES(GLIB_ONLY, glib-2.0 >= $GLIB2_REQ)
 252 AC_SUBST(GLIB_ONLY_CFLAGS)
 253 AC_SUBST(GLIB_ONLY_LIBS)
 254
 255 dnl === libxml 2 ===
 256 if test "x$GST_DISABLE_LOADSAVE" = "xyes" && test "x$GST_DISABLE_REGISTRY" = "xyes"
 257 then
 258   AC_MSG_NOTICE([Registry and load/save are disabled, not checking for libxml2])
 259 else
 260   dnl check for libxml2 with minimum req version
 261   GST_LIBXML2_CHECK(2.4.9)
 262 fi
 263
 264 dnl popt checks
 265 dnl FIXME: This test passes on popt 1.6.2, maybe earlier, but popt 1.6.2
 266 dnl        causes segfaults on gst_init. Write a working test if possible.
 267 GST_CHECK_LIBHEADER(POPT, popt, poptStrippedArgv,, popt.h, POPT_LIBS="-lpopt",
 268   AC_MSG_ERROR([popt 1.6.3 or newer is required to build gstreamer. You can
 269                 download the latest version from
 270                 ftp://ftp.rpm.org/pub/rpm/dist/])
 271 )
 272 AC_MSG_NOTICE(Checking for POPT_TABLEEND)
 273 AC_COMPILE_IFELSE([
 274 #include <popt.h>
 275 int main ()
 276 {
 277 #ifndef POPT_TABLEEND
 278 #error
 279 #else
 280   return 0;
 281 #endif
 282 }
 283 ],, [
 284   dnl it failed
 285   AC_MSG_ERROR([popt 1.6.3 or newer is required to build gstreamer. You can
 286                 download the latest version from
 287                 ftp://ftp.rpm.org/pub/rpm/dist/])
 288 ])
 289 AC_SUBST(POPT_CFLAGS)
 290 AC_SUBST(POPT_LIBS)
 291
 292 dnl Check for ucontext.h
 293 AC_CHECK_HEADER(ucontext.h, AC_DEFINE(HAVE_UCONTEXT_H, 1, [defined if we have ucontext.h]))
 294
 295 dnl check for "check", unit testing library/header
 296 AM_PATH_CHECK(0.9.2,
 297     [
 298         HAVE_CHECK=yes
 299         AC_MSG_NOTICE(CHECK_CFLAGS: $CHECK_CFLAGS)
 300         AC_MSG_NOTICE(CHECK_LIBS: $CHECK_LIBS)
 301     ],
 302     HAVE_CHECK=no)
 303 AM_CONDITIONAL(HAVE_CHECK, test "x$HAVE_CHECK" = "xyes")
 304
 305 dnl ######################################################################
 306 dnl # Check command line parameters, and set shell variables accordingly #
 307 dnl ######################################################################
 308
 309 dnl FIXME: simplify all this down using a few m4 macros
 310
 311 AC_ARG_ENABLE(fast-stack-trash,
 312 AC_HELP_STRING([--enable-fast-stack-trash],[use fast memory allocator (i586 or above)]),
 313 [case "${enableval}" in
 314   yes) USE_FAST_STACK_TRASH=yes;;
 315   noset) USE_FAST_STACK_TRASH=no;;
 316   no)  USE_FAST_STACK_TRASH=no;;
 317   *) AC_MSG_ERROR(bad value ${enableval} for --enable-atomic) ;;
 318 esac],
 319 [USE_FAST_STACK_TRASH=yes]) dnl Default value
 320
 321 AC_ARG_ENABLE(plugin-builddir,
 322 AC_HELP_STRING([--enable-plugin-builddir],[allow tests/demos to use non-installed plugins]),
 323 [case "${enableval}" in
 324   yes) PLUGINS_USE_BUILDDIR=yes ;;
 325   no)  PLUGINS_USE_BUILDDIR=no ;;
 326   *) AC_MSG_ERROR(bad value ${enableval} for --enable-plugin-builddir) ;;
 327 esac],
 328 [PLUGINS_USE_BUILDDIR=no]) dnl Default value
 329
 330 AC_ARG_ENABLE(profiling,
 331 AC_HELP_STRING([--enable-profiling],[adds -pg to compiler commandline, for profiling]),
 332 [case "${enableval}" in
 333   yes) USE_PROFILING=yes ;;
 334   no)  USE_PROFILING=no ;;
 335   *) AC_MSG_ERROR(bad value ${enableval} for --enable-profiling) ;;
 336 esac],
 337 [USE_PROFILING=no]) dnl Default value
 338
 339 dnl use a cache dir for storing element registry info.
 340 dnl default to building registry in the source tree if we are enabling plugin build dir
 341 if test "x$PLUGINS_USE_BUILDDIR" = "xyes"; then
 342   GST_CACHE_DIR=`pwd`
 343 else
 344   dnl ${localstatedir} points to PREFIX/var
 345   GST_CACHE_DIR=${localstatedir}/cache/gstreamer-$GST_MAJORMINOR
 346 fi
 347 AC_ARG_WITH(cachedir,
 348 AC_HELP_STRING([--with-cachedir],[specify path to use for plugin and command completion registries]),
 349 [case "${withval}" in
 350   yes) AC_MSG_ERROR(bad value ${withval} for --with-cachedir) ;;
 351   no) AC_MSG_ERROR(bad value ${withval} for --with-cachedir) ;;
 352   *) GST_CACHE_DIR="${withval}" ;;
 353 esac],
 354 [:]) dnl Default value
 355
 356 AS_AC_EXPAND(GST_CACHE_DIR, $GST_CACHE_DIR)
 357 AC_DEFINE_UNQUOTED(GST_CACHE_DIR, "$GST_CACHE_DIR", [Location of registry])
 358 AC_MSG_NOTICE(Using $GST_CACHE_DIR as registry cache dir)
 359
 360 dnl building of tests
 361 AC_ARG_ENABLE(tests,
 362 AC_HELP_STRING([--disable-tests],[disable building test apps]),
 363 [case "${enableval}" in
 364   yes) BUILD_TESTS=yes ;;
 365   no)  BUILD_TESTS=no ;;
 366   *) AC_MSG_ERROR(bad value ${enableval} for --disable-tests) ;;
 367 esac],
 368 [BUILD_TESTS=yes]) dnl Default value
 369 AM_CONDITIONAL(BUILD_TESTS,         test "x$BUILD_TESTS" = "xyes")
 370
 371 dnl tests known to fail
 372 AC_ARG_ENABLE(failing-tests,
 373 AC_HELP_STRING([--disable-failing-tests],[disable building tests known to fail]),
 374 [case "${enableval}" in
 375   yes) BUILD_FAILING_TESTS=yes ;;
 376   no)  BUILD_FAILING_TESTS=no ;;
 377   *) AC_MSG_ERROR(bad value ${enableval} for --disable-failing-tests) ;;
 378 esac],
 379 [BUILD_FAILING_TESTS=no]) dnl Default value
 380 AM_CONDITIONAL(BUILD_FAILING_TESTS, test "x$BUILD_FAILING_TESTS" = "xyes")
 381 if test x$BUILD_FAILING_TESTS = xyes; then
 382   AC_MSG_WARN([building tests known to fail, use --disable-failing-tests to disable])
 383 else
 384   AC_MSG_WARN([Sissy ! By asking to not build the tests known to fail, you hereby waive your right to customer support.  If you do not agree with this EULA, please press Ctrl-C before the next line is printed.  By allowing the next line to be printed, you expressly acknowledge your acceptance of this EULA.])
 385 fi
 386
 387 AC_ARG_ENABLE(examples,
 388 AC_HELP_STRING([--disable-examples],[disable building examples]),
 389 [case "${enableval}" in
 390   yes) BUILD_EXAMPLES=yes ;;
 391   no)  BUILD_EXAMPLES=no ;;
 392   *) AC_MSG_ERROR(bad value ${enableval} for --disable-examples) ;;
 393 esac],
 394 [BUILD_EXAMPLES=yes]) dnl Default value
 395 AM_CONDITIONAL(BUILD_EXAMPLES,      test "x$BUILD_EXAMPLES" = "xyes")
 396
 397 dnl poison destroyed objects
 398 AC_ARG_ENABLE(poisoning,
 399 AC_HELP_STRING([--enable-poisoning],[enable poisoning of deallocated objects]),
 400 [case "${enableval}" in
 401   yes) USE_POISONING=yes ;;
 402   no)  USE_POISONING=no ;;
 403   *) AC_MSG_ERROR(bad value ${enableval} for --enable-poisoning) ;;
 404 esac],
 405 [USE_POISONING=no]) dnl Default value
 406
 407 dnl Next, check for the optional components:
 408 dnl ========================================
 409
 410 dnl debugging stuff
 411 AC_ARG_ENABLE(debug,
 412 AC_HELP_STRING([--disable-debug],[disable addition of -g debugging info]),
 413 [case "${enableval}" in
 414   yes) USE_DEBUG=yes ;;
 415   no)  USE_DEBUG=no ;;
 416   *) AC_MSG_ERROR(bad value ${enableval} for --enable-debug) ;;
 417 esac],
 418 [USE_DEBUG=yes]) dnl Default value
 419
 420 dnl valgrind inclusion
 421 AC_ARG_ENABLE(valgrind,
 422 AC_HELP_STRING([--disable-valgrind],[disable run-time valgrind detection]),
 423 [case "${enableval}" in
 424   yes) USE_VALGRIND="$USE_DEBUG" ;;
 425   no)  USE_VALGRIND=no ;;
 426   *) AC_MSG_ERROR(bad value ${enableval} for --enable-valgrind) ;;
 427 esac],
 428 [USE_VALGRIND="$USE_DEBUG"]) dnl Default value
 429 VALGRIND_REQ="2.1"
 430 if test "x$USE_VALGRIND" = xyes; then
 431
 432   PKG_CHECK_MODULES(VALGRIND, valgrind > $VALGRIND_REQ, USE_VALGRIND="yes", USE_VALGRIND="no")
 433 fi
 434 if test "x$USE_VALGRIND" = xyes; then
 435   AC_DEFINE(HAVE_VALGRIND, 1, [Define if valgrind should be used])
 436   AC_MSG_NOTICE(Using extra code paths for valgrind)
 437 fi
 438 AC_SUBST(VALGRIND_CFLAGS)
 439 AC_SUBST(VALGRIND_LIBS)
 440
 441 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 442 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 443
 444 dnl ################################################
 445 dnl # Set defines according to variables set above #
 446 dnl ################################################
 447
 448
 449 dnl These should be "USE_*" instead of "HAVE_*", but some packages expect
 450 dnl HAVE_ and it is likely to be easier to stick with the old name
 451 if test "x$USE_FAST_STACK_TRASH" = xyes; then
 452   AC_DEFINE(USE_FAST_STACK_TRASH, 1, [Define if we should use i586 optimized stack functions])
 453 fi
 454
 455 if test "x$USE_POISONING" = xyes; then
 456   AC_DEFINE(USE_POISONING, 1, [Define if we should poison deallocated memory])
 457 fi
 458
 459 dnl test for sigaction()
 460 AC_CHECK_FUNC(sigaction,
 461    AC_DEFINE(HAVE_SIGACTION, 1,
 462              [Defined if we have sigaction ()]))
 463
 464 dnl test for register_printf_function
 465 AC_CHECK_FUNC(register_printf_function,
 466   [
 467     GST_PRINTF_EXTENSION_FORMAT_DEFINE="#define GST_PTR_FORMAT \"P\""
 468     AC_DEFINE(HAVE_PRINTF_EXTENSION, 1,
 469              [Defined if we have register_printf_function ()])
 470   ],
 471   GST_PRINTF_EXTENSION_FORMAT_DEFINE="#define GST_PTR_FORMAT \"p\""
 472 )
 473 AC_SUBST(GST_PRINTF_EXTENSION_FORMAT_DEFINE)
 474
 475 dnl test if we have dladdr(); we use it for debugging
 476 save_cflags="$CFLAGS"
 477 CFLAGS="$CFLAGS -D_GNU_SOURCE"
 478 AC_CHECK_LIB(dl, dladdr,
 479    AC_DEFINE(HAVE_DLADDR, 1,
 480              [Defined if we have dladdr ()]))
 481 CFLAGS="$save_cflags"
 482
 483 if test "x$PLUGINS_USE_BUILDDIR" = xyes; then
 484   AC_DEFINE(PLUGINS_USE_BUILDDIR, 1, [Define if plugins should be loaded from the build tree - only developers should use this])
 485 fi
 486
 487 if test "x$USE_DEBUG" = xyes; then
 488    GST_INT_CFLAGS="$GST_INT_CFLAGS -g"
 489 fi
 490
 491 dnl #############################
 492 dnl # Set automake conditionals #
 493 dnl #############################
 494
 495 dnl These should be "USE_*" instead of "HAVE_*", but some packages expect
 496 dnl HAVE_ and it is likely to be easier to stick with the old name
 497 AM_CONDITIONAL(EXPERIMENTAL,        test "x$EXPERIMENTAL" = "yes")
 498 AM_CONDITIONAL(BROKEN,              test "x$BROKEN" = "yes")
 499 AM_CONDITIONAL(PLUGINS_USE_BUILDDIR,  test "x$PLUGINS_USE_BUILDDIR" = "xyes")
 500
 501
 502 dnl ############################
 503 dnl # Set up some more defines #
 504 dnl ############################
 505
 506 dnl set license and copyright notice
 507 AC_DEFINE(GST_LICENSE, "LGPL", [GStreamer license])
 508
 509 dnl package name in plugins
 510 AC_ARG_WITH(package-name,
 511 AC_HELP_STRING([--with-package-name],[specify package name to use in plugins]),
 512 [case "${withval}" in
 513   yes) AC_MSG_ERROR(bad value ${withval} for --with-package-name) ;;
 514   no) AC_MSG_ERROR(bad value ${withval} for --with-package-name) ;;
 515   *) GST_PACKAGE="${withval}" ;;
 516 esac],
 517 [
 518 dnl default value
 519 if test "x$GST_CVS" = "xyes"
 520 then
 521   dnl nano >= 1
 522   GST_PACKAGE="GStreamer CVS/prerelease"
 523 else
 524   GST_PACKAGE="GStreamer source release"
 525 fi
 526 ]
 527 )
 528 AC_MSG_NOTICE(Using $GST_PACKAGE as package name)
 529 AC_DEFINE_UNQUOTED(GST_PACKAGE, "$GST_PACKAGE", [package name in plugins])
 530
 531 dnl package origin URL
 532 AC_ARG_WITH(package-origin,
 533 AC_HELP_STRING([--with-package-origin],[specify package origin URL to use in plugins]),
 534 [case "${withval}" in
 535   yes) AC_MSG_ERROR(bad value ${withval} for --with-package-origin) ;;
 536   no) AC_MSG_ERROR(bad value ${withval} for --with-package-origin) ;;
 537   *) GST_ORIGIN="${withval}" ;;
 538 esac],
 539 [GST_ORIGIN="http://gstreamer.freedesktop.org/"]) dnl Default value
 540 AC_MSG_NOTICE(Using $GST_ORIGIN as package origin)
 541 AC_DEFINE_UNQUOTED(GST_ORIGIN, "$GST_ORIGIN", [package origin])
 542
 543 dnl Set location of plugin directory
 544 AS_AC_EXPAND(PLUGINS_DIR, ${libdir}/gstreamer-$GST_MAJORMINOR)
 545 AC_DEFINE_UNQUOTED(PLUGINS_DIR, "$PLUGINS_DIR", [Define the plugin directory])
 546 AC_SUBST(PLUGINS_DIR)
 547 AC_MSG_NOTICE([Using $PLUGINS_DIR as the plugin install location])
 548
 549 dnl Set location of uninstalled plugin directory
 550 PLUGINS_BUILDDIR=`pwd`
 551 AC_DEFINE_UNQUOTED(PLUGINS_BUILDDIR, "$PLUGINS_BUILDDIR", [Define the uninstalled plugin directory])
 552 AC_SUBST(PLUGINS_BUILDDIR)
 553
 554 dnl LDFLAGS modifier defining exported symbols from built objects
 555 EXPORT_LDFLAGS="-export-symbols-regex [_]*\(gst_\|Gst\|GST_\).*"
 556
 557 dnl GST_PKG_*:    the flags we use that are also used
 558 dnl               for external applications/.pc file
 559 dnl GST_LIB_*:    used for the main library
 560 dnl GST_OBJ_*:    the flags we use for all the objects internal to the core
 561 dnl GST_PLUGIN_*: additional flags we use for all plugins
 562
 563 dnl finalize _CFLAGS and _LIBS
 564 dnl flags exported for external applications and use in our pkg-config .pc files
 565 dnl since glib and xml are package deps, there's no need to include their cflags
 566 dnl in the pkg-config file
 567
 568 GST_PKG_DEPS="glib-2.0, gobject-2.0, gmodule-2.0, gthread-2.0"
 569 AC_SUBST(GST_PKG_CFLAGS)
 570 AC_SUBST(GST_PKG_LIBS)
 571 AC_SUBST(GST_PKG_DEPS)
 572
 573 dnl flags shared for all internal objects (core libs, elements, applications)
 574 dnl we disable deprecated internally
 575 dnl XML, GLib, popt, GST_INT, VALGRIND, and the right include for CFLAGS
 576 dnl no need to add XML, GLib, popt explicitly since libgstreamer pulls them in
 577 GST_INT_CFLAGS="$GLIB_CFLAGS $XML_CFLAGS $GST_PKG_CFLAGS \
 578  $GST_INT_CFLAGS \$(ERROR_CFLAGS) -DGST_DISABLE_DEPRECATED"
 579
 580 dnl Private vars for libgst only
 581 GST_LIB_CFLAGS="$GST_PKG_CFLAGS $GST_INT_CFLAGS \
 582   $VALGRIND_CFLAGS -I\$(top_srcdir)"
 583 GST_LIB_LIBS="$XML_LIBS $GLIB_LIBS -lpopt $GST_PKG_LIBS $LTLIBINTL $VALGRIND_LIBS"
 584 GST_LIB_LDFLAGS="$GST_LT_LDFLAGS -version-info $GST_LIBVERSION -no-undefined $EXPORT_LDFLAGS"
 585 AC_SUBST(GST_LIB_CFLAGS)
 586 AC_SUBST(GST_LIB_LIBS)
 587 AC_SUBST(GST_LIB_LDFLAGS)
 588
 589 dnl Vars for all internal objects built on libgstreamer
 590 GST_OBJ_CFLAGS="$GST_INT_CFLAGS -I\$(top_srcdir)/libs -I\$(top_srcdir)"
 591 GST_OBJ_LIBS="\$(top_builddir)/gst/libgstreamer-$GST_MAJORMINOR.la"
 592
 593 AC_SUBST(GST_OBJ_CFLAGS, "$GST_OBJ_CFLAGS")
 594 AC_SUBST(GST_OBJ_LIBS, "$GST_OBJ_LIBS")
 595
 596 dnl specific additional LDFLAGS for plugins
 597 GST_PLUGIN_LDFLAGS="-module -avoid-version -no-undefined $EXPORT_LDFLAGS"
 598 AC_SUBST(GST_PLUGIN_LDFLAGS, "$GST_PLUGIN_LDFLAGS")
 599
 600 plugindir="\$(libdir)/gstreamer-$GST_MAJORMINOR"
 601 AC_SUBST(plugindir)
 602
 603 dnl ##################################################
 604 dnl # deps for examples from manual                  #
 605 dnl ##################################################
 606
 607 PKG_CHECK_MODULES(LIBGNOMEUI, libgnomeui-2.0,
 608                   HAVE_LIBGNOMEUI="yes", HAVE_LIBGNOMEUI="no")
 609 AC_SUBST(LIBGNOMEUI_CFLAGS)
 610 AC_SUBST(LIBGNOMEUI_LIBS)
 611 AM_CONDITIONAL(HAVE_LIBGNOMEUI, test "x$HAVE_LIBGNOMEUI" = "xyes")
 612
 613 dnl ##################################################
 614 dnl # Prepare informative messages to display at end #
 615 dnl ##################################################
 616
 617 infomessages=
 618
 619 if test "x$PLUGINS_USE_BUILDDIR" = xyes; then
 620   infomessages="$infomessages
 621 *** Warning: You have configured using the --enable-plugin-builddir option.
 622
 623 This option is for development purposes only: binaries built with
 624 it should be used with code in the build tree only.  To build an
 625 installable version, use ./configure without the --enable-plugin-builddir
 626 option.  Note that the autogen.sh script supplies the plugin builddir
 627 option automatically -- run ./autogen.sh -- --disable-plugin-builddir to make
 628 an installable build.
 629
 630 "
 631 fi
 632
 633 dnl #########################
 634 dnl # Make the output files #
 635 dnl #########################
 636
 637 dnl libs/ext/Makefile
 638 dnl nothing there yet !
 639 AC_OUTPUT(
 640 Makefile
 641 include/Makefile
 642 gst/Makefile
 643 gst/gstconfig.h
 644 gst/gstversion.h
 645 gst/base/Makefile
 646 gst/check/Makefile
 647 gst/indexers/Makefile
 648 gst/elements/Makefile
 649 gst/parse/Makefile
 650 libs/Makefile
 651 libs/gst/Makefile
 652 libs/gst/controller/Makefile
 653 libs/gst/dataprotocol/Makefile
 654 po/Makefile.in
 655 check/Makefile
 656 tests/Makefile
 657 tests/instantiate/Makefile
 658 tests/memchunk/Makefile
 659 tests/muxing/Makefile
 660 tests/seeking/Makefile
 661 tests/sched/Makefile
 662 tests/threadstate/Makefile
 663 testsuite/Makefile
 664 testsuite/bytestream/Makefile
 665 testsuite/caps/Makefile
 666 testsuite/cleanup/Makefile
 667 testsuite/controller/Makefile
 668 testsuite/debug/Makefile
 669 testsuite/dlopen/Makefile
 670 testsuite/elements/Makefile
 671 testsuite/indexers/Makefile
 672 testsuite/negotiation/Makefile
 673 testsuite/pad/Makefile
 674 testsuite/parse/Makefile
 675 testsuite/plugin/Makefile
 676 testsuite/refcounting/Makefile
 677 testsuite/schedulers/Makefile
 678 testsuite/states/Makefile
 679 testsuite/threads/Makefile
 680 testsuite/trigger/Makefile
 681 examples/Makefile
 682 examples/controller/Makefile
 683 examples/cutter/Makefile
 684 examples/helloworld/Makefile
 685 examples/launch/Makefile
 686 examples/manual/Makefile
 687 examples/mixer/Makefile
 688 examples/metadata/Makefile
 689 examples/pingpong/Makefile
 690 examples/plugins/Makefile
 691 examples/pwg/Makefile
 692 examples/queue/Makefile
 693 examples/retag/Makefile
 694 examples/thread/Makefile
 695 examples/typefind/Makefile
 696 examples/xml/Makefile
 697 tools/Makefile
 698 common/Makefile
 699 common/m4/Makefile
 700 docs/Makefile
 701 docs/faq/Makefile
 702 docs/gst/Makefile
 703 docs/libs/Makefile
 704 docs/manual/Makefile
 705 docs/pwg/Makefile
 706 docs/xsl/Makefile
 707 docs/version.entities
 708 pkgconfig/Makefile
 709 stamp.h
 710 pkgconfig/gstreamer.pc
 711 pkgconfig/gstreamer-uninstalled.pc
 712 pkgconfig/gstreamer-base.pc
 713 pkgconfig/gstreamer-base-uninstalled.pc
 714 pkgconfig/gstreamer-check.pc
 715 pkgconfig/gstreamer-check-uninstalled.pc
 716 pkgconfig/gstreamer-controller.pc
 717 pkgconfig/gstreamer-controller-uninstalled.pc
 718 pkgconfig/gstreamer-dataprotocol.pc
 719 pkgconfig/gstreamer-dataprotocol-uninstalled.pc
 720 gstreamer.spec,
 721 echo "$infomessages", infomessages="$infomessages"
 722 )