configure.ac

   1 AC_PREREQ(2.69)
   2 dnl initialize autoconf
   3 dnl when going to/from release please set the nano (fourth number) right !
   4 dnl releases only do Wall, cvs and prerelease does Werror too
   5 AC_INIT([GStreamer RTSP Server Library], [1.5.1.1],
   6     [http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer],
   7     [gst-rtsp-server])
   8 AG_GST_INIT
   9
  10 dnl initialize automake
  11 AM_INIT_AUTOMAKE([-Wno-portability 1.14 no-dist-gzip dist-xz tar-ustar subdir-objects])
  12
  13 dnl define PACKAGE_VERSION_* variables
  14 AS_VERSION
  15
  16 dnl check if this is a release version
  17 AS_NANO(GST_GIT="no", GST_GIT="yes")
  18
  19 dnl can autoconf find the source ?
  20 AC_CONFIG_SRCDIR([gst/rtsp-server/rtsp-server.c])
  21
  22 dnl define the output header for config
  23 AC_CONFIG_HEADERS([config.h])
  24
  25 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  26 AM_MAINTAINER_MODE([enable])
  27
  28 dnl sets host_* variables
  29 AC_CANONICAL_HOST
  30
  31 dnl use pretty build output with automake >= 1.11
  32 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],
  33   [AM_DEFAULT_VERBOSITY=1
  34    AC_SUBST(AM_DEFAULT_VERBOSITY)])
  35
  36 dnl our libraries and install dirs use major.minor as a version
  37 dnl GST_API_VERSION=$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR
  38 dnl we override it here if we need to for the release candidate of new series
  39 GST_API_VERSION=1.0
  40 AC_SUBST(GST_API_VERSION)
  41
  42 dnl CURRENT, REVISION, AGE
  43 dnl - library source changed -> increment REVISION
  44 dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
  45 dnl - interfaces added -> increment AGE
  46 dnl - interfaces removed -> AGE = 0
  47 dnl
  48 dnl Keep CURRENT as MINOR * 100 + MICRO
  49 dnl Ex : 1.0.0 => 0
  50 dnl      1.0.3 => 3
  51 dnl      1.1.0 => 100
  52 dnl      1.2.5 => 205
  53 dnl      1.10.9 (who knows) => 1009
  54 dnl
  55 dnl sets GST_LT_LDFLAGS
  56 AS_LIBTOOL(GST, 501, 0, 501)
  57
  58 dnl *** required versions of GStreamer stuff ***
  59 GST_REQ=1.5.1.1
  60 GSTPB_REQ=1.5.1.1
  61 GSTPG_REQ=1.5.1.1
  62 GSTPD_REQ=1.5.1.1
  63
  64 dnl *** autotools stuff ****
  65
  66 dnl allow for different autotools
  67 AS_AUTOTOOLS_ALTERNATE
  68
  69 dnl Add parameters for aclocal
  70 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  71 AC_CONFIG_MACRO_DIR([m4])
  72
  73 dnl set up gettext
  74 dnl the version check needs to stay here because autopoint greps for it
  75 #AM_GNU_GETTEXT_VERSION([0.17])
  76 #AM_GNU_GETTEXT([external])
  77 #AG_GST_GETTEXT([gst-rtsp-server-$GST_API_VERSION])
  78
  79 dnl *** check for arguments to configure ***
  80
  81 AG_GST_ARG_DISABLE_FATAL_WARNINGS
  82
  83 AG_GST_ARG_DEBUG
  84 AG_GST_ARG_VALGRIND
  85 AG_GST_ARG_GCOV
  86 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  87 AG_GST_ARG_WITH_PACKAGE_NAME
  88 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  89
  90 AG_GST_ARG_EXAMPLES
  91
  92 AG_GST_PKG_CONFIG_PATH
  93
  94 AG_GST_SET_PACKAGE_RELEASE_DATETIME_WITH_NANO([$PACKAGE_VERSION_NANO],
  95   ["${srcdir}/gst-rtsp-server.doap"],
  96   [$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_MICRO])
  97
  98 dnl building of tests
  99 AC_ARG_ENABLE(tests,
 100   AS_HELP_STRING([--disable-tests],[disable building test apps]),
 101   [
 102     case "${enableval}" in
 103       yes) BUILD_TESTS=yes ;;
 104       no)  BUILD_TESTS=no ;;
 105       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-tests) ;;
 106     esac
 107   ],
 108 [BUILD_TESTS=yes]) dnl Default value
 109 AM_CONDITIONAL(BUILD_TESTS,         test "x$BUILD_TESTS" = "xyes")
 110
 111 dnl *** checks for platform ***
 112
 113 dnl * hardware/architecture *
 114
 115 dnl *** checks for programs ***
 116
 117 dnl find a compiler
 118 AC_PROG_CC
 119 AC_PROG_CC_STDC
 120
 121 dnl check if the compiler supports '-c' and '-o' options
 122 AM_PROG_CC_C_O
 123
 124 dnl find an assembler
 125 AM_PROG_AS
 126
 127 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 128 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 129
 130 dnl check for gobject-introspection
 131 GOBJECT_INTROSPECTION_CHECK([1.31.1])
 132
 133 dnl check for documentation tools
 134 AG_GST_DOCBOOK_CHECK
 135 GTK_DOC_CHECK([1.12])
 136
 137 dnl *** checks for libraries ***
 138
 139 dnl *** checks for header files ***
 140
 141 dnl *** checks for types/defines ***
 142
 143 dnl *** checks for structures ***
 144
 145 dnl *** checks for compiler characteristics ***
 146
 147 dnl *** checks for library functions ***
 148
 149 dnl *** checks for dependancy libraries ***
 150
 151 dnl GLib is required
 152 GLIB_REQ=2.32.0
 153 AC_SUBST([GLIB_REQ])
 154 AG_GST_GLIB_CHECK([$GLIB_REQ])
 155
 156 dnl checks for gstreamer
 157 dnl uninstalled is selected preferentially -- see pkg-config(1)
 158 AG_GST_CHECK_GST($GST_API_VERSION, [$GST_REQ], [yes])
 159
 160 GST_TOOLS_DIR=`$PKG_CONFIG --variable=toolsdir gstreamer-$GST_API_VERSION`
 161 if test -z $GST_TOOLS_DIR; then
 162   AC_MSG_ERROR([no tools dir defined in GStreamer pkg-config file; core upgrade needed.])
 163 fi
 164 AC_SUBST(GST_TOOLS_DIR)
 165
 166 GST_PLUGINS_DIR=`$PKG_CONFIG gstreamer-$GST_API_VERSION --variable pluginsdir`
 167 AC_SUBST(GST_PLUGINS_DIR)
 168 AC_MSG_NOTICE(Using GStreamer Core Plugins in $GST_PLUGINS_DIR)
 169
 170 AG_GST_CHECK_GST_BASE($GST_API_VERSION, [$GST_REQ], [yes])
 171
 172 AG_GST_CHECK_GST_PLUGINS_BASE($GST_API_VERSION, [$GSTPB_REQ], [yes])
 173 GSTPB_PLUGINS_DIR=`$PKG_CONFIG gstreamer-plugins-base-$GST_API_VERSION --variable pluginsdir`
 174 AC_SUBST(GSTPB_PLUGINS_DIR)
 175 AC_MSG_NOTICE(Using GStreamer Base Plugins in $GSTPB_PLUGINS_DIR)
 176
 177 AG_GST_CHECK_GST_PLUGINS_GOOD($GST_API_VERSION, [$GSTPG_REQ], [yes])
 178 GSTPG_PLUGINS_DIR=`$PKG_CONFIG gstreamer-plugins-good-$GST_API_VERSION --variable pluginsdir`
 179 AC_SUBST(GSTPG_PLUGINS_DIR)
 180 AC_MSG_NOTICE(Using GStreamer Good Plugins in $GSTPG_PLUGINS_DIR)
 181
 182 AG_GST_CHECK_GST_PLUGINS_BAD($GST_API_VERSION, [$GSTPD_REQ], [yes])
 183 GSTPD_PLUGINS_DIR=`$PKG_CONFIG gstreamer-plugins-bad-$GST_API_VERSION --variable pluginsdir`
 184 AC_SUBST(GSTPD_PLUGINS_DIR)
 185 AC_MSG_NOTICE(Using GStreamer Bad Plugins in $GSTPD_PLUGINS_DIR)
 186
 187 AG_GST_CHECK_GST_CHECK($GST_API_VERSION, [$GST_REQ], no)
 188 AM_CONDITIONAL(HAVE_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 189
 190 dnl Check for -Bsymbolic-functions linker flag used to avoid
 191 dnl intra-library PLT jumps, if available.
 192 AC_ARG_ENABLE(Bsymbolic,
 193               [AS_HELP_STRING([--disable-Bsymbolic],[avoid linking with -Bsymbolic])],,
 194               [SAVED_LDFLAGS="${LDFLAGS}"
 195                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
 196                LDFLAGS=-Wl,-Bsymbolic-functions
 197                AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [[int main (void) { return 0; }]])],[
 198                            AC_MSG_RESULT(yes)
 199                            enable_Bsymbolic=yes],[
 200                            AC_MSG_RESULT(no)
 201                            enable_Bsymbolic=no])
 202                LDFLAGS="${SAVED_LDFLAGS}"])
 203
 204 dnl *** set variables based on configure arguments ***
 205
 206 dnl set license and copyright notice
 207 GST_LICENSE="LGPL"
 208 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 209 AC_SUBST(GST_LICENSE)
 210
 211 dnl set location of plugin directory
 212 AG_GST_SET_PLUGINDIR
 213
 214 dnl set release date/time (and check that release version is in doap file)
 215 AG_GST_SET_PACKAGE_RELEASE_DATETIME_WITH_NANO([$PACKAGE_VERSION_NANO],
 216   ["${srcdir}/gst-rtsp-server.doap"],
 217   [$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_MICRO])
 218
 219 # set by AG_GST_PARSE_SUBSYSTEM_DISABLES above
 220 dnl make sure it doesn't complain about unused variables if debugging is disabled
 221 NO_WARNINGS=""
 222 AG_GST_CHECK_GST_DEBUG_DISABLED([NO_WARNINGS="-Wno-unused"], [NO_WARNINGS=""])
 223
 224 dnl define an ERROR_CFLAGS Makefile variable
 225 AG_GST_SET_ERROR_CFLAGS($FATAL_WARNINGS, [-Wmissing-declarations -Wmissing-prototypes -Wredundant-decls -Wundef -Wwrite-strings -Wformat-nonliteral -Wformat-security -Wold-style-definition -Winit-self -Wmissing-include-dirs -Waddress -Waggregate-return -Wno-multichar -Wnested-externs $NO_WARNINGS])
 226
 227 dnl define correct level for debugging messages
 228 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 229
 230 dnl used in examples
 231 AG_GST_DEFAULT_ELEMENTS
 232
 233 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 234
 235 dnl Overview:
 236 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
 237 dnl GST_*:              flags shared by built objects to link against GStreamer
 238 dnl GST_ALL_LDFLAGS:    linker flags shared by all
 239 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 240 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 241 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 242
 243 dnl GST_OPTION_CFLAGS
 244 if test "x$USE_DEBUG" = xyes; then
 245    PROFILE_CFLAGS="-g"
 246 fi
 247 AC_SUBST(PROFILE_CFLAGS)
 248
 249 # GST_DISABLE_DEPRECATED: hide the visibility of deprecated
 250 # functionality from the API that gstreamer uses
 251 # GST_REMOVE_DEPRECATED: don't compile deprecated functionality (breaks ABI)
 252 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
 253   dnl Define _only_ when compiling from git (not for pre-releases or releases)
 254   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 255 else
 256   DEPRECATED_CFLAGS=""
 257 fi
 258 AC_SUBST(DEPRECATED_CFLAGS)
 259
 260 dnl every flag in GST_OPTION_CFLAGS can be overridden at make time
 261 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 262 AC_SUBST(GST_OPTION_CFLAGS)
 263
 264 dnl FIXME: do we want to rename to GST_ALL_* ?
 265 dnl prefer internal headers to already installed ones
 266 dnl add GST_OPTION_CFLAGS, but overridable
 267 GST_CFLAGS="$GST_CFLAGS \$(GST_OPTION_CFLAGS)"
 268 AC_SUBST(GST_CFLAGS)
 269 AC_SUBST(GST_LIBS)
 270
 271 dnl GST_ALL_*
 272 dnl vars common to for all internal objects (core libs, elements, applications)
 273 dnl CFLAGS:
 274 dnl - src and build dirs need to be added because every piece that gets built
 275 dnl   will need the GStreamer source and generated headers
 276 GST_ALL_CFLAGS="-I\$(top_srcdir) -I\$(top_builddir) $GST_PLUGINS_BASE_CFLAGS $GST_CFLAGS \$(GST_OPTION_CFLAGS)"
 277 AC_SUBST([GST_ALL_CFLAGS])
 278
 279 dnl FIXME: check if LTLIBINTL is needed everywhere
 280 dnl I presume it is given that it contains the symbols that _() stuff maps to
 281 GST_ALL_LIBS="$GST_LIBS $LTLIBINTL \$(GCOV_LIBS)"
 282 AC_SUBST([GST_ALL_LIBS])
 283
 284 dnl LDFLAGS really should only contain flags, not libs - they get added before
 285 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 286 GST_ALL_LDFLAGS="-no-undefined"
 287 if test "x${enable_Bsymbolic}" = "xyes"; then
 288   GST_ALL_LDFLAGS="$GST_ALL_LDFLAGS -Wl,-Bsymbolic-functions"
 289 fi
 290
 291 AC_SUBST(GST_ALL_LDFLAGS)
 292
 293 dnl GST_LIB_LDFLAGS
 294 dnl linker flags shared by all libraries
 295 dnl LDFLAGS modifier defining exported symbols from built libraries
 296 GST_LIB_LDFLAGS="-export-symbols-regex \^[_]?\(gst_\|Gst\|GST_\).*"
 297 AC_SUBST(GST_LIB_LDFLAGS)
 298
 299 dnl GST_OBJ_*
 300 dnl default vars for all internal objects built on libgstrtspserver
 301 dnl includes GST_ALL_*
 302 GST_OBJ_CFLAGS="\$(GST_ALL_CFLAGS)"
 303 AC_SUBST([GST_OBJ_CFLAGS])
 304 GST_OBJ_LIBS="\$(top_builddir)/gst/rtsp-server/libgstrtspserver-$GST_API_VERSION.la \$(GST_ALL_LIBS)"
 305 AC_SUBST([GST_OBJ_LIBS])
 306
 307 PKG_CHECK_MODULES(LIBCGROUP, libcgroup >= 0.26, HAVE_LIBCGROUP="yes", HAVE_LIBCGROUP="no")
 308 AC_SUBST(LIBCGROUP_CFLAGS)
 309 AC_SUBST(LIBCGROUP_LIBS)
 310 AM_CONDITIONAL(HAVE_LIBCGROUP, test "x$HAVE_LIBCGROUP" = "xyes")
 311
 312 dnl this really should only contain flags, not libs - they get added before
 313 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 314
 315 dnl *** output files ***
 316
 317 dnl keep this alphabetic per directory, please
 318 AC_CONFIG_FILES([
 319 Makefile
 320 gst-rtsp.spec
 321 common/Makefile
 322 common/m4/Makefile
 323 gst/Makefile
 324 gst/rtsp-server/Makefile
 325 examples/Makefile
 326 tests/Makefile
 327 tests/check/Makefile
 328 pkgconfig/Makefile
 329 pkgconfig/gstreamer-rtsp-server.pc
 330 pkgconfig/gstreamer-rtsp-server-uninstalled.pc
 331 docs/Makefile
 332 docs/version.entities
 333 docs/libs/Makefile
 334 ])
 335 AC_OUTPUT
 336
 337 echo "
 338
 339 Configuration
 340         Version                    : ${VERSION}
 341         Source code location       : ${srcdir}
 342         Prefix                     : ${prefix}
 343         Compiler                   : ${CC}
 344         CGroups example            : ${HAVE_LIBCGROUP}
 345
 346 gst-rtsp-server configured. Type 'make' to build.
 347 "