configure.ac

   1 AC_PREREQ(2.60)
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, git and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for git/pre
   8 AC_INIT(GStreamer Good Plug-ins, 0.11.0.1,
   9     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
  10     gst-plugins-good)
  11
  12 AG_GST_INIT
  13
  14 dnl initialize automake
  15 AM_INIT_AUTOMAKE([-Wno-portability 1.10])
  16
  17 dnl define PACKAGE_VERSION_* variables
  18 AS_VERSION
  19
  20 dnl check if this is a release version
  21 AS_NANO(GST_GIT="no", GST_GIT="yes")
  22
  23 dnl can autoconf find the source ?
  24 AC_CONFIG_SRCDIR([gst/law/alaw.c])
  25
  26 dnl define the output header for config
  27 AM_CONFIG_HEADER([config.h])
  28
  29 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  30 AM_MAINTAINER_MODE
  31
  32 dnl sets host_* variables
  33 AC_CANONICAL_HOST
  34
  35 dnl use pretty build output with automake >= 1.11
  36 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],
  37   [AM_DEFAULT_VERBOSITY=1
  38    AC_SUBST(AM_DEFAULT_VERBOSITY)])
  39
  40 dnl our libraries and install dirs use major.minor as a version
  41 GST_MAJORMINOR=$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR
  42 dnl we override it here if we need to for the release candidate of new series
  43 GST_MAJORMINOR=0.11
  44 AC_SUBST(GST_MAJORMINOR)
  45
  46 AG_GST_LIBTOOL_PREPARE
  47
  48 dnl FIXME: this macro doesn't actually work;
  49 dnl the generated libtool script has no support for the listed tags.
  50 dnl So this needs to be fixed first if we want to use this
  51 dnl AS_LIBTOOL_TAGS
  52
  53 AC_LIBTOOL_WIN32_DLL
  54 AM_PROG_LIBTOOL
  55
  56 dnl *** required versions of GStreamer stuff ***
  57 GST_REQ=0.11.0
  58 GSTPB_REQ=0.11.0
  59
  60 dnl *** autotools stuff ****
  61
  62 dnl allow for different autotools
  63 AS_AUTOTOOLS_ALTERNATE
  64
  65 dnl Add parameters for aclocal
  66 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  67
  68 dnl set up gettext
  69 dnl the version check needs to stay here because autopoint greps for it
  70 AM_GNU_GETTEXT_VERSION([0.17])
  71 AM_GNU_GETTEXT([external])
  72 AG_GST_GETTEXT([gst-plugins-good-$GST_MAJORMINOR])
  73
  74 dnl *** check for arguments to configure ***
  75
  76 AG_GST_ARG_DEBUG
  77 AG_GST_ARG_PROFILING
  78 AG_GST_ARG_VALGRIND
  79 AG_GST_ARG_GCOV
  80
  81 AG_GST_ARG_EXAMPLES
  82
  83 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  84 AG_GST_ARG_WITH_PACKAGE_NAME
  85 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  86
  87 AG_GST_ARG_WITH_PLUGINS
  88
  89 AG_GST_ARG_ENABLE_EXTERNAL
  90
  91 AG_GST_ARG_ENABLE_EXPERIMENTAL
  92
  93 dnl *** checks for platform ***
  94
  95 dnl * hardware/architecture *
  96
  97 dnl common/m4/gst-arch.m4
  98 dnl check CPU type
  99 AG_GST_ARCH
 100
 101 dnl Determine endianness
 102 AC_C_BIGENDIAN
 103
 104 dnl *** checks for programs ***
 105
 106 dnl find a compiler
 107 AC_PROG_CC
 108 AC_PROG_CC_STDC
 109
 110 dnl determine c++ compiler
 111 AC_PROG_CXX
 112 dnl determine if c++ is available on this system
 113 AC_CHECK_PROG(HAVE_CXX, $CXX, yes, no)
 114
 115 dnl determine c++ preprocessor
 116 dnl FIXME: do we need this ?
 117 AC_PROG_CXXCPP
 118
 119 AS_PROG_OBJC
 120
 121 dnl check if the compiler supports '-c' and '-o' options
 122 AM_PROG_CC_C_O
 123
 124 dnl find an assembler
 125 AM_PROG_AS
 126
 127 dnl check if the compiler supports do while(0) macros
 128 AG_GST_CHECK_DOWHILE_MACROS
 129
 130 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 131 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 132
 133 dnl check for documentation tools
 134 GTK_DOC_CHECK([1.3])
 135 AS_PATH_PYTHON([2.1])
 136 AG_GST_PLUGIN_DOCS([1.3],[2.1])
 137
 138 dnl *** checks for libraries ***
 139
 140 dnl check for libm, for sin()
 141 AC_CHECK_LIBM
 142 AC_SUBST(LIBM)
 143
 144 dnl *** checks for header files ***
 145
 146 dnl check if we have ANSI C header files
 147 AC_HEADER_STDC
 148
 149 dnl used by ext/wavpack
 150 AX_CREATE_STDINT_H
 151
 152 dnl used in gst/rtp/gstasteriskh263.c
 153 AC_CHECK_HEADERS([netinet/in.h])
 154 AC_CHECK_HEADERS([winsock2.h], HAVE_WINSOCK2_H=yes)
 155 AM_CONDITIONAL(HAVE_WINSOCK2_H, test "x$HAVE_WINSOCK2_H" = "xyes")
 156
 157 dnl used in gst/udp
 158 AC_CHECK_HEADERS([sys/time.h])
 159
 160 dnl *** checks for types/defines ***
 161
 162 dnl Check for FIONREAD ioctl declaration.  This check is needed
 163 dnl for the UDP plugin to build on Solaris
 164 GST_CHECK_FIONREAD
 165
 166 dnl *** checks for structures ***
 167
 168 dnl *** checks for compiler characteristics ***
 169
 170 dnl check if we have GCC inline-asm
 171 AS_GCC_INLINE_ASSEMBLY([HAVE_GCC_ASM=yes], [HAVE_GCC_ASM=no])
 172 if test x$HAVE_GCC_ASM = xyes ; then
 173   AC_DEFINE(HAVE_GCC_ASM, 1,
 174     [Define if compiler supports gcc inline assembly])
 175 fi
 176 AM_CONDITIONAL(HAVE_GCC_ASM, test "x$HAVE_GCC_ASM" = "xyes")
 177
 178 dnl *** checks for library functions ***
 179
 180 LIBS_SAVE=$LIBS
 181 LIBS="$LIBS $LIBM"
 182 AC_CHECK_FUNCS(rint sinh cosh asinh fpclass)
 183 LIBS=$LIBS_SAVE
 184
 185 dnl Check whether isinf() is defined by math.h
 186 AC_CACHE_CHECK([for isinf], ac_cv_have_isinf,
 187     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>]], [[float f = 0.0; int i=isinf(f)]])],[ac_cv_have_isinf="yes"],[ac_cv_have_isinf="no"]))
 188 if test "$ac_cv_have_isinf" = "yes"
 189 then
 190     AC_DEFINE(HAVE_ISINF, 1, [Define to 1 if you have the `isinf' function.])
 191 fi
 192
 193 dnl Check for mmap (needed by electricfence plugin)
 194 AC_FUNC_MMAP
 195 AM_CONDITIONAL(GST_HAVE_MMAP, test "x$ac_cv_func_mmap_fixed_mapped" = "xyes")
 196
 197 dnl Check for mmap (needed by electricfence plugin)
 198
 199 AC_CHECK_TYPE([struct ip_mreqn], [
 200               AC_DEFINE(HAVE_IP_MREQN,, [Define if we have struct ip_mreqn])],,
 201               [#include <netinet/in.h>])
 202
 203 dnl *** checks for dependency libraries ***
 204
 205 dnl GLib is required
 206 AG_GST_GLIB_CHECK([2.24])
 207
 208 dnl Check for GIO
 209 translit(dnm, m, l) AM_CONDITIONAL(USE_GIO, true)
 210 AG_GST_CHECK_FEATURE(GIO, [GIO library], gio, [
 211   PKG_CHECK_MODULES(GIO, gio-2.0 >= 2.31.10)
 212   GIO_MODULE_DIR="`$PKG_CONFIG --variable=giomoduledir gio-2.0`"
 213   AC_DEFINE_UNQUOTED(GIO_MODULE_DIR, "$GIO_MODULE_DIR",
 214       [The GIO modules directory.])
 215   GIO_LIBDIR="`$PKG_CONFIG --variable=libdir gio-2.0`"
 216       AC_DEFINE_UNQUOTED(GIO_LIBDIR, "$GIO_LIBDIR",
 217           [The GIO library directory.])
 218
 219   AC_SUBST(GIO_CFLAGS)
 220   AC_SUBST(GIO_LIBS)
 221   AC_SUBST(GIO_LDFLAGS)
 222 ])
 223
 224 dnl Orc
 225 ORC_CHECK([0.4.11])
 226
 227 dnl checks for gstreamer
 228 dnl uninstalled is selected preferentially -- see pkg-config(1)
 229 AG_GST_CHECK_GST($GST_MAJORMINOR, [$GST_REQ], yes)
 230 AG_GST_CHECK_GST_BASE($GST_MAJORMINOR, [$GST_REQ], yes)
 231 AG_GST_CHECK_GST_CONTROLLER($GST_MAJORMINOR, [$GST_REQ], yes)
 232 AG_GST_CHECK_GST_NET($GST_MAJORMINOR, [$GST_REQ], yes)
 233 AG_GST_CHECK_GST_CHECK($GST_MAJORMINOR, [$GST_REQ], no)
 234 AG_GST_CHECK_GST_PLUGINS_BASE($GST_MAJORMINOR, [$GSTPB_REQ], yes)
 235
 236 GST_TOOLS_DIR=`$PKG_CONFIG --variable=toolsdir gstreamer-$GST_MAJORMINOR`
 237 if test -z $GST_TOOLS_DIR; then
 238   AC_MSG_ERROR([no tools dir defined in GStreamer pkg-config file; core upgrade needed.])
 239 fi
 240 AC_SUBST(GST_TOOLS_DIR)
 241
 242 AC_MSG_NOTICE(Using GStreamer Core Plugins in $GST_PLUGINS_DIR)
 243 AC_MSG_NOTICE(Using GStreamer Base Plugins in $GSTPB_PLUGINS_DIR)
 244
 245 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 246
 247 dnl Check for documentation xrefs
 248 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 249 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_MAJORMINOR`"
 250 GSTPB_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-plugins-base-$GST_MAJORMINOR`"
 251 AC_SUBST(GLIB_PREFIX)
 252 AC_SUBST(GST_PREFIX)
 253 AC_SUBST(GSTPB_PREFIX)
 254
 255 dnl GTK is optional and used in examples
 256 HAVE_GTK=no
 257 GTK2_REQ=2.14.0
 258 GTK3_REQ=2.91.3
 259 if test "x$BUILD_EXAMPLES" = "xyes"; then
 260   AC_MSG_CHECKING([which gtk+ version to compile examples against (optional)])
 261   AC_ARG_WITH([gtk],
 262     AC_HELP_STRING([--with-gtk=3.0|2.0],
 263                    [which gtk+ version to compile against (default: 2.0)]),
 264     [case "$with_gtk" in
 265         2.0) GTK_REQ=$GTK2_REQ ;;
 266         3.0) GTK_REQ=$GTK3_REQ ;;
 267         *) AC_MSG_ERROR([invalid gtk+ version specified]);;
 268     esac],
 269     [with_gtk=2.0
 270      GTK_REQ=$GTK2_REQ])
 271   AC_MSG_RESULT([$with_gtk (>= $GTK_REQ)])
 272   PKG_CHECK_MODULES(GTK, gtk+-$with_gtk >= $GTK_REQ, HAVE_GTK=yes, HAVE_GTK=no)
 273   dnl some examples need gtk+-x11
 274   PKG_CHECK_MODULES(GTK_X11, gtk+-x11-$with_gtk >= $GTK_REQ, HAVE_GTK_X11=yes, HAVE_GTK_X11=no)
 275   AC_SUBST(GTK_LIBS)
 276   AC_SUBST(GTK_CFLAGS)
 277 fi
 278 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 279 AM_CONDITIONAL(HAVE_GTK_X11, test "x$HAVE_GTK_X11" = "xyes")
 280
 281 dnl *** set variables based on configure arguments ***
 282
 283 dnl set license and copyright notice
 284 GST_LICENSE="LGPL"
 285 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 286 AC_SUBST(GST_LICENSE)
 287
 288 dnl set location of plugin directory
 289 AG_GST_SET_PLUGINDIR
 290
 291 dnl set release date/time
 292 AG_GST_SET_PACKAGE_RELEASE_DATETIME_WITH_NANO([$PACKAGE_VERSION_NANO],
 293   ["${srcdir}/gst-plugins-good.doap"],
 294   [$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_MICRO])
 295
 296 dnl define an ERROR_CFLAGS Makefile variable
 297 dnl -Wundef: too many broken headers
 298 if test "x$HAVE_OSX_VIDEO" != "xyes"; then
 299   AG_GST_SET_ERROR_CFLAGS($GST_GIT, [
 300         -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls
 301         -Wwrite-strings -Wold-style-definition -Waggregate-return
 302         -Winit-self -Wmissing-include-dirs -Waddress -Wno-multichar
 303         -Wnested-externs ])
 304 else
 305   dnl work-around for us passing GST_CFLAGS to the ObjC-compiler, which
 306   dnl doesn't understand all warning flags that the C compiler knows about
 307   dnl (e.g. -Waddress) or causes problems with some flags (-Waggregate-return)
 308   AG_GST_SET_ERROR_CFLAGS($GST_GIT, [
 309         -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls
 310         -Wwrite-strings -Wold-style-definition
 311         -Winit-self -Wmissing-include-dirs -Wno-multichar
 312         -Wnested-externs ])
 313 fi
 314
 315 dnl define an ERROR_CXXFLAGS Makefile variable
 316 AG_GST_SET_ERROR_CXXFLAGS($GST_GIT, [
 317         -Wmissing-declarations -Wredundant-decls
 318         -Wwrite-strings
 319         -Winit-self -Wmissing-include-dirs -Waddress -Wno-multichar ])
 320
 321 dnl define correct level for debugging messages
 322 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 323
 324 dnl used in examples
 325 AG_GST_DEFAULT_ELEMENTS
 326
 327 dnl *** plug-ins to include ***
 328
 329 dnl Non ported plugins (non-dependant, then dependant)
 330 dnl Make sure you have a space before and after all plugins
 331 GST_PLUGINS_NONPORTED="deinterlace interleave flx goom2k1 \
 332  imagefreeze interleave monoscope smpte \
 333  videobox videomixer \
 334  cairo cairo_gobject dv1394 gdk_pixbuf libdv libpng \
 335  oss oss4 shout2 \
 336  taglib wavpack \
 337  osx_video osx_audio "
 338 AC_SUBST(GST_PLUGINS_NONPORTED)
 339
 340 dnl these are all the gst plug-ins, compilable without additional libs
 341 dnl videofilter is at the top because others depend on it
 342 AG_GST_CHECK_PLUGIN(alpha)
 343 AG_GST_CHECK_PLUGIN(apetag)
 344 AG_GST_CHECK_PLUGIN(audiofx)
 345 AG_GST_CHECK_PLUGIN(audioparsers)
 346 AG_GST_CHECK_PLUGIN(auparse)
 347 AG_GST_CHECK_PLUGIN(autodetect)
 348 AG_GST_CHECK_PLUGIN(avi)
 349 AG_GST_CHECK_PLUGIN(cutter)
 350 AG_GST_CHECK_PLUGIN(debugutils)
 351 AG_GST_CHECK_PLUGIN(deinterlace)
 352 AG_GST_CHECK_PLUGIN(effectv)
 353 AG_GST_CHECK_PLUGIN(equalizer)
 354 AG_GST_CHECK_PLUGIN(flv)
 355 AG_GST_CHECK_PLUGIN(flx)
 356 AG_GST_CHECK_PLUGIN(goom)
 357 AG_GST_CHECK_PLUGIN(goom2k1)
 358 AG_GST_CHECK_PLUGIN(icydemux)
 359 AG_GST_CHECK_PLUGIN(id3demux)
 360 AG_GST_CHECK_PLUGIN(imagefreeze)
 361 AG_GST_CHECK_PLUGIN(interleave)
 362 AG_GST_CHECK_PLUGIN(isomp4)
 363 AG_GST_CHECK_PLUGIN(law)
 364 AG_GST_CHECK_PLUGIN(level)
 365 AG_GST_CHECK_PLUGIN(matroska)
 366 AG_GST_CHECK_PLUGIN(monoscope)
 367 AG_GST_CHECK_PLUGIN(multifile)
 368 AG_GST_CHECK_PLUGIN(multipart)
 369 AG_GST_CHECK_PLUGIN(replaygain)
 370 AG_GST_CHECK_PLUGIN(rtp)
 371 AG_GST_CHECK_PLUGIN(rtpmanager)
 372 AG_GST_CHECK_PLUGIN(rtsp)
 373 AG_GST_CHECK_PLUGIN(shapewipe)
 374 AG_GST_CHECK_PLUGIN(smpte)
 375 AG_GST_CHECK_PLUGIN(spectrum)
 376 AG_GST_CHECK_PLUGIN(udp)
 377 AG_GST_CHECK_PLUGIN(videobox)
 378 AG_GST_CHECK_PLUGIN(videocrop)
 379 AG_GST_CHECK_PLUGIN(videofilter)
 380 AG_GST_CHECK_PLUGIN(videomixer)
 381 AG_GST_CHECK_PLUGIN(wavenc)
 382 AG_GST_CHECK_PLUGIN(wavparse)
 383 AG_GST_CHECK_PLUGIN(y4m)
 384
 385 dnl *** checks for socket and nsl libraries ***
 386 AC_CHECK_FUNC(socket,,[AC_CHECK_LIB(socket,socket)])
 387
 388 dnl disable gst plugins we might not be able to build on this
 389 dnl platform: udp and rtsp (ugly but minimally invasive)
 390 dnl FIXME: maybe move to sys
 391 AC_CHECK_HEADERS([sys/socket.h], HAVE_SYS_SOCKET_H=yes)
 392 AC_CHECK_HEADERS([winsock2.h], HAVE_WINSOCK2_H=yes)
 393
 394 if test "x$HAVE_SYS_SOCKET_H" != "xyes" -a "x$HAVE_WINSOCK2_H" != "xyes"; then
 395   AG_GST_DISABLE_PLUGIN(udp)
 396   AG_GST_DISABLE_PLUGIN(rtsp)
 397 fi
 398
 399 if test "x$HAVE_WINSOCK2_H" = "xyes"; then
 400   WIN32_LIBS="-lws2_32"
 401   AC_SUBST(WIN32_LIBS)
 402 fi
 403
 404 dnl disable experimental plug-ins
 405 if test "x$BUILD_EXPERIMENTAL" != "xyes"; then
 406   AG_GST_DISABLE_PLUGIN(monoscope)
 407 fi
 408
 409 dnl *** sys plug-ins ***
 410
 411 echo
 412 AC_MSG_NOTICE([Checking libraries for plugins in sys/])
 413 echo
 414
 415 dnl DirectSound
 416 translit(dnm, m, l) AM_CONDITIONAL(USE_DIRECTSOUND, true)
 417 AG_GST_CHECK_FEATURE(DIRECTSOUND, [DirectSound plug-in], directsoundsink, [
 418   HAVE_DIRECTSOUND="no"
 419   save_CFLAGS="$CFLAGS"
 420   save_LDFLAGS="$LDFLAGS"
 421   save_LIBS="$LIBS"
 422   CFLAGS="$CFLAGS $DIRECTSOUND_CFLAGS"
 423   LDFLAGS="$LDFLAGS $DIRECTSOUND_LDFLAGS"
 424   LIBS="$LIBS -ldsound -ldxerr9 -luser32"
 425   AC_MSG_CHECKING(for DirectSound LDFLAGS)
 426   AC_LINK_IFELSE([
 427 #include <windows.h>
 428 #include <dxerr9.h>
 429 #include <dsound.h>
 430
 431 int main ()
 432 {
 433   DXGetErrorString9 (0);
 434   DirectSoundCreate(NULL, NULL, NULL);
 435
 436   return 0;
 437 }
 438 ],
 439     [HAVE_DIRECTSOUND="yes"],
 440     [HAVE_DIRECTSOUND="no"])
 441   AC_MSG_RESULT($HAVE_DIRECTSOUND)
 442   CFLAGS=$save_CFLAGS
 443   LDFLAGS=$save_LDFLAGS
 444   LIBS=$save_LIBS
 445
 446   if test "x$HAVE_DIRECTSOUND" = "xyes";  then
 447     dnl this is much more than we want
 448     DIRECTSOUND_LIBS="-ldsound -ldxerr9 -luser32"
 449     AC_SUBST(DIRECTSOUND_CFLAGS)
 450     AC_SUBST(DIRECTSOUND_LDFLAGS)
 451     AC_SUBST(DIRECTSOUND_LIBS)
 452   fi
 453   AC_SUBST(HAVE_DIRECTSOUND)
 454 ])
 455
 456 dnl *** Win32 WaveOut ***
 457 translit(dnm, m, l) AM_CONDITIONAL(USE_WAVEFORM, true)
 458 AG_GST_CHECK_FEATURE(WAVEFORM, [Win32 WaveForm], waveformsink, [
 459   AC_CHECK_HEADER(mmsystem.h, HAVE_WAVEFORM="yes", HAVE_WAVEFORM="no", [#include <windows.h>])
 460 ])
 461
 462 dnl *** OSS audio *** (Linux, *BSD)
 463 translit(dnm, m, l) AM_CONDITIONAL(USE_OSS, true)
 464 AG_GST_CHECK_FEATURE(OSS, [OSS audio], ossaudio, [
 465  HAVE_OSS="yes"
 466 dnl Linux and newer BSD versions :
 467  AC_CHECK_HEADER(sys/soundcard.h, [
 468    AC_DEFINE(HAVE_OSS_INCLUDE_IN_SYS,, [Define if OSS includes are in /sys/])
 469    ] , [
 470 dnl Some old BSD versions and also newer OpenBSD versions :
 471    AC_CHECK_HEADER(soundcard.h, [
 472      AC_DEFINE(HAVE_OSS_INCLUDE_IN_ROOT,, [Define if OSS includes are in /])
 473      ], [
 474   dnl Some old BSD versions :
 475      AC_CHECK_HEADER(machine/soundcard.h, [
 476        AC_DEFINE(HAVE_OSS_INCLUDE_IN_MACHINE,,
 477          [Define if OSS includes are in /machine/])
 478        ], [
 479        HAVE_OSS="no"
 480      ])
 481    ])
 482  ])
 483 ])
 484
 485 dnl *** oss4 ***
 486 translit(dnm, m, l) AM_CONDITIONAL(USE_OSS4, true)
 487 AG_GST_CHECK_FEATURE(OSS4, [Open Sound System 4], oss4, [
 488   AC_MSG_CHECKING([Checking if we can build the OSS4 elements])
 489   AC_CHECK_HEADERS([fcntl.h sys/ioctl.h sys/stat.h sys/types.h],
 490       [test -z "$OSS4_MISSING_HEADER" && HAVE_OSS4="yes"],
 491       [OSS4_MISSING_HEADER="yes";HAVE_OSS4="no"])
 492 ])
 493
 494 dnl *** Sun Audio ***
 495 translit(dnm, m, l) AM_CONDITIONAL(USE_SUNAUDIO, true)
 496 AG_GST_CHECK_FEATURE(SUNAUDIO, [Sun Audio], sunaudio, [
 497   AC_CHECK_HEADER(sys/audioio.h, HAVE_SUNAUDIO="yes", HAVE_SUNAUDIO="no")
 498 ])
 499
 500 dnl *** OSX Audio ***
 501 translit(dnm, m, l) AM_CONDITIONAL(USE_OSX_AUDIO, true)
 502 AG_GST_CHECK_FEATURE(OSX_AUDIO, [OSX audio], osxaudio, [
 503   AC_CHECK_HEADER(CoreAudio/CoreAudio.h, HAVE_OSX_AUDIO="yes", HAVE_OSX_AUDIO="no")
 504 ])
 505
 506 dnl *** OS X video ***
 507 translit(dnm, m, l) AM_CONDITIONAL(USE_OSX_VIDEO, true)
 508 HAVE_OSX_VIDEO="no"
 509 AG_GST_CHECK_FEATURE(OSX_VIDEO, [OSX video], osxvideosink, [
 510   AC_CHECK_HEADER(OpenGL/gl.h, HAVE_OSX_VIDEO="yes", HAVE_OSX_VIDEO="no")
 511 ])
 512 dnl in case header OpenGL/gl.h is found on other platforms
 513 case "$host" in
 514   *-*darwin*)
 515     dnl do nothing
 516     ;;
 517   *)
 518     HAVE_OSX_VIDEO="no"
 519     ;;
 520 esac
 521
 522
 523 dnl *** Video 4 Linux 2 ***
 524 dnl for information about the header/define, see sys/v4l2/gstv4l2element.h
 525 dnl renamed to GST_V4L2 because of some conflict with kernel headers
 526 translit(dnm, m, l) AM_CONDITIONAL(USE_GST_V4L2, true)
 527 AG_GST_CHECK_FEATURE(GST_V4L2, [Video 4 Linux 2], v4l2src, [
 528   AC_MSG_CHECKING([Checking for up to date v4l2 installation])
 529   AC_TRY_COMPILE([
 530 #include <sys/types.h>
 531 #ifdef __sun /* Solaris */
 532 #include <sys/types.h>
 533 #include <sys/videodev2.h>
 534 #else /* Linux */
 535 #include <linux/types.h>
 536 #define _LINUX_TIME_H
 537 #define __user
 538 #include <linux/videodev2.h>
 539 #endif
 540 #if defined(V4L2_MAJOR_VERSION) || defined(V4L2_MINOR_VERSION)
 541 #error too early v4l2 version or no v4l2 at all
 542 #endif
 543     ], [
 544 return 0;
 545     ], [
 546       HAVE_GST_V4L2="yes"
 547       AC_MSG_RESULT(yes)
 548     ], [
 549       HAVE_GST_V4L2="no"
 550       AC_MSG_RESULT(no)
 551
 552       HAVE_VIDEODEV=no
 553       AC_CHECK_HEADER(linux/videodev2.h, [ HAVE_VIDEODEV=yes ],
 554       [
 555         AC_CHECK_HEADER(sys/videodev2.h, [ HAVE_VIDEODEV=yes ])
 556       ])
 557
 558       if test "x$HAVE_VIDEODEV" = "xyes"; then
 559         AC_MSG_WARN([video4linux2 headers were found, but they're old.])
 560         AC_MSG_WARN([Please update v4l2 to compile the v4l2 plugins])
 561       else
 562         AC_MSG_WARN([video4linux2 was not found])
 563       fi
 564     ])
 565
 566   if [ test x$HAVE_GST_V4L2 = xyes ]; then
 567     dnl check for missing v4l2_buffer declaration (see #135919)
 568     MISSING_DECL=0
 569     AC_MSG_CHECKING(struct v4l2_buffer declaration)
 570     AC_TRY_COMPILE([
 571 #include <sys/types.h>
 572 #ifdef __sun /* Solaris */
 573 #include <sys/types.h>
 574 #include <sys/videodev2.h>
 575 #else /* Linux */
 576 #include <linux/types.h>
 577 #define _LINUX_TIME_H
 578 #define __user
 579 #include <linux/videodev2.h>
 580 #endif
 581     ],[
 582 struct v4l2_buffer buf;
 583 buf.index = 0;
 584 return 0;
 585     ], [ AC_MSG_RESULT(yes) ], [ MISSING_DECL=1 && AC_MSG_RESULT(no) ])
 586     if [ test x$MISSING_DECL = x1 ]; then
 587       AC_DEFINE(GST_V4L2_MISSING_BUFDECL, 1, [struct v4l2_buffer missing])
 588     fi
 589
 590     dnl check for XOverlay libraries
 591     AG_GST_CHECK_XV
 592   fi
 593 ])
 594
 595 # Optional gudev for device probing
 596 AC_ARG_WITH([gudev],
 597   AC_HELP_STRING([--with-gudev],
 598     [device detection with gudev]),
 599   [],
 600   [with_gudev=check])
 601 if test x$HAVE_GST_V4L2 = xyes; then
 602   if test x$with_gudev != xno; then
 603       PKG_CHECK_MODULES(GUDEV, [ gudev-1.0 >= 143 ],
 604           [ have_gudev=yes
 605             AC_DEFINE(HAVE_GUDEV, 1,
 606                [Whether gudev is available for device detection])
 607             AC_DEFINE([G_UDEV_API_IS_SUBJECT_TO_CHANGE], 1, [I know the API is subject to change.])
 608           ], [
 609           have_gudev=no
 610           ])
 611   else
 612     have_gudev=no
 613   fi
 614 fi
 615 AC_SUBST(GUDEV_CFLAGS)
 616 AC_SUBST(GUDEV_LIBS)
 617
 618 # Make libv4l2 non-automagic
 619 AC_ARG_WITH([libv4l2],
 620   AC_HELP_STRING([--with-libv4l2],
 621     [support video buffer conversion using libv4l2]),
 622   [],
 623   [with_libv4l2=check])
 624 if test x$HAVE_GST_V4L2 = xyes; then
 625   if test x$with_libv4l2 != xno; then
 626       PKG_CHECK_MODULES(LIBV4L2, libv4l2,
 627           [ have_libv4l2=yes
 628             AC_DEFINE(HAVE_LIBV4L2, 1,
 629                 [Whether libv4l2 is available for video buffer conversion])
 630           ], [
 631           have_libv4l2=no
 632           ])
 633   else
 634     have_libv4l2=no
 635   fi
 636 fi
 637
 638 dnl Check for X11
 639 translit(dnm, m, l) AM_CONDITIONAL(USE_X, true)
 640 AG_GST_CHECK_FEATURE(X, [X libraries and plugins],
 641                   [ximagesrc], [
 642   AC_PATH_XTRA
 643
 644   dnl now try to find the HEADER
 645   ac_cflags_save="$CFLAGS"
 646   ac_cppflags_save="$CPPFLAGS"
 647   CFLAGS="$CFLAGS $X_CFLAGS"
 648   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 649   AC_CHECK_HEADER(X11/Xlib.h, HAVE_X="yes", HAVE_X="no")
 650
 651   if test "x$HAVE_X" = "xno"
 652   then
 653     AC_MSG_NOTICE([cannot find X11 development files])
 654   else
 655     dnl this is much more than we want
 656     X_LIBS="$X_LIBS $X_PRE_LIBS $X_EXTRA_LIBS"
 657     dnl AC_PATH_XTRA only defines the path needed to find the X libs,
 658     dnl it does not add the libs; therefore we add them here
 659     X_LIBS="$X_LIBS -lX11"
 660     AC_SUBST(X_CFLAGS)
 661     AC_SUBST(X_LIBS)
 662
 663     dnl check for Xfixes
 664     PKG_CHECK_MODULES(XFIXES, xfixes, HAVE_XFIXES="yes", HAVE_XFIXES="no")
 665     if test "x$HAVE_XFIXES" = "xyes"
 666     then
 667         XFIXES_CFLAGS="-DHAVE_XFIXES $XFIXES_CFLAGS"
 668     fi
 669     AC_SUBST(XFIXES_LIBS)
 670     AC_SUBST(XFIXES_CFLAGS)
 671
 672     dnl check for Xdamage
 673     PKG_CHECK_MODULES(XDAMAGE, xdamage, HAVE_XDAMAGE="yes", HAVE_XDAMAGE="no")
 674     if test "x$HAVE_XDAMAGE" = "xyes"
 675     then
 676         XDAMAGE_CFLAGS="-DHAVE_XDAMAGE $XDAMAGE_CFLAGS"
 677     fi
 678     AC_SUBST(XDAMAGE_LIBS)
 679     AC_SUBST(XDAMAGE_CFLAGS)
 680   fi
 681   AC_SUBST(HAVE_X)
 682   CFLAGS="$ac_cflags_save"
 683   CPPFLAGS="$ac_cppflags_save"
 684 ])
 685
 686 dnl FIXME: this should be rolled into the test above, it's just an additional
 687 dnl feature of the ximagesrc plug-in
 688 dnl This is the same as in gst-plugins-base
 689 dnl check for X Shm
 690 translit(dnm, m, l) AM_CONDITIONAL(USE_XSHM, true)
 691 AG_GST_CHECK_FEATURE(XSHM, [X Shared Memory extension], , [
 692   if test x$HAVE_X = xyes; then
 693     AC_CHECK_LIB(Xext, XShmAttach,
 694                  HAVE_XSHM="yes", HAVE_XSHM="no",
 695                  $X_LIBS)
 696     if test "x$HAVE_XSHM" = "xyes"; then
 697       XSHM_LIBS="-lXext"
 698     else
 699       dnl On AIX, it is in XextSam instead, but we still need -lXext
 700       AC_CHECK_LIB(XextSam, XShmAttach,
 701                    HAVE_XSHM="yes", HAVE_XSHM="no",
 702                    $X_LIBS)
 703       if test "x$HAVE_XSHM" = "xyes"; then
 704         XSHM_LIBS="-lXext -lXextSam"
 705       fi
 706     fi
 707   fi
 708 ], ,[
 709   AC_SUBST(HAVE_XSHM)
 710   AC_SUBST(XSHM_LIBS)
 711 ])
 712
 713 dnl for V4L2, we also need to know if we have XVIDEO
 714 translit(dnm, m, l) AM_CONDITIONAL(USE_XVIDEO, true)
 715 AG_GST_CHECK_FEATURE(XVIDEO, [X11 XVideo extensions],
 716                   [], [
 717   AG_GST_CHECK_XV
 718 ])
 719
 720 dnl *** ext plug-ins ***
 721 dnl keep this list sorted alphabetically !
 722
 723 if test "x$BUILD_EXTERNAL" = "xyes"; then
 724
 725 echo
 726 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 727 echo
 728
 729 dnl *** aalib ***
 730 translit(dnm, m, l) AM_CONDITIONAL(USE_AALIB, true)
 731 AG_GST_CHECK_FEATURE(AALIB, [aalib ASCII Art library], aasink, [
 732   AM_PATH_AALIB(, HAVE_AALIB=yes, HAVE_AALIB=no)
 733   AS_SCRUB_INCLUDE(AALIB_CFLAGS)
 734 ])
 735
 736 dnl *** annodex ***
 737 translit(dnm, m, l) AM_CONDITIONAL(USE_ANNODEX, true)
 738 AG_GST_CHECK_FEATURE(ANNODEX, [XML library], annodex, [
 739   AG_GST_PKG_CHECK_MODULES(ANNODEX, libxml-2.0 >= 2.4.9)
 740 ])
 741
 742 dnl *** cairo ***
 743 translit(dnm, m, l) AM_CONDITIONAL(USE_CAIRO, true)
 744 AG_GST_CHECK_FEATURE(CAIRO, [Cairo graphics rendering], cairo, [
 745   AG_GST_PKG_CHECK_MODULES(CAIRO, cairo >= 1.0.0)
 746 ])
 747
 748 dnl *** cairo-gobject ***
 749 translit(dnm, m, l) AM_CONDITIONAL(USE_CAIRO_GOBJECT, true)
 750 AG_GST_CHECK_FEATURE(CAIRO_GOBJECT,
 751   [Cairo graphics rendering gobject bindings], cairooverlay, [
 752   AG_GST_PKG_CHECK_MODULES(CAIRO_GOBJECT, cairo-gobject >= 1.10.0)
 753 ])
 754
 755 dnl *** FLAC ***
 756 translit(dnm, m, l) AM_CONDITIONAL(USE_FLAC, true)
 757 AG_GST_CHECK_FEATURE(FLAC, [FLAC lossless audio], flac, [
 758   AG_GST_PKG_CHECK_MODULES(FLAC, flac >= 1.1.4)
 759 ])
 760
 761 dnl *** GDK pixbuf ***
 762 translit(dnm, m, l) AM_CONDITIONAL(USE_GDK_PIXBUF, true)
 763 AG_GST_CHECK_FEATURE(GDK_PIXBUF, [GDK pixbuf], gdkpixbuf, [
 764   AG_GST_PKG_CHECK_MODULES(GDK_PIXBUF, gdk-pixbuf-2.0 >= 2.8.0)
 765 ])
 766
 767 dnl *** Jack ***
 768 translit(dnm, m, l) AM_CONDITIONAL(USE_JACK, true)
 769 AG_GST_CHECK_FEATURE(JACK, Jack, jack, [
 770   PKG_CHECK_MODULES(JACK, jack >= 0.99.10, HAVE_JACK="yes", HAVE_JACK="no")
 771   AC_SUBST(JACK_CFLAGS)
 772   AC_SUBST(JACK_LIBS)
 773
 774   AG_GST_PKG_CHECK_MODULES(JACK_0_120_1, jack >= 0.120.1 jack < 1.0)
 775   if test x$HAVE_JACK_0_120_1 = xyes; then
 776     AC_DEFINE(HAVE_JACK_0_120_1, 1, [defined if jack >= 0.120.1 is available])
 777   fi
 778   AG_GST_PKG_CHECK_MODULES(JACK_1_9_7, jack >= 1.9.7)
 779   if test x$HAVE_JACK_1_9_7 = xyes; then
 780     AC_DEFINE(HAVE_JACK_1_9_7, 1, [defined if jack >= 1.9.7 is available])
 781   fi
 782
 783 ])
 784
 785 dnl *** jpeg ***
 786 dnl FIXME: we could use header checks here as well IMO
 787 translit(dnm, m, l) AM_CONDITIONAL(USE_JPEG, true)
 788 AG_GST_CHECK_FEATURE(JPEG, [jpeg library], jpeg, [
 789   AC_ARG_WITH(jpeg-mmx,
 790     [  --with-jpeg-mmx, path to MMX'ified JPEG library])
 791   OLD_LIBS="$LIBS"
 792   if test x$with_jpeg_mmx != x; then
 793     LIBS="$LIBS -L$with_jpeg_mmx"
 794   fi
 795   AC_CHECK_LIB(jpeg-mmx, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
 796   JPEG_LIBS="$LIBS -ljpeg-mmx"
 797   LIBS="$OLD_LIBS"
 798   if test x$HAVE_JPEG != xyes; then
 799     AC_CHECK_LIB(jpeg, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
 800     JPEG_LIBS="-ljpeg"
 801   fi
 802   AC_SUBST(JPEG_LIBS)
 803 ])
 804
 805 dnl *** libcaca ***
 806 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBCACA, true)
 807 AG_GST_CHECK_FEATURE(LIBCACA, [libcaca coloured ASCII art], cacasink, [
 808   AG_GST_PKG_CHECK_MODULES(LIBCACA, caca)
 809 ])
 810
 811 dnl *** libdv ***
 812 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBDV, true)
 813 AG_GST_CHECK_FEATURE(LIBDV, [libdv DV demuxer/decoder], dv, [
 814   AG_GST_PKG_CHECK_MODULES(LIBDV, libdv >= 0.100)
 815 ])
 816
 817 dnl *** libpng ***
 818 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBPNG, true)
 819 AG_GST_CHECK_FEATURE(LIBPNG, [Portable Network Graphics library], png, [
 820   AG_GST_PKG_CHECK_MODULES(LIBPNG, libpng >= 1.2)
 821 ])
 822
 823 dnl *** pulseaudio ***
 824 translit(dnm, m, l) AM_CONDITIONAL(USE_PULSE, true)
 825 AG_GST_CHECK_FEATURE(PULSE, [pulseaudio plug-in], pulseaudio, [
 826
 827   dnl used in ext/pulse/pulseutil.c
 828   AC_CHECK_HEADERS([process.h])
 829
 830   AG_GST_PKG_CHECK_MODULES(PULSE, libpulse >= 1.0)
 831 ])
 832
 833 dnl *** dv1394 ***
 834 translit(dnm, m, l) AM_CONDITIONAL(USE_DV1394, true)
 835 AG_GST_CHECK_FEATURE(DV1394, [raw1394 and avc1394 library], 1394, [
 836   dnl first test for libraw1394 >= 2.0.0
 837   AG_GST_PKG_CHECK_MODULES(RAW1394, libraw1394 >= 2.0.0)
 838   AG_GST_PKG_CHECK_MODULES(LIBIEC61883, libiec61883 >= 1.0.0)
 839   dnl now see how far we got
 840   if test x$HAVE_RAW1394 = xyes && \
 841      test x$HAVE_LIBIEC61883 = xyes; then
 842        AG_GST_CHECK_LIBHEADER(AVC1394,
 843         avc1394, avc1394_send_command, $RAW1394_LIBS,
 844         libavc1394/avc1394.h, AVC1394_LIBS="-lavc1394")
 845        AG_GST_CHECK_LIBHEADER(ROM1394,
 846         rom1394, rom1394_free_directory, $RAW1394_LIBS,
 847         libavc1394/rom1394.h, ROM1394_LIBS="-lrom1394")
 848        if test x$HAVE_AVC1394 = xyes && \
 849           test x$HAVE_AVC1394 = xyes && \
 850           test x$HAVE_ROM1394 = xyes; then
 851           HAVE_DV1394=yes
 852           DV1394_LIBS="$RAW1394_LIBS $AVC1394_LIBS $ROM1394_LIBS $LIBIEC61883_LIBS"
 853           DV1394_CFLAGS="$RAW1394_CFLAGS $LIBIEC61883_CFLAGS -DHAVE_LIBIEC61883"
 854           AC_SUBST(DV1394_CFLAGS)
 855           AC_SUBST(DV1394_LIBS)
 856         fi
 857   else
 858        if test x$HAVE_RAW1394 = xno; then
 859           AG_GST_PKG_CHECK_MODULES(RAW1394, libraw1394 >= 1.1.0)
 860           AG_GST_CHECK_LIBHEADER(AVC1394,
 861            avc1394, avc1394_send_command, $RAW1394_LIBS,
 862            libavc1394/avc1394.h, AVC1394_LIBS="-lavc1394")
 863           AG_GST_CHECK_LIBHEADER(ROM1394,
 864            rom1394, rom1394_free_directory, $RAW1394_LIBS,
 865            libavc1394/rom1394.h, ROM1394_LIBS="-lrom1394")
 866           if test x$HAVE_RAW1394 = xyes && \
 867              test x$HAVE_AVC1394 = xyes && \
 868              test x$HAVE_ROM1394 = xyes; then
 869              HAVE_DV1394=yes
 870              DV1394_LIBS="$RAW1394_LIBS $AVC1394_LIBS $ROM1394_LIBS"
 871              DV1394_CFLAGS="$RAW1394_CFLAGS"
 872              if test x$HAVE_LIBIEC61883 = xyes; then
 873                DV1394_CFLAGS="$RAW1394_CFLAGS $LIBIEC61883_CFLAGS -DHAVE_LIBIEC61883"
 874                DV1394_LIBS="$DV1394_LIBS $LIBIEC61883_LIBS"
 875              fi
 876              AC_SUBST(DV1394_CFLAGS)
 877              AC_SUBST(DV1394_LIBS)
 878            fi
 879          fi
 880   fi
 881 ])
 882 AM_CONDITIONAL(USE_LIBIEC61883, [ test "x${HAVE_LIBIEC61883}" = xyes ] )
 883
 884 dnl *** shout2 ***
 885 translit(dnm, m, l) AM_CONDITIONAL(USE_SHOUT2, true)
 886 AG_GST_CHECK_FEATURE(SHOUT2, [Shoutcast/Icecast client library], shout2, [
 887   AG_GST_PKG_CHECK_MODULES(SHOUT2, shout >= 2.0)
 888 ])
 889
 890 dnl *** soup ***
 891 translit(dnm, m, l) AM_CONDITIONAL(USE_SOUP, true)
 892 AG_GST_CHECK_FEATURE(SOUP, [soup http client plugin (2.4)], souphttpsrc, [
 893   PKG_CHECK_MODULES(SOUP, libsoup-gnome-2.4 >= 2.3.2, [
 894     HAVE_SOUP="yes"
 895     AC_DEFINE(HAVE_LIBSOUP_GNOME, 1, [soup gnome integration])
 896   ],[
 897     PKG_CHECK_MODULES(SOUP, libsoup-2.4 >= 2.26, HAVE_SOUP="yes", [
 898       HAVE_SOUP="no"
 899     ])
 900   ])
 901   AC_SUBST(SOUP_CFLAGS)
 902   AC_SUBST(SOUP_LIBS)
 903 ])
 904
 905 dnl *** speex >= 1.0.4 or >= 1.1.5 ***
 906 dnl   1.1.4 and earlier were not API/ABI compatible with 1.0
 907 dnl   1.1.6 is the first to use a .pc/pkg-config file ***
 908 dnl   speex_jitter.h is 1.1.x only
 909 translit(dnm, m, l) AM_CONDITIONAL(USE_SPEEX, true)
 910 AG_GST_CHECK_FEATURE(SPEEX, [speex speech codec], speex, [
 911   AG_GST_PKG_CHECK_MODULES(SPEEX, speex >= 1.1.6)
 912   if test $HAVE_SPEEX = no
 913   then
 914     AG_GST_CHECK_LIBHEADER(SPEEX, speex, speex_bits_init, , speex/speex.h, [
 915       AC_CHECK_HEADER(speex/speex_jitter.h, [
 916         dnl speex 1.1.x :
 917         AG_GST_CHECK_LIBHEADER(SPEEX, speex, speex_encode_int, , speex/speex.h, [
 918           dnl speex 1.1.5 or + :
 919           HAVE_SPEEX="yes"
 920           SPEEX_LIBS="-lspeex"
 921           AC_SUBST(SPEEX_CFLAGS)
 922           AC_SUBST(SPEEX_LIBS)
 923         ],[
 924           HAVE_SPEEX="no"
 925         ])
 926       ],[
 927         dnl speex 1.0.x :
 928           AC_CHECK_DECL(SPEEX_GET_LOOKAHEAD, [
 929             dnl speex 1.0.4
 930             HAVE_SPEEX="yes"
 931             SPEEX_LIBS="-lspeex"
 932             AC_SUBST(SPEEX_CFLAGS)
 933             AC_SUBST(SPEEX_LIBS)
 934
 935             AC_DEFINE_UNQUOTED(SPEEX_1_0, 1,
 936               [defined if speex 1.0.x API detected])
 937         ],[
 938             HAVE_SPEEX="no"
 939             AC_MSG_NOTICE(You need at least 1.0.4 to compile the speex plugin)
 940         ], [
 941 #include <speex/speex.h>
 942         ])
 943       ])
 944     ])
 945   fi
 946 ])
 947
 948 dnl *** taglib ***
 949 translit(dnm, m, l) AM_CONDITIONAL(USE_TAGLIB, true)
 950 AG_GST_CHECK_FEATURE(TAGLIB, [taglib tagging library], taglib, [
 951   AG_GST_PKG_CHECK_MODULES(TAGLIB, taglib >= 1.5)
 952   if test "x$HAVE_CXX" != "xyes"; then
 953     USE_TAGLIB=false
 954     AC_MSG_NOTICE([Not building taglib plugin: no C++ compiler found])
 955   else
 956     dnl work around bug in taglib 1.5 headers, remove once there is a 1.6
 957     AS_CXX_COMPILER_FLAG([-Wno-attributes], [
 958         TAGLIB_CXXFLAGS="$TAGLIB_CFLAGS -Wno-attributes"
 959       ], [
 960         TAGLIB_CXXFLAGS="$TAGLIB_CFLAGS"
 961     ])
 962     AC_SUBST(TAGLIB_CXXFLAGS)
 963   fi
 964 ])
 965
 966 dnl *** wavpack ***
 967 translit(dnm, m, l) AM_CONDITIONAL(USE_WAVPACK, true)
 968 AG_GST_CHECK_FEATURE(WAVPACK, [wavpack plug-in], wavpack, [
 969   PKG_CHECK_MODULES(WAVPACK, wavpack >= 4.40.0, HAVE_WAVPACK=yes, [
 970     PKG_CHECK_MODULES(WAVPACK, wavpack >= 4.20, [
 971       HAVE_WAVPACK=yes
 972       AC_DEFINE(WAVPACK_OLD_API, 1, [old wavpack API])
 973     ],[
 974       HAVE_WAVPACK=no
 975     ])
 976   ])
 977   AC_SUBST(WAVPACK_CFLAGS)
 978   AC_SUBST(WAVPACK_LIBS)
 979 ])
 980
 981 dnl *** qtdemux & matroska prefer to have zlib ***
 982 translit(dnm, m, l) AM_CONDITIONAL(USE_ZLIB, true)
 983 AG_GST_CHECK_FEATURE(ZLIB, [zlib support for qtdemux/matroska],, [
 984   AG_GST_CHECK_LIBHEADER(ZLIB,
 985     z, uncompress,, zlib.h, [
 986     HAVE_ZLIB="yes"
 987     ZLIB_LIBS="-lz"
 988     AC_SUBST(ZLIB_LIBS)
 989   ])
 990 ])
 991
 992 dnl *** matroska prefers to have bz2 ***
 993 translit(dnm, m, l) AM_CONDITIONAL(USE_BZ2, true)
 994 AG_GST_CHECK_FEATURE(BZ2, [bz2 library for matroska ],, [
 995   AG_GST_CHECK_LIBHEADER(BZ2, bz2, BZ2_bzCompress, ,bzlib.h, BZ2_LIBS="-lbz2")
 996   AC_SUBST(BZ2_LIBS)
 997 ])
 998
 999 else
1000
1001 dnl not building plugins with external dependencies,
1002 dnl but we still need to set the conditionals
1003 AM_CONDITIONAL(USE_AALIB, false)
1004 AM_CONDITIONAL(USE_ANNODEX, false)
1005 AM_CONDITIONAL(USE_BZ2, false)
1006 AM_CONDITIONAL(USE_CAIRO, false)
1007 AM_CONDITIONAL(USE_CAIRO_GOBJECT, false)
1008 AM_CONDITIONAL(USE_DIRECTSOUND, false)
1009 AM_CONDITIONAL(USE_DV1394, false)
1010 AM_CONDITIONAL(USE_FLAC, false)
1011 AM_CONDITIONAL(USE_GDK_PIXBUF, false)
1012 AM_CONDITIONAL(USE_GST_V4L2, false)
1013 AM_CONDITIONAL(USE_JACK, false)
1014 AM_CONDITIONAL(USE_JPEG, false)
1015 AM_CONDITIONAL(USE_LIBCACA, false)
1016 AM_CONDITIONAL(USE_LIBDV, false)
1017 AM_CONDITIONAL(USE_LIBIEC61883, false)
1018 AM_CONDITIONAL(USE_LIBPNG, false)
1019 AM_CONDITIONAL(USE_OSS, false)
1020 AM_CONDITIONAL(USE_OSS4, false)
1021 AM_CONDITIONAL(USE_OSX_AUDIO, false)
1022 AM_CONDITIONAL(USE_OSX_VIDEO, false)
1023 AM_CONDITIONAL(USE_PULSE, false)
1024 AM_CONDITIONAL(USE_SHOUT2, false)
1025 AM_CONDITIONAL(USE_SOUP, false)
1026 AM_CONDITIONAL(USE_SPEEX, false)
1027 AM_CONDITIONAL(USE_SUNAUDIO, false)
1028 AM_CONDITIONAL(USE_TAGLIB, false)
1029 AM_CONDITIONAL(USE_WAVEFORM, false)
1030 AM_CONDITIONAL(USE_WAVPACK, false)
1031 AM_CONDITIONAL(USE_X, false)
1032 AM_CONDITIONAL(USE_XSHM, false)
1033 AM_CONDITIONAL(USE_XVIDEO, false)
1034 AM_CONDITIONAL(USE_ZLIB, false)
1035
1036 fi dnl of EXT plugins
1037
1038 dnl *** finalize CFLAGS, LDFLAGS, LIBS
1039
1040 dnl Overview:
1041 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
1042 dnl GST_*:              flags shared by all built objects
1043 dnl GST_ALL_LDFLAGS:    linker flags shared by all
1044 dnl GST_LIB_LDFLAGS:    not needed, we don't install libraries
1045 dnl GST_LT_LDFLAGS:     library versioning of our libraries
1046 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
1047
1048 dnl GST_OPTION_CFLAGS
1049 if test "x$USE_DEBUG" = xyes; then
1050    PROFILE_CFLAGS="-g"
1051 fi
1052 AC_SUBST(PROFILE_CFLAGS)
1053
1054 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
1055   dnl Define _only_ for git (not pre-releases or releases)
1056   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
1057 else
1058   DEPRECATED_CFLAGS=""
1059 fi
1060 AC_SUBST(DEPRECATED_CFLAGS)
1061
1062 dnl every flag in GST_OPTION_CFLAGS and GST_OPTION_CXXFLAGS can be overridden
1063 dnl at make time with e.g. make ERROR_CFLAGS=""
1064 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
1065 GST_OPTION_CXXFLAGS="\$(WARNING_CXXFLAGS) \$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
1066 AC_SUBST(GST_OPTION_CFLAGS)
1067 AC_SUBST(GST_OPTION_CXXFLAGS)
1068
1069 dnl our libraries need to be versioned correctly
1070 AC_SUBST(GST_LT_LDFLAGS)
1071
1072 dnl FIXME: do we want to rename to GST_ALL_* ?
1073 dnl prefer internal headers to already installed ones
1074 dnl also add builddir include for enumtypes and marshal
1075 dnl add ERROR_CFLAGS, but overridable
1076 GST_CFLAGS="$GST_CFLAGS -DGST_USE_UNSTABLE_API"
1077 GST_CXXFLAGS="-I\$(top_srcdir)/gst-libs $GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_CXXFLAGS)"
1078 GST_CFLAGS="-I\$(top_srcdir)/gst-libs $GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_CFLAGS)"
1079 AC_SUBST(GST_CFLAGS)
1080 AC_SUBST(GST_CXXFLAGS)
1081 AC_SUBST(GST_LIBS)
1082
1083 dnl LDFLAGS really should only contain flags, not libs - they get added before
1084 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
1085 GST_ALL_LDFLAGS="-no-undefined"
1086 AC_SUBST(GST_ALL_LDFLAGS)
1087
1088 dnl this really should only contain flags, not libs - they get added before
1089 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
1090 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc.*' $GST_ALL_LDFLAGS"
1091 AC_SUBST(GST_PLUGIN_LDFLAGS)
1092
1093 dnl *** output files ***
1094
1095 dnl keep this alphabetic per directory, please
1096 AC_CONFIG_FILES(
1097 Makefile
1098 gst/Makefile
1099 gst/alpha/Makefile
1100 gst/apetag/Makefile
1101 gst/audiofx/Makefile
1102 gst/audioparsers/Makefile
1103 gst/auparse/Makefile
1104 gst/autodetect/Makefile
1105 gst/avi/Makefile
1106 gst/cutter/Makefile
1107 gst/deinterlace/Makefile
1108 gst/debugutils/Makefile
1109 gst/effectv/Makefile
1110 gst/equalizer/Makefile
1111 gst/flv/Makefile
1112 gst/goom/Makefile
1113 gst/goom2k1/Makefile
1114 gst/id3demux/Makefile
1115 gst/icydemux/Makefile
1116 gst/imagefreeze/Makefile
1117 gst/interleave/Makefile
1118 gst/isomp4/Makefile
1119 gst/law/Makefile
1120 gst/level/Makefile
1121 gst/matroska/Makefile
1122 gst/monoscope/Makefile
1123 gst/multifile/Makefile
1124 gst/multipart/Makefile
1125 gst/replaygain/Makefile
1126 gst/rtp/Makefile
1127 gst/rtpmanager/Makefile
1128 gst/rtsp/Makefile
1129 gst/shapewipe/Makefile
1130 gst/smpte/Makefile
1131 gst/spectrum/Makefile
1132 gst/udp/Makefile
1133 gst/videobox/Makefile
1134 gst/videocrop/Makefile
1135 gst/videofilter/Makefile
1136 gst/videomixer/Makefile
1137 gst/wavenc/Makefile
1138 gst/wavparse/Makefile
1139 gst/flx/Makefile
1140 gst/y4m/Makefile
1141 ext/Makefile
1142 ext/aalib/Makefile
1143 ext/annodex/Makefile
1144 ext/cairo/Makefile
1145 ext/dv/Makefile
1146 ext/flac/Makefile
1147 ext/gdk_pixbuf/Makefile
1148 ext/jack/Makefile
1149 ext/jpeg/Makefile
1150 ext/libcaca/Makefile
1151 ext/libpng/Makefile
1152 ext/pulse/Makefile
1153 ext/raw1394/Makefile
1154 ext/shout2/Makefile
1155 ext/soup/Makefile
1156 ext/speex/Makefile
1157 ext/taglib/Makefile
1158 ext/wavpack/Makefile
1159 sys/Makefile
1160 sys/directsound/Makefile
1161 sys/oss/Makefile
1162 sys/oss4/Makefile
1163 sys/osxaudio/Makefile
1164 sys/osxvideo/Makefile
1165 sys/sunaudio/Makefile
1166 sys/v4l2/Makefile
1167 sys/waveform/Makefile
1168 sys/ximage/Makefile
1169 po/Makefile.in
1170 tests/Makefile
1171 tests/check/Makefile
1172 tests/examples/Makefile
1173 tests/examples/audiofx/Makefile
1174 tests/examples/cairo/Makefile
1175 tests/examples/equalizer/Makefile
1176 tests/examples/jack/Makefile
1177 tests/examples/level/Makefile
1178 tests/examples/pulse/Makefile
1179 tests/examples/rtp/Makefile
1180 tests/examples/shapewipe/Makefile
1181 tests/examples/spectrum/Makefile
1182 tests/examples/v4l2/Makefile
1183 tests/files/Makefile
1184 tests/icles/Makefile
1185 common/Makefile
1186 common/m4/Makefile
1187 m4/Makefile
1188 docs/Makefile
1189 docs/plugins/Makefile
1190 docs/version.entities
1191 pkgconfig/Makefile
1192 pkgconfig/gstreamer-plugins-good-uninstalled.pc
1193 gst-plugins-good.spec
1194 )
1195
1196 dnl Create the config.h file for Visual Studio builds
1197 dnl Beware of spaces and /'s in some of the shell variable contents.
1198 sed \
1199     -e 's/.*config.h.in.*autoheader.*/\/* Autogenerated config.h created for win32 Visual Studio builds *\/\n\n\/* PREFIX -- specifically added for Windows for easier moving *\/\n#define PREFIX "C:\\\\gstreamer"\n\n#define GST_INSTALL_PLUGINS_HELPER PREFIX "\\\\libexec\\\\gst-install-plugins-helper.exe"/' \
1200     -e 's/.* GETTEXT_PACKAGE$/#define GETTEXT_PACKAGE "'$GETTEXT_PACKAGE'"/' \
1201     -e 's/.* GST_DATADIR$/#define GST_DATADIR PREFIX "\\\\share"/' \
1202     -e 's/.* GST_LEVEL_DEFAULT$/#define GST_LEVEL_DEFAULT GST_LEVEL_ERROR/' \
1203     -e 's/.* GST_LICENSE$/#define GST_LICENSE "'$GST_LICENSE'"/' \
1204     -e 's/.* GST_MAJORMINOR$/#define GST_MAJORMINOR "'$GST_MAJORMINOR'"/' \
1205     -e "s,.* GST_PACKAGE_NAME$,#define GST_PACKAGE_NAME \"${GST_PACKAGE_NAME}\"," \
1206     -e 's/.* GST_PACKAGE_ORIGIN$/#define GST_PACKAGE_ORIGIN "Unknown package origin"/' \
1207     -e "s,.* GST_PACKAGE_RELEASE_DATETIME$,#define GST_PACKAGE_RELEASE_DATETIME \"${GST_PACKAGE_RELEASE_DATETIME}\"," \
1208     -e 's/.* HAVE_CPU_I386$/#define HAVE_CPU_I386 1/' \
1209     -e 's/.* HAVE_FGETPOS$/#define HAVE_FGETPOS 1/' \
1210     -e 's/.* HAVE_FSETPOS$/#define HAVE_FSETPOS 1/' \
1211     -e 's/.* HAVE_LIBXML2$/#define HAVE_LIBXML2 1/' \
1212     -e 's/.* HAVE_PROCESS_H$/#define HAVE_PROCESS_H 1/' \
1213     -e 's/.* HAVE_STDLIB_H$/#define HAVE_STDLIB_H 1/' \
1214     -e 's/.* HAVE_STRING_H$/#define HAVE_STRING_H 1/' \
1215     -e 's/.* HAVE_SYS_STAT_H$/#define HAVE_SYS_STAT_H 1/' \
1216     -e 's/.* HAVE_SYS_TYPES_H$/#define HAVE_SYS_TYPES_H 1/' \
1217     -e 's/.* HAVE_WIN32$/#define HAVE_WIN32 1/' \
1218     -e 's/.* HAVE_WINSOCK2_H$/#define HAVE_WINSOCK2_H 1/' \
1219     -e 's/.* HOST_CPU$/#define HOST_CPU "i686"/' \
1220     -e 's/.* LIBDIR$/#ifdef _DEBUG\n#  define LIBDIR PREFIX "\\\\debug\\\\lib"\n#else\n#  define LIBDIR PREFIX "\\\\lib"\n#endif/' \
1221     -e 's/.* LOCALEDIR$/#define LOCALEDIR PREFIX "\\\\share\\\\locale"/' \
1222     -e "s/.* PACKAGE$/#define PACKAGE \"$PACKAGE\"/" \
1223     -e 's/.* PACKAGE_BUGREPORT$/#define PACKAGE_BUGREPORT "http:\/\/bugzilla.gnome.org\/enter_bug.cgi?product=GStreamer"/' \
1224     -e "s/.* PACKAGE_NAME$/#define PACKAGE_NAME \"$PACKAGE_NAME\"/" \
1225     -e "s/.* PACKAGE_STRING$/#define PACKAGE_STRING \"$PACKAGE_STRING\"/" \
1226     -e 's/.* PACKAGE_TARNAME$/#define PACKAGE_TARNAME "'$PACKAGE_TARNAME'"/' \
1227     -e 's/.* PACKAGE_VERSION$/#define PACKAGE_VERSION "'$PACKAGE_VERSION'"/' \
1228     -e 's/.* PLUGINDIR$/#ifdef _DEBUG\n#  define PLUGINDIR PREFIX "\\\\debug\\\\lib\\\\gstreamer-0.11"\n#else\n#  define PLUGINDIR PREFIX "\\\\lib\\\\gstreamer-0.11"\n#endif/' \
1229     -e 's/.* USE_BINARY_REGISTRY$/#define USE_BINARY_REGISTRY/' \
1230     -e 's/.* VERSION$/#define VERSION "'$VERSION'"/' \
1231     -e "s/.* DEFAULT_AUDIOSINK$/#define DEFAULT_AUDIOSINK \"directsoundsink\"/" \
1232     -e "s/.* DEFAULT_AUDIOSRC$/#define DEFAULT_AUDIOSRC \"audiotestsrc\"/" \
1233     -e "s/.* DEFAULT_VIDEOSRC$/#define DEFAULT_VIDEOSRC \"videotestsrc\"/" \
1234     -e "s/.* DEFAULT_VISUALIZER$/#define DEFAULT_VISUALIZER \"goom\"/" \
1235     config.h.in >win32/common/config.h-new
1236
1237 AC_OUTPUT
1238
1239 AG_GST_OUTPUT_PLUGINS
1240 ORC_OUTPUT
1241