configure.ac

   1 dnl autoconf configuration file for plugins
   2 AC_INIT
   3 dnl FIXME take something else ?
   4 AC_CONFIG_SRCDIR([COPYING])
   5
   6 AC_CANONICAL_TARGET([])
   7
   8 AM_CONFIG_HEADER(config.h)
   9
  10 GST_VERSION_MAJOR=0
  11 GST_VERSION_MINOR=3
  12 GST_VERSION_MICRO=02
  13
  14 dnl we use the release tag during CVS development
  15 GST_VERSION_RELEASE=`date +%Y%m%d`
  16
  17 GST_VERSION=$GST_VERSION_MAJOR.$GST_VERSION_MINOR.$GST_VERSION_MICRO
  18
  19 PACKAGE=gst-plugins
  20 VERSION=$GST_VERSION
  21
  22 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE")
  23 AC_DEFINE_UNQUOTED(VERSION, "$VERSION")
  24 AC_SUBST(PACKAGE)
  25 AC_SUBST(VERSION)
  26 AC_DEFINE_UNQUOTED(GST_VERSION_RELEASE, "$GST_VERSION_RELEASE")
  27 AC_SUBST(GST_VERSION_RELEASE)
  28
  29 dnl libtool
  30 GST_CURRENT=1
  31 GST_REVISION=0
  32 GST_AGE=0
  33 GST_LIBVERSION=$GST_CURRENT:$GST_REVISION:$GST_AGE
  34
  35 AM_INIT_AUTOMAKE($PACKAGE, $VERSION)
  36 dnl Add parameters for aclocal
  37 dnl (This must come after AM_INIT_AUTOMAKE, since it modifies ACLOCAL)
  38 ACLOCAL="$ACLOCAL $ACLOCAL_FLAGS"
  39
  40 AC_SUBST(GST_VERSION_MAJOR)
  41 AC_SUBST(GST_VERSION_MINOR)
  42 AC_SUBST(GST_VERSION_MICRO)
  43 AC_SUBST(GST_VERSION)
  44
  45 AC_SUBST(GST_CURRENT)
  46 AC_SUBST(GST_REVISION)
  47 AC_SUBST(GST_AGE)
  48 AC_SUBST(GST_LIBVERSION)
  49
  50 AM_MAINTAINER_MODE
  51
  52 AC_PROG_CC
  53 AM_PROG_CC_STDC
  54 AM_PROG_AS
  55 AS="${CC}"
  56 AC_PROG_CXX
  57 AC_PROG_CXXCPP
  58 AC_ISC_POSIX
  59
  60 dnl We disable static building for development, for time savings
  61 dnl *NOTE*: dnl this line before release, so release does static too
  62 AM_DISABLE_STATIC
  63 AC_LIBTOOL_DLOPEN
  64 AM_PROG_LIBTOOL
  65
  66 AC_HEADER_STDC([])
  67
  68 dnl ###########################################
  69 dnl # Super Duper options for plugin building #
  70 dnl ###########################################
  71
  72 dnl experimental plugins; stuff that hasn't had the dust settle yet
  73 dnl read 'builds, but might not work'
  74 GST_CHECK_FEATURE(EXPERIMENTAL, [enable building of experimental plugins],,
  75 [HAVE_EXPERIMENTAL=yes],disabled,
  76 [
  77   AC_MSG_WARN(building experimental plugins)
  78   USE_LIBMIKMOD="yes"
  79   USE_SMOOTHWAVE="yes"
  80 ],[
  81   AC_MSG_NOTICE(not building experimental plugins)
  82   USE_LIBMIKMOD="no"
  83   USE_SMOOTHWAVE="no"
  84 ])
  85
  86 dnl broken plugins; stuff that doesn't seem to build at the moment
  87 GST_CHECK_FEATURE(BROKEN, [enable building of broken plugins],,
  88 HAVE_BROKEN=yes,disabled,
  89 [
  90   AC_MSG_WARN(building broken plugins)
  91   USE_VGA="yes"
  92   USE_XMMS="yes"
  93   dnl AC_MSG_NOTICE(actually there are no broken plugins at the moment)
  94 ],[
  95   USE_VGA="no"
  96   USE_XMMS="no"
  97   AC_MSG_NOTICE(not building broken plugins)
  98 ])
  99
 100 dnl ##############################
 101 dnl # Do automated configuration #
 102 dnl ##############################
 103
 104 dnl Check for tools:
 105 dnl ================
 106
 107 dnl modify pkg-config path
 108 AC_ARG_WITH(pkg-config-path,
 109    AC_HELP_STRING([--with-pkg-config-path],[colon-separated list of pkg-config(1) dirs]),
 110    [export PKG_CONFIG_PATH=${withval}])
 111
 112 dnl Check for nasm
 113 AC_PATH_PROG(NASM_PATH, nasm, no)
 114 AC_SUBST(NASM_PATH)
 115 if test x$NASM_PATH = xno; then
 116   AC_MSG_WARN(Couldn't find nasm)
 117   HAVE_NASM="no"
 118 else
 119   AC_DEFINE(HAVE_NASM, 1, [Define if NASM, the netwide assembler, is available])
 120   HAVE_NASM="yes"
 121 fi
 122
 123 dnl check for gstreamer; check for uninstalled first
 124 PKG_CHECK_MODULES(GST, gstreamer-uninstalled >= 0.3.0, HAVE_GST="yes", HAVE_GST="no")
 125 if test "x$HAVE_GST" = "xno"; then
 126   PKG_CHECK_MODULES(GST, gstreamer >= 0.3.0, HAVE_GST="yes", HAVE_GST="no")
 127 fi
 128
 129 if test "x$HAVE_GST" = "xno"; then
 130   AC_MSG_ERROR(no GStreamer found)
 131 fi
 132
 133 dnl Set up conditionals for (target) architecture:
 134 dnl ==============================================
 135
 136 dnl Determine CPU
 137 case "x${target_cpu}" in
 138   xi?86 | k?) HAVE_CPU_I386=yes
 139               AC_DEFINE(HAVE_CPU_I386, 1, [Define if the target CPU is an x86])
 140               dnl FIXME could use some better detection
 141               dnl       (ie CPUID)
 142               case "x${target_cpu}" in
 143                 xi386 | xi486) ;;
 144                 *)             AC_DEFINE(HAVE_RDTSC) ;;
 145               esac ;;
 146   xpowerpc)   HAVE_CPU_PPC=yes
 147               AC_DEFINE(HAVE_CPU_PPC, 1, [Define if the target CPU is a PPC]) ;;
 148   xalpha)     HAVE_CPU_ALPHA=yes
 149               AC_DEFINE(HAVE_CPU_ALPHA, 1, [Define if the target CPU is an Alpha]) ;;
 150   xarm*)      HAVE_CPU_ARM=yes
 151               AC_DEFINE(HAVE_CPU_ARM, 1, [Define if the target CPU is an ARM]) ;;
 152   xsparc*)    HAVE_CPU_SPARC=yes
 153               AC_DEFINE(HAVE_CPU_SPARC, 1, [Define if the target CPU is a PPC]) ;;
 154   xmips*)     HAVE_CPU_MIPS=yes
 155               AC_DEFINE(HAVE_CPU_MIPS, 1, [Define if the target CPU is a MIPS]) ;;
 156   xhppa*)     HAVE_CPU_HPPA=yes
 157               AC_DEFINE(HAVE_CPU_HPPA, 1, [Define if the target CPU is a HPPA]) ;;
 158 esac
 159
 160 dnl Determine endianness
 161 AC_C_BIGENDIAN
 162
 163 dnl Check for MMX-capable compiler
 164 AC_MSG_CHECKING(for MMX-capable compiler)
 165 AC_TRY_RUN([
 166 #include "include/mmx.h"
 167
 168 main()
 169 { movq_r2r(mm0, mm1); return 0; }
 170 ],
 171 [
 172 HAVE_LIBMMX="yes"
 173 AC_MSG_RESULT(yes)
 174 ],
 175 HAVE_LIBMMX="no"
 176 AC_MSG_RESULT(no)
 177 ,
 178 HAVE_LIBMMX="no"
 179 AC_MSG_RESULT(no)
 180 )
 181
 182 dnl
 183 dnl We should really use AC_SYS_LARGEFILE, but the problem is
 184 dnl many of the plugins don't include "config.h".  To assure
 185 dnl binary compatibility, it is necessary that all gstreamer
 186 dnl code be compiled with the same sizeof(off_t), so we use
 187 dnl the following crude hack.
 188 dnl
 189
 190 AC_MSG_CHECKING(for large file support)
 191 AC_TRY_RUN([
 192 #define _LARGEFILE_SOURCE
 193 #define _FILE_OFFSET_BITS 64
 194 #include <sys/types.h>
 195 int main () { return !(sizeof(off_t) == 8); }
 196 ],
 197 [
 198 AC_MSG_RESULT(yes)
 199 GST_CFLAGS="$GST_CFLAGS -D_LARGEFILE_SOURCE -D_FILE_OFFSET_BITS=64"
 200 ],
 201 [
 202 AC_MSG_RESULT(no)
 203 ],
 204 [
 205 AC_MSG_RESULT(no)
 206 ])
 207
 208 dnl Check for essential libraries first:
 209 dnl ====================================
 210
 211 if test -n "`echo $GST_CFLAGS | grep USE_GLIB2`"; then
 212   USE_GLIB2=yes
 213 else
 214   USE_GLIB2=no
 215 fi
 216
 217 dnl needed for some plugins and demos, now's a nice time to check for gtk
 218 if test x$USE_GLIB2 = xno; then
 219   AM_PATH_GTK(1.2.0,,
 220               AC_MSG_ERROR(Cannot find gtk: Is gtk-config in path?))
 221   HAVE_GTK=yes
 222   # we have to have it
 223 else
 224   PKG_CHECK_MODULES(GTK2, gtk+-2.0, HAVE_GTK=yes, HAVE_GTK=no)
 225
 226   GTK_CFLAGS=$GTK2_CFLAGS
 227   GTK_LIBS=$GTK2_LIBS
 228 fi
 229 AC_SUBST(GTK_LIBS)
 230 AC_SUBST(GTK_CFLAGS)
 231
 232 dnl Check for X11 extensions
 233 AC_PATH_XTRA
 234 if test "-DX_DISPLAY_MISSING" = "$X_CFLAGS"; then
 235   AC_MSG_ERROR(can not find X11)
 236 fi
 237 AC_SUBST(X_CFLAGS)
 238 AC_SUBST(X_PRE_LIBS)
 239 AC_SUBST(X_EXTRA_LIBS)
 240 AC_SUBST(X_LIBS)
 241
 242 dnl ==========================================================================
 243 dnl ============================= gst plugins ================================
 244 dnl ==========================================================================
 245
 246 GST_PLUGINS_ALL="\
 247         ac3parse adder audioscale auparse avi chart\
 248         cutter deinterlace flx intfloat law level\
 249         median mpeg1enc mpeg1sys mpeg1videoparse mpeg2enc mpeg2sub\
 250         mpegaudio mpegaudioparse mpegstream mpegtypes\
 251         passthrough playondemand rtjpeg silence sine\
 252         smooth spectrum speed stereo stereomono\
 253         synaesthesia udp videoscale volenv volume vumeter wavparse y4m"
 254
 255 AC_SUBST(GST_PLUGINS_ALL)
 256
 257 GST_PLUGINS_SELECTED=""
 258
 259 AC_ARG_WITH(plugins,
 260     AC_HELP_STRING([--with-plugins],[comma-separated list of plugins to compile]),
 261     [for i in `echo $withval | tr , ' '`; do
 262         if test -n `echo $i | grep $GST_PLUGINS_ALL`; then
 263             GST_PLUGINS_SELECTED="$GST_PLUGINS_SELECTED $i"
 264         else
 265             echo "plugin $i not recognized, ignoring..."
 266         fi
 267     done],
 268     [GST_PLUGINS_SELECTED=$GST_PLUGINS_ALL])
 269
 270 AC_SUBST(GST_PLUGINS_SELECTED)
 271
 272 dnl ==========================================================================
 273 dnl ============================= sys plugins ================================
 274 dnl ==========================================================================
 275
 276
 277 dnl *** OSS audio ***
 278 translit(dnm, m, l) AM_CONDITIONAL(USE_OSS, true)
 279 GST_CHECK_FEATURE(OSS, [OSS audio], osssrc osssink, [
 280   AC_CHECK_HEADER(sys/soundcard.h, HAVE_OSS="yes", HAVE_OSS="no")
 281 ])
 282
 283 dnl *** QuickCam ***
 284 translit(dnm, m, l) AM_CONDITIONAL(USE_QCAM, true)
 285 GST_CHECK_FEATURE(QCAM, [QuickCam], qcamsrc, HAVE_QCAM="yes")
 286
 287 dnl *** Video 4 Linux ***
 288 translit(dnm, m, l) AM_CONDITIONAL(USE_V4L, true)
 289 GST_CHECK_FEATURE(V4L, [Video 4 Linux], v4lsrc, [
 290   AC_CHECK_HEADER(linux/videodev.h, HAVE_V4L="yes", HAVE_V4L="no")
 291 ])
 292
 293 dnl *** Video CD ***
 294 translit(dnm, m, l) AM_CONDITIONAL(USE_VCD, true)
 295 GST_CHECK_FEATURE(VCD, [Video CD], vcdsrc, [
 296   AC_CHECK_HEADER(linux/cdrom.h, HAVE_VCD="yes", HAVE_VCD="no")
 297 ])
 298
 299 dnl *** VGA ***
 300 translit(dnm, m, l) AM_CONDITIONAL(USE_VGA, true)
 301 GST_CHECK_FEATURE(VGA, [VGA], vgavideosink, [
 302   AC_CHECK_HEADER(asm/vga.h, HAVE_VGA="yes", HAVE_VGA="no")
 303 ])
 304
 305 dnl *** XVideo ***
 306 dnl look for the PIC library first, debian likes it
 307 dnl yeah but redhat doesn't even *have* it and it works fine without
 308 dnl GST_CHECK_LIBHEADER(XVIDEO, Xv_pic, XvQueryExtension, $X_LIBS $X_PRE_LIBS -lXext -lX11 $X_EXTRA_LIBS, X11/extensions/Xvlib.h)
 309 translit(dnm, m, l) AM_CONDITIONAL(USE_XVIDEO, true)
 310 GST_CHECK_FEATURE(XVIDEO, [X11 XVideo extensions], xvideosink, [
 311   GST_CHECK_LIBHEADER(XVIDEO, Xv, XvQueryExtension, $X_LIBS $X_PRE_LIBS -lXext -lX11 $X_EXTRA_LIBS, X11/extensions/Xvlib.h)
 312   XVIDEO_LIBS="-lXv -lXext"
 313   AC_SUBST(XVIDEO_LIBS)
 314 ])
 315
 316 dnl Next, check for the optional libraries:
 317 dnl These are all libraries used in building plugins
 318 dnl ================================================
 319 dnl let's try and sort them alphabetically, shall we ?
 320
 321 echo
 322 echo
 323 AC_MSG_NOTICE(Checking for plugin libraries)
 324
 325 dnl *** a52dec ***
 326 translit(dnm, m, l) AM_CONDITIONAL(USE_A52DEC, true)
 327 GST_CHECK_FEATURE(A52DEC, [a52dec], a52dec, [
 328   GST_CHECK_LIBHEADER(A52DEC, a52, a52_init, -lm, a52dec/a52.h, A52DEC_LIBS="-la52")
 329 ])
 330
 331 dnl *** aalib ***
 332 translit(dnm, m, l) AM_CONDITIONAL(USE_AALIB, true)
 333 GST_CHECK_FEATURE(AALIB, [aasink plugin], aasink, [
 334   AM_PATH_AALIB(, HAVE_AALIB=yes, HAVE_AALIB=no)
 335 ])
 336
 337 dnl *** alsa ***
 338 translit(dnm, m, l) AM_CONDITIONAL(USE_ALSA, true)
 339 GST_CHECK_FEATURE(ALSA, [alsa plugins], gstalsa, [
 340   AM_PATH_ALSA(0.9.0, HAVE_ALSA=yes, HAVE_ALSA=no)
 341 ])
 342
 343 dnl *** arts ***
 344
 345 dnl if mcopidl can't be found there's no use in compiling it
 346 AC_CHECK_PROG(MCOPIDL, mcopidl, yes, no)
 347 if test "xHAVE_MCOPIDL" = "xno";
 348 then
 349   USE_ARTS=no
 350 fi
 351
 352 translit(dnm, m, l) AM_CONDITIONAL(USE_ARTS, true)
 353 GST_CHECK_FEATURE(ARTS, [arts plugins], arts, [
 354   AM_PATH_ARTS(, HAVE_ARTS=yes, HAVE_ARTS=no)
 355 ])
 356 dnl if mcopidl can't be found there's no use in compiling it
 357 AC_PATH_PROG(MCOPIDL, mcopidl, yes, no)
 358 if test "xHAVE_MCOPIDL" = "xno";
 359 then
 360   USE_ARTS=NO
 361 fi
 362
 363 dnl *** artsc ***
 364 translit(dnm, m, l) AM_CONDITIONAL(USE_ARTSC, true)
 365 GST_CHECK_FEATURE(ARTSC, [artsd plugins], artsdsink, [
 366   GST_CHECK_ARTSC()
 367 ])
 368
 369 dnl *** audiofile ***
 370 dnl this check uses the GST_CHECK_CONFIGPROG macro
 371 translit(dnm, m, l) AM_CONDITIONAL(USE_AUDIOFILE, true)
 372 GST_CHECK_FEATURE(AUDIOFILE, [audiofile], afsink afsrc, [
 373   translit(dnm, m, l) AC_SUBST(AUDIOFILE_LIBS)
 374   translit(dnm, m, l) AC_SUBST(AUDIOFILE_CFLAGS)
 375   GST_CHECK_CONFIGPROG(AUDIOFILE, audiofile-config)
 376 ])
 377
 378 dnl *** avifile ***
 379 dnl this check uses the GST_CHECK_CONFIGPROG macro
 380 dnl this check needs more fixing
 381 dnl translit(dnm, m, l) AC_SUBST(AVIFILE_LIBS)
 382 translit(dnm, m, l) AM_CONDITIONAL(USE_AVIFILE, true)
 383 GST_CHECK_FEATURE(AVIFILE, [avifile], windec winenc, [
 384   translit(dnm, m, l) AC_SUBST(AVIFILE_CFLAGS)
 385   GST_CHECK_CONFIGPROG(AVIFILE, avifile-config)
 386   AVIFILE_LIBS="$AVIFILE_LIBS -lstdc++"
 387   AC_SUBST(AVIFILE_LIBS)
 388 ])
 389
 390 dnl *** CDParanoia ***
 391 translit(dnm, m, l) AM_CONDITIONAL(USE_CDPARANOIA, true)
 392 GST_CHECK_FEATURE(CDPARANOIA, [CDParanoia], cdparanoia, [
 393   GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface, cdda_open, , cdda_interface.h, CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia")
 394   AC_SUBST(CDPARANOIA_LIBS)
 395 ])
 396 dnl FIXME : add second check somehow if that is necessary
 397 dnl AC_CHECK_LIB(cdda_paranoia, paranoia_init, : , HAVE_CDPARANOIA=no, -lcdda_interface )
 398 dnl AC_CHECK_HEADER(cdda_paranoia.h, :, HAVE_CDPARANOIA=no)
 399
 400 dnl *** dv ***
 401 dnl FIXME : check if those GLIB thingies are ok
 402 translit(dnm, m, l) AM_CONDITIONAL(USE_DV, true)
 403 GST_CHECK_FEATURE(DV, [dv library], dv, [
 404   GST_CHECK_LIBHEADER(DV, dv, dv_init, -lm $GLIB_LIBS $GLIB_CFLAGS, libdv/dv.h, DV_LIBS="-ldv")
 405   AC_SUBST(DV_LIBS)
 406 ])
 407
 408 dnl *** dvdread ***
 409 translit(dnm, m, l) AM_CONDITIONAL(USE_DVDREAD, true)
 410 GST_CHECK_FEATURE(DVDREAD, [dvdread library], dvdsrc, [
 411   GST_CHECK_LIBHEADER(DVDREAD, dvdread, DVDOpen, , dvdread/dvd_reader.h, DVDREAD_LIBS="-ldvdread")
 412   AC_SUBST(DVDREAD_LIBS)
 413 ])
 414
 415 dnl **** ESound ****
 416 translit(dnm, m, l) AM_CONDITIONAL(USE_ESD, true)
 417 GST_CHECK_FEATURE(ESD, [esound plugins], esdsrc esdsink, [
 418   AM_PATH_ESD(0.2.12, HAVE_ESD=yes, HAVE_ESD=no)
 419 ])
 420
 421 dnl **** festival ****
 422 dnl FIXME until thomas can be bothered to download the 20 MB festival sources
 423 dnl this will not go in
 424 translit(dnm, m, l) AM_CONDITIONAL(USE_FESTIVAL, true)
 425 GST_CHECK_FEATURE(FESTIVAL, [festival plugins], festivalsrc, [
 426   GST_CHECK_LIBHEADER(FESTIVAL, festival, festival_tidy_up, -lFestival, festival/festival.h, FESTIVAL_LIBS="-lFestival")
 427   AC_SUBST(FESTIVAL_LIBS)
 428 ])
 429
 430 dnl *** FLAC ***
 431 dnl thomas : checking for compile with main instead of actual function,
 432 dnl since that made autoconf break (for version 2.13)
 433 translit(dnm, m, l) AM_CONDITIONAL(USE_FLAC, true)
 434 GST_CHECK_FEATURE(FLAC, [FLAC lossless audio], flacenc flacdec, [
 435   GST_CHECK_LIBHEADER(FLAC, FLAC, main, -lm, FLAC/all.h, FLAC_LIBS="-lFLAC")
 436   AC_SUBST(FLAC_LIBS)
 437 ])
 438
 439 dnl *** Gnome VFS ***
 440 dnl this check uses the GST_CHECK_CONFIGPROG macro with gnome-config vfs
 441 translit(dnm, m, l) AM_CONDITIONAL(USE_GNOME_VFS, true)
 442 GST_CHECK_FEATURE(GNOME_VFS, [Gnome VFS], gnomevfssrc, [
 443 translit(dnm, m, l) AC_SUBST(GNOME_VFS_LIBS)
 444 translit(dnm, m, l) AC_SUBST(GNOME_VFS_CFLAGS)
 445 GST_CHECK_CONFIGPROG(GNOME_VFS, gnome-config vfs)
 446 ])
 447
 448 dnl *** gsm ***
 449 translit(dnm, m, l) AM_CONDITIONAL(USE_GSM, true)
 450 GST_CHECK_FEATURE(GSM, [GSM library], gsmenc gsmdec, [
 451   GST_CHECK_LIBHEADER(GSM, gsm, gsm_create, , gsm.h, GSM_LIBS="-lgsm")
 452   AC_SUBST(GSM_LIBS)
 453 ])
 454
 455 dnl *** Hermes ***
 456 translit(dnm, m, l) AM_CONDITIONAL(USE_HERMES, true)
 457 GST_CHECK_FEATURE(HERMES, [Hermes library], colorspace, [
 458   GST_CHECK_LIBHEADER(HERMES, Hermes, Hermes_ConverterInstance, , Hermes/Hermes.h, HERMES_LIBS="-lHermes")
 459 ], AC_SUBST(HERMES_LIBS))
 460
 461 dnl *** http ***
 462 translit(dnm, m, l) AM_CONDITIONAL(USE_HTTP, true)
 463 GST_CHECK_FEATURE(HTTP, [http plugins], gsthttpsrc, [
 464   dnl FIXME: need to check for header
 465   GHTTP_LIBS=
 466   GST_HTTPSRC_GET_TYPE=
 467   if test x$USE_GLIB2 = xyes; then
 468     AC_MSG_WARN(ghttp disabled for glib2.0)
 469   else
 470     AC_CHECK_LIB(ghttp, ghttp_request_new,
 471       [HTTP_LIBS="-lghttp"
 472        GST_HTTPSRC_GET_TYPE="gst_httpsrc_get_type"
 473        HAVE_HTTP=yes
 474       ], :, $LIBS)
 475   fi
 476   AC_SUBST(HTTP_LIBS)
 477   AC_SUBST(GST_HTTPSRC_GET_TYPE)
 478 ])
 479
 480 dnl *** lame ***
 481 translit(dnm, m, l) AM_CONDITIONAL(USE_LAME, true)
 482 GST_CHECK_FEATURE(LAME, [lame mp3 encoder library], lame, [
 483 GST_CHECK_LIBHEADER(LAME, mp3lame, lame_init, -lm, lame/lame.h, LAME_LIBS="-lmp3lame")
 484 ])
 485 AC_SUBST(LAME_LIBS)
 486
 487
 488 dnl FIXME : check if these CPP flags can be dealt with otherwise
 489 dnl libdvcheck_save_CPPFLAGS="$CPPFLAGS"
 490 dnl CPPFLAGS="$CPPFLAGS $GLIB_CFLAGS"
 491 dnl AC_CHECK_HEADER(libdv/dv.h, :, HAVE_LIBDV=no)
 492 dnl CPPFLAGS="$libdvcheck_save_CPPFLAGS"
 493
 494 dnl *** jpeg ***
 495 dnl FIXME: we could use header checks here as well IMO
 496 translit(dnm, m, l) AM_CONDITIONAL(USE_JPEG, true)
 497 GST_CHECK_FEATURE(JPEG, [jpeg], jpegenc jpegdec, [
 498   AC_CHECK_LIB(jpeg, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
 499   JPEG_LIBS="-ljpeg"
 500   AC_SUBST(JPEG_LIBS)
 501 ])
 502
 503 dnl *** mad ***
 504 dnl FIXME: we could use header checks here as well IMO
 505 translit(dnm, m, l) AM_CONDITIONAL(USE_MAD, true)
 506 GST_CHECK_FEATURE(MAD, [mad mp3 decoder], mad, [
 507   AC_CHECK_LIB(mad, mad_decoder_finish, HAVE_MAD="yes" MAD_LIBS="-lmad")
 508 ])
 509 AC_SUBST(MAD_LIBS)
 510
 511 dnl *** mikmod ***
 512 translit(dnm, m, l) AM_CONDITIONAL(USE_MIKMOD, true)
 513 GST_CHECK_FEATURE(MIKMOD, [mikmod plugin], mikmod, [
 514   AM_PATH_LIBMIKMOD(, HAVE_MIKMOD=yes, HAVE_MIKMOD=no)
 515   AC_SUBST(MIKMOD_LIBS, "$LIBMIKMOD_LIBS")
 516   AC_SUBST(MIKMOD_CFLAGS, "$LIBMIKMODCFLAGS")
 517 ])
 518
 519 dnl *** mpeg2dec ***
 520 translit(dnm, m, l) AM_CONDITIONAL(USE_MPEG2DEC, true)
 521 GST_CHECK_FEATURE(MPEG2DEC, [mpeg2dec], mpeg2dec, [
 522   GST_CHECK_LIBHEADER(MPEG2DEC, mpeg2, mpeg2_init,, mpeg2dec/mpeg2.h, MPEG2DEC_LIBS="-lmpeg2 -lmpeg2dec")
 523   AC_SUBST(MPEG2DEC_LIBS)
 524 ])
 525
 526 dnl *** openquicktime ***
 527 translit(dnm, m, l) AM_CONDITIONAL(USE_OPENQUICKTIME, true)
 528 GST_CHECK_FEATURE(OPENQUICKTIME, [Open Quicktime], quicktime_parser quicktime_decoder quicktime_demux,[
 529   GST_CHECK_LIBHEADER(OPENQUICKTIME, openquicktime, quicktime_init,, openquicktime/openquicktime.h, OPENQUICKTIME_LIBS="-lopenquicktime")
 530   AC_SUBST(OPENQUICKTIME_LIBS)
 531 ])
 532
 533 dnl *** raw1394 ***
 534 translit(dnm, m, l) AM_CONDITIONAL(USE_RAW1394, true)
 535 GST_CHECK_FEATURE(RAW1394, [raw1394 library], dv1394src, [
 536   GST_CHECK_LIBHEADER(RAW1394, raw1934, raw1934_get_handle,, libraw1394/raw1394.h, RAW1394_LIBS="-raw1394")
 537   AC_SUBST(RAW1394_LIBS)
 538 ])
 539
 540 dnl *** rtp ***
 541 dnl FIXME : adapt and make it work
 542 translit(dnm, m, l) AM_CONDITIONAL(USE_RTP, true)
 543 GST_CHECK_FEATURE(RTP, [RTP library], rtpenc rtpdec,[
 544   AC_CHECK_LIB(rtp, rtp_packet_new_take_data, HAVE_RTP=yes, HAVE_RTP=no, $GLIB_LIBS $GLIB_CFLAGS)
 545   RTP_LIBS="-lrtp"
 546   AC_SUBST(RTP_LIBS)
 547 ])
 548
 549
 550 dnl FIXME header check needs to use GLIB_CFLAGS in order to succeed for rtp
 551 dnl AC_CHECK_HEADERS(rtp/rtp.h, HAVE_LIBRTP=yes, HAVE_LIBRTP=no)
 552 dnl AC_CHECK_HEADERS(rtp/rtp-packet.h, :, HAVE_LIBRTP=no)
 553 dnl AC_CHECK_HEADERS(rtp/rtcp-packet.h, :, HAVE_LIBRTP=no)
 554 dnl AC_CHECK_HEADERS(rtp/rtp-audio.h, :, HAVE_LIBRTP=no)
 555
 556 dnl *** SDL ***
 557 translit(dnm, m, l) AM_CONDITIONAL(USE_SDL, true)
 558 GST_CHECK_FEATURE(SDL, [SDL plugin], sdlvideosink, [
 559  AM_PATH_SDL(, HAVE_SDL=yes, HAVE_SDL=no)
 560 ])
 561
 562 dnl *** shout ***
 563 translit(dnm, m, l) AM_CONDITIONAL(USE_SHOUT, true)
 564 GST_CHECK_FEATURE(SHOUT, [shout plugin], icecastsend, [
 565   GST_CHECK_LIBHEADER(SHOUT, shout, shout_init_connection,, shout/shout.h, SHOUT_LIBS="-lshout")
 566   AC_SUBST(SHOUT_LIBS)
 567 ])
 568
 569 dnl *** sidplay ***
 570 dnl FIXME : make this work
 571 translit(dnm, m, l) AM_CONDITIONAL(USE_SIDPLAY, true)
 572 GST_CHECK_FEATURE(SIDPLAY, [sidplay plugin], sidplay, [
 573   AC_LANG_PUSH(C++)
 574   AC_CHECK_HEADER(sidplay/sidtune.h, SIDPLAY_LIBS="-lsidplay", )
 575   AC_SUBST(SIDPLAY_LIBS)
 576   AC_LANG_POP()
 577 ])
 578
 579 dnl *** smoothwave ***
 580 translit(dnm, m, l) AM_CONDITIONAL(USE_SMOOTHWAVE, true)
 581 GST_CHECK_FEATURE(SMOOTHWAVE, [smoothwave plugin], smoothwave, [
 582   if test $HAVE_GTK = "yes"; then HAVE_SMOOTHWAVE=yes; fi;
 583 ])
 584
 585 dnl *** vorbis ***
 586 dnl AM_PATH_VORBIS only takes two options
 587 translit(dnm, m, l) AM_CONDITIONAL(USE_VORBIS, true)
 588 GST_CHECK_FEATURE(VORBIS, [vorbis plugin], vorbisenc vorbisdec, [
 589   AM_PATH_VORBIS(HAVE_VORBIS=yes, HAVE_VORBIS=no)
 590 ])
 591
 592 dnl *** XMMS ***
 593 translit(dnm, m, l) AM_CONDITIONAL(USE_XMMS, true)
 594 GST_CHECK_FEATURE(XMMS, [xmms plugin], xmms, [
 595   AM_PATH_XMMS(0.1.0, HAVE_XMMS=yes, HAVE_XMMS=no)
 596 ])
 597
 598 dnl Check for atomic.h
 599 dnl Note: use AC_CHECK_HEADER not AC_CHECK_HEADERS, because the latter
 600 dnl defines the wrong default symbol as well (HAVE_ASM_ATOMIC_H)
 601 AC_CHECK_HEADER(asm/atomic.h, HAVE_ATOMIC_H=yes, HAVE_ATOMIC_H=no)
 602 dnl Do a compile to check that it has atomic_set (eg, linux 2.0 didn't)
 603 if test x$HAVE_ATOMIC_H = xyes; then
 604   AC_TRY_RUN([
 605 #include "asm/atomic.h"
 606 main() { atomic_t t; atomic_set(&t,0); atomic_inc(&t); atomic_add(1,&t);return 0;}
 607   ],, [
 608     # Not successful
 609     if test x$HAVE_ATOMIC_H = xyes; then
 610       AC_MSG_WARN(Atomic reference counting is out of date: doing without.)
 611     fi
 612     HAVE_ATOMIC_H=no
 613   ], [
 614     # Cross compiling
 615     AC_MSG_RESULT(yes)
 616     AC_MSG_WARN(Can't check properly for atomic reference counting.  Assuming OK.)
 617   ])
 618 fi
 619
 620 dnl ######################################################################
 621 dnl # Check command line parameters, and set shell variables accordingly #
 622 dnl ######################################################################
 623
 624 AC_ARG_ENABLE(libmmx,
 625 [  --enable-libmmx              use libmmx, if available],
 626 [case "${enableval}" in
 627   yes) USE_LIBMMX=$HAVE_LIBMMX ;;
 628   no)  USE_LIBMMX=no ;;
 629   *) AC_MSG_ERROR(bad value ${enableval} for --enable-libmmx) ;;
 630 esac],
 631 [USE_LIBMMX=$HAVE_LIBMMX]) dnl Default value
 632
 633 AC_ARG_ENABLE(atomic,
 634 [  --enable-atomic              use atomic reference counting header],
 635 [case "${enableval}" in
 636   yes) USE_ATOMIC_H=$HAVE_ATOMIC_H;;
 637   noset) USE_ATOMIC_H=$HAVE_ATOMIC_H;;
 638   no)  USE_ATOMIC_H=no;;
 639   *) AC_MSG_ERROR(bad value ${enableval} for --enable-atomic) ;;
 640 esac],
 641 [USE_ATOMIC_H=$HAVE_ATOMIC_H]) dnl Default value
 642
 643 AC_ARG_ENABLE(plugin-builddir,
 644 [  --enable-plugin-builddir     allow tests/demos to use non-installed plugins ],
 645 [case "${enableval}" in
 646   yes) PLUGINS_USE_BUILDDIR=yes ;;
 647   no)  PLUGINS_USE_BUILDDIR=no ;;
 648   *) AC_MSG_ERROR(bad value ${enableval} for --enable-plugin-builddir) ;;
 649 esac],
 650 [PLUGINS_USE_BUILDDIR=no]) dnl Default value
 651
 652 AC_ARG_ENABLE(debug,
 653 [  --enable-debug               compile with -g debugging info],
 654 [case "${enableval}" in
 655   yes) USE_DEBUG=yes ;;
 656   no)  USE_DEBUG=no ;;
 657   *) AC_MSG_ERROR(bad value ${enableval} for --enable-debug) ;;
 658 esac],
 659 [USE_DEBUG=no]) dnl Default value
 660
 661 AC_ARG_ENABLE(DEBUG,
 662 [  --enable-DEBUG               compiles in a large number of debugging messages],
 663 [case "${enableval}" in
 664   yes) ENABLE_DEBUG=yes ;;
 665   no)  ENABLE_DEBUG=no ;;
 666   *) AC_MSG_ERROR(bad value ${enableval} for --enable-DEBUG) ;;
 667 esac],
 668 [ENABLE_DEBUG=no]) dnl Default value
 669 if test x$ENABLE_DEBUG = xyes; then
 670   AC_DEFINE(GST_DEBUG_ENABLED, 1, [Define if DEBUG statements should be compiled in])
 671 fi
 672
 673 AC_ARG_ENABLE(INFO,
 674 [  --disable-INFO               disables compilation of informational messages],
 675 [case "${enableval}" in
 676   yes) ENABLE_INFO=yes ;;
 677   no)  ENABLE_INFO=no ;;
 678   *) AC_MSG_ERROR(bad value ${enableval} for --enable-INFO) ;;
 679 esac],
 680 [ENABLE_INFO=yes]) dnl Default value
 681 if test x$ENABLE_INFO = xyes; then
 682   AC_DEFINE(GST_INFO_ENABLED, 1, [Define if INFO statements should be compiled in])
 683 fi
 684
 685 AC_ARG_ENABLE(debug-color,
 686 [  --disable-debug-color        disables color output of DEBUG and INFO output],
 687 [case "${enableval}" in
 688   yes) ENABLE_DEBUG_COLOR=yes ;;
 689   no)  ENABLE_DEBUG_COLOR=no ;;
 690   *) AC_MSG_ERROR(bad value ${enableval} for --enable-debug-color) ;;
 691 esac],
 692 [ENABLE_DEBUG_COLOR=yes]) dnl Default value
 693 if test "x$ENABLE_DEBUG_COLOR" = xyes; then
 694   AC_DEFINE(GST_DEBUG_COLOR, 1, [Define if debugging messages should be colorized])
 695 fi
 696
 697 AC_ARG_ENABLE(profiling,
 698 [  --enable-profiling           adds -pg to compiler commandline, for profiling],
 699 [case "${enableval}" in
 700   yes) USE_PROFILING=yes ;;
 701   no)  UES_PROFILING=no ;;
 702   *) AC_MSG_ERROR(bad value ${enableval} for --enable-profiling) ;;
 703 esac],
 704 [USE_PROFILING=no]) dnl Default value
 705
 706 dnl default to building registry in the source tree if we are enabling plugin build dir
 707 if test "x$PLUGINS_USE_BUILDDIR"="xyes"; then
 708   GST_CONFIG_DIR=`pwd`
 709 else
 710   GST_CONFIG_DIR=/etc/gstreamer
 711 fi
 712 AC_ARG_WITH(configdir,
 713 [  --with-configdir             specify path to use for configdir],
 714 [case "${withval}" in
 715   yes) AC_MSG_ERROR(bad value ${withval} for --with-configdir) ;;
 716   no) AC_MSG_ERROR(bad value ${withval} for --with-configdir) ;;
 717   *) GST_CONFIG_DIR="${withval}" ;;
 718 esac],
 719 [:]) dnl Default value
 720
 721 dnl Default value
 722 GST_WIN32_LIBDIR="/usr/lib/win32"
 723 AC_ARG_WITH(win32_libdir,
 724 [  --with-win32-libdir          specify location for win32 DLLs],
 725 [case "${withval}" in
 726   yes) AC_MSG_ERROR(bad value ${withval} for --with-win32-libdir) ;;
 727   no) AC_MSG_ERROR(bad value ${withval} for --with-win32-libdir) ;;
 728   *) GST_WIN32_LIBDIR="${withval}" ;;
 729 esac],
 730 [:]) dnl Default value
 731
 732 AC_ARG_ENABLE(docs-build,
 733 [  --enable-docs-build          enable building of documentation],
 734 [case "${enableval}" in
 735   yes) if $HAVE_GTK_DOC; then BUILD_DOCS=yes; else AC_MSG_ERROR([you don't have gtk-doc, so don't use --docs-build]); fi; ;;
 736   no)  BUILD_DOCS=no ;;
 737   *) AC_MSG_ERROR(bad value ${enableval} for --enable-docs-build) ;;
 738 esac],
 739 [BUILD_DOCS=no]) dnl Default value
 740
 741 AC_ARG_ENABLE(plugin-docs,
 742 [  --enable-plugin-docs         enable the building of plugin documentation
 743                                (this is currently broken, so off by default)],
 744 [case "${enableval}" in
 745   yes) BUILD_PLUGIN_DOCS=yes ;;
 746   no)  BUILD_PLUGIN_DOCS=no ;;
 747   *) AC_MSG_ERROR(bad value ${enableval} for --enable-plugin-docs) ;;
 748 esac],
 749 [BUILD_PLUGIN_DOCS=no]) dnl Default value
 750
 751 AC_ARG_ENABLE(tests,
 752 [  --disable-tests              disable building test apps],
 753 [case "${enableval}" in
 754   yes) BUILD_TESTS=yes ;;
 755   no)  BUILD_TESTS=no ;;
 756   *) AC_MSG_ERROR(bad value ${enableval} for --disable-tests) ;;
 757 esac],
 758 [BUILD_TESTS=yes]) dnl Default value
 759
 760 AC_ARG_ENABLE(examples,
 761 [  --disable-examples           disable building examples],
 762 [case "${enableval}" in
 763   yes) BUILD_EXAMPLES=yes ;;
 764   no)  BUILD_EXAMPLES=no ;;
 765   *) AC_MSG_ERROR(bad value ${enableval} for --disable-examples) ;;
 766 esac],
 767 [BUILD_EXAMPLES=yes]) dnl Default value
 768
 769 dnl Next, check for the optional components:
 770 dnl ========================================
 771
 772
 773 AC_DEFUN(GST_SUBSYSTEM_DISABLE,
 774 [dnl
 775 dnl Add a subsystem --disable flag and all the necessary symbols and substitions
 776 dnl
 777 AC_ARG_ENABLE(translit([$1], A-Z, a-z),
 778 [  ]builtin(format, --disable-%-17s  disable %s, translit([$1], A-Z, a-z), $2),
 779 [ case "${enableval}" in
 780     yes) GST_DISABLE_[$1]=no ;;
 781     no) GST_DISABLE_[$1]=yes ;;
 782     *) AC_MSG_ERROR(bad value ${enableval} for --enable-translit([$1], A-Z, a-z)) ;;
 783   esac],
 784 [GST_DISABLE_[$1]=no]) dnl Default value
 785 if test x$GST_DISABLE_[$1] = xyes; then
 786   AC_DEFINE(GST_DISABLE_[$1], 1, [Disable $2])
 787   GST_DISABLE_[$1]_DEFINE=-DGST_DISABLE_[$1]
 788 fi
 789 AM_CONDITIONAL(GST_DISABLE_[$1], test x$GST_DISABLE_[$1] = xyes)
 790 AC_SUBST(GST_DISABLE_[$1]_DEFINE)
 791 GST_SUBSYSTEM_DISABLE_DEFINES="$GST_SUBSYTEM_DISABLE_DEFINES $GST_DISABLE_[$1]_DEFINE"
 792 ])
 793
 794 translit(dnm, m, l) AM_CONDITIONAL(GST_DISABLE_LOADSAVE, true)
 795 GST_SUBSYSTEM_DISABLE(LOADSAVE,[pipeline XML load/save])
 796 translit(dnm, m, l) AM_CONDITIONAL(GST_DISABLE_TYPEFIND, true)
 797 GST_SUBSYSTEM_DISABLE(TYPEFIND,[typefind plugin],)
 798 translit(dnm, m, l) AM_CONDITIONAL(GST_DISABLE_AUTOPLUG, true)
 799 GST_SUBSYSTEM_DISABLE(AUTOPLUG,[autoplugger subsystem])
 800 translit(dnm, m, l) AM_CONDITIONAL(GST_DISABLE_PARSE, true)
 801 GST_SUBSYSTEM_DISABLE(PARSE,[command-line parser])
 802 translit(dnm, m, l) AM_CONDITIONAL(GST_DISABLE_TRACE, true)
 803 GST_SUBSYSTEM_DISABLE(TRACE,[tracing subsystem])
 804 translit(dnm, m, l) AM_CONDITIONAL(GST_DISABLE_REGISTRY, true)
 805 GST_SUBSYSTEM_DISABLE(REGISTRY,[plugin registry])
 806
 807 GST_CFLAGS="$GST_CFLAGS $GST_SUBSYSTEM_DISABLE_DEFINES"
 808
 809
 810 dnl ################################################
 811 dnl # Set defines according to variables set above #
 812 dnl ################################################
 813
 814
 815 if test "x$USE_LIBMMX" = xyes; then
 816   AC_DEFINE(HAVE_LIBMMX, 1, [Define if libmmx is available])
 817 fi
 818
 819 if test "x$USE_ATOMIC_H" = xyes; then
 820   AC_DEFINE(HAVE_ATOMIC_H, 1, [Define if atomic.h header file is available])
 821 fi
 822
 823 if test "x$PLUGINS_USE_BUILDDIR" = xyes; then
 824   AC_DEFINE(PLUGINS_USE_BUILDDIR, 1, [Define if plugins should be loaded from the build tree - only developers should use this])
 825 fi
 826
 827 dnl if test "x$USE_DEBUG" = xyes; then
 828 dnl   CFLAGS="$CFLAGS -g"
 829 dnl fi
 830
 831 if test "x$USE_PROFILING" = xyes; then
 832 dnl  CFLAGS="$CFLAGS -pg -fprofile-arcs"
 833   FOMIT_FRAME_POINTER=""
 834 else
 835   FOMIT_FRAME_POINTER="-fomit-frame-pointer"
 836 fi
 837
 838 dnl
 839 dnl AC_SUBST(FOMIT_FRAME_POINTER)
 840 dnl
 841
 842 if test "x$HAVE_LIBMIKMOD" = xyes; then
 843   AC_DEFINE(HAVE_LIBMIKMOD)
 844 fi
 845
 846 if test "x$HAVE_LIBGSM" = xyes; then
 847   AC_DEFINE(HAVE_LIBGSM)
 848 fi
 849
 850 dnl #############################
 851 dnl # Set automake conditionals #
 852 dnl #############################
 853
 854 dnl These should be "USE_*" instead of "HAVE_*", but some packages expect
 855 dnl HAVE_ and it is likely to be easier to stick with the old name
 856 AM_CONDITIONAL(HAVE_CPU_I386,       test "x$HAVE_CPU_I386" = "xyes")
 857 AM_CONDITIONAL(HAVE_CPU_PPC,        test "x$HAVE_CPU_PPC" = "xyes")
 858 AM_CONDITIONAL(HAVE_CPU_ALPHA,      test "x$HAVE_CPU_ALPHA" = "xyes")
 859 AM_CONDITIONAL(HAVE_CPU_ARM,        test "x$HAVE_CPU_ARM" = "xyes")
 860 AM_CONDITIONAL(HAVE_CPU_SPARC,      test "x$HAVE_CPU_SPARC" = "xyes")
 861 AM_CONDITIONAL(HAVE_LIBMMX,         test "x$USE_LIBMMX" = "xyes")
 862
 863 AM_CONDITIONAL(HAVE_ATOMIC_H,       test "x$USE_ATOMIC_H" = "xyes")
 864
 865 AM_CONDITIONAL(EXPERIMENTAL,        test "$EXPERIMENTAL" = "$xyes")
 866 AM_CONDITIONAL(BROKEN,              test "$BROKEN" = "$xyes")
 867
 868 AM_CONDITIONAL(HAVE_LIBMIKMOD,      test "x$HAVE_LIBMIKMOD" = "xyes")
 869 AM_CONDITIONAL(HAVE_LIBSDL,         test "x$HAVE_LIBSDL" = "xyes")
 870 AM_CONDITIONAL(HAVE_NASM,           test "x$HAVE_NASM" = "xyes")
 871 AM_CONDITIONAL(HAVE_LIBGLADE_GNOME, test "x$HAVE_LIBGLADE_GNOME" = "xyes")
 872 AM_CONDITIONAL(HAVE_GNOME,          test "x$HAVE_GNOME" = "xyes")
 873 AM_CONDITIONAL(HAVE_GTK,            test "x$HAVE_GTK" = "xyes")
 874 AM_CONDITIONAL(HAVE_GTK_DOC,        $HAVE_GTK_DOC)
 875 AM_CONDITIONAL(BUILD_DOCS,          test "x$BUILD_DOCS" = "xyes")
 876 AM_CONDITIONAL(BUILD_TESTS,         test "x$BUILD_TESTS" = "xyes")
 877 AM_CONDITIONAL(BUILD_EXAMPLES,      test "x$BUILD_EXAMPLES" = "xyes")
 878 AM_CONDITIONAL(BUILD_PLUGIN_DOCS,   test "x$BUILD_PLUGIN_DOCS" = "xyes")
 879 AM_CONDITIONAL(HAVE_PDFXMLTEX,      $HAVE_PDFXMLTEX)
 880 AM_CONDITIONAL(HAVE_PDFTOPS,        $HAVE_PDFTOPS)
 881 AM_CONDITIONAL(HAVE_XSLTPROC,       $HAVE_XSLTPROC)
 882 AM_CONDITIONAL(HAVE_FIG2DEV_PNG,    $HAVE_FIG2DEV_PNG)
 883 AM_CONDITIONAL(HAVE_FIG2DEV_PDF,    $HAVE_FIG2DEV_PDF)
 884 AM_CONDITIONAL(HAVE_LIBRTP,         test "x$HAVE_LIBRTP" = "xyes")
 885 AM_CONDITIONAL(HAVE_ARTS,           test "x$HAVE_ARTS" = "xyes")
 886 AM_CONDITIONAL(HAVE_RAW1394,        test "x$HAVE_RAW1394" = "xyes")
 887 AM_CONDITIONAL(HAVE_LIBDV,          test "x$HAVE_LIBDV" = "xyes")
 888 AM_CONDITIONAL(HAVE_GNOME_VFS,      test "x$HAVE_GNOME_VFS" = "xyes")
 889 AM_CONDITIONAL(HAVE_LIBGSM,         test "x$HAVE_LIBGSM" = "xyes")
 890 AM_CONDITIONAL(PLUGINS_USE_BUILDDIR,  test "x$PLUGINS_USE_BUILDDIR" = "xyes")
 891 AM_CONDITIONAL(HAVE_SIDPLAY,        test "x$have_sidplay" = "xyes")
 892
 893
 894 dnl ############################
 895 dnl # Set up some more defines #
 896 dnl ############################
 897
 898 dnl Set location of configuration dir.
 899 AC_DEFINE_UNQUOTED(GST_CONFIG_DIR,"$GST_CONFIG_DIR")
 900 AC_SUBST(GST_CONFIG_DIR)
 901
 902 dnl Set location of windows dll dir.
 903 AC_DEFINE_UNQUOTED(GST_WIN32_LIBDIR,"$GST_WIN32_LIBDIR")
 904 AC_SUBST(GST_WIN32_LIBDIR)
 905
 906 dnl Set location of plugin directory
 907 if test "x${prefix}" = "xNONE"; then
 908   PLUGINS_DIR=${ac_default_prefix}/lib/gst
 909 else
 910   PLUGINS_DIR=${prefix}/lib/gst
 911 fi
 912 AC_DEFINE_UNQUOTED(PLUGINS_DIR,"$PLUGINS_DIR")
 913 AC_SUBST(PLUGINS_DIR)
 914
 915 dnl Set location of uninstalled plugin directory
 916 PLUGINS_BUILDDIR=`pwd`
 917 AC_DEFINE_UNQUOTED(PLUGINS_BUILDDIR,"$PLUGINS_BUILDDIR")
 918 AC_SUBST(PLUGINS_BUILDDIR)
 919
 920 dnl Private vars for libgst only
 921 LIBGST_LIBS="$GST_LIBS $XML_LIBS $GLIB_LIBS"
 922 LIBGST_CFLAGS="$GST_CFLAGS $XML_CFLAGS $GLIB_CFLAGS"
 923 AC_SUBST(LIBGST_LIBS)
 924 AC_SUBST(LIBGST_CFLAGS)
 925
 926 dnl Vars for everyone else
 927 dnl FIXME: is there a reason to add this top_builddir stuff ? don't think so
 928 dnl GST_LIBS="\$(top_builddir)/gst/libgst.la $LIBGST_LIBS"
 929 dnl GST_CFLAGS="-I\$(top_srcdir) -I\$(top_srcdir)/include $LIBGST_CFLAGS"
 930 GST_CFLAGS="$GST_CFLAGS -I\$(top_srcdir)/gst-libs"
 931 AC_SUBST(GST_LIBS)
 932 AC_SUBST(GST_CFLAGS)
 933
 934 dnl #############################
 935 dnl # Configure the subpackages #
 936 dnl #############################
 937
 938 dnl AC_CONFIG_SUBDIRS(gist)
 939 dnl AC_CONFIG_SUBDIRS(plugins/mp3decode/xing/libxing)
 940
 941 dnl ##################################################
 942 dnl # Prepare informative messages to display at end #
 943 dnl ##################################################
 944
 945 infomessages=
 946
 947 if test "x$PLUGINS_USE_BUILDDIR" = xyes; then
 948   infomessages="$infomessages
 949 *** Warning: You have configured using the --enable-plugin-builddir option.
 950
 951 This option is for development purposes only: binaries built with
 952 it should be used with code in the build tree only.  To build an
 953 installable version, use ./configure without the --enable-plugin-builddir
 954 option.  Note that the autogen.sh script supplies the plugin builddir
 955 option automatically - it cannot be used to configure installable builds.
 956
 957 "
 958 fi
 959
 960 dnl #########################
 961 dnl # Make the output files #
 962 dnl #########################
 963
 964 AC_OUTPUT(
 965 Makefile
 966 gstreamer-libs.pc
 967 gstreamer-libs-uninstalled.pc
 968 gst/Makefile
 969 gst/ac3parse/Makefile
 970 gst/adder/Makefile
 971 gst/audioscale/Makefile
 972 gst/auparse/Makefile
 973 gst/avi/Makefile
 974 gst/chart/Makefile
 975 gst/cutter/Makefile
 976 gst/deinterlace/Makefile
 977 gst/flx/Makefile
 978 gst/intfloat/Makefile
 979 gst/law/Makefile
 980 gst/level/Makefile
 981 gst/median/Makefile
 982 gst/mpeg1enc/Makefile
 983 gst/mpeg1sys/Makefile
 984 gst/mpeg1videoparse/Makefile
 985 gst/mpeg2enc/Makefile
 986 gst/mpeg2sub/Makefile
 987 gst/mpegaudio/Makefile
 988 gst/mpegaudioparse/Makefile
 989 gst/mpegstream/Makefile
 990 gst/mpegtypes/Makefile
 991 gst/passthrough/Makefile
 992 gst/playondemand/Makefile
 993 gst/rtjpeg/Makefile
 994 gst/silence/Makefile
 995 gst/sine/Makefile
 996 gst/smooth/Makefile
 997 gst/spectrum/Makefile
 998 gst/speed/Makefile
 999 gst/stereo/Makefile
1000 gst/stereomono/Makefile
1001 gst/synaesthesia/Makefile
1002 gst/udp/Makefile
1003 gst/videoscale/Makefile
1004 gst/volenv/Makefile
1005 gst/volume/Makefile
1006 gst/vumeter/Makefile
1007 gst/wavparse/Makefile
1008 gst/y4m/Makefile
1009 sys/Makefile
1010 sys/oss/Makefile
1011 sys/qcam/Makefile
1012 sys/v4l/Makefile
1013 sys/vcd/Makefile
1014 sys/vga/Makefile
1015 sys/xvideo/Makefile
1016 examples/capsfilter/Makefile
1017 ext/Makefile
1018 ext/a52dec/Makefile
1019 ext/aalib/Makefile
1020 ext/alsa/Makefile
1021 ext/arts/Makefile
1022 ext/artsd/Makefile
1023 ext/audiofile/Makefile
1024 ext/avifile/Makefile
1025 ext/cdparanoia/Makefile
1026 ext/dv/Makefile
1027 ext/dvdread/Makefile
1028 ext/esd/Makefile
1029 ext/festival/Makefile
1030 ext/flac/Makefile
1031 ext/gnomevfs/Makefile
1032 ext/gsm/Makefile
1033 ext/hermes/Makefile
1034 ext/http/Makefile
1035 ext/jpeg/Makefile
1036 ext/ladspa/Makefile
1037 ext/lame/Makefile
1038 ext/mad/Makefile
1039 ext/mikmod/Makefile
1040 ext/mpeg2dec/Makefile
1041 ext/openquicktime/Makefile
1042 ext/raw1394/Makefile
1043 ext/rtp/Makefile
1044 ext/sdl/Makefile
1045 ext/shout/Makefile
1046 ext/sidplay/Makefile
1047 ext/smoothwave/Makefile
1048 ext/vorbis/Makefile
1049 ext/xmms/Makefile
1050 gst-libs/Makefile
1051 gst-libs/gst/Makefile
1052 gst-libs/gst/audio/Makefile
1053 gst-libs/gst/idct/Makefile
1054 gst-libs/gst/resample/Makefile
1055 gst-libs/gst/riff/Makefile
1056 gst-plugins.spec
1057 )
1058
1059 echo -e "configure: *** Plugins that will be built : $GST_PLUGINS_YES"
1060 echo
1061 echo -e "configure: *** Plugins that will not be built : $GST_PLUGINS_NO"
1062 echo